qcsrc/server/vehicles/spiderbot.qc

   1 const vector SPIDERBOT_MIN = '-75 -75 10';
   2 const vector SPIDERBOT_MAX  = '75 75 125';
   3
   4 #ifdef SVQC
   5 float autocvar_g_vehicle_spiderbot_respawntime;
   6
   7 float autocvar_g_vehicle_spiderbot_speed_stop;
   8 float autocvar_g_vehicle_spiderbot_speed_strafe;
   9 float autocvar_g_vehicle_spiderbot_speed_walk;
  10 float autocvar_g_vehicle_spiderbot_turnspeed;
  11 float autocvar_g_vehicle_spiderbot_movement_inertia;
  12
  13 float autocvar_g_vehicle_spiderbot_springlength;
  14 float autocvar_g_vehicle_spiderbot_springup;
  15 float autocvar_g_vehicle_spiderbot_springblend;
  16
  17 float autocvar_g_vehicle_spiderbot_head_pitchlimit_down;
  18 float autocvar_g_vehicle_spiderbot_head_pitchlimit_up;
  19 float autocvar_g_vehicle_spiderbot_head_pitchspeed;
  20 float autocvar_g_vehicle_spiderbot_head_turnlimit;
  21 float autocvar_g_vehicle_spiderbot_head_turnspeed;
  22
  23 //float autocvar_g_vehicle_spiderbot_energy;
  24 //float autocvar_g_vehicle_spiderbot_energy_regen;
  25 //float autocvar_g_vehicle_spiderbot_energy_regen_pause;
  26
  27 float autocvar_g_vehicle_spiderbot_health;
  28 float autocvar_g_vehicle_spiderbot_health_regen;
  29 float autocvar_g_vehicle_spiderbot_health_regen_pause;
  30
  31 float autocvar_g_vehicle_spiderbot_shield;
  32 float autocvar_g_vehicle_spiderbot_shield_regen;
  33 float autocvar_g_vehicle_spiderbot_shield_regen_pause;
  34
  35 float autocvar_g_vehicle_spiderbot_minigun_damage;
  36 float autocvar_g_vehicle_spiderbot_minigun_refire;
  37 float autocvar_g_vehicle_spiderbot_minigun_spread;
  38 float autocvar_g_vehicle_spiderbot_minigun_ammo_cost;
  39 float autocvar_g_vehicle_spiderbot_minigun_ammo_max;
  40 float autocvar_g_vehicle_spiderbot_minigun_ammo_regen;
  41 float autocvar_g_vehicle_spiderbot_minigun_ammo_regen_pause;
  42
  43 float autocvar_g_vehicle_spiderbot_rocket_damage;
  44 float autocvar_g_vehicle_spiderbot_rocket_force;
  45 float autocvar_g_vehicle_spiderbot_rocket_radius;
  46 float autocvar_g_vehicle_spiderbot_rocket_speed;
  47 float autocvar_g_vehicle_spiderbot_rocket_refire;
  48 float autocvar_g_vehicle_spiderbot_rocket_reload;
  49 float autocvar_g_vehicle_spiderbot_rocket_health;
  50 float autocvar_g_vehicle_spiderbot_rocket_noise;
  51 float autocvar_g_vehicle_spiderbot_rocket_turnrate;
  52 float autocvar_g_vehicle_spiderbot_rocket_lifetime;
  53
  54 void spiderbot_exit(float eject);
  55 void spiderbot_enter();
  56 void spiderbot_spawn();
  57
  58 void spiderbot_rocket_unguided()
  59 {
  60     vector newdir, olddir;
  61
  62     self.nextthink  = time;
  63
  64     olddir = normalize(self.velocity);
  65     newdir = normalize(self.pos1 - self.origin) + randomvec() * autocvar_g_vehicle_spiderbot_rocket_noise;
  66     self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_spiderbot_rocket_turnrate) * autocvar_g_vehicle_spiderbot_rocket_speed;
  67
  68     UpdateCSQCProjectile(self);
  69
  70     if (self.owner.deadflag != DEAD_NO || self.cnt < time || vlen(self.pos1 - self.origin) < 16)
  71         self.use();
  72 }
  73
  74 void spiderbot_rocket_guided()
  75 {
  76     vector newdir, olddir;
  77
  78     self.nextthink  = time;
  79
  80     if not (self.realowner.vehicle)
  81         self.think = spiderbot_rocket_unguided;
  82
  83     crosshair_trace(self.realowner);
  84     olddir = normalize(self.velocity);
  85     newdir = normalize(trace_endpos - self.origin) + randomvec() * autocvar_g_vehicle_spiderbot_rocket_noise;
  86     self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_spiderbot_rocket_turnrate) * autocvar_g_vehicle_spiderbot_rocket_speed;
  87
  88     UpdateCSQCProjectile(self);
  89
  90     if (self.owner.deadflag != DEAD_NO || self.cnt < time)
  91         self.use();
  92 }
  93
  94 void spiderbot_guide_release()
  95 {
  96     entity rkt;
  97     rkt = findchainentity(realowner, self.owner);
  98     if not (rkt)
  99         return;
 100
 101     crosshair_trace(self.owner);
 102     while(rkt)
 103     {
 104         if(rkt.think == spiderbot_rocket_guided)
 105         {
 106             rkt.pos1 = trace_endpos;
 107             rkt.think = spiderbot_rocket_unguided;
 108         }
 109         rkt = rkt.chain;
 110     }
 111 }
 112
 113 void spiderbot_rocket_do()
 114 {
 115
 116     vector v;
 117     entity rocket;
 118
 119     if (self.owner.BUTTON_ATCK2)
 120     {
 121         if (self.wait == 1)
 122         if (self.tur_head.frame == 9 || self.tur_head.frame == 1)
 123         {
 124             if(self.gun2.cnt < time && self.tur_head.frame == 9)
 125                 self.tur_head.frame = 1;
 126
 127             return;
 128         }
 129         self.wait = 1;
 130     }
 131     else
 132     {
 133         if(self.wait)
 134             spiderbot_guide_release();
 135
 136         self.wait = 0;
 137     }
 138
 139     if(self.gun2.cnt > time)
 140         return;
 141
 142     if (self.tur_head.frame >= 9)
 143         self.tur_head.frame = 1;
 144
 145     if not (self.owner.BUTTON_ATCK2)
 146         return;
 147
 148     crosshair_trace(self.owner);
 149
 150     v = gettaginfo(self.tur_head,gettagindex(self.tur_head,"tag_fire"));
 151     rocket = vehicles_projectile("spiderbot_rocket_launch", "weapons/rocket_fire.wav",
 152                            v, normalize(v_forward) * autocvar_g_vehicle_spiderbot_rocket_speed,
 153                            autocvar_g_vehicle_spiderbot_rocket_damage, autocvar_g_vehicle_spiderbot_rocket_radius, autocvar_g_vehicle_spiderbot_rocket_force, 1,
 154                            DEATH_SBROCKET, PROJECTILE_SPIDERROCKET, autocvar_g_vehicle_spiderbot_rocket_health, FALSE, FALSE);
 155
 156     rocket.cnt        = time + 15;
 157     rocket.classname  = "spiderbot_rocket";
 158     rocket.pos1       = trace_endpos;
 159     rocket.think      = spiderbot_rocket_guided;
 160     rocket.nextthink  = time;
 161     rocket.cnt        = time + autocvar_g_vehicle_spiderbot_rocket_lifetime;
 162
 163     self.tur_head.frame += 1;
 164     if (self.tur_head.frame == 9)
 165         self.attack_finished_single = autocvar_g_vehicle_spiderbot_rocket_reload;
 166     else
 167         self.attack_finished_single = autocvar_g_vehicle_spiderbot_rocket_refire;
 168
 169     self.gun2.cnt = time + self.attack_finished_single;
 170 }
 171
 172 float spiderbot_frame()
 173 {
 174     vector ad;
 175     entity player, spider;
 176     float ftmp;
 177
 178     player = self;
 179     spider = self.vehicle;
 180     self   = spider;
 181
 182     player.BUTTON_ZOOM      = 0;
 183     player.BUTTON_CROUCH    = 0;
 184     player.switchweapon     = 0;
 185
 186     crosshair_trace(player);
 187     //UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload2) + ('0 1 0' * (1 - player.vehicle_reload2)), 2);
 188
 189     player.v_angle_x *= -1;
 190     ad = player.v_angle - (spider.tur_head.angles + spider.angles);
 191     player.v_angle_x *= -1;
 192     if(ad_x > 180)  ad_x -= 360;
 193     if(ad_x < -180) ad_x += 360;
 194     if(ad_y > 180)  ad_y -= 360;
 195     if(ad_y < -180) ad_y += 360;
 196
 197     // Rotate head
 198     ftmp = autocvar_g_vehicle_spiderbot_head_turnspeed * sys_frametime;
 199     ad_y = bound(-ftmp, ad_y, ftmp);
 200     spider.tur_head.angles_y = bound(autocvar_g_vehicle_spiderbot_head_turnlimit * -1, spider.tur_head.angles_y + ad_y, autocvar_g_vehicle_spiderbot_head_turnlimit);
 201
 202     // Pitch head
 203 #if 0 // Enable to pich by cross-trace (more precise in chase, but less predictable)
 204     ad = vectoangles(normalize(trace_endpos - gettaginfo(spider.tur_head,gettagindex(spider.tur_head,"tag_hud")))) - (spider.tur_head.angles + spider.angles);
 205     if(ad_x > 180) ad_x -= 360;
 206     if(ad_x < -180) ad_x += 360;
 207 #endif
 208     ftmp = autocvar_g_vehicle_spiderbot_head_pitchspeed * sys_frametime;
 209     ad_x = bound(ftmp * -1, ad_x, ftmp);
 210     spider.tur_head.angles_x = bound(autocvar_g_vehicle_spiderbot_head_pitchlimit_down, spider.tur_head.angles_x + ad_x, autocvar_g_vehicle_spiderbot_head_pitchlimit_up);
 211
 212     // Turn Body
 213     ftmp = autocvar_g_vehicle_spiderbot_turnspeed * sys_frametime;
 214     ftmp = bound(-ftmp, spider.tur_head.angles_y, ftmp);
 215
 216     makevectors(spider.angles + '-2 0 0' * spider.angles_x);
 217
 218 /*
 219     vector ofs;
 220     ofs = self.origin + v_up * 128;
 221     te_lightning1(world, ofs, ofs + v_up * 32);
 222     te_lightning1(world, ofs, ofs + v_right * 128);
 223     te_lightning1(world, ofs, ofs + v_forward * 256);
 224 */
 225
 226     movelib_groundalign4point(autocvar_g_vehicle_spiderbot_springlength, autocvar_g_vehicle_spiderbot_springup, autocvar_g_vehicle_spiderbot_springblend);
 227
 228     if(spider.flags & FL_ONGROUND)
 229     {
 230         if(spider.frame == 4 && self.tur_head.wait != 0)
 231         {
 232             sound (self, CHAN_TRIGGER, "vehicles/spiderbot_land.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 233             spider.frame = 5;
 234         }
 235
 236         if(player.BUTTON_JUMP && self.tur_head.wait < time)
 237         {
 238             sound (self, CHAN_TRIGGER, "vehicles/spiderbot_jump.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 239             //dprint("spiderbot_jump:", ftos(soundlength("vehicles/spiderbot_jump.wav")), "\n");
 240             self.delay = 0;
 241
 242             self.tur_head.wait = time + 2;
 243             player.BUTTON_JUMP = 0;
 244             spider.velocity   = v_forward * 700 + v_up * 600;
 245             spider.frame = 4;
 246         }
 247         else
 248         {
 249             if(vlen(player.movement) == 0)
 250             {
 251                 if(self.sound_nexttime < time || self.delay != 3)
 252                 {
 253                     self.delay = 3;
 254                     self.sound_nexttime = time + 6.486500; //soundlength("vehicles/spiderbot_idle.wav");
 255                     //dprint("spiderbot_idle:", ftos(soundlength("vehicles/spiderbot_idle.wav")), "\n");
 256                     sound (self, CHAN_TRIGGER, "vehicles/spiderbot_idle.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 257                 }
 258                 movelib_beak_simple(autocvar_g_vehicle_spiderbot_speed_stop);
 259                 spider.frame = 5;
 260             }
 261             else
 262             {
 263                 spider.angles_y = anglemods(spider.angles_y + ftmp);
 264                 spider.tur_head.angles_y -= ftmp;
 265
 266                 if(player.movement_x != 0)
 267                 {
 268                     if(player.movement_x > 0)
 269                     {
 270                         player.movement_x = 1;
 271                         spider.frame = 0;
 272                     }
 273                     else if(player.movement_x < 0)
 274                     {
 275                         player.movement_x = -1;
 276                         spider.frame = 1;
 277                     }
 278                     player.movement_y = 0;
 279                     movelib_move_simple(normalize(v_forward * player.movement_x),autocvar_g_vehicle_spiderbot_speed_walk,autocvar_g_vehicle_spiderbot_movement_inertia);
 280
 281                     if(self.sound_nexttime < time || self.delay != 1)
 282                     {
 283                         self.delay = 1;
 284                         self.sound_nexttime = time + 6.486500; //soundlength("vehicles/spiderbot_walk.wav");
 285                         sound (self, CHAN_TRIGGER, "vehicles/spiderbot_walk.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 286                         //dprint("spiderbot_walk:", ftos(soundlength("vehicles/spiderbot_walk.wav")), "\n");
 287                     }
 288                 }
 289                 else if(player.movement_y != 0)
 290                 {
 291                     if(player.movement_y < 0)
 292                     {
 293                         player.movement_y = -1;
 294                         spider.frame = 2;
 295                     }
 296                     else if(player.movement_y > 0)
 297                     {
 298                         player.movement_y = 1;
 299                         spider.frame = 3;
 300                     }
 301                     movelib_move_simple(normalize(v_right * player.movement_y),autocvar_g_vehicle_spiderbot_speed_strafe,autocvar_g_vehicle_spiderbot_movement_inertia);
 302                     if(self.sound_nexttime < time || self.delay != 2)
 303                     {
 304                         self.delay = 2;
 305                         self.sound_nexttime = time + 6.486500; //soundlength("vehicles/spiderbot_strafe.wav");
 306                         sound (self, CHAN_TRIGGER, "vehicles/spiderbot_strafe.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 307                         //dprint("spiderbot_strafe:", ftos(soundlength("vehicles/spiderbot_strafe.wav")), "\n");
 308                     }
 309                 }
 310             }
 311         }
 312     }
 313
 314     self.angles_x = bound(-45, self.angles_x, 45);
 315     self.angles_z = bound(-45, self.angles_z, 45);
 316
 317     if(player.BUTTON_ATCK)
 318     {
 319         spider.cnt = time;
 320         if(spider.vehicle_ammo1 >= autocvar_g_vehicle_spiderbot_minigun_ammo_cost && spider.tur_head.attack_finished_single <= time)
 321         {
 322             entity gun;
 323             vector v;
 324             spider.misc_bulletcounter += 1;
 325
 326             self = player;
 327
 328             mod(spider.misc_bulletcounter, 2) ? gun = spider.gun1 : gun = spider.gun2;
 329             v = gettaginfo(gun, gettagindex(gun, "barrels"));
 330             v_forward = normalize(v_forward);
 331             v += v_forward * 50;
 332
 333             fireBullet (v, v_forward, autocvar_g_vehicle_spiderbot_minigun_spread, autocvar_g_vehicle_spiderbot_minigun_damage,
 334                 autocvar_g_vehicle_spiderbot_minigun_spread, DEATH_SBMINIGUN, 0);
 335
 336             sound (gun, CHAN_WEAPON, "weapons/uzi_fire.wav", VOL_BASE, ATTN_NORM);
 337             trailparticles(self, particleeffectnum("spiderbot_minigun_trail"), v, trace_endpos);
 338             pointparticles(particleeffectnum("spiderbot_minigun_muzzleflash"), v, v_forward * 2500, 1);
 339
 340             self = spider;
 341
 342             spider.vehicle_ammo1 -= autocvar_g_vehicle_spiderbot_minigun_ammo_cost;
 343             spider.tur_head.attack_finished_single = time + autocvar_g_vehicle_spiderbot_minigun_refire;
 344             player.vehicle_ammo1 = (spider.vehicle_ammo1 / autocvar_g_vehicle_spiderbot_minigun_ammo_max) * 100;
 345         }
 346     }
 347     else
 348         vehicles_regen(cnt, vehicle_ammo1, autocvar_g_vehicle_spiderbot_minigun_ammo_max,
 349                                            autocvar_g_vehicle_spiderbot_minigun_ammo_regen_pause,
 350                                            autocvar_g_vehicle_spiderbot_minigun_ammo_regen, frametime);
 351
 352     spiderbot_rocket_do();
 353
 354     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 355         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_spiderbot_shield, autocvar_g_vehicle_spiderbot_shield_regen_pause, autocvar_g_vehicle_spiderbot_shield_regen, frametime);
 356
 357     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 358         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_spiderbot_health, autocvar_g_vehicle_spiderbot_health_regen_pause, autocvar_g_vehicle_spiderbot_health_regen, frametime);
 359
 360     player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 361     player.vehicle_ammo2 = spider.tur_head.frame;
 362
 363     if(spider.gun2.cnt <= time)
 364         player.vehicle_reload2 = 100;
 365     else
 366         player.vehicle_reload2 = 100 - ((spider.gun2.cnt - time) / spider.attack_finished_single) * 100;
 367
 368     setorigin(player, spider.origin + '0 0 1' * SPIDERBOT_MAX_z);
 369     player.velocity = spider.velocity;
 370
 371     VEHICLE_UPDATE_PLAYER(health, spiderbot);
 372
 373     if(self.vehicle_flags & VHF_HASSHIELD)
 374         VEHICLE_UPDATE_PLAYER(shield, spiderbot);
 375
 376 #if 1 // 0 to enable per-gun impact aux crosshairs
 377     // Avarage gun impact point's -> aux cross
 378     vector vf;
 379     ad = gettaginfo(spider.gun1, gettagindex(spider.gun1, "barrels"));
 380     vf = v_forward;
 381     ad += gettaginfo(spider.gun2, gettagindex(spider.gun2, "barrels"));
 382     vf += v_forward;
 383     ad = ad * 0.5;
 384     v_forward = vf * 0.5;
 385     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, spider);
 386     UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload1) + ('0 1 0' * (1 - player.vehicle_reload1)), 0);
 387
 388 #else
 389     ad = gettaginfo(spider.gun1, gettagindex(spider.gun1, "barrels"));
 390     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, spider);
 391     UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload1) + ('0 1 0' * (1 - player.vehicle_reload1)), 0);
 392
 393     ad = gettaginfo(spider.gun2, gettagindex(spider.gun2, "barrels"));
 394     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, spider);
 395     UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload1) + ('0 1 0' * (1 - player.vehicle_reload1)), 1);
 396 #endif
 397
 398     self = player;
 399     return 1;
 400 }
 401
 402 void spiderbot_think()
 403 {
 404     if(self.flags & FL_ONGROUND)
 405         movelib_beak_simple(autocvar_g_vehicle_spiderbot_speed_stop);
 406
 407     self.nextthink = time;
 408 }
 409
 410 void spiderbot_enter()
 411 {
 412     self.movetype   = MOVETYPE_WALK;
 413
 414     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_spiderbot_health);
 415     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_spiderbot_shield);
 416
 417     if(self.owner.flagcarried)
 418     {
 419         setattachment(self.owner.flagcarried, self.tur_head, "");
 420         setorigin(self.owner.flagcarried, '-20 0 120');
 421     }
 422 }
 423
 424 void spiderbot_exit(float eject)
 425 {
 426     entity e;
 427     vector spot;
 428
 429     e = findchain(classname,"spiderbot_rocket");
 430     while(e)
 431     {
 432         if(e.owner == self.owner)
 433         {
 434             e.realowner = self.owner;
 435             e.owner = world;
 436         }
 437         e = e.chain;
 438     }
 439
 440     self.velocity   = '0 0 0';
 441     self.think      = spiderbot_think;
 442     self.nextthink  = time;
 443     self.frame      = 5;
 444     self.movetype   = MOVETYPE_WALK;
 445
 446     if not (self.owner)
 447         return;
 448
 449         makevectors(self.angles);
 450         if(eject)
 451         {
 452             spot = self.origin + v_forward * 100 + '0 0 64';
 453             spot = vehicles_findgoodexit(spot);
 454             setorigin(self.owner , spot);
 455             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 456         }
 457         else
 458         {
 459             spot = self.origin - v_forward * 200 + '0 0 64';
 460             spot = vehicles_findgoodexit(spot);
 461             setorigin(self.owner , spot);
 462         }
 463
 464     self.owner = world;
 465 }
 466
 467 void spiderbot_spawn()
 468 {
 469     self.frame              = 5;
 470     self.tur_head.frame     = 1;
 471     self.think              = spiderbot_think;
 472     self.nextthink          = time;
 473     self.vehicle_health     = autocvar_g_vehicle_spiderbot_health;
 474     self.vehicle_shield     = autocvar_g_vehicle_spiderbot_shield;
 475     self.movetype           = MOVETYPE_WALK;
 476     self.solid              = SOLID_SLIDEBOX;
 477     self.alpha              = self.tur_head.alpha = self.gun1.alpha = self.gun2.alpha = 1;
 478     self.tur_head.angles    = '0 0 0';
 479
 480     setorigin(self, self.pos1 + '0 0 128');
 481     self.angles = self.pos2;
 482 }
 483
 484 void spiderbot_headfade()
 485 {
 486         self.think = spiderbot_headfade;
 487         self.nextthink = self.fade_time;
 488         self.alpha = 1 - (time - self.fade_time) * self.fade_rate;
 489
 490     if(self.cnt < time || self.alpha < 0.1)
 491     {
 492         if(self.alpha > 0.1)
 493         {
 494             sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 495             pointparticles(particleeffectnum("explosion_big"), self.origin + '0 0 100', '0 0 0', 1);
 496         }
 497         remove(self);
 498     }
 499 }
 500
 501 void spiderbot_blowup()
 502 {
 503     if(self.cnt > time)
 504     {
 505         if(random() < 0.1)
 506         {
 507             sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 508             pointparticles(particleeffectnum("explosion_small"), randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
 509         }
 510         self.nextthink = time + 0.1;
 511         return;
 512     }
 513
 514     entity h, g1, g2, b;
 515     b = spawn();
 516     h = spawn();
 517     g1 = spawn();
 518     g2 = spawn();
 519
 520     setmodel(b,  "models/vehicles/spiderbot.dpm");
 521     setmodel(h,  "models/vehicles/spiderbot_top.dpm");
 522     setmodel(g1, "models/vehicles/spiderbot_barrels.dpm");
 523     setmodel(g2, "models/vehicles/spiderbot_barrels.dpm");
 524
 525     setorigin(b, self.origin);
 526     b.frame         = 11;
 527     b.angles        = self.angles;
 528     setsize(b, self.mins, self.maxs);
 529
 530     setorigin(h, gettaginfo(self, gettagindex(self, "tag_head")));
 531     h.movetype      = MOVETYPE_BOUNCE;
 532     h.solid         = SOLID_BBOX;
 533     h.velocity      = v_up * (500 + random() * 500) + randomvec() * 128;
 534     h.modelflags    = MF_ROCKET;
 535     h.effects       = EF_FLAME | EF_LOWPRECISION;
 536     h.avelocity     = randomvec() * 360;
 537
 538     h.alpha         = 1;
 539     h.cnt           = time + (3.5 * random());
 540     h.fade_rate     = 1 / min(autocvar_g_vehicle_spiderbot_respawntime, 10);
 541     h.fade_time     = time;
 542     h.think         = spiderbot_headfade;
 543     h.nextthink     = time;
 544
 545     setorigin(g1, gettaginfo(self.tur_head, gettagindex(self.tur_head, "tag_hardpoint01")));
 546     g1.movetype     = MOVETYPE_TOSS;
 547     g1.solid        = SOLID_CORPSE;
 548     g1.velocity     = v_forward * 700 + (randomvec() * 32);
 549     g1.avelocity    = randomvec() * 180;
 550
 551     setorigin(g2, gettaginfo(self.tur_head, gettagindex(self.tur_head, "tag_hardpoint02")));
 552     g2.movetype     = MOVETYPE_TOSS;
 553     g2.solid        = SOLID_CORPSE;
 554     g2.velocity     = v_forward * 700 + (randomvec() * 32);
 555     g2.avelocity    = randomvec() * 180;
 556
 557     h.colormod = b.colormod = g1.colormod = g2.colormod = '-2 -2 -2';
 558
 559     SUB_SetFade(b,  time + 5, min(autocvar_g_vehicle_spiderbot_respawntime, 1));
 560     //SUB_SetFade(h,  time, min(autocvar_g_vehicle_spiderbot_respawntime, 10));
 561     SUB_SetFade(g1, time, min(autocvar_g_vehicle_spiderbot_respawntime, 10));
 562     SUB_SetFade(g2, time, min(autocvar_g_vehicle_spiderbot_respawntime, 10));
 563
 564     RadiusDamage (self, self, 250, 15, 250, world, 250, DEATH_SBBLOWUP, world);
 565
 566     self.alpha = self.tur_head.alpha = self.gun1.alpha = self.gun2.alpha = -1;
 567     self.movetype   = MOVETYPE_NONE;
 568     self.deadflag   = DEAD_DEAD;
 569     self.solid      = SOLID_NOT;
 570     self.tur_head.effects  &~=  EF_FLAME;
 571         self.vehicle_hudmodel.viewmodelforclient = self;
 572 }
 573
 574 void spiderbot_die()
 575 {
 576     sound (self, CHAN_TRIGGER, "vehicles/spiderbot_die.wav", VOL_BASE, ATTN_NORM);
 577     pointparticles(particleeffectnum("explosion_medium"), self.origin + '0 0 100', '0 0 0', 1);
 578
 579     self.health             = 0;
 580     self.event_damage       = SUB_Null;
 581     self.takedamage         = DAMAGE_NO;
 582     self.touch              = SUB_Null;
 583     self.cnt                = 3.4 + time + random() * 2;
 584     self.think              = spiderbot_blowup;
 585     self.nextthink          = time;
 586     self.deadflag           = DEAD_DYING;
 587         self.frame              = 5;
 588         self.tur_head.effects  |= EF_FLAME;
 589         self.colormod           = self.tur_head.colormod = '-1 -1 -1';
 590         self.frame              = 10;
 591         self.movetype           = MOVETYPE_TOSS;
 592 }
 593
 594 void vewhicle_spiderbot_dinit()
 595 {
 596     if not (vehicle_initialize(
 597              "Spiderbot",
 598              "models/vehicles/spiderbot.dpm",
 599              "models/vehicles/spiderbot_top.dpm",
 600              "models/vehicles/spiderbot_cockpit.dpm",
 601              "tag_head", "tag_hud", "",
 602              HUD_SPIDERBOT,
 603              SPIDERBOT_MIN, SPIDERBOT_MAX,
 604              FALSE,
 605              spiderbot_spawn, autocvar_g_vehicle_spiderbot_respawntime,
 606              spiderbot_frame,
 607              spiderbot_enter, spiderbot_exit,
 608              spiderbot_die,   spiderbot_think,
 609              FALSE))
 610     {
 611         remove(self);
 612         return;
 613     }
 614
 615
 616     self.gun1               = spawn();
 617     self.gun2               = spawn();
 618
 619     setmodel(self.gun1, "models/vehicles/spiderbot_barrels.dpm");
 620     setmodel(self.gun2, "models/vehicles/spiderbot_barrels.dpm");
 621
 622     setattachment(self.gun1, self.tur_head, "tag_hardpoint01");
 623     setattachment(self.gun2, self.tur_head, "tag_hardpoint02");
 624
 625     self.gravity            = 2;
 626     self.mass               = 5000;
 627 }
 628
 629 void spawnfunc_vehicle_spiderbot()
 630 {
 631     precache_model ( "models/vhshield.md3");
 632     precache_model ( "models/vehicles/spiderbot.dpm");
 633     precache_model ( "models/vehicles/spiderbot_top.dpm");
 634     precache_model ( "models/vehicles/spiderbot_barrels.dpm");
 635     precache_model ( "models/vehicles/spiderbot_cockpit.dpm");
 636     precache_model ( "models/uziflash.md3");
 637
 638     precache_sound ( "weapons/rocket_impact.wav" );
 639     precache_sound ( "weapons/uzi_fire.wav" );
 640     precache_sound ( "weapons/rocket_impact.wav");
 641
 642     precache_sound ( "vehicles/spiderbot_die.wav");
 643     precache_sound ( "vehicles/spiderbot_idle.wav");
 644     precache_sound ( "vehicles/spiderbot_jump.wav");
 645     precache_sound ( "vehicles/spiderbot_strafe.wav");
 646     precache_sound ( "vehicles/spiderbot_walk.wav");
 647     precache_sound ( "vehicles/spiderbot_land.wav");
 648
 649     vehicles_configcheck("vehicle_spiderbot.cfg", autocvar_g_vehicle_spiderbot_health);
 650     if(autocvar_g_vehicle_spiderbot_shield)
 651         self.vehicle_flags |= VHF_HASSHIELD;
 652
 653     if(autocvar_g_vehicle_spiderbot_shield_regen)
 654         self.vehicle_flags |= VHF_SHIELDREGEN;
 655
 656     if(autocvar_g_vehicle_spiderbot_health_regen)
 657         self.vehicle_flags |= VHF_HEALTHREGEN;
 658
 659     self.think = vewhicle_spiderbot_dinit;
 660     self.nextthink = time + (autocvar_g_vehicles_delayspawn ? autocvar_g_vehicle_spiderbot_respawntime + (random() * autocvar_g_vehicles_delayspawn_jitter) : 0.5);
 661 }
 662 #endif // SVQC