qcsrc/server/world.qc

   1 #include "world.qh"
   2
   3 #include <common/constants.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/gamemodes/sv_rules.qh>
   7 #include <common/items/_mod.qh>
   8 #include <common/mapinfo.qh>
   9 #include <common/mapobjects/target/music.qh>
  10 #include <common/mapobjects/trigger/hurt.qh>
  11 #include <common/mapobjects/trigger/secret.qh>
  12 #include <common/mapobjects/triggers.qh>
  13 #include <common/monsters/_mod.qh>
  14 #include <common/monsters/sv_monsters.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/notifications/all.qh>
  17 #include <common/physics/player.qh>
  18 #include <common/playerstats.qh>
  19 #include <common/state.qh>
  20 #include <common/stats.qh>
  21 #include <common/teams.qh>
  22 #include <common/util.qh>
  23 #include <common/vehicles/all.qh>
  24 #include <common/weapons/_all.qh>
  25 #include <server/anticheat.qh>
  26 #include <server/antilag.qh>
  27 #include <server/bot/api.qh>
  28 #include <server/campaign.qh>
  29 #include <server/cheats.qh>
  30 #include <server/client.qh>
  31 #include <server/command/common.qh>
  32 #include <server/command/getreplies.qh>
  33 #include <server/command/sv_cmd.qh>
  34 #include <server/command/vote.qh>
  35 #include <server/damage.qh>
  36 #include <server/gamelog.qh>
  37 #include <server/hook.qh>
  38 #include <server/ipban.qh>
  39 #include <server/items/items.qh>
  40 #include <server/main.qh>
  41 #include <server/mapvoting.qh>
  42 #include <server/mutators/_mod.qh>
  43 #include <server/race.qh>
  44 #include <server/scores.qh>
  45 #include <server/scores_rules.qh>
  46 #include <server/spawnpoints.qh>
  47 #include <server/teamplay.qh>
  48 #include <server/weapons/weaponstats.qh>
  49
  50 const float LATENCY_THINKRATE = 10;
  51 .float latency_sum;
  52 .float latency_cnt;
  53 .float latency_time;
  54 entity pingplreport;
  55 void PingPLReport_Think(entity this)
  56 {
  57         float delta;
  58         entity e;
  59
  60         delta = 3 / maxclients;
  61         if(delta < sys_frametime)
  62                 delta = 0;
  63         this.nextthink = time + delta;
  64
  65         e = edict_num(this.cnt + 1);
  66         if(IS_CLIENT(e) && IS_REAL_CLIENT(e))
  67         {
  68                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  69                 WriteByte(MSG_BROADCAST, this.cnt);
  70                 WriteShort(MSG_BROADCAST, bound(1, rint(CS(e).ping), 32767));
  71                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_packetloss * 255), 255));
  72                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_movementloss * 255), 255));
  73
  74                 // record latency times for clients throughout the match so we can report it to playerstats
  75                 if(time > (CS(e).latency_time + LATENCY_THINKRATE))
  76                 {
  77                         CS(e).latency_sum += CS(e).ping;
  78                         CS(e).latency_cnt += 1;
  79                         CS(e).latency_time = time;
  80                         //print("sum: ", ftos(CS(e).latency_sum), ", cnt: ", ftos(CS(e).latency_cnt), ", avg: ", ftos(CS(e).latency_sum / CS(e).latency_cnt), ".\n");
  81                 }
  82         }
  83         else
  84         {
  85                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  86                 WriteByte(MSG_BROADCAST, this.cnt);
  87                 WriteShort(MSG_BROADCAST, 0);
  88                 WriteByte(MSG_BROADCAST, 0);
  89                 WriteByte(MSG_BROADCAST, 0);
  90         }
  91         this.cnt = (this.cnt + 1) % maxclients;
  92 }
  93 void PingPLReport_Spawn()
  94 {
  95         pingplreport = new_pure(pingplreport);
  96         setthink(pingplreport, PingPLReport_Think);
  97         pingplreport.nextthink = time;
  98 }
  99
 100 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
 101
 102 void SetDefaultAlpha()
 103 {
 104         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
 105         {
 106                 default_player_alpha = autocvar_g_player_alpha;
 107                 if(default_player_alpha == 0)
 108                         default_player_alpha = 1;
 109                 default_weapon_alpha = default_player_alpha;
 110         }
 111 }
 112
 113 void GotoFirstMap(entity this)
 114 {
 115         float n;
 116         if(autocvar__sv_init)
 117         {
 118                 // cvar_set("_sv_init", "0");
 119                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 120                 // to this "init" map on a dedicated server will cause no permanent
 121                 // harm
 122                 if(autocvar_g_maplist_shuffle)
 123                         ShuffleMaplist();
 124                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 125                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 126
 127                 MapInfo_Enumerate();
 128                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 129
 130                 if(!DoNextMapOverride(1))
 131                         GotoNextMap(1);
 132
 133                 return;
 134         }
 135
 136         if(time < 5)
 137         {
 138                 this.nextthink = time;
 139         }
 140         else
 141         {
 142                 this.nextthink = time + 1;
 143                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...");
 144         }
 145 }
 146
 147 void cvar_changes_init()
 148 {
 149         float h;
 150         string k, v, d;
 151         float n, i, adding, pureadding;
 152
 153         strfree(cvar_changes);
 154         strfree(cvar_purechanges);
 155         cvar_purechanges_count = 0;
 156
 157         h = buf_create();
 158         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 159         n = buf_getsize(h);
 160
 161         adding = true;
 162         pureadding = true;
 163
 164         for(i = 0; i < n; ++i)
 165         {
 166                 k = bufstr_get(h, i);
 167
 168 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 169 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 170 #define BADCVAR(p) if(k == p) continue
 171 #define BADVALUE(p, val) if (k == p && v == val) continue
 172
 173                 // general excludes and namespaces for server admin used cvars
 174                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 175
 176                 // internal
 177                 BADPREFIX("csqc_");
 178                 BADPREFIX("cvar_check_");
 179                 BADCVAR("gamecfg");
 180                 BADCVAR("g_configversion");
 181                 BADCVAR("halflifebsp");
 182                 BADCVAR("sv_mapformat_is_quake2");
 183                 BADCVAR("sv_mapformat_is_quake3");
 184                 BADPREFIX("sv_world");
 185
 186                 // client
 187                 BADPREFIX("chase_");
 188                 BADPREFIX("cl_");
 189                 BADPREFIX("con_");
 190                 BADPREFIX("scoreboard_");
 191                 BADPREFIX("g_campaign");
 192                 BADPREFIX("g_waypointsprite_");
 193                 BADPREFIX("gl_");
 194                 BADPREFIX("joy");
 195                 BADPREFIX("hud_");
 196                 BADPREFIX("m_");
 197                 BADPREFIX("menu_");
 198                 BADPREFIX("net_slist_");
 199                 BADPREFIX("r_");
 200                 BADPREFIX("sbar_");
 201                 BADPREFIX("scr_");
 202                 BADPREFIX("snd_");
 203                 BADPREFIX("show");
 204                 BADPREFIX("sensitivity");
 205                 BADPREFIX("userbind");
 206                 BADPREFIX("v_");
 207                 BADPREFIX("vid_");
 208                 BADPREFIX("crosshair");
 209                 BADCVAR("mod_q3bsp_lightmapmergepower");
 210                 BADCVAR("mod_q3bsp_nolightmaps");
 211                 BADCVAR("fov");
 212                 BADCVAR("mastervolume");
 213                 BADCVAR("volume");
 214                 BADCVAR("bgmvolume");
 215                 BADCVAR("in_pitch_min");
 216                 BADCVAR("in_pitch_max");
 217
 218                 // private
 219                 BADCVAR("developer");
 220                 BADCVAR("log_dest_udp");
 221                 BADCVAR("net_address");
 222                 BADCVAR("net_address_ipv6");
 223                 BADCVAR("port");
 224                 BADCVAR("savedgamecfg");
 225                 BADCVAR("serverconfig");
 226                 BADCVAR("sv_autoscreenshot");
 227                 BADCVAR("sv_heartbeatperiod");
 228                 BADCVAR("sv_vote_master_password");
 229                 BADCVAR("sys_colortranslation");
 230                 BADCVAR("sys_specialcharactertranslation");
 231                 BADCVAR("timeformat");
 232                 BADCVAR("timestamps");
 233                 BADCVAR("g_require_stats");
 234                 BADPREFIX("developer_");
 235                 BADPREFIX("g_ban_");
 236                 BADPREFIX("g_banned_list");
 237                 BADPREFIX("g_require_stats_");
 238                 BADPREFIX("g_chat_flood_");
 239                 BADPREFIX("g_ghost_items");
 240                 BADPREFIX("g_playerstats_");
 241                 BADPREFIX("g_voice_flood_");
 242                 BADPREFIX("log_file");
 243                 BADPREFIX("quit_");
 244                 BADPREFIX("rcon_");
 245                 BADPREFIX("sv_allowdownloads");
 246                 BADPREFIX("sv_autodemo");
 247                 BADPREFIX("sv_curl_");
 248                 BADPREFIX("sv_eventlog");
 249                 BADPREFIX("sv_logscores_");
 250                 BADPREFIX("sv_master");
 251                 BADPREFIX("sv_weaponstats_");
 252                 BADPREFIX("sv_waypointsprite_");
 253                 BADCVAR("rescan_pending");
 254
 255                 // these can contain player IDs, so better hide
 256                 BADPREFIX("g_forced_team_");
 257                 BADCVAR("sv_muteban_list");
 258                 BADCVAR("sv_voteban_list");
 259                 BADCVAR("sv_allow_customplayermodels_idlist");
 260                 BADCVAR("sv_allow_customplayermodels_speciallist");
 261
 262                 // mapinfo
 263                 BADCVAR("fraglimit");
 264                 BADCVAR("g_arena");
 265                 BADCVAR("g_assault");
 266                 BADCVAR("g_ca");
 267                 BADCVAR("g_ca_teams");
 268                 BADCVAR("g_conquest");
 269                 BADCVAR("g_conquest_teams");
 270                 BADCVAR("g_ctf");
 271                 BADCVAR("g_cts");
 272                 BADCVAR("g_dotc");
 273                 BADCVAR("g_dm");
 274                 BADCVAR("g_domination");
 275                 BADCVAR("g_domination_default_teams");
 276                 BADCVAR("g_duel");
 277                 BADCVAR("g_duel_not_dm_maps");
 278                 BADCVAR("g_freezetag");
 279                 BADCVAR("g_freezetag_teams");
 280                 BADCVAR("g_invasion_type");
 281                 BADCVAR("g_jailbreak");
 282                 BADCVAR("g_jailbreak_teams");
 283                 BADCVAR("g_keepaway");
 284                 BADCVAR("g_keyhunt");
 285                 BADCVAR("g_keyhunt_teams");
 286                 BADCVAR("g_lms");
 287                 BADCVAR("g_nexball");
 288                 BADCVAR("g_onslaught");
 289                 BADCVAR("g_race");
 290                 BADCVAR("g_race_laps_limit");
 291                 BADCVAR("g_race_qualifying_timelimit");
 292                 BADCVAR("g_race_qualifying_timelimit_override");
 293                 BADCVAR("g_runematch");
 294                 BADCVAR("g_shootfromeye");
 295                 BADCVAR("g_snafu");
 296                 BADCVAR("g_survival");
 297                 BADCVAR("g_survival_not_dm_maps");
 298                 BADCVAR("g_tdm");
 299                 BADCVAR("g_tdm_on_dm_maps");
 300                 BADCVAR("g_tdm_teams");
 301                 BADCVAR("g_vip");
 302                 BADCVAR("leadlimit");
 303                 BADCVAR("nextmap");
 304                 BADCVAR("teamplay");
 305                 BADCVAR("timelimit");
 306                 BADCVAR("g_mapinfo_q3compat");
 307                 BADCVAR("g_mapinfo_settemp_acl");
 308                 BADCVAR("g_mapinfo_ignore_warnings");
 309                 BADCVAR("g_maplist_ignore_sizes");
 310                 BADCVAR("g_maplist_sizes_count_bots");
 311
 312                 // long
 313                 BADCVAR("hostname");
 314                 BADCVAR("g_maplist");
 315                 BADCVAR("g_maplist_mostrecent");
 316                 BADCVAR("sv_motd");
 317                 BADCVAR("sv_termsofservice_url");
 318
 319                 v = cvar_string(k);
 320                 d = cvar_defstring(k);
 321                 if(v == d)
 322                         continue;
 323
 324                 if(adding)
 325                 {
 326                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 327                         if(strlen(cvar_changes) > 16384)
 328                         {
 329                                 cvar_changes = "// too many settings have been changed to show them here\n";
 330                                 adding = 0;
 331                         }
 332                 }
 333
 334                 // now check if the changes are actually gameplay relevant
 335
 336                 // does nothing gameplay relevant
 337                 BADCVAR("captureleadlimit_override");
 338                 BADCVAR("condump_stripcolors");
 339                 BADCVAR("fs_gamedir");
 340                 BADCVAR("g_allow_oldvortexbeam");
 341                 BADCVAR("g_balance_kill_delay");
 342                 BADCVAR("g_buffs_pickup_anyway");
 343                 BADCVAR("g_buffs_randomize");
 344                 BADCVAR("g_buffs_randomize_teamplay");
 345                 BADCVAR("g_campcheck_distance");
 346                 BADCVAR("g_chatsounds");
 347                 BADCVAR("g_ca_point_leadlimit");
 348                 BADCVAR("g_ca_point_limit");
 349                 BADCVAR("g_ca_spectate_enemies");
 350                 BADCVAR("g_ctf_captimerecord_always");
 351                 BADCVAR("g_ctf_flag_glowtrails");
 352                 BADCVAR("g_ctf_dynamiclights");
 353                 BADCVAR("g_ctf_flag_pickup_verbosename");
 354                 BADCVAR("g_ctf_flagcarrier_auto_helpme_damage");
 355                 BADPRESUFFIX("g_ctf_flag_", "_model");
 356                 BADPRESUFFIX("g_ctf_flag_", "_skin");
 357                 BADCVAR("g_domination_point_leadlimit");
 358                 BADCVAR("g_forced_respawn");
 359                 BADCVAR("g_freezetag_point_leadlimit");
 360                 BADCVAR("g_freezetag_point_limit");
 361                 BADCVAR("g_glowtrails");
 362                 BADCVAR("g_hats");
 363                 BADCVAR("g_casings");
 364                 BADCVAR("g_invasion_point_limit");
 365                 BADCVAR("g_jump_grunt");
 366                 BADCVAR("g_keepaway_ballcarrier_effects");
 367                 BADCVAR("g_keepawayball_effects");
 368                 BADCVAR("g_keyhunt_point_leadlimit");
 369                 BADCVAR("g_nexball_goalleadlimit");
 370                 BADCVAR("g_new_toys_autoreplace");
 371                 BADCVAR("g_new_toys_use_pickupsound");
 372                 BADCVAR("g_physics_predictall");
 373                 BADCVAR("g_piggyback");
 374                 BADCVAR("g_playerclip_collisions");
 375                 BADCVAR("g_spawn_alloweffects");
 376                 BADCVAR("g_tdm_point_leadlimit");
 377                 BADCVAR("g_tdm_point_limit");
 378                 BADCVAR("leadlimit_and_fraglimit");
 379                 BADCVAR("leadlimit_override");
 380                 BADCVAR("pausable");
 381                 BADCVAR("sv_announcer");
 382                 BADCVAR("sv_checkforpacketsduringsleep");
 383                 BADCVAR("sv_damagetext");
 384                 BADCVAR("sv_db_saveasdump");
 385                 BADCVAR("sv_intermission_cdtrack");
 386                 BADCVAR("sv_mapchange_delay");
 387                 BADCVAR("sv_minigames");
 388                 BADCVAR("sv_namechangetimer");
 389                 BADCVAR("sv_precacheplayermodels");
 390                 BADCVAR("sv_qcphysics");
 391                 BADCVAR("sv_radio");
 392                 BADCVAR("sv_stepheight");
 393                 BADCVAR("sv_timeout");
 394                 BADCVAR("sv_weapons_modeloverride");
 395                 BADCVAR("w_prop_interval");
 396                 BADPREFIX("chat_");
 397                 BADPREFIX("crypto_");
 398                 BADPREFIX("gameversion");
 399                 BADPREFIX("g_chat_");
 400                 BADPREFIX("g_ctf_captimerecord_");
 401                 BADPREFIX("g_hats_");
 402                 BADPREFIX("g_maplist_");
 403                 BADPREFIX("g_mod_");
 404                 BADPREFIX("g_respawn_");
 405                 BADPREFIX("net_");
 406                 BADPREFIX("notification_");
 407                 BADPREFIX("prvm_");
 408                 BADPREFIX("skill_");
 409                 BADPREFIX("sv_allow_");
 410                 BADPREFIX("sv_cullentities_");
 411                 BADPREFIX("sv_maxidle");
 412                 BADPREFIX("sv_minigames_");
 413                 BADPREFIX("sv_radio_");
 414                 BADPREFIX("sv_timeout_");
 415                 BADPREFIX("sv_vote_");
 416                 BADPREFIX("timelimit_");
 417                 BADPRESUFFIX("g_", "_round_timelimit");
 418
 419                 // allowed changes to server admins (please sync this to server.cfg)
 420                 // vi commands:
 421                 //   :/"impure"/,$d
 422                 //   :g!,^\/\/[^ /],d
 423                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 424                 //   :%!sort
 425                 // yes, this does contain some redundant stuff, don't really care
 426                 BADPREFIX("bot_ai_");
 427                 BADCVAR("bot_config_file");
 428                 BADCVAR("bot_number");
 429                 BADCVAR("bot_prefix");
 430                 BADCVAR("bot_suffix");
 431                 BADCVAR("capturelimit_override");
 432                 BADCVAR("fraglimit_override");
 433                 BADCVAR("gametype");
 434                 BADCVAR("g_antilag");
 435                 BADCVAR("g_balance_teams");
 436                 BADCVAR("g_balance_teams_prevent_imbalance");
 437                 BADCVAR("g_balance_teams_scorefactor");
 438                 BADCVAR("g_ban_sync_trusted_servers");
 439                 BADCVAR("g_ban_sync_uri");
 440                 BADCVAR("g_buffs");
 441                 BADCVAR("g_ca_teams_override");
 442                 BADCVAR("g_ctf_fullbrightflags");
 443                 BADCVAR("g_ctf_ignore_frags");
 444                 BADCVAR("g_ctf_leaderboard");
 445                 BADCVAR("g_domination_point_limit");
 446                 BADCVAR("g_domination_teams_override");
 447                 BADCVAR("g_freezetag_revive_spawnshield");
 448                 BADCVAR("g_freezetag_teams_override");
 449                 BADCVAR("g_friendlyfire");
 450                 BADCVAR("g_fullbrightitems");
 451                 BADCVAR("g_fullbrightplayers");
 452                 BADCVAR("g_keyhunt_point_limit");
 453                 BADCVAR("g_keyhunt_teams_override");
 454                 BADCVAR("g_lms_lives_override");
 455                 BADCVAR("g_maplist");
 456                 BADCVAR("g_maxplayers");
 457                 BADCVAR("g_mirrordamage");
 458                 BADCVAR("g_nexball_goallimit");
 459                 BADCVAR("g_norecoil");
 460                 BADCVAR("g_physics_clientselect");
 461                 BADCVAR("g_pinata");
 462                 BADCVAR("g_powerups");
 463                 BADCVAR("g_powerups_drop_ondeath");
 464                 BADCVAR("g_player_brightness");
 465                 BADCVAR("g_rocket_flying");
 466                 BADCVAR("g_rocket_flying_disabledelays");
 467                 BADPREFIX("g_spawnshield");
 468                 BADCVAR("g_start_delay");
 469                 BADCVAR("g_superspectate");
 470                 BADCVAR("g_tdm_teams_override");
 471                 BADCVAR("g_warmup");
 472                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 473                 BADCVAR("hostname");
 474                 BADCVAR("log_file");
 475                 BADCVAR("maxplayers");
 476                 BADCVAR("minplayers");
 477                 BADCVAR("minplayers_per_team");
 478                 BADCVAR("net_address");
 479                 BADCVAR("port");
 480                 BADCVAR("rcon_password");
 481                 BADCVAR("rcon_restricted_commands");
 482                 BADCVAR("rcon_restricted_password");
 483                 BADCVAR("skill");
 484                 BADCVAR("sv_adminnick");
 485                 BADCVAR("sv_autoscreenshot");
 486                 BADCVAR("sv_autotaunt");
 487                 BADCVAR("sv_curl_defaulturl");
 488                 BADCVAR("sv_defaultcharacter");
 489                 BADCVAR("sv_defaultcharacterskin");
 490                 BADCVAR("sv_defaultplayercolors");
 491                 BADCVAR("sv_defaultplayermodel");
 492                 BADCVAR("sv_defaultplayerskin");
 493                 BADCVAR("sv_maxrate");
 494                 BADCVAR("sv_motd");
 495                 BADCVAR("sv_public");
 496                 BADCVAR("sv_showfps");
 497                 BADCVAR("sv_showspectators");
 498                 BADCVAR("sv_status_privacy");
 499                 BADCVAR("sv_taunt");
 500                 BADCVAR("sv_vote_call");
 501                 BADCVAR("sv_vote_commands");
 502                 BADCVAR("sv_vote_majority_factor");
 503                 BADCVAR("sv_vote_master");
 504                 BADCVAR("sv_vote_master_commands");
 505                 BADCVAR("sv_vote_master_password");
 506                 BADCVAR("sv_vote_simple_majority_factor");
 507                 BADVALUE("sys_ticrate", "0.0166667");
 508                 BADVALUE("sys_ticrate", "0.0333333");
 509                 BADCVAR("teamplay_mode");
 510                 BADCVAR("timelimit_override");
 511                 BADPREFIX("g_warmup_");
 512                 BADPREFIX("sv_info_");
 513                 BADPREFIX("sv_ready_restart_");
 514
 515                 // mutators that announce themselves properly to the server browser
 516                 BADCVAR("g_instagib");
 517                 BADCVAR("g_new_toys");
 518                 BADCVAR("g_nix");
 519                 BADCVAR("g_grappling_hook");
 520                 BADCVAR("g_jetpack");
 521
 522 #undef BADPRESUFFIX
 523 #undef BADPREFIX
 524 #undef BADCVAR
 525 #undef BADVALUE
 526
 527                 if(pureadding)
 528                 {
 529                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 530                         if(strlen(cvar_purechanges) > 16384)
 531                         {
 532                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 533                                 pureadding = 0;
 534                         }
 535                 }
 536                 ++cvar_purechanges_count;
 537                 // WARNING: this variable is used for the server list
 538                 // NEVER dare to skip this code!
 539                 // Hacks to intentionally appearing as "pure server" even though you DO have
 540                 // modified settings may be punished by removal from the server list.
 541                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 542                 // though.
 543         }
 544         buf_del(h);
 545         if(cvar_changes == "")
 546                 cvar_changes = "// this server runs at default server settings\n";
 547         else
 548                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 549         cvar_changes = strzone(cvar_changes);
 550         if(cvar_purechanges == "")
 551                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 552         else
 553                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 554         cvar_purechanges = strzone(cvar_purechanges);
 555 }
 556
 557 entity randomseed;
 558 bool RandomSeed_Send(entity this, entity to, int sf)
 559 {
 560         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 561         WriteShort(MSG_ENTITY, this.cnt);
 562         return true;
 563 }
 564 void RandomSeed_Think(entity this)
 565 {
 566         this.cnt = bound(0, floor(random() * 65536), 65535);
 567         this.nextthink = time + 5;
 568
 569         this.SendFlags |= 1;
 570 }
 571 void RandomSeed_Spawn()
 572 {
 573         randomseed = new_pure(randomseed);
 574         setthink(randomseed, RandomSeed_Think);
 575         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 576
 577         getthink(randomseed)(randomseed); // sets random seed and nextthink
 578 }
 579
 580 spawnfunc(__init_dedicated_server)
 581 {
 582         // handler for _init/_init map (only for dedicated server initialization)
 583
 584         world_initialized = -1; // don't complain
 585
 586         delete_fn = remove_unsafely;
 587
 588         entity e = new(GotoFirstMap);
 589         setthink(e, GotoFirstMap);
 590         e.nextthink = time; // this is usually 1 at this point
 591
 592         e = new(info_player_deathmatch);  // safeguard against player joining
 593
 594     // assign reflectively to avoid "assignment to world" warning
 595     for (int i = 0, n = numentityfields(); i < n; ++i) {
 596         string k = entityfieldname(i);
 597         if (k == "classname") {
 598             // safeguard against various stuff ;)
 599             putentityfieldstring(i, this, "worldspawn");
 600             break;
 601         }
 602     }
 603
 604         // needs to be done so early because of the constants they create
 605         static_init();
 606         static_init_late();
 607         static_init_precache();
 608
 609         IL_PUSH(g_spawnpoints, e); // just incase
 610
 611         MapInfo_Enumerate();
 612         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 613 }
 614
 615 void __init_dedicated_server_shutdown() {
 616         MapInfo_Shutdown();
 617 }
 618
 619 STATIC_INIT_EARLY(maxclients)
 620 {
 621         maxclients = 0;
 622         for (entity head = nextent(NULL); head; head = nextent(head)) {
 623                 ++maxclients;
 624         }
 625 }
 626
 627 void GameplayMode_DelayedInit(entity this)
 628 {
 629         if(!scores_initialized)
 630                 ScoreRules_generic();
 631 }
 632
 633 void InitGameplayMode()
 634 {
 635         VoteReset();
 636
 637         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 638         get_mi_min_max(1);
 639         // assign reflectively to avoid "assignment to world" warning
 640         int done = 0; for (int i = 0, n = numentityfields(); i < n; ++i) {
 641             string k = entityfieldname(i); vector v = (k == "mins") ? mi_min : (k == "maxs") ? mi_max : '0 0 0';
 642             if (v) {
 643             putentityfieldstring(i, world, sprintf("%v", v));
 644             if (++done == 2) break;
 645         }
 646         }
 647         // currently, NetRadiant's limit is 131072 qu for each side
 648         // distance from one corner of a 131072qu cube to the opposite corner is approx. 227023 qu
 649         // set the distance according to map size but don't go over the limit to avoid issues with float precision
 650         // in case somebody makes extremely large maps
 651         max_shot_distance = min(230000, vlen(world.maxs - world.mins));
 652
 653         MapInfo_LoadMapSettings(mapname);
 654         GameRules_teams(false);
 655
 656         if (!cvar_value_issafe(world.fog))
 657         {
 658                 LOG_INFO("The current map contains a potentially harmful fog setting, ignored");
 659                 world.fog = string_null;
 660         }
 661         if(MapInfo_Map_fog != "")
 662         {
 663                 if(MapInfo_Map_fog == "none")
 664                         world.fog = string_null;
 665                 else
 666                         world.fog = strzone(MapInfo_Map_fog);
 667         }
 668         clientstuff = strzone(MapInfo_Map_clientstuff);
 669
 670         MapInfo_ClearTemps();
 671
 672         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
 673
 674         cache_mutatormsg = strzone("");
 675         cache_lastmutatormsg = strzone("");
 676
 677         InitializeEntity(NULL, GameplayMode_DelayedInit, INITPRIO_GAMETYPE_FALLBACK);
 678 }
 679
 680 bool world_already_spawned;
 681 spawnfunc(worldspawn)
 682 {
 683         cvar_set("_endmatch", "0");
 684         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
 685
 686         if (autocvar_sv_termsofservice_url && autocvar_sv_termsofservice_url != "")
 687         {
 688                 strcpy(sv_termsofservice_url_escaped, strreplace(":", "|", autocvar_sv_termsofservice_url));
 689         }
 690         else
 691         {
 692                 strcpy(sv_termsofservice_url_escaped, "INVALID");
 693         }
 694
 695         bool wantrestart = false;
 696         {
 697                 if (!server_is_dedicated)
 698                 {
 699                         // force unloading of server pk3 files when starting a listen server
 700                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
 701                         // restore csqc_progname too
 702                         string expect = "csprogs.dat";
 703                         wantrestart = cvar_string("csqc_progname") != expect;
 704                         cvar_set("csqc_progname", expect);
 705                 }
 706                 else
 707                 {
 708                         // Try to use versioned csprogs from pk3
 709                         // Only ever use versioned csprogs.dat files on dedicated servers;
 710                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
 711                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
 712                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
 713                         string select = "csprogs.dat";
 714                         if (fexists(pk3csprogs)) select = pk3csprogs;
 715                         if (cvar_string("csqc_progname") != select)
 716                         {
 717                                 cvar_set("csqc_progname", select);
 718                                 wantrestart = true;
 719                         }
 720                         // Check for updates on startup
 721                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
 722                         int sentinel = fopen("progs.txt", FILE_READ);
 723                         if (sentinel >= 0)
 724                         {
 725                                 string switchversion = fgets(sentinel);
 726                                 fclose(sentinel);
 727                                 if (switchversion != "" && switchversion != WATERMARK)
 728                                 {
 729                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s", switchversion);
 730                                         // if it doesn't exist, assume either:
 731                                         //   a) the current program was overwritten
 732                                         //   b) this is a client only update
 733                                         string newprogs = sprintf("progs-%s.dat", switchversion);
 734                                         if (fexists(newprogs))
 735                                         {
 736                                                 cvar_set("sv_progs", newprogs);
 737                                                 wantrestart = true;
 738                                         }
 739                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
 740                                         if (fexists(newcsprogs))
 741                                         {
 742                                                 cvar_set("csqc_progname", newcsprogs);
 743                                                 wantrestart = true;
 744                                         }
 745                                 }
 746                         }
 747                 }
 748                 if (wantrestart)
 749                 {
 750                         LOG_INFO("Restart requested");
 751                         changelevel(mapname);
 752                         // let initialization continue, shutdown depends on it
 753                 }
 754         }
 755
 756         if(world_already_spawned)
 757                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 758         world_already_spawned = true;
 759
 760         delete_fn = remove_safely; // during spawning, watch what you remove!
 761
 762         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 763
 764         // default to RACE_RECORD, can be overwritten by gamemodes
 765         record_type = RACE_RECORD;
 766
 767         // needs to be done so early because of the constants they create
 768         static_init();
 769
 770         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 771
 772         TemporaryDB = db_create();
 773
 774         // 0 normal
 775         lightstyle(0, "m");
 776
 777         // 1 FLICKER (first variety)
 778         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 779
 780         // 2 SLOW STRONG PULSE
 781         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 782
 783         // 3 CANDLE (first variety)
 784         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 785
 786         // 4 FAST STROBE
 787         lightstyle(4, "mamamamamama");
 788
 789         // 5 GENTLE PULSE 1
 790         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 791
 792         // 6 FLICKER (second variety)
 793         lightstyle(6, "nmonqnmomnmomomno");
 794
 795         // 7 CANDLE (second variety)
 796         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 797
 798         // 8 CANDLE (third variety)
 799         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 800
 801         // 9 SLOW STROBE (fourth variety)
 802         lightstyle(9, "aaaaaaaazzzzzzzz");
 803
 804         // 10 FLUORESCENT FLICKER
 805         lightstyle(10, "mmamammmmammamamaaamammma");
 806
 807         // 11 SLOW PULSE NOT FADE TO BLACK
 808         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 809
 810         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 811
 812         // 63 testing
 813         lightstyle(63, "a");
 814
 815         if(autocvar_g_campaign)
 816                 CampaignPreInit();
 817         else
 818                 PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 819
 820         Map_MarkAsRecent(mapname);
 821
 822         InitGameplayMode();
 823         static_init_late();
 824         static_init_precache();
 825         readlevelcvars();
 826
 827         GameRules_limit_fallbacks();
 828
 829         if(warmup_limit == 0)
 830                 warmup_limit = (autocvar_timelimit > 0) ? autocvar_timelimit * 60 : autocvar_timelimit;
 831
 832         player_count = 0;
 833         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 834         if(bot_waypoints_for_items == 1)
 835                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 836                         bot_waypoints_for_items = 0;
 837
 838         WaypointSprite_Init();
 839
 840         // NOTE for matchid:
 841         // changing the logic generating it is okay. But:
 842         // it HAS to stay <= 64 chars
 843         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 844         // strftime(false, "%s") isn't reliable, see strftime_s description
 845         matchid = strzone(sprintf("%d.%s.%06d", autocvar_sv_eventlog_files_counter, strftime_s(), random() * 1000000));
 846
 847         if(autocvar_sv_eventlog)
 848                 GameLogInit(); // requires matchid to be set
 849
 850         cvar_set("nextmap", "");
 851
 852         SetDefaultAlpha();
 853
 854         if(autocvar_g_campaign)
 855                 CampaignPostInit();
 856
 857         Ban_LoadBans();
 858
 859         MapInfo_Enumerate();
 860         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 861
 862         q3compat = BITSET(q3compat, Q3COMPAT_ARENA, _MapInfo_FindArenaFile(mapname, ".arena") != "");
 863         q3compat = BITSET(q3compat, Q3COMPAT_DEFI, _MapInfo_FindArenaFile(mapname, ".defi") != "");
 864
 865         // quake 3 music support
 866         if(world.music || world.noise)
 867         {
 868                 // prefer .music over .noise
 869                 string chosen_music;
 870                 if(world.music)
 871                         chosen_music = world.music;
 872                 else
 873                         chosen_music = world.noise;
 874
 875                 string newstuff = strcat(clientstuff, "cd loop \"", chosen_music, "\"\n");
 876                 strcpy(clientstuff, newstuff);
 877         }
 878
 879         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 880         {
 881                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 882                 if(fd != -1)
 883                 {
 884                         string s;
 885                         while((s = fgets(fd)))
 886                         {
 887                                 int l = tokenize_console(s);
 888                                 if(l < 2)
 889                                         continue;
 890                                 if(argv(0) == "cd")
 891                                 {
 892                                         string trackname = argv(2);
 893                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:");
 894                                         LOG_INFO("  cdtrack ", trackname);
 895                                         if (cvar_value_issafe(trackname))
 896                                         {
 897                                                 string newstuff = strcat(clientstuff, "cd loop \"", trackname, "\"\n");
 898                                                 strcpy(clientstuff, newstuff);
 899                                         }
 900                                 }
 901                                 else if(argv(0) == "fog")
 902                                 {
 903                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:");
 904                                         LOG_INFO("  \"fog\" \"", s, "\"");
 905                                 }
 906                                 else if(argv(0) == "set")
 907                                 {
 908                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 909                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2));
 910                                 }
 911                                 else if(argv(0) != "//")
 912                                 {
 913                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 914                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1));
 915                                 }
 916                         }
 917                         fclose(fd);
 918                 }
 919         }
 920
 921         WeaponStats_Init();
 922
 923         Nagger_Init();
 924
 925         // set up information replies for clients and server to use
 926         maplist_reply = strzone(getmaplist());
 927         lsmaps_reply = strzone(getlsmaps());
 928         monsterlist_reply = strzone(getmonsterlist());
 929         bool records_available = false;
 930         for(int i = 0; i < 10; ++i)
 931         {
 932                 string s = getrecords(i);
 933                 if (s != "")
 934                 {
 935                         records_reply[i] = strzone(s);
 936                         records_available = true;
 937                 }
 938         }
 939         if (!records_available)
 940                 records_reply[0] = "No records available for the current game mode.\n";
 941         ladder_reply = strzone(getladder());
 942         rankings_reply = strzone(getrankings());
 943
 944         // begin other init
 945         ClientInit_Spawn();
 946         RandomSeed_Spawn();
 947         PingPLReport_Spawn();
 948
 949         CheatInit();
 950
 951         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 952
 953         // fill sv_curl_serverpackages from .serverpackage files
 954         if (autocvar_sv_curl_serverpackages_auto)
 955         {
 956                 string s = "csprogs-" WATERMARK ".dat";
 957                 // remove automatically managed files from the list to prevent duplicates
 958                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
 959                 {
 960                         string pkg = argv(i);
 961                         if (startsWith(pkg, "csprogs-")) continue;
 962                         if (endsWith(pkg, "-serverpackage.txt")) continue;
 963                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
 964                         s = cons(s, pkg);
 965                 }
 966                 // add automatically managed files to the list
 967                 #define X(match) MACRO_BEGIN \
 968                         int fd = search_begin(match, true, false); \
 969                         if (fd >= 0) \
 970                         { \
 971                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
 972                                 { \
 973                                         s = cons(s, search_getfilename(fd, i)); \
 974                                 } \
 975                                 search_end(fd); \
 976                         } \
 977                 MACRO_END
 978                 X("*-serverpackage.txt");
 979                 X("*.serverpackage");
 980                 #undef X
 981                 cvar_set("sv_curl_serverpackages", s);
 982         }
 983
 984         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 985         modname = "Xonotic";
 986         // physics/balance/config changes that count as mod
 987         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 988                 modname = cvar_string("g_mod_physics");
 989         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance") && cvar_string("g_mod_balance") != "Testing")
 990                 modname = cvar_string("g_mod_balance");
 991         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 992                 modname = cvar_string("g_mod_config");
 993         // extra mutators that deserve to count as mod
 994         MUTATOR_CALLHOOK(SetModname, modname);
 995         modname = M_ARGV(0, string);
 996
 997         // save it for later
 998         modname = strzone(modname);
 999
1000         WinningConditionHelper(this); // set worldstatus
1001
1002         world_initialized = 1;
1003         __spawnfunc_spawn_all();
1004 }
1005
1006 spawnfunc(light)
1007 {
1008         //makestatic (this); // Who the f___ did that?
1009         delete(this);
1010 }
1011
1012 bool MoveToRandomLocationWithinBounds(entity e, vector boundmin, vector boundmax, float goodcontents, float badcontents, float badsurfaceflags, int attempts, float maxaboveground, float minviewdistance, bool frompos)
1013 {
1014     float m = e.dphitcontentsmask;
1015     e.dphitcontentsmask = goodcontents | badcontents;
1016
1017     vector org = boundmin;
1018     vector delta = boundmax - boundmin;
1019
1020     vector start, end;
1021     start = end = org;
1022     int j; // used after the loop
1023     for(j = 0; j < attempts; ++j)
1024     {
1025         start.x = org.x + random() * delta.x;
1026         start.y = org.y + random() * delta.y;
1027         start.z = org.z + random() * delta.z;
1028
1029         // rule 1: start inside world bounds, and outside
1030         // solid, and don't start from somewhere where you can
1031         // fall down to evil
1032         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1033         if (trace_fraction >= 1)
1034             continue;
1035         if (trace_startsolid)
1036             continue;
1037         if (trace_dphitcontents & badcontents)
1038             continue;
1039         if (trace_dphitq3surfaceflags & badsurfaceflags)
1040             continue;
1041
1042         // rule 2: if we are too high, lower the point
1043         if (trace_fraction * delta.z > maxaboveground)
1044             start = trace_endpos + '0 0 1' * maxaboveground;
1045         vector enddown = trace_endpos;
1046
1047         // rule 3: make sure we aren't outside the map. This only works
1048         // for somewhat well formed maps. A good rule of thumb is that
1049         // the map should have a convex outside hull.
1050         // these can be traceLINES as we already verified the starting box
1051         vector mstart = start + 0.5 * (e.mins + e.maxs);
1052         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1053         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1054             continue;
1055         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1056         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1057             continue;
1058         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1059         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1060             continue;
1061         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1062         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1063             continue;
1064         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1065         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1066             continue;
1067
1068                 // rule 4: we must "see" some spawnpoint or item
1069                 entity sp = NULL;
1070                 if(frompos)
1071                 {
1072                         if((traceline(mstart, e.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1073                                 sp = e;
1074                 }
1075                 if(!sp)
1076                 {
1077                         IL_EACH(g_spawnpoints, checkpvs(mstart, it),
1078                         {
1079                                 if((traceline(mstart, it.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1080                                 {
1081                                         sp = it;
1082                                         break;
1083                                 }
1084                         });
1085                 }
1086                 if(!sp)
1087                 {
1088                         int items_checked = 0;
1089                         IL_EACH(g_items, checkpvs(mstart, it),
1090                         {
1091                                 if((traceline(mstart, it.origin + (it.mins + it.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1092                                 {
1093                                         sp = it;
1094                                         break;
1095                                 }
1096
1097                                 ++items_checked;
1098                                 if(items_checked >= attempts)
1099                                         break; // sanity
1100                         });
1101
1102                         if(!sp)
1103                                 continue;
1104                 }
1105
1106         // find a random vector to "look at"
1107         end.x = org.x + random() * delta.x;
1108         end.y = org.y + random() * delta.y;
1109         end.z = org.z + random() * delta.z;
1110         end = start + normalize(end - start) * vlen(delta);
1111
1112         // rule 4: start TO end must not be too short
1113         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1114         if(trace_startsolid)
1115             continue;
1116         if(trace_fraction < minviewdistance / vlen(delta))
1117             continue;
1118
1119         // rule 5: don't want to look at sky
1120         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1121             continue;
1122
1123         // rule 6: we must not end up in trigger_hurt
1124         if(tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1125             continue;
1126
1127         break;
1128     }
1129
1130     e.dphitcontentsmask = m;
1131
1132     if(j < attempts)
1133     {
1134         setorigin(e, start);
1135         e.angles = vectoangles(end - start);
1136         LOG_DEBUG("Needed ", ftos(j + 1), " attempts");
1137         return true;
1138     }
1139     return false;
1140 }
1141
1142 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1143 {
1144         return MoveToRandomLocationWithinBounds(e, world.mins, world.maxs, goodcontents, badcontents, badsurfaceflags, attempts, maxaboveground, minviewdistance, false);
1145 }
1146
1147 /*
1148 ===============================================================================
1149
1150 RULES
1151
1152 ===============================================================================
1153 */
1154
1155 void DumpStats(float final)
1156 {
1157         float file;
1158         string s;
1159         float to_console;
1160         float to_eventlog;
1161         float to_file;
1162         float i;
1163
1164         to_console = autocvar_sv_logscores_console;
1165         to_eventlog = autocvar_sv_eventlog;
1166         to_file = autocvar_sv_logscores_file;
1167
1168         if(!final)
1169         {
1170                 to_console = true; // always print printstats replies
1171                 to_eventlog = false; // but never print them to the event log
1172         }
1173
1174         if(to_eventlog)
1175                 if(autocvar_sv_eventlog_console)
1176                         to_console = false; // otherwise we get the output twice
1177
1178         if(final)
1179                 s = ":scores:";
1180         else
1181                 s = ":status:";
1182         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1183
1184         if(to_console)
1185                 LOG_HELP(s);
1186         if(to_eventlog)
1187                 GameLogEcho(s);
1188
1189         file = -1;
1190         if(to_file)
1191         {
1192                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1193                 if(file == -1)
1194                         to_file = false;
1195                 else
1196                         fputs(file, strcat(s, "\n"));
1197         }
1198
1199         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1200         if(to_console)
1201                 LOG_HELP(s);
1202         if(to_eventlog)
1203                 GameLogEcho(s);
1204         if(to_file)
1205                 fputs(file, strcat(s, "\n"));
1206
1207         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), {
1208                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1209                 s = strcat(s, ftos(rint(time - CS(it).jointime)), ":");
1210                 if(IS_PLAYER(it) || INGAME_JOINED(it))
1211                         s = strcat(s, ftos(it.team), ":");
1212                 else
1213                         s = strcat(s, "spectator:");
1214
1215                 if(to_console)
1216                         LOG_HELP(s, playername(it.netname, it.team, false));
1217                 if(to_eventlog)
1218                         GameLogEcho(strcat(s, ftos(it.playerid), ":", playername(it.netname, it.team, false)));
1219                 if(to_file)
1220                         fputs(file, strcat(s, playername(it.netname, it.team, false), "\n"));
1221         });
1222
1223         if(teamplay)
1224         {
1225                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1226                 if(to_console)
1227                         LOG_HELP(s);
1228                 if(to_eventlog)
1229                         GameLogEcho(s);
1230                 if(to_file)
1231                         fputs(file, strcat(s, "\n"));
1232
1233                 for(i = 1; i < 16; ++i)
1234                 {
1235                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1236                         s = strcat(s, ":", ftos(i));
1237                         if(to_console)
1238                                 LOG_HELP(s);
1239                         if(to_eventlog)
1240                                 GameLogEcho(s);
1241                         if(to_file)
1242                                 fputs(file, strcat(s, "\n"));
1243                 }
1244         }
1245
1246         if(to_console)
1247                 LOG_HELP(":end");
1248         if(to_eventlog)
1249                 GameLogEcho(":end");
1250         if(to_file)
1251         {
1252                 fputs(file, ":end\n");
1253                 fclose(file);
1254         }
1255 }
1256
1257 /*
1258 go to the next level for deathmatch
1259 only called if a time or frag limit has expired
1260 */
1261 void NextLevel()
1262 {
1263         cvar_set("_endmatch", "0");
1264         game_stopped = true;
1265         intermission_running = true; // game over
1266
1267         // enforce a wait time before allowing changelevel
1268         if(player_count > 0)
1269                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1270         else
1271                 intermission_exittime = -1;
1272
1273         /*
1274         WriteByte (MSG_ALL, SVC_CDTRACK);
1275         WriteByte (MSG_ALL, 3);
1276         WriteByte (MSG_ALL, 3);
1277         // done in FixIntermission
1278         */
1279
1280         //pos = FindIntermission ();
1281
1282         VoteReset();
1283
1284         DumpStats(true);
1285
1286         // send statistics
1287         PlayerStats_GameReport(true);
1288         WeaponStats_Shutdown();
1289
1290         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1291
1292         if(autocvar_sv_eventlog)
1293                 GameLogEcho(":gameover");
1294
1295         GameLogClose();
1296
1297         int winner_team = 0;
1298         FOREACH_CLIENT(IS_PLAYER(it) || INGAME(it), {
1299                 FixIntermissionClient(it);
1300                 if(it.winning)
1301                 {
1302                         if (teamplay && !winner_team)
1303                         {
1304                                 winner_team = it.team;
1305                                 bprint(Team_ColorCode(winner_team), Team_ColorName_Upper(winner_team), "^7 team wins the match\n");
1306                         }
1307                         bprint(playername(it.netname, it.team, false), " ^7wins\n");
1308                 }
1309         });
1310
1311         target_music_kill();
1312
1313         if(autocvar_g_campaign)
1314                 CampaignPreIntermission();
1315
1316         MUTATOR_CALLHOOK(MatchEnd);
1317
1318         localcmd("\nsv_hook_gameend\n");
1319 }
1320
1321
1322 int InitiateSuddenDeath()
1323 {
1324         // Check first whether normal overtimes could be added before initiating suddendeath mode
1325         // - for this timelimit_overtime needs to be >0 of course
1326         // - also check the winning condition calculated in the previous frame and only add normal overtime
1327         //   again, if at the point at which timelimit would be extended again, still no winner was found
1328         if (!autocvar_g_campaign && checkrules_overtimesadded >= 0
1329                 && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0)
1330                 && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1331         {
1332                 return 1; // need to call InitiateOvertime later
1333         }
1334         else
1335         {
1336                 if(!checkrules_suddendeathend)
1337                 {
1338                         if(autocvar_g_campaign)
1339                         {
1340                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1341                         }
1342                         else
1343                         {
1344                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1345                                 overtimes = -1;
1346                         }
1347                         if(g_race && !g_race_qualifying)
1348                                 race_StartCompleting();
1349                 }
1350                 return 0;
1351         }
1352 }
1353
1354 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1355 {
1356         ++checkrules_overtimesadded;
1357         overtimes = checkrules_overtimesadded;
1358         //add one more overtime by simply extending the timelimit
1359         cvar_set("timelimit", ftos(autocvar_timelimit + autocvar_timelimit_overtime));
1360         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1361 }
1362
1363 float GetWinningCode(float fraglimitreached, float equality)
1364 {
1365         if(autocvar_g_campaign == 1)
1366         {
1367                 if(fraglimitreached)
1368                         return WINNING_YES;
1369                 else
1370                         return WINNING_NO;
1371         }
1372         else
1373         {
1374                 if(equality)
1375                 {
1376                         if(fraglimitreached)
1377                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1378                         else
1379                                 return WINNING_NEVER;
1380                 }
1381                 else
1382                 {
1383                         if(fraglimitreached)
1384                                 return WINNING_YES;
1385                         else
1386                                 return WINNING_NO;
1387                 }
1388         }
1389 }
1390
1391 // set the .winning flag for exactly those players with a given field value
1392 void SetWinners(.float field, float value)
1393 {
1394         FOREACH_CLIENT(IS_PLAYER(it) || INGAME(it), { it.winning = (it.(field) == value); });
1395 }
1396
1397 // set the .winning flag for those players with a given field value
1398 void AddWinners(.float field, float value)
1399 {
1400         FOREACH_CLIENT(IS_PLAYER(it) || INGAME(it), {
1401                 if(it.(field) == value)
1402                         it.winning = 1;
1403         });
1404 }
1405
1406 // clear the .winning flags
1407 void ClearWinners()
1408 {
1409         FOREACH_CLIENT(IS_PLAYER(it) || INGAME(it), { it.winning = 0; });
1410 }
1411
1412 int fragsleft_last;
1413 float WinningCondition_Scores(float limit, float leadlimit)
1414 {
1415         // TODO make everything use THIS winning condition (except LMS)
1416         WinningConditionHelper(NULL);
1417
1418         if(teamplay)
1419         {
1420                 for (int i = 1; i < 5; ++i)
1421                 {
1422                         Team_SetTeamScore(Team_GetTeamFromIndex(i),
1423                                 TeamScore_GetCompareValue(Team_IndexToTeam(i)));
1424                 }
1425         }
1426
1427         ClearWinners();
1428         if(WinningConditionHelper_winner)
1429                 WinningConditionHelper_winner.winning = 1;
1430         if(WinningConditionHelper_winnerteam >= 0)
1431                 SetWinners(team, WinningConditionHelper_winnerteam);
1432
1433         if(WinningConditionHelper_lowerisbetter)
1434         {
1435                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1436                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1437                 limit = -limit;
1438         }
1439
1440         if(WinningConditionHelper_zeroisworst)
1441                 leadlimit = 0; // not supported in this mode
1442
1443         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1444         {
1445                 float fragsleft;
1446                 if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1447                 {
1448                         fragsleft = 1;
1449                 }
1450                 else
1451                 {
1452                         fragsleft = FLOAT_MAX;
1453                         float leadingfragsleft = FLOAT_MAX;
1454                         if (limit)
1455                                 fragsleft = limit - WinningConditionHelper_topscore;
1456                         if (leadlimit)
1457                                 leadingfragsleft = WinningConditionHelper_secondscore + leadlimit - WinningConditionHelper_topscore;
1458
1459                         if (limit && leadlimit && autocvar_leadlimit_and_fraglimit)
1460                                 fragsleft = max(fragsleft, leadingfragsleft);
1461                         else
1462                                 fragsleft = min(fragsleft, leadingfragsleft);
1463                 }
1464
1465                 if (fragsleft_last != fragsleft) // do not announce same remaining frags multiple times
1466                 {
1467                         if (fragsleft == 1)
1468                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1469                         else if (fragsleft == 2)
1470                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1471                         else if (fragsleft == 3)
1472                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1473
1474                         fragsleft_last = fragsleft;
1475                 }
1476         }
1477
1478         bool fraglimit_reached = (limit && WinningConditionHelper_topscore >= limit);
1479         bool leadlimit_reached = (leadlimit && WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1480
1481         bool limit_reached;
1482         // only respect leadlimit_and_fraglimit when both limits are set or the game will never end
1483         if (limit && leadlimit && autocvar_leadlimit_and_fraglimit)
1484                 limit_reached = (fraglimit_reached && leadlimit_reached);
1485         else
1486                 limit_reached = (fraglimit_reached || leadlimit_reached);
1487
1488         return GetWinningCode(
1489                 WinningConditionHelper_topscore && limit_reached,
1490                 WinningConditionHelper_equality
1491         );
1492 }
1493
1494 float WinningCondition_RanOutOfSpawns()
1495 {
1496         if(have_team_spawns <= 0)
1497                 return WINNING_NO;
1498
1499         if(!autocvar_g_spawn_useallspawns)
1500                 return WINNING_NO;
1501
1502         if(!some_spawn_has_been_used)
1503                 return WINNING_NO;
1504
1505         for (int i = 1; i < 5; ++i)
1506         {
1507                 Team_SetTeamScore(Team_GetTeamFromIndex(i), 0);
1508         }
1509
1510         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it),
1511         {
1512                 if (Team_IsValidTeam(it.team))
1513                 {
1514                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1515                 }
1516         });
1517
1518         IL_EACH(g_spawnpoints, true,
1519         {
1520                 if (Team_IsValidTeam(it.team))
1521                 {
1522                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1523                 }
1524         });
1525
1526         ClearWinners();
1527         float team1_score = Team_GetTeamScore(Team_GetTeamFromIndex(1));
1528         float team2_score = Team_GetTeamScore(Team_GetTeamFromIndex(2));
1529         float team3_score = Team_GetTeamScore(Team_GetTeamFromIndex(3));
1530         float team4_score = Team_GetTeamScore(Team_GetTeamFromIndex(4));
1531         if(team1_score + team2_score + team3_score + team4_score == 0)
1532         {
1533                 checkrules_equality = true;
1534                 return WINNING_YES;
1535         }
1536         else if(team1_score + team2_score + team3_score + team4_score == 1)
1537         {
1538                 float t, i;
1539                 if(team1_score)
1540                         t = 1;
1541                 else if(team2_score)
1542                         t = 2;
1543                 else if(team3_score)
1544                         t = 3;
1545                 else // if(team4_score)
1546                         t = 4;
1547                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
1548                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1549                 {
1550                         for (int j = 1; j <= NUM_TEAMS; ++j)
1551                         {
1552                                 if (t == j)
1553                                 {
1554                                         continue;
1555                                 }
1556                                 if (!TeamBalance_IsTeamAllowed(balance, j))
1557                                 {
1558                                         continue;
1559                                 }
1560                                 TeamScore_AddToTeam(Team_IndexToTeam(j), i, -1000);
1561                         }
1562                 }
1563
1564                 AddWinners(team, t);
1565                 return WINNING_YES;
1566         }
1567         else
1568                 return WINNING_NO;
1569 }
1570
1571 /*
1572 ============
1573 CheckRules_World
1574
1575 Exit deathmatch games upon conditions
1576 ============
1577 */
1578 void CheckRules_World()
1579 {
1580         VoteThink();
1581         MapVote_Think();
1582
1583         SetDefaultAlpha();
1584
1585         if (intermission_running) // someone else quit the game already
1586         {
1587                 if(player_count == 0) // Nobody there? Then let's go to the next map
1588                         MapVote_Start();
1589                         // this will actually check the player count in the next frame
1590                         // again, but this shouldn't hurt
1591                 return;
1592         }
1593
1594         float timelimit = autocvar_timelimit * 60;
1595         float fraglimit = autocvar_fraglimit;
1596         float leadlimit = autocvar_leadlimit;
1597         if (leadlimit < 0) leadlimit = 0;
1598
1599         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1600         {
1601                 if(timelimit > 0)
1602                         timelimit = 0; // timelimit is not made for warmup
1603                 if(fraglimit > 0)
1604                         fraglimit = 0; // no fraglimit for now
1605                 leadlimit = 0; // no leadlimit for now
1606         }
1607
1608         if (autocvar__endmatch || timelimit < 0)
1609         {
1610                 // endmatch
1611                 NextLevel();
1612                 return;
1613         }
1614
1615         if(timelimit > 0)
1616                 timelimit += game_starttime;
1617
1618         int overtimes_prev = overtimes;
1619         int wantovertime = 0;
1620
1621         if(checkrules_suddendeathend)
1622         {
1623                 if(!checkrules_suddendeathwarning)
1624                 {
1625                         checkrules_suddendeathwarning = true;
1626                         if(g_race && !g_race_qualifying)
1627                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1628                         else
1629                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1630                 }
1631         }
1632         else
1633         {
1634                 if (timelimit && time >= timelimit)
1635                 {
1636                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1637                         {
1638                                 float totalplayers;
1639                                 float playerswithlaps;
1640                                 float readyplayers;
1641                                 totalplayers = playerswithlaps = readyplayers = 0;
1642                                 FOREACH_CLIENT(IS_PLAYER(it), {
1643                                         ++totalplayers;
1644                                         if(GameRules_scoring_add(it, RACE_FASTEST, 0))
1645                                                 ++playerswithlaps;
1646                                         if(it.ready)
1647                                                 ++readyplayers;
1648                                 });
1649
1650                                 // at least 2 of the players have completed a lap: start the RACE
1651                                 // otherwise, the players should end the qualifying on their own
1652                                 if(readyplayers || playerswithlaps >= 2)
1653                                 {
1654                                         checkrules_suddendeathend = 0;
1655                                         ReadyRestart(true); // go to race
1656                                         return;
1657                                 }
1658                                 else
1659                                         wantovertime |= InitiateSuddenDeath();
1660                         }
1661                         else
1662                                 wantovertime |= InitiateSuddenDeath();
1663                 }
1664         }
1665
1666         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1667         {
1668                 NextLevel();
1669                 return;
1670         }
1671
1672         int checkrules_status = WinningCondition_RanOutOfSpawns();
1673         if(checkrules_status == WINNING_YES)
1674                 bprint("Hey! Someone ran out of spawns!\n");
1675         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1676                 checkrules_status = M_ARGV(0, float);
1677         else
1678                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1679
1680         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1681         {
1682                 checkrules_status = WINNING_NEVER;
1683                 checkrules_overtimesadded = -1;
1684                 wantovertime |= InitiateSuddenDeath();
1685         }
1686
1687         if(checkrules_status == WINNING_NEVER)
1688                 // equality cases! Nobody wins if the overtime ends in a draw.
1689                 ClearWinners();
1690
1691         if(wantovertime)
1692         {
1693                 if(checkrules_status == WINNING_NEVER)
1694                         InitiateOvertime();
1695                 else
1696                         checkrules_status = WINNING_YES;
1697         }
1698
1699         if(checkrules_suddendeathend)
1700                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1701                         checkrules_status = WINNING_YES;
1702
1703         if(checkrules_status == WINNING_YES)
1704         {
1705                 if (overtimes == -1 && overtimes != overtimes_prev)
1706                 {
1707                         // if suddendeathend overtime has just begun, revert it
1708                         checkrules_suddendeathend = 0;
1709                         overtimes = overtimes_prev;
1710                 }
1711                 //print("WINNING\n");
1712                 NextLevel();
1713         }
1714 }
1715
1716 float want_weapon(entity weaponinfo, float allguns)
1717 {
1718         int d = 0;
1719         bool allow_mutatorblocked = false;
1720
1721         if(!weaponinfo.m_id)
1722                 return 0;
1723
1724         bool mutator_returnvalue = MUTATOR_CALLHOOK(WantWeapon, weaponinfo, d, allguns, allow_mutatorblocked);
1725         d = M_ARGV(1, float);
1726         allguns = M_ARGV(2, bool);
1727         allow_mutatorblocked = M_ARGV(3, bool);
1728
1729         if(allguns)
1730                 d = boolean((weaponinfo.spawnflags & WEP_FLAG_NORMAL) && !(weaponinfo.spawnflags & (WEP_FLAG_HIDDEN | WEP_FLAG_SPECIALATTACK)));
1731         else if(!mutator_returnvalue)
1732                 d = !(!weaponinfo.weaponstart);
1733
1734         if(!allow_mutatorblocked && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
1735                 d = 0;
1736
1737         float t = weaponinfo.weaponstartoverride;
1738
1739         //LOG_INFOF("want_weapon: %s - d: %d t: %d\n", weaponinfo.netname, d, t);
1740
1741         // bit order in t:
1742         // 1: want or not
1743         // 2: is default?
1744         // 4: is set by default?
1745         if(t < 0)
1746                 t = 4 | (3 * d);
1747         else
1748                 t |= (2 * d);
1749
1750         return t;
1751 }
1752
1753 /// Weapons the player normally starts with outside weapon arena.
1754 WepSet weapons_start()
1755 {
1756         WepSet ret = '0 0 0';
1757         FOREACH(Weapons, it != WEP_Null, {
1758                 int w = want_weapon(it, false);
1759                 if (w & 1)
1760                         ret |= it.m_wepset;
1761         });
1762         return ret;
1763 }
1764
1765 WepSet weapons_all()
1766 {
1767         WepSet ret = '0 0 0';
1768         FOREACH(Weapons, it != WEP_Null, {
1769                 if (!(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_SPECIALATTACK)))
1770                         ret |= it.m_wepset;
1771         });
1772         return ret;
1773 }
1774
1775 WepSet weapons_devall()
1776 {
1777         WepSet ret = '0 0 0';
1778         FOREACH(Weapons, it != WEP_Null,
1779         {
1780                 ret |= it.m_wepset;
1781         });
1782         return ret;
1783 }
1784
1785 WepSet weapons_most()
1786 {
1787         WepSet ret = '0 0 0';
1788         FOREACH(Weapons, it != WEP_Null, {
1789                 if ((it.spawnflags & WEP_FLAG_NORMAL) && !(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_HIDDEN | WEP_FLAG_SPECIALATTACK)))
1790                         ret |= it.m_wepset;
1791         });
1792         return ret;
1793 }
1794
1795 void weaponarena_available_all_update(entity this)
1796 {
1797         if (weaponsInMapAll)
1798         {
1799                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | (weaponsInMapAll & weapons_all());
1800         }
1801         else
1802         {
1803                 // if no weapons are available on the map, just fall back to all weapons arena
1804                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_all();
1805         }
1806 }
1807
1808 void weaponarena_available_devall_update(entity this)
1809 {
1810         if (weaponsInMapAll)
1811         {
1812                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | weaponsInMapAll;
1813         }
1814         else
1815         {
1816                 // if no weapons are available on the map, just fall back to devall weapons arena
1817                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_devall();
1818         }
1819 }
1820
1821 void weaponarena_available_most_update(entity this)
1822 {
1823         if (weaponsInMapAll)
1824         {
1825                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | (weaponsInMapAll & weapons_most());
1826         }
1827         else
1828         {
1829                 // if no weapons are available on the map, just fall back to most weapons arena
1830                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_most();
1831         }
1832 }
1833
1834 void readplayerstartcvars()
1835 {
1836         // initialize starting values for players
1837         start_weapons = '0 0 0';
1838         start_weapons_default = '0 0 0';
1839         start_weapons_defaultmask = '0 0 0';
1840         start_items = 0;
1841         start_ammo_shells = 0;
1842         start_ammo_nails = 0;
1843         start_ammo_rockets = 0;
1844         start_ammo_cells = 0;
1845         start_ammo_plasma = 0;
1846         if (random_start_ammo == NULL)
1847         {
1848                 random_start_ammo = new_pure(random_start_ammo);
1849         }
1850         start_health = cvar("g_balance_health_start");
1851         start_armorvalue = cvar("g_balance_armor_start");
1852
1853         g_weaponarena = 0;
1854         g_weaponarena_weapons = '0 0 0';
1855
1856         string s = cvar_string("g_weaponarena");
1857
1858         MUTATOR_CALLHOOK(SetWeaponArena, s);
1859         s = M_ARGV(0, string);
1860
1861         if (s == "0" || s == "")
1862         {
1863                 // no arena
1864         }
1865         else if (s == "off")
1866         {
1867                 // forcibly turn off weaponarena
1868         }
1869         else if (s == "all" || s == "1")
1870         {
1871                 g_weaponarena = 1;
1872                 g_weaponarena_list = "All Weapons Arena";
1873                 g_weaponarena_weapons = weapons_all();
1874         }
1875         else if (s == "devall")
1876         {
1877                 g_weaponarena = 1;
1878                 g_weaponarena_list = "Dev All Weapons Arena";
1879                 g_weaponarena_weapons = weapons_devall();
1880         }
1881         else if (s == "most")
1882         {
1883                 g_weaponarena = 1;
1884                 g_weaponarena_list = "Most Weapons Arena";
1885                 g_weaponarena_weapons = weapons_most();
1886         }
1887         else if (s == "all_available")
1888         {
1889                 g_weaponarena = 1;
1890                 g_weaponarena_list = "All Available Weapons Arena";
1891
1892                 // this needs to run after weaponsInMapAll is initialized
1893                 InitializeEntity(NULL, weaponarena_available_all_update, INITPRIO_FINDTARGET);
1894         }
1895         else if (s == "devall_available")
1896         {
1897                 g_weaponarena = 1;
1898                 g_weaponarena_list = "Dev All Available Weapons Arena";
1899
1900                 // this needs to run after weaponsInMapAll is initialized
1901                 InitializeEntity(NULL, weaponarena_available_devall_update, INITPRIO_FINDTARGET);
1902         }
1903         else if (s == "most_available")
1904         {
1905                 g_weaponarena = 1;
1906                 g_weaponarena_list = "Most Available Weapons Arena";
1907
1908                 // this needs to run after weaponsInMapAll is initialized
1909                 InitializeEntity(NULL, weaponarena_available_most_update, INITPRIO_FINDTARGET);
1910         }
1911         else if (s == "none")
1912         {
1913                 g_weaponarena = 1;
1914                 g_weaponarena_list = "No Weapons Arena";
1915         }
1916         else
1917         {
1918                 g_weaponarena = 1;
1919                 float t = tokenize_console(s);
1920                 g_weaponarena_list = "";
1921                 for (int j = 0; j < t; ++j)
1922                 {
1923                         s = argv(j);
1924                         Weapon wep = Weapon_from_name(s);
1925                         if(wep != WEP_Null)
1926                         {
1927                                 g_weaponarena_weapons |= (wep.m_wepset);
1928                                 g_weaponarena_list = strcat(g_weaponarena_list, wep.netname, " & ");
1929                         }
1930                 }
1931                 if (g_weaponarena_list != "") // remove trailing " & "
1932                         g_weaponarena_list = substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3);
1933                 else // no valid weapon found
1934                         g_weaponarena_list = "No Weapons Arena";
1935         }
1936
1937         if (g_weaponarena)
1938         {
1939                 g_weapon_stay = 0; // incompatible
1940                 start_weapons = g_weaponarena_weapons;
1941                 start_items |= IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS;
1942                 g_weaponarena_list = strzone(g_weaponarena_list);
1943         }
1944         else
1945         {
1946                 FOREACH(Weapons, it != WEP_Null, {
1947                         int w = want_weapon(it, false);
1948                         WepSet s = it.m_wepset;
1949                         if(w & 1)
1950                                 start_weapons |= s;
1951                         if(w & 2)
1952                                 start_weapons_default |= s;
1953                         if(w & 4)
1954                                 start_weapons_defaultmask |= s;
1955                 });
1956         }
1957
1958         if(cvar("g_balance_superweapons_time") < 0)
1959                 start_items |= IT_UNLIMITED_SUPERWEAPONS;
1960
1961         if(!cvar("g_use_ammunition"))
1962                 start_items |= IT_UNLIMITED_AMMO;
1963
1964         if(start_items & IT_UNLIMITED_AMMO)
1965         {
1966                 start_ammo_shells = 999;
1967                 start_ammo_nails = 999;
1968                 start_ammo_rockets = 999;
1969                 start_ammo_cells = 999;
1970                 start_ammo_plasma = 999;
1971                 start_ammo_fuel = 999;
1972         }
1973         else
1974         {
1975                 start_ammo_shells = cvar("g_start_ammo_shells");
1976                 start_ammo_nails = cvar("g_start_ammo_nails");
1977                 start_ammo_rockets = cvar("g_start_ammo_rockets");
1978                 start_ammo_cells = cvar("g_start_ammo_cells");
1979                 start_ammo_plasma = cvar("g_start_ammo_plasma");
1980                 start_ammo_fuel = cvar("g_start_ammo_fuel");
1981                 random_start_weapons_count = cvar("g_random_start_weapons_count");
1982                 SetResource(random_start_ammo, RES_SHELLS, cvar("g_random_start_shells"));
1983                 SetResource(random_start_ammo, RES_BULLETS, cvar("g_random_start_bullets"));
1984                 SetResource(random_start_ammo, RES_ROCKETS, cvar("g_random_start_rockets"));
1985                 SetResource(random_start_ammo, RES_CELLS, cvar("g_random_start_cells"));
1986                 SetResource(random_start_ammo, RES_PLASMA, cvar("g_random_start_plasma"));
1987         }
1988
1989         warmup_start_ammo_shells = start_ammo_shells;
1990         warmup_start_ammo_nails = start_ammo_nails;
1991         warmup_start_ammo_rockets = start_ammo_rockets;
1992         warmup_start_ammo_cells = start_ammo_cells;
1993         warmup_start_ammo_plasma = start_ammo_plasma;
1994         warmup_start_ammo_fuel = start_ammo_fuel;
1995         warmup_start_health = start_health;
1996         warmup_start_armorvalue = start_armorvalue;
1997         warmup_start_weapons = start_weapons;
1998         warmup_start_weapons_default = start_weapons_default;
1999         warmup_start_weapons_defaultmask = start_weapons_defaultmask;
2000
2001         if (!g_weaponarena)
2002         {
2003                 warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
2004                 warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
2005                 warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
2006                 warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
2007                 warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
2008                 warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
2009                 warmup_start_health = cvar("g_warmup_start_health");
2010                 warmup_start_armorvalue = cvar("g_warmup_start_armor");
2011                 warmup_start_weapons = '0 0 0';
2012                 warmup_start_weapons_default = '0 0 0';
2013                 warmup_start_weapons_defaultmask = '0 0 0';
2014                 FOREACH(Weapons, it != WEP_Null, {
2015                         int w = want_weapon(it, autocvar_g_warmup_allguns);
2016                         WepSet s = it.m_wepset;
2017                         if(w & 1)
2018                                 warmup_start_weapons |= s;
2019                         if(w & 2)
2020                                 warmup_start_weapons_default |= s;
2021                         if(w & 4)
2022                                 warmup_start_weapons_defaultmask |= s;
2023                 });
2024         }
2025
2026         if (autocvar_g_jetpack)
2027                 start_items |= ITEM_Jetpack.m_itemid;
2028
2029         MUTATOR_CALLHOOK(SetStartItems);
2030
2031         if (start_items & ITEM_Jetpack.m_itemid)
2032         {
2033                 start_items |= ITEM_JetpackRegen.m_itemid;
2034                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
2035                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
2036         }
2037
2038         start_ammo_shells = max(0, start_ammo_shells);
2039         start_ammo_nails = max(0, start_ammo_nails);
2040         start_ammo_rockets = max(0, start_ammo_rockets);
2041         start_ammo_cells = max(0, start_ammo_cells);
2042         start_ammo_plasma = max(0, start_ammo_plasma);
2043         start_ammo_fuel = max(0, start_ammo_fuel);
2044         SetResource(random_start_ammo, RES_SHELLS, max(0, GetResource(random_start_ammo, RES_SHELLS)));
2045         SetResource(random_start_ammo, RES_BULLETS, max(0, GetResource(random_start_ammo, RES_BULLETS)));
2046         SetResource(random_start_ammo, RES_ROCKETS, max(0, GetResource(random_start_ammo, RES_ROCKETS)));
2047         SetResource(random_start_ammo, RES_CELLS, max(0, GetResource(random_start_ammo, RES_CELLS)));
2048         SetResource(random_start_ammo, RES_PLASMA, max(0, GetResource(random_start_ammo, RES_PLASMA)));
2049
2050         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
2051         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
2052         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
2053         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
2054         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
2055         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
2056 }
2057
2058 void readlevelcvars()
2059 {
2060         if(cvar("sv_allow_fullbright"))
2061                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
2062
2063         sv_ready_restart_after_countdown = cvar("sv_ready_restart_after_countdown");
2064
2065         warmup_stage = cvar("g_warmup");
2066         warmup_limit = cvar("g_warmup_limit");
2067
2068         if(cvar("g_campaign"))
2069                 warmup_stage = 0; // no warmup during campaign
2070
2071         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
2072         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
2073         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
2074         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
2075         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
2076         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
2077         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
2078         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
2079         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
2080         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
2081         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
2082         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
2083         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
2084         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
2085
2086         g_pickup_shells = cvar("g_pickup_shells");
2087         g_pickup_shells_max = cvar("g_pickup_shells_max");
2088         g_pickup_nails = cvar("g_pickup_nails");
2089         g_pickup_nails_max = cvar("g_pickup_nails_max");
2090         g_pickup_rockets = cvar("g_pickup_rockets");
2091         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
2092         g_pickup_cells = cvar("g_pickup_cells");
2093         g_pickup_cells_max = cvar("g_pickup_cells_max");
2094         g_pickup_plasma = cvar("g_pickup_plasma");
2095         g_pickup_plasma_max = cvar("g_pickup_plasma_max");
2096         g_pickup_fuel = cvar("g_pickup_fuel");
2097         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
2098         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
2099         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
2100         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
2101         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
2102         g_pickup_armormedium = cvar("g_pickup_armormedium");
2103         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
2104         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
2105         g_pickup_armorbig = cvar("g_pickup_armorbig");
2106         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
2107         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
2108         g_pickup_armormega = cvar("g_pickup_armormega");
2109         g_pickup_armormega_max = cvar("g_pickup_armormega_max");
2110         g_pickup_armormega_anyway = cvar("g_pickup_armormega_anyway");
2111         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
2112         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
2113         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
2114         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
2115         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
2116         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
2117         g_pickup_healthbig = cvar("g_pickup_healthbig");
2118         g_pickup_healthbig_max = cvar("g_pickup_healthbig_max");
2119         g_pickup_healthbig_anyway = cvar("g_pickup_healthbig_anyway");
2120         g_pickup_healthmega = cvar("g_pickup_healthmega");
2121         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
2122         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
2123
2124         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
2125         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
2126
2127     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
2128     if(!g_weapon_stay)
2129         g_weapon_stay = cvar("g_weapon_stay");
2130
2131     MUTATOR_CALLHOOK(ReadLevelCvars);
2132
2133         if (!warmup_stage && !autocvar_g_campaign)
2134                 game_starttime = time + cvar("g_start_delay");
2135
2136         FOREACH(Weapons, it != WEP_Null, { it.wr_init(it); });
2137
2138         readplayerstartcvars();
2139 }
2140
2141 void InitializeEntity(entity e, void(entity this) func, int order)
2142 {
2143     entity prev, cur;
2144
2145     if (!e || e.initialize_entity)
2146     {
2147         // make a proxy initializer entity
2148         entity e_old = e;
2149         e = new(initialize_entity);
2150         e.enemy = e_old;
2151     }
2152
2153     e.initialize_entity = func;
2154     e.initialize_entity_order = order;
2155
2156     cur = initialize_entity_first;
2157     prev = NULL;
2158     for (;;)
2159     {
2160         if (!cur || cur.initialize_entity_order > order)
2161         {
2162             // insert between prev and cur
2163             if (prev)
2164                 prev.initialize_entity_next = e;
2165             else
2166                 initialize_entity_first = e;
2167             e.initialize_entity_next = cur;
2168             return;
2169         }
2170         prev = cur;
2171         cur = cur.initialize_entity_next;
2172     }
2173 }
2174 void InitializeEntitiesRun()
2175 {
2176     entity startoflist = initialize_entity_first;
2177     initialize_entity_first = NULL;
2178     delete_fn = remove_except_protected;
2179     for (entity e = startoflist; e; e = e.initialize_entity_next)
2180     {
2181                 e.remove_except_protected_forbidden = 1;
2182     }
2183     for (entity e = startoflist; e; )
2184     {
2185                 e.remove_except_protected_forbidden = 0;
2186         e.initialize_entity_order = 0;
2187         entity next = e.initialize_entity_next;
2188         e.initialize_entity_next = NULL;
2189         var void(entity this) func = e.initialize_entity;
2190         e.initialize_entity = func_null;
2191         if (e.classname == "initialize_entity")
2192         {
2193             entity wrappee = e.enemy;
2194             builtin_remove(e);
2195             e = wrappee;
2196         }
2197         //dprint("Delayed initialization: ", e.classname, "\n");
2198         if (func)
2199         {
2200                 func(e);
2201         }
2202         else
2203         {
2204             eprint(e);
2205             backtrace(strcat("Null function in: ", e.classname, "\n"));
2206         }
2207         e = next;
2208     }
2209     delete_fn = remove_unsafely;
2210 }
2211
2212 // deferred dropping
2213 void DropToFloor_Handler(entity this)
2214 {
2215         WITHSELF(this, builtin_droptofloor());
2216         this.dropped_origin = this.origin;
2217 }
2218
2219 void droptofloor(entity this)
2220 {
2221         InitializeEntity(this, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
2222 }
2223
2224 bool autocvar_sv_gameplayfix_multiplethinksperframe = true;
2225 void RunThink(entity this, float dt)
2226 {
2227         // don't let things stay in the past.
2228         // it is possible to start that way by a trigger with a local time.
2229         if(this.nextthink <= 0 || this.nextthink > time + dt)
2230                 return;
2231
2232         float oldtime = time; // do we need to save this?
2233
2234         for (int iterations = 0; iterations < 128 && !wasfreed(this); iterations++)
2235         {
2236                 time = max(oldtime, this.nextthink);
2237                 this.nextthink = 0;
2238
2239                 if(getthink(this))
2240                         getthink(this)(this);
2241                 // mods often set nextthink to time to cause a think every frame,
2242                 // we don't want to loop in that case, so exit if the new nextthink is
2243                 // <= the time the qc was told, also exit if it is past the end of the
2244                 // frame
2245                 if(this.nextthink <= time || this.nextthink > oldtime + dt || !autocvar_sv_gameplayfix_multiplethinksperframe)
2246                         break;
2247         }
2248
2249         time = oldtime;
2250 }
2251
2252 bool autocvar_sv_freezenonclients;
2253 void Physics_Frame()
2254 {
2255         if(autocvar_sv_freezenonclients)
2256                 return;
2257
2258         IL_EACH(g_moveables, true,
2259         {
2260                 if(IS_CLIENT(it) || it.move_movetype == MOVETYPE_PHYSICS)
2261                         continue;
2262
2263                 //set_movetype(it, it.move_movetype);
2264                 // inline the set_movetype function, since this is called a lot
2265                 it.movetype = (it.move_qcphysics) ? MOVETYPE_QCENTITY : it.move_movetype;
2266
2267                 if(it.move_qcphysics && it.move_movetype != MOVETYPE_NONE)
2268                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2269
2270                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
2271                 {
2272                         if(it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH)
2273                                 continue; // these movetypes have no regular think function
2274                         // handle thinking here
2275                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + PHYS_INPUT_TIMELENGTH)
2276                                 RunThink(it, PHYS_INPUT_TIMELENGTH);
2277                 }
2278         });
2279
2280         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2281                 return;
2282
2283         // make a second pass to see if any ents spawned this frame and make
2284         // sure they run their move/think. this is verified by checking .move_time, which will never be 0 if the entity has moved
2285         // MOVETYPE_NONE is also checked as .move_time WILL be 0 with that movetype
2286         IL_EACH(g_moveables, it.move_qcphysics,
2287         {
2288                 if(IS_CLIENT(it) || it.move_time || it.move_movetype == MOVETYPE_NONE || it.move_movetype == MOVETYPE_PHYSICS)
2289                         continue;
2290                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2291         });
2292 }
2293
2294 void systems_update();
2295 void EndFrame()
2296 {
2297         anticheat_endframe();
2298
2299         Physics_Frame();
2300
2301         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2302                 entity e = IS_SPEC(it) ? it.enemy : it;
2303                 if (e.typehitsound) {
2304                         STAT(TYPEHIT_TIME, it) = time;
2305                 } else if (e.killsound) {
2306                         STAT(KILL_TIME, it) = time;
2307                 } else if (e.hitsound_damage_dealt) {
2308                         STAT(HIT_TIME, it) = time;
2309                         // NOTE: this is not accurate as client code doesn't need so much accuracy for its purposes
2310                         STAT(HITSOUND_DAMAGE_DEALT_TOTAL, it) += ceil(e.hitsound_damage_dealt);
2311                 }
2312         });
2313         // add 1 frametime because after this, engine SV_Physics
2314         // increases time by a frametime and then networks the frame
2315         // add another frametime because client shows everything with
2316         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2317         // needed!
2318         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2319         FOREACH_CLIENT(true, {
2320                 it.typehitsound = false;
2321                 it.hitsound_damage_dealt = 0;
2322                 it.killsound = false;
2323                 antilag_record(it, CS(it), altime);
2324         });
2325         IL_EACH(g_monsters, true,
2326         {
2327                 antilag_record(it, it, altime);
2328         });
2329         IL_EACH(g_projectiles, it.classname == "nade",
2330         {
2331                 antilag_record(it, it, altime);
2332         });
2333         systems_update();
2334         IL_ENDFRAME();
2335 }
2336
2337
2338 /*
2339  * RedirectionThink:
2340  * returns true if redirecting
2341  */
2342 float redirection_timeout;
2343 float redirection_nextthink;
2344 float RedirectionThink()
2345 {
2346         float clients_found;
2347
2348         if(redirection_target == "")
2349                 return false;
2350
2351         if(!redirection_timeout)
2352         {
2353                 cvar_set("sv_public", "-2");
2354                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2355                 if(redirection_target == "self")
2356                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2357                 else
2358                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2359         }
2360
2361         if(time < redirection_nextthink)
2362                 return true;
2363
2364         redirection_nextthink = time + 1;
2365
2366         clients_found = 0;
2367         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2368                 // TODO add timer
2369                 LOG_INFO("Redirecting: sending connect command to ", it.netname);
2370                 if(redirection_target == "self")
2371                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2372                 else
2373                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2374                 ++clients_found;
2375         });
2376
2377         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.");
2378
2379         if(time > redirection_timeout || clients_found == 0)
2380                 localcmd("\nwait; wait; wait; quit\n");
2381
2382         return true;
2383 }
2384
2385 void RestoreGame()
2386 {
2387         // Loaded from a save game
2388         // some things then break, so let's work around them...
2389
2390         // Progs DB (capture records)
2391         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2392
2393         // Mapinfo
2394         MapInfo_Shutdown();
2395         MapInfo_Enumerate();
2396         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2397         WeaponStats_Init();
2398
2399         TargetMusic_RestoreGame();
2400 }
2401
2402 void Shutdown()
2403 {
2404         game_stopped = 2;
2405
2406         if(world_initialized > 0)
2407         {
2408                 world_initialized = 0;
2409
2410                 // if a timeout is active, reset the slowmo value to normal
2411                 if(timeout_status == TIMEOUT_ACTIVE)
2412                         cvar_set("slowmo", ftos(orig_slowmo));
2413
2414                 LOG_TRACE("Saving persistent data...");
2415                 Ban_SaveBans();
2416
2417                 // playerstats with unfinished match
2418                 PlayerStats_GameReport(false);
2419
2420                 if(!cheatcount_total)
2421                 {
2422                         if(autocvar_sv_db_saveasdump)
2423                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2424                         else
2425                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2426                 }
2427                 if(autocvar_developer > 0)
2428                 {
2429                         if(autocvar_sv_db_saveasdump)
2430                                 db_dump(TemporaryDB, "server-temp.db");
2431                         else
2432                                 db_save(TemporaryDB, "server-temp.db");
2433                 }
2434                 CheatShutdown(); // must be after cheatcount check
2435                 db_close(ServerProgsDB);
2436                 db_close(TemporaryDB);
2437                 LOG_TRACE("Saving persistent data... done!");
2438                 // tell the bot system the game is ending now
2439                 bot_endgame();
2440
2441                 WeaponStats_Shutdown();
2442                 MapInfo_Shutdown();
2443
2444                 strfree(sv_termsofservice_url_escaped);
2445         }
2446         else if(world_initialized == 0)
2447         {
2448                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data");
2449         }
2450         else
2451         {
2452                 __init_dedicated_server_shutdown();
2453         }
2454 }