qcsrc/server/vehicles/vehicles.qc

   1 float autocvar_g_vehicles_crush_dmg;
   2 float autocvar_g_vehicles_crush_force;
   3 float autocvar_g_vehicles_delayspawn;
   4 float autocvar_g_vehicles_delayspawn_jitter;
   5
   6 void vehicles_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force);
   7 void vehicles_return();
   8 void vehicles_enter();
   9 void vehicles_touch();
  10 void vehicles_reset_colors();
  11 void vehicles_clearrturn();
  12 void vehicles_setreturn();
  13
  14
  15 /** AuxiliaryXhair*
  16     Send additional points of interest to be drawn, to vehicle owner
  17 **/
  18 float MAX_AXH = 4;
  19 .entity AuxiliaryXhair[MAX_AXH];
  20
  21 float SendAuxiliaryXhair(entity to, float sf)
  22 {
  23
  24         WriteByte(MSG_ENTITY, ENT_CLIENT_AUXILIARYXHAIR);
  25
  26         WriteByte(MSG_ENTITY, self.cnt);
  27
  28         WriteCoord(MSG_ENTITY, self.origin_x);
  29         WriteCoord(MSG_ENTITY, self.origin_y);
  30         WriteCoord(MSG_ENTITY, self.origin_z);
  31
  32     WriteByte(MSG_ENTITY, rint(self.colormod_x * 255));
  33     WriteByte(MSG_ENTITY, rint(self.colormod_y * 255));
  34     WriteByte(MSG_ENTITY, rint(self.colormod_z * 255));
  35
  36     return TRUE;
  37 }
  38
  39 void UpdateAuxiliaryXhair(entity own, vector loc, vector clr, float axh_id)
  40 {
  41     entity axh;
  42
  43     axh_id = bound(0, axh_id, MAX_AXH);
  44     axh = own.AuxiliaryXhair[axh_id];
  45
  46     if(axh == world || wasfreed(axh))  // MADNESS? THIS IS QQQQCCCCCCCCC (wasfreed, why do you exsist?)
  47     {
  48         axh                     = spawn();
  49         axh.cnt                 = axh_id;
  50         axh.drawonlytoclient    = own;
  51         axh.owner               = own;
  52         Net_LinkEntity(axh, FALSE, 0, SendAuxiliaryXhair);
  53     }
  54
  55     setorigin(axh, loc);
  56     axh.colormod            = clr;
  57     axh.SendFlags           = 0x01;
  58     own.AuxiliaryXhair[axh_id] = axh;
  59 }
  60
  61 /*
  62 // SVC_TEMPENTITY based, horrible with even 50 ping. hm.
  63 // WriteByte(MSG_ONE, SVC_TEMPENTITY) uses reliable messagess, never use for thinsg that need continous updates.
  64 void SendAuxiliaryXhair2(entity own, vector loc, vector clr, float axh_id)
  65 {
  66         msg_entity = own;
  67
  68         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  69         WriteByte(MSG_ONE, TE_CSQC_AUXILIARYXHAIR);
  70
  71         WriteByte(MSG_ONE, axh_id);
  72
  73         WriteCoord(MSG_ONE, loc_x);
  74         WriteCoord(MSG_ONE, loc_y);
  75         WriteCoord(MSG_ONE, loc_z);
  76
  77     WriteByte(MSG_ONE, rint(clr_x * 255));
  78     WriteByte(MSG_ONE, rint(clr_y * 255));
  79     WriteByte(MSG_ONE, rint(clr_z * 255));
  80
  81 }
  82 */
  83 // End AuxiliaryXhair
  84
  85 /**
  86     Notifies the client that he enterd a vehicle, and sends
  87     realavent data.
  88
  89     only sends vehicle_id atm (wich is a HUD_* constant, ex. HUD_SPIDERBOT)
  90 **/
  91 void CSQCVehicleSetup(entity own, float vehicle_id)
  92 {
  93         msg_entity = own;
  94
  95         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  96         WriteByte(MSG_ONE, TE_CSQC_VEHICLESETUP);
  97         WriteByte(MSG_ONE, vehicle_id);
  98 }
  99
 100 /** vehicles_locktarget
 101
 102     Generic target locking.
 103
 104     Figure out if what target is "locked" (if any), for missile tracking as such.
 105
 106     after calling, "if(self.lock_target != world && self.lock_strength == 1)" mean
 107     you have a locked in target.
 108
 109     Exspects a crosshair_trace() or equivalent to be
 110     dont before calling.
 111
 112 **/
 113 .entity lock_target;
 114 .float  lock_strength;
 115 .float  lock_time;
 116 .float  lock_soundtime;
 117 void vehicles_locktarget(float incr, float decr, float _lock_time)
 118 {
 119     if(self.lock_target && self.lock_target.deadflag != DEAD_NO)
 120     {
 121         self.lock_target    = world;
 122         self.lock_strength  = 0;
 123         self.lock_time      = 0;
 124     }
 125
 126     if(self.lock_time > time)
 127     {
 128         if(self.lock_target)
 129         if(self.lock_soundtime < time)
 130         {
 131             self.lock_soundtime = time + 0.5;
 132             play2(self.owner, "vehicles/locked.wav");
 133         }
 134
 135         return;
 136     }
 137
 138     if(trace_ent != world)
 139     {
 140         if(teamplay && trace_ent.team == self.team)
 141             trace_ent = world;
 142
 143         if(trace_ent.deadflag != DEAD_NO)
 144             trace_ent = world;
 145
 146         if not (trace_ent.vehicle_flags & VHF_ISVEHICLE || trace_ent.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 147             trace_ent = world;
 148     }
 149
 150     if(self.lock_target == world && trace_ent != world)
 151         self.lock_target = trace_ent;
 152
 153     if(self.lock_target && trace_ent == self.lock_target)
 154     {
 155         if(self.lock_strength != 1 && self.lock_strength + incr >= 1)
 156         {
 157             play2(self.owner, "vehicles/lock.wav");
 158             self.lock_soundtime = time + 0.8;
 159         }
 160         else if (self.lock_strength != 1 && self.lock_soundtime < time)
 161         {
 162             play2(self.owner, "vehicles/locking.wav");
 163             self.lock_soundtime = time + 0.3;
 164         }
 165
 166     }
 167
 168     // Have a locking target
 169     // Trace hit current target
 170     if(trace_ent == self.lock_target && trace_ent != world)
 171     {
 172         self.lock_strength = min(self.lock_strength + incr, 1);
 173         if(self.lock_strength == 1)
 174             self.lock_time = time + _lock_time;
 175     }
 176     else
 177     {
 178         if(trace_ent)
 179             self.lock_strength = max(self.lock_strength - decr * 2, 0);
 180         else
 181             self.lock_strength = max(self.lock_strength - decr, 0);
 182
 183         if(self.lock_strength == 0)
 184             self.lock_target = world;
 185     }
 186 }
 187
 188 #define VEHICLE_UPDATE_PLAYER(fld,vhname) \
 189 self.owner.vehicle_##fld = (self.vehicle_##fld / autocvar_g_vehicle_##vhname##_##fld) * 100
 190
 191 #define vehicles_sweap_collision(orig,vel,dt,acm,mult) \
 192 traceline(orig, orig + vel * dt, MOVE_NORMAL, self); \
 193 if(trace_fraction != 1) \
 194     acm += normalize(self.origin - trace_endpos) * (vlen(vel) * mult)
 195
 196 // Hover movement support
 197 float  force_fromtag_power;
 198 float  force_fromtag_normpower;
 199 vector force_fromtag_origin;
 200 vector vehicles_force_fromtag_hover(string tag_name, float spring_length, float max_power)
 201 {
 202     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 203     v_forward  = normalize(v_forward) * -1;
 204     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 205
 206     force_fromtag_power = (1 - trace_fraction) * max_power;
 207     force_fromtag_normpower = force_fromtag_power / max_power;
 208
 209     return v_forward  * force_fromtag_power;
 210 }
 211
 212 // Experimental hovermode wich uses attraction/repulstion from surface insted of gravity/repulsion
 213 // Can possibly be use to move abt any surface (inclusing walls/celings)
 214 vector vehicles_force_fromtag_maglev(string tag_name, float spring_length, float max_power)
 215 {
 216
 217     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 218     v_forward  = normalize(v_forward) * -1;
 219     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 220
 221     // TODO - this may NOT be compatible with wall/celing movement, unhardcode 0.25 (engine count multiplier)
 222     if(trace_fraction == 1.0)
 223     {
 224         force_fromtag_normpower = -0.25;
 225         return '0 0 -200';
 226     }
 227
 228     force_fromtag_power = ((1 - trace_fraction) - trace_fraction) * max_power;
 229     force_fromtag_normpower = force_fromtag_power / max_power;
 230
 231     return v_forward  * force_fromtag_power;
 232 }
 233
 234 // Generic vehile projectile system
 235 void vehicles_projectile_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 236 {
 237     // Ignore damage from oterh projectiles from my owner (dont mess up volly's)
 238     if(inflictor.owner == self.owner)
 239         return;
 240
 241     self.health -= damage;
 242     self.velocity += force;
 243     if(self.health < 1)
 244     {
 245         self.takedamage = DAMAGE_NO;
 246         self.event_damage = SUB_Null;
 247         self.think = self.use;
 248         self.nextthink = time;
 249     }
 250
 251 }
 252
 253 void vehicles_projectile_explode()
 254 {
 255     if(self.owner && other != world)
 256     {
 257         if(other == self.owner.vehicle)
 258             return;
 259
 260         if(other == self.owner.vehicle.tur_head)
 261             return;
 262     }
 263
 264         PROJECTILE_TOUCH;
 265
 266         self.event_damage = SUB_Null;
 267     RadiusDamage (self, self.realowner, self.shot_dmg, 0, self.shot_radius, self, self.shot_force, self.totalfrags, other);
 268
 269     remove (self);
 270 }
 271
 272 entity vehicles_projectile(string _mzlfx, string _mzlsound,
 273                            vector _org, vector _vel,
 274                            float _dmg, float _radi, float _force,  float _size,
 275                            float _deahtype, float _projtype, float _health,
 276                            float _cull, float _clianim)
 277 {
 278     entity proj;
 279
 280     proj = spawn();
 281
 282     PROJECTILE_MAKETRIGGER(proj);
 283     setorigin(proj, _org);
 284
 285     proj.shot_dmg         = _dmg;
 286     proj.shot_radius      = _radi;
 287     proj.shot_force       = _force;
 288     proj.totalfrags       = _deahtype;
 289     proj.solid            = SOLID_BBOX;
 290     proj.movetype         = MOVETYPE_FLYMISSILE;
 291     proj.flags            = FL_PROJECTILE;
 292     proj.bot_dodge        = TRUE;
 293     proj.bot_dodgerating  = _dmg;
 294     proj.velocity         = _vel;
 295     proj.touch            = vehicles_projectile_explode;
 296     proj.use              = vehicles_projectile_explode;
 297     proj.owner            = self;
 298     proj.realowner        = self.owner;
 299     proj.think            = SUB_Remove;
 300     proj.nextthink        = time + 30;
 301
 302     if(_health)
 303     {
 304         proj.takedamage       = DAMAGE_AIM;
 305         proj.event_damage     = vehicles_projectile_damage;
 306         proj.health           = _health;
 307     }
 308     else
 309         proj.flags           = FL_PROJECTILE | FL_NOTARGET;
 310
 311     if(_mzlsound)
 312         sound (self, CHAN_WEAPON, _mzlsound, VOL_BASE, ATTN_NORM);
 313
 314     if(_mzlfx)
 315         pointparticles(particleeffectnum(_mzlfx), proj.origin, proj.velocity, 1);
 316
 317
 318     setsize (proj, '-1 -1 -1' * _size, '1 1 1' * _size);
 319
 320     CSQCProjectile(proj, _clianim, _projtype, _cull);
 321
 322     return proj;
 323 }
 324 // End generic vehile projectile system
 325
 326 /** vehicles_spawn
 327     Exetuted for all vehicles on (re)spawn.
 328     Sets defaults for newly spawned units.
 329 **/
 330 void vehicles_spawn()
 331 {
 332     dprint("Spawning vehicle: ", self.netname, "\n");
 333
 334     // De-own & reset
 335     self.vehicle_hudmodel.viewmodelforclient = self;
 336
 337     self.owner              = world;
 338     self.touch              = vehicles_touch;
 339     self.event_damage       = vehicles_damage;
 340     self.iscreature         = TRUE;
 341     self.movetype           = MOVETYPE_WALK;
 342     self.solid              = SOLID_SLIDEBOX;
 343     self.takedamage         = DAMAGE_AIM;
 344         self.deadflag           = DEAD_NO;
 345     self.bot_attack         = TRUE;
 346     self.flags              = FL_NOTARGET;
 347     self.avelocity          = '0 0 0';
 348     self.velocity           = '0 0 0';
 349
 350     // Reset locking
 351     self.lock_strength      = 0;
 352     self.lock_target        = world;
 353     self.misc_bulletcounter = 0;
 354
 355     // Return to spawn
 356     self.angles             = self.pos2;
 357     setorigin(self, self.pos1 + '0 0 128');
 358     // Show it
 359     pointparticles(particleeffectnum("teleport"), self.origin + '0 0 64', '0 0 0', 1);
 360
 361     vehicles_reset_colors();
 362     self.vehicle_spawn();
 363 }
 364
 365 // Better way of determening whats crushable needed! (fl_crushable?)
 366 float vehicles_crushable(entity e)
 367 {
 368     if(e.classname == "player")
 369         return TRUE;
 370
 371     if(e.classname == "monster_zombie")
 372         return TRUE;
 373
 374     return FALSE;
 375 }
 376
 377 void vehicles_touch()
 378 {
 379     // Vehicle currently in use
 380     if(self.owner)
 381     {
 382         // Colided with world?
 383         if(other == world)
 384         {
 385             // Apply velocity based self damage here
 386         }
 387         else
 388         {
 389             if(other.vehicle_flags & VHF_ISVEHICLE)
 390             {
 391                 //other.velocity += self.velocity * (self.mass / other.mass);
 392             }
 393             else if(vehicles_crushable(other))
 394             {
 395                 if(vlen(self.velocity) != 0)
 396                     Damage(other, self, self.owner, autocvar_g_vehicles_crush_dmg, DEATH_VHCRUSH, '0 0 0', normalize(other.origin - self.origin) * autocvar_g_vehicles_crush_force);
 397             }
 398         }
 399         return;
 400     }
 401
 402     if(other.classname != "player")
 403         return;
 404
 405     if(other.deadflag != DEAD_NO)
 406         return;
 407
 408     if(other.vehicle != world)
 409         return;
 410
 411     // Remove this when bots know how to use vehicles.
 412     if (clienttype(other) != CLIENTTYPE_REAL)
 413         return;
 414
 415     vehicles_enter();
 416 }
 417
 418 void vehicles_enter()
 419 {
 420    // Remove this when bots know how to use vehicles
 421     if (clienttype(other) != CLIENTTYPE_REAL)
 422         return;
 423
 424     if(self.phase > time)
 425         return;
 426
 427     if(teamplay)
 428     if(self.team)
 429     if(self.team != other.team)
 430         return;
 431
 432     self.vehicle_ammo1   = 0;
 433     self.vehicle_ammo2   = 0;
 434     self.vehicle_reload1 = 0;
 435     self.vehicle_reload2 = 0;
 436     self.vehicle_energy  = 0;
 437
 438     self.owner          = other;
 439     self.switchweapon   = other.switchweapon;
 440
 441     // .viewmodelforclient works better.
 442     //self.vehicle_hudmodel.drawonlytoclient = self.owner;
 443
 444     self.vehicle_hudmodel.viewmodelforclient = self.owner;
 445
 446     self.event_damage         = vehicles_damage;
 447     self.nextthink            = 0;
 448     self.owner.angles         = self.angles;
 449     self.owner.takedamage     = DAMAGE_NO;
 450     self.owner.solid          = SOLID_NOT;
 451     self.owner.movetype       = MOVETYPE_NOCLIP;
 452     self.owner.alpha          = -1;
 453     self.owner.vehicle        = self;
 454     self.owner.event_damage   = SUB_Null;
 455     self.owner.view_ofs       = '0 0 0';
 456     self.colormap             = self.owner.colormap;
 457     if(self.tur_head)
 458         self.tur_head.colormap    = self.owner.colormap;
 459
 460     self.owner.hud            = self.hud;
 461     self.owner.PlayerPhysplug = self.PlayerPhysplug;
 462
 463     self.owner.vehicle_ammo1    = self.vehicle_ammo1;
 464     self.owner.vehicle_ammo2    = self.vehicle_ammo2;
 465     self.owner.vehicle_reload1  = self.vehicle_reload1;
 466     self.owner.vehicle_reload2  = self.vehicle_reload2;
 467
 468     // Cant do this, hides attached objects too.
 469     //self.exteriormodeltoclient = self.owner;
 470     //self.tur_head.exteriormodeltoclient = self.owner;
 471
 472     other.flags &~= FL_ONGROUND;
 473     self.flags  &~= FL_ONGROUND;
 474
 475     self.team                 = self.owner.team;
 476     self.flags               -= FL_NOTARGET;
 477
 478     msg_entity = other;
 479     WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 480     WriteEntity(MSG_ONE, self.vehicle_viewport);
 481
 482     WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 483     if(self.tur_head)
 484     {
 485         WriteAngle(MSG_ONE, self.tur_head.angles_x + self.angles_x); // tilt
 486         WriteAngle(MSG_ONE, self.tur_head.angles_y + self.angles_y); // yaw
 487         WriteAngle(MSG_ONE, 0);                                      // roll
 488     }
 489     else
 490     {
 491         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 492         WriteAngle(MSG_ONE,  self.angles_x * -1); // tilt
 493         WriteAngle(MSG_ONE,  self.angles_y);      // yaw
 494         WriteAngle(MSG_ONE,  0);                  // roll
 495     }
 496
 497     vehicles_clearrturn();
 498
 499     CSQCVehicleSetup(self.owner, self.hud);
 500
 501     if(other.flagcarried)
 502     {
 503         other.flagcarried.scale = 1;
 504         setattachment(other.flagcarried, self, "");
 505         setorigin(other, '0 0 96');
 506     }
 507
 508     self.vehicle_enter();
 509 }
 510
 511 /** vehicles_findgoodexit
 512     Locates a valid location for the player to exit the vehicle.
 513     Will first try prefer_spot, then up 100 random spots arround the vehicle
 514     wich are in direct line of sight and empty enougth to hold a players bbox
 515 **/
 516 vector vehicles_findgoodexit(vector prefer_spot)
 517 {
 518     //vector exitspot;
 519     float mysize;
 520
 521     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, prefer_spot, MOVE_NORMAL, self.owner);
 522     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 523         return prefer_spot;
 524
 525     mysize = vlen(self.maxs - self.mins);
 526     float i;
 527     vector v, v2;
 528     v2 = 0.5 * (self.absmin + self.absmax);
 529     for(i = 0; i < 100; ++i)
 530     {
 531         v = randomvec();
 532         v_z = 0;
 533         v = v2 + normalize(v) * mysize;
 534         tracebox(v2, PL_MIN, PL_MAX, v, MOVE_NORMAL, self.owner);
 535         if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 536             return v;
 537     }
 538
 539     /*
 540     exitspot = (self.origin + '0 0 48') + v_forward * mysize;
 541     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 542     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 543         return exitspot;
 544
 545     exitspot = (self.origin + '0 0 48') - v_forward * mysize;
 546     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 547     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 548         return exitspot;
 549
 550     exitspot = (self.origin + '0 0 48') + v_right * mysize;
 551     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 552     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 553         return exitspot;
 554
 555     exitspot = (self.origin + '0 0 48') - v_right * mysize;
 556     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 557     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 558         return exitspot;
 559     */
 560
 561     return self.origin;
 562 }
 563
 564 /** vehicles_exit
 565     Standarrd vehicle release fucntion.
 566     custom code goes in self.vehicle_exit
 567 **/
 568 void vehicles_exit(float eject)
 569 {
 570         self.flags |= FL_NOTARGET;
 571
 572     if (self.owner)
 573     {
 574         msg_entity = self.owner;
 575         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 576         WriteEntity( MSG_ONE, self.owner);
 577
 578         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 579         WriteAngle(MSG_ONE, 0);                 // pich
 580         WriteAngle(MSG_ONE, self.angles_y);     // yaw
 581         WriteAngle(MSG_ONE, 0);                 // roll
 582
 583         setsize(self.owner, PL_MIN,PL_MAX);
 584
 585         self.owner.takedamage     = DAMAGE_AIM;
 586         self.owner.solid          = SOLID_SLIDEBOX;
 587         self.owner.movetype       = MOVETYPE_WALK;
 588         self.owner.effects        &~= EF_NODRAW;
 589         self.owner.alpha          = 1;
 590         self.owner.PlayerPhysplug = SUB_Null;
 591         self.owner.vehicle        = world;
 592         self.owner.view_ofs       = PL_VIEW_OFS;
 593         self.owner.event_damage   = PlayerDamage;
 594         self.owner.hud            = HUD_NORMAL;
 595         self.owner.switchweapon   = self.switchweapon;
 596         //self.owner.BUTTON_USE     = 0;
 597     }
 598
 599     if(self.deadflag == DEAD_NO)
 600         self.avelocity          = '0 0 0';
 601
 602     self.vehicle_hudmodel.viewmodelforclient = self;
 603         self.tur_head.nodrawtoclient             = world;
 604     vehicles_setreturn();
 605
 606     self.phase = time + 1;
 607
 608     if(!teamplay)
 609         self.team = 0;
 610
 611     if(self.owner.flagcarried)
 612     {
 613         self.owner.flagcarried.scale = 0.6;
 614         setattachment(self.owner.flagcarried, self.owner, "");
 615         setorigin(self.owner.flagcarried, FLAG_CARRY_POS);
 616     }
 617
 618     self.vehicle_exit(eject);
 619     self.owner = world;
 620 }
 621
 622
 623 void vehicles_regen(.float timer, .float regen_field, float field_max, float rpause, float regen, float delta_time)
 624 {
 625     if(self.regen_field < field_max)
 626     if(self.timer + rpause < time)
 627     {
 628         self.regen_field = min(self.regen_field + regen * delta_time, field_max);
 629
 630         if(self.owner)
 631             self.owner.regen_field = (self.regen_field / field_max) * 100;
 632     }
 633 }
 634
 635 void shieldhit_think()
 636 {
 637     self.alpha -= 0.1;
 638     if (self.alpha <= 0)
 639     {
 640         //setmodel(self, "");
 641         self.alpha = -1;
 642     }
 643     else
 644     {
 645         self.nextthink = time + 0.1;
 646     }
 647 }
 648
 649 void vehicles_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 650 {
 651     self.dmg_time = time;
 652
 653     if((self.vehicle_flags & VHF_HASSHIELD) && (self.vehicle_shield > 0))
 654     {
 655         if (wasfreed(self.vehicle_shieldent) || self.vehicle_shieldent == world)
 656         {
 657             self.vehicle_shieldent = spawn();
 658             self.vehicle_shieldent.effects = EF_LOWPRECISION;
 659
 660             setmodel(self.vehicle_shieldent, "models/vhshield.md3");
 661             setattachment(self.vehicle_shieldent, self, "");
 662             setorigin(self.vehicle_shieldent, real_origin(self) - self.origin);
 663             self.vehicle_shieldent.scale       = 256 / vlen(self.maxs - self.mins);
 664             self.vehicle_shieldent.think       = shieldhit_think;
 665         }
 666
 667
 668         self.vehicle_shieldent.colormod    = '1 1 1';
 669         self.vehicle_shieldent.alpha       = 0.45;
 670         self.vehicle_shieldent.angles      = vectoangles(normalize(hitloc - (self.origin + self.vehicle_shieldent.origin))) - self.angles;
 671         self.vehicle_shieldent.nextthink   = time;
 672
 673         self.vehicle_shield -= damage;
 674
 675         if(self.vehicle_shield < 0)
 676         {
 677             self.vehicle_shieldent.colormod = '2 0 0';
 678             self.vehicle_shield             = 0;
 679             self.vehicle_shieldent.alpha    = 0.75;
 680             self.vehicle_health            -= fabs(self.vehicle_shield);
 681         }
 682     }
 683     else
 684         self.vehicle_health -= damage;
 685
 686     self.velocity += force; // * (vlen(force) / self.mass);
 687
 688     if(self.vehicle_health <= 0)
 689     {
 690         if(self.owner)
 691             if(self.vehicle_flags & VHF_DEATHEJECT)
 692                 vehicles_exit(VHEF_EJECT);
 693             else
 694                 vehicles_exit(VHEF_RELESE);
 695
 696         self.vehicle_die();
 697         vehicles_setreturn();
 698     }
 699 }
 700
 701 void vehicles_clearrturn()
 702 {
 703     entity ret;
 704     // Remove "return helper", if any.
 705     ret = findchain(classname, "vehicle_return");
 706     while(ret)
 707     {
 708         if(ret.enemy == self)
 709         {
 710             ret.classname   = "";
 711             ret.think       = SUB_Remove;
 712             ret.nextthink   = time + 0.1;
 713
 714             if(ret.waypointsprite_attached)
 715                 WaypointSprite_Kill(ret.waypointsprite_attached);
 716
 717             return;
 718         }
 719         ret = ret.chain;
 720     }
 721 }
 722
 723 void vehicles_return()
 724 {
 725     pointparticles(particleeffectnum("teleport"), self.enemy.origin + '0 0 64', '0 0 0', 1);
 726
 727     self.enemy.think     = vehicles_spawn;
 728     self.enemy.nextthink = time;
 729
 730     if(self.waypointsprite_attached)
 731         WaypointSprite_Kill(self.waypointsprite_attached);
 732
 733     remove(self);
 734 }
 735
 736 void vehicles_showwp_goaway()
 737 {
 738     if(self.waypointsprite_attached)
 739         WaypointSprite_Kill(self.waypointsprite_attached);
 740
 741     remove(self);
 742
 743 }
 744
 745 void vehicles_showwp()
 746 {
 747     entity oldself;
 748
 749     if(self.cnt)
 750     {
 751         self.think      = vehicles_return;
 752         self.nextthink  = self.cnt;
 753     }
 754     else
 755     {
 756         self.think      = vehicles_return;
 757         self.nextthink  = time +1;
 758
 759         oldself = self;
 760         self = spawn();
 761         setmodel(self, "null");
 762         self.team = oldself.enemy.team;
 763         self.enemy = oldself.enemy;
 764         setorigin(self, oldself.enemy.pos1);
 765
 766         self.nextthink = time + 5;
 767         self.think = vehicles_showwp_goaway;
 768     }
 769
 770     WaypointSprite_Spawn("vehicle", 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE);
 771     if(self.waypointsprite_attached)
 772     {
 773
 774         if(teamplay && self.team)
 775             WaypointSprite_UpdateTeamRadar(self.waypointsprite_attached, RADARICON_POWERUP, TeamColor(self.team));
 776         else
 777             WaypointSprite_UpdateTeamRadar(self.waypointsprite_attached, RADARICON_POWERUP, '1 1 1');
 778
 779         WaypointSprite_UpdateRule(self.waypointsprite_attached, self.enemy.team, SPRITERULE_DEFAULT);
 780         if(oldself == world)
 781         {
 782             WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, self.nextthink);
 783             dprint("Oldies is goldies\n");
 784         }
 785
 786         WaypointSprite_Ping(self.waypointsprite_attached);
 787     }
 788
 789     if(oldself != world)
 790         self = oldself;
 791 }
 792
 793 void vehicles_setreturn()
 794 {
 795     entity ret;
 796
 797     vehicles_clearrturn();
 798
 799     ret = spawn();
 800     ret.classname   = "vehicle_return";
 801     ret.enemy       = self;
 802     ret.team        = self.team;
 803     ret.think       = vehicles_showwp;
 804
 805     if(self.deadflag != DEAD_NO)
 806     {
 807         ret.cnt         = time + self.vehicle_respawntime;
 808         ret.nextthink   = min(time + self.vehicle_respawntime, time + self.vehicle_respawntime - 5);
 809     }
 810     else
 811     {
 812         ret.nextthink   = min(time + self.vehicle_respawntime, time + self.vehicle_respawntime - 1);
 813     }
 814
 815
 816
 817     setmodel(ret, "null");
 818     setorigin(ret, self.pos1 + '0 0 96');
 819
 820 }
 821
 822 void vehicles_configcheck(string  configname, float check_cvar)
 823 {
 824     if(check_cvar == 0)
 825         localcmd(strcat("exec ", configname, "\n"));
 826 }
 827
 828 void vehicles_reset_colors()
 829 {
 830     entity e;
 831     float _effects, _colormap;
 832     vector _glowmod, _colormod;
 833
 834     if(autocvar_g_nodepthtestplayers)
 835         _effects = EF_NODEPTHTEST;
 836
 837     if(autocvar_g_fullbrightplayers)
 838         _effects |= EF_FULLBRIGHT;
 839
 840     if(self.team)
 841         _colormap = 1024 + (self.team - 1) * 17;
 842     else
 843         _colormap = 1024;
 844
 845     _glowmod  = '0 0 0';
 846     _colormod = '0 0 0';
 847
 848     // Find all ents attacked to main model and setup effects, colormod etc.
 849     e = findchainentity(tag_entity, self);
 850     while(e)
 851     {
 852         if(e != self.vehicle_shieldent)
 853         {
 854             e.effects   = _effects  | EF_LOWPRECISION;
 855             e.colormod  = _colormod;
 856             e.colormap  = _colormap;
 857             e.alpha     = 1;
 858         }
 859         e = e.chain;
 860     }
 861
 862     self.vehicle_hudmodel.effects  = self.effects  = _effects | EF_LOWPRECISION;
 863     self.vehicle_hudmodel.colormod = self.colormod = _colormod;
 864     self.vehicle_hudmodel.colormap = self.colormap = _colormap;
 865     self.vehicle_viewport.effects = (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NOGUNBOB | EF_NOSHADOW | EF_LOWPRECISION | EF_SELECTABLE | EF_TELEPORT_BIT);
 866
 867     self.alpha     = 1;
 868     self.avelocity = '0 0 0';
 869     self.velocity  = '0 0 0';
 870     self.effects   = _effects;
 871 }
 872
 873 float vehicle_initialize(string  net_name,
 874                          string  bodymodel,
 875                          string  topmodel,
 876                          string  hudmodel,
 877                          string  toptag,
 878                          string  hudtag,
 879                          string  viewtag,
 880                          float   vhud,
 881                          vector  min_s,
 882                          vector  max_s,
 883                          float   nodrop,
 884                          void()  spawnproc,
 885                          float   _respawntime,
 886                          float() physproc,
 887                          void()  enterproc,
 888                          void(float extflag) exitfunc,
 889                          void() dieproc,
 890                          void() thinkproc,
 891                          float  use_csqc)
 892 {
 893     addstat(STAT_HUD, AS_INT,  hud);
 894         addstat(STAT_VEHICLESTAT_HEALTH,  AS_INT, vehicle_health);
 895         addstat(STAT_VEHICLESTAT_SHIELD,  AS_INT, vehicle_shield);
 896         addstat(STAT_VEHICLESTAT_ENERGY,  AS_INT, vehicle_energy);
 897
 898         addstat(STAT_VEHICLESTAT_AMMO1,   AS_INT,   vehicle_ammo1);
 899         addstat(STAT_VEHICLESTAT_RELOAD1, AS_INT, vehicle_reload1);
 900
 901         addstat(STAT_VEHICLESTAT_AMMO2,   AS_INT,   vehicle_ammo2);
 902         addstat(STAT_VEHICLESTAT_RELOAD2, AS_INT, vehicle_reload2);
 903
 904     if(bodymodel == "")
 905         error("vehicles: missing bodymodel!");
 906
 907     if(hudmodel == "")
 908         error("vehicles: missing hudmodel!");
 909
 910     if(net_name == "")
 911         self.netname = self.classname;
 912     else
 913         self.netname = net_name;
 914
 915     if(self.team && !teamplay)
 916         self.team = 0;
 917
 918     self.vehicle_flags |= VHF_ISVEHICLE;
 919
 920     setmodel(self, bodymodel);
 921
 922     self.vehicle_viewport   = spawn();
 923     self.vehicle_hudmodel   = spawn();
 924     self.tur_head           = spawn();
 925     self.tur_head.owner     = self;
 926     self.takedamage         = DAMAGE_AIM;
 927     self.bot_attack         = TRUE;
 928     self.iscreature         = TRUE;
 929     self.hud                = vhud;
 930
 931     self.vehicle_die         = dieproc;
 932     self.vehicle_exit        = exitfunc;
 933     self.vehicle_enter       = enterproc;
 934     self.PlayerPhysplug      = physproc;
 935     self.event_damage        = vehicles_damage;
 936     self.touch               = vehicles_touch;
 937     self.think               = vehicles_spawn;
 938     self.nextthink           = time;
 939     self.vehicle_respawntime = _respawntime;
 940     self.vehicle_spawn       = spawnproc;
 941
 942     if(autocvar_g_nodepthtestplayers)
 943         self.effects = self.effects | EF_NODEPTHTEST;
 944
 945     if(autocvar_g_fullbrightplayers)
 946         self.effects = self.effects | EF_FULLBRIGHT;
 947
 948     setmodel(self.vehicle_hudmodel, hudmodel);
 949     setmodel(self.vehicle_viewport, "null");
 950
 951
 952     if(topmodel != "")
 953     {
 954         setmodel(self.tur_head, topmodel);
 955         setattachment(self.tur_head, self, toptag);
 956         setattachment(self.vehicle_hudmodel, self.tur_head, hudtag);
 957         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
 958     }
 959     else
 960     {
 961         setattachment(self.tur_head, self, "");
 962         setattachment(self.vehicle_hudmodel, self, hudtag);
 963         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
 964     }
 965
 966     setsize(self, min_s, max_s);
 967     if not (nodrop)
 968     {
 969         setorigin(self, self.origin);
 970         tracebox(self.origin + '0 0 100', min_s, max_s, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
 971         setorigin(self, trace_endpos);
 972     }
 973
 974     self.pos1 = self.origin;
 975     self.pos2 = self.angles;
 976
 977     return TRUE;
 978 }
 979
 980 void bugmenot()
 981 {
 982     self.vehicle_exit       = self.vehicle_exit;
 983     self.vehicle_enter      = self.vehicle_exit;
 984     self.vehicle_die        = self.vehicle_exit;
 985     self.vehicle_spawn      = self.vehicle_exit;
 986     self.AuxiliaryXhair     = self.AuxiliaryXhair;
 987 }