qcsrc/server/world.qc

   1 #include "world.qh"
   2
   3 #include <common/constants.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/gamemodes/sv_rules.qh>
   7 #include <common/items/_mod.qh>
   8 #include <common/mapinfo.qh>
   9 #include <common/mapobjects/target/music.qh>
  10 #include <common/mapobjects/trigger/hurt.qh>
  11 #include <common/mapobjects/trigger/secret.qh>
  12 #include <common/mapobjects/triggers.qh>
  13 #include <common/monsters/_mod.qh>
  14 #include <common/monsters/sv_monsters.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/notifications/all.qh>
  17 #include <common/physics/player.qh>
  18 #include <common/playerstats.qh>
  19 #include <common/state.qh>
  20 #include <common/stats.qh>
  21 #include <common/teams.qh>
  22 #include <common/util.qh>
  23 #include <common/vehicles/all.qh>
  24 #include <common/weapons/_all.qh>
  25 #include <server/anticheat.qh>
  26 #include <server/antilag.qh>
  27 #include <server/bot/api.qh>
  28 #include <server/campaign.qh>
  29 #include <server/cheats.qh>
  30 #include <server/client.qh>
  31 #include <server/command/common.qh>
  32 #include <server/command/getreplies.qh>
  33 #include <server/command/sv_cmd.qh>
  34 #include <server/command/vote.qh>
  35 #include <server/damage.qh>
  36 #include <server/gamelog.qh>
  37 #include <server/hook.qh>
  38 #include <server/ipban.qh>
  39 #include <server/items/items.qh>
  40 #include <server/main.qh>
  41 #include <server/mapvoting.qh>
  42 #include <server/mutators/_mod.qh>
  43 #include <server/race.qh>
  44 #include <server/scores.qh>
  45 #include <server/scores_rules.qh>
  46 #include <server/spawnpoints.qh>
  47 #include <server/teamplay.qh>
  48 #include <server/weapons/weaponstats.qh>
  49
  50 const float LATENCY_THINKRATE = 10;
  51 .float latency_sum;
  52 .float latency_cnt;
  53 .float latency_time;
  54 entity pingplreport;
  55 void PingPLReport_Think(entity this)
  56 {
  57         float delta;
  58         entity e;
  59
  60         delta = 3 / maxclients;
  61         if(delta < sys_frametime)
  62                 delta = 0;
  63         this.nextthink = time + delta;
  64
  65         e = edict_num(this.cnt + 1);
  66         if(IS_CLIENT(e) && IS_REAL_CLIENT(e))
  67         {
  68                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  69                 WriteByte(MSG_BROADCAST, this.cnt);
  70                 WriteShort(MSG_BROADCAST, bound(1, rint(CS(e).ping), 32767));
  71                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_packetloss * 255), 255));
  72                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_movementloss * 255), 255));
  73
  74                 // record latency times for clients throughout the match so we can report it to playerstats
  75                 if(time > (CS(e).latency_time + LATENCY_THINKRATE))
  76                 {
  77                         CS(e).latency_sum += CS(e).ping;
  78                         CS(e).latency_cnt += 1;
  79                         CS(e).latency_time = time;
  80                         //print("sum: ", ftos(CS(e).latency_sum), ", cnt: ", ftos(CS(e).latency_cnt), ", avg: ", ftos(CS(e).latency_sum / CS(e).latency_cnt), ".\n");
  81                 }
  82         }
  83         else
  84         {
  85                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  86                 WriteByte(MSG_BROADCAST, this.cnt);
  87                 WriteShort(MSG_BROADCAST, 0);
  88                 WriteByte(MSG_BROADCAST, 0);
  89                 WriteByte(MSG_BROADCAST, 0);
  90         }
  91         this.cnt = (this.cnt + 1) % maxclients;
  92 }
  93 void PingPLReport_Spawn()
  94 {
  95         pingplreport = new_pure(pingplreport);
  96         setthink(pingplreport, PingPLReport_Think);
  97         pingplreport.nextthink = time;
  98 }
  99
 100 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
 101
 102 void SetDefaultAlpha()
 103 {
 104         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
 105         {
 106                 default_player_alpha = autocvar_g_player_alpha;
 107                 if(default_player_alpha == 0)
 108                         default_player_alpha = 1;
 109                 default_weapon_alpha = default_player_alpha;
 110         }
 111 }
 112
 113 void GotoFirstMap(entity this)
 114 {
 115         float n;
 116         if(autocvar__sv_init)
 117         {
 118                 // cvar_set("_sv_init", "0");
 119                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 120                 // to this "init" map on a dedicated server will cause no permanent
 121                 // harm
 122                 if(autocvar_g_maplist_shuffle)
 123                         ShuffleMaplist();
 124                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 125                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 126
 127                 MapInfo_Enumerate();
 128                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 129
 130                 if(!DoNextMapOverride(1))
 131                         GotoNextMap(1);
 132
 133                 return;
 134         }
 135
 136         if(time < 5)
 137         {
 138                 this.nextthink = time;
 139         }
 140         else
 141         {
 142                 this.nextthink = time + 1;
 143                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...");
 144         }
 145 }
 146
 147 void cvar_changes_init()
 148 {
 149         float h;
 150         string k, v, d;
 151         float n, i, adding, pureadding;
 152
 153         strfree(cvar_changes);
 154         strfree(cvar_purechanges);
 155         cvar_purechanges_count = 0;
 156
 157         h = buf_create();
 158         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 159         n = buf_getsize(h);
 160
 161         adding = true;
 162         pureadding = true;
 163
 164         for(i = 0; i < n; ++i)
 165         {
 166                 k = bufstr_get(h, i);
 167
 168 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 169 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 170 #define BADCVAR(p) if(k == p) continue
 171 #define BADVALUE(p, val) if (k == p && v == val) continue
 172
 173                 // general excludes and namespaces for server admin used cvars
 174                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 175
 176                 // internal
 177                 BADPREFIX("csqc_");
 178                 BADPREFIX("cvar_check_");
 179                 BADCVAR("gamecfg");
 180                 BADCVAR("g_configversion");
 181                 BADCVAR("halflifebsp");
 182                 BADCVAR("sv_mapformat_is_quake2");
 183                 BADCVAR("sv_mapformat_is_quake3");
 184                 BADPREFIX("sv_world");
 185
 186                 // client
 187                 BADPREFIX("chase_");
 188                 BADPREFIX("cl_");
 189                 BADPREFIX("con_");
 190                 BADPREFIX("scoreboard_");
 191                 BADPREFIX("g_campaign");
 192                 BADPREFIX("g_waypointsprite_");
 193                 BADPREFIX("gl_");
 194                 BADPREFIX("joy");
 195                 BADPREFIX("hud_");
 196                 BADPREFIX("m_");
 197                 BADPREFIX("menu_");
 198                 BADPREFIX("net_slist_");
 199                 BADPREFIX("r_");
 200                 BADPREFIX("sbar_");
 201                 BADPREFIX("scr_");
 202                 BADPREFIX("snd_");
 203                 BADPREFIX("show");
 204                 BADPREFIX("sensitivity");
 205                 BADPREFIX("userbind");
 206                 BADPREFIX("v_");
 207                 BADPREFIX("vid_");
 208                 BADPREFIX("crosshair");
 209                 BADCVAR("mod_q3bsp_lightmapmergepower");
 210                 BADCVAR("mod_q3bsp_nolightmaps");
 211                 BADCVAR("fov");
 212                 BADCVAR("mastervolume");
 213                 BADCVAR("volume");
 214                 BADCVAR("bgmvolume");
 215                 BADCVAR("in_pitch_min");
 216                 BADCVAR("in_pitch_max");
 217
 218                 // private
 219                 BADCVAR("developer");
 220                 BADCVAR("log_dest_udp");
 221                 BADCVAR("net_address");
 222                 BADCVAR("net_address_ipv6");
 223                 BADCVAR("port");
 224                 BADCVAR("savedgamecfg");
 225                 BADCVAR("serverconfig");
 226                 BADCVAR("sv_autoscreenshot");
 227                 BADCVAR("sv_heartbeatperiod");
 228                 BADCVAR("sv_vote_master_password");
 229                 BADCVAR("sys_colortranslation");
 230                 BADCVAR("sys_specialcharactertranslation");
 231                 BADCVAR("timeformat");
 232                 BADCVAR("timestamps");
 233                 BADCVAR("g_require_stats");
 234                 BADPREFIX("developer_");
 235                 BADPREFIX("g_ban_");
 236                 BADPREFIX("g_banned_list");
 237                 BADPREFIX("g_require_stats_");
 238                 BADPREFIX("g_chat_flood_");
 239                 BADPREFIX("g_ghost_items");
 240                 BADPREFIX("g_playerstats_");
 241                 BADPREFIX("g_voice_flood_");
 242                 BADPREFIX("log_file");
 243                 BADPREFIX("quit_");
 244                 BADPREFIX("rcon_");
 245                 BADPREFIX("sv_allowdownloads");
 246                 BADPREFIX("sv_autodemo");
 247                 BADPREFIX("sv_curl_");
 248                 BADPREFIX("sv_eventlog");
 249                 BADPREFIX("sv_logscores_");
 250                 BADPREFIX("sv_master");
 251                 BADPREFIX("sv_weaponstats_");
 252                 BADPREFIX("sv_waypointsprite_");
 253                 BADCVAR("rescan_pending");
 254
 255                 // these can contain player IDs, so better hide
 256                 BADPREFIX("g_forced_team_");
 257                 BADCVAR("sv_muteban_list");
 258                 BADCVAR("sv_voteban_list");
 259                 BADCVAR("sv_allow_customplayermodels_idlist");
 260                 BADCVAR("sv_allow_customplayermodels_speciallist");
 261
 262                 // mapinfo
 263                 BADCVAR("fraglimit");
 264                 BADCVAR("g_arena");
 265                 BADCVAR("g_assault");
 266                 BADCVAR("g_ca");
 267                 BADCVAR("g_ca_teams");
 268                 BADCVAR("g_conquest");
 269                 BADCVAR("g_conquest_teams");
 270                 BADCVAR("g_ctf");
 271                 BADCVAR("g_cts");
 272                 BADCVAR("g_dotc");
 273                 BADCVAR("g_dm");
 274                 BADCVAR("g_domination");
 275                 BADCVAR("g_domination_default_teams");
 276                 BADCVAR("g_duel");
 277                 BADCVAR("g_duel_not_dm_maps");
 278                 BADCVAR("g_freezetag");
 279                 BADCVAR("g_freezetag_teams");
 280                 BADCVAR("g_invasion_type");
 281                 BADCVAR("g_jailbreak");
 282                 BADCVAR("g_jailbreak_teams");
 283                 BADCVAR("g_keepaway");
 284                 BADCVAR("g_keyhunt");
 285                 BADCVAR("g_keyhunt_teams");
 286                 BADCVAR("g_lms");
 287                 BADCVAR("g_nexball");
 288                 BADCVAR("g_onslaught");
 289                 BADCVAR("g_race");
 290                 BADCVAR("g_race_laps_limit");
 291                 BADCVAR("g_race_qualifying_timelimit");
 292                 BADCVAR("g_race_qualifying_timelimit_override");
 293                 BADCVAR("g_runematch");
 294                 BADCVAR("g_shootfromeye");
 295                 BADCVAR("g_snafu");
 296                 BADCVAR("g_survival");
 297                 BADCVAR("g_survival_not_dm_maps");
 298                 BADCVAR("g_tdm");
 299                 BADCVAR("g_tdm_on_dm_maps");
 300                 BADCVAR("g_tdm_teams");
 301                 BADCVAR("g_tka");
 302                 BADCVAR("g_tka_on_ka_maps");
 303                 BADCVAR("g_tka_on_tdm_maps");
 304                 BADCVAR("g_tka_teams");
 305                 BADCVAR("g_vip");
 306                 BADCVAR("leadlimit");
 307                 BADCVAR("nextmap");
 308                 BADCVAR("teamplay");
 309                 BADCVAR("timelimit");
 310                 BADCVAR("g_mapinfo_q3compat");
 311                 BADCVAR("g_mapinfo_settemp_acl");
 312                 BADCVAR("g_mapinfo_ignore_warnings");
 313                 BADCVAR("g_maplist_ignore_sizes");
 314                 BADCVAR("g_maplist_sizes_count_bots");
 315
 316                 // long
 317                 BADCVAR("hostname");
 318                 BADCVAR("g_maplist");
 319                 BADCVAR("g_maplist_mostrecent");
 320                 BADCVAR("sv_motd");
 321                 BADCVAR("sv_termsofservice_url");
 322
 323                 v = cvar_string(k);
 324                 d = cvar_defstring(k);
 325                 if(v == d)
 326                         continue;
 327
 328                 if(adding)
 329                 {
 330                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 331                         if(strlen(cvar_changes) > 16384)
 332                         {
 333                                 cvar_changes = "// too many settings have been changed to show them here\n";
 334                                 adding = 0;
 335                         }
 336                 }
 337
 338                 // now check if the changes are actually gameplay relevant
 339
 340                 // does nothing gameplay relevant
 341                 BADCVAR("captureleadlimit_override");
 342                 BADCVAR("condump_stripcolors");
 343                 BADCVAR("fs_gamedir");
 344                 BADCVAR("g_allow_oldvortexbeam");
 345                 BADCVAR("g_balance_kill_delay");
 346                 BADCVAR("g_buffs_pickup_anyway");
 347                 BADCVAR("g_buffs_randomize");
 348                 BADCVAR("g_buffs_randomize_teamplay");
 349                 BADCVAR("g_campcheck_distance");
 350                 BADCVAR("g_chatsounds");
 351                 BADCVAR("g_ca_point_leadlimit");
 352                 BADCVAR("g_ca_point_limit");
 353                 BADCVAR("g_ca_spectate_enemies");
 354                 BADCVAR("g_ctf_captimerecord_always");
 355                 BADCVAR("g_ctf_flag_glowtrails");
 356                 BADCVAR("g_ctf_dynamiclights");
 357                 BADCVAR("g_ctf_flag_pickup_verbosename");
 358                 BADCVAR("g_ctf_flagcarrier_auto_helpme_damage");
 359                 BADPRESUFFIX("g_ctf_flag_", "_model");
 360                 BADPRESUFFIX("g_ctf_flag_", "_skin");
 361                 BADCVAR("g_domination_point_leadlimit");
 362                 BADCVAR("g_forced_respawn");
 363                 BADCVAR("g_freezetag_point_leadlimit");
 364                 BADCVAR("g_freezetag_point_limit");
 365                 BADCVAR("g_glowtrails");
 366                 BADCVAR("g_hats");
 367                 BADCVAR("g_casings");
 368                 BADCVAR("g_invasion_point_limit");
 369                 BADCVAR("g_jump_grunt");
 370                 BADCVAR("g_keepaway_ballcarrier_effects");
 371                 BADCVAR("g_keepawayball_effects");
 372                 BADCVAR("g_keyhunt_point_leadlimit");
 373                 BADCVAR("g_nexball_goalleadlimit");
 374                 BADCVAR("g_new_toys_autoreplace");
 375                 BADCVAR("g_new_toys_use_pickupsound");
 376                 BADCVAR("g_physics_predictall");
 377                 BADCVAR("g_piggyback");
 378                 BADCVAR("g_playerclip_collisions");
 379                 BADCVAR("g_spawn_alloweffects");
 380                 BADCVAR("g_tdm_point_leadlimit");
 381                 BADCVAR("g_tdm_point_limit");
 382                 BADCVAR("leadlimit_and_fraglimit");
 383                 BADCVAR("leadlimit_override");
 384                 BADCVAR("pausable");
 385                 BADCVAR("sv_announcer");
 386                 BADCVAR("sv_checkforpacketsduringsleep");
 387                 BADCVAR("sv_damagetext");
 388                 BADCVAR("sv_db_saveasdump");
 389                 BADCVAR("sv_intermission_cdtrack");
 390                 BADCVAR("sv_mapchange_delay");
 391                 BADCVAR("sv_minigames");
 392                 BADCVAR("sv_namechangetimer");
 393                 BADCVAR("sv_precacheplayermodels");
 394                 BADCVAR("sv_qcphysics");
 395                 BADCVAR("sv_radio");
 396                 BADCVAR("sv_stepheight");
 397                 BADCVAR("sv_timeout");
 398                 BADCVAR("sv_weapons_modeloverride");
 399                 BADCVAR("w_prop_interval");
 400                 BADPREFIX("chat_");
 401                 BADPREFIX("crypto_");
 402                 BADPREFIX("gameversion");
 403                 BADPREFIX("g_chat_");
 404                 BADPREFIX("g_ctf_captimerecord_");
 405                 BADPREFIX("g_hats_");
 406                 BADPREFIX("g_maplist_");
 407                 BADPREFIX("g_mod_");
 408                 BADPREFIX("g_respawn_");
 409                 BADPREFIX("net_");
 410                 BADPREFIX("notification_");
 411                 BADPREFIX("prvm_");
 412                 BADPREFIX("skill_");
 413                 BADPREFIX("sv_allow_");
 414                 BADPREFIX("sv_cullentities_");
 415                 BADPREFIX("sv_maxidle");
 416                 BADPREFIX("sv_minigames_");
 417                 BADPREFIX("sv_radio_");
 418                 BADPREFIX("sv_timeout_");
 419                 BADPREFIX("sv_vote_");
 420                 BADPREFIX("timelimit_");
 421                 BADPRESUFFIX("g_", "_round_timelimit");
 422
 423                 // allowed changes to server admins (please sync this to server.cfg)
 424                 // vi commands:
 425                 //   :/"impure"/,$d
 426                 //   :g!,^\/\/[^ /],d
 427                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 428                 //   :%!sort
 429                 // yes, this does contain some redundant stuff, don't really care
 430                 BADPREFIX("bot_ai_");
 431                 BADCVAR("bot_config_file");
 432                 BADCVAR("bot_number");
 433                 BADCVAR("bot_prefix");
 434                 BADCVAR("bot_suffix");
 435                 BADCVAR("capturelimit_override");
 436                 BADCVAR("fraglimit_override");
 437                 BADCVAR("gametype");
 438                 BADCVAR("g_antilag");
 439                 BADCVAR("g_balance_teams");
 440                 BADCVAR("g_balance_teams_prevent_imbalance");
 441                 BADCVAR("g_balance_teams_scorefactor");
 442                 BADCVAR("g_ban_sync_trusted_servers");
 443                 BADCVAR("g_ban_sync_uri");
 444                 BADCVAR("g_buffs");
 445                 BADCVAR("g_ca_teams_override");
 446                 BADCVAR("g_ctf_fullbrightflags");
 447                 BADCVAR("g_ctf_ignore_frags");
 448                 BADCVAR("g_ctf_leaderboard");
 449                 BADCVAR("g_domination_point_limit");
 450                 BADCVAR("g_domination_teams_override");
 451                 BADCVAR("g_freezetag_revive_spawnshield");
 452                 BADCVAR("g_freezetag_teams_override");
 453                 BADCVAR("g_friendlyfire");
 454                 BADCVAR("g_fullbrightitems");
 455                 BADCVAR("g_fullbrightplayers");
 456                 BADCVAR("g_keyhunt_point_limit");
 457                 BADCVAR("g_keyhunt_teams_override");
 458                 BADCVAR("g_lms_lives_override");
 459                 BADCVAR("g_maplist");
 460                 BADCVAR("g_maxplayers");
 461                 BADCVAR("g_mirrordamage");
 462                 BADCVAR("g_nexball_goallimit");
 463                 BADCVAR("g_norecoil");
 464                 BADCVAR("g_physics_clientselect");
 465                 BADCVAR("g_pinata");
 466                 BADCVAR("g_powerups");
 467                 BADCVAR("g_powerups_drop_ondeath");
 468                 BADCVAR("g_player_brightness");
 469                 BADCVAR("g_rocket_flying");
 470                 BADCVAR("g_rocket_flying_disabledelays");
 471                 BADPREFIX("g_spawnshield");
 472                 BADCVAR("g_start_delay");
 473                 BADCVAR("g_superspectate");
 474                 BADCVAR("g_tdm_teams_override");
 475                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 476                 BADCVAR("hostname");
 477                 BADCVAR("log_file");
 478                 BADCVAR("maxplayers");
 479                 BADCVAR("minplayers");
 480                 BADCVAR("minplayers_per_team");
 481                 BADCVAR("net_address");
 482                 BADCVAR("port");
 483                 BADCVAR("rcon_password");
 484                 BADCVAR("rcon_restricted_commands");
 485                 BADCVAR("rcon_restricted_password");
 486                 BADCVAR("skill");
 487                 BADCVAR("sv_adminnick");
 488                 BADCVAR("sv_autoscreenshot");
 489                 BADCVAR("sv_autotaunt");
 490                 BADCVAR("sv_curl_defaulturl");
 491                 BADCVAR("sv_defaultcharacter");
 492                 BADCVAR("sv_defaultcharacterskin");
 493                 BADCVAR("sv_defaultplayercolors");
 494                 BADCVAR("sv_defaultplayermodel");
 495                 BADCVAR("sv_defaultplayerskin");
 496                 BADCVAR("sv_maxrate");
 497                 BADCVAR("sv_motd");
 498                 BADCVAR("sv_public");
 499                 BADCVAR("sv_showfps");
 500                 BADCVAR("sv_showspectators");
 501                 BADCVAR("sv_status_privacy");
 502                 BADCVAR("sv_taunt");
 503                 BADCVAR("sv_vote_call");
 504                 BADCVAR("sv_vote_commands");
 505                 BADCVAR("sv_vote_majority_factor");
 506                 BADCVAR("sv_vote_master");
 507                 BADCVAR("sv_vote_master_commands");
 508                 BADCVAR("sv_vote_master_password");
 509                 BADCVAR("sv_vote_simple_majority_factor");
 510                 BADVALUE("sys_ticrate", "0.0166667");
 511                 BADVALUE("sys_ticrate", "0.0333333");
 512                 BADCVAR("teamplay_mode");
 513                 BADCVAR("timelimit_override");
 514                 BADPREFIX("g_warmup");
 515                 BADPREFIX("sv_info_");
 516                 BADPREFIX("sv_ready_restart_");
 517
 518                 // mutators that announce themselves properly to the server browser
 519                 BADCVAR("g_instagib");
 520                 BADCVAR("g_new_toys");
 521                 BADCVAR("g_nix");
 522                 BADCVAR("g_grappling_hook");
 523                 BADCVAR("g_jetpack");
 524
 525 #undef BADPRESUFFIX
 526 #undef BADPREFIX
 527 #undef BADCVAR
 528 #undef BADVALUE
 529
 530                 if(pureadding)
 531                 {
 532                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 533                         if(strlen(cvar_purechanges) > 16384)
 534                         {
 535                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 536                                 pureadding = 0;
 537                         }
 538                 }
 539                 ++cvar_purechanges_count;
 540                 // WARNING: this variable is used for the server list
 541                 // NEVER dare to skip this code!
 542                 // Hacks to intentionally appearing as "pure server" even though you DO have
 543                 // modified settings may be punished by removal from the server list.
 544                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 545                 // though.
 546         }
 547         buf_del(h);
 548         if(cvar_changes == "")
 549                 cvar_changes = "// this server runs at default server settings\n";
 550         else
 551                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 552         cvar_changes = strzone(cvar_changes);
 553         if(cvar_purechanges == "")
 554                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 555         else
 556                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 557         cvar_purechanges = strzone(cvar_purechanges);
 558 }
 559
 560 entity randomseed;
 561 bool RandomSeed_Send(entity this, entity to, int sf)
 562 {
 563         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 564         WriteShort(MSG_ENTITY, this.cnt);
 565         return true;
 566 }
 567 void RandomSeed_Think(entity this)
 568 {
 569         this.cnt = bound(0, floor(random() * 65536), 65535);
 570         this.nextthink = time + 5;
 571
 572         this.SendFlags |= 1;
 573 }
 574 void RandomSeed_Spawn()
 575 {
 576         randomseed = new_pure(randomseed);
 577         setthink(randomseed, RandomSeed_Think);
 578         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 579
 580         getthink(randomseed)(randomseed); // sets random seed and nextthink
 581 }
 582
 583 spawnfunc(__init_dedicated_server)
 584 {
 585         // handler for _init/_init map (only for dedicated server initialization)
 586
 587         world_initialized = -1; // don't complain
 588
 589         delete_fn = remove_unsafely;
 590
 591         entity e = new(GotoFirstMap);
 592         setthink(e, GotoFirstMap);
 593         e.nextthink = time; // this is usually 1 at this point
 594
 595         e = new(info_player_deathmatch);  // safeguard against player joining
 596
 597         // assign reflectively to avoid "assignment to world" warning
 598         for (int i = 0, n = numentityfields(); i < n; ++i)
 599         {
 600                 string k = entityfieldname(i);
 601                 if (k == "classname")
 602                 {
 603                         // safeguard against various stuff ;)
 604                         putentityfieldstring(i, this, "worldspawn");
 605                         break;
 606                 }
 607         }
 608
 609         // needs to be done so early because of the constants they create
 610         static_init();
 611         static_init_late();
 612         static_init_precache();
 613
 614         IL_PUSH(g_spawnpoints, e); // just incase
 615
 616         MapInfo_Enumerate();
 617         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 618 }
 619
 620 void __init_dedicated_server_shutdown() {
 621         MapInfo_Shutdown();
 622 }
 623
 624 STATIC_INIT_EARLY(maxclients)
 625 {
 626         maxclients = 0;
 627         for (entity head = nextent(NULL); head; head = nextent(head)) {
 628                 ++maxclients;
 629         }
 630 }
 631
 632 void GameplayMode_DelayedInit(entity this)
 633 {
 634         // at this stage team entities are spawned, teamplay contains the number of them
 635
 636         if(!scores_initialized)
 637                 ScoreRules_generic();
 638
 639         if (warmup_stage >= 0 && autocvar_g_maxplayers >= 0)
 640                 return;
 641         if (!g_duel)
 642                 MapReadSizes(mapname);
 643
 644         if (autocvar_g_maxplayers < 0 && teamplay)
 645         {
 646                 // automatic maxplayers should be a multiple of team count
 647                 if (map_maxplayers == 0 || map_maxplayers > maxclients)
 648                         map_maxplayers = maxclients; // unlimited, but may need rounding
 649                 int d = map_maxplayers % AVAILABLE_TEAMS;
 650                 int u = AVAILABLE_TEAMS - d;
 651                 map_maxplayers += (u <= d && u + map_maxplayers <= maxclients) ? u : -d;
 652         }
 653
 654         if (warmup_stage < 0)
 655         {
 656                 int m = GetPlayerLimit();
 657                 if (m <= 0) m = maxclients;
 658                 map_minplayers = bound(max(2, AVAILABLE_TEAMS * 2), map_minplayers, m);
 659                 if (teamplay)
 660                 {
 661                         // automatic minplayers should be a multiple of team count
 662                         int d = map_minplayers % AVAILABLE_TEAMS;
 663                         int u = AVAILABLE_TEAMS - d;
 664                         map_minplayers += (u < d && u + map_minplayers <= m) ? u : -d;
 665                 }
 666                 warmup_limit = -1;
 667         }
 668         else
 669                 map_minplayers = 0; // don't display a minimum if it's not used
 670 }
 671
 672 void InitGameplayMode()
 673 {
 674         VoteReset();
 675
 676         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 677         get_mi_min_max(1);
 678         // assign reflectively to avoid "assignment to world" warning
 679         for (int i = 0, done = 0, n = numentityfields(); i < n; ++i)
 680         {
 681                 string k = entityfieldname(i);
 682                 vector v = (k == "mins") ? mi_min : (k == "maxs") ? mi_max : '0 0 0';
 683                 if (v)
 684                 {
 685                         putentityfieldstring(i, world, sprintf("%v", v));
 686                         if (++done == 2) break;
 687                 }
 688         }
 689         // currently, NetRadiant's limit is 131072 qu for each side
 690         // distance from one corner of a 131072qu cube to the opposite corner is approx. 227023 qu
 691         // set the distance according to map size but don't go over the limit to avoid issues with float precision
 692         // in case somebody makes extremely large maps
 693         max_shot_distance = min(230000, vlen(world.maxs - world.mins));
 694
 695         MapInfo_LoadMapSettings(mapname);
 696         GameRules_teams(false);
 697
 698         if (!cvar_value_issafe(world.fog))
 699         {
 700                 LOG_INFO("The current map contains a potentially harmful fog setting, ignored");
 701                 world.fog = string_null;
 702         }
 703         if(MapInfo_Map_fog != "")
 704         {
 705                 if(MapInfo_Map_fog == "none")
 706                         world.fog = string_null;
 707                 else
 708                         world.fog = strzone(MapInfo_Map_fog);
 709         }
 710         clientstuff = strzone(MapInfo_Map_clientstuff);
 711
 712         MapInfo_ClearTemps();
 713
 714         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
 715
 716         cache_mutatormsg = strzone("");
 717         cache_lastmutatormsg = strzone("");
 718
 719         InitializeEntity(NULL, GameplayMode_DelayedInit, INITPRIO_GAMETYPE_FALLBACK);
 720 }
 721
 722 bool world_already_spawned;
 723 spawnfunc(worldspawn)
 724 {
 725         cvar_set("_endmatch", "0");
 726         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
 727
 728         if (autocvar_sv_termsofservice_url && autocvar_sv_termsofservice_url != "")
 729         {
 730                 strcpy(sv_termsofservice_url_escaped, strreplace(":", "|", autocvar_sv_termsofservice_url));
 731         }
 732         else
 733         {
 734                 strcpy(sv_termsofservice_url_escaped, "INVALID");
 735         }
 736
 737         bool wantrestart = false;
 738         {
 739                 if (!server_is_dedicated)
 740                 {
 741                         // force unloading of server pk3 files when starting a listen server
 742                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
 743                         // restore csqc_progname too
 744                         string expect = "csprogs.dat";
 745                         wantrestart = cvar_string("csqc_progname") != expect;
 746                         cvar_set("csqc_progname", expect);
 747                 }
 748                 else
 749                 {
 750                         // Try to use versioned csprogs from pk3
 751                         // Only ever use versioned csprogs.dat files on dedicated servers;
 752                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
 753                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
 754                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
 755                         string select = "csprogs.dat";
 756                         if (fexists(pk3csprogs)) select = pk3csprogs;
 757                         if (cvar_string("csqc_progname") != select)
 758                         {
 759                                 cvar_set("csqc_progname", select);
 760                                 wantrestart = true;
 761                         }
 762                         // Check for updates on startup
 763                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
 764                         int sentinel = fopen("progs.txt", FILE_READ);
 765                         if (sentinel >= 0)
 766                         {
 767                                 string switchversion = fgets(sentinel);
 768                                 fclose(sentinel);
 769                                 if (switchversion != "" && switchversion != WATERMARK)
 770                                 {
 771                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s", switchversion);
 772                                         // if it doesn't exist, assume either:
 773                                         //   a) the current program was overwritten
 774                                         //   b) this is a client only update
 775                                         string newprogs = sprintf("progs-%s.dat", switchversion);
 776                                         if (fexists(newprogs))
 777                                         {
 778                                                 cvar_set("sv_progs", newprogs);
 779                                                 wantrestart = true;
 780                                         }
 781                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
 782                                         if (fexists(newcsprogs))
 783                                         {
 784                                                 cvar_set("csqc_progname", newcsprogs);
 785                                                 wantrestart = true;
 786                                         }
 787                                 }
 788                         }
 789                 }
 790                 if (wantrestart)
 791                 {
 792                         LOG_INFO("Restart requested");
 793                         changelevel(mapname);
 794                         // let initialization continue, shutdown depends on it
 795                 }
 796         }
 797
 798         if(world_already_spawned)
 799                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 800         world_already_spawned = true;
 801
 802         delete_fn = remove_safely; // during spawning, watch what you remove!
 803
 804         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 805
 806         // default to RACE_RECORD, can be overwritten by gamemodes
 807         record_type = RACE_RECORD;
 808
 809         // needs to be done so early because of the constants they create
 810         static_init();
 811
 812         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 813
 814         TemporaryDB = db_create();
 815
 816         // 0 normal
 817         lightstyle(0, "m");
 818
 819         // 1 FLICKER (first variety)
 820         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 821
 822         // 2 SLOW STRONG PULSE
 823         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 824
 825         // 3 CANDLE (first variety)
 826         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 827
 828         // 4 FAST STROBE
 829         lightstyle(4, "mamamamamama");
 830
 831         // 5 GENTLE PULSE 1
 832         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 833
 834         // 6 FLICKER (second variety)
 835         lightstyle(6, "nmonqnmomnmomomno");
 836
 837         // 7 CANDLE (second variety)
 838         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 839
 840         // 8 CANDLE (third variety)
 841         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 842
 843         // 9 SLOW STROBE (fourth variety)
 844         lightstyle(9, "aaaaaaaazzzzzzzz");
 845
 846         // 10 FLUORESCENT FLICKER
 847         lightstyle(10, "mmamammmmammamamaaamammma");
 848
 849         // 11 SLOW PULSE NOT FADE TO BLACK
 850         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 851
 852         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 853
 854         // 63 testing
 855         lightstyle(63, "a");
 856
 857         if(autocvar_g_campaign)
 858                 CampaignPreInit();
 859         else
 860                 PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 861
 862         Map_MarkAsRecent(mapname);
 863
 864         InitGameplayMode();
 865         static_init_late();
 866         static_init_precache();
 867         readlevelcvars();
 868
 869         GameRules_limit_fallbacks();
 870
 871         if(warmup_limit == 0)
 872                 warmup_limit = autocvar_timelimit * 60;
 873
 874         player_count = 0;
 875         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 876         if(bot_waypoints_for_items == 1)
 877                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 878                         bot_waypoints_for_items = 0;
 879
 880         WaypointSprite_Init();
 881
 882         // NOTE for matchid:
 883         // changing the logic generating it is okay. But:
 884         // it HAS to stay <= 64 chars
 885         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 886         // strftime(false, "%s") isn't reliable, see strftime_s description
 887         matchid = strzone(sprintf("%d.%s.%06d", autocvar_sv_eventlog_files_counter, strftime_s(), random() * 1000000));
 888
 889         if(autocvar_sv_eventlog)
 890                 GameLogInit(); // requires matchid to be set
 891
 892         cvar_set("nextmap", "");
 893
 894         SetDefaultAlpha();
 895
 896         if(autocvar_g_campaign)
 897                 CampaignPostInit();
 898
 899         Ban_LoadBans();
 900
 901         MapInfo_Enumerate();
 902         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 903
 904         q3compat = BITSET(q3compat, Q3COMPAT_ARENA, _MapInfo_FindArenaFile(mapname, ".arena") != "");
 905         q3compat = BITSET(q3compat, Q3COMPAT_DEFI, _MapInfo_FindArenaFile(mapname, ".defi") != "");
 906
 907         // quake 3 music support
 908         if(world.music || world.noise)
 909         {
 910                 // prefer .music over .noise
 911                 string chosen_music;
 912                 if(world.music)
 913                         chosen_music = world.music;
 914                 else
 915                         chosen_music = world.noise;
 916
 917                 string newstuff = strcat(clientstuff, "cd loop \"", chosen_music, "\"\n");
 918                 strcpy(clientstuff, newstuff);
 919         }
 920
 921         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 922         {
 923                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 924                 if(fd != -1)
 925                 {
 926                         string s;
 927                         while((s = fgets(fd)))
 928                         {
 929                                 int l = tokenize_console(s);
 930                                 if(l < 2)
 931                                         continue;
 932                                 if(argv(0) == "cd")
 933                                 {
 934                                         string trackname = argv(2);
 935                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:");
 936                                         LOG_INFO("  cdtrack ", trackname);
 937                                         if (cvar_value_issafe(trackname))
 938                                         {
 939                                                 string newstuff = strcat(clientstuff, "cd loop \"", trackname, "\"\n");
 940                                                 strcpy(clientstuff, newstuff);
 941                                         }
 942                                 }
 943                                 else if(argv(0) == "fog")
 944                                 {
 945                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:");
 946                                         LOG_INFO("  \"fog\" \"", s, "\"");
 947                                 }
 948                                 else if(argv(0) == "set")
 949                                 {
 950                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 951                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2));
 952                                 }
 953                                 else if(argv(0) != "//")
 954                                 {
 955                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 956                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1));
 957                                 }
 958                         }
 959                         fclose(fd);
 960                 }
 961         }
 962
 963         WeaponStats_Init();
 964
 965         Nagger_Init();
 966
 967         // set up information replies for clients and server to use
 968         maplist_reply = strzone(getmaplist());
 969         lsmaps_reply = strzone(getlsmaps());
 970         monsterlist_reply = strzone(getmonsterlist());
 971         bool records_available = false;
 972         for(int i = 0; i < 10; ++i)
 973         {
 974                 string s = getrecords(i);
 975                 if (s != "")
 976                 {
 977                         records_reply[i] = strzone(s);
 978                         records_available = true;
 979                 }
 980         }
 981         if (!records_available)
 982                 records_reply[0] = "No records available for the current game mode.\n";
 983         ladder_reply = strzone(getladder());
 984         rankings_reply = strzone(getrankings());
 985
 986         // begin other init
 987         ClientInit_Spawn();
 988         RandomSeed_Spawn();
 989         PingPLReport_Spawn();
 990
 991         CheatInit();
 992
 993         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 994
 995         // fill sv_curl_serverpackages from .serverpackage files
 996         if (autocvar_sv_curl_serverpackages_auto)
 997         {
 998                 string s = "csprogs-" WATERMARK ".dat";
 999                 // remove automatically managed files from the list to prevent duplicates
1000                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
1001                 {
1002                         string pkg = argv(i);
1003                         if (startsWith(pkg, "csprogs-")) continue;
1004                         if (endsWith(pkg, "-serverpackage.txt")) continue;
1005                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
1006                         s = cons(s, pkg);
1007                 }
1008                 // add automatically managed files to the list
1009                 #define X(match) MACRO_BEGIN \
1010                         int fd = search_begin(match, true, false); \
1011                         if (fd >= 0) \
1012                         { \
1013                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
1014                                 { \
1015                                         s = cons(s, search_getfilename(fd, i)); \
1016                                 } \
1017                                 search_end(fd); \
1018                         } \
1019                 MACRO_END
1020                 X("*-serverpackage.txt");
1021                 X("*.serverpackage");
1022                 #undef X
1023                 cvar_set("sv_curl_serverpackages", s);
1024         }
1025
1026         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
1027         modname = "Xonotic";
1028         // physics/balance/config changes that count as mod
1029         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
1030                 modname = cvar_string("g_mod_physics");
1031         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance") && cvar_string("g_mod_balance") != "Testing")
1032                 modname = cvar_string("g_mod_balance");
1033         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
1034                 modname = cvar_string("g_mod_config");
1035         // extra mutators that deserve to count as mod
1036         MUTATOR_CALLHOOK(SetModname, modname);
1037         modname = M_ARGV(0, string);
1038
1039         // save it for later
1040         modname = strzone(modname);
1041
1042         WinningConditionHelper(this); // set worldstatus
1043
1044         world_initialized = 1;
1045         __spawnfunc_spawn_all();
1046 }
1047
1048 spawnfunc(light)
1049 {
1050         //makestatic (this); // Who the f___ did that?
1051         delete(this);
1052 }
1053
1054 bool MoveToRandomLocationWithinBounds(entity e, vector boundmin, vector boundmax, float goodcontents, float badcontents, float badsurfaceflags, int attempts, float maxaboveground, float minviewdistance, bool frompos)
1055 {
1056         float m = e.dphitcontentsmask;
1057         e.dphitcontentsmask = goodcontents | badcontents;
1058
1059         vector org = boundmin;
1060         vector delta = boundmax - boundmin;
1061
1062         vector start, end;
1063         start = end = org;
1064         int j; // used after the loop
1065         for(j = 0; j < attempts; ++j)
1066         {
1067                 start.x = org.x + random() * delta.x;
1068                 start.y = org.y + random() * delta.y;
1069                 start.z = org.z + random() * delta.z;
1070
1071                 // rule 1: start inside world bounds, and outside
1072                 // solid, and don't start from somewhere where you can
1073                 // fall down to evil
1074                 tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1075                 if (trace_fraction >= 1)
1076                         continue;
1077                 if (trace_startsolid)
1078                         continue;
1079                 if (trace_dphitcontents & badcontents)
1080                         continue;
1081                 if (trace_dphitq3surfaceflags & badsurfaceflags)
1082                         continue;
1083
1084                 // rule 2: if we are too high, lower the point
1085                 if (trace_fraction * delta.z > maxaboveground)
1086                         start = trace_endpos + '0 0 1' * maxaboveground;
1087                 vector enddown = trace_endpos;
1088
1089                 // rule 3: make sure we aren't outside the map. This only works
1090                 // for somewhat well formed maps. A good rule of thumb is that
1091                 // the map should have a convex outside hull.
1092                 // these can be traceLINES as we already verified the starting box
1093                 vector mstart = start + 0.5 * (e.mins + e.maxs);
1094                 traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1095                 if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1096                         continue;
1097                 traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1098                 if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1099                         continue;
1100                 traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1101                 if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1102                         continue;
1103                 traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1104                 if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1105                         continue;
1106                 traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1107                 if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1108                         continue;
1109
1110                 // rule 4: we must "see" some spawnpoint or item
1111                 entity sp = NULL;
1112                 if(frompos)
1113                 {
1114                         if((traceline(mstart, e.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1115                                 sp = e;
1116                 }
1117                 if(!sp)
1118                 {
1119                         IL_EACH(g_spawnpoints, checkpvs(mstart, it),
1120                         {
1121                                 if((traceline(mstart, it.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1122                                 {
1123                                         sp = it;
1124                                         break;
1125                                 }
1126                         });
1127                 }
1128                 if(!sp)
1129                 {
1130                         int items_checked = 0;
1131                         IL_EACH(g_items, checkpvs(mstart, it),
1132                         {
1133                                 if((traceline(mstart, it.origin + (it.mins + it.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1134                                 {
1135                                         sp = it;
1136                                         break;
1137                                 }
1138
1139                                 ++items_checked;
1140                                 if(items_checked >= attempts)
1141                                         break; // sanity
1142                         });
1143
1144                         if(!sp)
1145                                 continue;
1146                 }
1147
1148                 // find a random vector to "look at"
1149                 end.x = org.x + random() * delta.x;
1150                 end.y = org.y + random() * delta.y;
1151                 end.z = org.z + random() * delta.z;
1152                 end = start + normalize(end - start) * vlen(delta);
1153
1154                 // rule 4: start TO end must not be too short
1155                 tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1156                 if(trace_startsolid)
1157                         continue;
1158                 if(trace_fraction < minviewdistance / vlen(delta))
1159                         continue;
1160
1161                 // rule 5: don't want to look at sky
1162                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1163                         continue;
1164
1165                 // rule 6: we must not end up in trigger_hurt
1166                 if(tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1167                         continue;
1168
1169                 break;
1170         }
1171
1172         e.dphitcontentsmask = m;
1173
1174         if(j < attempts)
1175         {
1176                 setorigin(e, start);
1177                 e.angles = vectoangles(end - start);
1178                 LOG_DEBUG("Needed ", ftos(j + 1), " attempts");
1179                 return true;
1180         }
1181         return false;
1182 }
1183
1184 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1185 {
1186         return MoveToRandomLocationWithinBounds(e, world.mins, world.maxs, goodcontents, badcontents, badsurfaceflags, attempts, maxaboveground, minviewdistance, false);
1187 }
1188
1189 /*
1190 ===============================================================================
1191
1192 RULES
1193
1194 ===============================================================================
1195 */
1196
1197 void DumpStats(float final)
1198 {
1199         float file;
1200         string s;
1201         float to_console;
1202         float to_eventlog;
1203         float to_file;
1204         float i;
1205
1206         to_console = autocvar_sv_logscores_console;
1207         to_eventlog = autocvar_sv_eventlog;
1208         to_file = autocvar_sv_logscores_file;
1209
1210         if(!final)
1211         {
1212                 to_console = true; // always print printstats replies
1213                 to_eventlog = false; // but never print them to the event log
1214         }
1215
1216         if(to_eventlog)
1217                 if(autocvar_sv_eventlog_console)
1218                         to_console = false; // otherwise we get the output twice
1219
1220         if(final)
1221                 s = ":scores:";
1222         else
1223                 s = ":status:";
1224         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1225
1226         if(to_console)
1227                 LOG_HELP(s);
1228         if(to_eventlog)
1229                 GameLogEcho(s);
1230
1231         file = -1;
1232         if(to_file)
1233         {
1234                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1235                 if(file == -1)
1236                         to_file = false;
1237                 else
1238                         fputs(file, strcat(s, "\n"));
1239         }
1240
1241         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1242         if(to_console)
1243                 LOG_HELP(s);
1244         if(to_eventlog)
1245                 GameLogEcho(s);
1246         if(to_file)
1247                 fputs(file, strcat(s, "\n"));
1248
1249         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), {
1250                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1251                 s = strcat(s, ftos(rint(time - CS(it).jointime)), ":");
1252                 if(IS_PLAYER(it) || INGAME_JOINED(it))
1253                         s = strcat(s, ftos(it.team), ":");
1254                 else
1255                         s = strcat(s, "spectator:");
1256
1257                 if(to_console)
1258                         LOG_HELP(s, playername(it.netname, it.team, false));
1259                 if(to_eventlog)
1260                         GameLogEcho(strcat(s, ftos(it.playerid), ":", playername(it.netname, it.team, false)));
1261                 if(to_file)
1262                         fputs(file, strcat(s, playername(it.netname, it.team, false), "\n"));
1263         });
1264
1265         if(teamplay)
1266         {
1267                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1268                 if(to_console)
1269                         LOG_HELP(s);
1270                 if(to_eventlog)
1271                         GameLogEcho(s);
1272                 if(to_file)
1273                         fputs(file, strcat(s, "\n"));
1274
1275                 for(i = 1; i < 16; ++i)
1276                 {
1277                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1278                         s = strcat(s, ":", ftos(i));
1279                         if(to_console)
1280                                 LOG_HELP(s);
1281                         if(to_eventlog)
1282                                 GameLogEcho(s);
1283                         if(to_file)
1284                                 fputs(file, strcat(s, "\n"));
1285                 }
1286         }
1287
1288         if(to_console)
1289                 LOG_HELP(":end");
1290         if(to_eventlog)
1291                 GameLogEcho(":end");
1292         if(to_file)
1293         {
1294                 fputs(file, ":end\n");
1295                 fclose(file);
1296         }
1297 }
1298
1299 /*
1300 go to the next level for deathmatch
1301 only called if a time or frag limit has expired
1302 */
1303 void NextLevel()
1304 {
1305         cvar_set("_endmatch", "0");
1306         game_stopped = true;
1307         intermission_running = true; // game over
1308
1309         // enforce a wait time before allowing changelevel
1310         if(player_count > 0)
1311                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1312         else
1313                 intermission_exittime = -1;
1314
1315         /*
1316         WriteByte (MSG_ALL, SVC_CDTRACK);
1317         WriteByte (MSG_ALL, 3);
1318         WriteByte (MSG_ALL, 3);
1319         // done in FixIntermission
1320         */
1321
1322         //pos = FindIntermission ();
1323
1324         VoteReset();
1325
1326         DumpStats(true);
1327
1328         // send statistics
1329         PlayerStats_GameReport(true);
1330         WeaponStats_Shutdown();
1331
1332         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1333
1334         if(autocvar_sv_eventlog)
1335                 GameLogEcho(":gameover");
1336
1337         GameLogClose();
1338
1339         int winner_team = 0;
1340         FOREACH_CLIENT(IS_PLAYER(it) || INGAME(it), {
1341                 FixIntermissionClient(it);
1342                 if(it.winning)
1343                 {
1344                         if (teamplay && !winner_team)
1345                         {
1346                                 winner_team = it.team;
1347                                 bprint(Team_ColorCode(winner_team), Team_ColorName_Upper(winner_team), "^7 team wins the match\n");
1348                         }
1349                         bprint(playername(it.netname, it.team, false), " ^7wins\n");
1350                 }
1351         });
1352
1353         target_music_kill();
1354
1355         if(autocvar_g_campaign)
1356                 CampaignPreIntermission();
1357
1358         MUTATOR_CALLHOOK(MatchEnd);
1359
1360         localcmd("\nsv_hook_gameend\n");
1361 }
1362
1363
1364 int InitiateSuddenDeath()
1365 {
1366         // Check first whether normal overtimes could be added before initiating suddendeath mode
1367         // - for this timelimit_overtime needs to be >0 of course
1368         // - also check the winning condition calculated in the previous frame and only add normal overtime
1369         //   again, if at the point at which timelimit would be extended again, still no winner was found
1370         if (!autocvar_g_campaign && checkrules_overtimesadded >= 0
1371                 && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0)
1372                 && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1373         {
1374                 return 1; // need to call InitiateOvertime later
1375         }
1376         else
1377         {
1378                 if(!checkrules_suddendeathend)
1379                 {
1380                         if(autocvar_g_campaign)
1381                         {
1382                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1383                         }
1384                         else
1385                         {
1386                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1387                                 overtimes = -1;
1388                         }
1389                         if(g_race && !g_race_qualifying)
1390                                 race_StartCompleting();
1391                 }
1392                 return 0;
1393         }
1394 }
1395
1396 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1397 {
1398         ++checkrules_overtimesadded;
1399         overtimes = checkrules_overtimesadded;
1400         //add one more overtime by simply extending the timelimit
1401         cvar_set("timelimit", ftos(autocvar_timelimit + autocvar_timelimit_overtime));
1402         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1403 }
1404
1405 float GetWinningCode(float fraglimitreached, float equality)
1406 {
1407         if(autocvar_g_campaign == 1)
1408         {
1409                 if(fraglimitreached)
1410                         return WINNING_YES;
1411                 else
1412                         return WINNING_NO;
1413         }
1414         else
1415         {
1416                 if(equality)
1417                 {
1418                         if(fraglimitreached)
1419                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1420                         else
1421                                 return WINNING_NEVER;
1422                 }
1423                 else
1424                 {
1425                         if(fraglimitreached)
1426                                 return WINNING_YES;
1427                         else
1428                                 return WINNING_NO;
1429                 }
1430         }
1431 }
1432
1433 // set the .winning flag for exactly those players with a given field value
1434 void SetWinners(.float field, float value)
1435 {
1436         FOREACH_CLIENT(IS_PLAYER(it) || INGAME(it), { it.winning = (it.(field) == value); });
1437 }
1438
1439 // set the .winning flag for those players with a given field value
1440 void AddWinners(.float field, float value)
1441 {
1442         FOREACH_CLIENT(IS_PLAYER(it) || INGAME(it), {
1443                 if(it.(field) == value)
1444                         it.winning = 1;
1445         });
1446 }
1447
1448 // clear the .winning flags
1449 void ClearWinners()
1450 {
1451         FOREACH_CLIENT(IS_PLAYER(it) || INGAME(it), { it.winning = 0; });
1452 }
1453
1454 int fragsleft_last;
1455 float WinningCondition_Scores(float limit, float leadlimit)
1456 {
1457         // TODO make everything use THIS winning condition (except LMS)
1458         WinningConditionHelper(NULL);
1459
1460         if(teamplay)
1461         {
1462                 for (int i = 1; i < 5; ++i)
1463                 {
1464                         Team_SetTeamScore(Team_GetTeamFromIndex(i),
1465                                 TeamScore_GetCompareValue(Team_IndexToTeam(i)));
1466                 }
1467         }
1468
1469         ClearWinners();
1470         if(WinningConditionHelper_winner)
1471                 WinningConditionHelper_winner.winning = 1;
1472         if(WinningConditionHelper_winnerteam >= 0)
1473                 SetWinners(team, WinningConditionHelper_winnerteam);
1474
1475         if(WinningConditionHelper_lowerisbetter)
1476         {
1477                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1478                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1479                 limit = -limit;
1480         }
1481
1482         if(WinningConditionHelper_zeroisworst)
1483                 leadlimit = 0; // not supported in this mode
1484
1485         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1486         {
1487                 float fragsleft;
1488                 if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1489                 {
1490                         fragsleft = 1;
1491                 }
1492                 else
1493                 {
1494                         fragsleft = FLOAT_MAX;
1495                         float leadingfragsleft = FLOAT_MAX;
1496                         if (limit)
1497                                 fragsleft = limit - WinningConditionHelper_topscore;
1498                         if (leadlimit)
1499                                 leadingfragsleft = WinningConditionHelper_secondscore + leadlimit - WinningConditionHelper_topscore;
1500
1501                         if (limit && leadlimit && autocvar_leadlimit_and_fraglimit)
1502                                 fragsleft = max(fragsleft, leadingfragsleft);
1503                         else
1504                                 fragsleft = min(fragsleft, leadingfragsleft);
1505                 }
1506
1507                 if (fragsleft_last != fragsleft) // do not announce same remaining frags multiple times
1508                 {
1509                         if (fragsleft == 1)
1510                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1511                         else if (fragsleft == 2)
1512                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1513                         else if (fragsleft == 3)
1514                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1515
1516                         fragsleft_last = fragsleft;
1517                 }
1518         }
1519
1520         bool fraglimit_reached = (limit && WinningConditionHelper_topscore >= limit);
1521         bool leadlimit_reached = (leadlimit && WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1522
1523         bool limit_reached;
1524         // only respect leadlimit_and_fraglimit when both limits are set or the game will never end
1525         if (limit && leadlimit && autocvar_leadlimit_and_fraglimit)
1526                 limit_reached = (fraglimit_reached && leadlimit_reached);
1527         else
1528                 limit_reached = (fraglimit_reached || leadlimit_reached);
1529
1530         return GetWinningCode(
1531                 WinningConditionHelper_topscore && limit_reached,
1532                 WinningConditionHelper_equality
1533         );
1534 }
1535
1536 float WinningCondition_RanOutOfSpawns()
1537 {
1538         if(have_team_spawns <= 0)
1539                 return WINNING_NO;
1540
1541         if(!autocvar_g_spawn_useallspawns)
1542                 return WINNING_NO;
1543
1544         if(!some_spawn_has_been_used)
1545                 return WINNING_NO;
1546
1547         for (int i = 1; i < 5; ++i)
1548         {
1549                 Team_SetTeamScore(Team_GetTeamFromIndex(i), 0);
1550         }
1551
1552         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it),
1553         {
1554                 if (Team_IsValidTeam(it.team))
1555                 {
1556                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1557                 }
1558         });
1559
1560         IL_EACH(g_spawnpoints, true,
1561         {
1562                 if (Team_IsValidTeam(it.team))
1563                 {
1564                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1565                 }
1566         });
1567
1568         ClearWinners();
1569         float team1_score = Team_GetTeamScore(Team_GetTeamFromIndex(1));
1570         float team2_score = Team_GetTeamScore(Team_GetTeamFromIndex(2));
1571         float team3_score = Team_GetTeamScore(Team_GetTeamFromIndex(3));
1572         float team4_score = Team_GetTeamScore(Team_GetTeamFromIndex(4));
1573         if(team1_score + team2_score + team3_score + team4_score == 0)
1574         {
1575                 checkrules_equality = true;
1576                 return WINNING_YES;
1577         }
1578         else if(team1_score + team2_score + team3_score + team4_score == 1)
1579         {
1580                 float t, i;
1581                 if(team1_score)
1582                         t = 1;
1583                 else if(team2_score)
1584                         t = 2;
1585                 else if(team3_score)
1586                         t = 3;
1587                 else // if(team4_score)
1588                         t = 4;
1589                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
1590                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1591                 {
1592                         for (int j = 1; j <= NUM_TEAMS; ++j)
1593                         {
1594                                 if (t == j)
1595                                 {
1596                                         continue;
1597                                 }
1598                                 if (!TeamBalance_IsTeamAllowed(balance, j))
1599                                 {
1600                                         continue;
1601                                 }
1602                                 TeamScore_AddToTeam(Team_IndexToTeam(j), i, -1000);
1603                         }
1604                 }
1605
1606                 AddWinners(team, t);
1607                 return WINNING_YES;
1608         }
1609         else
1610                 return WINNING_NO;
1611 }
1612
1613 /*
1614 ============
1615 CheckRules_World
1616
1617 Exit deathmatch games upon conditions
1618 ============
1619 */
1620 void CheckRules_World()
1621 {
1622         VoteThink();
1623         MapVote_Think();
1624
1625         SetDefaultAlpha();
1626
1627         if (intermission_running) // someone else quit the game already
1628         {
1629                 if(player_count == 0) // Nobody there? Then let's go to the next map
1630                         MapVote_Start();
1631                         // this will actually check the player count in the next frame
1632                         // again, but this shouldn't hurt
1633                 return;
1634         }
1635
1636         float timelimit = autocvar_timelimit * 60;
1637         float fraglimit = autocvar_fraglimit;
1638         float leadlimit = autocvar_leadlimit;
1639         if (leadlimit < 0) leadlimit = 0;
1640
1641         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1642         {
1643                 if(timelimit > 0)
1644                         timelimit = 0; // timelimit is not made for warmup
1645                 if(fraglimit > 0)
1646                         fraglimit = 0; // no fraglimit for now
1647                 leadlimit = 0; // no leadlimit for now
1648         }
1649
1650         if (autocvar__endmatch || timelimit < 0)
1651         {
1652                 // endmatch
1653                 NextLevel();
1654                 return;
1655         }
1656
1657         if(timelimit > 0)
1658                 timelimit += game_starttime;
1659
1660         int overtimes_prev = overtimes;
1661         int wantovertime = 0;
1662
1663         if(checkrules_suddendeathend)
1664         {
1665                 if(!checkrules_suddendeathwarning)
1666                 {
1667                         checkrules_suddendeathwarning = true;
1668                         if(g_race && !g_race_qualifying)
1669                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1670                         else
1671                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1672                 }
1673         }
1674         else
1675         {
1676                 if (timelimit && time >= timelimit)
1677                 {
1678                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1679                         {
1680                                 float totalplayers;
1681                                 float playerswithlaps;
1682                                 float readyplayers;
1683                                 totalplayers = playerswithlaps = readyplayers = 0;
1684                                 FOREACH_CLIENT(IS_PLAYER(it), {
1685                                         ++totalplayers;
1686                                         if(GameRules_scoring_add(it, RACE_FASTEST, 0))
1687                                                 ++playerswithlaps;
1688                                         if(it.ready)
1689                                                 ++readyplayers;
1690                                 });
1691
1692                                 // at least 2 of the players have completed a lap: start the RACE
1693                                 // otherwise, the players should end the qualifying on their own
1694                                 if(readyplayers || playerswithlaps >= 2)
1695                                 {
1696                                         checkrules_suddendeathend = 0;
1697                                         ReadyRestart(true); // go to race
1698                                         return;
1699                                 }
1700                                 else
1701                                         wantovertime |= InitiateSuddenDeath();
1702                         }
1703                         else
1704                                 wantovertime |= InitiateSuddenDeath();
1705                 }
1706         }
1707
1708         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1709         {
1710                 NextLevel();
1711                 return;
1712         }
1713
1714         int checkrules_status = WinningCondition_RanOutOfSpawns();
1715         if(checkrules_status == WINNING_YES)
1716                 bprint("Hey! Someone ran out of spawns!\n");
1717         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1718                 checkrules_status = M_ARGV(0, float);
1719         else
1720                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1721
1722         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1723         {
1724                 checkrules_status = WINNING_NEVER;
1725                 checkrules_overtimesadded = -1;
1726                 wantovertime |= InitiateSuddenDeath();
1727         }
1728
1729         if(checkrules_status == WINNING_NEVER)
1730                 // equality cases! Nobody wins if the overtime ends in a draw.
1731                 ClearWinners();
1732
1733         if(wantovertime)
1734         {
1735                 if(checkrules_status == WINNING_NEVER)
1736                         InitiateOvertime();
1737                 else
1738                         checkrules_status = WINNING_YES;
1739         }
1740
1741         if(checkrules_suddendeathend)
1742                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1743                         checkrules_status = WINNING_YES;
1744
1745         if(checkrules_status == WINNING_YES)
1746         {
1747                 if (overtimes == -1 && overtimes != overtimes_prev)
1748                 {
1749                         // if suddendeathend overtime has just begun, revert it
1750                         checkrules_suddendeathend = 0;
1751                         overtimes = overtimes_prev;
1752                 }
1753                 //print("WINNING\n");
1754                 NextLevel();
1755         }
1756 }
1757
1758 float want_weapon(entity weaponinfo, float allguns)
1759 {
1760         int d = 0;
1761         bool allow_mutatorblocked = false;
1762
1763         if(!weaponinfo.m_id)
1764                 return 0;
1765
1766         bool mutator_returnvalue = MUTATOR_CALLHOOK(WantWeapon, weaponinfo, d, allguns, allow_mutatorblocked);
1767         d = M_ARGV(1, float);
1768         allguns = M_ARGV(2, bool);
1769         allow_mutatorblocked = M_ARGV(3, bool);
1770
1771         if(allguns)
1772                 d = boolean((weaponinfo.spawnflags & WEP_FLAG_NORMAL) && !(weaponinfo.spawnflags & (WEP_FLAG_HIDDEN | WEP_FLAG_SPECIALATTACK)));
1773         else if(!mutator_returnvalue)
1774                 d = !(!weaponinfo.weaponstart);
1775
1776         if(!allow_mutatorblocked && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
1777                 d = 0;
1778
1779         float t = weaponinfo.weaponstartoverride;
1780
1781         //LOG_INFOF("want_weapon: %s - d: %d t: %d\n", weaponinfo.netname, d, t);
1782
1783         // bit order in t:
1784         // 1: want or not
1785         // 2: is default?
1786         // 4: is set by default?
1787         if(t < 0)
1788                 t = 4 | (3 * d);
1789         else
1790                 t |= (2 * d);
1791
1792         return t;
1793 }
1794
1795 /// Weapons the player normally starts with outside weapon arena.
1796 WepSet weapons_start()
1797 {
1798         WepSet ret = '0 0 0';
1799         FOREACH(Weapons, it != WEP_Null, {
1800                 int w = want_weapon(it, false);
1801                 if (w & 1)
1802                         ret |= it.m_wepset;
1803         });
1804         return ret;
1805 }
1806
1807 WepSet weapons_all()
1808 {
1809         WepSet ret = '0 0 0';
1810         FOREACH(Weapons, it != WEP_Null, {
1811                 if (!(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_SPECIALATTACK)))
1812                         ret |= it.m_wepset;
1813         });
1814         return ret;
1815 }
1816
1817 WepSet weapons_devall()
1818 {
1819         WepSet ret = '0 0 0';
1820         FOREACH(Weapons, it != WEP_Null,
1821         {
1822                 ret |= it.m_wepset;
1823         });
1824         return ret;
1825 }
1826
1827 WepSet weapons_most()
1828 {
1829         WepSet ret = '0 0 0';
1830         FOREACH(Weapons, it != WEP_Null, {
1831                 if ((it.spawnflags & WEP_FLAG_NORMAL) && !(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_HIDDEN | WEP_FLAG_SPECIALATTACK)))
1832                         ret |= it.m_wepset;
1833         });
1834         return ret;
1835 }
1836
1837 void weaponarena_available_all_update(entity this)
1838 {
1839         if (weaponsInMapAll)
1840         {
1841                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | (weaponsInMapAll & weapons_all());
1842         }
1843         else
1844         {
1845                 // if no weapons are available on the map, just fall back to all weapons arena
1846                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_all();
1847         }
1848 }
1849
1850 void weaponarena_available_devall_update(entity this)
1851 {
1852         if (weaponsInMapAll)
1853         {
1854                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | weaponsInMapAll;
1855         }
1856         else
1857         {
1858                 // if no weapons are available on the map, just fall back to devall weapons arena
1859                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_devall();
1860         }
1861 }
1862
1863 void weaponarena_available_most_update(entity this)
1864 {
1865         if (weaponsInMapAll)
1866         {
1867                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | (weaponsInMapAll & weapons_most());
1868         }
1869         else
1870         {
1871                 // if no weapons are available on the map, just fall back to most weapons arena
1872                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_most();
1873         }
1874 }
1875
1876 void readplayerstartcvars()
1877 {
1878         // initialize starting values for players
1879         start_weapons = '0 0 0';
1880         start_weapons_default = '0 0 0';
1881         start_weapons_defaultmask = '0 0 0';
1882         start_items = 0;
1883         start_ammo_shells = 0;
1884         start_ammo_nails = 0;
1885         start_ammo_rockets = 0;
1886         start_ammo_cells = 0;
1887         start_ammo_plasma = 0;
1888         if (random_start_ammo == NULL)
1889         {
1890                 random_start_ammo = new_pure(random_start_ammo);
1891         }
1892         start_health = cvar("g_balance_health_start");
1893         start_armorvalue = cvar("g_balance_armor_start");
1894
1895         g_weaponarena = 0;
1896         g_weaponarena_weapons = '0 0 0';
1897
1898         string s = cvar_string("g_weaponarena");
1899
1900         MUTATOR_CALLHOOK(SetWeaponArena, s);
1901         s = M_ARGV(0, string);
1902
1903         if (s == "0" || s == "")
1904         {
1905                 // no arena
1906         }
1907         else if (s == "off")
1908         {
1909                 // forcibly turn off weaponarena
1910         }
1911         else if (s == "all" || s == "1")
1912         {
1913                 g_weaponarena = 1;
1914                 g_weaponarena_list = "All Weapons Arena";
1915                 g_weaponarena_weapons = weapons_all();
1916         }
1917         else if (s == "devall")
1918         {
1919                 g_weaponarena = 1;
1920                 g_weaponarena_list = "Dev All Weapons Arena";
1921                 g_weaponarena_weapons = weapons_devall();
1922         }
1923         else if (s == "most")
1924         {
1925                 g_weaponarena = 1;
1926                 g_weaponarena_list = "Most Weapons Arena";
1927                 g_weaponarena_weapons = weapons_most();
1928         }
1929         else if (s == "all_available")
1930         {
1931                 g_weaponarena = 1;
1932                 g_weaponarena_list = "All Available Weapons Arena";
1933
1934                 // this needs to run after weaponsInMapAll is initialized
1935                 InitializeEntity(NULL, weaponarena_available_all_update, INITPRIO_FINDTARGET);
1936         }
1937         else if (s == "devall_available")
1938         {
1939                 g_weaponarena = 1;
1940                 g_weaponarena_list = "Dev All Available Weapons Arena";
1941
1942                 // this needs to run after weaponsInMapAll is initialized
1943                 InitializeEntity(NULL, weaponarena_available_devall_update, INITPRIO_FINDTARGET);
1944         }
1945         else if (s == "most_available")
1946         {
1947                 g_weaponarena = 1;
1948                 g_weaponarena_list = "Most Available Weapons Arena";
1949
1950                 // this needs to run after weaponsInMapAll is initialized
1951                 InitializeEntity(NULL, weaponarena_available_most_update, INITPRIO_FINDTARGET);
1952         }
1953         else if (s == "none")
1954         {
1955                 g_weaponarena = 1;
1956                 g_weaponarena_list = "No Weapons Arena";
1957         }
1958         else
1959         {
1960                 g_weaponarena = 1;
1961                 float t = tokenize_console(s);
1962                 g_weaponarena_list = "";
1963                 for (int j = 0; j < t; ++j)
1964                 {
1965                         s = argv(j);
1966                         Weapon wep = Weapon_from_name(s);
1967                         if(wep != WEP_Null)
1968                         {
1969                                 g_weaponarena_weapons |= (wep.m_wepset);
1970                                 g_weaponarena_list = strcat(g_weaponarena_list, wep.netname, " & ");
1971                         }
1972                 }
1973                 if (g_weaponarena_list != "") // remove trailing " & "
1974                         g_weaponarena_list = substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3);
1975                 else // no valid weapon found
1976                         g_weaponarena_list = "No Weapons Arena";
1977         }
1978
1979         if (g_weaponarena)
1980         {
1981                 g_weapon_stay = 0; // incompatible
1982                 start_weapons = g_weaponarena_weapons;
1983                 start_items |= IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS;
1984                 g_weaponarena_list = strzone(g_weaponarena_list);
1985         }
1986         else
1987         {
1988                 FOREACH(Weapons, it != WEP_Null, {
1989                         int w = want_weapon(it, false);
1990                         WepSet s = it.m_wepset;
1991                         if(w & 1)
1992                                 start_weapons |= s;
1993                         if(w & 2)
1994                                 start_weapons_default |= s;
1995                         if(w & 4)
1996                                 start_weapons_defaultmask |= s;
1997                 });
1998         }
1999
2000         if(cvar("g_balance_superweapons_time") < 0)
2001                 start_items |= IT_UNLIMITED_SUPERWEAPONS;
2002
2003         if(!cvar("g_use_ammunition"))
2004                 start_items |= IT_UNLIMITED_AMMO;
2005
2006         if(start_items & IT_UNLIMITED_AMMO)
2007         {
2008                 start_ammo_shells = 999;
2009                 start_ammo_nails = 999;
2010                 start_ammo_rockets = 999;
2011                 start_ammo_cells = 999;
2012                 start_ammo_plasma = 999;
2013                 start_ammo_fuel = 999;
2014         }
2015         else
2016         {
2017                 start_ammo_shells = cvar("g_start_ammo_shells");
2018                 start_ammo_nails = cvar("g_start_ammo_nails");
2019                 start_ammo_rockets = cvar("g_start_ammo_rockets");
2020                 start_ammo_cells = cvar("g_start_ammo_cells");
2021                 start_ammo_plasma = cvar("g_start_ammo_plasma");
2022                 start_ammo_fuel = cvar("g_start_ammo_fuel");
2023                 random_start_weapons_count = cvar("g_random_start_weapons_count");
2024                 SetResource(random_start_ammo, RES_SHELLS, cvar("g_random_start_shells"));
2025                 SetResource(random_start_ammo, RES_BULLETS, cvar("g_random_start_bullets"));
2026                 SetResource(random_start_ammo, RES_ROCKETS, cvar("g_random_start_rockets"));
2027                 SetResource(random_start_ammo, RES_CELLS, cvar("g_random_start_cells"));
2028                 SetResource(random_start_ammo, RES_PLASMA, cvar("g_random_start_plasma"));
2029         }
2030
2031         warmup_start_ammo_shells = start_ammo_shells;
2032         warmup_start_ammo_nails = start_ammo_nails;
2033         warmup_start_ammo_rockets = start_ammo_rockets;
2034         warmup_start_ammo_cells = start_ammo_cells;
2035         warmup_start_ammo_plasma = start_ammo_plasma;
2036         warmup_start_ammo_fuel = start_ammo_fuel;
2037         warmup_start_health = start_health;
2038         warmup_start_armorvalue = start_armorvalue;
2039         warmup_start_weapons = start_weapons;
2040         warmup_start_weapons_default = start_weapons_default;
2041         warmup_start_weapons_defaultmask = start_weapons_defaultmask;
2042
2043         if (!g_weaponarena)
2044         {
2045                 warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
2046                 warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
2047                 warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
2048                 warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
2049                 warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
2050                 warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
2051                 warmup_start_health = cvar("g_warmup_start_health");
2052                 warmup_start_armorvalue = cvar("g_warmup_start_armor");
2053                 warmup_start_weapons = '0 0 0';
2054                 warmup_start_weapons_default = '0 0 0';
2055                 warmup_start_weapons_defaultmask = '0 0 0';
2056                 FOREACH(Weapons, it != WEP_Null, {
2057                         int w = want_weapon(it, autocvar_g_warmup_allguns);
2058                         WepSet s = it.m_wepset;
2059                         if(w & 1)
2060                                 warmup_start_weapons |= s;
2061                         if(w & 2)
2062                                 warmup_start_weapons_default |= s;
2063                         if(w & 4)
2064                                 warmup_start_weapons_defaultmask |= s;
2065                 });
2066         }
2067
2068         if (autocvar_g_jetpack)
2069                 start_items |= ITEM_Jetpack.m_itemid;
2070
2071         MUTATOR_CALLHOOK(SetStartItems);
2072
2073         if (start_items & ITEM_Jetpack.m_itemid)
2074         {
2075                 start_items |= ITEM_JetpackRegen.m_itemid;
2076                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
2077                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
2078         }
2079
2080         start_ammo_shells = max(0, start_ammo_shells);
2081         start_ammo_nails = max(0, start_ammo_nails);
2082         start_ammo_rockets = max(0, start_ammo_rockets);
2083         start_ammo_cells = max(0, start_ammo_cells);
2084         start_ammo_plasma = max(0, start_ammo_plasma);
2085         start_ammo_fuel = max(0, start_ammo_fuel);
2086         SetResource(random_start_ammo, RES_SHELLS, max(0, GetResource(random_start_ammo, RES_SHELLS)));
2087         SetResource(random_start_ammo, RES_BULLETS, max(0, GetResource(random_start_ammo, RES_BULLETS)));
2088         SetResource(random_start_ammo, RES_ROCKETS, max(0, GetResource(random_start_ammo, RES_ROCKETS)));
2089         SetResource(random_start_ammo, RES_CELLS, max(0, GetResource(random_start_ammo, RES_CELLS)));
2090         SetResource(random_start_ammo, RES_PLASMA, max(0, GetResource(random_start_ammo, RES_PLASMA)));
2091
2092         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
2093         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
2094         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
2095         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
2096         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
2097         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
2098 }
2099
2100 void readlevelcvars()
2101 {
2102         serverflags &= ~SERVERFLAG_ALLOW_FULLBRIGHT;
2103         if(cvar("sv_allow_fullbright"))
2104                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
2105
2106         sv_ready_restart_after_countdown = cvar("sv_ready_restart_after_countdown");
2107
2108         warmup_stage = cvar("g_warmup");
2109         warmup_limit = cvar("g_warmup_limit");
2110
2111         if(cvar("g_campaign"))
2112                 warmup_stage = 0; // no warmup during campaign
2113
2114         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
2115         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
2116         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
2117         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
2118         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
2119         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
2120         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
2121         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
2122         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
2123         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
2124         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
2125         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
2126         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
2127         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
2128
2129         g_pickup_shells = cvar("g_pickup_shells");
2130         g_pickup_shells_max = cvar("g_pickup_shells_max");
2131         g_pickup_nails = cvar("g_pickup_nails");
2132         g_pickup_nails_max = cvar("g_pickup_nails_max");
2133         g_pickup_rockets = cvar("g_pickup_rockets");
2134         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
2135         g_pickup_cells = cvar("g_pickup_cells");
2136         g_pickup_cells_max = cvar("g_pickup_cells_max");
2137         g_pickup_plasma = cvar("g_pickup_plasma");
2138         g_pickup_plasma_max = cvar("g_pickup_plasma_max");
2139         g_pickup_fuel = cvar("g_pickup_fuel");
2140         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
2141         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
2142         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
2143         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
2144         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
2145         g_pickup_armormedium = cvar("g_pickup_armormedium");
2146         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
2147         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
2148         g_pickup_armorbig = cvar("g_pickup_armorbig");
2149         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
2150         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
2151         g_pickup_armormega = cvar("g_pickup_armormega");
2152         g_pickup_armormega_max = cvar("g_pickup_armormega_max");
2153         g_pickup_armormega_anyway = cvar("g_pickup_armormega_anyway");
2154         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
2155         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
2156         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
2157         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
2158         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
2159         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
2160         g_pickup_healthbig = cvar("g_pickup_healthbig");
2161         g_pickup_healthbig_max = cvar("g_pickup_healthbig_max");
2162         g_pickup_healthbig_anyway = cvar("g_pickup_healthbig_anyway");
2163         g_pickup_healthmega = cvar("g_pickup_healthmega");
2164         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
2165         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
2166
2167         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
2168         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
2169
2170         g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
2171         if(!g_weapon_stay)
2172                 g_weapon_stay = cvar("g_weapon_stay");
2173
2174         MUTATOR_CALLHOOK(ReadLevelCvars);
2175
2176         if (!warmup_stage && !autocvar_g_campaign)
2177                 game_starttime = time + cvar("g_start_delay");
2178
2179         FOREACH(Weapons, it != WEP_Null, { it.wr_init(it); });
2180
2181         readplayerstartcvars();
2182 }
2183
2184 void InitializeEntity(entity e, void(entity this) func, int order)
2185 {
2186         entity prev, cur;
2187
2188         if (!e || e.initialize_entity)
2189         {
2190                 // make a proxy initializer entity
2191                 entity e_old = e;
2192                 e = new(initialize_entity);
2193                 e.enemy = e_old;
2194         }
2195
2196         e.initialize_entity = func;
2197         e.initialize_entity_order = order;
2198
2199         cur = initialize_entity_first;
2200         prev = NULL;
2201         for (;;)
2202         {
2203                 if (!cur || cur.initialize_entity_order > order)
2204                 {
2205                         // insert between prev and cur
2206                         if (prev)
2207                                 prev.initialize_entity_next = e;
2208                         else
2209                                 initialize_entity_first = e;
2210                         e.initialize_entity_next = cur;
2211                         return;
2212                 }
2213                 prev = cur;
2214                 cur = cur.initialize_entity_next;
2215         }
2216 }
2217 void InitializeEntitiesRun()
2218 {
2219         entity startoflist = initialize_entity_first;
2220         initialize_entity_first = NULL;
2221         delete_fn = remove_except_protected;
2222         for (entity e = startoflist; e; e = e.initialize_entity_next)
2223         {
2224                 e.remove_except_protected_forbidden = 1;
2225         }
2226         for (entity e = startoflist; e; )
2227         {
2228                 e.remove_except_protected_forbidden = 0;
2229                 e.initialize_entity_order = 0;
2230                 entity next = e.initialize_entity_next;
2231                 e.initialize_entity_next = NULL;
2232                 var void(entity this) func = e.initialize_entity;
2233                 e.initialize_entity = func_null;
2234                 if (e.classname == "initialize_entity")
2235                 {
2236                         entity wrappee = e.enemy;
2237                         builtin_remove(e);
2238                         e = wrappee;
2239                 }
2240                 //dprint("Delayed initialization: ", e.classname, "\n");
2241                 if (func)
2242                 {
2243                         func(e);
2244                 }
2245                 else
2246                 {
2247                         eprint(e);
2248                         backtrace(strcat("Null function in: ", e.classname, "\n"));
2249                 }
2250                 e = next;
2251         }
2252         delete_fn = remove_unsafely;
2253 }
2254
2255 // deferred dropping
2256 // ported from VM_SV_droptofloor TODO: make a common function for the client-side?
2257 void DropToFloor_Handler(entity this)
2258 {
2259         if(!this || wasfreed(this))
2260         {
2261                 // no modifying free entities
2262                 return;
2263         }
2264
2265         vector end = this.origin - '0 0 256';
2266
2267         // NOTE: NudgeOutOfSolid support is not added as Xonotic's physics do not use it!
2268         //if(autocvar_sv_gameplayfix_droptofloorstartsolid_nudgetocorrect)
2269                 //SV_NudgeOutOfSolid(this);
2270
2271         tracebox(this.origin, this.mins, this.maxs, end, MOVE_NORMAL, this);
2272
2273         if(trace_startsolid && autocvar_sv_gameplayfix_droptofloorstartsolid)
2274         {
2275                 vector offset, org;
2276                 offset = 0.5 * (this.mins + this.maxs);
2277                 offset.z = this.mins.z;
2278                 org = this.origin + offset;
2279                 traceline(org, end, MOVE_NORMAL, this);
2280                 trace_endpos = trace_endpos - offset;
2281                 if(trace_startsolid)
2282                 {
2283                         LOG_DEBUGF("DropToFloor_Handler: %v could not fix badly placed entity", this.origin);
2284                         _Movetype_LinkEdict(this, false);
2285                         SET_ONGROUND(this);
2286                         this.groundentity = NULL;
2287                 }
2288                 else if(trace_fraction < 1)
2289                 {
2290                         LOG_DEBUGF("DropToFloor_Handler: %v fixed badly placed entity", this.origin);
2291                         //if(autocvar_sv_gameplayfix_droptofloorstartsolid_nudgetocorrect)
2292                                 //SV_NudgeOutOfSolid(this);
2293                         setorigin(this, trace_endpos);
2294                         SET_ONGROUND(this);
2295                         this.groundentity = trace_ent;
2296                         // if support is destroyed, keep suspended (gross hack for floating items in various maps)
2297                         this.move_suspendedinair = true;
2298                 }
2299         }
2300         else
2301         {
2302                 if(!trace_allsolid && trace_fraction < 1)
2303                 {
2304                         setorigin(this, trace_endpos);
2305                         SET_ONGROUND(this);
2306                         this.groundentity = trace_ent;
2307                         // if support is destroyed, keep suspended (gross hack for floating items in various maps)
2308                         this.move_suspendedinair = true;
2309                 }
2310         }
2311         this.dropped_origin = this.origin;
2312 }
2313
2314 void droptofloor(entity this)
2315 {
2316         InitializeEntity(this, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
2317 }
2318
2319 bool autocvar_sv_gameplayfix_multiplethinksperframe = true;
2320 void RunThink(entity this, float dt)
2321 {
2322         // don't let things stay in the past.
2323         // it is possible to start that way by a trigger with a local time.
2324         if(this.nextthink <= 0 || this.nextthink > time + dt)
2325                 return;
2326
2327         float oldtime = time; // do we need to save this?
2328
2329         for (int iterations = 0; iterations < 128 && !wasfreed(this); iterations++)
2330         {
2331                 time = max(oldtime, this.nextthink);
2332                 this.nextthink = 0;
2333
2334                 if(getthink(this))
2335                         getthink(this)(this);
2336                 // mods often set nextthink to time to cause a think every frame,
2337                 // we don't want to loop in that case, so exit if the new nextthink is
2338                 // <= the time the qc was told, also exit if it is past the end of the
2339                 // frame
2340                 if(this.nextthink <= time || this.nextthink > oldtime + dt || !autocvar_sv_gameplayfix_multiplethinksperframe)
2341                         break;
2342         }
2343
2344         time = oldtime;
2345 }
2346
2347 bool autocvar_sv_freezenonclients;
2348 void Physics_Frame()
2349 {
2350         if(autocvar_sv_freezenonclients)
2351                 return;
2352
2353         IL_EACH(g_moveables, true,
2354         {
2355                 if(IS_CLIENT(it) || it.move_movetype == MOVETYPE_PHYSICS)
2356                         continue;
2357
2358                 //set_movetype(it, it.move_movetype);
2359                 // inline the set_movetype function, since this is called a lot
2360                 it.movetype = (it.move_qcphysics) ? MOVETYPE_QCENTITY : it.move_movetype;
2361
2362                 if(it.move_qcphysics && it.move_movetype != MOVETYPE_NONE)
2363                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2364
2365                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
2366                 {
2367                         if(it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH)
2368                                 continue; // these movetypes have no regular think function
2369                         // handle thinking here
2370                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + PHYS_INPUT_TIMELENGTH)
2371                                 RunThink(it, PHYS_INPUT_TIMELENGTH);
2372                 }
2373         });
2374
2375         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2376                 return;
2377
2378         // make a second pass to see if any ents spawned this frame and make
2379         // sure they run their move/think. this is verified by checking .move_time, which will never be 0 if the entity has moved
2380         // MOVETYPE_NONE is also checked as .move_time WILL be 0 with that movetype
2381         IL_EACH(g_moveables, it.move_qcphysics,
2382         {
2383                 if(IS_CLIENT(it) || it.move_time || it.move_movetype == MOVETYPE_NONE || it.move_movetype == MOVETYPE_PHYSICS)
2384                         continue;
2385                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2386         });
2387 }
2388
2389 void systems_update();
2390 void EndFrame()
2391 {
2392         anticheat_endframe();
2393
2394         Physics_Frame();
2395
2396         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2397                 entity e = IS_SPEC(it) ? it.enemy : it;
2398                 if (e.typehitsound) {
2399                         STAT(TYPEHIT_TIME, it) = time;
2400                 } else if (e.killsound) {
2401                         STAT(KILL_TIME, it) = time;
2402                 } else if (e.hitsound_damage_dealt) {
2403                         STAT(HIT_TIME, it) = time;
2404                         // NOTE: this is not accurate as client code doesn't need so much accuracy for its purposes
2405                         STAT(HITSOUND_DAMAGE_DEALT_TOTAL, it) += ceil(e.hitsound_damage_dealt);
2406                 }
2407         });
2408         // add 1 frametime because after this, engine SV_Physics
2409         // increases time by a frametime and then networks the frame
2410         // add another frametime because client shows everything with
2411         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2412         // needed!
2413         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2414         FOREACH_CLIENT(true, {
2415                 it.typehitsound = false;
2416                 it.hitsound_damage_dealt = 0;
2417                 it.killsound = false;
2418                 antilag_record(it, CS(it), altime);
2419         });
2420         IL_EACH(g_monsters, true,
2421         {
2422                 antilag_record(it, it, altime);
2423         });
2424         IL_EACH(g_projectiles, it.classname == "nade",
2425         {
2426                 antilag_record(it, it, altime);
2427         });
2428         systems_update();
2429         IL_ENDFRAME();
2430 }
2431
2432
2433 /*
2434  * RedirectionThink:
2435  * returns true if redirecting
2436  */
2437 float redirection_timeout;
2438 float redirection_nextthink;
2439 float RedirectionThink()
2440 {
2441         float clients_found;
2442
2443         if(redirection_target == "")
2444                 return false;
2445
2446         if(!redirection_timeout)
2447         {
2448                 cvar_set("sv_public", "-2");
2449                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2450                 if(redirection_target == "self")
2451                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2452                 else
2453                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2454         }
2455
2456         if(time < redirection_nextthink)
2457                 return true;
2458
2459         redirection_nextthink = time + 1;
2460
2461         clients_found = 0;
2462         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2463                 // TODO add timer
2464                 LOG_INFO("Redirecting: sending connect command to ", it.netname);
2465                 if(redirection_target == "self")
2466                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2467                 else
2468                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2469                 ++clients_found;
2470         });
2471
2472         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.");
2473
2474         if(time > redirection_timeout || clients_found == 0)
2475                 localcmd("\nwait; wait; wait; quit\n");
2476
2477         return true;
2478 }
2479
2480 void RestoreGame()
2481 {
2482         // Loaded from a save game
2483         // some things then break, so let's work around them...
2484
2485         // Progs DB (capture records)
2486         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2487
2488         // Mapinfo
2489         MapInfo_Shutdown();
2490         MapInfo_Enumerate();
2491         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2492         WeaponStats_Init();
2493
2494         TargetMusic_RestoreGame();
2495 }
2496
2497 void Shutdown()
2498 {
2499         game_stopped = 2;
2500
2501         if(world_initialized > 0)
2502         {
2503                 world_initialized = 0;
2504
2505                 // if a timeout is active, reset the slowmo value to normal
2506                 if(timeout_status == TIMEOUT_ACTIVE)
2507                         cvar_set("slowmo", ftos(orig_slowmo));
2508
2509                 LOG_TRACE("Saving persistent data...");
2510                 Ban_SaveBans();
2511
2512                 // playerstats with unfinished match
2513                 PlayerStats_GameReport(false);
2514
2515                 if(!cheatcount_total)
2516                 {
2517                         if(autocvar_sv_db_saveasdump)
2518                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2519                         else
2520                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2521                 }
2522                 if(autocvar_developer > 0)
2523                 {
2524                         if(autocvar_sv_db_saveasdump)
2525                                 db_dump(TemporaryDB, "server-temp.db");
2526                         else
2527                                 db_save(TemporaryDB, "server-temp.db");
2528                 }
2529                 CheatShutdown(); // must be after cheatcount check
2530                 db_close(ServerProgsDB);
2531                 db_close(TemporaryDB);
2532                 LOG_TRACE("Saving persistent data... done!");
2533                 // tell the bot system the game is ending now
2534                 bot_endgame();
2535
2536                 WeaponStats_Shutdown();
2537                 MapInfo_Shutdown();
2538
2539                 strfree(sv_termsofservice_url_escaped);
2540         }
2541         else if(world_initialized == 0)
2542         {
2543                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data");
2544         }
2545         else
2546         {
2547                 __init_dedicated_server_shutdown();
2548         }
2549 }