CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.12 FATAL_ERROR)
   2 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/cmake")
   3 project(NetRadiant C CXX)
   4
   5 if (EXISTS "${PROJECT_SOURCE_DIR}/libs/crunch/inc/crn_decomp.h")
   6     set(DEFAULT_BUILD_CRUNCH ON CACHE INTERNAL "...")
   7 else ()
   8     set(DEFAULT_BUILD_CRUNCH OFF CACHE INTERNAL "...")
   9 endif ()
  10
  11 option(BUILD_RADIANT "Build the GUI" ON)
  12 option(BUILD_TOOLS "Build the tools" ON)
  13 option(BUILD_CRUNCH "Build Crunch image support" ${DEFAULT_BUILD_CRUNCH})
  14 option(DOWNLOAD_GAMEPACKS "Download game packs" ON)
  15 option(USE_WERROR "Build with -Werror -pedantic-errors" OFF)
  16 option(FHS_INSTALL "Install according to Filesystem Hierarchy Standard" OFF)
  17
  18 set(BUILD_BINARIES OFF CACHE INTERNAL "...")
  19 if (BUILD_RADIANT OR BUILD_TOOLS)
  20     set(BUILD_BINARIES ON)
  21 endif ()
  22
  23 #-----------------------------------------------------------------------
  24 # Paths
  25 #-----------------------------------------------------------------------
  26
  27 if (CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  28     set(CMAKE_INSTALL_PREFIX "${PROJECT_SOURCE_DIR}/install" CACHE PATH "..." FORCE)
  29 endif ()
  30
  31 set(RADIANT_NAME "NetRadiant" CACHE INTERNAL "...")
  32 add_definitions(-DRADIANT_NAME="${RADIANT_NAME}")
  33 set(RADIANT_BASENAME "netradiant" CACHE INTERNAL "...")
  34 add_definitions(-DRADIANT_BASENAME="${RADIANT_BASENAME}")
  35
  36 set(RADIANT_LIB_DIR ${CMAKE_INSTALL_PREFIX} CACHE INTERNAL "...")
  37 set(RADIANT_BIN_DIR ${CMAKE_INSTALL_PREFIX} CACHE INTERNAL "...")
  38 set(RADIANT_DATA_DIR ${CMAKE_INSTALL_PREFIX} CACHE INTERNAL "...")
  39
  40 if (FHS_INSTALL AND NOT BUNDLE_LIBRARIES)
  41     set(RADIANT_LIB_DIR ${CMAKE_INSTALL_PREFIX}/lib/${RADIANT_BASENAME})
  42     set(RADIANT_BIN_DIR ${CMAKE_INSTALL_PREFIX}/bin)
  43     set(RADIANT_DATA_DIR ${CMAKE_INSTALL_PREFIX}/share/${RADIANT_BASENAME})
  44 endif ()
  45
  46 set(GAMEPACKS_DOWNLOAD_DIR ${PROJECT_BINARY_DIR}/download CACHE PATH "Where to store downloaded game packs")
  47
  48 #-----------------------------------------------------------------------
  49 # Version
  50 #-----------------------------------------------------------------------
  51
  52 # CMake 3.0+ would allow this in project()
  53 set(RADIANT_VERSION_MAJOR 1)
  54 set(RADIANT_VERSION_MINOR 5)
  55 set(RADIANT_VERSION_PATCH 0)
  56 set(RADIANT_VERSION "${RADIANT_VERSION_MAJOR}.${RADIANT_VERSION_MINOR}.${RADIANT_VERSION_PATCH}")
  57
  58 set(RADIANT_ABOUTMSG "Custom build" CACHE STRING "About message")
  59
  60 find_package(Git REQUIRED)
  61
  62 execute_process(
  63      COMMAND ${GIT_EXECUTABLE} rev-parse --short HEAD
  64      WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
  65      OUTPUT_VARIABLE GIT_VERSION
  66      OUTPUT_STRIP_TRAILING_WHITESPACE
  67 )
  68
  69 set(RADIANT_VERSION_STRING "${RADIANT_VERSION}n")
  70
  71 if (GIT_VERSION)
  72     set(RADIANT_VERSION_STRING "${RADIANT_VERSION_STRING}-git-${GIT_VERSION}")
  73 endif ()
  74
  75 message(STATUS "Building ${PROJECT_NAME} ${RADIANT_VERSION_STRING} ${RADIANT_ABOUTMSG}")
  76
  77 #-----------------------------------------------------------------------
  78 # Language standard
  79 #-----------------------------------------------------------------------
  80
  81 if (BUILD_BINARIES)
  82     set(CMAKE_CXX_STANDARD 11)
  83     set(CMAKE_CXX_STANDARD_REQUIRED ON)
  84     set(CMAKE_CXX_EXTENSIONS OFF)
  85
  86     if (CMAKE_VERSION VERSION_LESS "3.1")
  87         if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" OR CMAKE_COMPILER_IS_GNUCXX)
  88             include(CheckCXXCompilerFlag)
  89             check_cxx_compiler_flag(--std=c++${CMAKE_CXX_STANDARD} STD_CXX)
  90             if (STD_CXX)
  91                 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} --std=c++${CMAKE_CXX_STANDARD}")
  92             else ()
  93                 message(SEND_ERROR "Requires C++${CMAKE_CXX_STANDARD} or better")
  94             endif ()
  95         else ()
  96             message(WARNING "Unrecognized compiler: ${CMAKE_CXX_COMPILER_ID}, make sure it supports C++${CMAKE_CXX_STANDARD}")
  97         endif ()
  98     endif ()
  99 endif ()
 100
 101 #-----------------------------------------------------------------------
 102 # Flags
 103 #-----------------------------------------------------------------------
 104
 105 if (BUILD_BINARIES)
 106     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-exceptions -fno-rtti")
 107
 108     macro (addflags_c args)
 109         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${args}")
 110     endmacro ()
 111
 112     macro (addflags_cxx args)
 113         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${args}")
 114     endmacro ()
 115
 116     macro (addflags args)
 117         addflags_c("${args}")
 118         addflags_cxx("${args}")
 119     endmacro ()
 120
 121     addflags("-fno-strict-aliasing")
 122     if (NOT WIN32)
 123         addflags("-fvisibility=hidden")
 124     endif ()
 125
 126     if (USE_WERROR)
 127         addflags("-Werror")
 128         addflags("-pedantic-errors")
 129     endif ()
 130
 131     addflags("-Wall")
 132     addflags("-Wextra")
 133     addflags("-pedantic")
 134
 135     addflags_c("-Wno-deprecated-declarations") # vfs.c: g_strdown
 136
 137     addflags("-Wno-unused-function")
 138     addflags("-Wno-unused-variable")
 139     addflags("-Wno-unused-parameter")
 140
 141     set(CMAKE_POSITION_INDEPENDENT_CODE 1)
 142 endif ()
 143
 144 if (BUILD_RADIANT)
 145     set(GTK_TARGET 2 CACHE STRING "GTK target")
 146     add_definitions(-DGTK_TARGET=${GTK_TARGET})
 147
 148     if (WIN32)
 149         add_definitions(-DWORKAROUND_WINDOWS_FLOATING_WINDOW=1)
 150
 151         if (GTK_TARGET EQUAL 2)
 152             add_definitions(-DWORKAROUND_WINDOWS_GTK2_GLWIDGET=1)
 153         endif ()
 154     endif ()
 155 endif ()
 156
 157 #-----------------------------------------------------------------------
 158 # Defs
 159 #-----------------------------------------------------------------------
 160
 161 if (BUILD_BINARIES)
 162     add_definitions(-DRADIANT_VERSION="${RADIANT_VERSION}")
 163     add_definitions(-DRADIANT_VERSION_STRING="${RADIANT_VERSION_STRING}")
 164
 165     if (NOT CMAKE_BUILD_TYPE MATCHES Release)
 166         add_definitions(-D_DEBUG=1)
 167     endif ()
 168 endif ()
 169
 170 if (BUILD_RADIANT)
 171     add_definitions(-DRADIANT_ABOUTMSG="${RADIANT_ABOUTMSG}")
 172
 173     macro (disable_deprecated name gtk2only)
 174         add_definitions(-D${name}_DISABLE_SINGLE_INCLUDES)
 175         if ((${gtk2only} EQUAL 0) OR (GTK_TARGET EQUAL 2))
 176             add_definitions(-D${name}_DISABLE_DEPRECATED)
 177         endif ()
 178     endmacro ()
 179
 180     disable_deprecated(ATK 0)
 181     disable_deprecated(G 0)
 182     disable_deprecated(GDK 0)
 183     disable_deprecated(GDK_PIXBUF 0)
 184     disable_deprecated(GTK 1)
 185     disable_deprecated(PANGO 0)
 186 endif ()
 187
 188 if (BUILD_BINARIES)
 189     add_custom_target(binaries ALL)
 190
 191     if(APPLE OR ${CMAKE_SYSTEM_NAME} STREQUAL "FreeBSD")
 192         link_directories(
 193             /usr/local/lib
 194         )
 195     endif ()
 196
 197     if (WIN32)
 198         add_definitions(
 199             -DWIN32=1
 200             -D_WIN32=1
 201         )
 202     else ()
 203         add_definitions(
 204             -DPOSIX=1
 205         )
 206     endif ()
 207 endif ()
 208
 209 if (BUILD_RADIANT AND NOT APPLE AND NOT WIN32)
 210     set(XWINDOWS ON)
 211     find_package(X11 REQUIRED)
 212     include_directories(${X11_INCLUDE_DIR})
 213     add_definitions(-DXWINDOWS=1)
 214 endif ()
 215
 216 if (BUILD_BINARIES)
 217     include_directories("${PROJECT_SOURCE_DIR}/include")
 218     include_directories("${PROJECT_SOURCE_DIR}/libs")
 219
 220     if (WIN32 OR "${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
 221         set(BUNDLING_SUPPORTED ON)
 222     endif()
 223
 224     if (BUNDLING_SUPPORTED)
 225         if(WIN32 AND NOT CMAKE_CROSSCOMPILING)
 226             set(BUNDLE_LIBRARIES_DEFAULT ON)
 227         else ()
 228             set(BUNDLE_LIBRARIES_DEFAULT OFF)
 229         endif ()
 230
 231         option(BUNDLE_LIBRARIES "Bundle libraries" ${BUNDLE_LIBRARIES_DEFAULT})
 232     endif ()
 233
 234     if (BUNDLE_LIBRARIES AND BUNDLING_SUPPORTED)
 235         add_subdirectory(bundle)
 236
 237         set(FHS_INSTALL OFF CACHE PATH "Disabled because of BUNDLE_LIBRARIES" FORCE)
 238     endif ()
 239
 240     macro (copy_dlls target)
 241         if (BUNDLE_LIBRARIES AND BUNDLING_SUPPORTED)
 242             add_custom_command(TARGET ${target} POST_BUILD
 243                 COMMAND "${PROJECT_SOURCE_DIR}/library-bundler"
 244                 "register" "${PROJECT_BINARY_DIR}" "$<TARGET_FILE:${target}>"
 245                 VERBATIM
 246             )
 247             add_dependencies(bundle ${target})
 248         endif ()
 249     endmacro ()
 250 endif ()
 251
 252 #-----------------------------------------------------------------------
 253 # Libraries
 254 #-----------------------------------------------------------------------
 255
 256 if (BUILD_BINARIES)
 257     add_subdirectory(libs)
 258 endif ()
 259
 260 if (BUILD_RADIANT)
 261     add_subdirectory(include)
 262 endif ()
 263
 264 #-----------------------------------------------------------------------
 265 # Plugins
 266 #-----------------------------------------------------------------------
 267
 268 if (BUILD_RADIANT)
 269     add_subdirectory(contrib)
 270 endif ()
 271
 272 #-----------------------------------------------------------------------
 273 # Modules
 274 #-----------------------------------------------------------------------
 275
 276 if (BUILD_RADIANT)
 277     add_subdirectory(plugins)
 278 endif ()
 279
 280 #-----------------------------------------------------------------------
 281 # Radiant
 282 #-----------------------------------------------------------------------
 283
 284 if (BUILD_BINARIES)
 285     macro (radiant_tool name)
 286         add_dependencies(binaries ${name})
 287
 288         if (WIN32)
 289             add_executable(${name} ${ARGN} ${PROJECT_SOURCE_DIR}/include/lib.rc)
 290         else ()
 291             add_executable(${name} ${ARGN})
 292         endif()
 293
 294         copy_dlls(${name})
 295
 296         install(
 297             TARGETS ${name}
 298             RUNTIME DESTINATION ${RADIANT_BIN_DIR}
 299         )
 300     endmacro ()
 301
 302     if (BUILD_RADIANT)
 303         add_subdirectory(radiant)
 304     endif ()
 305 endif ()
 306
 307 #-----------------------------------------------------------------------
 308 # Tools
 309 #-----------------------------------------------------------------------
 310
 311 if (BUILD_TOOLS)
 312     add_subdirectory(tools)
 313
 314     file(GLOB DATA_FILES "${PROJECT_SOURCE_DIR}/setup/data/tools/*")
 315
 316     if (NOT (PROJECT_SOURCE_DIR STREQUAL PROJECT_BINARY_DIR))
 317         # Copy data files from sources to the build directory
 318         message(STATUS "Copying data files")
 319         file(COPY ${DATA_FILES} DESTINATION "${PROJECT_BINARY_DIR}")
 320     endif ()
 321 endif ()
 322
 323 #-----------------------------------------------------------------------
 324 # Game packs
 325 #-----------------------------------------------------------------------
 326
 327 set(GAMEPACKS_LICENSE_LIST free CACHE STRING "Download game packs by license")
 328 set(GAMEPACKS_NAME_LIST none CACHE STRING "Download game packs by name")
 329
 330 if (DOWNLOAD_GAMEPACKS)
 331     add_custom_target(gamepacks ALL
 332        COMMAND "${PROJECT_SOURCE_DIR}/gamepack-manager" --license ${GAMEPACKS_LICENSE_LIST} --name ${GAMEPACKS_NAME_LIST} --download-dir "${GAMEPACKS_DOWNLOAD_DIR}" --install-dir "${PROJECT_BINARY_DIR}/gamepacks" --download --install
 333        COMMENT "Downloading game packs"
 334     )
 335 endif ()
 336
 337 #-----------------------------------------------------------------------
 338 # Install
 339 #-----------------------------------------------------------------------
 340
 341 if (BUILD_BINARIES)
 342     install(DIRECTORY
 343         setup/data/tools/base
 344         setup/data/tools/bitmaps
 345         setup/data/tools/gl
 346         setup/data/tools/plugins
 347         docs
 348         DESTINATION ${RADIANT_DATA_DIR}
 349     )
 350 endif ()
 351
 352 if (DOWNLOAD_GAMEPACKS)
 353     if (FHS_INSTALL)
 354        set(GAME_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}/share/netradiant")
 355     else ()
 356        set(GAME_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}")
 357     endif ()
 358
 359     install(DIRECTORY
 360         ${PROJECT_BINARY_DIR}/gamepacks
 361         DESTINATION ${RADIANT_DATA_DIR}
 362     )
 363 endif ()
 364
 365 if(BUILD_BINARIES AND FHS_INSTALL AND NOT WIN32 AND NOT APPLE)
 366     install(FILES
 367         ${PROJECT_SOURCE_DIR}/icons/netradiant.png
 368         DESTINATION ${CMAKE_INSTALL_PREFIX}/share/pixmaps
 369     )
 370     install(FILES
 371         ${PROJECT_SOURCE_DIR}/icons/netradiant.desktop
 372         DESTINATION ${CMAKE_INSTALL_PREFIX}/share/applications
 373     )
 374     install(FILES
 375         ${PROJECT_SOURCE_DIR}/icons/mime/map.xml
 376         DESTINATION ${CMAKE_INSTALL_PREFIX}/share/mime/model
 377     )
 378 endif ()
 379
 380 include(cmake/scripts/package.cmake)