qcsrc/server/teamplay.qc

   1 string cache_mutatormsg;
   2 string cache_lastmutatormsg;
   3
   4 // client counts for each team
   5 float c1, c2, c3, c4;
   6 // # of bots on those teams
   7 float cb1, cb2, cb3, cb4;
   8
   9 float audit_teams_time;
  10
  11 float IsTeamBalanceForced()
  12 {
  13         if(intermission_running)
  14                 return 0; // no rebalancing whatsoever please
  15         if(!teamplay)
  16                 return 0;
  17         if(autocvar_g_campaign)
  18                 return 0;
  19         if(autocvar_bot_vs_human && (c3==-1 && c4==-1))
  20                 return 0;
  21         if(!autocvar_g_balance_teams_force)
  22                 return -1;
  23         return 1;
  24 }
  25
  26 void TeamchangeFrags(entity e)
  27 {
  28         PlayerScore_Clear(e);
  29 }
  30
  31 vector TeamColor(float teem)
  32 {
  33         switch(teem)
  34         {
  35                 case COLOR_TEAM1:
  36                         return '1 0.0625 0.0625';
  37                 case COLOR_TEAM2:
  38                         return '0.0625 0.0625 1';
  39                 case COLOR_TEAM3:
  40                         return '1 1 0.0625';
  41                 case COLOR_TEAM4:
  42                         return '1 0.0625 1';
  43                 default:
  44                         return '1 1 1';
  45         }
  46 }
  47
  48 string TeamName(float t)
  49 {
  50         return strcat(Team_ColorName(t), " Team");
  51 }
  52 string ColoredTeamName(float t)
  53 {
  54         return strcat(Team_ColorCode(t), Team_ColorName(t), " Team^7");
  55 }
  56 string TeamNoName(float t)
  57 {
  58         // fixme: Search for team entities and get their .netname's!
  59         if(t == 1)
  60                 return "Red Team";
  61         if(t == 2)
  62                 return "Blue Team";
  63         if(t == 3)
  64                 return "Yellow Team";
  65         if(t == 4)
  66                 return "Pink Team";
  67         return "Neutral Team";
  68 }
  69
  70 void dom_init();
  71 void ctf_init();
  72 void runematch_init();
  73 void tdm_init();
  74 void entcs_init();
  75
  76 void LogTeamchange(float player_id, float team_number, float type)
  77 {
  78         if(!autocvar_sv_eventlog)
  79                 return;
  80
  81         if(player_id < 1)
  82                 return;
  83
  84         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
  85 }
  86
  87 void default_delayedinit()
  88 {
  89         if(!scores_initialized)
  90                 ScoreRules_generic();
  91 }
  92
  93 void ActivateTeamplay()
  94 {
  95         serverflags |= SERVERFLAG_TEAMPLAY;
  96         teamplay = 1;
  97 }
  98
  99 void InitGameplayMode()
 100 {
 101         float fraglimit_override, timelimit_override, leadlimit_override, qualifying_override;
 102
 103         qualifying_override = -1;
 104
 105         VoteReset();
 106
 107         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 108         get_mi_min_max(1);
 109         world.mins = mi_min;
 110         world.maxs = mi_max;
 111
 112         MapInfo_LoadMapSettings(mapname);
 113         teamplay = 0;
 114         serverflags &~= SERVERFLAG_TEAMPLAY;
 115
 116         if not(cvar_value_issafe(world.fog))
 117         {
 118                 print("The current map contains a potentially harmful fog setting, ignored\n");
 119                 world.fog = string_null;
 120         }
 121         if(MapInfo_Map_fog != "")
 122                 if(MapInfo_Map_fog == "none")
 123                         world.fog = string_null;
 124                 else
 125                         world.fog = strzone(MapInfo_Map_fog);
 126         clientstuff = strzone(MapInfo_Map_clientstuff);
 127
 128         MapInfo_ClearTemps();
 129
 130         // set both here, gamemode can override it later
 131         timelimit_override = autocvar_timelimit_override;
 132         fraglimit_override = autocvar_fraglimit_override;
 133         leadlimit_override = autocvar_leadlimit_override;
 134         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
 135
 136         if(g_dm)
 137         {
 138         }
 139
 140         if(g_tdm)
 141         {
 142                 ActivateTeamplay();
 143                 tdm_init();
 144                 if(autocvar_g_tdm_team_spawns)
 145                         have_team_spawns = -1; // request team spawns
 146         }
 147
 148         if(g_domination)
 149         {
 150                 ActivateTeamplay();
 151                 fraglimit_override = autocvar_g_domination_point_limit;
 152                 leadlimit_override = autocvar_g_domination_point_leadlimit;
 153                 dom_init();
 154                 have_team_spawns = -1; // request team spawns
 155         }
 156
 157         if(g_ctf)
 158         {
 159                 ActivateTeamplay();
 160                 g_ctf_ignore_frags = autocvar_g_ctf_ignore_frags;
 161                 fraglimit_override = autocvar_capturelimit_override;
 162                 leadlimit_override = autocvar_captureleadlimit_override;
 163                 ctf_init();
 164                 have_team_spawns = -1; // request team spawns
 165         }
 166
 167         if(g_runematch)
 168         {
 169                 // ActivateTeamplay();
 170                 fraglimit_override = autocvar_g_runematch_point_limit;
 171                 leadlimit_override = autocvar_g_runematch_point_leadlimit;
 172                 runematch_init();
 173         }
 174
 175         if(g_lms)
 176         {
 177                 fraglimit_override = autocvar_g_lms_lives_override;
 178                 leadlimit_override = 0; // not supported by LMS
 179                 if(fraglimit_override == 0)
 180                         fraglimit_override = -1;
 181                 lms_lowest_lives = 9999;
 182                 lms_next_place = 0;
 183                 ScoreRules_lms();
 184         }
 185
 186         if(g_arena)
 187         {
 188                 fraglimit_override = autocvar_g_arena_point_limit;
 189                 leadlimit_override = autocvar_g_arena_point_leadlimit;
 190                 maxspawned = autocvar_g_arena_maxspawned;
 191                 if(maxspawned < 2)
 192                         maxspawned = 2;
 193                 arena_roundbased = autocvar_g_arena_roundbased;
 194         }
 195
 196         if(g_ca)
 197         {
 198                 ActivateTeamplay();
 199                 fraglimit_override = autocvar_g_ca_point_limit;
 200                 leadlimit_override = autocvar_g_ca_point_leadlimit;
 201                 precache_sound("ctf/red_capture.wav");
 202                 precache_sound("ctf/blue_capture.wav");
 203         }
 204         if(g_keyhunt)
 205         {
 206                 ActivateTeamplay();
 207                 fraglimit_override = autocvar_g_keyhunt_point_limit;
 208                 leadlimit_override = autocvar_g_keyhunt_point_leadlimit;
 209                 MUTATOR_ADD(gamemode_keyhunt);
 210         }
 211
 212         if(g_freezetag)
 213         {
 214                 ActivateTeamplay();
 215                 fraglimit_override = autocvar_g_freezetag_point_limit;
 216                 leadlimit_override = autocvar_g_freezetag_point_leadlimit;
 217                 MUTATOR_ADD(gamemode_freezetag);
 218         }
 219
 220         if(g_assault)
 221         {
 222                 ActivateTeamplay();
 223                 ScoreRules_assault();
 224                 have_team_spawns = -1; // request team spawns
 225         }
 226
 227         if(g_onslaught)
 228         {
 229                 ActivateTeamplay();
 230                 have_team_spawns = -1; // request team spawns
 231         }
 232
 233         if(g_race)
 234         {
 235
 236                 if(autocvar_g_race_teams)
 237                 {
 238                         ActivateTeamplay();
 239                         race_teams = bound(2, autocvar_g_race_teams, 4);
 240                         have_team_spawns = -1; // request team spawns
 241                 }
 242                 else
 243                         race_teams = 0;
 244
 245                 qualifying_override = autocvar_g_race_qualifying_timelimit_override;
 246                 fraglimit_override = autocvar_g_race_laps_limit;
 247                 leadlimit_override = 0; // currently not supported by race
 248         }
 249
 250         if(g_cts)
 251         {
 252                 g_race_qualifying = 1;
 253                 fraglimit_override = 0;
 254                 leadlimit_override = 0;
 255         }
 256
 257         if(g_nexball)
 258         {
 259         fraglimit_override = autocvar_g_nexball_goallimit;
 260         leadlimit_override = autocvar_g_nexball_goalleadlimit;
 261         ActivateTeamplay();
 262         have_team_spawns = -1; // request team spawns
 263             MUTATOR_ADD(gamemode_nexball);
 264         }
 265
 266         if(g_keepaway)
 267         {
 268                 MUTATOR_ADD(gamemode_keepaway);
 269         }
 270
 271         if(teamplay)
 272                 entcs_init();
 273
 274         cache_mutatormsg = strzone("");
 275         cache_lastmutatormsg = strzone("");
 276
 277         // enforce the server's universal frag/time limits
 278         if(!autocvar_g_campaign)
 279         {
 280                 if(fraglimit_override >= 0)
 281                         cvar_set("fraglimit", ftos(fraglimit_override));
 282                 if(timelimit_override >= 0)
 283                         cvar_set("timelimit", ftos(timelimit_override));
 284                 if(leadlimit_override >= 0)
 285                         cvar_set("leadlimit", ftos(leadlimit_override));
 286                 if(qualifying_override >= 0)
 287                         cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 288         }
 289
 290         if(g_race)
 291         {
 292                 // we need to find out the correct value for g_race_qualifying
 293                 if(autocvar_g_campaign)
 294                 {
 295                         g_race_qualifying = 1;
 296                 }
 297                 else if(!autocvar_g_campaign && autocvar_g_race_qualifying_timelimit > 0)
 298                 {
 299                         g_race_qualifying = 2;
 300                         race_fraglimit = autocvar_fraglimit;
 301                         race_leadlimit = autocvar_leadlimit;
 302                         race_timelimit = autocvar_timelimit;
 303                         cvar_set("fraglimit", "0");
 304                         cvar_set("leadlimit", "0");
 305                         cvar_set("timelimit", ftos(autocvar_g_race_qualifying_timelimit));
 306                 }
 307                 else
 308                         g_race_qualifying = 0;
 309         }
 310
 311         if(g_race || g_cts)
 312         {
 313                 if(g_race_qualifying)
 314                         independent_players = 1;
 315
 316                 ScoreRules_race();
 317         }
 318
 319         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 320 }
 321
 322 string GetClientVersionMessage() {
 323         string versionmsg;
 324         if (self.version_mismatch) {
 325                 if(self.version < autocvar_gameversion) {
 326                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
 327                 } else {
 328                         versionmsg = "^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
 329                 }
 330         } else {
 331                 versionmsg = "^2client version and server version are compatible.^8";
 332         }
 333         return versionmsg;
 334 }
 335
 336 string getwelcomemessage(void)
 337 {
 338         string s, modifications, motd;
 339
 340         ret_string = "";
 341         MUTATOR_CALLHOOK(BuildMutatorsPrettyString);
 342         modifications = ret_string;
 343
 344         if(g_minstagib)
 345                 modifications = strcat(modifications, ", MinstaGib");
 346         if(g_weaponarena)
 347         {
 348                 if(g_weaponarena_random)
 349                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
 350                 else
 351                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 352         }
 353         if(autocvar_g_start_weapon_laser == 0)
 354                 modifications = strcat(modifications, ", No start weapons");
 355         if(autocvar_sv_gravity < 800)
 356                 modifications = strcat(modifications, ", Low gravity");
 357         if(g_cloaked && !g_cts)
 358                 modifications = strcat(modifications, ", Cloaked");
 359         if(g_grappling_hook)
 360                 modifications = strcat(modifications, ", Hook");
 361         if(g_midair)
 362                 modifications = strcat(modifications, ", Midair");
 363         if(g_pinata)
 364                 modifications = strcat(modifications, ", Piñata");
 365         if(g_weapon_stay && !g_cts)
 366                 modifications = strcat(modifications, ", Weapons stay");
 367         if(g_bloodloss > 0)
 368                 modifications = strcat(modifications, ", Blood loss");
 369         if(g_jetpack)
 370                 modifications = strcat(modifications, ", Jet pack");
 371         if(autocvar_g_powerups == 0)
 372                 modifications = strcat(modifications, ", No powerups");
 373         if(autocvar_g_powerups > 0)
 374                 modifications = strcat(modifications, ", Powerups");
 375         modifications = substring(modifications, 2, strlen(modifications) - 2);
 376
 377         string versionmessage;
 378         versionmessage = GetClientVersionMessage();
 379
 380         s = strcat("This is Xonotic ", autocvar_g_xonoticversion, "\n", versionmessage);
 381         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 382
 383         if(modifications != "")
 384                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 385
 386         if (g_grappling_hook)
 387                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
 388
 389         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
 390         {
 391                 if(cache_lastmutatormsg)
 392                         strunzone(cache_lastmutatormsg);
 393                 if(cache_mutatormsg)
 394                         strunzone(cache_mutatormsg);
 395                 cache_lastmutatormsg = strzone(autocvar_g_mutatormsg);
 396                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 397         }
 398
 399         if (cache_mutatormsg != "") {
 400                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 401         }
 402
 403         motd = autocvar_sv_motd;
 404         if (motd != "") {
 405                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 406         }
 407         return s;
 408 }
 409
 410 void SetPlayerColors(entity pl, float _color)
 411 {
 412         /*string s;
 413         s = ftos(cl);
 414         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 415         pl.team = cl + 1;
 416         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 417         pl.clientcolors = 16*cl + cl;*/
 418
 419         float pants, shirt;
 420         pants = _color & 0x0F;
 421         shirt = _color & 0xF0;
 422
 423
 424         if(teamplay) {
 425                 setcolor(pl, 16*pants + pants);
 426         } else {
 427                 setcolor(pl, shirt + pants);
 428         }
 429 }
 430
 431 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 432 {
 433         float _color;
 434
 435         if(t == 4)
 436                 _color = COLOR_TEAM4 - 1;
 437         else if(t == 3)
 438                 _color = COLOR_TEAM3 - 1;
 439         else if(t == 2)
 440                 _color = COLOR_TEAM2 - 1;
 441         else
 442                 _color = COLOR_TEAM1 - 1;
 443
 444         SetPlayerColors(pl,_color);
 445
 446         if(t != s) {
 447                 LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
 448
 449                 if(!noprint)
 450                 bprint(pl.netname, "^7 has changed from ", TeamNoName(s), " to ", TeamNoName(t), "\n");
 451         }
 452
 453 }
 454
 455 // set c1...c4 to show what teams are allowed
 456 void CheckAllowedTeams (entity for_whom)
 457 {
 458         float dm;
 459         entity head;
 460         string teament_name;
 461
 462         c1 = c2 = c3 = c4 = -1;
 463         cb1 = cb2 = cb3 = cb4 = 0;
 464
 465         teament_name = string_null;
 466         if(g_onslaught)
 467         {
 468                 // onslaught is special
 469                 head = findchain(classname, "onslaught_generator");
 470                 while (head)
 471                 {
 472                         if (head.team == COLOR_TEAM1) c1 = 0;
 473                         if (head.team == COLOR_TEAM2) c2 = 0;
 474                         if (head.team == COLOR_TEAM3) c3 = 0;
 475                         if (head.team == COLOR_TEAM4) c4 = 0;
 476                         head = head.chain;
 477                 }
 478         }
 479         else if(g_domination)
 480                 teament_name = "dom_team";
 481         else if(g_ctf)
 482                 teament_name = "ctf_team";
 483         else if(g_tdm)
 484                 teament_name = "tdm_team";
 485         else if(g_nexball)
 486                 teament_name = "nexball_team";
 487         else if(g_assault)
 488                 c1 = c2 = 0; // Assault always has 2 teams
 489         else
 490         {
 491                 // cover anything else by treating it like tdm with no teams spawned
 492                 if(g_race)
 493                         dm = race_teams;
 494                 else
 495                         dm = 2;
 496
 497                 ret_float = dm;
 498                 MUTATOR_CALLHOOK(GetTeamCount);
 499                 dm = ret_float;
 500
 501                 if(dm >= 4)
 502                         c1 = c2 = c3 = c4 = 0;
 503                 else if(dm >= 3)
 504                         c1 = c2 = c3 = 0;
 505                 else
 506                         c1 = c2 = 0;
 507         }
 508
 509         // find out what teams are allowed if necessary
 510         if(teament_name)
 511         {
 512                 head = find(world, classname, teament_name);
 513                 while(head)
 514                 {
 515                         if(!(g_domination && head.netname == ""))
 516                         {
 517                                 if(head.team == COLOR_TEAM1)
 518                                         c1 = 0;
 519                                 else if(head.team == COLOR_TEAM2)
 520                                         c2 = 0;
 521                                 else if(head.team == COLOR_TEAM3)
 522                                         c3 = 0;
 523                                 else if(head.team == COLOR_TEAM4)
 524                                         c4 = 0;
 525                         }
 526                         head = find(head, classname, teament_name);
 527                 }
 528         }
 529
 530         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
 531         if(c3==-1 && c4==-1)
 532         if(autocvar_bot_vs_human && for_whom)
 533         {
 534                 if(autocvar_bot_vs_human > 0)
 535                 {
 536                         // bots are all blue
 537                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 538                                 c1 = c3 = c4 = -1;
 539                         else
 540                                 c2 = -1;
 541                 }
 542                 else
 543                 {
 544                         // bots are all red
 545                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 546                                 c2 = c3 = c4 = -1;
 547                         else
 548                                 c1 = -1;
 549                 }
 550         }
 551
 552         // if player has a forced team, ONLY allow that one
 553         if(self.team_forced == COLOR_TEAM1 && c1 >= 0)
 554                 c2 = c3 = c4 = -1;
 555         else if(self.team_forced == COLOR_TEAM2 && c2 >= 0)
 556                 c1 = c3 = c4 = -1;
 557         else if(self.team_forced == COLOR_TEAM3 && c3 >= 0)
 558                 c1 = c2 = c4 = -1;
 559         else if(self.team_forced == COLOR_TEAM4 && c4 >= 0)
 560                 c1 = c2 = c3 = -1;
 561 }
 562
 563 float PlayerValue(entity p)
 564 {
 565         if(IsTeamBalanceForced() == 1)
 566                 return 1;
 567         return 1;
 568         // FIXME: it always returns 1...
 569 }
 570
 571 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 572 // teams that are allowed will now have their player counts stored in c1...c4
 573 void GetTeamCounts(entity ignore)
 574 {
 575         entity head;
 576         float value, bvalue;
 577         // now count how many players are on each team already
 578
 579         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 580         // also remember the lowest-scoring player
 581
 582         FOR_EACH_CLIENT(head)
 583         {
 584                 float t;
 585                 if(head.classname == "player")
 586                         t = head.team;
 587                 else if(head.team_forced > 0)
 588                         t = head.team_forced; // reserve the spot
 589                 else
 590                         continue;
 591                 if(head != ignore)// && head.netname != "")
 592                 {
 593                         value = PlayerValue(head);
 594                         if(clienttype(head) == CLIENTTYPE_BOT)
 595                                 bvalue = value;
 596                         else
 597                                 bvalue = 0;
 598                         if(t == COLOR_TEAM1)
 599                         {
 600                                 if(c1 >= 0)
 601                                 {
 602                                         c1 = c1 + value;
 603                                         cb1 = cb1 + bvalue;
 604                                 }
 605                         }
 606                         if(t == COLOR_TEAM2)
 607                         {
 608                                 if(c2 >= 0)
 609                                 {
 610                                         c2 = c2 + value;
 611                                         cb2 = cb2 + bvalue;
 612                                 }
 613                         }
 614                         if(t == COLOR_TEAM3)
 615                         {
 616                                 if(c3 >= 0)
 617                                 {
 618                                         c3 = c3 + value;
 619                                         cb3 = cb3 + bvalue;
 620                                 }
 621                         }
 622                         if(t == COLOR_TEAM4)
 623                         {
 624                                 if(c4 >= 0)
 625                                 {
 626                                         c4 = c4 + value;
 627                                         cb4 = cb4 + bvalue;
 628                                 }
 629                         }
 630                 }
 631         }
 632
 633         // if the player who has a forced team has not joined yet, reserve the spot
 634         if(autocvar_g_campaign)
 635         {
 636                 switch(autocvar_g_campaign_forceteam)
 637                 {
 638                         case 1: if(c1 == cb1) ++c1; break;
 639                         case 2: if(c2 == cb2) ++c2; break;
 640                         case 3: if(c3 == cb3) ++c3; break;
 641                         case 4: if(c4 == cb4) ++c4; break;
 642                 }
 643         }
 644 }
 645
 646 // returns # of smallest team (1, 2, 3, 4)
 647 // NOTE: Assumes CheckAllowedTeams has already been called!
 648 float FindSmallestTeam(entity pl, float ignore_pl)
 649 {
 650         float totalteams, balance_type, maxc;
 651         totalteams = 0;
 652
 653         // find out what teams are available
 654         //CheckAllowedTeams();
 655
 656         // make sure there are at least 2 teams to join
 657         if(c1 >= 0)
 658                 totalteams = totalteams + 1;
 659         if(c2 >= 0)
 660                 totalteams = totalteams + 1;
 661         if(c3 >= 0)
 662                 totalteams = totalteams + 1;
 663         if(c4 >= 0)
 664                 totalteams = totalteams + 1;
 665
 666         if((autocvar_bot_vs_human || pl.team_forced > 0) && totalteams == 1)
 667                 totalteams += 1;
 668
 669         if(totalteams <= 1)
 670         {
 671                 if(autocvar_g_campaign && pl && clienttype(pl) == CLIENTTYPE_REAL)
 672                         return 1; // special case for campaign and player joining
 673                 else if(g_domination)
 674                         error("Too few teams available for domination\n");
 675                 else if(g_ctf)
 676                         error("Too few teams available for ctf\n");
 677                 else if(g_keyhunt)
 678                         error("Too few teams available for key hunt\n");
 679                 else if(g_freezetag)
 680                         error("Too few teams available for freeze tag\n");
 681                 else
 682                         error("Too few teams available for team deathmatch\n");
 683         }
 684
 685         // count how many players are in each team
 686         if(ignore_pl)
 687                 GetTeamCounts(pl);
 688         else
 689                 GetTeamCounts(world);
 690
 691         // c1...c4 now have counts of each team
 692         // figure out which is smallest, giving priority to the team the player is already on as a tie-breaker
 693
 694         // 2 gives priority to what team you're already on, 1 goes in order
 695         // 2 doesn't seem to work though...
 696         balance_type = 1;
 697
 698         if(bots_would_leave)
 699         //if(pl.classname != "player")
 700         if(clienttype(pl) != CLIENTTYPE_BOT)
 701         {
 702                 c1 -= cb1 * 255.0/256.0;
 703                 c2 -= cb2 * 255.0/256.0;
 704                 c3 -= cb3 * 255.0/256.0;
 705                 c4 -= cb4 * 255.0/256.0;
 706         }
 707         maxc = max4(c1, c2, c3, c4);
 708
 709         RandomSelection_Init();
 710         if(balance_type == 1)
 711         {
 712                 // 1: use team count, then score (note: can only use 8 significant bits of score)
 713                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + float2range01(-team1_score) / 256.0);
 714                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c2) + float2range01(-team2_score) / 256.0);
 715                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c3) + float2range01(-team3_score) / 256.0);
 716                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c4) + float2range01(-team4_score) / 256.0);
 717         }
 718         else if(balance_type == 2)
 719         {
 720                 // 1: use team count, if equal prefer own team
 721                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM1) / 512.0);
 722                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM2) / 512.0);
 723                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM3) / 512.0);
 724                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM4) / 512.0);
 725         }
 726         else if(balance_type == 3)
 727         {
 728                 // 1: use team count, then score, if equal prefer own team (probably fails due to float accuracy problems)
 729                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + float2range01(-team1_score + 0.5 * (self.team == COLOR_TEAM1)) / 256.0);
 730                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c2) + float2range01(-team2_score + 0.5 * (self.team == COLOR_TEAM2)) / 256.0);
 731                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c3) + float2range01(-team3_score + 0.5 * (self.team == COLOR_TEAM3)) / 256.0);
 732                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c4) + float2range01(-team4_score + 0.5 * (self.team == COLOR_TEAM4)) / 256.0);
 733         }
 734         return RandomSelection_chosen_float;
 735 }
 736
 737 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
 738 {
 739         float smallest, selectedteam;
 740
 741         // don't join a team if we're not playing a team game
 742         if(!teamplay)
 743                 return 0;
 744
 745         // find out what teams are available
 746         CheckAllowedTeams(pl);
 747
 748         // if we don't care what team he ends up on, put him on whatever team he entered as.
 749         // if he's not on a valid team, then let other code put him on the smallest team
 750         if(!forcebestteam)
 751         {
 752                 if(     c1 >= 0 && pl.team == COLOR_TEAM1)
 753                         selectedteam = pl.team;
 754                 else if(c2 >= 0 && pl.team == COLOR_TEAM2)
 755                         selectedteam = pl.team;
 756                 else if(c3 >= 0 && pl.team == COLOR_TEAM3)
 757                         selectedteam = pl.team;
 758                 else if(c4 >= 0 && pl.team == COLOR_TEAM4)
 759                         selectedteam = pl.team;
 760                 else
 761                         selectedteam = -1;
 762
 763                 if(selectedteam > 0)
 764                 {
 765                         if(!only_return_best)
 766                         {
 767                                 SetPlayerColors(pl, selectedteam - 1);
 768
 769                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
 770                                 // when JoinBestTeam is called by cl_client.qc/ClientConnect the player_id is 0 the log attempt is rejected
 771                                 LogTeamchange(pl.playerid, pl.team, 99);
 772                         }
 773                         return selectedteam;
 774                 }
 775                 // otherwise end up on the smallest team (handled below)
 776         }
 777
 778         smallest = FindSmallestTeam(pl, TRUE);
 779
 780         if(!only_return_best && !pl.bot_forced_team)
 781         {
 782                 TeamchangeFrags(self);
 783                 if(smallest == 1)
 784                 {
 785                         SetPlayerColors(pl, COLOR_TEAM1 - 1);
 786                 }
 787                 else if(smallest == 2)
 788                 {
 789                         SetPlayerColors(pl, COLOR_TEAM2 - 1);
 790                 }
 791                 else if(smallest == 3)
 792                 {
 793                         SetPlayerColors(pl, COLOR_TEAM3 - 1);
 794                 }
 795                 else if(smallest == 4)
 796                 {
 797                         SetPlayerColors(pl, COLOR_TEAM4 - 1);
 798                 }
 799                 else
 800                 {
 801                         error("smallest team: invalid team\n");
 802                 }
 803
 804                 LogTeamchange(pl.playerid, pl.team, 2); // log auto join
 805
 806                 if(pl.deadflag == DEAD_NO)
 807                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
 808         }
 809
 810         return smallest;
 811 }
 812
 813 //void() ctf_playerchanged;
 814 void SV_ChangeTeam(float _color)
 815 {
 816         float scolor, dcolor, steam, dteam, dbotcount, scount, dcount;
 817
 818         // in normal deathmatch we can just apply the color and we're done
 819         if(!teamplay) {
 820                 SetPlayerColors(self, _color);
 821                 return;
 822         }
 823
 824         scolor = self.clientcolors & 0x0F;
 825         dcolor = _color & 0x0F;
 826
 827         if(scolor == COLOR_TEAM1 - 1)
 828                 steam = 1;
 829         else if(scolor == COLOR_TEAM2 - 1)
 830                 steam = 2;
 831         else if(scolor == COLOR_TEAM3 - 1)
 832                 steam = 3;
 833         else // if(scolor == COLOR_TEAM4 - 1)
 834                 steam = 4;
 835         if(dcolor == COLOR_TEAM1 - 1)
 836                 dteam = 1;
 837         else if(dcolor == COLOR_TEAM2 - 1)
 838                 dteam = 2;
 839         else if(dcolor == COLOR_TEAM3 - 1)
 840                 dteam = 3;
 841         else // if(dcolor == COLOR_TEAM4 - 1)
 842                 dteam = 4;
 843
 844         CheckAllowedTeams(self);
 845
 846         if(dteam == 1 && c1 < 0) dteam = 4;
 847         if(dteam == 4 && c4 < 0) dteam = 3;
 848         if(dteam == 3 && c3 < 0) dteam = 2;
 849         if(dteam == 2 && c2 < 0) dteam = 1;
 850
 851         // not changing teams
 852         if(scolor == dcolor)
 853         {
 854                 //bprint("same team change\n");
 855                 SetPlayerTeam(self, dteam, steam, TRUE);
 856                 return;
 857         }
 858
 859         if((autocvar_g_campaign) || (autocvar_g_changeteam_banned && self.wasplayer)) {
 860                 sprint(self, "Team changes not allowed\n");
 861                 return; // changing teams is not allowed
 862         }
 863
 864         if(autocvar_g_balance_teams_prevent_imbalance)
 865         {
 866                 t = FindSmallestTeam(self, TRUE);
 867                 if(dteam != t)
 868                 {
 869                         sprint(self, "Cannot change to the given team\n");
 870                         return;
 871                 }
 872         }
 873
 874 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
 875
 876         if(self.classname == "player" && steam != dteam)
 877         {
 878                 // reduce frags during a team change
 879                 TeamchangeFrags(self);
 880         }
 881
 882         SetPlayerTeam(self, dteam, steam, FALSE);
 883
 884         if(self.classname == "player" && steam != dteam)
 885         {
 886                 // kill player when changing teams
 887                 if(self.deadflag == DEAD_NO)
 888                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
 889         }
 890         //ctf_playerchanged();
 891 }
 892
 893 void ShufflePlayerOutOfTeam (float source_team)
 894 {
 895         float smallestteam, smallestteam_count, steam;
 896         float lowest_bot_score, lowest_player_score;
 897         entity head, lowest_bot, lowest_player, selected;
 898
 899         smallestteam = 0;
 900         smallestteam_count = 999999999;
 901
 902         if(c1 >= 0 && c1 < smallestteam_count)
 903         {
 904                 smallestteam = 1;
 905                 smallestteam_count = c1;
 906         }
 907         if(c2 >= 0 && c2 < smallestteam_count)
 908         {
 909                 smallestteam = 2;
 910                 smallestteam_count = c2;
 911         }
 912         if(c3 >= 0 && c3 < smallestteam_count)
 913         {
 914                 smallestteam = 3;
 915                 smallestteam_count = c3;
 916         }
 917         if(c4 >= 0 && c4 < smallestteam_count)
 918         {
 919                 smallestteam = 4;
 920                 smallestteam_count = c4;
 921         }
 922
 923         if(!smallestteam)
 924         {
 925                 bprint("warning: no smallest team\n");
 926                 return;
 927         }
 928
 929         if(source_team == 1)
 930                 steam = COLOR_TEAM1;
 931         else if(source_team == 2)
 932                 steam = COLOR_TEAM2;
 933         else if(source_team == 3)
 934                 steam = COLOR_TEAM3;
 935         else // if(source_team == 4)
 936                 steam = COLOR_TEAM4;
 937
 938         lowest_bot = world;
 939         lowest_bot_score = 999999999;
 940         lowest_player = world;
 941         lowest_player_score = 999999999;
 942
 943         // find the lowest-scoring player & bot of that team
 944         FOR_EACH_PLAYER(head)
 945         {
 946                 if(head.team == steam)
 947                 {
 948                         if(head.isbot)
 949                         {
 950                                 if(head.totalfrags < lowest_bot_score)
 951                                 {
 952                                         lowest_bot = head;
 953                                         lowest_bot_score = head.totalfrags;
 954                                 }
 955                         }
 956                         else
 957                         {
 958                                 if(head.totalfrags < lowest_player_score)
 959                                 {
 960                                         lowest_player = head;
 961                                         lowest_player_score = head.totalfrags;
 962                                 }
 963                         }
 964                 }
 965         }
 966
 967         // prefers to move a bot...
 968         if(lowest_bot != world)
 969                 selected = lowest_bot;
 970         // but it will move a player if it has to
 971         else
 972                 selected = lowest_player;
 973         // don't do anything if it couldn't find anyone
 974         if(!selected)
 975         {
 976                 bprint("warning: couldn't find a player to move from team\n");
 977                 return;
 978         }
 979
 980         // smallest team gains a member
 981         if(smallestteam == 1)
 982         {
 983                 c1 = c1 + 1;
 984         }
 985         else if(smallestteam == 2)
 986         {
 987                 c2 = c2 + 1;
 988         }
 989         else if(smallestteam == 3)
 990         {
 991                 c3 = c3 + 1;
 992         }
 993         else if(smallestteam == 4)
 994         {
 995                 c4 = c4 + 1;
 996         }
 997         else
 998         {
 999                 bprint("warning: destination team invalid\n");
1000                 return;
1001         }
1002         // source team loses a member
1003         if(source_team == 1)
1004         {
1005                 c1 = c1 + 1;
1006         }
1007         else if(source_team == 2)
1008         {
1009                 c2 = c2 + 2;
1010         }
1011         else if(source_team == 3)
1012         {
1013                 c3 = c3 + 3;
1014         }
1015         else if(source_team == 4)
1016         {
1017                 c4 = c4 + 4;
1018         }
1019         else
1020         {
1021                 bprint("warning: source team invalid\n");
1022                 return;
1023         }
1024
1025         // move the player to the new team
1026         TeamchangeFrags(selected);
1027         SetPlayerTeam(selected, smallestteam, source_team, FALSE);
1028
1029         if(selected.deadflag == DEAD_NO)
1030                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
1031         centerprint(selected, strcat("You have been moved into a different team to improve team balance\nYou are now on: ", ColoredTeamName(selected.team)));
1032 }
1033
1034 void CauseRebalance(float source_team, float howmany_toomany)
1035 {
1036         if(IsTeamBalanceForced() == 1)
1037         {
1038                 bprint("Rebalancing Teams\n");
1039                 ShufflePlayerOutOfTeam(source_team);
1040         }
1041 }
1042
1043 // part of g_balance_teams_force
1044 // occasionally perform an audit of the teams to make
1045 // sure they're more or less balanced in player count.
1046 void AuditTeams()
1047 {
1048         float numplayers, numteams, smallest, toomany;
1049         float balance;
1050         balance = IsTeamBalanceForced();
1051         if(balance == 0)
1052                 return;
1053
1054         if(audit_teams_time > time)
1055                 return;
1056
1057         audit_teams_time = time + 4 + random();
1058
1059 //      bprint("Auditing teams\n");
1060
1061         CheckAllowedTeams(world);
1062         GetTeamCounts(world);
1063
1064
1065         numteams = numplayers = smallest = 0;
1066         if(c1 >= 0)
1067         {
1068                 numteams = numteams + 1;
1069                 numplayers = numplayers + c1;
1070                 smallest = c1;
1071         }
1072         if(c2 >= 0)
1073         {
1074                 numteams = numteams + 1;
1075                 numplayers = numplayers + c2;
1076                 if(c2 < smallest)
1077                         smallest = c2;
1078         }
1079         if(c3 >= 0)
1080         {
1081                 numteams = numteams + 1;
1082                 numplayers = numplayers + c3;
1083                 if(c3 < smallest)
1084                         smallest = c3;
1085         }
1086         if(c4 >= 0)
1087         {
1088                 numteams = numteams + 1;
1089                 numplayers = numplayers + c4;
1090                 if(c4 < smallest)
1091                         smallest = c4;
1092         }
1093
1094         if(numplayers <= 0)
1095                 return; // no players to move around
1096         if(numteams < 2)
1097                 return; // don't bother shuffling if for some reason there aren't any teams
1098
1099         toomany = smallest + 1;
1100
1101         if(c1 && c1 > toomany)
1102                 CauseRebalance(1, c1 - toomany);
1103         if(c2 && c2 > toomany)
1104                 CauseRebalance(2, c2 - toomany);
1105         if(c3 && c3 > toomany)
1106                 CauseRebalance(3, c3 - toomany);
1107         if(c4 && c4 > toomany)
1108                 CauseRebalance(4, c4 - toomany);
1109
1110         // if teams are still unbalanced, balance them further in the next audit,
1111         // which will happen sooner (keep doing rapid audits until things are in order)
1112         audit_teams_time = time + 0.7 + random()*0.3;
1113 }
1114
1115 // code from here on is just to support maps that don't have team entities
1116 void tdm_spawnteam (string teamname, float teamcolor)
1117 {
1118         entity e;
1119         e = spawn();
1120         e.classname = "tdm_team";
1121         e.netname = teamname;
1122         e.cnt = teamcolor;
1123         e.team = e.cnt + 1;
1124 }
1125
1126 // spawn some default teams if the map is not set up for tdm
1127 void tdm_spawnteams()
1128 {
1129         float numteams;
1130
1131         numteams = autocvar_g_tdm_teams_override;
1132         if(numteams < 2)
1133                 numteams = autocvar_g_tdm_teams;
1134         numteams = bound(2, numteams, 4);
1135
1136         tdm_spawnteam("Red", COLOR_TEAM1-1);
1137         tdm_spawnteam("Blue", COLOR_TEAM2-1);
1138         if(numteams >= 3)
1139                 tdm_spawnteam("Yellow", COLOR_TEAM3-1);
1140         if(numteams >= 4)
1141                 tdm_spawnteam("Pink", COLOR_TEAM4-1);
1142 }
1143
1144 void tdm_delayedinit()
1145 {
1146         // if no teams are found, spawn defaults
1147         if (find(world, classname, "tdm_team") == world)
1148                 tdm_spawnteams();
1149 }
1150
1151 void tdm_init()
1152 {
1153         InitializeEntity(world, tdm_delayedinit, INITPRIO_GAMETYPE);
1154 }