qcsrc/server/vehicles/raptor.qc

   1 #ifdef SVQC
   2 #define RAPTOR_MIN '-80 -80 0'
   3 #define RAPTOR_MAX '80 80 70'
   4 //#define RAPTOR_ENGINE "sound/vehicles/raptor.wav"
   5 float autocvar_g_vehicle_raptor_respawntime;
   6
   7 float autocvar_g_vehicle_raptor_movestyle;
   8 float autocvar_g_vehicle_raptor_turnspeed;
   9 float autocvar_g_vehicle_raptor_pitchspeed;
  10 float autocvar_g_vehicle_raptor_pitchlimit;
  11
  12 float autocvar_g_vehicle_raptor_speed_forward;
  13 float autocvar_g_vehicle_raptor_speed_strafe;
  14 float autocvar_g_vehicle_raptor_speed_up;
  15 float autocvar_g_vehicle_raptor_speed_down;
  16 float autocvar_g_vehicle_raptor_friction;
  17
  18 float autocvar_g_vehicle_raptor_bomblets;
  19 float autocvar_g_vehicle_raptor_bomblet_alt;
  20 float autocvar_g_vehicle_raptor_bomblet_time;
  21 float autocvar_g_vehicle_raptor_bomblet_damage;
  22 float autocvar_g_vehicle_raptor_bomblet_spread;
  23 float autocvar_g_vehicle_raptor_bomblet_edgedamage;
  24 float autocvar_g_vehicle_raptor_bomblet_radius;
  25 float autocvar_g_vehicle_raptor_bomblet_force;
  26 float autocvar_g_vehicle_raptor_bomblet_explode_delay;
  27 float autocvar_g_vehicle_raptor_bombs_refire;
  28
  29 float autocvar_g_vehicle_raptor_cannon_turnspeed;
  30 float autocvar_g_vehicle_raptor_cannon_turnlimit;
  31 float autocvar_g_vehicle_raptor_cannon_pitchlimit_up;
  32 float autocvar_g_vehicle_raptor_cannon_pitchlimit_down;
  33
  34 float autocvar_g_vehicle_raptor_cannon_locktarget;
  35 float autocvar_g_vehicle_raptor_cannon_locking_time;
  36 float autocvar_g_vehicle_raptor_cannon_locking_releasetime;
  37 float autocvar_g_vehicle_raptor_cannon_locked_time;
  38 float autocvar_g_vehicle_raptor_cannon_predicttarget;
  39
  40 float autocvar_g_vehicle_raptor_cannon_cost;
  41 float autocvar_g_vehicle_raptor_cannon_damage;
  42 float autocvar_g_vehicle_raptor_cannon_radius;
  43 float autocvar_g_vehicle_raptor_cannon_refire;
  44 float autocvar_g_vehicle_raptor_cannon_speed;
  45 float autocvar_g_vehicle_raptor_cannon_spread;
  46 float autocvar_g_vehicle_raptor_cannon_force;
  47
  48 float autocvar_g_vehicle_raptor_energy;
  49 float autocvar_g_vehicle_raptor_energy_regen;
  50 float autocvar_g_vehicle_raptor_energy_regen_pause;
  51
  52 float autocvar_g_vehicle_raptor_health;
  53 float autocvar_g_vehicle_raptor_health_regen;
  54 float autocvar_g_vehicle_raptor_health_regen_pause;
  55
  56 float autocvar_g_vehicle_raptor_shield;
  57 float autocvar_g_vehicle_raptor_shield_regen;
  58 float autocvar_g_vehicle_raptor_shield_regen_pause;
  59
  60 void raptor_spawn();
  61 float raptor_frame();
  62 float raptor_takeoff();
  63
  64 .entity bomb1;
  65 .entity bomb2;
  66
  67 float raptor_altitude(float amax)
  68 {
  69         tracebox(self.origin, self.mins, self.maxs, self.origin - ('0 0 1' * amax), TRUE, self);
  70     return vlen(self.origin - trace_endpos);
  71 }
  72
  73
  74 void raptor_bomblet_boom()
  75 {
  76     RadiusDamage (self, self.realowner, autocvar_g_vehicle_raptor_bomblet_damage,
  77                                     autocvar_g_vehicle_raptor_bomblet_edgedamage,
  78                                     autocvar_g_vehicle_raptor_bomblet_radius, world,
  79                                     autocvar_g_vehicle_raptor_bomblet_force, DEATH_RAPTOR_BOMB, world);
  80     remove(self);
  81 }
  82
  83 void raptor_bomblet_touch()
  84 {
  85     if(other == self.owner)
  86         return;
  87
  88     PROJECTILE_TOUCH;
  89     self.think = raptor_bomblet_boom;
  90     self.nextthink = time + random() * autocvar_g_vehicle_raptor_bomblet_explode_delay;
  91 }
  92
  93 void raptor_bomb_burst()
  94 {
  95     if(self.cnt > time)
  96     if(autocvar_g_vehicle_raptor_bomblet_alt)
  97     {
  98         self.nextthink = time;
  99         traceline(self.origin, self.origin + (normalize(self.velocity) * autocvar_g_vehicle_raptor_bomblet_alt), MOVE_NORMAL, self);
 100         if((trace_fraction == 1.0) || (vlen(self.origin - self.owner.origin) < autocvar_g_vehicle_raptor_bomblet_radius))
 101         {
 102             UpdateCSQCProjectile(self);
 103             return;
 104         }
 105     }
 106
 107     entity bomblet;
 108     float i;
 109
 110     Damage_DamageInfo(self.origin, 0, 0, 0, '0 0 0', DEATH_RAPTOR_BOMB_SPLIT, self);
 111
 112     for(i = 0; i < autocvar_g_vehicle_raptor_bomblets; ++i)
 113     {
 114         bomblet = spawn();
 115         setorigin(bomblet, self.origin);
 116
 117         bomblet.movetype    = MOVETYPE_TOSS;
 118         bomblet.touch       = raptor_bomblet_touch;
 119         bomblet.think       = raptor_bomblet_boom;
 120         bomblet.nextthink   = time + 5;
 121         bomblet.owner       = self.owner;
 122         bomblet.realowner   = self.realowner;
 123         bomblet.velocity    = normalize(normalize(self.velocity) + (randomvec() * autocvar_g_vehicle_raptor_bomblet_spread)) * vlen(self.velocity);
 124
 125         PROJECTILE_MAKETRIGGER(bomblet);
 126         CSQCProjectile(bomblet, TRUE, PROJECTILE_RAPTORBOMBLET, TRUE);
 127     }
 128
 129     remove(self);
 130 }
 131
 132 void raptor_bomb_touch()
 133 {
 134     raptor_bomb_burst();
 135 }
 136
 137 void raptor_bombdrop()
 138 {
 139     entity bomb_1, bomb_2;
 140
 141     bomb_1 = spawn();
 142     bomb_2 = spawn();
 143
 144     setorigin(bomb_1, gettaginfo(self, gettagindex(self, "bombmount_left")));
 145     setorigin(bomb_2, gettaginfo(self, gettagindex(self, "bombmount_right")));
 146
 147     bomb_1.movetype     = bomb_2.movetype   = MOVETYPE_BOUNCE;
 148     bomb_1.velocity     = bomb_2.velocity   = self.velocity;
 149     bomb_1.touch        = bomb_2.touch      = raptor_bomb_touch;
 150     bomb_1.think        = bomb_2.think      = raptor_bomb_burst;
 151     bomb_1.cnt          = bomb_2.cnt        = time + 10;
 152
 153     if(autocvar_g_vehicle_raptor_bomblet_alt)
 154         bomb_1.nextthink = bomb_2.nextthink  = time;
 155     else
 156         bomb_1.nextthink = bomb_2.nextthink  = time + autocvar_g_vehicle_raptor_bomblet_time;
 157
 158     bomb_1.owner     = bomb_2.owner      = self;
 159     bomb_1.realowner = bomb_2.realowner  = self.owner;
 160     bomb_1.solid     = bomb_2.solid      = SOLID_BBOX;
 161     bomb_1.gravity   = bomb_2.gravity    = 1;
 162
 163     PROJECTILE_MAKETRIGGER(bomb_1);
 164     PROJECTILE_MAKETRIGGER(bomb_2);
 165
 166     CSQCProjectile(bomb_1, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 167     CSQCProjectile(bomb_2, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 168
 169 }
 170
 171
 172 void raptor_fire_cannon(entity gun, string tagname)
 173 {
 174     entity bolt;
 175     vector b_org;
 176     b_org = gettaginfo(gun, gettagindex(gun, tagname));
 177     bolt = vehicles_projectile("raptor_cannon_muzzleflash", "weapons/lasergun_fire.wav",
 178                            b_org, normalize(v_forward + randomvec() * autocvar_g_vehicle_raptor_cannon_spread) * autocvar_g_vehicle_raptor_cannon_speed,
 179                            autocvar_g_vehicle_raptor_cannon_damage, autocvar_g_vehicle_raptor_cannon_radius, autocvar_g_vehicle_raptor_cannon_force,  0,
 180                            DEATH_RAPTOR_CANNON, PROJECTILE_RAPTORCANNON, 0, TRUE, TRUE);
 181 }
 182
 183 void raptor_think()
 184 {
 185 }
 186
 187 void raptor_enter()
 188 {
 189     self.owner.PlayerPhysplug = raptor_takeoff;
 190     self.movetype       = MOVETYPE_BOUNCEMISSILE;
 191     self.solid          = SOLID_SLIDEBOX;
 192     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_raptor_health);
 193     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_raptor_shield);
 194     self.velocity_z = 1; // Nudge upwards to takeoff sequense can work.
 195     self.tur_head.exteriormodeltoclient = self.owner;
 196
 197     self.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 198     self.lip   = time;
 199
 200 }
 201
 202 void raptor_land()
 203 {
 204     float hgt;
 205
 206     hgt = raptor_altitude(512);
 207     self.velocity = (self.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * sys_frametime);
 208     self.angles_x *= 0.95;
 209     self.angles_z *= 0.95;
 210
 211     if(hgt < 128)
 212         if(self.frame != 0)
 213             self.frame = max(self.frame - 0.25, 0);
 214
 215     self.bomb1.gun1.avelocity_y = 90 + ((self.frame / 25) * 2000);
 216     self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 217
 218     if(hgt < 16)
 219     {
 220         self.movetype   = MOVETYPE_TOSS;
 221         self.think      = raptor_think;
 222     }
 223
 224     self.nextthink  = time;
 225 }
 226
 227 void raptor_exit(float eject)
 228 {
 229     vector spot;
 230     self.tur_head.exteriormodeltoclient = world;
 231
 232     if(self.deadflag == DEAD_NO)
 233     {
 234         self.think      = raptor_land;
 235         self.nextthink  = time;
 236     }
 237
 238     if not (self.owner)
 239         return;
 240
 241         makevectors(self.angles);
 242         if(eject)
 243         {
 244             spot = self.origin + v_forward * 100 + '0 0 64';
 245             spot = vehicles_findgoodexit(spot);
 246             setorigin(self.owner , spot);
 247             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 248         }
 249         else
 250         {
 251             spot = self.origin - v_forward * 200 + '0 0 64';
 252             spot = vehicles_findgoodexit(spot);
 253             setorigin(self.owner , spot);
 254         }
 255
 256     self.owner = world;
 257 }
 258
 259 float raptor_takeoff()
 260 {
 261     entity player, raptor;
 262
 263     player = self;
 264     raptor = self.vehicle;
 265     self   = raptor;
 266
 267     if(self.sound_nexttime < time)
 268     {
 269         self.sound_nexttime = time + 7.955812; //soundlength("vehicles/raptor_fly.wav");
 270         sound (self, CHAN_TRIGGER, "vehicles/raptor_speed.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 271     }
 272
 273     // Takeoff sequense
 274     if(raptor.frame < 25)
 275     {
 276         raptor.frame += 0.25;
 277         raptor.velocity_z = min(raptor.velocity_z * 1.5, 256);
 278         self.bomb1.gun1.avelocity_y = 90 + ((raptor.frame / 25) * 25000);
 279         self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 280         player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 281
 282         setorigin(player, raptor.origin + '0 0 32');
 283     }
 284     else
 285         player.PlayerPhysplug = raptor_frame;
 286
 287     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 288         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime);
 289
 290     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 291         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime);
 292
 293     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 294         vehicles_regen(cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime);
 295
 296
 297     raptor.bomb1.alpha = raptor.bomb2.alpha = (time - raptor.lip) / (raptor.delay - raptor.lip);
 298     player.vehicle_reload2 = bound(0, raptor.bomb1.alpha * 100, 100);
 299
 300     VEHICLE_UPDATE_PLAYER(health, raptor);
 301     VEHICLE_UPDATE_PLAYER(energy, raptor);
 302     if(self.vehicle_flags & VHF_HASSHIELD)
 303         VEHICLE_UPDATE_PLAYER(shield, raptor);
 304
 305     player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 306     self = player;
 307     return 1;
 308 }
 309
 310 float raptor_frame()
 311 {
 312     entity player, raptor;
 313     float ftmp, ftmp2;
 314     vector df, ra;
 315
 316     player = self;
 317     raptor = self.vehicle;
 318     self   = raptor;
 319
 320     /*
 321     ftmp = vlen(self.velocity);
 322     if(ftmp > autocvar_g_vehicle_raptor_speed_forward)
 323         ftmp = 1;
 324     else
 325         ftmp = ftmp / autocvar_g_vehicle_raptor_speed_forward;
 326     */
 327     if(self.sound_nexttime < time)
 328     {
 329         self.sound_nexttime = time + 7.955812;
 330         //dprint("LEN:", ftos(soundlength("vehicles/raptor_fly.wav")), "\n");
 331         //sound (self, CHAN_VOICE, "vehicles/raptor_fly.wav", 1 - ftmp,   ATTN_NORM );
 332         sound (self, CHAN_TRIGGER, "vehicles/raptor_speed.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 333         //self.wait = ftmp;
 334     }
 335     /*
 336     else if(fabs(ftmp - self.wait) > 0.2)
 337     {
 338         sound (self, CHAN_VOICE, "", 1 - ftmp,   ATTN_NORM );
 339         sound (self, CHAN_PLAYER, "", ftmp, ATTN_NORM);
 340         self.wait = ftmp;
 341     }*/
 342
 343     if(player.BUTTON_USE && raptor.deadflag == DEAD_NO)
 344     {
 345         self = raptor;
 346         vehicles_exit(VHEF_NORMAL);
 347         self = player;
 348         return 0;
 349     }
 350
 351     if(raptor.deadflag != DEAD_NO)
 352     {
 353         self = player;
 354         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 355         return 1;
 356     }
 357     crosshair_trace(player);
 358
 359
 360     vector vang;
 361     vang = raptor.angles;
 362     df = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 363     vang_x *= -1;
 364     df_x *= -1;
 365     if(df_x > 180)  df_x -= 360;
 366     if(df_x < -180) df_x += 360;
 367     if(df_y > 180)  df_y -= 360;
 368     if(df_y < -180) df_y += 360;
 369
 370     ftmp = shortangle_f(player.v_angle_y - vang_y, vang_y);
 371     if(ftmp > 180)  ftmp -= 360; if(ftmp < -180) ftmp += 360;
 372     raptor.avelocity_y = bound(-autocvar_g_vehicle_raptor_turnspeed, ftmp + raptor.avelocity_y * 0.9, autocvar_g_vehicle_raptor_turnspeed);
 373
 374     // Pitch
 375     ftmp = 0;
 376     if(player.movement_x > 0 && vang_x < autocvar_g_vehicle_raptor_pitchlimit) ftmp = 5;
 377     else if(player.movement_x < 0 && vang_x > -autocvar_g_vehicle_raptor_pitchlimit) ftmp = -20;
 378
 379     df_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x , autocvar_g_vehicle_raptor_pitchlimit);
 380     ftmp = vang_x - bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x + ftmp, autocvar_g_vehicle_raptor_pitchlimit);
 381     raptor.avelocity_x = bound(-autocvar_g_vehicle_raptor_pitchspeed, ftmp + raptor.avelocity_x * 0.9, autocvar_g_vehicle_raptor_pitchspeed);
 382
 383     raptor.angles_x = anglemods(raptor.angles_x);
 384     raptor.angles_y = anglemods(raptor.angles_y);
 385     raptor.angles_z = anglemods(raptor.angles_z);
 386
 387
 388     if(autocvar_g_vehicle_raptor_movestyle == 1)
 389         makevectors('0 1 0' * raptor.angles_y);
 390     else
 391         makevectors(player.v_angle);
 392
 393     df = raptor.velocity * -autocvar_g_vehicle_raptor_friction;
 394
 395     if(player.movement_x != 0)
 396     {
 397         if(player.movement_x > 0)
 398             df += v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 399         else if(player.movement_x < 0)
 400             df -= v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 401     }
 402
 403     if(player.movement_y != 0)
 404     {
 405         if(player.movement_y < 0)
 406             df -= v_right * autocvar_g_vehicle_raptor_speed_strafe;
 407         else if(player.movement_y > 0)
 408             df += v_right * autocvar_g_vehicle_raptor_speed_strafe;
 409
 410         raptor.angles_z = bound(-30,raptor.angles_z + (player.movement_y / autocvar_g_vehicle_raptor_speed_strafe),30);
 411     }
 412     else
 413     {
 414         raptor.angles_z *= 0.95;
 415         if(raptor.angles_z >= -1 && raptor.angles_z <= -1)
 416             raptor.angles_z = 0;
 417     }
 418
 419     if(player.BUTTON_CROUCH)
 420         df -=   v_up * autocvar_g_vehicle_raptor_speed_down;
 421     else if (player.BUTTON_JUMP)
 422         df +=  v_up * autocvar_g_vehicle_raptor_speed_up;
 423
 424     raptor.velocity  += df * frametime;
 425     //player.velocity = player.movement  = raptor.velocity;
 426     player.velocity = raptor.velocity;
 427     //setorigin(player,raptor.origin + '0 0 32');
 428
 429     vector vf, ad;
 430     // Target lock & predict
 431     if(autocvar_g_vehicle_raptor_cannon_locktarget)
 432     {
 433
 434         vehicles_locktarget((1 / autocvar_g_vehicle_raptor_cannon_locking_time) * frametime,
 435                              (1 / autocvar_g_vehicle_raptor_cannon_locking_releasetime) * frametime,
 436                              autocvar_g_vehicle_raptor_cannon_locked_time);
 437
 438         if(self.lock_target != world)
 439         if(autocvar_g_vehicle_raptor_cannon_predicttarget)
 440         if(self.lock_strength == 1)
 441         {
 442             float i, distance, impact_time;
 443
 444             vf = real_origin(raptor.lock_target);
 445             ad = vf;
 446             for(i = 0; i < 4; ++i)
 447             {
 448                 distance = vlen(ad - raptor.origin);
 449                 impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 450                 ad = vf + raptor.lock_target.velocity * impact_time;
 451             }
 452             trace_endpos = ad;
 453             //UpdateAuxiliaryXhair(player, trace_endpos, '1 1 1', 0);
 454         }
 455
 456         if(self.lock_target)
 457         {
 458             if(raptor.lock_strength == 1)
 459                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '1 0 0', 1);
 460             else if(self.lock_strength > 0.5)
 461                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 1 0', 1);
 462             else if(self.lock_strength < 0.5)
 463                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 0 1', 1);
 464         }
 465     }
 466
 467     ra = raptor.angles;
 468     ra_z = 0;
 469     // Aim the gunz
 470     ftmp2 = autocvar_g_vehicle_raptor_cannon_turnspeed * frametime;
 471     ftmp = -ftmp2;
 472
 473     // Gun1
 474     df = gettaginfo(raptor.gun1, gettagindex(raptor.gun1, "fire1"));
 475     //ad = df;
 476     //vf = v_forward;
 477     df = vectoangles(normalize(trace_endpos - df)); // Find the direction & angle
 478     df = shortangle_vxy(df - (ra + raptor.gun1.angles), ra + raptor.gun1.angles);     // Find aim offset
 479     // Bind to aimspeed
 480     df_x = bound(ftmp, df_x, ftmp2);
 481     df_y = bound(ftmp, df_y, ftmp2);
 482     // Bind to limts
 483     raptor.gun1.angles_x = bound(-autocvar_g_vehicle_raptor_cannon_pitchlimit_down, df_x + raptor.gun1.angles_x, autocvar_g_vehicle_raptor_cannon_pitchlimit_up);
 484     raptor.gun1.angles_y = bound(-autocvar_g_vehicle_raptor_cannon_turnlimit,  df_y + raptor.gun1.angles_y, autocvar_g_vehicle_raptor_cannon_turnlimit);
 485
 486     //df = vectoangles(normalize(trace_endpos - df));
 487
 488     //Gun 2
 489     df = gettaginfo(raptor.gun2, gettagindex(raptor.gun2, "fire1"));
 490     //ad += df;
 491     //vf += v_forward;
 492     df = vectoangles(normalize(trace_endpos - df)); // Find the direction & angle
 493     df = shortangle_vxy(df - (ra + raptor.gun2.angles), ra + raptor.gun2.angles);     // Find aim offset
 494     // Bind to aimspeed
 495     df_x = bound(ftmp, df_x, ftmp2);
 496     df_y = bound(ftmp, df_y, ftmp2);
 497     // Bind to limts
 498     raptor.gun2.angles_x = bound(-autocvar_g_vehicle_raptor_cannon_pitchlimit_down, df_x + raptor.gun2.angles_x, autocvar_g_vehicle_raptor_cannon_pitchlimit_up);
 499     raptor.gun2.angles_y = bound(-autocvar_g_vehicle_raptor_cannon_turnlimit,  df_y + raptor.gun2.angles_y, autocvar_g_vehicle_raptor_cannon_turnlimit);
 500
 501     /*
 502     ad = ad * 0.5;
 503     v_forward = vf * 0.5;
 504     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, raptor);
 505     UpdateAuxiliaryXhair(player, trace_endpos, '0 1 0', 0);
 506     */
 507
 508     if(player.BUTTON_ATCK)
 509     if(raptor.attack_finished_single <= time)
 510     if(raptor.vehicle_energy > autocvar_g_vehicle_raptor_cannon_cost)
 511     {
 512         raptor.misc_bulletcounter += 1;
 513         raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire;
 514         if(raptor.misc_bulletcounter <= 2)
 515             raptor_fire_cannon(self.gun1, "fire1");
 516         else if(raptor.misc_bulletcounter == 3)
 517             raptor_fire_cannon(self.gun2, "fire1");
 518         else
 519         {
 520             raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire * 2;
 521             raptor_fire_cannon(self.gun2, "fire1");
 522             raptor.misc_bulletcounter = 0;
 523         }
 524         raptor.vehicle_energy -= autocvar_g_vehicle_raptor_cannon_cost;
 525         self.cnt = time;
 526     }
 527
 528     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 529         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime);
 530
 531     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 532         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime);
 533
 534     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 535         vehicles_regen(cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime);
 536
 537
 538     if(time > raptor.delay)
 539     if(player.BUTTON_ATCK2)
 540     {
 541         raptor_bombdrop();
 542         raptor.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 543         raptor.lip   = time;
 544     }
 545
 546     raptor.bomb1.alpha = raptor.bomb2.alpha = (time - raptor.lip) / (raptor.delay - raptor.lip);
 547     player.vehicle_reload2 = bound(0, raptor.bomb1.alpha * 100, 100);
 548
 549     VEHICLE_UPDATE_PLAYER(health, raptor);
 550     VEHICLE_UPDATE_PLAYER(energy, raptor);
 551     if(self.vehicle_flags & VHF_HASSHIELD)
 552         VEHICLE_UPDATE_PLAYER(shield, raptor);
 553
 554     player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 555     return 1;
 556 }
 557
 558 void raptor_blowup()
 559 {
 560     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 561     pointparticles(particleeffectnum("explosion_big"), self.origin, '0 0 0', 1);
 562
 563     self.deadflag    = DEAD_DEAD;
 564     self.vehicle_exit(VHEF_NORMAL);
 565     RadiusDamage (self, self, 250, 15, 250, world, 250, DEATH_WAKIBLOWUP, world);
 566
 567     self.alpha          = -1;
 568     self.movetype       = MOVETYPE_NONE;
 569     self.effects        = EF_NODRAW;
 570     self.colormod       = '0 0 0';
 571     self.avelocity      = '0 0 0';
 572     self.velocity       = '0 0 0';
 573
 574     setorigin(self, self.pos1);
 575     self.touch = SUB_Null;
 576     self.nextthink = 0;
 577 }
 578
 579 void raptor_diethink()
 580 {
 581     //self.avelocity += '0 0.5 1' * (random() * 5);
 582     //self.avelocity -= '0 0.5 1' * (random() * 5);
 583
 584     if(random() < 0.1)
 585     {
 586         sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 587         pointparticles(particleeffectnum("explosion_small"), randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
 588     }
 589     self.nextthink = time + 0.1;
 590 }
 591
 592 void raptor_die()
 593 {
 594     self.health       = 0;
 595     self.event_damage = SUB_Null;
 596     self.iscreature   = FALSE;
 597     self.solid        = SOLID_CORPSE;
 598     self.takedamage   = DAMAGE_NO;
 599     self.deadflag     = DEAD_DYING;
 600     self.movetype     = MOVETYPE_BOUNCE;
 601     self.think        = raptor_diethink;
 602     self.nextthink    = time;
 603
 604     pointparticles(particleeffectnum("explosion_medium"), findbetterlocation (self.origin, 16), '0 0 0', 1);
 605
 606     self.velocity_z += 600;
 607
 608     self.avelocity = '0 0.5 1' * (random() * 400);
 609     self.avelocity -= '0 0.5 1' * (random() * 400);
 610
 611     self.colormod = '-0.5 -0.5 -0.5';
 612         self.touch     = raptor_blowup;
 613 }
 614
 615 void raptor_spawn()
 616 {
 617     self.frame          = 0;
 618     self.vehicle_health = autocvar_g_vehicle_raptor_health;
 619     self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 620     self.movetype       = MOVETYPE_TOSS;
 621     self.solid          = SOLID_SLIDEBOX;
 622     self.vehicle_energy = 1;
 623
 624     self.bomb1.gun1.avelocity_y = 90;
 625     self.bomb1.gun2.avelocity_y = -90;
 626
 627     setsize(self, RAPTOR_MIN, RAPTOR_MAX );
 628     self.delay = time;
 629 }
 630
 631 // If we dont do this ever now and then, the raptors rotors
 632 // stop working, presumably due to angle overflow. cute.
 633 void raptor_rotor_anglefix()
 634 {
 635     self.gun1.angles_y = anglemods(self.gun1.angles_y);
 636     self.gun2.angles_y = anglemods(self.gun2.angles_y);
 637     self.nextthink = time + 15;
 638 }
 639
 640 void raptor_dinit()
 641 {
 642     entity spinner;
 643     vector ofs;
 644
 645     if not (vehicle_initialize(
 646              "Raptor",
 647              "models/vehicles/raptor.dpm",
 648              "",
 649              "models/vehicles/raptor_cockpit.dpm",
 650              "", "tag_hud", "tag_camera",
 651              HUD_RAPTOR,
 652              RAPTOR_MIN, RAPTOR_MAX,
 653              FALSE,
 654              raptor_spawn, autocvar_g_vehicle_raptor_respawntime,
 655              raptor_frame,
 656              raptor_enter, raptor_exit,
 657              raptor_die,   raptor_think,
 658              FALSE))
 659     {
 660         remove(self);
 661         return;
 662     }
 663
 664     //FIXME: Camera is in a bad place in HUD model.
 665     //setorigin(self.vehicle_viewport, '25 0 5');
 666
 667     self.frame = 0;
 668
 669     self.bomb1 = spawn();
 670     self.bomb2 = spawn();
 671     self.gun1  = spawn();
 672     self.gun2  = spawn();
 673
 674     setmodel(self.bomb1,"models/vehicles/clusterbomb_folded.md3");
 675     setmodel(self.bomb2,"models/vehicles/clusterbomb_folded.md3");
 676     setmodel(self.gun1, "models/vehicles/raptor_gun.dpm");
 677     setmodel(self.gun2, "models/vehicles/raptor_gun.dpm");
 678     setmodel(self.tur_head, "models/vehicles/raptor_body.dpm");
 679
 680     setattachment(self.bomb1, self,"bombmount_left");
 681     setattachment(self.bomb2, self,"bombmount_right");
 682     setattachment(self.tur_head, self,"root");
 683
 684
 685     // FIXME Guns mounts to angled bones
 686     self.bomb1.angles = self.angles;
 687     self.angles = '0 0 0';
 688     // This messes up gun-aim, so work arround it.
 689     //setattachment(self.gun1, self, "gunmount_left");
 690     ofs = gettaginfo(self, gettagindex(self, "gunmount_left"));
 691     ofs -= self.origin;
 692     setattachment(self.gun1, self, "");
 693     setorigin(self.gun1, ofs);
 694
 695     //setattachment(self.gun2, self, "gunmount_right");
 696     ofs = gettaginfo(self, gettagindex(self, "gunmount_right"));
 697     ofs -= self.origin;
 698     setattachment(self.gun2, self, "");
 699     setorigin(self.gun2, ofs);
 700
 701     self.angles = self.bomb1.angles;
 702     self.bomb1.angles = '0 0 0';
 703
 704     spinner = spawn();
 705     spinner.owner = self;
 706     setmodel(spinner,"models/vehicles/spinner.dpm");
 707     setattachment(spinner, self, "engine_left");
 708     spinner.movetype = MOVETYPE_NOCLIP;
 709     spinner.avelocity = '0 90 0';
 710     self.bomb1.gun1 = spinner;
 711
 712     spinner = spawn();
 713     spinner.owner = self;
 714     setmodel(spinner,"models/vehicles/spinner.dpm");
 715     setattachment(spinner, self, "engine_right");
 716     spinner.movetype = MOVETYPE_NOCLIP;
 717     spinner.avelocity = '0 -90 0';
 718     self.bomb1.gun2 = spinner;
 719
 720     // Sigh.
 721     self.bomb1.think = raptor_rotor_anglefix;
 722     self.bomb1.nextthink = time;
 723
 724     self.mass               = 1 ;
 725 }
 726
 727 void spawnfunc_vehicle_raptor()
 728 {
 729     vehicles_configcheck("vehicle_raptor.cfg", autocvar_g_vehicle_raptor_health);
 730
 731
 732
 733     if(autocvar_g_vehicle_raptor_shield)
 734         self.vehicle_flags |= VHF_HASSHIELD;
 735
 736     if(autocvar_g_vehicle_raptor_shield_regen)
 737         self.vehicle_flags |= VHF_SHIELDREGEN;
 738
 739     if(autocvar_g_vehicle_raptor_health_regen)
 740         self.vehicle_flags |= VHF_HEALTHREGEN;
 741
 742     if(autocvar_g_vehicle_raptor_energy_regen)
 743         self.vehicle_flags |= VHF_ENERGYREGEN;
 744
 745     precache_model ("models/vehicles/raptor.dpm");
 746     precache_model ("models/vehicles/raptor_gun.dpm");
 747     precache_model ("models/vehicles/spinner.dpm");
 748     precache_model ("models/vehicles/raptor_cockpit.dpm");
 749     precache_model ("models/vehicles/clusterbomb.md3");
 750     precache_model ("models/vehicles/clusterbomb_folded.md3");
 751     precache_model ("models/vehicles/raptor_body.dpm");
 752     precache_sound ("vehicles/raptor_fly.wav");
 753     precache_sound ("vehicles/raptor_speed.wav");
 754
 755     self.think = raptor_dinit;
 756     self.nextthink = time + (autocvar_g_vehicles_delayspawn ? autocvar_g_vehicle_raptor_respawntime + (random() * autocvar_g_vehicles_delayspawn_jitter) : 0.5);
 757 }
 758 #endif // SVQC