+GENERIC_COMMAND(cvar_localchanges, "Print locally changed cvars")
+{
+ switch (request)
+ {
+ case CMD_REQUEST_COMMAND:
+ {
+ string s = "";
+ int h = buf_create();
+ buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
+ int n = buf_getsize(h);
+ for (int i = 0; i < n; ++i) {
+ string k = bufstr_get(h, i);
+ string v = cvar_string(k);
+ string d = cvar_defstring(k);
+ if (v == d)
+ continue;
+ s = strcat(s, k, " \"", v, "\" // \"", d, "\"\n");
+ }
+ buf_del(h);
+ LOG_INFO(s);
+ return;
+ }
+ default:
+ case CMD_REQUEST_USAGE:
+ {
+ LOG_INFO("Usage:^3 ", GetProgramCommandPrefix(), " cvar_localchanges");
+ return;
+ }
+ }
+}
+
+
+#if ENABLE_DEBUGTRACE
+REGISTER_STAT(TRACE_ENT, int)
+#ifdef SVQC
+bool autocvar_debugtrace;
+
+REGISTER_MUTATOR(trace, autocvar_debugtrace);
+
+.bool debug_trace_button;
+.int solid_prev;
+MUTATOR_HOOKFUNCTION(trace, SV_StartFrame)
+{
+ FOREACH_CLIENT(true, {
+ bool skip = false;
+ bool btn = PHYS_INPUT_BUTTON_HOOK(it);
+ if (btn == it.debug_trace_button) skip = true;
+ it.debug_trace_button = btn;
+ if (!btn || skip) continue;
+ FOREACH_ENTITY(true, {
+ it.solid_prev = it.solid;
+ it.solid = SOLID_BBOX;
+ });
+ vector forward = '0 0 0'; vector right = '0 0 0'; vector up = '0 0 0';
+ MAKEVECTORS(makevectors, it.v_angle, forward, right, up);
+ vector pos = it.origin + it.view_ofs;
+ traceline(pos, pos + forward * max_shot_distance, MOVE_NORMAL, it);
+ FOREACH_ENTITY(true, {
+ it.solid = it.solid_prev;
+ it.solid_prev = 0;
+ });
+ entity e = trace_ent;
+ int i = etof(e);
+ STAT(TRACE_ENT, it) = i;
+ if (!e) continue;
+ setorigin(e, e.origin + '0 0 100');
+ stuffcmd(it, sprintf("prvm_edict server %d\n", i));
+ });
+}
+#endif
+#ifdef CSQC
+entity TRACE_ENT;
+void Trace_draw2d(entity this)
+{
+ int e = STAT(TRACE_ENT);
+ if (!e) return;
+ vector pos = '0 0 0';
+ pos.y += vid_conheight / 2;
+ drawstring(pos, sprintf("prvm_edict server %d", e), '10 10 0', '1 1 1', 1, DRAWFLAG_NORMAL);
+}
+
+STATIC_INIT(TRACE_ENT)
+{
+ entity e = TRACE_ENT = new_pure(TRACE_ENT);
+ e.draw2d = Trace_draw2d;
+ IL_PUSH(g_drawables_2d, e);
+}
+#endif
+#endif
+
+
+GENERIC_COMMAND(find, "Search through entities for matching classname")
+{
+ switch (request)
+ {
+ case CMD_REQUEST_COMMAND:
+ {
+ int entcnt = 0;
+ FOREACH_ENTITY_CLASS_ORDERED(argv(1), true,
+ {
+ LOG_INFOF("%i (%s)", it, it.classname);
+ ++entcnt;
+ });
+ if(entcnt)
+ LOG_INFOF("Found %d entities", entcnt);
+ return;
+ }
+
+ default:
+ {
+ LOG_INFO("Incorrect parameters for ^2find^7");
+ }
+ case CMD_REQUEST_USAGE:
+ {
+ LOG_INFO("Usage:^3 " GetProgramCommandPrefix() " find classname");
+ LOG_INFO(" Where 'classname' is the classname to search for.");
+ return;
+ }
+ }
+}
+
+
+GENERIC_COMMAND(findat, "Search through entities for matching origin")
+{
+ switch (request)
+ {
+ case CMD_REQUEST_COMMAND:
+ {
+ vector match = stov(argv(1));
+ FOREACH_ENTITY_ORDERED(it.origin == match, LOG_INFOF("%i (%s)", it, it.classname));
+ return;
+ }
+
+ default:
+ LOG_INFO("Incorrect parameters for ^2findat^7");
+ case CMD_REQUEST_USAGE:
+ {
+ LOG_INFO("Usage:^3 " GetProgramCommandPrefix() " findat \"0 0 0\"");
+ return;
+ }
+ }
+}
+
+
+// debug_test() allows drawing text from server on the client anywhere in world coordinates.
+
+#ifdef GAMEQC
+REGISTER_NET_TEMP(debug_text_3d);
+#endif
+
+#ifdef CSQC
+
+CLASS(DebugText3d, Object)
+ // reusing existing fields
+ ATTRIB(DebugText3d, origin, vector);
+ ATTRIB(DebugText3d, message, string); // the text (i wanted to use the .text field but then this whole macro-based-inheritance thing shat itself)
+ ATTRIB(DebugText3d, health, float); // text alignment (recycled field)
+ ATTRIB(DebugText3d, hit_time, float); // when it was created
+ ATTRIB(DebugText3d, fade_rate, float); // how fast is should disappear
+ ATTRIB(DebugText3d, velocity, vector);
+
+ CONSTRUCTOR(DebugText3d, vector pos, string msg, float align, float fade_rate_, vector vel) {
+ CONSTRUCT(DebugText3d);
+ this.origin = pos;
+ this.message = strzone(msg);
+ this.health = align;
+ this.hit_time = time;
+ this.fade_rate = fade_rate_;
+ this.velocity = vel;
+ IL_PUSH(g_drawables_2d, this);
+ }
+
+ DESTRUCTOR(DebugText3d) {
+ strfree(this.message);
+ }
+
+ void DebugText3d_draw2d(DebugText3d this) {
+ float since_created = time - this.hit_time;
+ float alpha_ = 1 - since_created * this.fade_rate;
+
+ if (alpha_ < 0) {
+ delete(this);
+ return;
+ }
+
+ int size = 8;
+ vector screen_pos = project_3d_to_2d(this.origin) + since_created * this.velocity;
+ float align = this.health;
+ if (align > 0)
+ screen_pos.x -= stringwidth(this.message, true, size * '1 1 0') * min(1, align);
+ if (screen_pos.z < 0) return; // behind camera
+ screen_pos.z = 0;
+
+ vector rgb = '1 1 0';
+ drawcolorcodedstring2_builtin(screen_pos, this.message, size * '1 1 0', rgb, alpha_, DRAWFLAG_NORMAL);
+ }
+ ATTRIB(DebugText3d, draw2d, void(DebugText3d), DebugText3d_draw2d);
+ENDCLASS(DebugText3d)
+
+NET_HANDLE(debug_text_3d, bool is_new) {
+ vector pos = ReadVector();
+ string msg = ReadString();
+ float align = ReadFloat();
+ float duration = ReadFloat();
+ vector vel = ReadVector();
+ make_impure(NEW(DebugText3d, pos, msg, align, 1 / duration, vel));
+ return true;
+}
+
+#endif // CSQC
+
+#ifdef SVQC
+
+// can't use autocvars because they give unused warning unless the macros are expanded
+#define debug_text_3d(...) EVAL(OVERLOAD(debug_text_3d, __VA_ARGS__))
+#define debug_text_3d_2(pos, msg) debug_text_3d_3(pos, msg, cvar("debug_text_3d_default_align"))
+#define debug_text_3d_3(pos, msg, align) debug_text_3d_4(pos, msg, align, cvar("debug_text_3d_default_duration"))
+#define debug_text_3d_4(pos, msg, align, dur) debug_text_3d_5(pos, msg, align, dur, stov(cvar_string("debug_text_3d_default_velocity")))
+#define debug_text_3d_5(pos, msg, align, dur, vel) debug_text_3d_fn(pos, msg, align, dur, vel)
+
+ERASEABLE
+void debug_text_3d_fn(vector pos, string msg, float align, float duration, vector vel) {
+ WriteHeader(MSG_BROADCAST, debug_text_3d);
+ WriteVector(MSG_BROADCAST, pos);
+ WriteString(MSG_BROADCAST, msg);
+ WriteFloat(MSG_BROADCAST, align);
+ WriteFloat(MSG_BROADCAST, duration);
+ WriteVector(MSG_BROADCAST, vel);
+}
+
+#endif // SVQC