qcsrc/server/w_nex.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(NEX, w_nex, IT_CELLS, 7, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_HIGH, "nex", "nex", _("Nex"))
   3 #else
   4 #ifdef SVQC
   5
   6 void W_Nex_Reload()
   7 {
   8         self.reload_ammo_player = ammo_cells;
   9         self.reload_ammo_min = min(autocvar_g_balance_nex_primary_ammo, autocvar_g_balance_nex_secondary_ammo);
  10         self.reload_ammo_amount = autocvar_g_balance_nex_reload_ammo;
  11         self.reload_time = autocvar_g_balance_nex_reload_time;
  12         self.reload_sound = "weapons/reload.wav";
  13
  14         W_Reload();
  15 }
  16
  17 void SendCSQCNexBeamParticle(float charge) {
  18         vector v;
  19         v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
  20         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  21         WriteByte(MSG_BROADCAST, TE_CSQC_NEXGUNBEAMPARTICLE);
  22         WriteCoord(MSG_BROADCAST, w_shotorg_x);
  23         WriteCoord(MSG_BROADCAST, w_shotorg_y);
  24         WriteCoord(MSG_BROADCAST, w_shotorg_z);
  25         WriteCoord(MSG_BROADCAST, v_x);
  26         WriteCoord(MSG_BROADCAST, v_y);
  27         WriteCoord(MSG_BROADCAST, v_z);
  28         WriteByte(MSG_BROADCAST, bound(0, 255 * charge, 255));
  29 }
  30
  31 void W_Nex_Attack (float issecondary)
  32 {
  33         float mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, myammo, charge;
  34         if(issecondary)
  35         {
  36                 mydmg = autocvar_g_balance_nex_secondary_damage;
  37                 myforce = autocvar_g_balance_nex_secondary_force;
  38                 mymindist = autocvar_g_balance_nex_secondary_damagefalloff_mindist;
  39                 mymaxdist = autocvar_g_balance_nex_secondary_damagefalloff_maxdist;
  40                 myhalflife = autocvar_g_balance_nex_secondary_damagefalloff_halflife;
  41                 myforcehalflife = autocvar_g_balance_nex_secondary_damagefalloff_forcehalflife;
  42                 myammo = autocvar_g_balance_nex_secondary_ammo;
  43         }
  44         else
  45         {
  46                 mydmg = autocvar_g_balance_nex_primary_damage;
  47                 myforce = autocvar_g_balance_nex_primary_force;
  48                 mymindist = autocvar_g_balance_nex_primary_damagefalloff_mindist;
  49                 mymaxdist = autocvar_g_balance_nex_primary_damagefalloff_maxdist;
  50                 myhalflife = autocvar_g_balance_nex_primary_damagefalloff_halflife;
  51                 myforcehalflife = autocvar_g_balance_nex_primary_damagefalloff_forcehalflife;
  52                 myammo = autocvar_g_balance_nex_primary_ammo;
  53         }
  54
  55         float flying;
  56         flying = IsFlying(self); // do this BEFORE to make the trace values from FireRailgunBullet last
  57
  58         if(autocvar_g_balance_nex_charge)
  59         {
  60                 charge = autocvar_g_balance_nex_charge_mindmg / mydmg + (1 - autocvar_g_balance_nex_charge_mindmg / mydmg) * self.nex_charge;
  61                 self.nex_charge *= autocvar_g_balance_nex_charge_shot_multiplier; // do this AFTER setting mydmg/myforce
  62                 // O RLY? -- divVerent
  63                 // YA RLY -- FruitieX
  64         }
  65         else
  66                 charge = 1;
  67         mydmg *= charge;
  68         myforce *= charge;
  69
  70         W_SetupShot (self, TRUE, 5, "weapons/nexfire.wav", CHAN_WEAPON, mydmg);
  71         if(charge > autocvar_g_balance_nex_charge_limit && autocvar_g_balance_nex_charge_limit) // if the Nex is overcharged, we play an extra sound
  72         {
  73                 sound (self, CHAN_WEAPON2, "weapons/nexcharge.wav", VOL_BASE * (charge - 0.5 * autocvar_g_balance_nex_charge_limit) / (1 - 0.5 * autocvar_g_balance_nex_charge_limit), ATTN_NORM);
  74         }
  75
  76         yoda = 0;
  77         FireRailgunBullet (w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, WEP_NEX);
  78
  79         if(yoda && flying)
  80                 AnnounceTo(self, "yoda");
  81
  82         //beam and muzzle flash done on client
  83         SendCSQCNexBeamParticle(charge);
  84
  85         // flash and burn the wall
  86         if (trace_ent.solid == SOLID_BSP && !(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
  87                 Damage_DamageInfo(trace_endpos, mydmg, 0, 0, myforce * w_shotdir, WEP_NEX, self);
  88
  89         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
  90         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  91         {
  92                 if(autocvar_g_balance_nex_reload_ammo)
  93                 {
  94                         self.clip_load -= myammo;
  95                         self.weapon_load[WEP_NEX] = self.clip_load;
  96                 }
  97                 else
  98                         self.ammo_cells -= myammo;
  99         }
 100 }
 101
 102 void spawnfunc_weapon_nex (void); // defined in t_items.qc
 103
 104 .float nex_chargepool_pauseregen_finished;
 105 float w_nex(float req)
 106 {
 107         float dt;
 108         float ammo_amount;
 109         if (req == WR_AIM)
 110         {
 111                 self.BUTTON_ATCK = bot_aim(1000000, 0, 1, FALSE);
 112                 self.BUTTON_ATCK2 = bot_aim(1000000, 0, 1, FALSE);
 113         }
 114         else if (req == WR_THINK)
 115         {
 116                 if(autocvar_g_balance_nex_charge && self.nex_charge < autocvar_g_balance_nex_charge_limit)
 117                         self.nex_charge = min(1, self.nex_charge + autocvar_g_balance_nex_charge_rate * frametime / W_TICSPERFRAME);
 118
 119                 if(autocvar_g_balance_nex_secondary_chargepool)
 120                         if(self.nex_chargepool_ammo < 1)
 121                         {
 122                                 if(self.nex_chargepool_pauseregen_finished < time)
 123                                         self.nex_chargepool_ammo = min(1, self.nex_chargepool_ammo + autocvar_g_balance_nex_secondary_chargepool_regen * frametime / W_TICSPERFRAME);
 124                                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_nex_secondary_chargepool_pause_health_regen);
 125                         }
 126
 127                 if(autocvar_g_balance_nex_reload_ammo && self.clip_load < min(autocvar_g_balance_nex_primary_ammo, autocvar_g_balance_nex_secondary_ammo)) // forced reload
 128                         W_Nex_Reload();
 129                 else
 130                 {
 131                         if (self.BUTTON_ATCK)
 132                         {
 133                                 if (weapon_prepareattack(0, autocvar_g_balance_nex_primary_refire))
 134                                 {
 135                                         W_Nex_Attack(0);
 136                                         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_nex_primary_animtime, w_ready);
 137                                 }
 138                         }
 139                         if ((autocvar_g_balance_nex_secondary_charge && !autocvar_g_balance_nex_secondary) ? self.BUTTON_ZOOM : self.BUTTON_ATCK2)
 140                         {
 141                                 if(autocvar_g_balance_nex_secondary_charge)
 142                                 {
 143                                         self.nex_charge_rottime = time + autocvar_g_balance_nex_charge_rot_pause;
 144                                         dt = frametime / W_TICSPERFRAME;
 145
 146                                         if(self.nex_charge < 1)
 147                                         {
 148                                                 if(autocvar_g_balance_nex_secondary_chargepool)
 149                                                 {
 150                                                         if(autocvar_g_balance_nex_secondary_ammo)
 151                                                         {
 152                                                                 // always deplete if secondary is held
 153                                                                 self.nex_chargepool_ammo = max(0, self.nex_chargepool_ammo - autocvar_g_balance_nex_secondary_ammo * dt);
 154
 155                                                                 dt = min(dt, (1 - self.nex_charge) / autocvar_g_balance_nex_secondary_charge_rate);
 156                                                                 self.nex_chargepool_pauseregen_finished = time + autocvar_g_balance_nex_secondary_chargepool_pause_regen;
 157                                                                 dt = min(dt, self.nex_chargepool_ammo);
 158                                                                 dt = max(0, dt);
 159
 160                                                                 self.nex_charge += dt * autocvar_g_balance_nex_secondary_charge_rate;
 161                                                         }
 162                                                 }
 163
 164                                                 else if(autocvar_g_balance_nex_secondary_ammo)
 165                                                 {
 166                                                         if(self.BUTTON_ATCK2) // only eat ammo when the button is pressed
 167                                                         {
 168                                                                 dt = min(dt, (1 - self.nex_charge) / autocvar_g_balance_nex_secondary_charge_rate);
 169                                                                 if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 170                                                                 {
 171                                                                         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 172                                                                         if(autocvar_g_balance_nex_reload_ammo)
 173                                                                         {
 174                                                                                 dt = min(dt, (self.clip_load - autocvar_g_balance_nex_primary_ammo) / autocvar_g_balance_nex_secondary_ammo);
 175                                                                                 dt = max(0, dt);
 176                                                                                 if(dt > 0)
 177                                                                                 {
 178                                                                                         self.clip_load = max(autocvar_g_balance_nex_secondary_ammo, self.clip_load - autocvar_g_balance_nex_secondary_ammo * dt);
 179                                                                                 }
 180                                                                                 self.weapon_load[WEP_NEX] = self.clip_load;
 181                                                                         }
 182                                                                         else
 183                                                                         {
 184                                                                                 dt = min(dt, (self.ammo_cells - autocvar_g_balance_nex_primary_ammo) / autocvar_g_balance_nex_secondary_ammo);
 185                                                                                 dt = max(0, dt);
 186                                                                                 if(dt > 0)
 187                                                                                 {
 188                                                                                         self.ammo_cells = max(autocvar_g_balance_nex_secondary_ammo, self.ammo_cells - autocvar_g_balance_nex_secondary_ammo * dt);
 189                                                                                 }
 190                                                                         }
 191                                                                 }
 192                                                                 self.nex_charge += dt * autocvar_g_balance_nex_secondary_charge_rate;
 193                                                         }
 194                                                 }
 195
 196                                                 else
 197                                                 {
 198                                                         dt = min(dt, (1 - self.nex_charge) / autocvar_g_balance_nex_secondary_charge_rate);
 199                                                         self.nex_charge += dt * autocvar_g_balance_nex_secondary_charge_rate;
 200                                                 }
 201                                         }
 202                                 }
 203                                 else if(autocvar_g_balance_nex_secondary)
 204                                 {
 205                                         if (weapon_prepareattack(0, autocvar_g_balance_nex_secondary_refire))
 206                                         {
 207                                                 W_Nex_Attack(1);
 208                                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_nex_secondary_animtime, w_ready);
 209                                         }
 210                                 }
 211                         }
 212                 }
 213
 214                 if(autocvar_g_balance_nex_charge)
 215                 {
 216                         self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_limit);
 217                         self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_limit);
 218                         self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_limit);
 219
 220                         if(self.nex_charge > autocvar_g_balance_nex_charge_limit)
 221                         {
 222                                 self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_limit) / (1 - autocvar_g_balance_nex_charge_limit);
 223                                 self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_limit) / (1 - autocvar_g_balance_nex_charge_limit);
 224                                 self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_limit) / (1 - autocvar_g_balance_nex_charge_limit);
 225                         }
 226                 }
 227         }
 228         else if (req == WR_PRECACHE)
 229         {
 230                 precache_model ("models/nexflash.md3");
 231                 precache_model ("models/weapons/g_nex.md3");
 232                 precache_model ("models/weapons/v_nex.md3");
 233                 precache_model ("models/weapons/h_nex.iqm");
 234                 precache_sound ("weapons/nexfire.wav");
 235                 precache_sound ("weapons/nexcharge.wav");
 236                 precache_sound ("weapons/nexwhoosh1.wav");
 237                 precache_sound ("weapons/nexwhoosh2.wav");
 238                 precache_sound ("weapons/nexwhoosh3.wav");
 239                 precache_sound ("weapons/reload.wav");
 240         }
 241         else if (req == WR_SETUP)
 242         {
 243                 weapon_setup(WEP_NEX);
 244         }
 245         else if (req == WR_CHECKAMMO1)
 246         {
 247                 ammo_amount = self.ammo_cells >= autocvar_g_balance_nex_primary_ammo;
 248                 ammo_amount += (autocvar_g_balance_nex_reload_ammo && self.weapon_load[WEP_NEX] >= autocvar_g_balance_nex_primary_ammo);
 249                 return ammo_amount;
 250         }
 251         else if (req == WR_CHECKAMMO2)
 252         {
 253                 // don't allow charging if we don't have enough ammo
 254                 ammo_amount = self.ammo_cells >= autocvar_g_balance_nex_secondary_ammo;
 255                 ammo_amount += self.weapon_load[WEP_NEX] >= autocvar_g_balance_nex_secondary_ammo;
 256                 return ammo_amount;
 257         }
 258         else if (req == WR_RELOAD)
 259         {
 260                 W_Nex_Reload();
 261         }
 262
 263         return TRUE;
 264 };
 265 #endif
 266 #ifdef CSQC
 267 float w_nex(float req)
 268 {
 269         if(req == WR_IMPACTEFFECT)
 270         {
 271                 vector org2;
 272                 org2 = w_org + w_backoff * 6;
 273                 pointparticles(particleeffectnum("nex_impact"), org2, '0 0 0', 1);
 274                 if(!w_issilent)
 275                         sound(self, CHAN_PROJECTILE, "weapons/neximpact.wav", VOL_BASE, ATTN_NORM);
 276         }
 277         else if(req == WR_PRECACHE)
 278         {
 279                 precache_sound("weapons/neximpact.wav");
 280         }
 281         else if (req == WR_SUICIDEMESSAGE)
 282                 w_deathtypestring = _("%s did the impossible");
 283         else if (req == WR_KILLMESSAGE)
 284                 w_deathtypestring = _("%s has been vaporized by %s");
 285         return TRUE;
 286 }
 287 #endif
 288 #endif