CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.12 FATAL_ERROR)
   2 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/cmake")
   3 project(NetRadiant C CXX)
   4
   5 option(BUILD_RADIANT "Build the GUI" ON)
   6 option(BUILD_TOOLS "Build the tools" ON)
   7 option(BUILD_CRUNCH "Build Crunch image support" OFF)
   8 option(DOWNLOAD_GAMEPACKS "Download game packs" ON)
   9 option(USE_WERROR "Build with -Werror -pedantic-errors" OFF)
  10 option(FHS_INSTALL "Install according to Filesystem Hierarchy Standard" OFF)
  11
  12 set(BUILD_BINARIES OFF CACHE INTERNAL "...")
  13 if (BUILD_RADIANT OR BUILD_TOOLS)
  14     set(BUILD_BINARIES ON)
  15 endif ()
  16
  17 #-----------------------------------------------------------------------
  18 # Paths
  19 #-----------------------------------------------------------------------
  20
  21 if (CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  22     set(CMAKE_INSTALL_PREFIX "${PROJECT_SOURCE_DIR}/install" CACHE PATH "..." FORCE)
  23 endif ()
  24
  25 set(RADIANT_NAME "NetRadiant" CACHE INTERNAL "...")
  26 add_definitions(-DRADIANT_NAME="${RADIANT_NAME}")
  27 set(RADIANT_BASENAME "netradiant" CACHE INTERNAL "...")
  28 add_definitions(-DRADIANT_BASENAME="${RADIANT_BASENAME}")
  29
  30 set(RADIANT_LIB_DIR ${CMAKE_INSTALL_PREFIX} CACHE INTERNAL "...")
  31 set(RADIANT_BIN_DIR ${CMAKE_INSTALL_PREFIX} CACHE INTERNAL "...")
  32 set(RADIANT_DATA_DIR ${CMAKE_INSTALL_PREFIX} CACHE INTERNAL "...")
  33
  34 if (FHS_INSTALL)
  35     set(RADIANT_LIB_DIR ${CMAKE_INSTALL_PREFIX}/lib/${RADIANT_BASENAME})
  36     set(RADIANT_BIN_DIR ${CMAKE_INSTALL_PREFIX}/bin)
  37     set(RADIANT_DATA_DIR ${CMAKE_INSTALL_PREFIX}/share/${RADIANT_BASENAME})
  38 endif ()
  39
  40 #-----------------------------------------------------------------------
  41 # Version
  42 #-----------------------------------------------------------------------
  43
  44 # CMake 3.0+ would allow this in project()
  45 set(RADIANT_VERSION_MAJOR 1)
  46 set(RADIANT_VERSION_MINOR 5)
  47 set(RADIANT_VERSION_PATCH 0)
  48 set(RADIANT_VERSION "${RADIANT_VERSION_MAJOR}.${RADIANT_VERSION_MINOR}.${RADIANT_VERSION_PATCH}")
  49
  50 set(RADIANT_ABOUTMSG "Custom build" CACHE STRING "About message")
  51
  52 find_package(Git REQUIRED)
  53
  54 execute_process(
  55      COMMAND ${GIT_EXECUTABLE} rev-parse --short HEAD
  56      WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
  57      OUTPUT_VARIABLE GIT_VERSION
  58      OUTPUT_STRIP_TRAILING_WHITESPACE
  59 )
  60
  61 set(RADIANT_VERSION_STRING "${RADIANT_VERSION}n")
  62
  63 if (GIT_VERSION)
  64     set(RADIANT_VERSION_STRING "${RADIANT_VERSION_STRING}-git-${GIT_VERSION}")
  65 endif ()
  66
  67 message(STATUS "Building ${PROJECT_NAME} ${RADIANT_VERSION_STRING} ${RADIANT_ABOUTMSG}")
  68
  69 #-----------------------------------------------------------------------
  70 # Language standard
  71 #-----------------------------------------------------------------------
  72
  73 if (BUILD_BINARIES)
  74     set(CMAKE_CXX_STANDARD 11)
  75     set(CMAKE_CXX_STANDARD_REQUIRED ON)
  76     set(CMAKE_CXX_EXTENSIONS OFF)
  77
  78     if (CMAKE_VERSION VERSION_LESS "3.1")
  79         if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" OR CMAKE_COMPILER_IS_GNUCXX)
  80             include(CheckCXXCompilerFlag)
  81             check_cxx_compiler_flag(--std=c++${CMAKE_CXX_STANDARD} STD_CXX)
  82             if (STD_CXX)
  83                 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} --std=c++${CMAKE_CXX_STANDARD}")
  84             else ()
  85                 message(SEND_ERROR "Requires C++${CMAKE_CXX_STANDARD} or better")
  86             endif ()
  87         else ()
  88             message(WARNING "Unrecognized compiler: ${CMAKE_CXX_COMPILER_ID}, make sure it supports C++${CMAKE_CXX_STANDARD}")
  89         endif ()
  90     endif ()
  91 endif ()
  92
  93 #-----------------------------------------------------------------------
  94 # Flags
  95 #-----------------------------------------------------------------------
  96
  97 if (BUILD_BINARIES)
  98     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-exceptions -fno-rtti")
  99
 100     macro (addflags_c args)
 101         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${args}")
 102     endmacro ()
 103
 104     macro (addflags_cxx args)
 105         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${args}")
 106     endmacro ()
 107
 108     macro (addflags args)
 109         addflags_c("${args}")
 110         addflags_cxx("${args}")
 111     endmacro ()
 112
 113     addflags("-fno-strict-aliasing")
 114     if (NOT WIN32)
 115         addflags("-fvisibility=hidden")
 116     endif ()
 117
 118     if (USE_WERROR)
 119         addflags("-Werror")
 120         addflags("-pedantic-errors")
 121     endif ()
 122
 123     addflags("-Wall")
 124     addflags("-Wextra")
 125     addflags("-pedantic")
 126
 127     addflags_c("-Wno-deprecated-declarations") # vfs.c: g_strdown
 128
 129     addflags("-Wno-unused-function")
 130     addflags("-Wno-unused-variable")
 131     addflags("-Wno-unused-parameter")
 132
 133     set(CMAKE_POSITION_INDEPENDENT_CODE 1)
 134 endif ()
 135
 136 if (BUILD_RADIANT)
 137     set(GTK_TARGET 2 CACHE STRING "GTK target")
 138     add_definitions(-DGTK_TARGET=${GTK_TARGET})
 139 endif ()
 140
 141 #-----------------------------------------------------------------------
 142 # Defs
 143 #-----------------------------------------------------------------------
 144
 145 if (BUILD_BINARIES)
 146     add_definitions(-DRADIANT_VERSION="${RADIANT_VERSION}")
 147     add_definitions(-DRADIANT_VERSION_STRING="${RADIANT_VERSION_STRING}")
 148
 149     if (NOT CMAKE_BUILD_TYPE MATCHES Release)
 150         add_definitions(-D_DEBUG=1)
 151     endif ()
 152 endif ()
 153
 154 if (BUILD_RADIANT)
 155     add_definitions(-DRADIANT_ABOUTMSG="${RADIANT_ABOUTMSG}")
 156
 157     macro (disable_deprecated name gtk2only)
 158         add_definitions(-D${name}_DISABLE_SINGLE_INCLUDES)
 159         if ((${gtk2only} EQUAL 0) OR (GTK_TARGET EQUAL 2))
 160             add_definitions(-D${name}_DISABLE_DEPRECATED)
 161         endif ()
 162     endmacro ()
 163
 164     disable_deprecated(ATK 0)
 165     disable_deprecated(G 0)
 166     disable_deprecated(GDK 0)
 167     disable_deprecated(GDK_PIXBUF 0)
 168     disable_deprecated(GTK 1)
 169     disable_deprecated(PANGO 0)
 170 endif ()
 171
 172 if (BUILD_BINARIES)
 173     if(APPLE OR ${CMAKE_SYSTEM_NAME} STREQUAL "FreeBSD")
 174         link_directories(
 175             /usr/local/lib
 176         )
 177     endif ()
 178
 179     if (WIN32)
 180         add_definitions(
 181             -DWIN32=1
 182             -D_WIN32=1
 183         )
 184     else ()
 185         add_definitions(
 186             -DPOSIX=1
 187         )
 188     endif ()
 189 endif ()
 190
 191 if (BUILD_RADIANT AND NOT APPLE AND NOT WIN32)
 192     set(XWINDOWS ON)
 193     find_package(X11 REQUIRED)
 194     include_directories(${X11_INCLUDE_DIR})
 195     add_definitions(-DXWINDOWS=1)
 196 endif ()
 197
 198 if (BUILD_BINARIES)
 199     include_directories("${PROJECT_SOURCE_DIR}/include")
 200     include_directories("${PROJECT_SOURCE_DIR}/libs")
 201
 202     if (WIN32 AND NOT CMAKE_CROSSCOMPILING)
 203         set(BUNDLE_LIBRARIES_DEFAULT ON)
 204     else ()
 205         set(BUNDLE_LIBRARIES_DEFAULT OFF)
 206     endif ()
 207
 208     option(BUNDLE_LIBRARIES "Bundle libraries" ${BUNDLE_LIBRARIES_DEFAULT})
 209
 210     macro (copy_dlls target)
 211         if (BUNDLE_LIBRARIES AND WIN32)
 212             add_custom_command(TARGET ${target} POST_BUILD
 213                 COMMAND bash
 214                 ARGS -c "ldd '$<TARGET_FILE:${target}>' | egrep -i '\\.dll ' | grep -iv '/c/Windows' | awk '{ print $1 }' | while read dll; do dllbasename=\"$(which \"$dll\")\"; [ -f \"${PROJECT_BINARY_DIR}/$dllbasename\" ] || cp --preserve=timestamps \"$dllbasename\" '${PROJECT_BINARY_DIR}'; done"
 215                 VERBATIM
 216         )
 217         endif ()
 218     endmacro ()
 219
 220     macro (bundle_stuff target)
 221         if (BUNDLE_LIBRARIES AND WIN32)
 222             add_custom_command(TARGET ${target} POST_BUILD
 223                 COMMAND bash
 224                 ARGS -c "mkdir -p '${PROJECT_BINARY_DIR}/share/themes'; mkdir -p '${PROJECT_BINARY_DIR}/lib'; mingw=\"$(echo '${CMAKE_C_COMPILER}' | sed -e 's|/bin/.*||')\"; [ -d '${PROJECT_BINARY_DIR}/share/themes/MS-Windows' ] || cp -r --preserve=timestamps \"$mingw/share/themes/MS-Windows\" '${PROJECT_BINARY_DIR}/share/themes/'; [ -d '${PROJECT_BINARY_DIR}/lib/gdk-pixbuf-2.0' ] || cp -r --preserve=timestamps \"$mingw/lib/gdk-pixbuf-2.0\" '${PROJECT_BINARY_DIR}/lib/'; [ -d '${PROJECT_BINARY_DIR}/lib/gtk-2.0' ] || cp -r --preserve=timestamps \"$mingw/lib/gtk-2.0\" '${PROJECT_BINARY_DIR}/lib/'"
 225                 VERBATIM
 226         )
 227
 228         file(GLOB DLL_FILES ${PROJECT_BINARY_DIR}/*.dll)
 229
 230         install(FILES
 231             ${DLL_FILES}
 232             DESTINATION ${CMAKE_INSTALL_PREFIX}
 233         )
 234
 235         install(DIRECTORY
 236             ${PROJECT_BINARY_DIR}/lib
 237             ${PROJECT_BINARY_DIR}/share
 238             DESTINATION ${CMAKE_INSTALL_PREFIX}
 239         )
 240         endif ()
 241     endmacro ()
 242 endif ()
 243
 244 #-----------------------------------------------------------------------
 245 # Libraries
 246 #-----------------------------------------------------------------------
 247
 248 if (BUILD_BINARIES)
 249     add_subdirectory(libs)
 250 endif ()
 251
 252 if (BUILD_RADIANT)
 253     add_subdirectory(include)
 254 endif ()
 255
 256 #-----------------------------------------------------------------------
 257 # Plugins
 258 #-----------------------------------------------------------------------
 259
 260 if (BUILD_RADIANT)
 261     add_subdirectory(contrib)
 262 endif ()
 263
 264 #-----------------------------------------------------------------------
 265 # Modules
 266 #-----------------------------------------------------------------------
 267
 268 if (BUILD_RADIANT)
 269     add_subdirectory(plugins)
 270 endif ()
 271
 272 #-----------------------------------------------------------------------
 273 # Radiant
 274 #-----------------------------------------------------------------------
 275
 276 if (BUILD_BINARIES)
 277     if (CMAKE_EXECUTABLE_SUFFIX)
 278         string(REGEX REPLACE "^[.]" "" RADIANT_EXECUTABLE ${CMAKE_EXECUTABLE_SUFFIX})
 279     endif ()
 280
 281     macro (radiant_tool name)
 282         add_executable(${name} ${ARGN})
 283
 284         copy_dlls(${name})
 285
 286         install(
 287             TARGETS ${name}
 288             RUNTIME DESTINATION ${RADIANT_BIN_DIR}
 289         )
 290     endmacro ()
 291
 292     if (BUILD_RADIANT)
 293         add_subdirectory(radiant)
 294         set_target_properties(${RADIANT_BASENAME} PROPERTIES
 295         COMPILE_DEFINITIONS RADIANT_EXECUTABLE="${RADIANT_EXECUTABLE}"
 296     )
 297     endif ()
 298 endif ()
 299
 300 #-----------------------------------------------------------------------
 301 # Tools
 302 #-----------------------------------------------------------------------
 303
 304 if (BUILD_TOOLS)
 305     add_subdirectory(tools)
 306
 307     file(GLOB DATA_FILES "${PROJECT_SOURCE_DIR}/setup/data/tools/*")
 308
 309     if (NOT (PROJECT_SOURCE_DIR STREQUAL PROJECT_BINARY_DIR))
 310         # Copy data files from sources to the build directory
 311         message(STATUS "Copying data files")
 312         file(COPY ${DATA_FILES} DESTINATION "${PROJECT_BINARY_DIR}")
 313     endif ()
 314 endif ()
 315
 316 #-----------------------------------------------------------------------
 317 # Game packs
 318 #-----------------------------------------------------------------------
 319
 320 set(GAMEPACKS_LICENSE_LIST free CACHE STRING "Download game packs by license")
 321 set(GAMEPACKS_NAME_LIST none CACHE STRING "Download game packs by name")
 322
 323 if (DOWNLOAD_GAMEPACKS)
 324     add_custom_target(game_packs ALL
 325        COMMAND "${PROJECT_SOURCE_DIR}/gamepack-manager" --license ${GAMEPACKS_LICENSE_LIST} --name ${GAMEPACKS_NAME_LIST} --download-dir "${PROJECT_BINARY_DIR}/download" --install-dir "${PROJECT_BINARY_DIR}" --download --install
 326        COMMENT "Downloading game packs"
 327     )
 328 endif ()
 329
 330 #-----------------------------------------------------------------------
 331 # Install
 332 #-----------------------------------------------------------------------
 333
 334 if (BUILD_BINARIES)
 335     install(DIRECTORY
 336         setup/data/tools/base
 337         setup/data/tools/bitmaps
 338         setup/data/tools/gl
 339         setup/data/tools/plugins
 340         docs
 341         DESTINATION ${RADIANT_DATA_DIR}
 342     )
 343 endif ()
 344
 345 if (DOWNLOAD_GAMEPACKS)
 346     if (FHS_INSTALL)
 347        set(GAME_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}/share/netradiant")
 348     else ()
 349        set(GAME_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}")
 350     endif ()
 351
 352     file(GLOB GAME_DIRS ${PROJECT_BINARY_DIR}/*.game)
 353
 354     install(DIRECTORY
 355         ${PROJECT_BINARY_DIR}/games
 356         ${GAME_DIRS}
 357         DESTINATION ${RADIANT_DATA_DIR}
 358     )
 359 endif ()
 360
 361 if(BUILD_BINARIES AND FHS_INSTALL AND NOT WIN32 AND NOT APPLE)
 362     install(FILES
 363         ${PROJECT_SOURCE_DIR}/icons/netradiant.png
 364         DESTINATION ${CMAKE_INSTALL_PREFIX}/share/pixmaps
 365     )
 366     install(FILES
 367         ${PROJECT_SOURCE_DIR}/icons/netradiant.desktop
 368         DESTINATION ${CMAKE_INSTALL_PREFIX}/share/applications
 369     )
 370     install(FILES
 371         ${PROJECT_SOURCE_DIR}/icons/mime/map.xml
 372         DESTINATION ${CMAKE_INSTALL_PREFIX}/share/mime/model
 373     )
 374 endif ()
 375
 376 include(cmake/scripts/package.cmake)