CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.1 FATAL_ERROR)
   2
   3 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/cmake")
   4 project(NetRadiant C CXX)
   5
   6 if (EXISTS "${PROJECT_SOURCE_DIR}/libs/crunch/inc/crn_decomp.h")
   7     set(DEFAULT_BUILD_CRUNCH ON CACHE INTERNAL "...")
   8 else ()
   9     set(DEFAULT_BUILD_CRUNCH OFF CACHE INTERNAL "...")
  10 endif ()
  11
  12 if (EXISTS "${PROJECT_SOURCE_DIR}/tools/unvanquished/daemonmap/tools/quake3/q3map2/main.c")
  13     set(DEFAULT_BUILD_DAEMONMAP ON CACHE INTERNAL "...")
  14 else ()
  15     set(DEFAULT_BUILD_DAEMONMAP OFF CACHE INTERNAL "...")
  16 endif ()
  17
  18 option(BUILD_RADIANT "Build the GUI" ON)
  19 option(BUILD_TOOLS "Build the tools" ON)
  20 option(BUILD_CRUNCH "Build Crunch image support" ${DEFAULT_BUILD_CRUNCH})
  21 option(BUILD_DAEMONMAP "Build daemonmap navigation mesh generator" ${DEFAULT_BUILD_DAEMONMAP})
  22 option(DOWNLOAD_GAMEPACKS "Download game packs" ON)
  23 option(USE_WERROR "Build with -Werror -pedantic-errors" OFF)
  24 option(FHS_INSTALL "Install according to Filesystem Hierarchy Standard" OFF)
  25
  26 set(BUILD_BINARIES OFF CACHE INTERNAL "...")
  27 if (BUILD_RADIANT OR BUILD_TOOLS)
  28     set(BUILD_BINARIES ON)
  29 endif ()
  30
  31 #-----------------------------------------------------------------------
  32 # Paths
  33 #-----------------------------------------------------------------------
  34
  35 if (CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  36     set(CMAKE_INSTALL_PREFIX "${PROJECT_SOURCE_DIR}/install" CACHE PATH "..." FORCE)
  37 endif ()
  38
  39 set(RADIANT_NAME "NetRadiant" CACHE INTERNAL "...")
  40 add_definitions(-DRADIANT_NAME="${RADIANT_NAME}")
  41 set(RADIANT_BASENAME "netradiant" CACHE INTERNAL "...")
  42 add_definitions(-DRADIANT_BASENAME="${RADIANT_BASENAME}")
  43
  44 set(RADIANT_LIB_DIR ${CMAKE_INSTALL_PREFIX} CACHE INTERNAL "...")
  45 set(RADIANT_BIN_DIR ${CMAKE_INSTALL_PREFIX} CACHE INTERNAL "...")
  46 set(RADIANT_DATA_DIR ${CMAKE_INSTALL_PREFIX} CACHE INTERNAL "...")
  47
  48 if (FHS_INSTALL AND NOT BUNDLE_LIBRARIES)
  49     set(RADIANT_LIB_DIR ${CMAKE_INSTALL_PREFIX}/lib/${RADIANT_BASENAME})
  50     set(RADIANT_BIN_DIR ${CMAKE_INSTALL_PREFIX}/bin)
  51     set(RADIANT_DATA_DIR ${CMAKE_INSTALL_PREFIX}/share/${RADIANT_BASENAME})
  52 endif ()
  53
  54 set(GAMEPACKS_DOWNLOAD_DIR ${PROJECT_BINARY_DIR}/download CACHE PATH "Where to store downloaded game packs")
  55
  56 #-----------------------------------------------------------------------
  57 # Version
  58 #-----------------------------------------------------------------------
  59
  60 # CMake 3.0+ would allow this in project()
  61 set(RADIANT_VERSION_MAJOR 1)
  62 set(RADIANT_VERSION_MINOR 5)
  63 set(RADIANT_VERSION_PATCH 0)
  64 set(RADIANT_VERSION "${RADIANT_VERSION_MAJOR}.${RADIANT_VERSION_MINOR}.${RADIANT_VERSION_PATCH}")
  65
  66 set(RADIANT_ABOUTMSG "Custom build" CACHE STRING "About message")
  67
  68 find_package(Git REQUIRED)
  69
  70 execute_process(
  71      COMMAND ${GIT_EXECUTABLE} rev-parse --short HEAD
  72      WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
  73      OUTPUT_VARIABLE GIT_VERSION
  74      OUTPUT_STRIP_TRAILING_WHITESPACE
  75 )
  76
  77 set(RADIANT_VERSION_STRING "${RADIANT_VERSION}n")
  78
  79 if (GIT_VERSION)
  80     set(RADIANT_VERSION_STRING "${RADIANT_VERSION_STRING}-git-${GIT_VERSION}")
  81 endif ()
  82
  83 message(STATUS "Building ${PROJECT_NAME} ${RADIANT_VERSION_STRING} ${RADIANT_ABOUTMSG}")
  84
  85 #-----------------------------------------------------------------------
  86 # Language standard
  87 #-----------------------------------------------------------------------
  88
  89 if (BUILD_BINARIES)
  90     set(CMAKE_CXX_STANDARD 11)
  91     set(CMAKE_CXX_STANDARD_REQUIRED ON)
  92     set(CMAKE_CXX_EXTENSIONS OFF)
  93
  94     if (CMAKE_VERSION VERSION_LESS "3.1")
  95         if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" OR CMAKE_COMPILER_IS_GNUCXX)
  96             include(CheckCXXCompilerFlag)
  97             check_cxx_compiler_flag(--std=c++${CMAKE_CXX_STANDARD} STD_CXX)
  98             if (STD_CXX)
  99                 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} --std=c++${CMAKE_CXX_STANDARD}")
 100             else ()
 101                 message(SEND_ERROR "Requires C++${CMAKE_CXX_STANDARD} or better")
 102             endif ()
 103         else ()
 104             message(WARNING "Unrecognized compiler: ${CMAKE_CXX_COMPILER_ID}, make sure it supports C++${CMAKE_CXX_STANDARD}")
 105         endif ()
 106     endif ()
 107 endif ()
 108
 109 #-----------------------------------------------------------------------
 110 # Flags
 111 #-----------------------------------------------------------------------
 112
 113 if (BUILD_BINARIES)
 114     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-exceptions -fno-rtti")
 115
 116     macro (addflags_c args)
 117         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${args}")
 118     endmacro ()
 119
 120     macro (addflags_cxx args)
 121         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${args}")
 122     endmacro ()
 123
 124     macro (addflags args)
 125         addflags_c("${args}")
 126         addflags_cxx("${args}")
 127     endmacro ()
 128
 129     addflags("-fno-strict-aliasing")
 130     if (NOT WIN32)
 131         addflags("-fvisibility=hidden")
 132     endif ()
 133
 134     if (USE_WERROR)
 135         addflags("-Werror")
 136         addflags("-pedantic-errors")
 137     endif ()
 138
 139     addflags("-Wall")
 140     addflags("-Wextra")
 141     addflags("-pedantic")
 142
 143     addflags_c("-Wno-deprecated-declarations") # vfs.c: g_strdown
 144
 145     addflags("-Wno-unused-function")
 146     addflags("-Wno-unused-variable")
 147     addflags("-Wno-unused-parameter")
 148
 149     set(CMAKE_POSITION_INDEPENDENT_CODE 1)
 150 endif ()
 151
 152 if (BUILD_RADIANT)
 153     set(GTK_TARGET 2 CACHE STRING "GTK target")
 154     add_definitions(-DGTK_TARGET=${GTK_TARGET})
 155
 156     if (WIN32)
 157         add_definitions(-DWORKAROUND_WINDOWS_FLOATING_WINDOW=1)
 158
 159         if (GTK_TARGET EQUAL 2)
 160             add_definitions(-DWORKAROUND_WINDOWS_GTK2_GLWIDGET=1)
 161         endif ()
 162     endif ()
 163 endif ()
 164
 165 option(BUILTIN_GTKGLEXT "Builtin GtkGLExt" OFF)
 166 if (BUILTIN_GTKGLEXT)
 167     include(${CMAKE_ROOT}/Modules/ExternalProject.cmake)
 168
 169     execute_process(COMMAND pkg-config --libs gdk-2.0 gtk+-2.0 glib-2.0 gl
 170         OUTPUT_VARIABLE GTKGLEXT_LDFLAGS
 171         OUTPUT_STRIP_TRAILING_WHITESPACE
 172     )
 173     set(GTKGLEXT_LDFLAGS "-lm ${GTKGLEXT_LDFLAGS}")
 174
 175     ExternalProject_Add(gtkglext
 176         GIT_REPOSITORY https://gitlab.gnome.org/illwieckz/gtkglext.git
 177         GIT_TAG fixes
 178         BUILD_IN_SOURCE ON
 179         CONFIGURE_COMMAND NOCONFIGURE=1 ./autogen.sh
 180         CONFIGURE_COMMAND && ./configure --prefix "${CMAKE_BINARY_DIR}/external"
 181         BUILD_COMMAND $(MAKE) LDFLAGS=${GTKGLEXT_LDFLAGS}
 182         INSTALL_COMMAND $(MAKE) install
 183     )
 184 endif ()
 185
 186 #-----------------------------------------------------------------------
 187 # Defs
 188 #-----------------------------------------------------------------------
 189
 190 if (BUILD_BINARIES)
 191     add_definitions(-DRADIANT_VERSION="${RADIANT_VERSION}")
 192     add_definitions(-DRADIANT_VERSION_STRING="${RADIANT_VERSION_STRING}")
 193
 194     if (NOT CMAKE_BUILD_TYPE MATCHES Release)
 195         add_definitions(-D_DEBUG=1)
 196     endif ()
 197 endif ()
 198
 199 if (BUILD_RADIANT)
 200     add_definitions(-DRADIANT_ABOUTMSG="${RADIANT_ABOUTMSG}")
 201
 202     macro (disable_deprecated name gtk2only)
 203         add_definitions(-D${name}_DISABLE_SINGLE_INCLUDES)
 204         if ((${gtk2only} EQUAL 0) OR (GTK_TARGET EQUAL 2))
 205             add_definitions(-D${name}_DISABLE_DEPRECATED)
 206         endif ()
 207     endmacro ()
 208
 209     disable_deprecated(ATK 0)
 210     disable_deprecated(G 0)
 211     disable_deprecated(GDK 0)
 212     disable_deprecated(GDK_PIXBUF 0)
 213     disable_deprecated(GTK 1)
 214     disable_deprecated(PANGO 0)
 215 endif ()
 216
 217 if (BUILD_BINARIES)
 218     add_custom_target(binaries ALL)
 219
 220     if(APPLE OR ${CMAKE_SYSTEM_NAME} STREQUAL "FreeBSD")
 221         link_directories(
 222             /usr/local/lib
 223         )
 224     endif ()
 225
 226     if (WIN32)
 227         add_definitions(
 228             -DWIN32=1
 229             -D_WIN32=1
 230         )
 231     else ()
 232         add_definitions(
 233             -DPOSIX=1
 234         )
 235     endif ()
 236 endif ()
 237
 238 if (BUILD_RADIANT AND NOT APPLE AND NOT WIN32)
 239     set(XWINDOWS ON)
 240     find_package(X11 REQUIRED)
 241     include_directories(${X11_INCLUDE_DIR})
 242     add_definitions(-DXWINDOWS=1)
 243 endif ()
 244
 245 if (BUILD_BINARIES)
 246     include_directories("${PROJECT_SOURCE_DIR}/include")
 247     include_directories("${PROJECT_SOURCE_DIR}/libs")
 248
 249     if (WIN32 OR "${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
 250         set(BUNDLING_SUPPORTED ON)
 251     endif()
 252
 253     if (BUNDLING_SUPPORTED)
 254         if(WIN32 AND NOT CMAKE_CROSSCOMPILING)
 255             set(BUNDLE_LIBRARIES_DEFAULT ON)
 256         else ()
 257             set(BUNDLE_LIBRARIES_DEFAULT OFF)
 258         endif ()
 259
 260         option(BUNDLE_LIBRARIES "Bundle libraries" ${BUNDLE_LIBRARIES_DEFAULT})
 261     endif ()
 262
 263     if (BUNDLE_LIBRARIES AND BUNDLING_SUPPORTED)
 264         add_subdirectory(bundle)
 265
 266         set(FHS_INSTALL OFF CACHE PATH "Disabled because of BUNDLE_LIBRARIES" FORCE)
 267     endif ()
 268
 269     macro (copy_dlls target)
 270         if (BUNDLE_LIBRARIES AND BUNDLING_SUPPORTED)
 271             add_custom_command(TARGET ${target} POST_BUILD
 272                 COMMAND "${PROJECT_SOURCE_DIR}/library-bundler"
 273                 "register" "${PROJECT_BINARY_DIR}" "$<TARGET_FILE:${target}>"
 274                 VERBATIM
 275             )
 276             add_dependencies(bundle ${target})
 277         endif ()
 278     endmacro ()
 279 endif ()
 280
 281 #-----------------------------------------------------------------------
 282 # Libraries
 283 #-----------------------------------------------------------------------
 284
 285 if (BUILD_BINARIES)
 286     add_subdirectory(libs)
 287 endif ()
 288
 289 if (BUILD_RADIANT)
 290     add_subdirectory(include)
 291 endif ()
 292
 293 #-----------------------------------------------------------------------
 294 # Plugins
 295 #-----------------------------------------------------------------------
 296
 297 if (BUILD_RADIANT)
 298     add_subdirectory(contrib)
 299 endif ()
 300
 301 #-----------------------------------------------------------------------
 302 # Modules
 303 #-----------------------------------------------------------------------
 304
 305 if (BUILD_RADIANT)
 306     add_subdirectory(plugins)
 307 endif ()
 308
 309 #-----------------------------------------------------------------------
 310 # Radiant
 311 #-----------------------------------------------------------------------
 312
 313 if (BUILD_BINARIES)
 314     macro (radiant_tool name)
 315         add_dependencies(binaries ${name})
 316
 317         if (WIN32)
 318             add_executable(${name} ${ARGN} ${PROJECT_SOURCE_DIR}/include/lib.rc)
 319         else ()
 320             add_executable(${name} ${ARGN})
 321         endif()
 322
 323         copy_dlls(${name})
 324
 325         install(
 326             TARGETS ${name}
 327             RUNTIME DESTINATION ${RADIANT_BIN_DIR}
 328         )
 329     endmacro ()
 330
 331     if (BUILD_RADIANT)
 332         add_subdirectory(radiant)
 333     endif ()
 334 endif ()
 335
 336 #-----------------------------------------------------------------------
 337 # Tools
 338 #-----------------------------------------------------------------------
 339
 340 if (BUILD_TOOLS)
 341     add_subdirectory(tools)
 342
 343     file(GLOB DATA_FILES "${PROJECT_SOURCE_DIR}/setup/data/tools/*")
 344
 345     if (NOT (PROJECT_SOURCE_DIR STREQUAL PROJECT_BINARY_DIR))
 346         # Copy data files from sources to the build directory
 347         message(STATUS "Copying data files")
 348         file(COPY ${DATA_FILES} DESTINATION "${PROJECT_BINARY_DIR}")
 349     endif ()
 350 endif ()
 351
 352 #-----------------------------------------------------------------------
 353 # Game packs
 354 #-----------------------------------------------------------------------
 355
 356 set(GAMEPACKS_LICENSE_LIST free CACHE STRING "Download game packs by license")
 357 set(GAMEPACKS_NAME_LIST none CACHE STRING "Download game packs by name")
 358
 359 if (DOWNLOAD_GAMEPACKS)
 360     add_custom_target(gamepacks ALL
 361        COMMAND "${PROJECT_SOURCE_DIR}/gamepack-manager" --license ${GAMEPACKS_LICENSE_LIST} --name ${GAMEPACKS_NAME_LIST} --download-dir "${GAMEPACKS_DOWNLOAD_DIR}" --install-dir "${PROJECT_BINARY_DIR}/gamepacks" --download --install
 362        COMMENT "Downloading game packs"
 363     )
 364 endif ()
 365
 366 #-----------------------------------------------------------------------
 367 # Install
 368 #-----------------------------------------------------------------------
 369
 370 if (BUILD_BINARIES)
 371     install(DIRECTORY
 372         setup/data/tools/base
 373         setup/data/tools/bitmaps
 374         setup/data/tools/gl
 375         setup/data/tools/plugins
 376         docs
 377         DESTINATION ${RADIANT_DATA_DIR}
 378     )
 379
 380     install(FILES
 381         setup/data/tools/global.xlink
 382         DESTINATION ${RADIANT_DATA_DIR}
 383     )
 384 endif ()
 385
 386 if (DOWNLOAD_GAMEPACKS)
 387     if (FHS_INSTALL)
 388        set(GAME_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}/share/netradiant")
 389     else ()
 390        set(GAME_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}")
 391     endif ()
 392
 393     install(DIRECTORY
 394         ${PROJECT_BINARY_DIR}/gamepacks
 395         DESTINATION ${RADIANT_DATA_DIR}
 396     )
 397 endif ()
 398
 399 if(BUILD_BINARIES AND FHS_INSTALL AND NOT WIN32 AND NOT APPLE)
 400     install(FILES
 401         ${PROJECT_SOURCE_DIR}/icons/netradiant.png
 402         DESTINATION ${CMAKE_INSTALL_PREFIX}/share/pixmaps
 403     )
 404     install(FILES
 405         ${PROJECT_SOURCE_DIR}/icons/netradiant.desktop
 406         DESTINATION ${CMAKE_INSTALL_PREFIX}/share/applications
 407     )
 408     install(FILES
 409         ${PROJECT_SOURCE_DIR}/icons/mime/map.xml
 410         DESTINATION ${CMAKE_INSTALL_PREFIX}/share/mime/model
 411     )
 412 endif ()
 413
 414 include(cmake/scripts/package.cmake)