qcsrc/server/waypointsprites.qc

   1 ..entity owned_by_field;
   2 .float rule;
   3 .string model1;
   4 .string model2;
   5 .string model3;
   6
   7 .float(entity) waypointsprite_visible_for_player;
   8
   9 void WaypointSprite_UpdateSprites(entity e, string m1, string m2, string m3)
  10 {
  11         if(m1 != e.model1)
  12         {
  13                 e.model1 = m1;
  14                 e.SendFlags |= 2;
  15         }
  16         if(m2 != e.model2)
  17         {
  18                 e.model2 = m2;
  19                 e.SendFlags |= 4;
  20         }
  21         if(m3 != e.model3)
  22         {
  23                 e.model3 = m3;
  24                 e.SendFlags |= 8;
  25         }
  26 }
  27
  28 void WaypointSprite_UpdateHealth(entity e, float f)
  29 {
  30         f = bound(0, f, e.max_health);
  31         if(f != e.health || e.pain_finished)
  32         {
  33                 e.health = f;
  34                 e.pain_finished = 0;
  35                 e.SendFlags |= 0x80;
  36         }
  37 }
  38
  39 void WaypointSprite_UpdateMaxHealth(entity e, float f)
  40 {
  41         if(f != e.max_health || e.pain_finished)
  42         {
  43                 e.max_health = f;
  44                 e.pain_finished = 0;
  45                 e.SendFlags |= 0x80;
  46         }
  47 }
  48
  49 void WaypointSprite_UpdateBuildFinished(entity e, float f)
  50 {
  51         if(f != e.pain_finished || e.max_health)
  52         {
  53                 e.max_health = 0;
  54                 e.pain_finished = f;
  55                 e.SendFlags |= 0x80;
  56         }
  57 }
  58
  59 void WaypointSprite_UpdateOrigin(entity e, vector o)
  60 {
  61         if(o != e.origin)
  62         {
  63                 setorigin(e, o);
  64                 e.SendFlags |= 64;
  65         }
  66 }
  67
  68 void WaypointSprite_UpdateRule(entity e, float t, float r)
  69 {
  70         // no check, as this is never called without doing an actual change (usually only once)
  71         e.rule = r;
  72         e.team = t;
  73         e.SendFlags |= 1;
  74 }
  75
  76 void WaypointSprite_UpdateTeamRadar(entity e, float icon, vector col)
  77 {
  78         // no check, as this is never called without doing an actual change (usually only once)
  79         e.cnt = (icon & 0x7F) | (e.cnt & 0x80);
  80         e.colormod = col;
  81         e.SendFlags |= 32;
  82 }
  83
  84 .float waypointsprite_pingtime;
  85 .float waypointsprite_helpmetime;
  86 void WaypointSprite_Ping(entity e)
  87 {
  88         // anti spam
  89         if(time < e.waypointsprite_pingtime)
  90                 return;
  91         e.waypointsprite_pingtime = time + 0.3;
  92         // ALWAYS sends (this causes a radar circle), thus no check
  93         e.cnt |= 0x80;
  94         e.SendFlags |= 32;
  95 }
  96
  97 float waypointsprite_limitedrange, waypointsprite_deployed_lifetime, waypointsprite_deadlifetime;
  98
  99 void WaypointSprite_HelpMePing(entity e)
 100 {
 101         WaypointSprite_Ping(e);
 102         e.waypointsprite_helpmetime = time + waypointsprite_deployed_lifetime;
 103         e.SendFlags |= 32;
 104 }
 105
 106 void WaypointSprite_FadeOutIn(entity e, float t)
 107 {
 108         if(!e.fade_time)
 109         {
 110                 e.fade_time = t;
 111                 e.teleport_time = time + t;
 112         }
 113         else if(t < (e.teleport_time - time))
 114         {
 115                 // accelerate the waypoint's dying
 116                 // ensure:
 117                 //   (e.teleport_time - time) / wp.fade_time stays
 118                 //   e.teleport_time = time + fadetime
 119                 float current_fadetime;
 120                 current_fadetime = e.teleport_time - time;
 121                 e.teleport_time = time + t;
 122                 e.fade_time = e.fade_time * t / current_fadetime;
 123         }
 124
 125         e.SendFlags |= 16;
 126 }
 127
 128 void WaypointSprite_Init()
 129 {
 130         waypointsprite_limitedrange = autocvar_g_waypointsprite_limitedrange;
 131         waypointsprite_deployed_lifetime = autocvar_g_waypointsprite_deployed_lifetime;
 132         waypointsprite_deadlifetime = autocvar_g_waypointsprite_deadlifetime;
 133 }
 134 void WaypointSprite_InitClient(entity e)
 135 {
 136 }
 137
 138 void WaypointSprite_Kill(entity wp)
 139 {
 140         if(!wp)
 141                 return;
 142         if(wp.owner)
 143                 wp.owner.(wp.owned_by_field) = world;
 144         remove(wp);
 145 }
 146
 147 void WaypointSprite_Disown(entity wp, float fadetime)
 148 {
 149         if(!wp)
 150                 return;
 151         if(wp.classname != "sprite_waypoint")
 152         {
 153                 backtrace("Trying to disown a non-waypointsprite");
 154                 return;
 155         }
 156         if(wp.owner)
 157         {
 158                 if(wp.exteriormodeltoclient == wp.owner)
 159                         wp.exteriormodeltoclient = world;
 160                 wp.owner.(wp.owned_by_field) = world;
 161                 wp.owner = world;
 162
 163                 WaypointSprite_FadeOutIn(wp, fadetime);
 164         }
 165 }
 166
 167 void WaypointSprite_Think()
 168 {
 169         float doremove;
 170
 171         doremove = FALSE;
 172
 173         if(self.fade_time)
 174         {
 175                 if(time >= self.teleport_time)
 176                         doremove = TRUE;
 177         }
 178
 179         if(self.exteriormodeltoclient)
 180                 WaypointSprite_UpdateOrigin(self, self.exteriormodeltoclient.origin + self.view_ofs);
 181
 182         if(doremove)
 183                 WaypointSprite_Kill(self);
 184         else
 185                 self.nextthink = time; // WHY?!?
 186 }
 187
 188 float WaypointSprite_visible_for_player(entity e)
 189 {
 190         // personal waypoints
 191         if(self.enemy)
 192                 if(self.enemy != e)
 193                         return FALSE;
 194
 195         // team waypoints
 196         if(self.team && self.rule == SPRITERULE_DEFAULT)
 197         {
 198                 if(self.team != e.team)
 199                         return FALSE;
 200                 if(e.classname != "player")
 201                         return FALSE;
 202         }
 203
 204         return TRUE;
 205 }
 206
 207 entity WaypointSprite_getviewentity(entity e)
 208 {
 209         if(e.classname == "spectator")
 210                 e = e.enemy;
 211         /* TODO idea (check this breaks nothing)
 212         else if(e.classname == "observer")
 213                 e = world;
 214         */
 215         return e;
 216 }
 217
 218 float WaypointSprite_isteammate(entity e, entity e2)
 219 {
 220         if(teamplay)
 221         {
 222                 if(e2.team != e.team)
 223                         return FALSE;
 224         }
 225         else
 226         {
 227                 if(e2 != e)
 228                         return FALSE;
 229         }
 230         return TRUE;
 231 }
 232
 233 float WaypointSprite_Customize()
 234 {
 235         // this is not in SendEntity because it shall run every frame, not just every update
 236
 237         // make spectators see what the player would see
 238         entity e;
 239         e = WaypointSprite_getviewentity(other);
 240
 241         // as a GENERAL rule:
 242         // if you have the invisibility powerup, sprites ALWAYS are restricted to your team
 243         // but only apply this to real players, not to spectators
 244         if(g_minstagib && (self.owner.items & IT_STRENGTH) && (e == other))
 245         {
 246                 if(!WaypointSprite_isteammate(self.owner, e))
 247                         return FALSE;
 248         }
 249
 250         return self.waypointsprite_visible_for_player(e);
 251 }
 252
 253 float WaypointSprite_SendEntity(entity to, float sendflags)
 254 {
 255         float dt;
 256
 257         WriteByte(MSG_ENTITY, ENT_CLIENT_WAYPOINT);
 258
 259         sendflags = sendflags & 0x7F;
 260
 261         if(g_nexball)
 262                 sendflags &~= 0x80;
 263         else if(self.max_health || (self.pain_finished && (time < self.pain_finished + 0.25)))
 264                 sendflags |= 0x80;
 265
 266         WriteByte(MSG_ENTITY, sendflags);
 267
 268         if(sendflags & 0x80)
 269         {
 270                 if(self.max_health)
 271                 {
 272                         WriteByte(MSG_ENTITY, (self.health / self.max_health) * 191.0);
 273                 }
 274                 else
 275                 {
 276                         dt = self.pain_finished - time;
 277                         dt = bound(0, dt * 32, 16383);
 278                         WriteByte(MSG_ENTITY, (dt & 0xFF00) / 256 + 192);
 279                         WriteByte(MSG_ENTITY, (dt & 0x00FF));
 280                 }
 281         }
 282
 283         if(sendflags & 64)
 284         {
 285                 WriteCoord(MSG_ENTITY, self.origin_x);
 286                 WriteCoord(MSG_ENTITY, self.origin_y);
 287                 WriteCoord(MSG_ENTITY, self.origin_z);
 288         }
 289
 290         if(sendflags & 1)
 291         {
 292                 WriteByte(MSG_ENTITY, self.team);
 293                 WriteByte(MSG_ENTITY, self.rule);
 294         }
 295
 296         if(sendflags & 2)
 297                 WriteString(MSG_ENTITY, self.model1);
 298
 299         if(sendflags & 4)
 300                 WriteString(MSG_ENTITY, self.model2);
 301
 302         if(sendflags & 8)
 303                 WriteString(MSG_ENTITY, self.model3);
 304
 305         if(sendflags & 16)
 306         {
 307                 WriteCoord(MSG_ENTITY, self.fade_time);
 308                 WriteCoord(MSG_ENTITY, self.teleport_time);
 309                 WriteShort(MSG_ENTITY, self.fade_rate); // maxdist
 310                 float f;
 311                 f = 0;
 312                 if(self.currentammo)
 313                         f |= 1; // hideable
 314                 if(self.exteriormodeltoclient == to)
 315                         f |= 2; // my own
 316                 WriteByte(MSG_ENTITY, f);
 317         }
 318
 319         if(sendflags & 32)
 320         {
 321                 WriteByte(MSG_ENTITY, self.cnt); // icon on radar
 322                 WriteByte(MSG_ENTITY, self.colormod_x * 255.0);
 323                 WriteByte(MSG_ENTITY, self.colormod_y * 255.0);
 324                 WriteByte(MSG_ENTITY, self.colormod_z * 255.0);
 325
 326                 if(WaypointSprite_isteammate(self.owner, WaypointSprite_getviewentity(to)))
 327                 {
 328                         dt = (self.waypointsprite_helpmetime - time) / 0.1;
 329                         if(dt < 0)
 330                                 dt = 0;
 331                         if(dt > 255)
 332                                 dt = 255;
 333                         WriteByte(MSG_ENTITY, dt);
 334                 }
 335                 else
 336                         WriteByte(MSG_ENTITY, 0);
 337         }
 338
 339         return TRUE;
 340 }
 341
 342 void WaypointSprite_Reset()
 343 {
 344         // if a WP wants to time out, let it time out immediately; other WPs ought to be reset/killed by their owners
 345
 346         if(self.fade_time) // there was there before: || g_keyhunt, do we really need this?
 347                 WaypointSprite_Kill(self);
 348 }
 349
 350 entity WaypointSprite_Spawn(
 351         string spr, // sprite
 352         float lifetime, float maxdistance, // lifetime, max distance
 353         entity ref, vector ofs, // position
 354         entity showto, float t, // show to whom? Use a flag to indicate a team
 355         entity own, .entity ownfield, // remove when own gets killed
 356         float hideable, // true when it should be controlled by cl_hidewaypoints
 357         float icon, vector rgb // initial icon and color
 358 )
 359 {
 360         entity wp;
 361         wp = spawn();
 362         wp.classname = "sprite_waypoint";
 363         wp.teleport_time = time + lifetime;
 364         wp.fade_time = lifetime;
 365         wp.exteriormodeltoclient = ref;
 366         if(ref)
 367         {
 368                 wp.view_ofs = ofs;
 369                 setorigin(wp, ref.origin + ofs);
 370         }
 371         else
 372                 setorigin(wp, ofs);
 373         wp.enemy = showto;
 374         wp.team = t;
 375         wp.owner = own;
 376         wp.currentammo = hideable;
 377         if(own)
 378         {
 379                 if(own.ownfield)
 380                         remove(own.ownfield);
 381                 own.ownfield = wp;
 382                 wp.owned_by_field = ownfield;
 383         }
 384         wp.fade_rate = maxdistance;
 385         wp.think = WaypointSprite_Think;
 386         wp.nextthink = time;
 387         wp.model1 = spr;
 388         wp.customizeentityforclient = WaypointSprite_Customize;
 389         wp.waypointsprite_visible_for_player = WaypointSprite_visible_for_player;
 390         wp.reset2 = WaypointSprite_Reset;
 391         wp.cnt = icon;
 392         wp.colormod = rgb;
 393         Net_LinkEntity(wp, FALSE, 0, WaypointSprite_SendEntity);
 394         return wp;
 395 }
 396
 397 entity WaypointSprite_SpawnFixed(
 398         string spr,
 399         vector ofs,
 400         entity own,
 401         .entity ownfield,
 402         float icon, vector rgb // initial icon and color
 403 )
 404 {
 405         return WaypointSprite_Spawn(spr, 0, 0, world, ofs, world, 0, own, ownfield, TRUE, icon, rgb);
 406 }
 407
 408 .entity waypointsprite_deployed_fixed;
 409 entity WaypointSprite_DeployFixed(
 410         string spr,
 411         float limited_range,
 412         vector ofs,
 413         float icon, vector rgb // initial icon and color
 414 )
 415 {
 416         float t, maxdistance;
 417         if(teamplay)
 418                 t = self.team;
 419         else
 420                 t = 0;
 421         if(limited_range)
 422                 maxdistance = waypointsprite_limitedrange;
 423         else
 424                 maxdistance = 0;
 425         return WaypointSprite_Spawn(spr, waypointsprite_deployed_lifetime, maxdistance, world, ofs, world, t, self, waypointsprite_deployed_fixed, FALSE, icon, rgb);
 426 }
 427
 428 .entity waypointsprite_deployed_personal;
 429 entity WaypointSprite_DeployPersonal(
 430         string spr,
 431         vector ofs,
 432         float icon, vector rgb // initial icon and color
 433 )
 434 {
 435         return WaypointSprite_Spawn(spr, 0, 0, world, ofs, world, 0, self, waypointsprite_deployed_personal, FALSE, icon, rgb);
 436 }
 437
 438 .entity waypointsprite_attached;
 439 .entity waypointsprite_attachedforcarrier;
 440 entity WaypointSprite_Attach(
 441         string spr,
 442         float limited_range,
 443         float icon, vector rgb // initial icon and color
 444 )
 445 {
 446         float t, maxdistance;
 447         if(self.waypointsprite_attachedforcarrier)
 448                 return world; // can't attach to FC
 449         if(teamplay)
 450                 t = self.team;
 451         else
 452                 t = 0;
 453         if(limited_range)
 454                 maxdistance = waypointsprite_limitedrange;
 455         else
 456                 maxdistance = 0;
 457         return WaypointSprite_Spawn(spr, waypointsprite_deployed_lifetime, maxdistance, self, '0 0 64', world, t, self, waypointsprite_attached, FALSE, icon, rgb);
 458 }
 459
 460 entity WaypointSprite_AttachCarrier(
 461         string spr,
 462         entity carrier,
 463         float icon, vector rgb // initial icon and color
 464 )
 465 {
 466         entity e;
 467         WaypointSprite_Kill(carrier.waypointsprite_attached); // FC overrides attached
 468         e = WaypointSprite_Spawn(spr, 0, 0, carrier, '0 0 64', world, carrier.team, carrier, waypointsprite_attachedforcarrier, FALSE, icon, rgb);
 469         if(e)
 470         {
 471                 WaypointSprite_UpdateMaxHealth(e, '1 0 0' * healtharmor_maxdamage(start_health, start_armorvalue, autocvar_g_balance_armor_blockpercent) * 2);
 472                 WaypointSprite_UpdateHealth(e, '1 0 0' * healtharmor_maxdamage(carrier.health, carrier.armorvalue, autocvar_g_balance_armor_blockpercent));
 473         }
 474         return e;
 475 }
 476
 477 void WaypointSprite_DetachCarrier(entity carrier)
 478 {
 479         WaypointSprite_Disown(carrier.waypointsprite_attachedforcarrier, waypointsprite_deadlifetime);
 480 }
 481
 482 void WaypointSprite_ClearPersonal()
 483 {
 484         WaypointSprite_Kill(self.waypointsprite_deployed_personal);
 485 }
 486
 487 void WaypointSprite_ClearOwned()
 488 {
 489         WaypointSprite_Kill(self.waypointsprite_deployed_fixed);
 490         WaypointSprite_Kill(self.waypointsprite_deployed_personal);
 491         WaypointSprite_Kill(self.waypointsprite_attached);
 492 }
 493
 494 void WaypointSprite_PlayerDead()
 495 {
 496         WaypointSprite_Disown(self.waypointsprite_attached, waypointsprite_deadlifetime);
 497         WaypointSprite_DetachCarrier(self);
 498 }
 499
 500 void WaypointSprite_PlayerGone()
 501 {
 502         WaypointSprite_Disown(self.waypointsprite_deployed_fixed, waypointsprite_deadlifetime);
 503         WaypointSprite_Kill(self.waypointsprite_deployed_personal);
 504         WaypointSprite_Disown(self.waypointsprite_attached, waypointsprite_deadlifetime);
 505         WaypointSprite_DetachCarrier(self);
 506 }