qcsrc/server/w_electro.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ ELECTRO,
   4 /* function  */ w_electro,
   5 /* ammotype  */ IT_CELLS,
   6 /* impulse   */ 5,
   7 /* flags     */ WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH,
   8 /* rating    */ BOT_PICKUP_RATING_MID,
   9 /* model     */ "electro",
  10 /* shortname */ "electro",
  11 /* fullname  */ _("Electro")
  12 );
  13 #else
  14 #ifdef SVQC
  15 .float electro_count;
  16 .float electro_secondarytime;
  17
  18 void W_Plasma_Explode_Combo (void);
  19
  20 void W_Plasma_TriggerCombo(vector org, float rad, entity own)
  21 {
  22         entity e;
  23         e = WarpZone_FindRadius(org, rad, TRUE);
  24         while (e)
  25         {
  26                 if (e.classname == "plasma")
  27                 {
  28                         // change owner to whoever caused the combo explosion
  29                         e.realowner = own;
  30                         e.takedamage = DAMAGE_NO;
  31                         e.classname = "plasma_chain";
  32                         e.think = W_Plasma_Explode_Combo;
  33                         e.nextthink = time + vlen(e.WarpZone_findradius_dist) / autocvar_g_balance_electro_combo_speed; // delay combo chains, looks cooler
  34                 }
  35                 e = e.chain;
  36         }
  37 }
  38
  39 void W_Plasma_Explode (void)
  40 {
  41         if(other.takedamage == DAMAGE_AIM)
  42                 if(IS_PLAYER(other))
  43                         if(IsDifferentTeam(self.realowner, other))
  44                                 if(other.deadflag == DEAD_NO)
  45                                         if(IsFlying(other))
  46                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_ELECTROBITCH);
  47
  48         self.event_damage = func_null;
  49         self.takedamage = DAMAGE_NO;
  50         if (self.movetype == MOVETYPE_BOUNCE)
  51         {
  52                 RadiusDamage (self, self.realowner, autocvar_g_balance_electro_secondary_damage, autocvar_g_balance_electro_secondary_edgedamage, autocvar_g_balance_electro_secondary_radius, world, world, autocvar_g_balance_electro_secondary_force, self.projectiledeathtype, other);
  53         }
  54         else
  55         {
  56                 W_Plasma_TriggerCombo(self.origin, autocvar_g_balance_electro_primary_comboradius, self.realowner);
  57                 RadiusDamage (self, self.realowner, autocvar_g_balance_electro_primary_damage, autocvar_g_balance_electro_primary_edgedamage, autocvar_g_balance_electro_primary_radius, world, world, autocvar_g_balance_electro_primary_force, self.projectiledeathtype, other);
  58         }
  59
  60         remove (self);
  61 }
  62
  63 void W_Plasma_Explode_Combo (void)
  64 {
  65         W_Plasma_TriggerCombo(self.origin, autocvar_g_balance_electro_combo_comboradius, self.realowner);
  66
  67         self.event_damage = func_null;
  68         RadiusDamage (self, self.realowner, autocvar_g_balance_electro_combo_damage, autocvar_g_balance_electro_combo_edgedamage, autocvar_g_balance_electro_combo_radius, world, world, autocvar_g_balance_electro_combo_force, WEP_ELECTRO | HITTYPE_BOUNCE, world); // use THIS type for a combo because primary can't bounce
  69
  70         remove (self);
  71 }
  72
  73 void W_Plasma_Touch (void)
  74 {
  75         //self.velocity = self.velocity  * 0.1;
  76
  77         PROJECTILE_TOUCH;
  78         if (other.takedamage == DAMAGE_AIM) {
  79                 W_Plasma_Explode ();
  80         } else {
  81                 //UpdateCSQCProjectile(self);
  82                 spamsound (self, CH_SHOTS, "weapons/electro_bounce.wav", VOL_BASE, ATTN_NORM);
  83                 self.projectiledeathtype |= HITTYPE_BOUNCE;
  84         }
  85 }
  86
  87 void W_Plasma_TouchExplode (void)
  88 {
  89         PROJECTILE_TOUCH;
  90         W_Plasma_Explode ();
  91 }
  92
  93 void W_Plasma_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  94 {
  95         if(self.health <= 0)
  96                 return;
  97
  98         // note: combos are usually triggered by W_Plasma_TriggerCombo, not damage
  99         float is_combo = (inflictor.classname == "plasma_chain" || inflictor.classname == "plasma_prim");
 100
 101         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, (is_combo ? 1 : -1)))
 102                 return; // g_projectiles_damage says to halt
 103
 104         self.health = self.health - damage;
 105         if (self.health <= 0)
 106         {
 107                 self.takedamage = DAMAGE_NO;
 108                 self.nextthink = time;
 109                 if (is_combo)
 110                 {
 111                         // change owner to whoever caused the combo explosion
 112                         self.realowner = inflictor.realowner;
 113                         self.classname = "plasma_chain";
 114                         self.think = W_Plasma_Explode_Combo;
 115                         self.nextthink = time + min(autocvar_g_balance_electro_combo_radius, vlen(self.origin - inflictor.origin)) / autocvar_g_balance_electro_combo_speed; // delay combo chains, looks cooler
 116                                 //                  ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ bounding the length, because inflictor may be in a galaxy far far away (warpzones)
 117                 }
 118                 else
 119                 {
 120                         self.use = W_Plasma_Explode;
 121                         self.think = adaptor_think2use; // not _hittype_splash, as this runs "immediately"
 122                 }
 123         }
 124 }
 125
 126 void W_Electro_Attack()
 127 {
 128         entity proj;
 129
 130         W_DecreaseAmmo(ammo_cells, autocvar_g_balance_electro_primary_ammo, autocvar_g_balance_electro_reload_ammo);
 131
 132         W_SetupShot_ProjectileSize (self, '0 0 -3', '0 0 -3', FALSE, 2, "weapons/electro_fire.wav", CH_WEAPON_A, autocvar_g_balance_electro_primary_damage);
 133
 134         pointparticles(particleeffectnum("electro_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 135
 136         proj = spawn ();
 137         proj.classname = "plasma_prim";
 138         proj.owner = proj.realowner = self;
 139         proj.bot_dodge = TRUE;
 140         proj.bot_dodgerating = autocvar_g_balance_electro_primary_damage;
 141         proj.use = W_Plasma_Explode;
 142         proj.think = adaptor_think2use_hittype_splash;
 143         proj.nextthink = time + autocvar_g_balance_electro_primary_lifetime;
 144         PROJECTILE_MAKETRIGGER(proj);
 145         proj.projectiledeathtype = WEP_ELECTRO;
 146         setorigin(proj, w_shotorg);
 147
 148         proj.movetype = MOVETYPE_FLY;
 149         W_SETUPPROJECTILEVELOCITY(proj, g_balance_electro_primary);
 150         proj.angles = vectoangles(proj.velocity);
 151         proj.touch = W_Plasma_TouchExplode;
 152         setsize(proj, '0 0 -3', '0 0 -3');
 153         proj.flags = FL_PROJECTILE;
 154         proj.missile_flags = MIF_SPLASH;
 155
 156         CSQCProjectile(proj, TRUE, PROJECTILE_ELECTRO_BEAM, TRUE);
 157
 158         other = proj; MUTATOR_CALLHOOK(EditProjectile);
 159 }
 160
 161 void W_Electro_Attack2()
 162 {
 163         entity proj;
 164
 165         W_DecreaseAmmo(ammo_cells, autocvar_g_balance_electro_secondary_ammo, autocvar_g_balance_electro_reload_ammo);
 166
 167         W_SetupShot_ProjectileSize (self, '0 0 -4', '0 0 -4', FALSE, 2, "weapons/electro_fire2.wav", CH_WEAPON_A, autocvar_g_balance_electro_secondary_damage);
 168
 169         w_shotdir = v_forward; // no TrueAim for grenades please
 170
 171         pointparticles(particleeffectnum("electro_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 172
 173         proj = spawn ();
 174         proj.classname = "plasma";
 175         proj.owner = proj.realowner = self;
 176         proj.use = W_Plasma_Explode;
 177         proj.think = adaptor_think2use_hittype_splash;
 178         proj.bot_dodge = TRUE;
 179         proj.bot_dodgerating = autocvar_g_balance_electro_secondary_damage;
 180         proj.nextthink = time + autocvar_g_balance_electro_secondary_lifetime;
 181         PROJECTILE_MAKETRIGGER(proj);
 182         proj.projectiledeathtype = WEP_ELECTRO | HITTYPE_SECONDARY;
 183         setorigin(proj, w_shotorg);
 184
 185         //proj.glow_size = 50;
 186         //proj.glow_color = 45;
 187         proj.movetype = MOVETYPE_BOUNCE;
 188         W_SETUPPROJECTILEVELOCITY_UP(proj, g_balance_electro_secondary);
 189         proj.touch = W_Plasma_Touch;
 190         setsize(proj, '0 0 -4', '0 0 -4');
 191         proj.takedamage = DAMAGE_YES;
 192         proj.damageforcescale = autocvar_g_balance_electro_secondary_damageforcescale;
 193         proj.health = autocvar_g_balance_electro_secondary_health;
 194         proj.event_damage = W_Plasma_Damage;
 195         proj.flags = FL_PROJECTILE;
 196         proj.damagedbycontents = (autocvar_g_balance_electro_secondary_damagedbycontents);
 197
 198         proj.bouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 199         proj.bouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 200         proj.missile_flags = MIF_SPLASH | MIF_ARC;
 201
 202 #if 0
 203         entity p2;
 204         p2 = spawn();
 205         copyentity(proj, p2);
 206         setmodel(p2, "models/ebomb.mdl");
 207         setsize(p2, proj.mins, proj.maxs);
 208 #endif
 209
 210         CSQCProjectile(proj, TRUE, PROJECTILE_ELECTRO, FALSE); // no culling, it has sound
 211
 212         other = proj; MUTATOR_CALLHOOK(EditProjectile);
 213 }
 214
 215 .vector hook_start, hook_end;
 216 float lgbeam_send(entity to, float sf)
 217 {
 218         WriteByte(MSG_ENTITY, ENT_CLIENT_LGBEAM);
 219         sf = sf & 0x7F;
 220         if(sound_allowed(MSG_BROADCAST, self.realowner))
 221                 sf |= 0x80;
 222         WriteByte(MSG_ENTITY, sf);
 223         if(sf & 1)
 224         {
 225                 WriteByte(MSG_ENTITY, num_for_edict(self.realowner));
 226                 WriteCoord(MSG_ENTITY, autocvar_g_balance_electro_primary_range);
 227         }
 228         if(sf & 2)
 229         {
 230                 WriteCoord(MSG_ENTITY, self.hook_start_x);
 231                 WriteCoord(MSG_ENTITY, self.hook_start_y);
 232                 WriteCoord(MSG_ENTITY, self.hook_start_z);
 233         }
 234         if(sf & 4)
 235         {
 236                 WriteCoord(MSG_ENTITY, self.hook_end_x);
 237                 WriteCoord(MSG_ENTITY, self.hook_end_y);
 238                 WriteCoord(MSG_ENTITY, self.hook_end_z);
 239         }
 240         return TRUE;
 241 }
 242 .entity lgbeam;
 243 .float prevlgfire;
 244 float lgbeam_checkammo()
 245 {
 246         if(self.realowner.items & IT_UNLIMITED_WEAPON_AMMO)
 247                 return TRUE;
 248         else if(autocvar_g_balance_electro_reload_ammo)
 249                 return self.realowner.clip_load > 0;
 250         else
 251                 return self.realowner.ammo_cells > 0;
 252 }
 253
 254 entity lgbeam_owner_ent;
 255 void lgbeam_think()
 256 {
 257         entity owner_player;
 258         owner_player = self.realowner;
 259
 260         owner_player.prevlgfire = time;
 261         if (self != owner_player.lgbeam)
 262         {
 263                 remove(self);
 264                 return;
 265         }
 266
 267         if (owner_player.weaponentity.state != WS_INUSE || !lgbeam_checkammo() || owner_player.deadflag != DEAD_NO || !owner_player.BUTTON_ATCK || owner_player.freezetag_frozen)
 268         {
 269                 if(self == owner_player.lgbeam)
 270                         owner_player.lgbeam = world;
 271                 remove(self);
 272                 return;
 273         }
 274
 275         self.nextthink = time;
 276
 277         makevectors(owner_player.v_angle);
 278
 279         float dt, f;
 280         dt = frametime;
 281
 282         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 283         if not(owner_player.items & IT_UNLIMITED_WEAPON_AMMO)
 284         {
 285                 if(autocvar_g_balance_electro_primary_ammo)
 286                 {
 287                         if(autocvar_g_balance_electro_reload_ammo)
 288                         {
 289                                 dt = min(dt, owner_player.clip_load / autocvar_g_balance_electro_primary_ammo);
 290                                 owner_player.clip_load = max(0, owner_player.clip_load - autocvar_g_balance_electro_primary_ammo * frametime);
 291                                 owner_player.(weapon_load[WEP_ELECTRO]) = owner_player.clip_load;
 292                         }
 293                         else
 294                         {
 295                                 dt = min(dt, owner_player.ammo_cells / autocvar_g_balance_electro_primary_ammo);
 296                                 owner_player.ammo_cells = max(0, owner_player.ammo_cells - autocvar_g_balance_electro_primary_ammo * frametime);
 297                         }
 298                 }
 299         }
 300
 301         W_SetupShot_Range(owner_player, TRUE, 0, "", 0, autocvar_g_balance_electro_primary_damage * dt, autocvar_g_balance_electro_primary_range);
 302         if(!lgbeam_owner_ent)
 303         {
 304                 lgbeam_owner_ent = spawn();
 305                 lgbeam_owner_ent.classname = "lgbeam_owner_ent";
 306         }
 307         WarpZone_traceline_antilag(lgbeam_owner_ent, w_shotorg, w_shotend, MOVE_NORMAL, lgbeam_owner_ent, ANTILAG_LATENCY(owner_player));
 308
 309         // apply the damage
 310         if(trace_ent)
 311         {
 312                 vector force;
 313                 force = w_shotdir * autocvar_g_balance_electro_primary_force + '0 0 1' * autocvar_g_balance_electro_primary_force_up;
 314
 315                 f = ExponentialFalloff(autocvar_g_balance_electro_primary_falloff_mindist, autocvar_g_balance_electro_primary_falloff_maxdist, autocvar_g_balance_electro_primary_falloff_halflifedist, vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos) - w_shotorg));
 316
 317                 if(accuracy_isgooddamage(owner_player, trace_ent))
 318                         accuracy_add(owner_player, WEP_ELECTRO, 0, autocvar_g_balance_electro_primary_damage * dt * f);
 319                 Damage (trace_ent, owner_player, owner_player, autocvar_g_balance_electro_primary_damage * dt * f, WEP_ELECTRO, trace_endpos, force * dt);
 320         }
 321         W_Plasma_TriggerCombo(trace_endpos, autocvar_g_balance_electro_primary_comboradius, owner_player);
 322
 323         // draw effect
 324         if(w_shotorg != self.hook_start)
 325         {
 326                 self.SendFlags |= 2;
 327                 self.hook_start = w_shotorg;
 328         }
 329         if(w_shotend != self.hook_end)
 330         {
 331                 self.SendFlags |= 4;
 332                 self.hook_end = w_shotend;
 333         }
 334 }
 335
 336 // experimental lightning gun
 337 void W_Electro_Attack3 (void)
 338 {
 339         // only play fire sound if 0.5 sec has passed since player let go the fire button
 340         if(time - self.prevlgfire > 0.5)
 341                 sound (self, CH_WEAPON_A, "weapons/lgbeam_fire.wav", VOL_BASE, ATTN_NORM);
 342
 343         entity beam, oldself;
 344
 345         self.lgbeam = beam = spawn();
 346         beam.classname = "lgbeam";
 347         beam.solid = SOLID_NOT;
 348         beam.think = lgbeam_think;
 349         beam.owner = beam.realowner = self;
 350         beam.movetype = MOVETYPE_NONE;
 351         beam.shot_spread = 0;
 352         beam.bot_dodge = TRUE;
 353         beam.bot_dodgerating = autocvar_g_balance_electro_primary_damage;
 354         Net_LinkEntity(beam, FALSE, 0, lgbeam_send);
 355
 356         oldself = self;
 357         self = beam;
 358         self.think();
 359         self = oldself;
 360 }
 361
 362 void ElectroInit()
 363 {
 364         weapon_action(WEP_ELECTRO, WR_PRECACHE);
 365         electro_shotorigin[0] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), FALSE, FALSE, 1);
 366         electro_shotorigin[1] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), FALSE, FALSE, 2);
 367         electro_shotorigin[2] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), FALSE, FALSE, 3);
 368         electro_shotorigin[3] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), FALSE, FALSE, 4);
 369 }
 370
 371 void spawnfunc_weapon_electro (void)
 372 {
 373         weapon_defaultspawnfunc(WEP_ELECTRO);
 374 }
 375
 376 void w_electro_checkattack()
 377 {
 378         if(self.electro_count > 1)
 379         if(self.BUTTON_ATCK2)
 380         if(weapon_prepareattack(1, -1))
 381         {
 382                 W_Electro_Attack2();
 383                 self.electro_count -= 1;
 384                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_electro_secondary_animtime, w_electro_checkattack);
 385                 return;
 386         }
 387
 388         w_ready();
 389 }
 390
 391 .float bot_secondary_electromooth;
 392 .float BUTTON_ATCK_prev;
 393 float w_electro(float req)
 394 {
 395         float ammo_amount;
 396         if (req == WR_AIM)
 397         {
 398                 self.BUTTON_ATCK=FALSE;
 399                 self.BUTTON_ATCK2=FALSE;
 400                 if(vlen(self.origin-self.enemy.origin) > 1000)
 401                         self.bot_secondary_electromooth = 0;
 402                 if(self.bot_secondary_electromooth == 0)
 403                 {
 404                         float shoot;
 405
 406                         if(autocvar_g_balance_electro_primary_speed)
 407                                 shoot = bot_aim(autocvar_g_balance_electro_primary_speed, 0, autocvar_g_balance_electro_primary_lifetime, FALSE);
 408                         else
 409                                 shoot = bot_aim(1000000, 0, 0.001, FALSE);
 410
 411                         if(shoot)
 412                         {
 413                                 self.BUTTON_ATCK = TRUE;
 414                                 if(random() < 0.01) self.bot_secondary_electromooth = 1;
 415                         }
 416                 }
 417                 else
 418                 {
 419                         if(bot_aim(autocvar_g_balance_electro_secondary_speed, autocvar_g_balance_grenadelauncher_secondary_speed_up, autocvar_g_balance_electro_secondary_lifetime, TRUE))
 420                         {
 421                                 self.BUTTON_ATCK2 = TRUE;
 422                                 if(random() < 0.03) self.bot_secondary_electromooth = 0;
 423                         }
 424                 }
 425         }
 426         else if (req == WR_THINK)
 427         {
 428                 if(autocvar_g_balance_electro_reload_ammo) // forced reload
 429                 {
 430                         ammo_amount = 0;
 431                         if(autocvar_g_balance_electro_lightning)
 432                         {
 433                                 if(self.clip_load > 0)
 434                                         ammo_amount = 1;
 435                         }
 436                         else if(self.clip_load >= autocvar_g_balance_electro_primary_ammo)
 437                                 ammo_amount = 1;
 438                         if(self.clip_load >= autocvar_g_balance_electro_secondary_ammo)
 439                                 ammo_amount += 1;
 440
 441                         if(!ammo_amount)
 442                         {
 443                                 weapon_action(self.weapon, WR_RELOAD);
 444                                 return FALSE;
 445                         }
 446                 }
 447                 if (self.BUTTON_ATCK)
 448                 {
 449                         if(autocvar_g_balance_electro_lightning)
 450                                 if(self.BUTTON_ATCK_prev)
 451                                         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_electro_primary_animtime, w_ready);
 452
 453                         if (weapon_prepareattack(0, (autocvar_g_balance_electro_lightning ? 0 : autocvar_g_balance_electro_primary_refire)))
 454                         {
 455                                 if(autocvar_g_balance_electro_lightning)
 456                                 {
 457                                         if ((!self.lgbeam) || wasfreed(self.lgbeam))
 458                                         {
 459                                                 W_Electro_Attack3();
 460                                         }
 461                                         if(!self.BUTTON_ATCK_prev)
 462                                         {
 463                                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_electro_primary_animtime, w_ready);
 464                                                 self.BUTTON_ATCK_prev = 1;
 465                                         }
 466                                 }
 467                                 else
 468                                 {
 469                                         W_Electro_Attack();
 470                                         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_electro_primary_animtime, w_ready);
 471                                 }
 472                         }
 473                 } else {
 474                         if(autocvar_g_balance_electro_lightning)
 475                         {
 476                                 if (self.BUTTON_ATCK_prev != 0)
 477                                 {
 478                                         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_electro_primary_animtime, w_ready);
 479                                         ATTACK_FINISHED(self) = time + autocvar_g_balance_electro_primary_refire * W_WeaponRateFactor();
 480                                 }
 481                                 self.BUTTON_ATCK_prev = 0;
 482                         }
 483
 484                         if (self.BUTTON_ATCK2)
 485                         {
 486                                 if (time >= self.electro_secondarytime)
 487                                 if (weapon_prepareattack(1, autocvar_g_balance_electro_secondary_refire))
 488                                 {
 489                                         W_Electro_Attack2();
 490                                         self.electro_count = autocvar_g_balance_electro_secondary_count;
 491                                         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_electro_secondary_animtime, w_electro_checkattack);
 492                                         self.electro_secondarytime = time + autocvar_g_balance_electro_secondary_refire2 * W_WeaponRateFactor();
 493                                 }
 494                         }
 495                 }
 496         }
 497         else if (req == WR_PRECACHE)
 498         {
 499                 precache_model ("models/weapons/g_electro.md3");
 500                 precache_model ("models/weapons/v_electro.md3");
 501                 precache_model ("models/weapons/h_electro.iqm");
 502                 precache_sound ("weapons/electro_bounce.wav");
 503                 precache_sound ("weapons/electro_fire.wav");
 504                 precache_sound ("weapons/electro_fire2.wav");
 505                 precache_sound ("weapons/electro_impact.wav");
 506                 precache_sound ("weapons/electro_impact_combo.wav");
 507                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 508                 if(autocvar_g_balance_electro_lightning)
 509                 {
 510                         precache_sound ("weapons/lgbeam_fire.wav");
 511                 }
 512         }
 513         else if (req == WR_SETUP)
 514         {
 515                 weapon_setup(WEP_ELECTRO);
 516                 self.current_ammo = ammo_cells;
 517         }
 518         else if (req == WR_CHECKAMMO1)
 519         {
 520                 if(autocvar_g_balance_electro_lightning)
 521                 {
 522                         if(!autocvar_g_balance_electro_primary_ammo)
 523                                 ammo_amount = 1;
 524                         else
 525                                 ammo_amount = self.ammo_cells > 0;
 526                         ammo_amount += self.(weapon_load[WEP_ELECTRO]) > 0;
 527                 }
 528                 else
 529                 {
 530                         ammo_amount = self.ammo_cells >= autocvar_g_balance_electro_primary_ammo;
 531                         ammo_amount += self.(weapon_load[WEP_ELECTRO]) >= autocvar_g_balance_electro_primary_ammo;
 532                 }
 533                 return ammo_amount;
 534         }
 535         else if (req == WR_CHECKAMMO2)
 536         {
 537                 if(autocvar_g_balance_electro_combo_safeammocheck) // true if you can fire at least one secondary blob AND one primary shot after it, otherwise false.
 538                 {
 539                         ammo_amount = self.ammo_cells >= autocvar_g_balance_electro_secondary_ammo + autocvar_g_balance_electro_primary_ammo;
 540                         ammo_amount += self.(weapon_load[WEP_ELECTRO]) >= autocvar_g_balance_electro_secondary_ammo + autocvar_g_balance_electro_primary_ammo;
 541                 }
 542                 else
 543                 {
 544                         ammo_amount = self.ammo_cells >= autocvar_g_balance_electro_secondary_ammo;
 545                         ammo_amount += self.(weapon_load[WEP_ELECTRO]) >= autocvar_g_balance_electro_secondary_ammo;
 546                 }
 547                 return ammo_amount;
 548         }
 549         else if (req == WR_RESETPLAYER)
 550         {
 551                 self.electro_secondarytime = time;
 552         }
 553         else if (req == WR_RELOAD)
 554         {
 555                 W_Reload(min(autocvar_g_balance_electro_primary_ammo, autocvar_g_balance_electro_secondary_ammo), autocvar_g_balance_electro_reload_ammo, autocvar_g_balance_electro_reload_time, "weapons/reload.wav");
 556         }
 557         else if (req == WR_SUICIDEMESSAGE)
 558         {
 559                 if(w_deathtype & HITTYPE_SECONDARY)
 560                         return WEAPON_ELECTRO_SUICIDE_ORBS;
 561                 else
 562                         return WEAPON_ELECTRO_SUICIDE_BOLT;
 563         }
 564         else if (req == WR_KILLMESSAGE)
 565         {
 566                 if(w_deathtype & HITTYPE_SECONDARY)
 567                 {
 568                         return WEAPON_ELECTRO_MURDER_ORBS;
 569                 }
 570                 else
 571                 {
 572                         if(w_deathtype & HITTYPE_BOUNCE)
 573                                 return WEAPON_ELECTRO_MURDER_COMBO;
 574                         else
 575                                 return WEAPON_ELECTRO_MURDER_BOLT;
 576                 }
 577         }
 578         return TRUE;
 579 }
 580 #endif
 581 #ifdef CSQC
 582 float w_electro(float req)
 583 {
 584         if(req == WR_IMPACTEFFECT)
 585         {
 586                 vector org2;
 587                 org2 = w_org + w_backoff * 6;
 588                 if(w_deathtype & HITTYPE_SECONDARY)
 589                 {
 590                         pointparticles(particleeffectnum("electro_ballexplode"), org2, '0 0 0', 1);
 591                         if(!w_issilent)
 592                                 sound(self, CH_SHOTS, "weapons/electro_impact.wav", VOL_BASE, ATTN_NORM);
 593                 }
 594                 else
 595                 {
 596                         if(w_deathtype & HITTYPE_BOUNCE)
 597                         {
 598                                 // this is sent as "primary (w_deathtype & HITTYPE_BOUNCE)" to distinguish it from (w_deathtype & HITTYPE_SECONDARY) bounced balls
 599                                 pointparticles(particleeffectnum("electro_combo"), org2, '0 0 0', 1);
 600                                 if(!w_issilent)
 601                                         sound(self, CH_SHOTS, "weapons/electro_impact_combo.wav", VOL_BASE, ATTN_NORM);
 602                         }
 603                         else
 604                         {
 605                                 pointparticles(particleeffectnum("electro_impact"), org2, '0 0 0', 1);
 606                                 if(!w_issilent)
 607                                         sound(self, CH_SHOTS, "weapons/electro_impact.wav", VOL_BASE, ATTN_NORM);
 608                         }
 609                 }
 610         }
 611         else if(req == WR_PRECACHE)
 612         {
 613                 precache_sound("weapons/electro_impact.wav");
 614                 precache_sound("weapons/electro_impact_combo.wav");
 615         }
 616         return TRUE;
 617 }
 618 #endif
 619 #endif