CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.1 FATAL_ERROR)
   2
   3 project(NetRadiant C CXX)
   4
   5 #-----------------------------------------------------------------------
   6 # Builtins: configuration
   7 #-----------------------------------------------------------------------
   8
   9 set(BUILTINS_INSTALL_DIR "${CMAKE_BINARY_DIR}/builtins")
  10 set(BUILTINS_INCLUDE_DIR "${BUILTINS_INSTALL_DIR}/include")
  11 set(BUILTINS_LIB_DIR "${BUILTINS_INSTALL_DIR}/lib")
  12 set(BUILTINS_PKGCONFIG_DIR "${BUILTINS_INSTALL_DIR}/lib/pkgconfig")
  13
  14 option(BUILTIN_GTKGLEXT "Builtin GtkGLExt" OFF)
  15 option(BUILTIN_GTKTHEME_MOJAVE "Builtin Mojave GTK theme" OFF)
  16
  17 if (APPLE)
  18     set(BUILTIN_GTKGLEXT ON)
  19     set(BUILTIN_GTKTHEME_MOJAVE ON)
  20 endif ()
  21
  22 set(BUILTIN_GTKGLEXT_BUILT OFF CACHE INTERNAL "...")
  23 if (EXISTS "${BUILTINS_PKGCONFIG_DIR}/gtkglext-1.0.pc")
  24     set(BUILTIN_GTKGLEXT_BUILT ON)
  25 endif ()
  26
  27 if (EXISTS "${BUILTINS_INCLUDE_DIR}")
  28     include_directories("${BUILTINS_INCLUDE_DIR}")
  29 endif ()
  30
  31 if (EXISTS "${BUILTINS_LIB_DIR}")
  32     set(ENV{LD_LIBRARY_PATH} "$ENV{LD_LIBRARY_PATH}:${BUILTINS_LIB_DIR}")
  33     link_directories("${BUILTINS_LIB_DIR}")
  34 endif ()
  35
  36 if (EXISTS "${BUILTINS_PKGCONFIG_DIR}")
  37     set(ENV{PKG_CONFIG_PATH} "$ENV{PKG_CONFIG_PATH}:${BUILTINS_PKGCONFIG_DIR}")
  38 endif ()
  39
  40 #-----------------------------------------------------------------------
  41 # CMake modules
  42 #-----------------------------------------------------------------------
  43
  44 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/cmake")
  45
  46 #-----------------------------------------------------------------------
  47 # Submodules
  48 #-----------------------------------------------------------------------
  49
  50 if (EXISTS "${PROJECT_SOURCE_DIR}/libs/crunch/inc/crn_decomp.h")
  51     set(DEFAULT_BUILD_CRUNCH ON CACHE INTERNAL "...")
  52 else ()
  53     set(DEFAULT_BUILD_CRUNCH OFF CACHE INTERNAL "...")
  54 endif ()
  55
  56 #-----------------------------------------------------------------------
  57 # Build options
  58 #-----------------------------------------------------------------------
  59
  60 option(BUILD_RADIANT "Build the GUI" ON)
  61 option(BUILD_TOOLS "Build the tools" ON)
  62 option(BUILD_CRUNCH "Build Crunch image support" ${DEFAULT_BUILD_CRUNCH})
  63 option(DOWNLOAD_GAMEPACKS "Download game packs" ON)
  64 option(USE_WERROR "Build with -Werror -pedantic-errors" OFF)
  65 option(FHS_INSTALL "Install according to Filesystem Hierarchy Standard" OFF)
  66 option(FHS_INSTALL_ABSOLUTE "Install using absolute paths (requires FHS_INSTALL)" OFF)
  67
  68 set(BUILD_BINARIES OFF CACHE INTERNAL "...")
  69 if (BUILD_RADIANT OR BUILD_TOOLS)
  70     set(BUILD_BINARIES ON)
  71 endif ()
  72
  73 if (BUILD_BINARIES)
  74     if (WIN32
  75         OR APPLE
  76         OR "${CMAKE_SYSTEM_NAME}" STREQUAL "Linux"
  77         OR "${CMAKE_SYSTEM_NAME}" STREQUAL "FreeBSD" )
  78         set(BUNDLING_SUPPORTED ON)
  79     endif()
  80
  81     if (BUNDLING_SUPPORTED)
  82         if(WIN32 AND NOT CMAKE_CROSSCOMPILING)
  83             set(BUNDLE_LIBRARIES_DEFAULT ON)
  84         else ()
  85             set(BUNDLE_LIBRARIES_DEFAULT OFF)
  86         endif ()
  87
  88         option(BUNDLE_LIBRARIES "Bundle libraries" ${BUNDLE_LIBRARIES_DEFAULT})
  89     endif ()
  90
  91     if (BUNDLE_LIBRARIES AND BUNDLING_SUPPORTED)
  92         set(FHS_INSTALL OFF CACHE PATH "Disabled because of BUNDLE_LIBRARIES is enabled" FORCE)
  93     endif ()
  94
  95     if (NOT FHS_INSTALL AND FHS_INSTALL_ABSOLUTE)
  96         set(FHS_INSTALL_ABSOLUTE OFF CACHE PATH "Disabled because of FHS_INSTALL is disabled" FORCE)
  97     endif ()
  98 endif ()
  99
 100 #-----------------------------------------------------------------------
 101 # Paths
 102 #-----------------------------------------------------------------------
 103
 104 if (CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 105     set(CMAKE_INSTALL_PREFIX "${PROJECT_SOURCE_DIR}/install" CACHE PATH "..." FORCE)
 106 endif ()
 107
 108 if (APPLE)
 109     set(APPLE_INSTALL_PREFIX ${CMAKE_INSTALL_PREFIX}/NetRadiant.app)
 110     set(FINAL_INSTALL_PREFIX ${APPLE_INSTALL_PREFIX}/Contents/Prefix)
 111 else ()
 112     set(FINAL_INSTALL_PREFIX ${CMAKE_INSTALL_PREFIX})
 113 endif ()
 114
 115 set(RADIANT_NAME "NetRadiant" CACHE INTERNAL "...")
 116 add_definitions(-DRADIANT_NAME="${RADIANT_NAME}")
 117 set(RADIANT_BASENAME "netradiant" CACHE INTERNAL "...")
 118 add_definitions(-DRADIANT_BASENAME="${RADIANT_BASENAME}")
 119
 120 set(RADIANT_BIN_DIR ${FINAL_INSTALL_PREFIX} CACHE INTERNAL "...")
 121 set(RADIANT_LIB_DIR ${FINAL_INSTALL_PREFIX}/lib CACHE INTERNAL "...")
 122 set(RADIANT_ADDONS_DIR ${FINAL_INSTALL_PREFIX} CACHE INTERNAL "...")
 123 set(RADIANT_SHARE_DIR ${FINAL_INSTALL_PREFIX}/share CACHE INTERNAL "...")
 124 set(RADIANT_DATA_DIR ${FINAL_INSTALL_PREFIX} CACHE INTERNAL "...")
 125
 126 if (FHS_INSTALL)
 127     add_definitions(-DRADIANT_FHS_INSTALL='ON')
 128
 129     set(RADIANT_BIN_DIR ${FINAL_INSTALL_PREFIX}/bin)
 130     set(RADIANT_LIB_DIR ${FINAL_INSTALL_PREFIX}/lib/${CMAKE_LIBRARY_ARCHITECTURE})
 131     set(RADIANT_ADDONS_DIR ${RADIANT_LIB_DIR}/${RADIANT_BASENAME})
 132     set(RADIANT_SHARE_DIR ${FINAL_INSTALL_PREFIX}/share)
 133     set(RADIANT_DATA_DIR ${RADIANT_SHARE_DIR}/${RADIANT_BASENAME})
 134     set(RADIANT_LIB_DIR ${FINAL_INSTALL_PREFIX}/lib/${CMAKE_LIBRARY_ARCHITECTURE})
 135
 136     if (FHS_INSTALL_ABSOLUTE)
 137         add_definitions(-DRADIANT_ADDONS_DIR="${RADIANT_ADDONS_DIR}")
 138         add_definitions(-DRADIANT_DATA_DIR="${RADIANT_DATA_DIR}")
 139     else ()
 140         add_definitions(-DRADIANT_LIB_ARCH="${CMAKE_LIBRARY_ARCHITECTURE}")
 141     endif ()
 142 endif ()
 143
 144
 145 set(GAMEPACKS_DOWNLOAD_DIR ${PROJECT_BINARY_DIR}/download CACHE PATH "Where to store downloaded game packs")
 146
 147 #-----------------------------------------------------------------------
 148 # Version
 149 #-----------------------------------------------------------------------
 150
 151 # CMake 3.0+ would allow this in project()
 152 set(RADIANT_VERSION_MAJOR 1)
 153 set(RADIANT_VERSION_MINOR 5)
 154 set(RADIANT_VERSION_PATCH 0)
 155 set(RADIANT_VERSION "${RADIANT_VERSION_MAJOR}.${RADIANT_VERSION_MINOR}.${RADIANT_VERSION_PATCH}")
 156
 157 set(RADIANT_ABOUTMSG "Custom build" CACHE STRING "About message")
 158
 159 set(RADIANT_VERSION_STRING "${RADIANT_VERSION}n")
 160
 161 if (NOT DEFINED GIT_VERSION)
 162      find_package(Git REQUIRED)
 163
 164      execute_process(
 165           COMMAND ${GIT_EXECUTABLE} rev-parse --short HEAD
 166           WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
 167           OUTPUT_VARIABLE GIT_VERSION
 168           OUTPUT_STRIP_TRAILING_WHITESPACE
 169      )
 170
 171      if (GIT_VERSION)
 172          set(RADIANT_VERSION_STRING "${RADIANT_VERSION_STRING}-git-${GIT_VERSION}")
 173      endif ()
 174 endif ()
 175
 176 message(STATUS "Building ${PROJECT_NAME} ${RADIANT_VERSION_STRING} ${RADIANT_ABOUTMSG}")
 177
 178 #-----------------------------------------------------------------------
 179 # Language standard
 180 #-----------------------------------------------------------------------
 181
 182 if (BUILD_BINARIES)
 183     set(CMAKE_CXX_STANDARD 11)
 184     set(CMAKE_CXX_STANDARD_REQUIRED ON)
 185     set(CMAKE_CXX_EXTENSIONS OFF)
 186
 187     if (CMAKE_VERSION VERSION_LESS "3.1")
 188         if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" OR CMAKE_COMPILER_IS_GNUCXX)
 189             include(CheckCXXCompilerFlag)
 190             check_cxx_compiler_flag(--std=c++${CMAKE_CXX_STANDARD} STD_CXX)
 191             if (STD_CXX)
 192                 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} --std=c++${CMAKE_CXX_STANDARD}")
 193             else ()
 194                 message(SEND_ERROR "Requires C++${CMAKE_CXX_STANDARD} or better")
 195             endif ()
 196         else ()
 197             message(WARNING "Unrecognized compiler: ${CMAKE_CXX_COMPILER_ID}, make sure it supports C++${CMAKE_CXX_STANDARD}")
 198         endif ()
 199     endif ()
 200 endif ()
 201
 202 #-----------------------------------------------------------------------
 203 # Flags
 204 #-----------------------------------------------------------------------
 205
 206 if (BUILD_BINARIES)
 207     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-exceptions -fno-rtti")
 208
 209     macro (addflags_c args)
 210         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${args}")
 211     endmacro ()
 212
 213     macro (addflags_cxx args)
 214         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${args}")
 215     endmacro ()
 216
 217     macro (addflags args)
 218         addflags_c("${args}")
 219         addflags_cxx("${args}")
 220     endmacro ()
 221
 222     addflags("-fno-strict-aliasing")
 223     if (NOT WIN32)
 224         addflags("-fvisibility=hidden")
 225     endif ()
 226
 227     if (USE_WERROR)
 228         addflags("-Werror")
 229         addflags("-pedantic-errors")
 230     endif ()
 231
 232     addflags("-Wall")
 233     addflags("-Wextra")
 234     addflags("-pedantic")
 235
 236     addflags_c("-Wno-deprecated-declarations") # vfs.c: g_strdown
 237
 238     addflags("-Wno-unused-function")
 239     addflags("-Wno-unused-variable")
 240     addflags("-Wno-unused-parameter")
 241
 242     if (APPLE)
 243         add_definitions(-DGL_SILENCE_DEPRECATION=1)
 244     endif()
 245
 246     set(CMAKE_POSITION_INDEPENDENT_CODE 1)
 247 endif ()
 248
 249 if (BUILD_RADIANT)
 250     set(GTK_TARGET 2 CACHE STRING "GTK target")
 251     add_definitions(-DGTK_TARGET=${GTK_TARGET})
 252
 253     if (WIN32)
 254         add_definitions(-DWORKAROUND_WINDOWS_FLOATING_WINDOW=1)
 255
 256         if (GTK_TARGET EQUAL 2)
 257             add_definitions(-DWORKAROUND_WINDOWS_GTK2_GLWIDGET=1)
 258         endif ()
 259     elseif (APPLE)
 260         if (GTK_TARGET EQUAL 2)
 261             add_definitions(-DWORKAROUND_MACOS_GTK2_DESTROY=1)
 262             add_definitions(-DWORKAROUND_MACOS_GTK2_GLWIDGET=1)
 263             add_definitions(-DWORKAROUND_MACOS_GTK2_LAGGYPOINTER=1)
 264         endif ()
 265     endif()
 266 endif ()
 267
 268 #-----------------------------------------------------------------------
 269 # Defs
 270 #-----------------------------------------------------------------------
 271
 272 if (BUILD_BINARIES)
 273     add_definitions(-DRADIANT_VERSION="${RADIANT_VERSION}")
 274     add_definitions(-DRADIANT_VERSION_STRING="${RADIANT_VERSION_STRING}")
 275
 276     if (NOT CMAKE_BUILD_TYPE MATCHES Release)
 277         add_definitions(-D_DEBUG=1)
 278     endif ()
 279 endif ()
 280
 281 if (BUILD_RADIANT)
 282     add_definitions(-DRADIANT_ABOUTMSG="${RADIANT_ABOUTMSG}")
 283
 284     macro (disable_deprecated name gtk2only)
 285         add_definitions(-D${name}_DISABLE_SINGLE_INCLUDES)
 286         if ((${gtk2only} EQUAL 0) OR (GTK_TARGET EQUAL 2))
 287             add_definitions(-D${name}_DISABLE_DEPRECATED)
 288         endif ()
 289     endmacro ()
 290
 291     disable_deprecated(ATK 0)
 292     disable_deprecated(G 0)
 293     disable_deprecated(GDK 0)
 294     disable_deprecated(GDK_PIXBUF 0)
 295     disable_deprecated(GTK 1)
 296     disable_deprecated(PANGO 0)
 297 endif ()
 298
 299 if (BUILD_BINARIES)
 300     add_custom_target(binaries ALL)
 301
 302     if(APPLE OR ${CMAKE_SYSTEM_NAME} STREQUAL "FreeBSD")
 303         link_directories(
 304             /usr/local/lib
 305         )
 306     endif ()
 307
 308     if (WIN32)
 309         add_definitions(
 310             -DWIN32=1
 311             -D_WIN32=1
 312         )
 313     else ()
 314         add_definitions(
 315             -DPOSIX=1
 316         )
 317     endif ()
 318 endif ()
 319
 320 if (BUILD_RADIANT AND NOT APPLE AND NOT WIN32)
 321     set(XWINDOWS ON)
 322     find_package(X11 REQUIRED)
 323     include_directories(${X11_INCLUDE_DIR})
 324     add_definitions(-DXWINDOWS=1)
 325 endif ()
 326
 327 if (BUILD_BINARIES)
 328     include_directories("${PROJECT_SOURCE_DIR}/include")
 329     include_directories("${PROJECT_SOURCE_DIR}/libs")
 330
 331     macro (copy_dlls target)
 332         if (BUNDLE_LIBRARIES AND BUNDLING_SUPPORTED)
 333             add_custom_command(TARGET ${target} POST_BUILD
 334                 COMMAND "${PROJECT_SOURCE_DIR}/library-bundler"
 335                 "register" "${PROJECT_BINARY_DIR}" "$<TARGET_FILE:${target}>"
 336                 VERBATIM
 337             )
 338             add_dependencies(bundle ${target})
 339         endif ()
 340     endmacro ()
 341 endif ()
 342
 343 #-----------------------------------------------------------------------
 344 # Bundle
 345 #-----------------------------------------------------------------------
 346
 347 if (BUILD_BINARIES)
 348     if (BUNDLE_LIBRARIES AND BUNDLING_SUPPORTED)
 349         add_subdirectory(bundle)
 350     endif ()
 351 endif ()
 352
 353 #-----------------------------------------------------------------------
 354 # Builtins: targets
 355 #-----------------------------------------------------------------------
 356
 357 add_custom_target(builtins)
 358
 359 if (BUILTIN_GTKGLEXT OR BUILTIN_GTKTHEME_MOJAVE)
 360     include(${CMAKE_ROOT}/Modules/ExternalProject.cmake)
 361 endif ()
 362
 363 if (BUILTIN_GTKGLEXT)
 364     set(GTKGLEXT_PKGNAMES "gdk-2.0 gtk+-2.0 glib-2.0")
 365
 366     if (NOT APPLE)
 367         set(GTKGLEXT_PKGNAMES "${GTKGLEXT_PKGNAMES} gl")
 368     endif ()
 369
 370     execute_process(COMMAND pkg-config --libs ${GTKGLEXT_PKGNAMES}
 371         OUTPUT_VARIABLE GTKGLEXT_LDFLAGS
 372         OUTPUT_STRIP_TRAILING_WHITESPACE
 373     )
 374
 375     set(GTKGLEXT_LDFLAGS "$ENV{LDFLAGS} -lm ${GTKGLEXT_LDFLAGS}")
 376
 377     execute_process(COMMAND pkg-config --cflags ${GTKGLEXT_PKGNAMES}
 378         OUTPUT_VARIABLE GTKGLEXT_CFLAGS
 379         OUTPUT_STRIP_TRAILING_WHITESPACE
 380     )
 381
 382     set(GTKGLEXT_CFLAGS "$ENV{CFLAGS} ${GTKGLEXT_CFLAGS}")
 383
 384
 385     set(CONFIGURE_OPTIONS --disable-gtk-doc --disable-gtk-doc-html --disable-gtk-doc-pdf --disable-dependency-tracking --without-x)
 386
 387     if (CMAKE_BUILD_TYPE MATCHES Release)
 388         set(CONFIGURE_OPTIONS ${CONFIGURE_OPTIONS} --disable-debug)
 389     endif ()
 390
 391     if (APPLE)
 392         set(GTKGLEXT_GIT_TAG macos)
 393     else ()
 394         set(GTKGLEXT_GIT_TAG fixes)
 395     endif ()
 396
 397     if (APPLE)
 398         set(GTKGLEXT_CFLAGS "${GTKGLEXT_CFLAGS} -DGL_SILENCE_DEPRECATION=1 -Wno-deprecated-declarations")
 399     endif ()
 400
 401     ExternalProject_Add(gtkglext
 402         GIT_REPOSITORY https://gitlab.gnome.org/illwieckz/gtkglext.git
 403         GIT_TAG ${GTKGLEXT_GIT_TAG}
 404         BUILD_IN_SOURCE ON
 405         CONFIGURE_COMMAND export CCFLAGS=${GTKGLEXT_CFLAGS}
 406         CONFIGURE_COMMAND && export LDFLAGS=${GTKGLEXT_LDFLAGS}
 407         CONFIGURE_COMMAND && export NOCONFIGURE=1
 408         CONFIGURE_COMMAND && ./autogen.sh
 409         CONFIGURE_COMMAND && ./configure --prefix "${BUILTINS_INSTALL_DIR}" ${CONFIGURE_OPTIONS}
 410         BUILD_COMMAND $(MAKE)
 411         BUILD_COMMAND CFLAGS=${GTKGLEXT_CFLAGS}
 412         BUILD_COMMAND LDFLAGS=${GTKGLEXT_LDFLAGS}
 413         INSTALL_COMMAND $(MAKE) install
 414     )
 415
 416     include_directories("${BUILTINS_INCLUDE_DIR}/gtkglext-1.0")
 417     include_directories("${BUILTINS_LIB_DIR}/gtkglext-1.0/include")
 418
 419     add_dependencies(builtins gtkglext)
 420     set_target_properties(gtkglext PROPERTIES EXCLUDE_FROM_ALL ON)
 421 endif ()
 422
 423 if (BUNDLE_LIBRARIES)
 424     # It was required to tell cmake to not patch rpath on macos builtins.
 425     # It was also required to tell cmake to not patch rpath on freebsd binaries.
 426     # Patching rpath is done in library_bundler instead so we can skip this
 427     # step entirely when bundling.
 428     set(CMAKE_SKIP_RPATH ON)
 429 endif()
 430
 431 if (BUILTIN_GTKTHEME_MOJAVE)
 432     ExternalProject_Add(gtktheme-mojave
 433         GIT_REPOSITORY https://github.com/vinceliuice/Mojave-gtk-theme.git
 434         GIT_TAG master
 435         BUILD_IN_SOURCE ON
 436         CONFIGURE_COMMAND echo
 437         BUILD_COMMAND echo
 438         INSTALL_COMMAND ./install.sh -o standard -a standard -s standard -i standard -d "${PROJECT_BINARY_DIR}/themes"
 439     )
 440     add_dependencies(builtins gtktheme-mojave)
 441     set_target_properties(gtktheme-mojave PROPERTIES EXCLUDE_FROM_ALL ON)
 442 endif ()
 443
 444 #-----------------------------------------------------------------------
 445 # Libraries
 446 #-----------------------------------------------------------------------
 447
 448 if (BUILD_BINARIES)
 449     add_subdirectory(libs)
 450 endif ()
 451
 452 if (BUILD_RADIANT)
 453     add_subdirectory(include)
 454 endif ()
 455
 456 #-----------------------------------------------------------------------
 457 # Plugins
 458 #-----------------------------------------------------------------------
 459
 460 if (BUILD_RADIANT)
 461     add_subdirectory(contrib)
 462 endif ()
 463
 464 #-----------------------------------------------------------------------
 465 # Modules
 466 #-----------------------------------------------------------------------
 467
 468 if (BUILD_RADIANT)
 469     add_subdirectory(plugins)
 470 endif ()
 471
 472 #-----------------------------------------------------------------------
 473 # Radiant
 474 #-----------------------------------------------------------------------
 475
 476 if (BUILD_BINARIES)
 477     macro (radiant_tool name)
 478         add_dependencies(binaries ${name})
 479
 480         if (WIN32)
 481             add_executable(${name} ${ARGN} ${PROJECT_SOURCE_DIR}/include/lib.rc)
 482         else ()
 483             add_executable(${name} ${ARGN})
 484         endif()
 485
 486         copy_dlls(${name})
 487
 488         install(
 489             TARGETS ${name}
 490             RUNTIME DESTINATION ${RADIANT_BIN_DIR}
 491         )
 492     endmacro ()
 493
 494     if (BUILD_RADIANT)
 495         add_subdirectory(radiant)
 496     endif ()
 497 endif ()
 498
 499 #-----------------------------------------------------------------------
 500 # Tools
 501 #-----------------------------------------------------------------------
 502
 503 if (BUILD_TOOLS)
 504     add_subdirectory(tools)
 505
 506     file(GLOB DATA_FILES "${PROJECT_SOURCE_DIR}/setup/data/tools/*")
 507
 508     if (NOT (PROJECT_SOURCE_DIR STREQUAL PROJECT_BINARY_DIR))
 509         # Copy data files from sources to the build directory
 510         message(STATUS "Copying data files")
 511         file(COPY ${DATA_FILES} DESTINATION "${PROJECT_BINARY_DIR}")
 512     endif ()
 513 endif ()
 514
 515 #-----------------------------------------------------------------------
 516 # Game packs
 517 #-----------------------------------------------------------------------
 518
 519 set(GAMEPACKS_LICENSE_LIST free CACHE STRING "Download game packs by license")
 520 set(GAMEPACKS_NAME_LIST none CACHE STRING "Download game packs by name")
 521
 522 if (DOWNLOAD_GAMEPACKS)
 523     add_custom_target(gamepacks ALL
 524        COMMAND "${PROJECT_SOURCE_DIR}/gamepack-manager" --license ${GAMEPACKS_LICENSE_LIST} --name ${GAMEPACKS_NAME_LIST} --download-dir "${GAMEPACKS_DOWNLOAD_DIR}" --install-dir "${PROJECT_BINARY_DIR}/gamepacks" --download --install
 525        COMMENT "Downloading game packs"
 526     )
 527 endif ()
 528
 529 #-----------------------------------------------------------------------
 530 # Install
 531 #-----------------------------------------------------------------------
 532
 533 if (BUILD_BINARIES)
 534     install(DIRECTORY
 535         setup/data/tools/base
 536         setup/data/tools/bitmaps
 537         setup/data/tools/gl
 538         setup/data/tools/plugins
 539         docs
 540         DESTINATION ${RADIANT_DATA_DIR}
 541     )
 542
 543     install(FILES
 544         setup/data/tools/global.xlink
 545         DESTINATION ${RADIANT_DATA_DIR}
 546     )
 547 endif ()
 548
 549 if (DOWNLOAD_GAMEPACKS)
 550     install(DIRECTORY
 551         ${PROJECT_BINARY_DIR}/gamepacks
 552         DESTINATION ${RADIANT_DATA_DIR}
 553     )
 554 endif ()
 555
 556 if (BUILD_BINARIES AND FHS_INSTALL AND NOT WIN32 AND NOT APPLE)
 557     install(FILES
 558         icons/netradiant.png
 559         DESTINATION ${RADIANT_SHARE_DIR}/pixmaps
 560     )
 561     install(FILES
 562         icons/netradiant.desktop
 563         DESTINATION ${RADIANT_SHARE_DIR}/applications
 564     )
 565     install(FILES
 566         icons/x-netradiant-map.xml
 567         DESTINATION ${RADIANT_SHARE_DIR}/mime/application
 568     )
 569 endif ()
 570
 571 if (APPLE)
 572     install(DIRECTORY
 573         setup/macos/Contents
 574         DESTINATION ${APPLE_INSTALL_PREFIX}
 575     )
 576     install(DIRECTORY
 577     ${PROJECT_BINARY_DIR}/themes
 578         DESTINATION ${APPLE_INSTALL_PREFIX}/Contents/Prefix/share
 579     )
 580     install(PROGRAMS
 581         setup/macos/NetRadiant
 582         DESTINATION ${APPLE_INSTALL_PREFIX}/Contents/MacOS
 583     )
 584 endif ()
 585
 586 include(cmake/scripts/package.cmake)