data/qcsrc/client/radar.qc

   1 float radar_angle; // player yaw angle\r
   2 vector radar_origin3d_in_texcoord; // player origin\r
   3 vector radar_origin2d; // 2D origin\r
   4 vector radar_size2d; // 2D size\r
   5 vector radar_extraclip_mins, radar_extraclip_maxs; // don't even ask\r
   6 float radar_size; // 2D scale factor\r
   7 float cl_radar_scale; // window size = ...qu\r
   8 float cl_radar_nohudhack;\r
   9 float v_flipped;\r
  10 \r
  11 float vlen2d(vector v)\r
  12 {\r
  13         return sqrt(v_x * v_x + v_y * v_y);\r
  14 }\r
  15 \r
  16 float vlen_maxnorm2d(vector v)\r
  17 {\r
  18         return max4(v_x, v_y, -v_x, -v_y);\r
  19 }\r
  20 \r
  21 float vlen_minnorm2d(vector v)\r
  22 {\r
  23         return min(max(v_x, -v_x), max(v_y, -v_y));\r
  24 }\r
  25 \r
  26 vector radar_3dcoord_to_texcoord(vector in)\r
  27 {\r
  28         vector out;\r
  29         out_x = (in_x - mi_picmin_x) / (mi_picmax_x - mi_picmin_x);\r
  30         out_y = (in_y - mi_picmin_y) / (mi_picmax_y - mi_picmin_y);\r
  31         out_z = 0;\r
  32         return out;\r
  33 }\r
  34 \r
  35 vector radar_texcoord_to_2dcoord(vector in)\r
  36 {\r
  37         vector out;\r
  38         in -= radar_origin3d_in_texcoord;\r
  39 \r
  40         out = rotate(in, radar_angle * DEG2RAD);\r
  41         out_y = - out_y; // screen space is reversed\r
  42 \r
  43         out = out * radar_size;\r
  44         if(v_flipped)\r
  45                 out_x = -out_x;\r
  46         out += radar_origin2d;\r
  47         return out;\r
  48 }\r
  49 \r
  50 vector yinvert(vector v)\r
  51 {\r
  52         v_y = 1 - v_y;\r
  53         return v;\r
  54 }\r
  55 \r
  56 void draw_radar_background(float ca, float bg)\r
  57 {\r
  58         vector col;\r
  59         vector pos1, pos2, pos3, pos4;\r
  60         pos1 = '1 0 0' * (radar_origin2d_x - radar_size2d_x * 0.5 + radar_extraclip_mins_x) + '0 1 0' * (radar_origin2d_y - radar_size2d_y * 0.5 + radar_extraclip_mins_y);\r
  61         pos2 = '1 0 0' * (radar_origin2d_x + radar_size2d_x * 0.5 + radar_extraclip_maxs_x) + '0 1 0' * (radar_origin2d_y - radar_size2d_y * 0.5 + radar_extraclip_mins_y);\r
  62         pos3 = '1 0 0' * (radar_origin2d_x + radar_size2d_x * 0.5 + radar_extraclip_maxs_x) + '0 1 0' * (radar_origin2d_y + radar_size2d_y * 0.5 + radar_extraclip_maxs_y);\r
  63         pos4 = '1 0 0' * (radar_origin2d_x - radar_size2d_x * 0.5 + radar_extraclip_mins_x) + '0 1 0' * (radar_origin2d_y + radar_size2d_y * 0.5 + radar_extraclip_maxs_y);\r
  64 \r
  65         if(bg > 0)\r
  66         {\r
  67                 R_BeginPolygon("gfx/hud/bg_radar.tga", 0);\r
  68                 R_PolygonVertex(pos1, yinvert('0 1 0'), '1 1 1', bg);\r
  69                 R_PolygonVertex(pos2, yinvert('1 1 0'), '1 1 1', bg);\r
  70                 R_PolygonVertex(pos3, yinvert('1 0 0'), '1 1 1', bg);\r
  71                 R_PolygonVertex(pos4, yinvert('0 0 0'), '1 1 1', bg);\r
  72                 R_EndPolygon();\r
  73         }\r
  74 \r
  75         if(ca > 0 && minimapname != "")\r
  76         {\r
  77                 col = '1 1 1' * ca;\r
  78                 R_BeginPolygon(minimapname, DRAWFLAG_SCREEN | DRAWFLAG_MIPMAP);\r
  79                 if(v_flipped)\r
  80                 {\r
  81                         R_PolygonVertex(radar_texcoord_to_2dcoord(mi_pictexcoord3), yinvert(mi_pictexcoord3), col, 1);\r
  82                         R_PolygonVertex(radar_texcoord_to_2dcoord(mi_pictexcoord2), yinvert(mi_pictexcoord2), col, 1);\r
  83                         R_PolygonVertex(radar_texcoord_to_2dcoord(mi_pictexcoord1), yinvert(mi_pictexcoord1), col, 1);\r
  84                         R_PolygonVertex(radar_texcoord_to_2dcoord(mi_pictexcoord0), yinvert(mi_pictexcoord0), col, 1);\r
  85                 }\r
  86                 else\r
  87                 {\r
  88                         R_PolygonVertex(radar_texcoord_to_2dcoord(mi_pictexcoord0), yinvert(mi_pictexcoord0), col, 1);\r
  89                         R_PolygonVertex(radar_texcoord_to_2dcoord(mi_pictexcoord1), yinvert(mi_pictexcoord1), col, 1);\r
  90                         R_PolygonVertex(radar_texcoord_to_2dcoord(mi_pictexcoord2), yinvert(mi_pictexcoord2), col, 1);\r
  91                         R_PolygonVertex(radar_texcoord_to_2dcoord(mi_pictexcoord3), yinvert(mi_pictexcoord3), col, 1);\r
  92                 }\r
  93                 R_EndPolygon();\r
  94         }\r
  95 }\r
  96 \r
  97 void draw_radar_foreground(float fg)\r
  98 {\r
  99         vector rgb;\r
 100         vector pos1, pos2, pos3, pos4;\r
 101         pos1 = '1 0 0' * (radar_origin2d_x - radar_size2d_x * 0.5 + radar_extraclip_mins_x) + '0 1 0' * (radar_origin2d_y - radar_size2d_y * 0.5 + radar_extraclip_mins_y);\r
 102         pos2 = '1 0 0' * (radar_origin2d_x + radar_size2d_x * 0.5 + radar_extraclip_maxs_x) + '0 1 0' * (radar_origin2d_y - radar_size2d_y * 0.5 + radar_extraclip_mins_y);\r
 103         pos3 = '1 0 0' * (radar_origin2d_x + radar_size2d_x * 0.5 + radar_extraclip_maxs_x) + '0 1 0' * (radar_origin2d_y + radar_size2d_y * 0.5 + radar_extraclip_maxs_y);\r
 104         pos4 = '1 0 0' * (radar_origin2d_x - radar_size2d_x * 0.5 + radar_extraclip_mins_x) + '0 1 0' * (radar_origin2d_y + radar_size2d_y * 0.5 + radar_extraclip_maxs_y);\r
 105         rgb = GetTeamRGB(GetPlayerColor(player_localentnum - 1));\r
 106 \r
 107         if(fg > 0)\r
 108         {\r
 109                 R_BeginPolygon("gfx/hud/fg_radar.tga", 0);\r
 110                 R_PolygonVertex(pos1, yinvert('0 1 0'), '1 1 1', fg);\r
 111                 R_PolygonVertex(pos2, yinvert('1 1 0'), '1 1 1', fg);\r
 112                 R_PolygonVertex(pos3, yinvert('1 0 0'), '1 1 1', fg);\r
 113                 R_PolygonVertex(pos4, yinvert('0 0 0'), '1 1 1', fg);\r
 114                 R_EndPolygon();\r
 115 \r
 116                 R_BeginPolygon("gfx/hud/fg_radar_team.tga", 0);\r
 117                 R_PolygonVertex(pos1, yinvert('0 1 0'), rgb, fg);\r
 118                 R_PolygonVertex(pos2, yinvert('1 1 0'), rgb, fg);\r
 119                 R_PolygonVertex(pos3, yinvert('1 0 0'), rgb, fg);\r
 120                 R_PolygonVertex(pos4, yinvert('0 0 0'), rgb, fg);\r
 121                 R_EndPolygon();\r
 122         }\r
 123 }\r
 124 \r
 125 void(vector coord3d, vector pangles, vector rgb) draw_radar_player =\r
 126 {\r
 127         vector coord, rgb2;\r
 128 \r
 129         coord = radar_texcoord_to_2dcoord(radar_3dcoord_to_texcoord(coord3d));\r
 130 \r
 131         makevectors(pangles - '0 1 0' * radar_angle);\r
 132         if(v_flipped)\r
 133         {\r
 134                 v_forward_x = -v_forward_x;\r
 135                 v_right_x = -v_right_x;\r
 136                 v_up_x = -v_up_x;\r
 137         }\r
 138         v_forward_z = 0;\r
 139         v_forward = normalize(v_forward);\r
 140         v_forward_y *= -1.0;\r
 141         v_right_x = -v_forward_y;\r
 142         v_right_y = v_forward_x;\r
 143 \r
 144         if(rgb == '1 1 1')\r
 145                 rgb2 = '0 0 0';\r
 146         else\r
 147                 rgb2 = '1 1 1';\r
 148 \r
 149         R_BeginPolygon("", 0);\r
 150         R_PolygonVertex(coord+v_forward*3, '0 0 0', rgb2, sbar_alpha_fg);\r
 151         R_PolygonVertex(coord+v_right*4-v_forward*2.5, '0 1 0', rgb2, sbar_alpha_fg);\r
 152         R_PolygonVertex(coord-v_forward*2, '1 0 0', rgb2, sbar_alpha_fg);\r
 153         R_PolygonVertex(coord-v_right*4-v_forward*2.5, '1 1 0', rgb2, sbar_alpha_fg);\r
 154         R_EndPolygon();\r
 155 \r
 156         R_BeginPolygon("", 0);\r
 157         R_PolygonVertex(coord+v_forward*2, '0 0 0', rgb, sbar_alpha_fg);\r
 158         R_PolygonVertex(coord+v_right*3-v_forward*2, '0 1 0', rgb, sbar_alpha_fg);\r
 159         R_PolygonVertex(coord-v_forward, '1 0 0', rgb, sbar_alpha_fg);\r
 160         R_PolygonVertex(coord-v_right*3-v_forward*2, '1 1 0', rgb, sbar_alpha_fg);\r
 161         R_EndPolygon();\r
 162 };\r
 163 \r
 164 void draw_radar_icon(vector coord, float icon, entity pingdata, vector rgb, float a)\r
 165 {\r
 166         float dt;\r
 167         vector v;\r
 168         float i;\r
 169 \r
 170         coord = radar_texcoord_to_2dcoord(radar_3dcoord_to_texcoord(coord));\r
 171         drawpic(coord - '4 4 0', strcat("gfx/radar_icon_", ftos(icon)), '8 8 0', rgb, a, 0);\r
 172 \r
 173         if(pingdata)\r
 174         {\r
 175                 for(i = 0; i < MAX_RADAR_TIMES; ++i)\r
 176                 {\r
 177                         dt = pingdata.(radar_times[i]);\r
 178                         if(dt == 0)\r
 179                                 continue;\r
 180                         dt = time - dt;\r
 181                         if(dt >= 1 || dt <= 0)\r
 182                                 continue;\r
 183                         v = '2 2 0' * radar_size * dt;\r
 184                         drawpic(coord - 0.5 * v, "gfx/radar_ping", v, '1 1 1', (1 - dt) * a, DRAWFLAG_ADDITIVE);\r
 185                 }\r
 186         }\r
 187 }\r
 188 \r
 189 void draw_radar_link(vector start, vector end, float colors)\r
 190 {\r
 191         vector c0, c1, norm;\r
 192 \r
 193         start = radar_texcoord_to_2dcoord(radar_3dcoord_to_texcoord(start));\r
 194         end = radar_texcoord_to_2dcoord(radar_3dcoord_to_texcoord(end));\r
 195         norm = normalize(start - end);\r
 196         norm_z = norm_x;\r
 197         norm_x = -norm_y;\r
 198         norm_y = norm_z;\r
 199         norm_z = 0;\r
 200 \r
 201         c0 = colormapPaletteColor(colors & 0x0F, FALSE);\r
 202         c1 = colormapPaletteColor((colors & 0xF0) / 0x10, FALSE);\r
 203 \r
 204         R_BeginPolygon("", 0);\r
 205         R_PolygonVertex(start - norm, '0 0 0', c0, sbar_alpha_fg);\r
 206         R_PolygonVertex(start + norm, '0 1 0', c0, sbar_alpha_fg);\r
 207         R_PolygonVertex(end + norm, '1 1 0', c1, sbar_alpha_fg);\r
 208         R_PolygonVertex(end - norm, '1 0 0', c1, sbar_alpha_fg);\r
 209         R_EndPolygon();\r
 210 }\r
 211 \r
 212 float cl_radar_scale;\r
 213 float cl_radar_content_alpha;\r
 214 float cl_radar_background_alpha;\r
 215 float cl_radar_foreground_alpha;\r
 216 float cl_radar_rotation;\r
 217 vector cl_radar_size;\r
 218 vector cl_radar_position;\r
 219 float cl_radar_zoommode;\r
 220 \r
 221 void radar_loadcvars()\r
 222 {\r
 223         v_flipped = cvar("v_flipped");\r
 224         if(showmap)\r
 225         {\r
 226                 cl_radar_scale = 42; // dummy, not used (see zoommode)\r
 227                 cl_radar_content_alpha = 1 * (1 - cvar("_menu_alpha"));\r
 228                 cl_radar_background_alpha = 1 * (1 - cvar("_menu_alpha"));\r
 229                 cl_radar_foreground_alpha = 1 * (1 - cvar("_menu_alpha"));\r
 230                 cl_radar_rotation = cvar("cl_radar_rotation");\r
 231                 if(!cl_radar_rotation)\r
 232                         cl_radar_rotation = 4;\r
 233                 cl_radar_size = '256 256 0'; // TODO make somewhat variable?\r
 234                 cl_radar_position = '0.5 0.5 0';\r
 235                 cl_radar_zoommode = 3;\r
 236                 cl_radar_nohudhack = 0;\r
 237         }\r
 238         else\r
 239         {\r
 240                 cl_radar_scale = cvar("cl_radar_scale");\r
 241                 cl_radar_content_alpha = cvar("cl_radar_content_alpha") * sbar_alpha_fg;\r
 242                 cl_radar_background_alpha = cvar("cl_radar_background_alpha") * sbar_alpha_fg;\r
 243                 cl_radar_foreground_alpha = cvar("cl_radar_foreground_alpha") * sbar_alpha_fg;\r
 244                 cl_radar_rotation = cvar("cl_radar_rotation");\r
 245                 cl_radar_size = stov(cvar_string("cl_radar_size"));\r
 246                 cl_radar_position = stov(cvar_string("cl_radar_position"));\r
 247                 cl_radar_zoommode = cvar("cl_radar_zoommode");\r
 248 \r
 249                 // others default to 0\r
 250                 // match this to defaultVoretournament.cfg!\r
 251                 if(!cl_radar_scale) cl_radar_scale = 4096;\r
 252                 if(!cl_radar_content_alpha) cl_radar_content_alpha = 0.4 * sbar_alpha_fg;\r
 253                 if(!cl_radar_background_alpha) cl_radar_background_alpha = 0.4 * sbar_alpha_fg;\r
 254                 if(!cl_radar_foreground_alpha) cl_radar_foreground_alpha = 0.8 * sbar_alpha_fg;\r
 255                 if(!cl_radar_size_x) cl_radar_size_x = 128;\r
 256                 if(!cl_radar_size_y) cl_radar_size_y = cl_radar_size_x;\r
 257 \r
 258                 cl_radar_size_z = 0;\r
 259                 cl_radar_nohudhack = cl_radar_position_z;\r
 260                 cl_radar_position_z = 0;\r
 261         }\r
 262 }\r
 263 \r
 264 void() radar_view =\r
 265 {\r
 266         local float col; // color already declared as a global in hud.qc\r
 267         local entity tm;\r
 268         float scale2d, normalsize, bigsize;\r
 269         float f;\r
 270 \r
 271         if(minimapname == "" && !showmap)\r
 272                 return;\r
 273 \r
 274         radar_loadcvars();\r
 275 \r
 276         switch(cl_radar_zoommode)\r
 277         {\r
 278                 default:\r
 279                 case 0:\r
 280                         f = current_zoomfraction;\r
 281                         break;\r
 282                 case 1:\r
 283                         f = 1 - current_zoomfraction;\r
 284                         break;\r
 285                 case 2:\r
 286                         f = 0;\r
 287                         break;\r
 288                 case 3:\r
 289                         f = 1;\r
 290                         break;\r
 291         }\r
 292 \r
 293         switch(cl_radar_rotation)\r
 294         {\r
 295                 case 0:\r
 296                         radar_angle = view_angles_y - 90;\r
 297                         break;\r
 298                 default:\r
 299                         radar_angle = 90 * cl_radar_rotation;\r
 300                         break;\r
 301         }\r
 302 \r
 303         scale2d = vlen_maxnorm2d(mi_picmax - mi_picmin);\r
 304         radar_size2d = cl_radar_size;\r
 305 \r
 306         radar_origin2d =\r
 307                   '1 0 0' * (0.5 * radar_size2d_x + cl_radar_position_x * (vid_conwidth - radar_size2d_x))\r
 308                 + '0 1 0' * (0.5 * radar_size2d_y + cl_radar_position_y * (vid_conheight - radar_size2d_y));\r
 309         \r
 310         radar_extraclip_mins = radar_extraclip_maxs = '0 0 0';\r
 311         if(cl_radar_position == '1 0 0')\r
 312         {\r
 313                 if(cl_radar_nohudhack < 2)\r
 314                         radar_origin2d_y += 25;\r
 315                 if(cl_radar_nohudhack < 1)\r
 316                         radar_extraclip_mins_y -= 25;\r
 317         }\r
 318         else if(cl_radar_position == '0 1 0' || cl_radar_position == '1 1 0')\r
 319         {\r
 320                 if(cl_radar_nohudhack < 2)\r
 321                         radar_origin2d_y -= 50;\r
 322                 //if(cl_radar_nohudhack < 1)\r
 323                         //radar_extraclip_size_y += 50; // don't, the HUD looks nice\r
 324         }\r
 325 \r
 326         // pixels per world qu to match the radar_size2d_x range in the longest dimension\r
 327         if(cl_radar_rotation == 0)\r
 328         {\r
 329                 // max-min distance must fit the radar in any rotation\r
 330                 bigsize = vlen_minnorm2d(radar_size2d) * scale2d / (1.05 * vlen2d(mi_max - mi_min));\r
 331         }\r
 332         else\r
 333         {\r
 334                 vector c0, c1, c2, c3, span;\r
 335                 c0 = rotate(mi_min, radar_angle * DEG2RAD);\r
 336                 c1 = rotate(mi_max, radar_angle * DEG2RAD);\r
 337                 c2 = rotate('1 0 0' * mi_min_x + '0 1 0' * mi_max_y, radar_angle * DEG2RAD);\r
 338                 c3 = rotate('1 0 0' * mi_max_x + '0 1 0' * mi_min_y, radar_angle * DEG2RAD);\r
 339                 span = '0 0 0';\r
 340                 span_x = max4(c0_x, c1_x, c2_x, c3_x) - min4(c0_x, c1_x, c2_x, c3_x);\r
 341                 span_y = max4(c0_y, c1_y, c2_y, c3_y) - min4(c0_y, c1_y, c2_y, c3_y);\r
 342 \r
 343                 // max-min distance must fit the radar in x=x, y=y\r
 344                 bigsize = min(\r
 345                         radar_size2d_x * scale2d / (1.05 * span_x),\r
 346                         radar_size2d_y * scale2d / (1.05 * span_y)\r
 347                 );\r
 348         }\r
 349 \r
 350         normalsize = vlen_maxnorm2d(radar_size2d) * scale2d / cl_radar_scale;\r
 351         if(bigsize > normalsize)\r
 352                 normalsize = bigsize;\r
 353 \r
 354         radar_size =\r
 355                   f * bigsize\r
 356                 + (1 - f) * normalsize;\r
 357         radar_origin3d_in_texcoord = radar_3dcoord_to_texcoord(\r
 358                   f * (mi_min + mi_max) * 0.5\r
 359                 + (1 - f) * view_origin);\r
 360 \r
 361         drawsetcliparea(\r
 362                 radar_origin2d_x - radar_size2d_x * 0.5 + radar_extraclip_mins_x,\r
 363                 radar_origin2d_y - radar_size2d_y * 0.5 + radar_extraclip_mins_y,\r
 364                 radar_size2d_x + radar_extraclip_maxs_x - radar_extraclip_mins_x,\r
 365                 radar_size2d_y + radar_extraclip_maxs_y - radar_extraclip_mins_y\r
 366         );\r
 367 \r
 368         draw_radar_background(cl_radar_content_alpha, cl_radar_background_alpha);\r
 369 \r
 370         if(showmap)\r
 371         {\r
 372                 drawresetcliparea();\r
 373                 drawsetcliparea(\r
 374                         radar_origin2d_x - radar_size2d_x * 0.5,\r
 375                         radar_origin2d_y - radar_size2d_y * 0.5,\r
 376                         radar_size2d_x,\r
 377                         radar_size2d_y\r
 378                 );\r
 379         }\r
 380 \r
 381         for(tm = world; (tm = find(tm, classname, "radarlink")); )\r
 382                 draw_radar_link(tm.origin, tm.velocity, tm.team);\r
 383         for(tm = world; (tm = findflags(tm, radar_icon, 0xFFFFFF)); )\r
 384                 draw_radar_icon(tm.origin, tm.radar_icon, tm, tm.radar_color, tm.alpha * sbar_alpha_fg);\r
 385         for(tm = world; (tm = find(tm, classname, "entcs_receiver")); )\r
 386         {\r
 387                 col = GetPlayerColor(tm.sv_entnum);\r
 388                 if(cvar("cl_radar_players") > 1 || (cvar("cl_radar_players") > 0 && teamplay && GetPlayerColor(player_localentnum - 1) == col))\r
 389                 if not(tm.sv_entnum == spectatee_status - 1) // don't show the player we are spectating, since we also draw ourself separately\r
 390                 if not(tm.eaten) // don't show prey on the radar\r
 391                         draw_radar_player(tm.origin, tm.angles, GetTeamRGB(col));\r
 392         }\r
 393         draw_radar_player(view_origin, view_angles, '1 1 1');\r
 394 \r
 395         drawresetcliparea();\r
 396 \r
 397         draw_radar_foreground(cl_radar_foreground_alpha);\r
 398 };\r
 399 \r
 400 \r
 401 \r
 402 // radar links\r
 403 \r
 404 void Ent_RadarLink()\r
 405 {\r
 406         float sendflags;\r
 407         sendflags = ReadByte();\r
 408 \r
 409         InterpolateOrigin_Undo();\r
 410 \r
 411         self.iflags = IFLAG_VELOCITY;\r
 412         self.classname = "radarlink";\r
 413 \r
 414         if(sendflags & 1)\r
 415         {\r
 416                 self.origin_x = ReadCoord();\r
 417                 self.origin_y = ReadCoord();\r
 418                 self.origin_z = ReadCoord();\r
 419         }\r
 420 \r
 421         if(sendflags & 2)\r
 422         {\r
 423                 self.velocity_x = ReadCoord();\r
 424                 self.velocity_y = ReadCoord();\r
 425                 self.velocity_z = ReadCoord();\r
 426         }\r
 427 \r
 428         if(sendflags & 4)\r
 429         {\r
 430                 self.team = ReadByte();\r
 431         }\r
 432 \r
 433         InterpolateOrigin_Note();\r
 434 }\r