qcsrc/server/tturrets/system/system_main.qc

   1 #define cvar_base "g_turrets_unit_"
   2
   3 float turret_send(entity to, float sf)
   4 {
   5         dprint("Sending update\n");
   6         WriteByte(MSG_ENTITY, ENT_CLIENT_TURRET);
   7         WriteByte(MSG_ENTITY, sf);
   8         if(sf & TNSF_SETUP)
   9         {
  10             WriteByte(MSG_ENTITY, self.turret_type);
  11
  12             WriteCoord(MSG_ENTITY, self.origin_x);
  13             WriteCoord(MSG_ENTITY, self.origin_y);
  14             WriteCoord(MSG_ENTITY, self.origin_z);
  15
  16             WriteAngle(MSG_ENTITY, self.angles_x);
  17             WriteAngle(MSG_ENTITY, self.angles_y);
  18     }
  19
  20     if(sf & TNSF_ANG)
  21     {
  22         WriteShort(MSG_ENTITY, rint(self.tur_head.angles_x));
  23         WriteShort(MSG_ENTITY, rint(self.tur_head.angles_y));
  24     }
  25
  26     if(sf & TNSF_AVEL)
  27     {
  28         WriteShort(MSG_ENTITY, rint(self.tur_head.avelocity_x));
  29         WriteShort(MSG_ENTITY, rint(self.tur_head.avelocity_y));
  30     }
  31
  32     if(sf & TNSF_STATUS)
  33     {
  34         WriteByte(MSG_ENTITY, self.team);
  35         WriteByte(MSG_ENTITY, rint((self.health / self.tur_health) * 255)); // Send health as 0-255 insted of real value, where 255 = 100%
  36     }
  37
  38         return TRUE;
  39 }
  40
  41 void load_unit_settings(entity ent, string unitname, float is_reload)
  42 {
  43     string sbase;
  44
  45     if (ent == world)
  46         return;
  47
  48     if not (ent.turret_scale_damage)    ent.turret_scale_damage  = 1;
  49     if not (ent.turret_scale_range)     ent.turret_scale_range   = 1;
  50     if not (ent.turret_scale_refire)    ent.turret_scale_refire  = 1;
  51     if not (ent.turret_scale_ammo)      ent.turret_scale_ammo    = 1;
  52     if not (ent.turret_scale_aim)       ent.turret_scale_aim     = 1;
  53     if not (ent.turret_scale_health)    ent.turret_scale_health  = 1;
  54     if not (ent.turret_scale_respawn)   ent.turret_scale_respawn = 1;
  55
  56     sbase = strcat(cvar_base,unitname);
  57     if (is_reload)
  58     {
  59         ent.enemy = world;
  60         ent.tur_head.avelocity = '0 0 0';
  61
  62         ent.tur_head.angles = '0 0 0';
  63     }
  64
  65     ent.health      = cvar(strcat(sbase,"_health")) * ent.turret_scale_health;
  66     ent.respawntime = cvar(strcat(sbase,"_respawntime")) * ent.turret_scale_respawn;
  67
  68     ent.shot_dmg          = cvar(strcat(sbase,"_shot_dmg")) * ent.turret_scale_damage;
  69     ent.shot_refire       = cvar(strcat(sbase,"_shot_refire")) * ent.turret_scale_refire;
  70     ent.shot_radius       = cvar(strcat(sbase,"_shot_radius")) * ent.turret_scale_damage;
  71     ent.shot_speed        = cvar(strcat(sbase,"_shot_speed"));
  72     ent.shot_spread       = cvar(strcat(sbase,"_shot_spread"));
  73     ent.shot_force        = cvar(strcat(sbase,"_shot_force")) * ent.turret_scale_damage;
  74     ent.shot_volly        = cvar(strcat(sbase,"_shot_volly"));
  75     ent.shot_volly_refire = cvar(strcat(sbase,"_shot_volly_refire")) * ent.turret_scale_refire;
  76
  77     ent.target_range         = cvar(strcat(sbase,"_target_range")) * ent.turret_scale_range;
  78     ent.target_range_min     = cvar(strcat(sbase,"_target_range_min")) * ent.turret_scale_range;
  79     ent.target_range_optimal = cvar(strcat(sbase,"_target_range_optimal")) * ent.turret_scale_range;
  80     //ent.target_range_fire    = cvar(strcat(sbase,"_target_range_fire")) * ent.turret_scale_range;
  81
  82     ent.target_select_rangebias  = cvar(strcat(sbase,"_target_select_rangebias"));
  83     ent.target_select_samebias   = cvar(strcat(sbase,"_target_select_samebias"));
  84     ent.target_select_anglebias  = cvar(strcat(sbase,"_target_select_anglebias"));
  85     ent.target_select_playerbias = cvar(strcat(sbase,"_target_select_playerbias"));
  86     //ent.target_select_fov = cvar(cvar_gets(sbase,"_target_select_fov"));
  87
  88     ent.ammo_max      = cvar(strcat(sbase,"_ammo_max")) * ent.turret_scale_ammo;
  89     ent.ammo_recharge = cvar(strcat(sbase,"_ammo_recharge")) * ent.turret_scale_ammo;
  90
  91     ent.aim_firetolerance_dist = cvar(strcat(sbase,"_aim_firetolerance_dist"));
  92     ent.aim_speed    = cvar(strcat(sbase,"_aim_speed")) * ent.turret_scale_aim;
  93     ent.aim_maxrot   = cvar(strcat(sbase,"_aim_maxrot"));
  94     ent.aim_maxpitch = cvar(strcat(sbase,"_aim_maxpitch"));
  95
  96     ent.track_type        = cvar(strcat(sbase,"_track_type"));
  97     ent.track_accel_pitch = cvar(strcat(sbase,"_track_accel_pitch"));
  98     ent.track_accel_rot   = cvar(strcat(sbase,"_track_accel_rot"));
  99     ent.track_blendrate   = cvar(strcat(sbase,"_track_blendrate"));
 100
 101     if(is_reload)
 102         if(ent.turret_respawnhook)
 103             ent.turret_respawnhook();
 104 }
 105
 106
 107 /**
 108 ** updates enemy distances, predicted impact point/time
 109 ** and updated aim<->predict impact distance.
 110 **/
 111 void turret_do_updates(entity t_turret)
 112 {
 113     vector enemy_pos, oldpos;
 114     entity oldself;
 115
 116     oldself = self;
 117     self = t_turret;
 118
 119     enemy_pos = real_origin(self.enemy);
 120
 121     turret_tag_fire_update();
 122
 123     self.tur_shotdir_updated = v_forward;
 124     self.tur_dist_enemy  = vlen(self.tur_shotorg - enemy_pos);
 125     self.tur_dist_aimpos = vlen(self.tur_shotorg - self.tur_aimpos);
 126
 127     if((self.firecheck_flags & TFL_FIRECHECK_VERIFIED) && (self.enemy))
 128     {
 129         oldpos = self.enemy.origin;
 130         setorigin(self.enemy,self.tur_aimpos);
 131         tracebox(self.tur_shotorg, '-1 -1 -1','1 1 1',self.tur_shotorg + (self.tur_shotdir_updated * self.tur_dist_aimpos),MOVE_NORMAL,self);
 132         setorigin(self.enemy,oldpos);
 133
 134         if(trace_ent == self.enemy)
 135             self.tur_dist_impact_to_aimpos = 0;
 136         else
 137             self.tur_dist_impact_to_aimpos = vlen(trace_endpos - self.tur_aimpos);
 138     }
 139     else
 140         tracebox(self.tur_shotorg, '-1 -1 -1','1 1 1', self.tur_shotorg + (self.tur_shotdir_updated * self.tur_dist_aimpos),MOVE_NORMAL,self);
 141
 142         self.tur_dist_impact_to_aimpos = vlen(trace_endpos - self.tur_aimpos) - (vlen(self.enemy.maxs - self.enemy.mins) * 0.5);
 143         self.tur_impactent             = trace_ent;
 144         self.tur_impacttime            = vlen(self.tur_shotorg - trace_endpos) / self.shot_speed;
 145
 146     self = oldself;
 147 }
 148
 149 /*
 150 vector turret_fovsearch_pingpong()
 151 {
 152     vector wish_angle;
 153     if(self.phase < time)
 154     {
 155         if( self.tur_head.phase )
 156             self.tur_head.phase = 0;
 157         else
 158             self.tur_head.phase = 1;
 159         self.phase = time + 5;
 160     }
 161
 162     if( self.tur_head.phase)
 163         wish_angle = self.idle_aim + '0 1 0' * (self.aim_maxrot * (self.target_select_fov / 360));
 164     else
 165         wish_angle = self.idle_aim - '0 1 0' * (self.aim_maxrot * (self.target_select_fov / 360));
 166
 167     return wish_angle;
 168 }
 169
 170 vector turret_fovsearch_steprot()
 171 {
 172     vector wish_angle;
 173     //float rot_add;
 174
 175     wish_angle   = self.tur_head.angles;
 176     wish_angle_x = self.idle_aim_x;
 177
 178     if (self.phase < time)
 179     {
 180         //rot_add = self.aim_maxrot / self.target_select_fov;
 181         wish_angle_y += (self.target_select_fov * 2);
 182
 183         if(wish_angle_y > 360)
 184             wish_angle_y = wish_angle_y - 360;
 185
 186          self.phase = time + 1.5;
 187     }
 188
 189     return wish_angle;
 190 }
 191
 192 vector turret_fovsearch_random()
 193 {
 194     vector wish_angle;
 195
 196     if (self.phase < time)
 197     {
 198         wish_angle_y = random() * self.aim_maxrot;
 199         if(random() < 0.5)
 200             wish_angle_y *= -1;
 201
 202         wish_angle_x = random() * self.aim_maxpitch;
 203         if(random() < 0.5)
 204             wish_angle_x *= -1;
 205
 206         self.phase = time + 5;
 207
 208         self.tur_aimpos = wish_angle;
 209     }
 210
 211     return self.idle_aim + self.tur_aimpos;
 212 }
 213 */
 214
 215 /**
 216 ** Handles head rotation according to
 217 ** the units .track_type and .track_flags
 218 **/
 219 .float turret_framecounter;
 220 void turret_stdproc_track()
 221 {
 222     vector target_angle; // This is where we want to aim
 223     vector move_angle;   // This is where we can aim
 224     float f_tmp;
 225     vector v1, v2;
 226     v1 = self.tur_head.angles;
 227     v2 = self.tur_head.avelocity;
 228
 229     if (self.track_flags == TFL_TRACK_NO)
 230         return;
 231
 232     if not (self.tur_active)
 233         target_angle = self.idle_aim - ('1 0 0' * self.aim_maxpitch);
 234     else if (self.enemy == world)
 235     {
 236         if(time > self.lip)
 237             target_angle = self.idle_aim + self.angles;
 238         else
 239             target_angle = vectoangles(normalize(self.tur_aimpos - self.tur_shotorg));
 240     }
 241     else
 242     {
 243         target_angle = vectoangles(normalize(self.tur_aimpos - self.tur_shotorg));
 244     }
 245
 246     self.tur_head.angles_x = anglemods(self.tur_head.angles_x);
 247     self.tur_head.angles_y = anglemods(self.tur_head.angles_y);
 248
 249     // Find the diffrence between where we currently aim and where we want to aim
 250     move_angle = target_angle - (self.angles + self.tur_head.angles);
 251     move_angle = shortangle_vxy(move_angle,(self.angles + self.tur_head.angles));
 252
 253     switch(self.track_type)
 254     {
 255         case TFL_TRACKTYPE_STEPMOTOR:
 256             f_tmp = self.aim_speed * self.ticrate; // dgr/sec -> dgr/tic
 257             if (self.track_flags & TFL_TRACK_PITCH)
 258             {
 259                 self.tur_head.angles_x += bound(-f_tmp,move_angle_x, f_tmp);
 260                 if(self.tur_head.angles_x > self.aim_maxpitch)
 261                     self.tur_head.angles_x = self.aim_maxpitch;
 262
 263                 if(self.tur_head.angles_x  < -self.aim_maxpitch)
 264                     self.tur_head.angles_x = self.aim_maxpitch;
 265             }
 266
 267             if (self.track_flags & TFL_TRACK_ROT)
 268             {
 269                 self.tur_head.angles_y += bound(-f_tmp, move_angle_y, f_tmp);
 270                 if(self.tur_head.angles_y > self.aim_maxrot)
 271                     self.tur_head.angles_y = self.aim_maxrot;
 272
 273                 if(self.tur_head.angles_y  < -self.aim_maxrot)
 274                     self.tur_head.angles_y = self.aim_maxrot;
 275             }
 276
 277             // CSQC
 278             self.SendFlags  = TNSF_ANG;
 279
 280             return;
 281
 282         case TFL_TRACKTYPE_FLUIDINERTIA:
 283             f_tmp = self.aim_speed * self.ticrate; // dgr/sec -> dgr/tic
 284             move_angle_x = bound(-self.aim_speed, move_angle_x * self.track_accel_pitch * f_tmp, self.aim_speed);
 285             move_angle_y = bound(-self.aim_speed, move_angle_y * self.track_accel_rot * f_tmp, self.aim_speed);
 286             move_angle = (self.tur_head.avelocity * self.track_blendrate) + (move_angle * (1 - self.track_blendrate));
 287             break;
 288
 289         case TFL_TRACKTYPE_FLUIDPRECISE:
 290
 291             move_angle_y = bound(-self.aim_speed, move_angle_y, self.aim_speed);
 292             move_angle_x = bound(-self.aim_speed, move_angle_x, self.aim_speed);
 293
 294             break;
 295     }
 296
 297     //  pitch
 298     if (self.track_flags & TFL_TRACK_PITCH)
 299     {
 300         self.tur_head.avelocity_x = move_angle_x;
 301         if((self.tur_head.angles_x + self.tur_head.avelocity_x * self.ticrate) > self.aim_maxpitch)
 302         {
 303             self.tur_head.avelocity_x = 0;
 304             self.tur_head.angles_x = self.aim_maxpitch;
 305
 306             self.SendFlags  |= TNSF_ANG;
 307         }
 308
 309         if((self.tur_head.angles_x + self.tur_head.avelocity_x * self.ticrate) < -self.aim_maxpitch)
 310         {
 311             self.tur_head.avelocity_x = 0;
 312             self.tur_head.angles_x = -self.aim_maxpitch;
 313
 314             self.SendFlags  |= TNSF_ANG;
 315         }
 316     }
 317
 318     //  rot
 319     if (self.track_flags & TFL_TRACK_ROT)
 320     {
 321         self.tur_head.avelocity_y = move_angle_y;
 322
 323         if((self.tur_head.angles_y + self.tur_head.avelocity_y * self.ticrate) > self.aim_maxrot)
 324         {
 325             self.tur_head.avelocity_y = 0;
 326             self.tur_head.angles_y = self.aim_maxrot;
 327
 328             self.SendFlags  |= TNSF_ANG;
 329         }
 330
 331         if((self.tur_head.angles_y + self.tur_head.avelocity_y * self.ticrate) < -self.aim_maxrot)
 332         {
 333             self.tur_head.avelocity_y = 0;
 334             self.tur_head.angles_y = -self.aim_maxrot;
 335
 336             self.SendFlags  |= TNSF_ANG;
 337         }
 338     }
 339
 340     self.SendFlags  |= TNSF_AVEL;
 341
 342     // Force a angle update every 10'th frame
 343     self.turret_framecounter += 1;
 344     if(self.turret_framecounter >= 10)
 345     {
 346         self.SendFlags |= TNSF_ANG;
 347         self.turret_framecounter = 0;
 348     }
 349 }
 350
 351
 352 /*
 353  + = implemented
 354  - = not implemented
 355
 356  + TFL_FIRECHECK_NO
 357  + TFL_FIRECHECK_WORLD
 358  + TFL_FIRECHECK_DEAD
 359  + TFL_FIRECHECK_DISTANCES
 360  - TFL_FIRECHECK_LOS
 361  + TFL_FIRECHECK_AIMDIST
 362  + TFL_FIRECHECK_REALDIST
 363  - TFL_FIRECHECK_ANGLEDIST
 364  - TFL_FIRECHECK_TEAMCECK
 365  + TFL_FIRECHECK_AFF
 366  + TFL_FIRECHECK_OWM_AMMO
 367  + TFL_FIRECHECK_OTHER_AMMO
 368  + TFL_FIRECHECK_REFIRE
 369 */
 370
 371 /**
 372 ** Preforms pre-fire checks based on the uints firecheck_flags
 373 **/
 374 float turret_stdproc_firecheck()
 375 {
 376     // This one just dont care =)
 377     if (self.firecheck_flags & TFL_FIRECHECK_NO) return 1;
 378
 379     // Ready?
 380     if (self.firecheck_flags & TFL_FIRECHECK_REFIRE)
 381         if (self.attack_finished_single > time) return 0;
 382
 383     // Special case: volly fire turret that has to fire a full volly if a shot was fired.
 384     if (self.shoot_flags & TFL_SHOOT_VOLLYALWAYS)
 385         if (self.volly_counter != self.shot_volly)
 386                         if(self.ammo >= self.shot_dmg)
 387                                 return 1;
 388
 389     // Lack of zombies makes shooting dead things unnecessary :P
 390     if (self.firecheck_flags & TFL_FIRECHECK_DEAD)
 391         if (self.enemy.deadflag != DEAD_NO)
 392             return 0;
 393
 394     // Plz stop killing the world!
 395     if (self.firecheck_flags & TFL_FIRECHECK_WORLD)
 396         if (self.enemy == world)
 397             return 0;
 398
 399     // Own ammo?
 400     if (self.firecheck_flags & TFL_FIRECHECK_OWM_AMMO)
 401         if (self.ammo < self.shot_dmg)
 402             return 0;
 403
 404     // Other's ammo? (support-supply units)
 405     if (self.firecheck_flags & TFL_FIRECHECK_OTHER_AMMO)
 406         if (self.enemy.ammo >= self.enemy.ammo_max)
 407             return 0;
 408
 409         // Target of opertunity?
 410         if(turret_validate_target(self, self.tur_impactent, self.target_validate_flags) > 0)
 411         {
 412                 self.enemy = self.tur_impactent;
 413                 return 1;
 414         }
 415
 416     if (self.firecheck_flags & TFL_FIRECHECK_DISTANCES)
 417     {
 418         // To close?
 419         if (self.tur_dist_aimpos < self.target_range_min)
 420                         if(turret_validate_target(self, self.tur_impactent, self.target_validate_flags) > 0)
 421                                 return 1; // Target of opertunity?
 422                         else
 423                                 return 0;
 424     }
 425
 426     // Try to avoid FF?
 427     if (self.firecheck_flags & TFL_FIRECHECK_AFF)
 428         if (self.tur_impactent.team == self.team)
 429             return 0;
 430
 431     // aim<->predicted impact
 432     if (self.firecheck_flags & TFL_FIRECHECK_AIMDIST)
 433         if (self.tur_dist_impact_to_aimpos > self.aim_firetolerance_dist)
 434             return 0;
 435
 436     // Volly status
 437     if (self.shot_volly > 1)
 438         if (self.volly_counter == self.shot_volly)
 439             if (self.ammo < (self.shot_dmg * self.shot_volly))
 440                 return 0;
 441
 442     if(self.firecheck_flags & TFL_FIRECHECK_VERIFIED)
 443         if(self.tur_impactent != self.enemy)
 444             return 0;
 445
 446     return 1;
 447 }
 448
 449 /*
 450  + TFL_TARGETSELECT_NO
 451  + TFL_TARGETSELECT_LOS
 452  + TFL_TARGETSELECT_PLAYERS
 453  + TFL_TARGETSELECT_MISSILES
 454  - TFL_TARGETSELECT_TRIGGERTARGET
 455  + TFL_TARGETSELECT_ANGLELIMITS
 456  + TFL_TARGETSELECT_RANGELIMTS
 457  + TFL_TARGETSELECT_TEAMCHECK
 458  - TFL_TARGETSELECT_NOBUILTIN
 459  + TFL_TARGETSELECT_OWNTEAM
 460 */
 461
 462 /**
 463 ** Evaluate a entity for target valitity based on validate_flags
 464 ** NOTE: the caller must check takedamage before calling this, to inline this check.
 465 **/
 466 float turret_validate_target(entity e_turret, entity e_target, float validate_flags)
 467 {
 468     vector v_tmp;
 469
 470     //if(!validate_flags & TFL_TARGETSELECT_NOBUILTIN)
 471     //    return -0.5;
 472
 473     if(e_target.owner == e_turret)
 474         return -0.5;
 475
 476     if not(checkpvs(e_target.origin, e_turret))
 477         return -1;
 478
 479     if not (e_target)
 480         return -2;
 481
 482         if(g_onslaught)
 483                 if (substring(e_target.classname, 0, 10) == "onslaught_") // don't attack onslaught targets, that's the player's job!
 484                         return - 3;
 485
 486     if (validate_flags & TFL_TARGETSELECT_NO)
 487         return -4;
 488
 489     // If only this was used more..
 490     if (e_target.flags & FL_NOTARGET)
 491         return -5;
 492
 493     // Cant touch this
 494     if (e_target.health < 0)
 495         return -6;
 496
 497     // player
 498     if (e_target.flags & FL_CLIENT)
 499     {
 500         if not (validate_flags & TFL_TARGETSELECT_PLAYERS)
 501             return -7;
 502
 503         if (e_target.deadflag != DEAD_NO)
 504             return -8;
 505     }
 506
 507         // enemy turrets
 508         if (validate_flags & TFL_TARGETSELECT_NOTURRETS)
 509         if (e_target.turret_firefunc || e_target.owner.tur_head == e_target)
 510             if(e_target.team != e_turret.team) // Dont break support units.
 511                 return -9;
 512
 513     // Missile
 514     if (e_target.flags & FL_PROJECTILE)
 515         if not (validate_flags & TFL_TARGETSELECT_MISSILES)
 516             return -10;
 517
 518     if (validate_flags & TFL_TARGETSELECT_MISSILESONLY)
 519         if not (e_target.flags & FL_PROJECTILE)
 520             return -10.5;
 521
 522     // Team check
 523     if (validate_flags & TFL_TARGETSELECT_TEAMCHECK)
 524     {
 525         if (validate_flags & TFL_TARGETSELECT_OWNTEAM)
 526         {
 527             if (e_target.team != e_turret.team)
 528                 return -11;
 529
 530             if (e_turret.team != e_target.owner.team)
 531                 return -12;
 532         }
 533         else
 534         {
 535             if (e_target.team == e_turret.team)
 536                 return -13;
 537
 538             if (e_turret.team == e_target.owner.team)
 539                 return -14;
 540         }
 541     }
 542
 543     // Range limits?
 544     tvt_dist = vlen(e_turret.origin - real_origin(e_target));
 545     if (validate_flags & TFL_TARGETSELECT_RANGELIMTS)
 546     {
 547         if (tvt_dist < e_turret.target_range_min)
 548             return -15;
 549
 550         if (tvt_dist > e_turret.target_range)
 551             return -16;
 552     }
 553
 554     // Can we even aim this thing?
 555     tvt_thadv = angleofs3(e_turret.tur_head.origin, e_turret.angles + e_turret.tur_head.angles, e_target);
 556     tvt_tadv  = shortangle_vxy(angleofs(e_turret, e_target), e_turret.angles);
 557     tvt_thadf = vlen(tvt_thadv);
 558     tvt_tadf  = vlen(tvt_tadv);
 559
 560     /*
 561     if(validate_flags & TFL_TARGETSELECT_FOV)
 562     {
 563         if(e_turret.target_select_fov < tvt_thadf)
 564             return -21;
 565     }
 566     */
 567
 568     if (validate_flags & TFL_TARGETSELECT_ANGLELIMITS)
 569     {
 570         if (fabs(tvt_tadv_x) > e_turret.aim_maxpitch)
 571             return -17;
 572
 573         if (fabs(tvt_tadv_y) > e_turret.aim_maxrot)
 574             return -18;
 575     }
 576
 577     // Line of sight?
 578     if (validate_flags & TFL_TARGETSELECT_LOS)
 579     {
 580         v_tmp = real_origin(e_target) + ((e_target.mins + e_target.maxs) * 0.5);
 581
 582         traceline(e_turret.tur_shotorg, v_tmp, 0, e_turret);
 583
 584         if (e_turret.aim_firetolerance_dist < vlen(v_tmp - trace_endpos))
 585             return -19;
 586     }
 587
 588     if (e_target.classname == "grapplinghook")
 589         return -20;
 590
 591     /*
 592     if (e_target.classname == "func_button")
 593         return -21;
 594     */
 595
 596 #ifdef TURRET_DEBUG_TARGETSELECT
 597     dprint("Target:",e_target.netname," is a valid target for ",e_turret.netname,"\n");
 598 #endif
 599
 600     return 1;
 601 }
 602
 603 entity turret_select_target()
 604 {
 605     entity e;        // target looper entity
 606     float  score;    // target looper entity score
 607     entity e_enemy;  // currently best scoreing target
 608     float  m_score;  // currently best scoreing target's score
 609
 610     m_score = 0;
 611     if(self.enemy)
 612         if(self.enemy.takedamage)
 613     if(turret_validate_target(self,self.enemy,self.target_validate_flags) > 0)
 614     {
 615         e_enemy = self.enemy;
 616         m_score = self.turret_score_target(self,e_enemy) * self.target_select_samebias;
 617     }
 618     else
 619         self.enemy = world;
 620
 621     e = findradius(self.origin, self.target_range);
 622
 623     // Nothing to aim at?
 624     if (!e)
 625                 return world;
 626
 627     while (e)
 628     {
 629                 if(e.takedamage)
 630                 {
 631                         if (turret_validate_target(self, e, self.target_select_flags) > 0)
 632                         {
 633                                 score = self.turret_score_target(self,e);
 634                                 if ((score > m_score) && (score > 0))
 635                                 {
 636                                         e_enemy = e;
 637                                         m_score = score;
 638                                 }
 639                         }
 640                 }
 641         e = e.chain;
 642     }
 643
 644     return e_enemy;
 645 }
 646
 647 void turret_think()
 648 {
 649     entity e;
 650
 651     self.nextthink = time + self.ticrate;
 652     //self.SendFlags = TNSF_UPDATE | TNSF_STATUS | TNSF_ANG | TNSF_AVEL;
 653
 654     // ONS uses somewhat backwards linking.
 655     if (teamplay)
 656     {
 657         if not (g_onslaught)
 658             if (self.target)
 659             {
 660                 e = find(world, targetname,self.target);
 661                 if (e != world)
 662                     self.team = e.team;
 663             }
 664
 665         if (self.team != self.tur_head.team)
 666             turret_stdproc_respawn();
 667     }
 668
 669 #ifdef TURRET_DEBUG
 670     if (self.tur_dbg_tmr1 < time)
 671     {
 672         if (self.enemy) paint_target (self.enemy,128,self.tur_dbg_rvec,0.9);
 673         paint_target(self,256,self.tur_dbg_rvec,0.9);
 674         self.tur_dbg_tmr1 = time + 1;
 675     }
 676 #endif
 677
 678     // Handle ammo
 679     if not (self.spawnflags & TSF_NO_AMMO_REGEN)
 680     if (self.ammo < self.ammo_max)
 681         self.ammo = min(self.ammo + self.ammo_recharge, self.ammo_max);
 682
 683     // Inactive turrets needs to run the think loop,
 684     // So they can handle animation and wake up if need be.
 685     if not (self.tur_active)
 686     {
 687         turret_stdproc_track();
 688         return;
 689     }
 690
 691     // This is typicaly used for zaping every target in range
 692     // turret_fusionreactor uses this to recharge friendlys.
 693     if (self.shoot_flags & TFL_SHOOT_HITALLVALID)
 694     {
 695         // Do a self.turret_fire for every valid target.
 696         e = findradius(self.origin,self.target_range);
 697         while (e)
 698         {
 699                         if(e.takedamage)
 700                         {
 701                                 if (turret_validate_target(self,e,self.target_validate_flags))
 702                                 {
 703                                         self.enemy = e;
 704
 705                                         turret_do_updates(self);
 706
 707                                         if (self.turret_firecheckfunc())
 708                                                 turret_fire();
 709                                 }
 710                         }
 711
 712             e = e.chain;
 713         }
 714         self.enemy = world;
 715     }
 716     else if(self.shoot_flags & TFL_SHOOT_CUSTOM)
 717     {
 718         // This one is doing something.. oddball. assume its handles what needs to be handled.
 719
 720         // Predict?
 721         if not(self.aim_flags & TFL_AIM_NO)
 722             self.tur_aimpos = turret_stdproc_aim_generic();
 723
 724         // Turn & pitch?
 725         if not(self.track_flags & TFL_TRACK_NO)
 726             turret_stdproc_track();
 727
 728         turret_do_updates(self);
 729
 730         // Fire?
 731         if (self.turret_firecheckfunc())
 732             turret_fire();
 733     }
 734     else
 735     {
 736         // Special case for volly always. if it fired once it must compleate the volly.
 737         if(self.shoot_flags & TFL_SHOOT_VOLLYALWAYS)
 738             if(self.volly_counter != self.shot_volly)
 739             {
 740                 // Predict or whatnot
 741                 if not(self.aim_flags & TFL_AIM_NO)
 742                     self.tur_aimpos = turret_stdproc_aim_generic();
 743
 744                 // Turn & pitch
 745                 if not(self.track_flags & TFL_TRACK_NO)
 746                     turret_stdproc_track();
 747
 748                 turret_do_updates(self);
 749
 750                 // Fire!
 751                 if (self.turret_firecheckfunc() != 0)
 752                     turret_fire();
 753
 754                 if(self.turret_postthink)
 755                     self.turret_postthink();
 756
 757                 return;
 758             }
 759
 760         // Check if we have a vailid enemy, and try to find one if we dont.
 761
 762         // g_turrets_targetscan_maxdelay forces a target re-scan at least this often
 763         float do_target_scan;
 764         if((self.target_select_time + autocvar_g_turrets_targetscan_maxdelay) < time)
 765             do_target_scan = 1;
 766
 767         // Old target (if any) invalid?
 768         if (turret_validate_target(self, self.enemy, self.target_validate_flags) <= 0)
 769         {
 770                 self.enemy = world;
 771                 do_target_scan = 1;
 772         }
 773
 774         // But never more often then g_turrets_targetscan_mindelay!
 775         if (self.target_select_time + autocvar_g_turrets_targetscan_mindelay > time)
 776             do_target_scan = 0;
 777
 778         if(do_target_scan)
 779         {
 780             self.enemy = turret_select_target();
 781             self.target_select_time = time;
 782         }
 783
 784         // No target, just go to idle, do any custom stuff and bail.
 785         if (self.enemy == world)
 786         {
 787             // Turn & pitch
 788             if not(self.track_flags & TFL_TRACK_NO)
 789                 turret_stdproc_track();
 790
 791             // do any per-turret stuff
 792             if(self.turret_postthink)
 793                 self.turret_postthink();
 794
 795             // And bail.
 796             return;
 797         }
 798         else
 799             self.lip = time + autocvar_g_turrets_aimidle_delay; // Keep track of the last time we had a target.
 800
 801         // Predict?
 802         if not(self.aim_flags & TFL_AIM_NO)
 803             self.tur_aimpos = turret_stdproc_aim_generic();
 804
 805         // Turn & pitch?
 806         if not(self.track_flags & TFL_TRACK_NO)
 807             turret_stdproc_track();
 808
 809         turret_do_updates(self);
 810
 811         // Fire?
 812         if (self.turret_firecheckfunc())
 813             turret_fire();
 814     }
 815
 816     // do any custom per-turret stuff
 817     if(self.turret_postthink)
 818         self.turret_postthink();
 819 }
 820
 821 void turret_fire()
 822 {
 823     if (autocvar_g_turrets_nofire != 0)
 824         return;
 825
 826     self.turret_firefunc();
 827
 828     self.attack_finished_single = time + self.shot_refire;
 829     self.ammo -= self.shot_dmg;
 830     self.volly_counter = self.volly_counter - 1;
 831
 832     if (self.volly_counter <= 0)
 833     {
 834         self.volly_counter = self.shot_volly;
 835
 836         if (self.shoot_flags & TFL_SHOOT_CLEARTARGET)
 837             self.enemy = world;
 838
 839         if (self.shot_volly > 1)
 840             self.attack_finished_single = time + self.shot_volly_refire;
 841     }
 842
 843 #ifdef TURRET_DEBUG
 844     if (self.enemy) paint_target3(self.tur_aimpos, 64, self.tur_dbg_rvec, self.tur_impacttime + 0.25);
 845 #endif
 846 }
 847
 848 void turret_stdproc_fire()
 849 {
 850     dprint("^1Bang, ^3your dead^7 ",self.enemy.netname,"! ^1(turret with no real firefunc)\n");
 851 }
 852
 853 /*
 854     When .used a turret switch team to activator.team.
 855     If activator is world, the turret go inactive.
 856 */
 857 void turret_stdproc_use()
 858 {
 859     dprint("Turret ",self.netname, " used by ", activator.classname, "\n");
 860
 861     self.team = activator.team;
 862
 863     if(self.team == 0)
 864         self.tur_active = 0;
 865     else
 866         self.tur_active = 1;
 867
 868 }
 869
 870 void turret_link()
 871 {
 872     Net_LinkEntity(self, TRUE, 0, turret_send);
 873     self.think      = turret_think;
 874     self.nextthink  = time;
 875     self.tur_head.effects = EF_NODRAW;
 876 }
 877
 878 void turrets_manager_think()
 879 {
 880     self.nextthink = time + 1;
 881
 882     entity e;
 883     if (autocvar_g_turrets_reloadcvars == 1)
 884     {
 885         e = nextent(world);
 886         while (e)
 887         {
 888             if (e.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 889             {
 890                 load_unit_settings(e,e.cvar_basename,1);
 891                 if(e.turret_postthink)
 892                     e.turret_postthink();
 893             }
 894
 895             e = nextent(e);
 896         }
 897         cvar_set("g_turrets_reloadcvars","0");
 898     }
 899 }
 900
 901 /*
 902 * Standard turret initialization. use this!
 903 * (unless you have a very good reason not to)
 904 * if the return value is 0, the turret should be removed.
 905 */
 906 float turret_stdproc_init (string cvar_base_name, string base, string head, float _turret_type)
 907 {
 908         entity e, ee;
 909
 910     // Are turrets allowed?
 911     if (autocvar_g_turrets == 0)
 912         return 0;
 913
 914     if(_turret_type < 1 || _turret_type > TID_LAST)
 915     {
 916         dprint("Invalid / Unkown turret type\"", ftos(_turret_type), "\", aborting!\n");
 917         return 0;
 918     }
 919     self.turret_type = _turret_type;
 920
 921     e = find(world, classname, "turret_manager");
 922     if not (e)
 923     {
 924         e = spawn();
 925
 926         /*
 927         setorigin(e,'0 0 0');
 928         setmodel(e,"models/turrets/plasma.md3");
 929         vector v;
 930         v = gettaginfo(e,gettagindex(e,"tag_fire"));
 931         if(v == '0 0 0')
 932         {
 933             //objerror("^1ERROR: Engine is borken! Turrets will NOT work. force g_turrets to 0 to run maps with turrets anyway.");
 934             //crash();
 935         }
 936         setmodel(e,"");
 937         */
 938
 939         e.classname = "turret_manager";
 940         e.think = turrets_manager_think;
 941         e.nextthink = time + 2;
 942     }
 943
 944     /*
 945     if(csqc_shared)
 946     {
 947         dprint("WARNING: turret requested csqc_shared but this is not implemented. Expect strange things to happen.\n");
 948         csqc_shared = 0;
 949     }
 950     */
 951
 952     if not (self.spawnflags & TSF_SUSPENDED)
 953         droptofloor_builtin();
 954
 955     // Terrainbase spawnflag. This puts a enlongated model
 956     // under the turret, so it looks ok on uneaven surfaces.
 957     /*  TODO: Handle this with CSQC
 958     if (self.spawnflags & TSF_TERRAINBASE)
 959     {
 960         entity tb;
 961         tb = spawn();
 962         setmodel(tb,"models/turrets/terrainbase.md3");
 963         setorigin(tb,self.origin);
 964         tb.solid = SOLID_BBOX;
 965     }
 966     */
 967
 968     self.cvar_basename = cvar_base_name;
 969     load_unit_settings(self, self.cvar_basename, 0);
 970
 971     // Handle turret teams.
 972     if (autocvar_g_assault != 0)
 973     {
 974         if not (self.team)
 975             self.team = 14; // Assume turrets are on the defending side if not explicitly set otehrwize
 976     }
 977     else if not (teamplay)
 978                 self.team = MAX_SHOT_DISTANCE; // Group all turrets into the same team, so they dont kill eachother.
 979         else if(g_onslaught && self.targetname)
 980         {
 981                 e = find(world,target,self.targetname);
 982                 if(e != world)
 983                 {
 984                         self.team = e.team;
 985                         ee = e;
 986                 }
 987         }
 988         else if(!self.team)
 989                 self.team = MAX_SHOT_DISTANCE; // Group all turrets into the same team, so they dont kill eachother.
 990
 991     /*
 992     * Try to guess some reasonaly defaults
 993     * for missing params and do sanety checks
 994     * thise checks could produce some "interesting" results
 995     * if it hits a glitch in my logic :P so try to set as mutch
 996     * as possible beforehand.
 997     */
 998     if (self.turrcaps_flags & TFL_TURRCAPS_SUPPORT)
 999         self.ticrate = 0.2;     // Support units generaly dont need to have a high speed ai-loop
1000     else
1001         self.ticrate = 0.1;     // 10 fps for normal turrets
1002
1003     self.ticrate = bound(sys_frametime, self.ticrate, 60);  // keep it sane
1004
1005 // General stuff
1006     if (self.netname == "")
1007         self.netname = self.classname;
1008
1009     if not (self.respawntime)
1010         self.respawntime = 60;
1011     self.respawntime = max(-1, self.respawntime);
1012
1013     if not (self.health)
1014         self.health = 1000;
1015     self.tur_health = max(1, self.health);
1016
1017     if not (self.turrcaps_flags)
1018         self.turrcaps_flags = TFL_TURRCAPS_RADIUSDMG | TFL_TURRCAPS_MEDPROJ | TFL_TURRCAPS_PLAYERKILL;
1019
1020     if not (self.damage_flags)
1021         self.damage_flags = TFL_DMG_YES | TFL_DMG_RETALIATE | TFL_DMG_AIMSHAKE;
1022
1023 // Shot stuff.
1024     if not (self.shot_refire)
1025         self.shot_refire = 1;
1026     self.shot_refire = bound(0.01, self.shot_refire, 9999);
1027
1028     if not (self.shot_dmg)
1029         self.shot_dmg  = self.shot_refire * 50;
1030     self.shot_dmg = max(1, self.shot_dmg);
1031
1032     if not (self.shot_radius)
1033         self.shot_radius = self.shot_dmg * 0.5;
1034     self.shot_radius = max(1, self.shot_radius);
1035
1036     if not (self.shot_speed)
1037         self.shot_speed = 2500;
1038     self.shot_speed = max(1, self.shot_speed);
1039
1040     if not (self.shot_spread)
1041         self.shot_spread = 0.0125;
1042     self.shot_spread = bound(0.0001, self.shot_spread, 500);
1043
1044     if not (self.shot_force)
1045         self.shot_force = self.shot_dmg * 0.5 + self.shot_radius * 0.5;
1046     self.shot_force = bound(0.001, self.shot_force, 5000);
1047
1048     if not (self.shot_volly)
1049         self.shot_volly = 1;
1050     self.shot_volly = bound(1, self.shot_volly, floor(self.ammo_max / self.shot_dmg));
1051
1052     if not (self.shot_volly_refire)
1053         self.shot_volly_refire = self.shot_refire * self.shot_volly;
1054     self.shot_volly_refire = bound(self.shot_refire, self.shot_volly_refire, 60);
1055
1056     if not (self.firecheck_flags)
1057         self.firecheck_flags = TFL_FIRECHECK_WORLD | TFL_FIRECHECK_DEAD | TFL_FIRECHECK_DISTANCES |
1058                                TFL_FIRECHECK_LOS | TFL_FIRECHECK_AIMDIST | TFL_FIRECHECK_TEAMCECK |
1059                                TFL_FIRECHECK_OWM_AMMO | TFL_FIRECHECK_REFIRE | TFL_FIRECHECK_WORLD;
1060
1061 // Range stuff.
1062     if not (self.target_range)
1063         self.target_range = self.shot_speed * 0.5;
1064     self.target_range = bound(0, self.target_range, MAX_SHOT_DISTANCE);
1065
1066     if not (self.target_range_min)
1067         self.target_range_min = self.shot_radius * 2;
1068     self.target_range_min = bound(0, self.target_range_min, MAX_SHOT_DISTANCE);
1069
1070     if not (self.target_range_optimal)
1071         self.target_range_optimal = self.target_range * 0.5;
1072     self.target_range_optimal = bound(0, self.target_range_optimal, MAX_SHOT_DISTANCE);
1073
1074
1075 // Aim stuff.
1076     if not (self.aim_maxrot)
1077         self.aim_maxrot = 90;
1078     self.aim_maxrot = bound(0, self.aim_maxrot, 360);
1079
1080     if not (self.aim_maxpitch)
1081         self.aim_maxpitch = 20;
1082     self.aim_maxpitch = bound(0, self.aim_maxpitch, 90);
1083
1084     if not (self.aim_speed)
1085         self.aim_speed = 36;
1086     self.aim_speed  = bound(0.1, self.aim_speed, 1000);
1087
1088     if not (self.aim_firetolerance_dist)
1089         self.aim_firetolerance_dist  = 5 + (self.shot_radius * 2);
1090     self.aim_firetolerance_dist = bound(0.1, self.aim_firetolerance_dist, MAX_SHOT_DISTANCE);
1091
1092     if not (self.aim_flags)
1093     {
1094         self.aim_flags = TFL_AIM_LEAD | TFL_AIM_SHOTTIMECOMPENSATE;
1095         if(self.turrcaps_flags & TFL_TURRCAPS_RADIUSDMG)
1096             self.aim_flags |= TFL_AIM_GROUND2;
1097     }
1098
1099     if not (self.track_type)
1100         self.track_type = TFL_TRACKTYPE_STEPMOTOR;
1101
1102     if (self.track_type != TFL_TRACKTYPE_STEPMOTOR)
1103     {
1104         // Fluid / Ineria mode. Looks mutch nicer.
1105         // Can reduce aim preformance alot, needs a bit diffrent aimspeed
1106
1107         if not (self.aim_speed)
1108             self.aim_speed = 180;
1109         self.aim_speed = bound(0.1, self.aim_speed, 1000);
1110
1111         if not (self.track_accel_pitch)
1112             self.track_accel_pitch = 0.5;
1113
1114         if not (self.track_accel_rot)
1115             self.track_accel_rot   = 0.5;
1116
1117         if not (self.track_blendrate)
1118             self.track_blendrate   = 0.35;
1119     }
1120
1121     if (!self.track_flags)
1122         self.track_flags = TFL_TRACK_PITCH | TFL_TRACK_ROT;
1123
1124
1125 // Target selection stuff.
1126     if not (self.target_select_rangebias)
1127         self.target_select_rangebias = 1;
1128     self.target_select_rangebias = bound(-10, self.target_select_rangebias, 10);
1129
1130     if not (self.target_select_samebias)
1131         self.target_select_samebias = 1;
1132     self.target_select_samebias = bound(-10, self.target_select_samebias, 10);
1133
1134     if not (self.target_select_anglebias)
1135         self.target_select_anglebias = 1;
1136     self.target_select_anglebias = bound(-10, self.target_select_anglebias, 10);
1137
1138     if not (self.target_select_missilebias)
1139         self.target_select_missilebias = -10;
1140
1141     self.target_select_missilebias = bound(-10, self.target_select_missilebias, 10);
1142     self.target_select_playerbias = bound(-10, self.target_select_playerbias, 10);
1143
1144     if not (self.target_select_flags)
1145     {
1146             self.target_select_flags = TFL_TARGETSELECT_LOS | TFL_TARGETSELECT_TEAMCHECK
1147                                      | TFL_TARGETSELECT_RANGELIMTS | TFL_TARGETSELECT_ANGLELIMITS;
1148
1149         if (self.turrcaps_flags & TFL_TURRCAPS_MISSILEKILL)
1150             self.target_select_flags |= TFL_TARGETSELECT_MISSILES;
1151
1152         if (self.turrcaps_flags & TFL_TURRCAPS_PLAYERKILL)
1153             self.target_select_flags |= TFL_TARGETSELECT_PLAYERS;
1154         //else
1155         //    self.target_select_flags = TFL_TARGETSELECT_NO;
1156     }
1157
1158     self.target_validate_flags = self.target_select_flags;
1159
1160 // Ammo stuff
1161     if not (self.ammo_max)
1162         self.ammo_max = self.shot_dmg * 10;
1163     self.ammo_max = max(self.shot_dmg, self.ammo_max);
1164
1165     if not (self.ammo)
1166         self.ammo = self.shot_dmg * 5;
1167     self.ammo = bound(0,self.ammo, self.ammo_max);
1168
1169     if not (self.ammo_recharge)
1170         self.ammo_recharge = self.shot_dmg * 0.5;
1171     self.ammo_recharge = max(0 ,self.ammo_recharge);
1172
1173     // Convert the recharge from X per sec to X per ticrate
1174     self.ammo_recharge = self.ammo_recharge * self.ticrate;
1175
1176     if not (self.ammo_flags)
1177         self.ammo_flags = TFL_AMMO_ENERGY | TFL_AMMO_RECHARGE;
1178
1179 // Damage stuff
1180     if(self.spawnflags & TSL_NO_RESPAWN)
1181         if not (self.damage_flags & TFL_DMG_DEATH_NORESPAWN)
1182             self.damage_flags |= TFL_DMG_DEATH_NORESPAWN;
1183
1184 // Offsets & origins
1185     if (!self.tur_shotorg)   self.tur_shotorg = '50 0 50';
1186
1187     if (!self.health)
1188         self.health = 150;
1189
1190 // Game hooks
1191         if(MUTATOR_CALLHOOK(TurretSpawn))
1192                 return 0;
1193
1194 // End of default & sanety checks, start building the turret.
1195
1196 // Spawn extra bits
1197     self.tur_head         = spawn();
1198     self.tur_head.netname = self.tur_head.classname = "turret_head";
1199     self.tur_head.team    = self.team;
1200     self.tur_head.owner   = self;
1201
1202     setmodel(self, base);
1203     setmodel(self.tur_head, head);
1204
1205     setsize(self, '-32 -32 0', '32 32 64');
1206     setsize(self.tur_head, '0 0 0', '0 0 0');
1207
1208     setorigin(self.tur_head, '0 0 0');
1209     setattachment(self.tur_head, self, "tag_head");
1210
1211     self.tur_health          = self.health;
1212     self.solid               = SOLID_BBOX;
1213     self.tur_head.solid      = SOLID_NOT;
1214     self.takedamage          = DAMAGE_AIM;
1215     self.tur_head.takedamage = DAMAGE_NO;
1216     self.movetype            = MOVETYPE_NOCLIP;
1217     self.tur_head.movetype   = MOVETYPE_NOCLIP;
1218
1219     // Defend mode?
1220     if not (self.tur_defend)
1221     if (self.target != "")
1222     {
1223         self.tur_defend = find(world, targetname, self.target);
1224         if (self.tur_defend == world)
1225         {
1226             self.target = "";
1227             dprint("Turret has invalid defendpoint!\n");
1228         }
1229     }
1230
1231     // In target defend mode, aim on the spot to defend when idle.
1232     if (self.tur_defend)
1233         self.idle_aim  = self.tur_head.angles + angleofs(self.tur_head, self.tur_defend);
1234     else
1235         self.idle_aim  = '0 0 0';
1236
1237     // Attach stdprocs. override when and what needed
1238     self.turret_firecheckfunc   = turret_stdproc_firecheck;
1239     self.turret_firefunc        = turret_stdproc_fire;
1240     self.event_damage           = turret_stdproc_damage;
1241
1242     if (self.turrcaps_flags & TFL_TURRCAPS_SUPPORT)
1243         self.turret_score_target    = turret_stdproc_targetscore_support;
1244     else
1245         self.turret_score_target    = turret_stdproc_targetscore_generic;
1246
1247     self.use = turret_stdproc_use;
1248     self.bot_attack = TRUE;
1249
1250     ++turret_count;
1251     self.nextthink = time + 1;
1252     self.nextthink +=  turret_count * sys_frametime;
1253
1254     self.tur_head.team = self.team;
1255     self.view_ofs = '0 0 0';
1256
1257 #ifdef TURRET_DEBUG
1258     self.tur_dbg_start = self.nextthink;
1259     while (vlen(self.tur_dbg_rvec) < 2)
1260         self.tur_dbg_rvec  = randomvec() * 4;
1261
1262     self.tur_dbg_rvec_x = fabs(self.tur_dbg_rvec_x);
1263     self.tur_dbg_rvec_y = fabs(self.tur_dbg_rvec_y);
1264     self.tur_dbg_rvec_z = fabs(self.tur_dbg_rvec_z);
1265 #endif
1266
1267     // Its all good.
1268     self.turrcaps_flags |= TFL_TURRCAPS_ISTURRET;
1269
1270     self.classname = "turret_main";
1271
1272     self.tur_active = 1;
1273
1274     // In ONS mode, and linked to a ONS ent. need to call the use to set team.
1275     if (g_onslaught && ee)
1276     {
1277         activator = ee;
1278         self.use();
1279     }
1280
1281         turret_stdproc_respawn();
1282
1283     if (!turret_tag_fire_update())
1284         dprint("Warning: Turret ",self.classname, " faild to initialize md3 tags\n");
1285
1286     return 1;
1287 }
1288
1289