qcsrc/server/weapons/tracing.qc

   1 // this function calculates w_shotorg and w_shotdir based on the weapon model
   2 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
   3 // make sure you call makevectors first (FIXME?)
   4 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float chan, float maxdamage, float range)
   5 {
   6         float nudge = 1; // added to traceline target and subtracted from result
   7         float oldsolid;
   8         vector vecs, dv;
   9         oldsolid = ent.dphitcontentsmask;
  10         if(ent.weapon == WEP_RIFLE)
  11                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  12         else
  13                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  14         if(antilag)
  15                 WarpZone_traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  16                 // passing world, because we do NOT want it to touch dphitcontentsmask
  17         else
  18                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
  19         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  20
  21         vector vf, vr, vu;
  22         vf = v_forward;
  23         vr = v_right;
  24         vu = v_up;
  25         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
  26         v_forward = vf;
  27         v_right = vr;
  28         v_up = vu;
  29
  30         // un-adjust trueaim if shotend is too close
  31         if(vlen(w_shotend - (ent.origin + ent.view_ofs)) < autocvar_g_trueaim_minrange)
  32                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
  33
  34         // track max damage
  35         if(accuracy_canbegooddamage(ent))
  36                 accuracy_add(ent, ent.weapon, maxdamage, 0);
  37
  38         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
  39
  40         if(ent.weaponentity.movedir_x > 0)
  41                 vecs = ent.weaponentity.movedir;
  42         else
  43                 vecs = '0 0 0';
  44
  45         dv = v_right * -vecs_y + v_up * vecs_z;
  46         w_shotorg = ent.origin + ent.view_ofs + dv;
  47
  48         // now move the shotorg forward as much as requested if possible
  49         if(antilag)
  50         {
  51                 if(ent.antilag_debug)
  52                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
  53                 else
  54                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  55         }
  56         else
  57                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent);
  58         w_shotorg = trace_endpos - v_forward * nudge;
  59         // calculate the shotdir from the chosen shotorg
  60         w_shotdir = normalize(w_shotend - w_shotorg);
  61
  62         if (antilag)
  63         if (!ent.cvar_cl_noantilag)
  64         {
  65                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
  66                 {
  67                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
  68                         if (!trace_ent.takedamage)
  69                         {
  70                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  71                                 if (trace_ent.takedamage && IS_PLAYER(trace_ent))
  72                                 {
  73                                         entity e;
  74                                         e = trace_ent;
  75                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
  76                                         if(trace_ent == e)
  77                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
  78                                 }
  79                         }
  80                 }
  81                 else if(autocvar_g_antilag == 3) // client side hitscan
  82                 {
  83                         // this part MUST use prydon cursor
  84                         if (ent.cursor_trace_ent)                 // client was aiming at someone
  85                         if (ent.cursor_trace_ent != ent)         // just to make sure
  86                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
  87                         if (IS_PLAYER(ent.cursor_trace_ent)) // and actually a player
  88                         {
  89                                 // verify that the shot would miss without antilag
  90                                 // (avoids an issue where guns would always shoot at their origin)
  91                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
  92                                 if (!trace_ent.takedamage)
  93                                 {
  94                                         // verify that the shot would hit if altered
  95                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
  96                                         if (trace_ent == ent.cursor_trace_ent)
  97                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
  98                                         else
  99                                                 print("antilag fail\n");
 100                                 }
 101                         }
 102                 }
 103         }
 104
 105         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 106
 107         if (!autocvar_g_norecoil)
 108                 ent.punchangle_x = recoil * -1;
 109
 110         if (snd != "")
 111         {
 112                 sound (ent, chan, snd, VOL_BASE, ATTN_NORM);
 113                 W_PlayStrengthSound(ent);
 114         }
 115
 116         // nudge w_shotend so a trace to w_shotend hits
 117         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
 118 }
 119
 120 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity, float forceAbsolute)
 121 {
 122         vector mdirection;
 123         float mspeed;
 124         vector outvelocity;
 125
 126         mvelocity = mvelocity * g_weaponspeedfactor;
 127
 128         mdirection = normalize(mvelocity);
 129         mspeed = vlen(mvelocity);
 130
 131         outvelocity = get_shotvelocity(pvelocity, mdirection, mspeed, (forceAbsolute ? 0 : autocvar_g_projectiles_newton_style), autocvar_g_projectiles_newton_style_2_minfactor, autocvar_g_projectiles_newton_style_2_maxfactor);
 132
 133         return outvelocity;
 134 }
 135
 136 void W_SetupProjectileVelocityEx(entity missile, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
 137 {
 138         if(missile.owner == world)
 139                 error("Unowned missile");
 140
 141         dir = dir + upDir * (pUpSpeed / pSpeed);
 142         dir_z += pZSpeed / pSpeed;
 143         pSpeed *= vlen(dir);
 144         dir = normalize(dir);
 145
 146 #if 0
 147         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
 148         {
 149                 mspercallsum = mspercallcount = 0;
 150                 mspercallsstyle = autocvar_g_projectiles_spread_style;
 151         }
 152         mspercallsum -= gettime(GETTIME_HIRES);
 153 #endif
 154         dir = W_CalculateSpread(dir, spread, g_weaponspreadfactor, autocvar_g_projectiles_spread_style);
 155 #if 0
 156         mspercallsum += gettime(GETTIME_HIRES);
 157         mspercallcount += 1;
 158         print("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
 159 #endif
 160
 161         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, pSpeed * dir, forceAbsolute);
 162 }
 163
 164
 165 // ====================
 166 //  Ballistics Tracing
 167 // ====================
 168
 169 void FireRailgunBullet (vector start, vector end, float bdamage, float bforce, float mindist, float maxdist, float halflifedist, float forcehalflifedist, float deathtype)
 170 {
 171         vector hitloc, force, endpoint, dir;
 172         entity ent, endent;
 173         float endq3surfaceflags;
 174         float totaldmg;
 175         entity o;
 176
 177         float length;
 178         vector beampos;
 179         string snd;
 180         entity pseudoprojectile;
 181         float f, ffs;
 182
 183         pseudoprojectile = world;
 184
 185         dir = normalize(end - start);
 186         length = vlen(end - start);
 187         force = dir * bforce;
 188
 189         // go a little bit into the wall because we need to hit this wall later
 190         end = end + dir;
 191
 192         totaldmg = 0;
 193
 194         // trace multiple times until we hit a wall, each obstacle will be made
 195         // non-solid so we can hit the next, while doing this we spawn effects and
 196         // note down which entities were hit so we can damage them later
 197         o = self;
 198         while (1)
 199         {
 200                 if(self.antilag_debug)
 201                         WarpZone_traceline_antilag (self, start, end, FALSE, o, self.antilag_debug);
 202                 else
 203                         WarpZone_traceline_antilag (self, start, end, FALSE, o, ANTILAG_LATENCY(self));
 204                 if(o && WarpZone_trace_firstzone)
 205                 {
 206                         o = world;
 207                         continue;
 208                 }
 209
 210                 if(trace_ent.solid == SOLID_BSP || trace_ent.solid == SOLID_SLIDEBOX)
 211                         Damage_DamageInfo(trace_endpos, bdamage, 0, 0, force, deathtype, trace_ent.species, self);
 212
 213                 // if it is world we can't hurt it so stop now
 214                 if (trace_ent == world || trace_fraction == 1)
 215                         break;
 216
 217                 // make the entity non-solid so we can hit the next one
 218                 trace_ent.railgunhit = TRUE;
 219                 trace_ent.railgunhitloc = end;
 220                 trace_ent.railgunhitsolidbackup = trace_ent.solid;
 221                 trace_ent.railgundistance = vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos) - start);
 222                 trace_ent.railgunforce = WarpZone_TransformVelocity(WarpZone_trace_transform, force);
 223
 224                 // stop if this is a wall
 225                 if (trace_ent.solid == SOLID_BSP)
 226                         break;
 227
 228                 // make the entity non-solid
 229                 trace_ent.solid = SOLID_NOT;
 230         }
 231
 232         endpoint = trace_endpos;
 233         endent = trace_ent;
 234         endq3surfaceflags = trace_dphitq3surfaceflags;
 235
 236         // find all the entities the railgun hit and restore their solid state
 237         ent = findfloat(world, railgunhit, TRUE);
 238         while (ent)
 239         {
 240                 // restore their solid type
 241                 ent.solid = ent.railgunhitsolidbackup;
 242                 ent = findfloat(ent, railgunhit, TRUE);
 243         }
 244
 245         // spawn a temporary explosion entity for RadiusDamage calls
 246         //explosion = spawn();
 247
 248         // Find all non-hit players the beam passed close by
 249         if(deathtype == WEP_VAPORIZER || deathtype == WEP_VORTEX)
 250         {
 251                 FOR_EACH_REALCLIENT(msg_entity)
 252                 if(msg_entity != self)
 253                 if(!msg_entity.railgunhit)
 254                 if(!(IS_SPEC(msg_entity) && msg_entity.enemy == self)) // we use realclient, so spectators can hear the whoosh too
 255                 {
 256                         // nearest point on the beam
 257                         beampos = start + dir * bound(0, (msg_entity.origin - start) * dir, length);
 258
 259                         f = bound(0, 1 - vlen(beampos - msg_entity.origin) / 512, 1);
 260                         if(f <= 0)
 261                                 continue;
 262
 263                         snd = strcat("weapons/nexwhoosh", ftos(floor(random() * 3) + 1), ".wav");
 264
 265                         if(!pseudoprojectile)
 266                                 pseudoprojectile = spawn(); // we need this so the sound uses the "entchannel4" volume
 267                         soundtoat(MSG_ONE, pseudoprojectile, beampos, CH_SHOTS, snd, VOL_BASE * f, ATTEN_NONE);
 268                 }
 269
 270                 if(pseudoprojectile)
 271                         remove(pseudoprojectile);
 272         }
 273
 274         // find all the entities the railgun hit and hurt them
 275         ent = findfloat(world, railgunhit, TRUE);
 276         while (ent)
 277         {
 278                 // get the details we need to call the damage function
 279                 hitloc = ent.railgunhitloc;
 280
 281                 f = ExponentialFalloff(mindist, maxdist, halflifedist, ent.railgundistance);
 282                 ffs = ExponentialFalloff(mindist, maxdist, forcehalflifedist, ent.railgundistance);
 283
 284                 if(accuracy_isgooddamage(self.realowner, ent))
 285                         totaldmg += bdamage * f;
 286
 287                 // apply the damage
 288                 if (ent.takedamage)
 289                         Damage (ent, self, self, bdamage * f, deathtype, hitloc, ent.railgunforce * ffs);
 290
 291                 // create a small explosion to throw gibs around (if applicable)
 292                 //setorigin (explosion, hitloc);
 293                 //RadiusDamage (explosion, self, 10, 0, 50, world, world, 300, deathtype);
 294
 295                 ent.railgunhitloc = '0 0 0';
 296                 ent.railgunhitsolidbackup = SOLID_NOT;
 297                 ent.railgunhit = FALSE;
 298                 ent.railgundistance = 0;
 299
 300                 // advance to the next entity
 301                 ent = findfloat(ent, railgunhit, TRUE);
 302         }
 303
 304         // calculate hits and fired shots for hitscan
 305         accuracy_add(self, self.weapon, 0, min(bdamage, totaldmg));
 306
 307         trace_endpos = endpoint;
 308         trace_ent = endent;
 309         trace_dphitq3surfaceflags = endq3surfaceflags;
 310 }
 311
 312 void fireBullet_trace_callback(vector start, vector hit, vector end)
 313 {
 314         if(vlen(hit - start) > 16)
 315                 trailparticles(world, fireBullet_trace_callback_eff, start, hit);
 316         WarpZone_trace_forent = world;
 317         fireBullet_last_hit = world;
 318 }
 319
 320 void fireBullet(vector start, vector dir, float spread, float max_solid_penetration, float damage, float force, float dtype, float tracereffects)
 321 {
 322         vector  end;
 323
 324         dir = normalize(dir + randomvec() * spread);
 325         end = start + dir * MAX_SHOT_DISTANCE;
 326
 327         entity pl;
 328         fireBullet_last_hit = world;
 329         float solid_penetration_left = 1;
 330         float total_damage = 0;
 331
 332         if(tracereffects & EF_RED)
 333                 fireBullet_trace_callback_eff = particleeffectnum("tr_rifle");
 334         else if(tracereffects & EF_BLUE)
 335                 fireBullet_trace_callback_eff = particleeffectnum("tr_rifle_weak");
 336         else
 337                 fireBullet_trace_callback_eff = particleeffectnum("tr_bullet");
 338
 339         float lag = ANTILAG_LATENCY(self);
 340         if(lag < 0.001)
 341                 lag = 0;
 342         if (!IS_REAL_CLIENT(self))
 343                 lag = 0;
 344         if(autocvar_g_antilag == 0 || self.cvar_cl_noantilag)
 345                 lag = 0; // only do hitscan, but no antilag
 346         if(lag)
 347                 FOR_EACH_PLAYER(pl)
 348                         if(pl != self)
 349                                 antilag_takeback(pl, time - lag);
 350
 351         WarpZone_trace_forent = self;
 352
 353         for (;;)
 354         {
 355                 // TODO also show effect while tracing
 356                 WarpZone_TraceBox_ThroughZone(start, '0 0 0', '0 0 0', end, FALSE, WarpZone_trace_forent, world, fireBullet_trace_callback);
 357                 dir = WarpZone_TransformVelocity(WarpZone_trace_transform, dir);
 358                 end = WarpZone_TransformOrigin(WarpZone_trace_transform, end);
 359                 start = trace_endpos;
 360                 entity hit = trace_ent;
 361
 362                 // When hitting sky, stop.
 363                 if (pointcontents(start) == CONTENT_SKY)
 364                         break;
 365
 366                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 367                         break;
 368
 369                 // if we hit "weapclip", bail out
 370                 //
 371                 // rationale of this check:
 372                 //
 373                 // any shader that is solid, nodraw AND trans is meant to clip weapon
 374                 // shots and players, but has no other effect!
 375                 //
 376                 // if it is not trans, it is caulk and should not have this side effect
 377                 //
 378                 // matching shaders:
 379                 //   common/weapclip (intended)
 380                 //   common/noimpact (is supposed to eat projectiles, but is erased anyway)
 381                 float is_weapclip = 0;
 382                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODRAW)
 383                 if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NONSOLID))
 384                 if (!(trace_dphitcontents & DPCONTENTS_OPAQUE))
 385                         is_weapclip = 1;
 386
 387                 if(!hit || hit.solid == SOLID_BSP || hit.solid == SOLID_SLIDEBOX)
 388                         Damage_DamageInfo(start, damage * solid_penetration_left, 0, 0, max(1, force) * dir * solid_penetration_left, dtype, hit.species, self);
 389
 390                 if (hit && hit != WarpZone_trace_forent && hit != fireBullet_last_hit)  // Avoid self-damage (except after going through a warp); avoid hitting the same entity twice (engine bug).
 391                 {
 392                         fireBullet_last_hit = hit;
 393                         yoda = 0;
 394                         float g = accuracy_isgooddamage(self, hit);
 395                         Damage(hit, self, self, damage * solid_penetration_left, dtype, start, force * dir * solid_penetration_left);
 396                         // calculate hits for ballistic weapons
 397                         if(g)
 398                         {
 399                                 // do not exceed 100%
 400                                 float added_damage = min(damage - total_damage, damage * solid_penetration_left);
 401                                 total_damage += damage * solid_penetration_left;
 402                                 accuracy_add(self, self.weapon, 0, added_damage);
 403                         }
 404                 }
 405
 406                 if (is_weapclip)
 407                         break;
 408
 409                 // go through solid!
 410                 // outside the world? forget it
 411                 if(start_x > world.maxs_x || start_y > world.maxs_y || start_z > world.maxs_z || start_x < world.mins_x || start_y < world.mins_y || start_z < world.mins_z)
 412                         break;
 413
 414                 float maxdist;
 415                 if(max_solid_penetration < 0)
 416                         break;
 417                 else if(hit.ballistics_density < -1)
 418                         break; // -2: no solid penetration, ever
 419                 else if(hit.ballistics_density < 0)
 420                         maxdist = vlen(hit.maxs - hit.mins) + 1; // -1: infinite travel distance
 421                 else if(hit.ballistics_density == 0)
 422                         maxdist = max_solid_penetration * solid_penetration_left;
 423                 else
 424                         maxdist = max_solid_penetration * solid_penetration_left * hit.ballistics_density;
 425
 426                 if(maxdist <= autocvar_g_ballistics_mindistance)
 427                         break;
 428
 429                 // move the entity along its velocity until it's out of solid, then let it resume
 430                 // The previously hit entity is ignored here!
 431                 traceline_inverted (start, start + dir * maxdist, MOVE_NORMAL, WarpZone_trace_forent, TRUE, hit);
 432                 if(trace_fraction == 1) // 1: we never got out of solid
 433                         break;
 434
 435                 float dist_taken = max(autocvar_g_ballistics_mindistance, vlen(trace_endpos - start));
 436                 solid_penetration_left *= (dist_taken / maxdist);
 437
 438                 // Only show effect when going through a player (invisible otherwise)
 439                 if (hit && (hit.solid != SOLID_BSP))
 440                         if(vlen(trace_endpos - start) > 4)
 441                                 trailparticles(self, fireBullet_trace_callback_eff, start, trace_endpos);
 442
 443                 start = trace_endpos;
 444
 445                 if(hit.solid == SOLID_BSP)
 446                         Damage_DamageInfo(start, 0, 0, 0, max(1, force) * normalize(dir) * -solid_penetration_left, dtype, 0, self);
 447         }
 448
 449         if(lag)
 450                 FOR_EACH_PLAYER(pl)
 451                         if(pl != self)
 452                                 antilag_restore(pl);
 453 }