qcsrc/server/vehicles/vehicles.qc

   1 float autocvar_g_vehicles_crush_dmg;
   2 float autocvar_g_vehicles_crush_force;
   3 float autocvar_g_vehicles_delayspawn;
   4 float autocvar_g_vehicles_delayspawn_jitter;
   5 float autocvar_g_vehicles_allow_flagcarry;
   6
   7 void vehicles_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force);
   8 void vehicles_return();
   9 void vehicles_enter();
  10 void vehicles_touch();
  11 void vehicles_reset_colors();
  12 void vehicles_clearrturn();
  13 void vehicles_setreturn();
  14
  15
  16 /** AuxiliaryXhair*
  17     Send additional points of interest to be drawn, to vehicle owner
  18 **/
  19 float MAX_AXH = 4;
  20 .entity AuxiliaryXhair[MAX_AXH];
  21
  22 float SendAuxiliaryXhair(entity to, float sf)
  23 {
  24
  25         WriteByte(MSG_ENTITY, ENT_CLIENT_AUXILIARYXHAIR);
  26
  27         WriteByte(MSG_ENTITY, self.cnt);
  28
  29         WriteCoord(MSG_ENTITY, self.origin_x);
  30         WriteCoord(MSG_ENTITY, self.origin_y);
  31         WriteCoord(MSG_ENTITY, self.origin_z);
  32
  33     WriteByte(MSG_ENTITY, rint(self.colormod_x * 255));
  34     WriteByte(MSG_ENTITY, rint(self.colormod_y * 255));
  35     WriteByte(MSG_ENTITY, rint(self.colormod_z * 255));
  36
  37     return TRUE;
  38 }
  39
  40 void UpdateAuxiliaryXhair(entity own, vector loc, vector clr, float axh_id)
  41 {
  42     entity axh;
  43
  44     axh_id = bound(0, axh_id, MAX_AXH);
  45     axh = own.AuxiliaryXhair[axh_id];
  46
  47     if(axh == world || wasfreed(axh))  // MADNESS? THIS IS QQQQCCCCCCCCC (wasfreed, why do you exsist?)
  48     {
  49         axh                     = spawn();
  50         axh.cnt                 = axh_id;
  51         axh.drawonlytoclient    = own;
  52         axh.owner               = own;
  53         Net_LinkEntity(axh, FALSE, 0, SendAuxiliaryXhair);
  54     }
  55
  56     setorigin(axh, loc);
  57     axh.colormod            = clr;
  58     axh.SendFlags           = 0x01;
  59     own.AuxiliaryXhair[axh_id] = axh;
  60 }
  61
  62 /*
  63 // SVC_TEMPENTITY based, horrible with even 50 ping. hm.
  64 // WriteByte(MSG_ONE, SVC_TEMPENTITY) uses reliable messagess, never use for thinsg that need continous updates.
  65 void SendAuxiliaryXhair2(entity own, vector loc, vector clr, float axh_id)
  66 {
  67         msg_entity = own;
  68
  69         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  70         WriteByte(MSG_ONE, TE_CSQC_AUXILIARYXHAIR);
  71
  72         WriteByte(MSG_ONE, axh_id);
  73
  74         WriteCoord(MSG_ONE, loc_x);
  75         WriteCoord(MSG_ONE, loc_y);
  76         WriteCoord(MSG_ONE, loc_z);
  77
  78     WriteByte(MSG_ONE, rint(clr_x * 255));
  79     WriteByte(MSG_ONE, rint(clr_y * 255));
  80     WriteByte(MSG_ONE, rint(clr_z * 255));
  81
  82 }
  83 */
  84 // End AuxiliaryXhair
  85
  86 /**
  87     Notifies the client that he enterd a vehicle, and sends
  88     realavent data.
  89
  90     only sends vehicle_id atm (wich is a HUD_* constant, ex. HUD_SPIDERBOT)
  91 **/
  92 void CSQCVehicleSetup(entity own, float vehicle_id)
  93 {
  94         msg_entity = own;
  95
  96         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  97         WriteByte(MSG_ONE, TE_CSQC_VEHICLESETUP);
  98         WriteByte(MSG_ONE, vehicle_id);
  99 }
 100
 101 /** vehicles_locktarget
 102
 103     Generic target locking.
 104
 105     Figure out if what target is "locked" (if any), for missile tracking as such.
 106
 107     after calling, "if(self.lock_target != world && self.lock_strength == 1)" mean
 108     you have a locked in target.
 109
 110     Exspects a crosshair_trace() or equivalent to be
 111     dont before calling.
 112
 113 **/
 114 .entity lock_target;
 115 .float  lock_strength;
 116 .float  lock_time;
 117 .float  lock_soundtime;
 118 void vehicles_locktarget(float incr, float decr, float _lock_time)
 119 {
 120     if(self.lock_target && self.lock_target.deadflag != DEAD_NO)
 121     {
 122         self.lock_target    = world;
 123         self.lock_strength  = 0;
 124         self.lock_time      = 0;
 125     }
 126
 127     if(self.lock_time > time)
 128     {
 129         if(self.lock_target)
 130         if(self.lock_soundtime < time)
 131         {
 132             self.lock_soundtime = time + 0.5;
 133             play2(self.owner, "vehicles/locked.wav");
 134         }
 135
 136         return;
 137     }
 138
 139     if(trace_ent != world)
 140     {
 141         if(teamplay && trace_ent.team == self.team)
 142             trace_ent = world;
 143
 144         if(trace_ent.deadflag != DEAD_NO)
 145             trace_ent = world;
 146
 147         if not (trace_ent.vehicle_flags & VHF_ISVEHICLE || trace_ent.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 148             trace_ent = world;
 149     }
 150
 151     if(self.lock_target == world && trace_ent != world)
 152         self.lock_target = trace_ent;
 153
 154     if(self.lock_target && trace_ent == self.lock_target)
 155     {
 156         if(self.lock_strength != 1 && self.lock_strength + incr >= 1)
 157         {
 158             play2(self.owner, "vehicles/lock.wav");
 159             self.lock_soundtime = time + 0.8;
 160         }
 161         else if (self.lock_strength != 1 && self.lock_soundtime < time)
 162         {
 163             play2(self.owner, "vehicles/locking.wav");
 164             self.lock_soundtime = time + 0.3;
 165         }
 166
 167     }
 168
 169     // Have a locking target
 170     // Trace hit current target
 171     if(trace_ent == self.lock_target && trace_ent != world)
 172     {
 173         self.lock_strength = min(self.lock_strength + incr, 1);
 174         if(self.lock_strength == 1)
 175             self.lock_time = time + _lock_time;
 176     }
 177     else
 178     {
 179         if(trace_ent)
 180             self.lock_strength = max(self.lock_strength - decr * 2, 0);
 181         else
 182             self.lock_strength = max(self.lock_strength - decr, 0);
 183
 184         if(self.lock_strength == 0)
 185             self.lock_target = world;
 186     }
 187 }
 188
 189 #define VEHICLE_UPDATE_PLAYER(fld,vhname) \
 190 self.owner.vehicle_##fld = (self.vehicle_##fld / autocvar_g_vehicle_##vhname##_##fld) * 100
 191
 192 #define vehicles_sweap_collision(orig,vel,dt,acm,mult) \
 193 traceline(orig, orig + vel * dt, MOVE_NORMAL, self); \
 194 if(trace_fraction != 1) \
 195     acm += normalize(self.origin - trace_endpos) * (vlen(vel) * mult)
 196
 197 // Hover movement support
 198 float  force_fromtag_power;
 199 float  force_fromtag_normpower;
 200 vector force_fromtag_origin;
 201 vector vehicles_force_fromtag_hover(string tag_name, float spring_length, float max_power)
 202 {
 203     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 204     v_forward  = normalize(v_forward) * -1;
 205     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 206
 207     force_fromtag_power = (1 - trace_fraction) * max_power;
 208     force_fromtag_normpower = force_fromtag_power / max_power;
 209
 210     return v_forward  * force_fromtag_power;
 211 }
 212
 213 // Experimental hovermode wich uses attraction/repulstion from surface insted of gravity/repulsion
 214 // Can possibly be use to move abt any surface (inclusing walls/celings)
 215 vector vehicles_force_fromtag_maglev(string tag_name, float spring_length, float max_power)
 216 {
 217
 218     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 219     v_forward  = normalize(v_forward) * -1;
 220     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 221
 222     // TODO - this may NOT be compatible with wall/celing movement, unhardcode 0.25 (engine count multiplier)
 223     if(trace_fraction == 1.0)
 224     {
 225         force_fromtag_normpower = -0.25;
 226         return '0 0 -200';
 227     }
 228
 229     force_fromtag_power = ((1 - trace_fraction) - trace_fraction) * max_power;
 230     force_fromtag_normpower = force_fromtag_power / max_power;
 231
 232     return v_forward  * force_fromtag_power;
 233 }
 234
 235 // Generic vehile projectile system
 236 void vehicles_projectile_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 237 {
 238     // Ignore damage from oterh projectiles from my owner (dont mess up volly's)
 239     if(inflictor.owner == self.owner)
 240         return;
 241
 242     self.health -= damage;
 243     self.velocity += force;
 244     if(self.health < 1)
 245     {
 246         self.takedamage = DAMAGE_NO;
 247         self.event_damage = SUB_Null;
 248         self.think = self.use;
 249         self.nextthink = time;
 250     }
 251
 252 }
 253
 254 void vehicles_projectile_explode()
 255 {
 256     if(self.owner && other != world)
 257     {
 258         if(other == self.owner.vehicle)
 259             return;
 260
 261         if(other == self.owner.vehicle.tur_head)
 262             return;
 263     }
 264
 265         PROJECTILE_TOUCH;
 266
 267         self.event_damage = SUB_Null;
 268     RadiusDamage (self, self.realowner, self.shot_dmg, 0, self.shot_radius, self, self.shot_force, self.totalfrags, other);
 269
 270     remove (self);
 271 }
 272
 273 entity vehicles_projectile(string _mzlfx, string _mzlsound,
 274                            vector _org, vector _vel,
 275                            float _dmg, float _radi, float _force,  float _size,
 276                            float _deahtype, float _projtype, float _health,
 277                            float _cull, float _clianim)
 278 {
 279     entity proj;
 280
 281     proj = spawn();
 282
 283     PROJECTILE_MAKETRIGGER(proj);
 284     setorigin(proj, _org);
 285
 286     proj.shot_dmg         = _dmg;
 287     proj.shot_radius      = _radi;
 288     proj.shot_force       = _force;
 289     proj.totalfrags       = _deahtype;
 290     proj.solid            = SOLID_BBOX;
 291     proj.movetype         = MOVETYPE_FLYMISSILE;
 292     proj.flags            = FL_PROJECTILE;
 293     proj.bot_dodge        = TRUE;
 294     proj.bot_dodgerating  = _dmg;
 295     proj.velocity         = _vel;
 296     proj.touch            = vehicles_projectile_explode;
 297     proj.use              = vehicles_projectile_explode;
 298     proj.owner            = self;
 299     proj.realowner        = self.owner;
 300     proj.think            = SUB_Remove;
 301     proj.nextthink        = time + 30;
 302
 303     if(_health)
 304     {
 305         proj.takedamage       = DAMAGE_AIM;
 306         proj.event_damage     = vehicles_projectile_damage;
 307         proj.health           = _health;
 308     }
 309     else
 310         proj.flags           = FL_PROJECTILE | FL_NOTARGET;
 311
 312     if(_mzlsound)
 313         sound (self, CHAN_WEAPON, _mzlsound, VOL_BASE, ATTN_NORM);
 314
 315     if(_mzlfx)
 316         pointparticles(particleeffectnum(_mzlfx), proj.origin, proj.velocity, 1);
 317
 318
 319     setsize (proj, '-1 -1 -1' * _size, '1 1 1' * _size);
 320
 321     CSQCProjectile(proj, _clianim, _projtype, _cull);
 322
 323     return proj;
 324 }
 325 // End generic vehile projectile system
 326
 327 /** vehicles_spawn
 328     Exetuted for all vehicles on (re)spawn.
 329     Sets defaults for newly spawned units.
 330 **/
 331 void vehicles_spawn()
 332 {
 333     dprint("Spawning vehicle: ", self.netname, "\n");
 334
 335     // De-own & reset
 336     self.vehicle_hudmodel.viewmodelforclient = self;
 337
 338     self.owner              = world;
 339     self.touch              = vehicles_touch;
 340     self.event_damage       = vehicles_damage;
 341     self.iscreature         = TRUE;
 342     self.movetype           = MOVETYPE_WALK;
 343     self.solid              = SOLID_SLIDEBOX;
 344     self.takedamage         = DAMAGE_AIM;
 345         self.deadflag           = DEAD_NO;
 346     self.bot_attack         = TRUE;
 347     self.flags              = FL_NOTARGET;
 348     self.avelocity          = '0 0 0';
 349     self.velocity           = '0 0 0';
 350
 351     // Reset locking
 352     self.lock_strength      = 0;
 353     self.lock_target        = world;
 354     self.misc_bulletcounter = 0;
 355
 356     // Return to spawn
 357     self.angles             = self.pos2;
 358     setorigin(self, self.pos1 + '0 0 128');
 359     // Show it
 360     pointparticles(particleeffectnum("teleport"), self.origin + '0 0 64', '0 0 0', 1);
 361
 362     vehicles_reset_colors();
 363     self.vehicle_spawn();
 364 }
 365
 366 // Better way of determening whats crushable needed! (fl_crushable?)
 367 float vehicles_crushable(entity e)
 368 {
 369     if(e.classname == "player")
 370         return TRUE;
 371
 372     if(e.classname == "monster_zombie")
 373         return TRUE;
 374
 375     return FALSE;
 376 }
 377
 378 void vehicles_touch()
 379 {
 380     // Vehicle currently in use
 381     if(self.owner)
 382     {
 383         // Colided with world?
 384         if(other == world)
 385         {
 386             // Apply velocity based self damage here
 387         }
 388         else
 389         {
 390             if(other.vehicle_flags & VHF_ISVEHICLE)
 391             {
 392                 //other.velocity += self.velocity * (self.mass / other.mass);
 393             }
 394             else if(vehicles_crushable(other))
 395             {
 396                 if(vlen(self.velocity) != 0)
 397                     Damage(other, self, self.owner, autocvar_g_vehicles_crush_dmg, DEATH_VHCRUSH, '0 0 0', normalize(other.origin - self.origin) * autocvar_g_vehicles_crush_force);
 398             }
 399         }
 400         return;
 401     }
 402
 403     if(other.classname != "player")
 404         return;
 405
 406     if(other.deadflag != DEAD_NO)
 407         return;
 408
 409     if(other.vehicle != world)
 410         return;
 411
 412     // Remove this when bots know how to use vehicles.
 413     if (clienttype(other) != CLIENTTYPE_REAL)
 414         return;
 415
 416     vehicles_enter();
 417 }
 418
 419 void vehicles_enter()
 420 {
 421    // Remove this when bots know how to use vehicles
 422     if (clienttype(other) != CLIENTTYPE_REAL)
 423         return;
 424
 425     if(self.phase > time)
 426         return;
 427
 428     if(teamplay)
 429     if(self.team)
 430     if(self.team != other.team)
 431         return;
 432
 433     self.vehicle_ammo1   = 0;
 434     self.vehicle_ammo2   = 0;
 435     self.vehicle_reload1 = 0;
 436     self.vehicle_reload2 = 0;
 437     self.vehicle_energy  = 0;
 438
 439     self.owner          = other;
 440     self.switchweapon   = other.switchweapon;
 441
 442     // .viewmodelforclient works better.
 443     //self.vehicle_hudmodel.drawonlytoclient = self.owner;
 444
 445     self.vehicle_hudmodel.viewmodelforclient = self.owner;
 446
 447     self.event_damage         = vehicles_damage;
 448     self.nextthink            = 0;
 449     self.owner.angles         = self.angles;
 450     self.owner.takedamage     = DAMAGE_NO;
 451     self.owner.solid          = SOLID_NOT;
 452     self.owner.movetype       = MOVETYPE_NOCLIP;
 453     self.owner.alpha          = -1;
 454     self.owner.vehicle        = self;
 455     self.owner.event_damage   = SUB_Null;
 456     self.owner.view_ofs       = '0 0 0';
 457     self.colormap             = self.owner.colormap;
 458     if(self.tur_head)
 459         self.tur_head.colormap    = self.owner.colormap;
 460
 461     self.owner.hud            = self.hud;
 462     self.owner.PlayerPhysplug = self.PlayerPhysplug;
 463
 464     self.owner.vehicle_ammo1    = self.vehicle_ammo1;
 465     self.owner.vehicle_ammo2    = self.vehicle_ammo2;
 466     self.owner.vehicle_reload1  = self.vehicle_reload1;
 467     self.owner.vehicle_reload2  = self.vehicle_reload2;
 468
 469     // Cant do this, hides attached objects too.
 470     //self.exteriormodeltoclient = self.owner;
 471     //self.tur_head.exteriormodeltoclient = self.owner;
 472
 473     other.flags &~= FL_ONGROUND;
 474     self.flags  &~= FL_ONGROUND;
 475
 476     self.team                 = self.owner.team;
 477     self.flags               -= FL_NOTARGET;
 478
 479     msg_entity = other;
 480     WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 481     WriteEntity(MSG_ONE, self.vehicle_viewport);
 482
 483     WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 484     if(self.tur_head)
 485     {
 486         WriteAngle(MSG_ONE, self.tur_head.angles_x + self.angles_x); // tilt
 487         WriteAngle(MSG_ONE, self.tur_head.angles_y + self.angles_y); // yaw
 488         WriteAngle(MSG_ONE, 0);                                      // roll
 489     }
 490     else
 491     {
 492         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 493         WriteAngle(MSG_ONE,  self.angles_x * -1); // tilt
 494         WriteAngle(MSG_ONE,  self.angles_y);      // yaw
 495         WriteAngle(MSG_ONE,  0);                  // roll
 496     }
 497
 498     vehicles_clearrturn();
 499
 500     CSQCVehicleSetup(self.owner, self.hud);
 501
 502     if(other.flagcarried)
 503     {
 504         if(!autocvar_g_vehicles_allow_flagcarry)
 505             DropFlag(other.flagcarried, world, world);
 506         else
 507         {
 508             other.flagcarried.scale = 1;
 509             setattachment(other.flagcarried, self, "");
 510             setorigin(other, '0 0 96');
 511         }
 512     }
 513
 514     self.vehicle_enter();
 515 }
 516
 517 /** vehicles_findgoodexit
 518     Locates a valid location for the player to exit the vehicle.
 519     Will first try prefer_spot, then up 100 random spots arround the vehicle
 520     wich are in direct line of sight and empty enougth to hold a players bbox
 521 **/
 522 vector vehicles_findgoodexit(vector prefer_spot)
 523 {
 524     //vector exitspot;
 525     float mysize;
 526
 527     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, prefer_spot, MOVE_NORMAL, self.owner);
 528     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 529         return prefer_spot;
 530
 531     mysize = vlen(self.maxs - self.mins);
 532     float i;
 533     vector v, v2;
 534     v2 = 0.5 * (self.absmin + self.absmax);
 535     for(i = 0; i < 100; ++i)
 536     {
 537         v = randomvec();
 538         v_z = 0;
 539         v = v2 + normalize(v) * mysize;
 540         tracebox(v2, PL_MIN, PL_MAX, v, MOVE_NORMAL, self.owner);
 541         if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 542             return v;
 543     }
 544
 545     /*
 546     exitspot = (self.origin + '0 0 48') + v_forward * mysize;
 547     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 548     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 549         return exitspot;
 550
 551     exitspot = (self.origin + '0 0 48') - v_forward * mysize;
 552     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 553     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 554         return exitspot;
 555
 556     exitspot = (self.origin + '0 0 48') + v_right * mysize;
 557     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 558     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 559         return exitspot;
 560
 561     exitspot = (self.origin + '0 0 48') - v_right * mysize;
 562     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 563     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 564         return exitspot;
 565     */
 566
 567     return self.origin;
 568 }
 569
 570 /** vehicles_exit
 571     Standarrd vehicle release fucntion.
 572     custom code goes in self.vehicle_exit
 573 **/
 574 void vehicles_exit(float eject)
 575 {
 576     entity oldself;
 577     if(self.flags & FL_CLIENT)
 578     {
 579         oldself = self;
 580         self = self.vehicle;
 581     }
 582
 583         self.flags |= FL_NOTARGET;
 584
 585     if (self.owner)
 586     {
 587         msg_entity = self.owner;
 588         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 589         WriteEntity( MSG_ONE, self.owner);
 590
 591         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 592         WriteAngle(MSG_ONE, 0);                 // pich
 593         WriteAngle(MSG_ONE, self.angles_y);     // yaw
 594         WriteAngle(MSG_ONE, 0);                 // roll
 595
 596         setsize(self.owner, PL_MIN,PL_MAX);
 597
 598         self.owner.takedamage     = DAMAGE_AIM;
 599         self.owner.solid          = SOLID_SLIDEBOX;
 600         self.owner.movetype       = MOVETYPE_WALK;
 601         self.owner.effects        &~= EF_NODRAW;
 602         self.owner.alpha          = 1;
 603         self.owner.PlayerPhysplug = SUB_Null;
 604         self.owner.vehicle        = world;
 605         self.owner.view_ofs       = PL_VIEW_OFS;
 606         self.owner.event_damage   = PlayerDamage;
 607         self.owner.hud            = HUD_NORMAL;
 608         self.owner.switchweapon   = self.switchweapon;
 609         //self.owner.BUTTON_USE     = 0;
 610     }
 611
 612     if(self.deadflag == DEAD_NO)
 613         self.avelocity          = '0 0 0';
 614
 615     self.vehicle_hudmodel.viewmodelforclient = self;
 616         self.tur_head.nodrawtoclient             = world;
 617     vehicles_setreturn();
 618
 619     self.phase = time + 1;
 620
 621     if(!teamplay)
 622         self.team = 0;
 623
 624     if(self.owner.flagcarried)
 625     {
 626         self.owner.flagcarried.scale = 0.6;
 627         setattachment(self.owner.flagcarried, self.owner, "");
 628         setorigin(self.owner.flagcarried, FLAG_CARRY_POS);
 629     }
 630
 631     sound (self, CHAN_TRIGGER, "misc/null.wav", 1, ATTN_NORM);
 632     self.vehicle_exit(eject);
 633     self.owner = world;
 634
 635     if(oldself)
 636         self = oldself;
 637 }
 638
 639
 640 void vehicles_regen(.float timer, .float regen_field, float field_max, float rpause, float regen, float delta_time)
 641 {
 642     if(self.regen_field < field_max)
 643     if(self.timer + rpause < time)
 644     {
 645         self.regen_field = min(self.regen_field + regen * delta_time, field_max);
 646
 647         if(self.owner)
 648             self.owner.regen_field = (self.regen_field / field_max) * 100;
 649     }
 650 }
 651
 652 void shieldhit_think()
 653 {
 654     self.alpha -= 0.1;
 655     if (self.alpha <= 0)
 656     {
 657         //setmodel(self, "");
 658         self.alpha = -1;
 659     }
 660     else
 661     {
 662         self.nextthink = time + 0.1;
 663     }
 664 }
 665
 666 void vehicles_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 667 {
 668     self.dmg_time = time;
 669
 670     if((self.vehicle_flags & VHF_HASSHIELD) && (self.vehicle_shield > 0))
 671     {
 672         if (wasfreed(self.vehicle_shieldent) || self.vehicle_shieldent == world)
 673         {
 674             self.vehicle_shieldent = spawn();
 675             self.vehicle_shieldent.effects = EF_LOWPRECISION;
 676
 677             setmodel(self.vehicle_shieldent, "models/vhshield.md3");
 678             setattachment(self.vehicle_shieldent, self, "");
 679             setorigin(self.vehicle_shieldent, real_origin(self) - self.origin);
 680             self.vehicle_shieldent.scale       = 256 / vlen(self.maxs - self.mins);
 681             self.vehicle_shieldent.think       = shieldhit_think;
 682         }
 683
 684
 685         self.vehicle_shieldent.colormod    = '1 1 1';
 686         self.vehicle_shieldent.alpha       = 0.45;
 687         self.vehicle_shieldent.angles      = vectoangles(normalize(hitloc - (self.origin + self.vehicle_shieldent.origin))) - self.angles;
 688         self.vehicle_shieldent.nextthink   = time;
 689
 690         self.vehicle_shield -= damage;
 691
 692         if(self.vehicle_shield < 0)
 693         {
 694             self.vehicle_shieldent.colormod = '2 0 0';
 695             self.vehicle_shield             = 0;
 696             self.vehicle_shieldent.alpha    = 0.75;
 697             self.vehicle_health            -= fabs(self.vehicle_shield);
 698         }
 699     }
 700     else
 701         self.vehicle_health -= damage;
 702
 703     self.velocity += force; // * (vlen(force) / self.mass);
 704
 705     if(self.vehicle_health <= 0)
 706     {
 707         if(self.owner)
 708             if(self.vehicle_flags & VHF_DEATHEJECT)
 709                 vehicles_exit(VHEF_EJECT);
 710             else
 711                 vehicles_exit(VHEF_RELESE);
 712
 713         self.vehicle_die();
 714         vehicles_setreturn();
 715     }
 716 }
 717
 718 void vehicles_clearrturn()
 719 {
 720     entity ret;
 721     // Remove "return helper", if any.
 722     ret = findchain(classname, "vehicle_return");
 723     while(ret)
 724     {
 725         if(ret.enemy == self)
 726         {
 727             ret.classname   = "";
 728             ret.think       = SUB_Remove;
 729             ret.nextthink   = time + 0.1;
 730
 731             if(ret.waypointsprite_attached)
 732                 WaypointSprite_Kill(ret.waypointsprite_attached);
 733
 734             return;
 735         }
 736         ret = ret.chain;
 737     }
 738 }
 739
 740 void vehicles_return()
 741 {
 742     pointparticles(particleeffectnum("teleport"), self.enemy.origin + '0 0 64', '0 0 0', 1);
 743
 744     self.enemy.think     = vehicles_spawn;
 745     self.enemy.nextthink = time;
 746
 747     if(self.waypointsprite_attached)
 748         WaypointSprite_Kill(self.waypointsprite_attached);
 749
 750     remove(self);
 751 }
 752
 753 void vehicles_showwp_goaway()
 754 {
 755     if(self.waypointsprite_attached)
 756         WaypointSprite_Kill(self.waypointsprite_attached);
 757
 758     remove(self);
 759
 760 }
 761
 762 void vehicles_showwp()
 763 {
 764     entity oldself;
 765
 766     if(self.cnt)
 767     {
 768         self.think      = vehicles_return;
 769         self.nextthink  = self.cnt;
 770     }
 771     else
 772     {
 773         self.think      = vehicles_return;
 774         self.nextthink  = time +1;
 775
 776         oldself = self;
 777         self = spawn();
 778         setmodel(self, "null");
 779         self.team = oldself.enemy.team;
 780         self.enemy = oldself.enemy;
 781         setorigin(self, oldself.enemy.pos1);
 782
 783         self.nextthink = time + 5;
 784         self.think = vehicles_showwp_goaway;
 785     }
 786
 787     WaypointSprite_Spawn("vehicle", 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE);
 788     if(self.waypointsprite_attached)
 789     {
 790
 791         if(teamplay && self.team)
 792             WaypointSprite_UpdateTeamRadar(self.waypointsprite_attached, RADARICON_POWERUP, TeamColor(self.team));
 793         else
 794             WaypointSprite_UpdateTeamRadar(self.waypointsprite_attached, RADARICON_POWERUP, '1 1 1');
 795
 796         WaypointSprite_UpdateRule(self.waypointsprite_attached, self.enemy.team, SPRITERULE_DEFAULT);
 797         if(oldself == world)
 798         {
 799             WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, self.nextthink);
 800             dprint("Oldies is goldies\n");
 801         }
 802
 803         WaypointSprite_Ping(self.waypointsprite_attached);
 804     }
 805
 806     if(oldself != world)
 807         self = oldself;
 808 }
 809
 810 void vehicles_setreturn()
 811 {
 812     entity ret;
 813
 814     vehicles_clearrturn();
 815
 816     ret = spawn();
 817     ret.classname   = "vehicle_return";
 818     ret.enemy       = self;
 819     ret.team        = self.team;
 820     ret.think       = vehicles_showwp;
 821
 822     if(self.deadflag != DEAD_NO)
 823     {
 824         ret.cnt         = time + self.vehicle_respawntime;
 825         ret.nextthink   = min(time + self.vehicle_respawntime, time + self.vehicle_respawntime - 5);
 826     }
 827     else
 828     {
 829         ret.nextthink   = min(time + self.vehicle_respawntime, time + self.vehicle_respawntime - 1);
 830     }
 831
 832
 833
 834     setmodel(ret, "null");
 835     setorigin(ret, self.pos1 + '0 0 96');
 836
 837 }
 838
 839 void vehicles_configcheck(string  configname, float check_cvar)
 840 {
 841     if(check_cvar == 0)
 842         localcmd(strcat("exec ", configname, "\n"));
 843 }
 844
 845 void vehicles_reset_colors()
 846 {
 847     entity e;
 848     float _effects, _colormap;
 849     vector _glowmod, _colormod;
 850
 851     if(autocvar_g_nodepthtestplayers)
 852         _effects = EF_NODEPTHTEST;
 853
 854     if(autocvar_g_fullbrightplayers)
 855         _effects |= EF_FULLBRIGHT;
 856
 857     if(self.team)
 858         _colormap = 1024 + (self.team - 1) * 17;
 859     else
 860         _colormap = 1024;
 861
 862     _glowmod  = '0 0 0';
 863     _colormod = '0 0 0';
 864
 865     // Find all ents attacked to main model and setup effects, colormod etc.
 866     e = findchainentity(tag_entity, self);
 867     while(e)
 868     {
 869         if(e != self.vehicle_shieldent)
 870         {
 871             e.effects   = _effects  | EF_LOWPRECISION;
 872             e.colormod  = _colormod;
 873             e.colormap  = _colormap;
 874             e.alpha     = 1;
 875         }
 876         e = e.chain;
 877     }
 878
 879     self.vehicle_hudmodel.effects  = self.effects  = _effects | EF_LOWPRECISION;
 880     self.vehicle_hudmodel.colormod = self.colormod = _colormod;
 881     self.vehicle_hudmodel.colormap = self.colormap = _colormap;
 882     self.vehicle_viewport.effects = (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NOGUNBOB | EF_NOSHADOW | EF_LOWPRECISION | EF_SELECTABLE | EF_TELEPORT_BIT);
 883
 884     self.alpha     = 1;
 885     self.avelocity = '0 0 0';
 886     self.velocity  = '0 0 0';
 887     self.effects   = _effects;
 888 }
 889
 890 float vehicle_initialize(string  net_name,
 891                          string  bodymodel,
 892                          string  topmodel,
 893                          string  hudmodel,
 894                          string  toptag,
 895                          string  hudtag,
 896                          string  viewtag,
 897                          float   vhud,
 898                          vector  min_s,
 899                          vector  max_s,
 900                          float   nodrop,
 901                          void()  spawnproc,
 902                          float   _respawntime,
 903                          float() physproc,
 904                          void()  enterproc,
 905                          void(float extflag) exitfunc,
 906                          void() dieproc,
 907                          void() thinkproc,
 908                          float  use_csqc)
 909 {
 910     addstat(STAT_HUD, AS_INT,  hud);
 911         addstat(STAT_VEHICLESTAT_HEALTH,  AS_INT, vehicle_health);
 912         addstat(STAT_VEHICLESTAT_SHIELD,  AS_INT, vehicle_shield);
 913         addstat(STAT_VEHICLESTAT_ENERGY,  AS_INT, vehicle_energy);
 914
 915         addstat(STAT_VEHICLESTAT_AMMO1,   AS_INT,   vehicle_ammo1);
 916         addstat(STAT_VEHICLESTAT_RELOAD1, AS_INT, vehicle_reload1);
 917
 918         addstat(STAT_VEHICLESTAT_AMMO2,   AS_INT,   vehicle_ammo2);
 919         addstat(STAT_VEHICLESTAT_RELOAD2, AS_INT, vehicle_reload2);
 920
 921     if(bodymodel == "")
 922         error("vehicles: missing bodymodel!");
 923
 924     if(hudmodel == "")
 925         error("vehicles: missing hudmodel!");
 926
 927     if(net_name == "")
 928         self.netname = self.classname;
 929     else
 930         self.netname = net_name;
 931
 932     if(self.team && !teamplay)
 933         self.team = 0;
 934
 935     self.vehicle_flags |= VHF_ISVEHICLE;
 936
 937     setmodel(self, bodymodel);
 938
 939     self.vehicle_viewport   = spawn();
 940     self.vehicle_hudmodel   = spawn();
 941     self.tur_head           = spawn();
 942     self.tur_head.owner     = self;
 943     self.takedamage         = DAMAGE_AIM;
 944     self.bot_attack         = TRUE;
 945     self.iscreature         = TRUE;
 946     self.hud                = vhud;
 947
 948     self.vehicle_die         = dieproc;
 949     self.vehicle_exit        = exitfunc;
 950     self.vehicle_enter       = enterproc;
 951     self.PlayerPhysplug      = physproc;
 952     self.event_damage        = vehicles_damage;
 953     self.touch               = vehicles_touch;
 954     self.think               = vehicles_spawn;
 955     self.nextthink           = time;
 956     self.vehicle_respawntime = _respawntime;
 957     self.vehicle_spawn       = spawnproc;
 958
 959     if(autocvar_g_nodepthtestplayers)
 960         self.effects = self.effects | EF_NODEPTHTEST;
 961
 962     if(autocvar_g_fullbrightplayers)
 963         self.effects = self.effects | EF_FULLBRIGHT;
 964
 965     setmodel(self.vehicle_hudmodel, hudmodel);
 966     setmodel(self.vehicle_viewport, "null");
 967
 968
 969     if(topmodel != "")
 970     {
 971         setmodel(self.tur_head, topmodel);
 972         setattachment(self.tur_head, self, toptag);
 973         setattachment(self.vehicle_hudmodel, self.tur_head, hudtag);
 974         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
 975     }
 976     else
 977     {
 978         setattachment(self.tur_head, self, "");
 979         setattachment(self.vehicle_hudmodel, self, hudtag);
 980         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
 981     }
 982
 983     setsize(self, min_s, max_s);
 984     if not (nodrop)
 985     {
 986         setorigin(self, self.origin);
 987         tracebox(self.origin + '0 0 100', min_s, max_s, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
 988         setorigin(self, trace_endpos);
 989     }
 990
 991     self.pos1 = self.origin;
 992     self.pos2 = self.angles;
 993
 994     return TRUE;
 995 }
 996
 997 void bugmenot()
 998 {
 999     self.vehicle_exit       = self.vehicle_exit;
1000     self.vehicle_enter      = self.vehicle_exit;
1001     self.vehicle_die        = self.vehicle_exit;
1002     self.vehicle_spawn      = self.vehicle_exit;
1003     self.AuxiliaryXhair     = self.AuxiliaryXhair;
1004 }