qcsrc/server/w_laser.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(LASER, W_Laser, 0, 1, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH, 0, "laser", "laser", _("Blaster"))
   3 #else
   4 #ifdef SVQC
   5 void(float imp) W_SwitchWeapon;
   6 void() W_LastWeapon;
   7 .float swing_prev;
   8 .entity swing_alreadyhit;
   9
  10 void SendCSQCShockwaveParticle(vector endpos)
  11 {
  12         //endpos = WarpZone_UnTransformOrigin(transform, endpos);
  13
  14         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  15         WriteByte(MSG_BROADCAST, TE_CSQC_SHOCKWAVEPARTICLE);
  16         WriteCoord(MSG_BROADCAST, w_shotorg_x);
  17         WriteCoord(MSG_BROADCAST, w_shotorg_y);
  18         WriteCoord(MSG_BROADCAST, w_shotorg_z);
  19         WriteCoord(MSG_BROADCAST, endpos_x);
  20         WriteCoord(MSG_BROADCAST, endpos_y);
  21         WriteCoord(MSG_BROADCAST, endpos_z);
  22         WriteByte(MSG_BROADCAST, bound(0, autocvar_g_balance_laser_shockwave_spread_max, 255));
  23         WriteByte(MSG_BROADCAST, bound(0, autocvar_g_balance_laser_shockwave_spread_min, 255));
  24 }
  25
  26 void W_Laser_Touch()
  27 {
  28         PROJECTILE_TOUCH;
  29
  30         self.event_damage = SUB_Null;
  31
  32         if(self.dmg)
  33                 RadiusDamage(self, self.realowner, autocvar_g_balance_laser_secondary_damage, autocvar_g_balance_laser_secondary_edgedamage, autocvar_g_balance_laser_secondary_radius, world, world, autocvar_g_balance_laser_secondary_force, self.projectiledeathtype, other);
  34         else
  35                 RadiusDamage(self, self.realowner, autocvar_g_balance_laser_primary_damage, autocvar_g_balance_laser_primary_edgedamage, autocvar_g_balance_laser_primary_radius, world, world, autocvar_g_balance_laser_primary_force, self.projectiledeathtype, other);
  36
  37         remove(self);
  38 }
  39
  40 void W_Laser_Think()
  41 {
  42         self.movetype = MOVETYPE_FLY;
  43         self.think = SUB_Remove;
  44
  45         if(self.dmg)
  46                 self.nextthink = time + autocvar_g_balance_laser_secondary_lifetime;
  47         else
  48                 self.nextthink = time + autocvar_g_balance_laser_primary_lifetime;
  49
  50         CSQCProjectile(self, TRUE, PROJECTILE_LASER, TRUE);
  51 }
  52
  53
  54 float W_Laser_Shockwave_CheckSpread(vector targetorg, vector nearest_on_line, vector sw_shotorg, vector attack_endpos)
  55 {
  56         float spreadlimit;
  57         float distance_of_attack = vlen(sw_shotorg - attack_endpos);
  58         float distance_from_line = vlen(targetorg - nearest_on_line);
  59
  60         spreadlimit = (distance_of_attack ? min(1, (vlen(sw_shotorg - nearest_on_line) / distance_of_attack)) : 1);
  61         spreadlimit = (autocvar_g_balance_laser_shockwave_spread_min * (1 - spreadlimit) + autocvar_g_balance_laser_shockwave_spread_max * spreadlimit);
  62
  63         if(spreadlimit && (distance_from_line <= spreadlimit) && ((vlen(normalize(targetorg - sw_shotorg) - normalize(attack_endpos - sw_shotorg)) * RAD2DEG) <= 90))
  64                 return bound(0, (distance_from_line / spreadlimit), 1);
  65         else
  66                 return FALSE;
  67 }
  68
  69 float W_Laser_Shockwave_IsVisible(entity head, vector nearest_on_line, vector sw_shotorg, vector attack_endpos)
  70 {
  71         vector nearest_to_attacker = head.WarpZone_findradius_nearest;
  72         vector center = (head.origin + (head.mins + head.maxs) * 0.5);
  73         vector corner;
  74         float i;
  75
  76         // STEP ONE: Check if the nearest point is clear
  77         if(W_Laser_Shockwave_CheckSpread(nearest_to_attacker, nearest_on_line, sw_shotorg, attack_endpos))
  78         {
  79                 WarpZone_TraceLine(sw_shotorg, nearest_to_attacker, MOVE_NOMONSTERS, self);
  80                 if(trace_fraction == 1) { return TRUE; } // yes, the nearest point is clear and we can allow the damage
  81         }
  82
  83         // STEP TWO: Check if shotorg to center point is clear
  84         if(W_Laser_Shockwave_CheckSpread(center, nearest_on_line, sw_shotorg, attack_endpos))
  85         {
  86                 WarpZone_TraceLine(sw_shotorg, center, MOVE_NOMONSTERS, self);
  87                 if(trace_fraction == 1) { return TRUE; } // yes, the center point is clear and we can allow the damage
  88         }
  89
  90         // STEP THREE: Check each corner to see if they are clear
  91         for(i=1; i<=8; ++i)
  92         {
  93                 corner = get_corner_position(head, i);
  94                 if(W_Laser_Shockwave_CheckSpread(corner, nearest_on_line, sw_shotorg, attack_endpos))
  95                 {
  96                         WarpZone_TraceLine(sw_shotorg, corner, MOVE_NOMONSTERS, self);
  97                         if(trace_fraction == 1) { return TRUE; } // yes, this corner is clear and we can allow the damage
  98                 }
  99         }
 100
 101         return FALSE;
 102 }
 103
 104 #define PLAYER_CENTER(ent) (ent.origin + ((ent.classname == "player") ? ent.view_ofs : ((ent.mins + ent.maxs) * 0.5)))
 105
 106 entity shockwave_hit[32];
 107 float shockwave_hit_damage[32];
 108 vector shockwave_hit_force[32];
 109
 110 float W_Laser_Shockwave_CheckHit(float queue, entity head, vector final_force, float final_damage)
 111 {
 112         if not(head) { return FALSE; }
 113         float i;
 114
 115         ++queue;
 116
 117         for(i = 1; i <= queue; ++i)
 118         {
 119                 if(shockwave_hit[i] == head)
 120                 {
 121                         if(vlen(final_force) > vlen(shockwave_hit_force[i])) { shockwave_hit_force[i] = final_force; }
 122                         if(final_damage > shockwave_hit_damage[i]) { shockwave_hit_damage[i] = final_damage; }
 123                         return FALSE;
 124                 }
 125         }
 126
 127         shockwave_hit[queue] = head;
 128         shockwave_hit_force[queue] = final_force;
 129         shockwave_hit_damage[queue] = final_damage;
 130         return TRUE;
 131 }
 132
 133 void W_Laser_Shockwave()
 134 {
 135         // declarations
 136         float multiplier, multiplier_from_accuracy, multiplier_from_distance;
 137         float final_damage, final_spread;
 138         vector final_force, center, vel;
 139         entity head, next;
 140
 141         float i, queue;
 142
 143         // set up the shot direction
 144         W_SetupShot(self, FALSE, 3, "weapons/lasergun_fire.wav", CH_WEAPON_B, autocvar_g_balance_laser_shockwave_damage);
 145         vector attack_endpos = (w_shotorg + (w_shotdir * autocvar_g_balance_laser_shockwave_distance));
 146         WarpZone_TraceLine(w_shotorg, attack_endpos, MOVE_NOMONSTERS, self);
 147         vector attack_hitpos = trace_endpos;
 148         float distance_to_end = vlen(w_shotorg - attack_endpos);
 149         float distance_to_hit = vlen(w_shotorg - attack_hitpos);
 150         entity transform = WarpZone_trace_transform;
 151
 152         // do the firing effect now
 153         SendCSQCShockwaveParticle(attack_endpos);
 154         Damage_DamageInfo(attack_hitpos, autocvar_g_balance_laser_shockwave_splash_damage, autocvar_g_balance_laser_shockwave_splash_edgedamage, autocvar_g_balance_laser_shockwave_splash_radius, w_shotdir * autocvar_g_balance_laser_shockwave_splash_force, WEP_LASER, 0, self);
 155
 156         // splash damage/jumping trace
 157         head = WarpZone_FindRadius(attack_hitpos, max(autocvar_g_balance_laser_shockwave_splash_radius, autocvar_g_balance_laser_shockwave_jump_radius), FALSE);
 158         while(head)
 159         {
 160                 next = head.chain;
 161
 162                 if(head.takedamage)
 163                 {
 164                         // if it's a player, use the view origin as reference (stolen from RadiusDamage functions in g_damage.qc)
 165                         center = PLAYER_CENTER(head);
 166
 167                         float distance_to_head = vlen(attack_hitpos - head.WarpZone_findradius_nearest);
 168
 169                         if((head == self) && (distance_to_head <= autocvar_g_balance_laser_shockwave_jump_radius))
 170                         {
 171                                 multiplier_from_accuracy = (1 - (distance_to_head ? min(1, (distance_to_head / autocvar_g_balance_laser_shockwave_jump_radius)) : 0));
 172                                 multiplier_from_distance = (1 - (distance_to_hit ? min(1, (distance_to_hit / distance_to_end)) : 0));
 173                                 multiplier = max(autocvar_g_balance_laser_shockwave_jump_multiplier_min, ((multiplier_from_accuracy * autocvar_g_balance_laser_shockwave_jump_multiplier_accuracy) + (multiplier_from_distance * autocvar_g_balance_laser_shockwave_jump_multiplier_distance)));
 174
 175                                 final_force = ((normalize(center - attack_hitpos) * autocvar_g_balance_laser_shockwave_jump_force) * multiplier);
 176                                 vel = head.velocity; vel_z = 0;
 177                                 vel = normalize(vel) * bound(0, vlen(vel) / autocvar_sv_maxspeed, 1) * autocvar_g_balance_laser_shockwave_jump_force_velocitybias;
 178                                 final_force = (vlen(final_force) * normalize(normalize(final_force) + vel));
 179                                 final_force_z *= autocvar_g_balance_laser_shockwave_jump_force_zscale;
 180                                 final_damage = (autocvar_g_balance_laser_shockwave_jump_damage * multiplier + autocvar_g_balance_laser_shockwave_jump_edgedamage * (1 - multiplier));
 181
 182                                 Damage(head, self, self, final_damage, WEP_LASER, head.origin, final_force);
 183                                 print("SELF HIT: multiplier = ", ftos(multiplier), strcat(", damage = ", ftos(final_damage), ", force = ", ftos(vlen(final_force))),"... multiplier_from_accuracy = ", ftos(multiplier_from_accuracy), ", multiplier_from_distance = ", ftos(multiplier_from_distance), ".\n");
 184                         }
 185                         else if (distance_to_head <= autocvar_g_balance_laser_shockwave_splash_radius)
 186                         {
 187                                 multiplier_from_accuracy = (1 - (distance_to_head ? min(1, (distance_to_head / autocvar_g_balance_laser_shockwave_splash_radius)) : 0));
 188                                 multiplier_from_distance = (1 - (distance_to_hit ? min(1, (distance_to_hit / distance_to_end)) : 0));
 189                                 multiplier = max(autocvar_g_balance_laser_shockwave_splash_multiplier_min, ((multiplier_from_accuracy * autocvar_g_balance_laser_shockwave_splash_multiplier_accuracy) + (multiplier_from_distance * autocvar_g_balance_laser_shockwave_splash_multiplier_distance)));
 190
 191                                 final_force = normalize(center - (attack_hitpos - (w_shotdir * autocvar_g_balance_laser_shockwave_splash_force_forwardbias)));
 192                                 te_lightning2(world, attack_hitpos, (attack_hitpos + (final_force * 200)));
 193                                 final_force = ((final_force * autocvar_g_balance_laser_shockwave_splash_force) * multiplier);
 194                                 final_damage = (autocvar_g_balance_laser_shockwave_splash_damage * multiplier + autocvar_g_balance_laser_shockwave_splash_edgedamage * (1 - multiplier));
 195
 196                                 if(W_Laser_Shockwave_CheckHit(queue, head, final_force, final_damage)) { ++queue; }
 197                                 print("SPLASH HIT: multiplier = ", ftos(multiplier), strcat(", damage = ", ftos(final_damage), ", force = ", ftos(vlen(final_force))),"... multiplier_from_accuracy = ", ftos(multiplier_from_accuracy), ", multiplier_from_distance = ", ftos(multiplier_from_distance), ".\n");
 198                         }
 199                 }
 200                 head = next;
 201         }
 202
 203         // cone damage trace
 204         head = WarpZone_FindRadius(w_shotorg, autocvar_g_balance_laser_shockwave_distance, FALSE);
 205         while(head)
 206         {
 207                 next = head.chain;
 208
 209                 if((head != self) && head.takedamage)
 210                 {
 211                         // if it's a player, use the view origin as reference (stolen from RadiusDamage functions in g_damage.qc)
 212                         center = PLAYER_CENTER(head);
 213
 214                         // find the closest point on the enemy to the center of the attack
 215                         float ang; // angle between shotdir and h
 216                         float h; // hypotenuse, which is the distance between attacker to head
 217                         float a; // adjacent side, which is the distance between attacker and the point on w_shotdir that is closest to head.origin
 218
 219                         h = vlen(center - self.origin);
 220                         ang = acos(dotproduct(normalize(center - self.origin), w_shotdir));
 221                         a = h * cos(ang);
 222
 223                         vector nearest_on_line = (w_shotorg + a * w_shotdir);
 224                         vector nearest_to_attacker = WarpZoneLib_NearestPointOnBox(center + head.mins, center + head.maxs, nearest_on_line);
 225                         float distance_to_target = vlen(w_shotorg - nearest_to_attacker); // todo: use the findradius function for this
 226
 227                         if((distance_to_target <= autocvar_g_balance_laser_shockwave_distance)
 228                                 && (W_Laser_Shockwave_IsVisible(head, nearest_on_line, w_shotorg, attack_endpos)))
 229                         {
 230                                 multiplier_from_accuracy = (1 - W_Laser_Shockwave_CheckSpread(nearest_to_attacker, nearest_on_line, w_shotorg, attack_endpos));
 231                                 multiplier_from_distance = (1 - (distance_to_hit ? min(1, (distance_to_target / distance_to_end)) : 0));
 232                                 multiplier = max(autocvar_g_balance_laser_shockwave_multiplier_min, ((multiplier_from_accuracy * autocvar_g_balance_laser_shockwave_multiplier_accuracy) + (multiplier_from_distance * autocvar_g_balance_laser_shockwave_multiplier_distance)));
 233
 234                                 final_force = normalize(center - (nearest_on_line - (w_shotdir * autocvar_g_balance_laser_shockwave_force_forwardbias)));
 235                                 te_lightning2(world, nearest_on_line, (attack_hitpos + (final_force * 200)));
 236                                 final_force = ((final_force * autocvar_g_balance_laser_shockwave_force) * multiplier);
 237                                 final_damage = (autocvar_g_balance_laser_shockwave_damage * multiplier + autocvar_g_balance_laser_shockwave_edgedamage * (1 - multiplier));
 238
 239                                 if(W_Laser_Shockwave_CheckHit(queue, head, final_force, final_damage)) { ++queue; }
 240                                 print("CONE HIT: multiplier = ", ftos(multiplier), strcat(", damage = ", ftos(final_damage), ", force = ", ftos(vlen(final_force))),"... multiplier_from_accuracy = ", ftos(multiplier_from_accuracy), ", multiplier_from_distance = ", ftos(multiplier_from_distance), ".\n");
 241                         }
 242                 }
 243                 head = next;
 244         }
 245
 246         for(i = 1; i <= queue; ++i)
 247         {
 248                 head = shockwave_hit[i];
 249                 final_force = shockwave_hit_force[i];
 250                 final_damage = shockwave_hit_damage[i];
 251
 252                 Damage(head, self, self, final_damage, WEP_LASER, head.origin, final_force);
 253                 print("DEQUEING DAMAGE: damage = ", ftos(final_damage), ", force = ", ftos(vlen(final_force)), ".\n");
 254
 255                 shockwave_hit[i] = world;
 256                 shockwave_hit_force = '0 0 0';
 257                 shockwave_hit_damage = 0;
 258         }
 259         print("queue was ", ftos(queue), ".\n\n");
 260 }
 261
 262 void W_Laser_Melee_Think()
 263 {
 264         // declarations
 265         float i, f, swing, swing_factor, swing_damage, meleetime, is_player;
 266         entity target_victim;
 267         vector targpos;
 268
 269         if(!self.cnt) // set start time of melee
 270         {
 271                 self.cnt = time;
 272                 W_PlayStrengthSound(self.realowner);
 273         }
 274
 275         makevectors(self.realowner.v_angle); // update values for v_* vectors
 276
 277         // calculate swing percentage based on time
 278         meleetime = autocvar_g_balance_laser_melee_time * W_WeaponRateFactor();
 279         swing = bound(0, (self.cnt + meleetime - time) / meleetime, 10);
 280         f = ((1 - swing) * autocvar_g_balance_laser_melee_traces);
 281
 282         // check to see if we can still continue, otherwise give up now
 283         if((self.realowner.deadflag != DEAD_NO) && autocvar_g_balance_laser_melee_no_doubleslap)
 284         {
 285                 remove(self);
 286                 return;
 287         }
 288
 289         // if okay, perform the traces needed for this frame
 290         for(i=self.swing_prev; i < f; ++i)
 291         {
 292                 swing_factor = ((1 - (i / autocvar_g_balance_laser_melee_traces)) * 2 - 1);
 293
 294                 targpos = (self.realowner.origin + self.realowner.view_ofs
 295                         + (v_forward * autocvar_g_balance_laser_melee_range)
 296                         + (v_up * swing_factor * autocvar_g_balance_laser_melee_swing_up)
 297                         + (v_right * swing_factor * autocvar_g_balance_laser_melee_swing_side));
 298
 299                 WarpZone_traceline_antilag(self.realowner, self.realowner.origin + self.realowner.view_ofs, targpos, FALSE, self.realowner, ANTILAG_LATENCY(self.realowner));
 300
 301                 // draw lightning beams for debugging
 302                 te_lightning2(world, targpos, self.realowner.origin + self.realowner.view_ofs + v_forward * 5 - v_up * 5);
 303                 te_customflash(targpos, 40,  2, '1 1 1');
 304
 305                 is_player = (trace_ent.classname == "player" || trace_ent.classname == "body");
 306
 307                 if((trace_fraction < 1) // if trace is good, apply the damage and remove self
 308                         && (trace_ent.takedamage == DAMAGE_AIM)
 309                         && (trace_ent != self.swing_alreadyhit)
 310                         && (is_player || autocvar_g_balance_laser_melee_nonplayerdamage))
 311                 {
 312                         target_victim = trace_ent; // so it persists through other calls
 313
 314                         if(is_player) // this allows us to be able to nerf the non-player damage done in e.g. assault or onslaught.
 315                                 swing_damage = (autocvar_g_balance_laser_melee_damage * min(1, swing_factor + 1));
 316                         else
 317                                 swing_damage = (autocvar_g_balance_laser_melee_nonplayerdamage * min(1, swing_factor + 1));
 318
 319                         //print(strcat(self.realowner.netname, " hitting ", target_victim.netname, " with ", strcat(ftos(swing_damage), " damage (factor: ", ftos(swing_factor), ") at "), ftos(time), " seconds.\n"));
 320
 321                         Damage(target_victim, self.realowner, self.realowner,
 322                                 swing_damage, WEP_LASER | HITTYPE_SECONDARY,
 323                                 self.realowner.origin + self.realowner.view_ofs,
 324                                 v_forward * autocvar_g_balance_laser_melee_force);
 325
 326                         if(accuracy_isgooddamage(self.realowner, target_victim)) { accuracy_add(self.realowner, WEP_LASER, 0, swing_damage); }
 327
 328                         if(autocvar_g_balance_laser_melee_multihit) // allow multiple hits with one swing, but not against the same player twice.
 329                         {
 330                                 self.swing_alreadyhit = target_victim;
 331                                 continue; // move along to next trace
 332                         }
 333                         else
 334                         {
 335                                 remove(self);
 336                                 return;
 337                         }
 338                 }
 339         }
 340
 341         if(time >= self.cnt + meleetime)
 342         {
 343                 // melee is finished
 344                 remove(self);
 345                 return;
 346         }
 347         else
 348         {
 349                 // set up next frame
 350                 self.swing_prev = i;
 351                 self.nextthink = time;
 352         }
 353 }
 354
 355 void W_Laser_Melee()
 356 {
 357         sound(self, CH_WEAPON_A, "weapons/shotgun_melee.wav", VOL_BASE, ATTN_NORM);
 358         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_laser_melee_animtime, w_ready);
 359
 360         entity meleetemp;
 361         meleetemp = spawn();
 362         meleetemp.owner = meleetemp.realowner = self;
 363         meleetemp.think = W_Laser_Melee_Think;
 364         meleetemp.nextthink = time + autocvar_g_balance_laser_melee_delay * W_WeaponRateFactor();
 365         W_SetupShot_Range(self, TRUE, 0, "", 0, autocvar_g_balance_laser_melee_damage, autocvar_g_balance_laser_melee_range);
 366 }
 367
 368 void W_Laser_Attack(float issecondary)
 369 {
 370         entity missile;
 371         vector s_forward;
 372         float a;
 373         float nodamage;
 374
 375         if(issecondary == 2) // minstanex shot
 376                 nodamage = g_minstagib;
 377         else
 378                 nodamage = FALSE;
 379
 380         a = autocvar_g_balance_laser_primary_shotangle;
 381         s_forward = v_forward * cos(a * DEG2RAD) + v_up * sin(a * DEG2RAD);
 382
 383         if(nodamage)
 384                 W_SetupShot_Dir(self, s_forward, FALSE, 3, "weapons/lasergun_fire.wav", CH_WEAPON_B, 0);
 385         else if(issecondary == 1)
 386                 W_SetupShot_Dir(self, s_forward, FALSE, 3, "weapons/lasergun_fire.wav", CH_WEAPON_B, autocvar_g_balance_laser_secondary_damage);
 387         else
 388                 W_SetupShot_Dir(self, s_forward, FALSE, 3, "weapons/lasergun_fire.wav", CH_WEAPON_B, autocvar_g_balance_laser_primary_damage);
 389         pointparticles(particleeffectnum("laser_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 390
 391         missile = spawn();
 392         missile.owner = missile.realowner = self;
 393         missile.classname = "laserbolt";
 394         missile.dmg = 0;
 395         if(!nodamage)
 396         {
 397                 missile.bot_dodge = TRUE;
 398                 missile.bot_dodgerating = autocvar_g_balance_laser_primary_damage;
 399         }
 400
 401         PROJECTILE_MAKETRIGGER(missile);
 402         missile.projectiledeathtype = WEP_LASER;
 403
 404         setorigin(missile, w_shotorg);
 405         setsize(missile, '0 0 0', '0 0 0');
 406
 407         W_SETUPPROJECTILEVELOCITY(missile, g_balance_laser_primary);
 408         missile.angles = vectoangles(missile.velocity);
 409         //missile.glow_color = 250; // 244, 250
 410         //missile.glow_size = 120;
 411         missile.touch = W_Laser_Touch;
 412
 413         missile.flags = FL_PROJECTILE;
 414         missile.missile_flags = MIF_SPLASH;
 415
 416         missile.think = W_Laser_Think;
 417         missile.nextthink = time + autocvar_g_balance_laser_primary_delay;
 418
 419         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 420
 421         if(time >= missile.nextthink)
 422         {
 423                 entity oldself;
 424                 oldself = self;
 425                 self = missile;
 426                 self.think();
 427                 self = oldself;
 428         }
 429 }
 430
 431 void spawnfunc_weapon_laser(void)
 432 {
 433         weapon_defaultspawnfunc(WEP_LASER);
 434 }
 435
 436 float W_Laser(float request)
 437 {
 438         switch(request)
 439         {
 440                 case WR_AIM:
 441                 {
 442                         if((autocvar_g_balance_laser_secondary == 2) && (vlen(self.origin-self.enemy.origin) <= autocvar_g_balance_laser_melee_range))
 443                                 self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
 444                         else
 445                                 self.BUTTON_ATCK = bot_aim(1000000, 0, 1, FALSE);
 446                         return TRUE;
 447                 }
 448
 449                 case WR_THINK:
 450                 {
 451                         if(autocvar_g_balance_laser_reload_ammo && self.clip_load < 1) // forced reload
 452                                 weapon_action(self.weapon, WR_RELOAD);
 453                         else if(self.BUTTON_ATCK)
 454                         {
 455                                 if(weapon_prepareattack(0, autocvar_g_balance_laser_primary_refire))
 456                                 {
 457                                         W_DecreaseAmmo(ammo_none, 1, TRUE);
 458
 459                                         if not(autocvar_g_balance_laser_primary)
 460                                                 W_Laser_Shockwave();
 461                                         else
 462                                                 W_Laser_Attack(FALSE);
 463
 464                                         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_laser_primary_animtime, w_ready);
 465                                 }
 466                         }
 467                         else if(self.BUTTON_ATCK2)
 468                         {
 469                                 switch(autocvar_g_balance_laser_secondary)
 470                                 {
 471                                         case 0: // switch to last used weapon
 472                                         {
 473                                                 if(self.switchweapon == WEP_LASER) // don't do this if already switching
 474                                                         W_LastWeapon();
 475
 476                                                 break;
 477                                         }
 478
 479                                         case 1: // normal projectile secondary
 480                                         {
 481                                                 if(weapon_prepareattack(1, autocvar_g_balance_laser_secondary_refire))
 482                                                 {
 483                                                         W_DecreaseAmmo(ammo_none, 1, TRUE);
 484                                                         W_Laser_Attack(TRUE);
 485                                                         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_laser_secondary_animtime, w_ready);
 486                                                 }
 487
 488                                                 break;
 489                                         }
 490
 491                                         case 2: // melee attack secondary
 492                                         {
 493                                                 if(!self.crouch) // we are not currently crouching; this fixes an exploit where your melee anim is not visible, and besides wouldn't make much sense
 494                                                 if(weapon_prepareattack(1, autocvar_g_balance_laser_melee_refire))
 495                                                 {
 496                                                         // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 497                                                         W_Laser_Melee();
 498                                                         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_laser_melee_animtime, w_ready);
 499                                                 }
 500                                         }
 501                                 }
 502                         }
 503                         return TRUE;
 504                 }
 505
 506                 case WR_PRECACHE:
 507                 {
 508                         precache_model("models/weapons/g_laser.md3");
 509                         precache_model("models/weapons/v_laser.md3");
 510                         precache_model("models/weapons/h_laser.iqm");
 511                         precache_sound("weapons/lasergun_fire.wav");
 512                         return TRUE;
 513                 }
 514
 515                 case WR_SETUP:
 516                 {
 517                         weapon_setup(WEP_LASER);
 518                         self.current_ammo = ammo_none;
 519                         return TRUE;
 520                 }
 521
 522                 case WR_CHECKAMMO1:
 523                 case WR_CHECKAMMO2:
 524                 {
 525                         return TRUE; // laser has infinite ammo
 526                 }
 527
 528                 case WR_RELOAD:
 529                 {
 530                         W_Reload(0, autocvar_g_balance_laser_reload_ammo, autocvar_g_balance_laser_reload_time, "weapons/reload.wav");
 531                         return TRUE;
 532                 }
 533         }
 534
 535         return TRUE;
 536 }
 537 #endif
 538 #ifdef CSQC
 539 float W_Laser(float request)
 540 {
 541         switch(request)
 542         {
 543                 case WR_IMPACTEFFECT:
 544                 {
 545                         vector org2;
 546                         org2 = w_org + w_backoff * 6;
 547                         pointparticles(particleeffectnum("new_laser_impact"), org2, w_backoff * 1000, 1);
 548                         if(!w_issilent) { sound(self, CH_SHOTS, "weapons/laserimpact.wav", VOL_BASE, ATTN_NORM); }
 549                         return TRUE;
 550                 }
 551
 552                 case WR_PRECACHE:
 553                 {
 554                         precache_sound("weapons/laserimpact.wav");
 555                         return TRUE;
 556                 }
 557                 case WR_SUICIDEMESSAGE:
 558                 {
 559                         w_deathtypestring = _("%s lasered themself to hell");
 560                         return TRUE;
 561                 }
 562                 case WR_KILLMESSAGE:
 563                 {
 564                         if(w_deathtype & HITTYPE_SECONDARY)
 565                                 w_deathtypestring = _("%s was cut in half by %s's gauntlet"); // unchecked: SPLASH // TODO
 566                         else
 567                                 w_deathtypestring = _("%s was lasered to death by %s"); // unchecked: SPLASH
 568                         return TRUE;
 569                 }
 570         }
 571
 572         return TRUE;
 573 }
 574 #endif
 575 #endif