qcsrc/server/teamplay.qc

   1 string cache_mutatormsg;
   2 string cache_lastmutatormsg;
   3
   4 // client counts for each team
   5 float c1, c2, c3, c4;
   6 // # of bots on those teams
   7 float cb1, cb2, cb3, cb4;
   8
   9 float audit_teams_time;
  10
  11 float IsTeamBalanceForced()
  12 {
  13         if(intermission_running)
  14                 return 0; // no rebalancing whatsoever please
  15         if(!teamplay)
  16                 return 0;
  17         if(autocvar_g_campaign)
  18                 return 0;
  19         if(autocvar_bot_vs_human && (c3==-1 && c4==-1))
  20                 return 0;
  21         if(!autocvar_g_balance_teams_force)
  22                 return -1;
  23         return 1;
  24 }
  25
  26 void TeamchangeFrags(entity e)
  27 {
  28         PlayerScore_Clear(e);
  29 }
  30
  31 vector TeamColor(float teem)
  32 {
  33         switch(teem)
  34         {
  35                 case COLOR_TEAM1:
  36                         return '1 0.0625 0.0625';
  37                 case COLOR_TEAM2:
  38                         return '0.0625 0.0625 1';
  39                 case COLOR_TEAM3:
  40                         return '1 1 0.0625';
  41                 case COLOR_TEAM4:
  42                         return '1 0.0625 1';
  43                 default:
  44                         return '1 1 1';
  45         }
  46 }
  47
  48 string TeamName(float t)
  49 {
  50         return strcat(Team_ColorName(t), " Team");
  51 }
  52 string ColoredTeamName(float t)
  53 {
  54         return strcat(Team_ColorCode(t), Team_ColorName(t), " Team^7");
  55 }
  56 string TeamNoName(float t)
  57 {
  58         // fixme: Search for team entities and get their .netname's!
  59         if(t == 1)
  60                 return "Red Team";
  61         if(t == 2)
  62                 return "Blue Team";
  63         if(t == 3)
  64                 return "Yellow Team";
  65         if(t == 4)
  66                 return "Pink Team";
  67         return "Neutral Team";
  68 }
  69
  70 void dom_init();
  71 //void ctf_init();
  72 void runematch_init();
  73 void tdm_init();
  74 void entcs_init();
  75
  76 void LogTeamchange(float player_id, float team_number, float type)
  77 {
  78         if(!autocvar_sv_eventlog)
  79                 return;
  80
  81         if(player_id < 1)
  82                 return;
  83
  84         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
  85 }
  86
  87 void default_delayedinit()
  88 {
  89         if(!scores_initialized)
  90                 ScoreRules_generic();
  91 }
  92
  93 void ActivateTeamplay()
  94 {
  95         serverflags |= SERVERFLAG_TEAMPLAY;
  96         teamplay = 1;
  97 }
  98
  99 void InitGameplayMode()
 100 {
 101         float fraglimit_override, timelimit_override, leadlimit_override, qualifying_override;
 102
 103         qualifying_override = -1;
 104
 105         VoteReset();
 106
 107         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 108         get_mi_min_max(1);
 109         world.mins = mi_min;
 110         world.maxs = mi_max;
 111
 112         MapInfo_LoadMapSettings(mapname);
 113         teamplay = 0;
 114         serverflags &~= SERVERFLAG_TEAMPLAY;
 115
 116         if not(cvar_value_issafe(world.fog))
 117         {
 118                 print("The current map contains a potentially harmful fog setting, ignored\n");
 119                 world.fog = string_null;
 120         }
 121         if(MapInfo_Map_fog != "")
 122                 if(MapInfo_Map_fog == "none")
 123                         world.fog = string_null;
 124                 else
 125                         world.fog = strzone(MapInfo_Map_fog);
 126         clientstuff = strzone(MapInfo_Map_clientstuff);
 127
 128         MapInfo_ClearTemps();
 129
 130         // set both here, gamemode can override it later
 131         timelimit_override = autocvar_timelimit_override;
 132         fraglimit_override = autocvar_fraglimit_override;
 133         leadlimit_override = autocvar_leadlimit_override;
 134         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
 135
 136         if(g_dm)
 137         {
 138         }
 139
 140         if(g_tdm)
 141         {
 142                 ActivateTeamplay();
 143                 tdm_init();
 144                 if(autocvar_g_tdm_team_spawns)
 145                         have_team_spawns = -1; // request team spawns
 146         }
 147
 148         if(g_domination)
 149         {
 150                 ActivateTeamplay();
 151                 fraglimit_override = autocvar_g_domination_point_limit;
 152                 leadlimit_override = autocvar_g_domination_point_leadlimit;
 153                 dom_init();
 154                 have_team_spawns = -1; // request team spawns
 155         }
 156
 157         if(g_ctf)
 158         {
 159                 ActivateTeamplay();
 160                 fraglimit_override = autocvar_capturelimit_override;
 161                 leadlimit_override = autocvar_captureleadlimit_override;
 162                 MUTATOR_ADD(gamemode_ctf);
 163                 have_team_spawns = -1; // request team spawns
 164         }
 165
 166         if(g_runematch)
 167         {
 168                 // ActivateTeamplay();
 169                 fraglimit_override = autocvar_g_runematch_point_limit;
 170                 leadlimit_override = autocvar_g_runematch_point_leadlimit;
 171                 runematch_init();
 172         }
 173
 174         if(g_lms)
 175         {
 176                 fraglimit_override = autocvar_g_lms_lives_override;
 177                 leadlimit_override = 0; // not supported by LMS
 178                 if(fraglimit_override == 0)
 179                         fraglimit_override = -1;
 180                 lms_lowest_lives = 9999;
 181                 lms_next_place = 0;
 182                 ScoreRules_lms();
 183         }
 184
 185         if(g_arena)
 186         {
 187                 fraglimit_override = autocvar_g_arena_point_limit;
 188                 leadlimit_override = autocvar_g_arena_point_leadlimit;
 189                 maxspawned = autocvar_g_arena_maxspawned;
 190                 if(maxspawned < 2)
 191                         maxspawned = 2;
 192                 arena_roundbased = autocvar_g_arena_roundbased;
 193         }
 194
 195         if(g_ca)
 196         {
 197                 ActivateTeamplay();
 198                 fraglimit_override = autocvar_g_ca_point_limit;
 199                 leadlimit_override = autocvar_g_ca_point_leadlimit;
 200                 precache_sound("ctf/red_capture.wav");
 201                 precache_sound("ctf/blue_capture.wav");
 202         }
 203         if(g_keyhunt)
 204         {
 205                 ActivateTeamplay();
 206                 fraglimit_override = autocvar_g_keyhunt_point_limit;
 207                 leadlimit_override = autocvar_g_keyhunt_point_leadlimit;
 208                 MUTATOR_ADD(gamemode_keyhunt);
 209         }
 210
 211         if(g_freezetag)
 212         {
 213                 ActivateTeamplay();
 214                 fraglimit_override = autocvar_g_freezetag_point_limit;
 215                 leadlimit_override = autocvar_g_freezetag_point_leadlimit;
 216                 MUTATOR_ADD(gamemode_freezetag);
 217         }
 218
 219         if(g_assault)
 220         {
 221                 ActivateTeamplay();
 222                 ScoreRules_assault();
 223                 have_team_spawns = -1; // request team spawns
 224         }
 225
 226         if(g_onslaught)
 227         {
 228                 ActivateTeamplay();
 229                 have_team_spawns = -1; // request team spawns
 230         }
 231
 232         if(g_race)
 233         {
 234
 235                 if(autocvar_g_race_teams)
 236                 {
 237                         ActivateTeamplay();
 238                         race_teams = bound(2, autocvar_g_race_teams, 4);
 239                         have_team_spawns = -1; // request team spawns
 240                 }
 241                 else
 242                         race_teams = 0;
 243
 244                 qualifying_override = autocvar_g_race_qualifying_timelimit_override;
 245                 fraglimit_override = autocvar_g_race_laps_limit;
 246                 leadlimit_override = 0; // currently not supported by race
 247         }
 248
 249         if(g_cts)
 250         {
 251                 g_race_qualifying = 1;
 252                 fraglimit_override = 0;
 253                 leadlimit_override = 0;
 254         }
 255
 256         if(g_nexball)
 257         {
 258         fraglimit_override = autocvar_g_nexball_goallimit;
 259         leadlimit_override = autocvar_g_nexball_goalleadlimit;
 260         ActivateTeamplay();
 261         have_team_spawns = -1; // request team spawns
 262             MUTATOR_ADD(gamemode_nexball);
 263         }
 264
 265         if(g_keepaway)
 266         {
 267                 MUTATOR_ADD(gamemode_keepaway);
 268         }
 269
 270         if(teamplay)
 271                 entcs_init();
 272
 273         cache_mutatormsg = strzone("");
 274         cache_lastmutatormsg = strzone("");
 275
 276         // enforce the server's universal frag/time limits
 277         if(!autocvar_g_campaign)
 278         {
 279                 if(fraglimit_override >= 0)
 280                         cvar_set("fraglimit", ftos(fraglimit_override));
 281                 if(timelimit_override >= 0)
 282                         cvar_set("timelimit", ftos(timelimit_override));
 283                 if(leadlimit_override >= 0)
 284                         cvar_set("leadlimit", ftos(leadlimit_override));
 285                 if(qualifying_override >= 0)
 286                         cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 287         }
 288
 289         if(g_race)
 290         {
 291                 // we need to find out the correct value for g_race_qualifying
 292                 if(autocvar_g_campaign)
 293                 {
 294                         g_race_qualifying = 1;
 295                 }
 296                 else if(!autocvar_g_campaign && autocvar_g_race_qualifying_timelimit > 0)
 297                 {
 298                         g_race_qualifying = 2;
 299                         race_fraglimit = autocvar_fraglimit;
 300                         race_leadlimit = autocvar_leadlimit;
 301                         race_timelimit = autocvar_timelimit;
 302                         cvar_set("fraglimit", "0");
 303                         cvar_set("leadlimit", "0");
 304                         cvar_set("timelimit", ftos(autocvar_g_race_qualifying_timelimit));
 305                 }
 306                 else
 307                         g_race_qualifying = 0;
 308         }
 309
 310         if(g_race || g_cts)
 311         {
 312                 if(g_race_qualifying)
 313                         independent_players = 1;
 314
 315                 ScoreRules_race();
 316         }
 317
 318         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 319 }
 320
 321 string GetClientVersionMessage() {
 322         string versionmsg;
 323         if (self.version_mismatch) {
 324                 if(self.version < autocvar_gameversion) {
 325                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
 326                 } else {
 327                         versionmsg = "^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
 328                 }
 329         } else {
 330                 versionmsg = "^2client version and server version are compatible.^8";
 331         }
 332         return versionmsg;
 333 }
 334
 335 string getwelcomemessage(void)
 336 {
 337         string s, modifications, motd;
 338
 339         ret_string = "";
 340         MUTATOR_CALLHOOK(BuildMutatorsPrettyString);
 341         modifications = ret_string;
 342
 343         if(g_minstagib)
 344                 modifications = strcat(modifications, ", MinstaGib");
 345         if(g_weaponarena)
 346         {
 347                 if(g_weaponarena_random)
 348                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
 349                 else
 350                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 351         }
 352         if(autocvar_g_start_weapon_laser == 0)
 353                 modifications = strcat(modifications, ", No start weapons");
 354         if(autocvar_sv_gravity < 800)
 355                 modifications = strcat(modifications, ", Low gravity");
 356         if(g_cloaked && !g_cts)
 357                 modifications = strcat(modifications, ", Cloaked");
 358         if(g_grappling_hook)
 359                 modifications = strcat(modifications, ", Hook");
 360         if(g_midair)
 361                 modifications = strcat(modifications, ", Midair");
 362         if(g_pinata)
 363                 modifications = strcat(modifications, ", Piñata");
 364         if(g_weapon_stay && !g_cts)
 365                 modifications = strcat(modifications, ", Weapons stay");
 366         if(g_bloodloss > 0)
 367                 modifications = strcat(modifications, ", Blood loss");
 368         if(g_jetpack)
 369                 modifications = strcat(modifications, ", Jet pack");
 370         if(autocvar_g_powerups == 0)
 371                 modifications = strcat(modifications, ", No powerups");
 372         if(autocvar_g_powerups > 0)
 373                 modifications = strcat(modifications, ", Powerups");
 374         modifications = substring(modifications, 2, strlen(modifications) - 2);
 375
 376         string versionmessage;
 377         versionmessage = GetClientVersionMessage();
 378
 379         s = strcat("This is Xonotic ", autocvar_g_xonoticversion, "\n", versionmessage);
 380         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 381
 382         if(modifications != "")
 383                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 384
 385         if (g_grappling_hook)
 386                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
 387
 388         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
 389         {
 390                 if(cache_lastmutatormsg)
 391                         strunzone(cache_lastmutatormsg);
 392                 if(cache_mutatormsg)
 393                         strunzone(cache_mutatormsg);
 394                 cache_lastmutatormsg = strzone(autocvar_g_mutatormsg);
 395                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 396         }
 397
 398         if (cache_mutatormsg != "") {
 399                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 400         }
 401
 402         motd = autocvar_sv_motd;
 403         if (motd != "") {
 404                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 405         }
 406         return s;
 407 }
 408
 409 void SetPlayerColors(entity pl, float _color)
 410 {
 411         /*string s;
 412         s = ftos(cl);
 413         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 414         pl.team = cl + 1;
 415         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 416         pl.clientcolors = 16*cl + cl;*/
 417
 418         float pants, shirt;
 419         pants = _color & 0x0F;
 420         shirt = _color & 0xF0;
 421
 422
 423         if(teamplay) {
 424                 setcolor(pl, 16*pants + pants);
 425         } else {
 426                 setcolor(pl, shirt + pants);
 427         }
 428 }
 429
 430 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 431 {
 432         float _color;
 433
 434         if(t == 4)
 435                 _color = COLOR_TEAM4 - 1;
 436         else if(t == 3)
 437                 _color = COLOR_TEAM3 - 1;
 438         else if(t == 2)
 439                 _color = COLOR_TEAM2 - 1;
 440         else
 441                 _color = COLOR_TEAM1 - 1;
 442
 443         SetPlayerColors(pl,_color);
 444
 445         if(t != s) {
 446                 LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
 447
 448                 if(!noprint)
 449                 bprint(pl.netname, "^7 has changed from ", TeamNoName(s), " to ", TeamNoName(t), "\n");
 450         }
 451
 452 }
 453
 454 // set c1...c4 to show what teams are allowed
 455 void CheckAllowedTeams (entity for_whom)
 456 {
 457         float dm;
 458         entity head;
 459         string teament_name;
 460
 461         c1 = c2 = c3 = c4 = -1;
 462         cb1 = cb2 = cb3 = cb4 = 0;
 463
 464         if(g_onslaught)
 465         {
 466                 // onslaught is special
 467                 head = findchain(classname, "onslaught_generator");
 468                 while (head)
 469                 {
 470                         if (head.team == COLOR_TEAM1) c1 = 0;
 471                         if (head.team == COLOR_TEAM2) c2 = 0;
 472                         if (head.team == COLOR_TEAM3) c3 = 0;
 473                         if (head.team == COLOR_TEAM4) c4 = 0;
 474                         head = head.chain;
 475                 }
 476         }
 477         else if(g_domination)
 478                 teament_name = "dom_team";
 479         else if(g_ctf)
 480                 teament_name = "ctf_team";
 481         else if(g_tdm)
 482                 teament_name = "tdm_team";
 483         else if(g_nexball)
 484                 teament_name = "nexball_team";
 485         else if(g_assault)
 486                 c1 = c2 = 0; // Assault always has 2 teams
 487         else
 488         {
 489                 // cover anything else by treating it like tdm with no teams spawned
 490                 if(g_race)
 491                         dm = race_teams;
 492                 else
 493                         dm = 2;
 494
 495                 ret_float = dm;
 496                 MUTATOR_CALLHOOK(GetTeamCount);
 497                 dm = ret_float;
 498
 499                 if(dm >= 4)
 500                         c1 = c2 = c3 = c4 = 0;
 501                 else if(dm >= 3)
 502                         c1 = c2 = c3 = 0;
 503                 else
 504                         c1 = c2 = 0;
 505         }
 506
 507         // find out what teams are allowed if necessary
 508         if(teament_name)
 509         {
 510                 head = find(world, classname, teament_name);
 511                 while(head)
 512                 {
 513                         if(!(g_domination && head.netname == ""))
 514                         {
 515                                 if(head.team == COLOR_TEAM1)
 516                                         c1 = 0;
 517                                 else if(head.team == COLOR_TEAM2)
 518                                         c2 = 0;
 519                                 else if(head.team == COLOR_TEAM3)
 520                                         c3 = 0;
 521                                 else if(head.team == COLOR_TEAM4)
 522                                         c4 = 0;
 523                         }
 524                         head = find(head, classname, teament_name);
 525                 }
 526         }
 527
 528         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
 529         if(c3==-1 && c4==-1)
 530         if(autocvar_bot_vs_human && for_whom)
 531         {
 532                 if(autocvar_bot_vs_human > 0)
 533                 {
 534                         // bots are all blue
 535                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 536                                 c1 = c3 = c4 = -1;
 537                         else
 538                                 c2 = -1;
 539                 }
 540                 else
 541                 {
 542                         // bots are all red
 543                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 544                                 c2 = c3 = c4 = -1;
 545                         else
 546                                 c1 = -1;
 547                 }
 548         }
 549
 550         // if player has a forced team, ONLY allow that one
 551         if(self.team_forced == COLOR_TEAM1 && c1 >= 0)
 552                 c2 = c3 = c4 = -1;
 553         else if(self.team_forced == COLOR_TEAM2 && c2 >= 0)
 554                 c1 = c3 = c4 = -1;
 555         else if(self.team_forced == COLOR_TEAM3 && c3 >= 0)
 556                 c1 = c2 = c4 = -1;
 557         else if(self.team_forced == COLOR_TEAM4 && c4 >= 0)
 558                 c1 = c2 = c3 = -1;
 559 }
 560
 561 float PlayerValue(entity p)
 562 {
 563         if(IsTeamBalanceForced() == 1)
 564                 return 1;
 565         return 1;
 566         // FIXME: it always returns 1...
 567 }
 568
 569 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 570 // teams that are allowed will now have their player counts stored in c1...c4
 571 void GetTeamCounts(entity ignore)
 572 {
 573         entity head;
 574         float value, bvalue;
 575         // now count how many players are on each team already
 576
 577         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 578         // also remember the lowest-scoring player
 579
 580         FOR_EACH_CLIENT(head)
 581         {
 582                 float t;
 583                 if(head.classname == "player")
 584                         t = head.team;
 585                 else if(head.team_forced > 0)
 586                         t = head.team_forced; // reserve the spot
 587                 else
 588                         continue;
 589                 if(head != ignore)// && head.netname != "")
 590                 {
 591                         value = PlayerValue(head);
 592                         if(clienttype(head) == CLIENTTYPE_BOT)
 593                                 bvalue = value;
 594                         else
 595                                 bvalue = 0;
 596                         if(t == COLOR_TEAM1)
 597                         {
 598                                 if(c1 >= 0)
 599                                 {
 600                                         c1 = c1 + value;
 601                                         cb1 = cb1 + bvalue;
 602                                 }
 603                         }
 604                         if(t == COLOR_TEAM2)
 605                         {
 606                                 if(c2 >= 0)
 607                                 {
 608                                         c2 = c2 + value;
 609                                         cb2 = cb2 + bvalue;
 610                                 }
 611                         }
 612                         if(t == COLOR_TEAM3)
 613                         {
 614                                 if(c3 >= 0)
 615                                 {
 616                                         c3 = c3 + value;
 617                                         cb3 = cb3 + bvalue;
 618                                 }
 619                         }
 620                         if(t == COLOR_TEAM4)
 621                         {
 622                                 if(c4 >= 0)
 623                                 {
 624                                         c4 = c4 + value;
 625                                         cb4 = cb4 + bvalue;
 626                                 }
 627                         }
 628                 }
 629         }
 630
 631         // if the player who has a forced team has not joined yet, reserve the spot
 632         if(autocvar_g_campaign)
 633         {
 634                 switch(autocvar_g_campaign_forceteam)
 635                 {
 636                         case 1: if(c1 == cb1) ++c1; break;
 637                         case 2: if(c2 == cb2) ++c2; break;
 638                         case 3: if(c3 == cb3) ++c3; break;
 639                         case 4: if(c4 == cb4) ++c4; break;
 640                 }
 641         }
 642 }
 643
 644 // returns # of smallest team (1, 2, 3, 4)
 645 // NOTE: Assumes CheckAllowedTeams has already been called!
 646 float FindSmallestTeam(entity pl, float ignore_pl)
 647 {
 648         float totalteams, balance_type, maxc;
 649         totalteams = 0;
 650
 651         // find out what teams are available
 652         //CheckAllowedTeams();
 653
 654         // make sure there are at least 2 teams to join
 655         if(c1 >= 0)
 656                 totalteams = totalteams + 1;
 657         if(c2 >= 0)
 658                 totalteams = totalteams + 1;
 659         if(c3 >= 0)
 660                 totalteams = totalteams + 1;
 661         if(c4 >= 0)
 662                 totalteams = totalteams + 1;
 663
 664         if((autocvar_bot_vs_human || pl.team_forced > 0) && totalteams == 1)
 665                 totalteams += 1;
 666
 667         if(totalteams <= 1)
 668         {
 669                 if(autocvar_g_campaign && pl && clienttype(pl) == CLIENTTYPE_REAL)
 670                         return 1; // special case for campaign and player joining
 671                 else if(g_domination)
 672                         error("Too few teams available for domination\n");
 673                 else if(g_ctf)
 674                         error("Too few teams available for ctf\n");
 675                 else if(g_keyhunt)
 676                         error("Too few teams available for key hunt\n");
 677                 else if(g_freezetag)
 678                         error("Too few teams available for freeze tag\n");
 679                 else
 680                         error("Too few teams available for team deathmatch\n");
 681         }
 682
 683         // count how many players are in each team
 684         if(ignore_pl)
 685                 GetTeamCounts(pl);
 686         else
 687                 GetTeamCounts(world);
 688
 689         // c1...c4 now have counts of each team
 690         // figure out which is smallest, giving priority to the team the player is already on as a tie-breaker
 691
 692         // 2 gives priority to what team you're already on, 1 goes in order
 693         // 2 doesn't seem to work though...
 694         balance_type = 1;
 695
 696         if(bots_would_leave)
 697         //if(pl.classname != "player")
 698         if(clienttype(pl) != CLIENTTYPE_BOT)
 699         {
 700                 c1 -= cb1 * 255.0/256.0;
 701                 c2 -= cb2 * 255.0/256.0;
 702                 c3 -= cb3 * 255.0/256.0;
 703                 c4 -= cb4 * 255.0/256.0;
 704         }
 705         maxc = max4(c1, c2, c3, c4);
 706
 707         RandomSelection_Init();
 708         if(balance_type == 1)
 709         {
 710                 // 1: use team count, then score (note: can only use 8 significant bits of score)
 711                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + float2range01(-team1_score) / 256.0);
 712                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c2) + float2range01(-team2_score) / 256.0);
 713                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c3) + float2range01(-team3_score) / 256.0);
 714                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c4) + float2range01(-team4_score) / 256.0);
 715         }
 716         else if(balance_type == 2)
 717         {
 718                 // 1: use team count, if equal prefer own team
 719                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM1) / 512.0);
 720                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM2) / 512.0);
 721                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM3) / 512.0);
 722                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM4) / 512.0);
 723         }
 724         else if(balance_type == 3)
 725         {
 726                 // 1: use team count, then score, if equal prefer own team (probably fails due to float accuracy problems)
 727                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + float2range01(-team1_score + 0.5 * (self.team == COLOR_TEAM1)) / 256.0);
 728                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c2) + float2range01(-team2_score + 0.5 * (self.team == COLOR_TEAM2)) / 256.0);
 729                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c3) + float2range01(-team3_score + 0.5 * (self.team == COLOR_TEAM3)) / 256.0);
 730                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c4) + float2range01(-team4_score + 0.5 * (self.team == COLOR_TEAM4)) / 256.0);
 731         }
 732         return RandomSelection_chosen_float;
 733 }
 734
 735 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
 736 {
 737         float smallest, selectedteam;
 738
 739         // don't join a team if we're not playing a team game
 740         if(!teamplay)
 741                 return 0;
 742
 743         // find out what teams are available
 744         CheckAllowedTeams(pl);
 745
 746         // if we don't care what team he ends up on, put him on whatever team he entered as.
 747         // if he's not on a valid team, then let other code put him on the smallest team
 748         if(!forcebestteam)
 749         {
 750                 if(     c1 >= 0 && pl.team == COLOR_TEAM1)
 751                         selectedteam = pl.team;
 752                 else if(c2 >= 0 && pl.team == COLOR_TEAM2)
 753                         selectedteam = pl.team;
 754                 else if(c3 >= 0 && pl.team == COLOR_TEAM3)
 755                         selectedteam = pl.team;
 756                 else if(c4 >= 0 && pl.team == COLOR_TEAM4)
 757                         selectedteam = pl.team;
 758                 else
 759                         selectedteam = -1;
 760
 761                 if(selectedteam > 0)
 762                 {
 763                         if(!only_return_best)
 764                         {
 765                                 SetPlayerColors(pl, selectedteam - 1);
 766
 767                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
 768                                 // when JoinBestTeam is called by cl_client.qc/ClientConnect the player_id is 0 the log attempt is rejected
 769                                 LogTeamchange(pl.playerid, pl.team, 99);
 770                         }
 771                         return selectedteam;
 772                 }
 773                 // otherwise end up on the smallest team (handled below)
 774         }
 775
 776         smallest = FindSmallestTeam(pl, TRUE);
 777
 778         if(!only_return_best && !pl.bot_forced_team)
 779         {
 780                 TeamchangeFrags(self);
 781                 if(smallest == 1)
 782                 {
 783                         SetPlayerColors(pl, COLOR_TEAM1 - 1);
 784                 }
 785                 else if(smallest == 2)
 786                 {
 787                         SetPlayerColors(pl, COLOR_TEAM2 - 1);
 788                 }
 789                 else if(smallest == 3)
 790                 {
 791                         SetPlayerColors(pl, COLOR_TEAM3 - 1);
 792                 }
 793                 else if(smallest == 4)
 794                 {
 795                         SetPlayerColors(pl, COLOR_TEAM4 - 1);
 796                 }
 797                 else
 798                 {
 799                         error("smallest team: invalid team\n");
 800                 }
 801
 802                 LogTeamchange(pl.playerid, pl.team, 2); // log auto join
 803
 804                 if(pl.deadflag == DEAD_NO)
 805                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
 806         }
 807
 808         return smallest;
 809 }
 810
 811 //void() ctf_playerchanged;
 812 void SV_ChangeTeam(float _color)
 813 {
 814         float scolor, dcolor, steam, dteam, dbotcount, scount, dcount;
 815
 816         // in normal deathmatch we can just apply the color and we're done
 817         if(!teamplay) {
 818                 SetPlayerColors(self, _color);
 819                 return;
 820         }
 821
 822         scolor = self.clientcolors & 0x0F;
 823         dcolor = _color & 0x0F;
 824
 825         if(scolor == COLOR_TEAM1 - 1)
 826                 steam = 1;
 827         else if(scolor == COLOR_TEAM2 - 1)
 828                 steam = 2;
 829         else if(scolor == COLOR_TEAM3 - 1)
 830                 steam = 3;
 831         else // if(scolor == COLOR_TEAM4 - 1)
 832                 steam = 4;
 833         if(dcolor == COLOR_TEAM1 - 1)
 834                 dteam = 1;
 835         else if(dcolor == COLOR_TEAM2 - 1)
 836                 dteam = 2;
 837         else if(dcolor == COLOR_TEAM3 - 1)
 838                 dteam = 3;
 839         else // if(dcolor == COLOR_TEAM4 - 1)
 840                 dteam = 4;
 841
 842         CheckAllowedTeams(self);
 843
 844         if(dteam == 1 && c1 < 0) dteam = 4;
 845         if(dteam == 4 && c4 < 0) dteam = 3;
 846         if(dteam == 3 && c3 < 0) dteam = 2;
 847         if(dteam == 2 && c2 < 0) dteam = 1;
 848
 849         // not changing teams
 850         if(scolor == dcolor)
 851         {
 852                 //bprint("same team change\n");
 853                 SetPlayerTeam(self, dteam, steam, TRUE);
 854                 return;
 855         }
 856
 857         if((autocvar_g_campaign) || (autocvar_g_changeteam_banned && self.wasplayer)) {
 858                 sprint(self, "Team changes not allowed\n");
 859                 return; // changing teams is not allowed
 860         }
 861
 862         if(autocvar_g_balance_teams_prevent_imbalance)
 863         {
 864                 // only allow changing to a smaller or equal size team
 865
 866                 // find out what teams are available
 867                 //CheckAllowedTeams();
 868                 // count how many players on each team
 869                 GetTeamCounts(world);
 870
 871                 // get desired team
 872                 if(dteam == 1 && c1 >= 0)//dcolor == COLOR_TEAM1 - 1)
 873                 {
 874                         dcount = c1;
 875                         dbotcount = cb1;
 876                 }
 877                 else if(dteam == 2 && c2 >= 0)//dcolor == COLOR_TEAM2 - 1)
 878                 {
 879                         dcount = c2;
 880                         dbotcount = cb2;
 881                 }
 882                 else if(dteam == 3 && c3 >= 0)//dcolor == COLOR_TEAM3 - 1)
 883                 {
 884                         dcount = c3;
 885                         dbotcount = cb3;
 886                 }
 887                 else if(dteam == 4 && c4 >= 0)//dcolor == COLOR_TEAM4 - 1)
 888                 {
 889                         dcount = c4;
 890                         dbotcount = cb4;
 891                 }
 892                 else
 893                 {
 894                         sprint(self, "Cannot change to an invalid team\n");
 895
 896                         return;
 897                 }
 898
 899                 // get starting team
 900                 if(steam == 1)//scolor == COLOR_TEAM1 - 1)
 901                         scount = c1;
 902                 else if(steam == 2)//scolor == COLOR_TEAM2 - 1)
 903                         scount = c2;
 904                 else if(steam == 3)//scolor == COLOR_TEAM3 - 1)
 905                         scount = c3;
 906                 else if(steam == 4)//scolor == COLOR_TEAM4 - 1)
 907                         scount = c4;
 908
 909                 if(scount) // started at a valid, nonempty team
 910                 {
 911                         // check if we're trying to change to a larger team that doens't have bots to swap with
 912                         if(dcount >= scount && dbotcount <= 0)
 913                         {
 914                                 sprint(self, "Cannot change to a larger team\n");
 915                                 return; // can't change to a larger team
 916                         }
 917                 }
 918         }
 919
 920 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
 921
 922         if(self.classname == "player" && steam != dteam)
 923         {
 924                 // reduce frags during a team change
 925                 TeamchangeFrags(self);
 926         }
 927
 928         SetPlayerTeam(self, dteam, steam, FALSE);
 929
 930         if(self.classname == "player" && steam != dteam)
 931         {
 932                 // kill player when changing teams
 933                 if(self.deadflag == DEAD_NO)
 934                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
 935         }
 936         //ctf_playerchanged();
 937 }
 938
 939 void ShufflePlayerOutOfTeam (float source_team)
 940 {
 941         float smallestteam, smallestteam_count, steam;
 942         float lowest_bot_score, lowest_player_score;
 943         entity head, lowest_bot, lowest_player, selected;
 944
 945         smallestteam = 0;
 946         smallestteam_count = 999999999;
 947
 948         if(c1 >= 0 && c1 < smallestteam_count)
 949         {
 950                 smallestteam = 1;
 951                 smallestteam_count = c1;
 952         }
 953         if(c2 >= 0 && c2 < smallestteam_count)
 954         {
 955                 smallestteam = 2;
 956                 smallestteam_count = c2;
 957         }
 958         if(c3 >= 0 && c3 < smallestteam_count)
 959         {
 960                 smallestteam = 3;
 961                 smallestteam_count = c3;
 962         }
 963         if(c4 >= 0 && c4 < smallestteam_count)
 964         {
 965                 smallestteam = 4;
 966                 smallestteam_count = c4;
 967         }
 968
 969         if(!smallestteam)
 970         {
 971                 bprint("warning: no smallest team\n");
 972                 return;
 973         }
 974
 975         if(source_team == 1)
 976                 steam = COLOR_TEAM1;
 977         else if(source_team == 2)
 978                 steam = COLOR_TEAM2;
 979         else if(source_team == 3)
 980                 steam = COLOR_TEAM3;
 981         else if(source_team == 4)
 982                 steam = COLOR_TEAM4;
 983
 984         lowest_bot = world;
 985         lowest_bot_score = 999999999;
 986         lowest_player = world;
 987         lowest_player_score = 999999999;
 988
 989         // find the lowest-scoring player & bot of that team
 990         FOR_EACH_PLAYER(head)
 991         {
 992                 if(head.team == steam)
 993                 {
 994                         if(head.isbot)
 995                         {
 996                                 if(head.totalfrags < lowest_bot_score)
 997                                 {
 998                                         lowest_bot = head;
 999                                         lowest_bot_score = head.totalfrags;
1000                                 }
1001                         }
1002                         else
1003                         {
1004                                 if(head.totalfrags < lowest_player_score)
1005                                 {
1006                                         lowest_player = head;
1007                                         lowest_player_score = head.totalfrags;
1008                                 }
1009                         }
1010                 }
1011         }
1012
1013         // prefers to move a bot...
1014         if(lowest_bot != world)
1015                 selected = lowest_bot;
1016         // but it will move a player if it has to
1017         else
1018                 selected = lowest_player;
1019         // don't do anything if it couldn't find anyone
1020         if(!selected)
1021         {
1022                 bprint("warning: couldn't find a player to move from team\n");
1023                 return;
1024         }
1025
1026         // smallest team gains a member
1027         if(smallestteam == 1)
1028         {
1029                 c1 = c1 + 1;
1030         }
1031         else if(smallestteam == 2)
1032         {
1033                 c2 = c2 + 1;
1034         }
1035         else if(smallestteam == 3)
1036         {
1037                 c3 = c3 + 1;
1038         }
1039         else if(smallestteam == 4)
1040         {
1041                 c4 = c4 + 1;
1042         }
1043         else
1044         {
1045                 bprint("warning: destination team invalid\n");
1046                 return;
1047         }
1048         // source team loses a member
1049         if(source_team == 1)
1050         {
1051                 c1 = c1 + 1;
1052         }
1053         else if(source_team == 2)
1054         {
1055                 c2 = c2 + 2;
1056         }
1057         else if(source_team == 3)
1058         {
1059                 c3 = c3 + 3;
1060         }
1061         else if(source_team == 4)
1062         {
1063                 c4 = c4 + 4;
1064         }
1065         else
1066         {
1067                 bprint("warning: source team invalid\n");
1068                 return;
1069         }
1070
1071         // move the player to the new team
1072         TeamchangeFrags(selected);
1073         SetPlayerTeam(selected, smallestteam, source_team, FALSE);
1074
1075         if(selected.deadflag == DEAD_NO)
1076                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
1077         centerprint(selected, strcat("You have been moved into a different team to improve team balance\nYou are now on: ", ColoredTeamName(selected.team)));
1078 }
1079
1080 void CauseRebalance(float source_team, float howmany_toomany)
1081 {
1082         if(IsTeamBalanceForced() == 1)
1083         {
1084                 bprint("Rebalancing Teams\n");
1085                 ShufflePlayerOutOfTeam(source_team);
1086         }
1087 }
1088
1089 // part of g_balance_teams_force
1090 // occasionally perform an audit of the teams to make
1091 // sure they're more or less balanced in player count.
1092 void AuditTeams()
1093 {
1094         float numplayers, numteams, smallest, toomany;
1095         float balance;
1096         balance = IsTeamBalanceForced();
1097         if(balance == 0)
1098                 return;
1099
1100         if(audit_teams_time > time)
1101                 return;
1102
1103         audit_teams_time = time + 4 + random();
1104
1105 //      bprint("Auditing teams\n");
1106
1107         CheckAllowedTeams(world);
1108         GetTeamCounts(world);
1109
1110
1111         numteams = numplayers = smallest = 0;
1112         if(c1 >= 0)
1113         {
1114                 numteams = numteams + 1;
1115                 numplayers = numplayers + c1;
1116                 smallest = c1;
1117         }
1118         if(c2 >= 0)
1119         {
1120                 numteams = numteams + 1;
1121                 numplayers = numplayers + c2;
1122                 if(c2 < smallest)
1123                         smallest = c2;
1124         }
1125         if(c3 >= 0)
1126         {
1127                 numteams = numteams + 1;
1128                 numplayers = numplayers + c3;
1129                 if(c3 < smallest)
1130                         smallest = c3;
1131         }
1132         if(c4 >= 0)
1133         {
1134                 numteams = numteams + 1;
1135                 numplayers = numplayers + c4;
1136                 if(c4 < smallest)
1137                         smallest = c4;
1138         }
1139
1140         if(numplayers <= 0)
1141                 return; // no players to move around
1142         if(numteams < 2)
1143                 return; // don't bother shuffling if for some reason there aren't any teams
1144
1145         toomany = smallest + 1;
1146
1147         if(c1 && c1 > toomany)
1148                 CauseRebalance(1, c1 - toomany);
1149         if(c2 && c2 > toomany)
1150                 CauseRebalance(2, c2 - toomany);
1151         if(c3 && c3 > toomany)
1152                 CauseRebalance(3, c3 - toomany);
1153         if(c4 && c4 > toomany)
1154                 CauseRebalance(4, c4 - toomany);
1155
1156         // if teams are still unbalanced, balance them further in the next audit,
1157         // which will happen sooner (keep doing rapid audits until things are in order)
1158         audit_teams_time = time + 0.7 + random()*0.3;
1159 }
1160
1161 // code from here on is just to support maps that don't have team entities
1162 void tdm_spawnteam (string teamname, float teamcolor)
1163 {
1164         entity e;
1165         e = spawn();
1166         e.classname = "tdm_team";
1167         e.netname = teamname;
1168         e.cnt = teamcolor;
1169         e.team = e.cnt + 1;
1170 }
1171
1172 // spawn some default teams if the map is not set up for tdm
1173 void tdm_spawnteams()
1174 {
1175         float numteams;
1176
1177         numteams = autocvar_g_tdm_teams_override;
1178         if(numteams < 2)
1179                 numteams = autocvar_g_tdm_teams;
1180         numteams = bound(2, numteams, 4);
1181
1182         tdm_spawnteam("Red", COLOR_TEAM1-1);
1183         tdm_spawnteam("Blue", COLOR_TEAM2-1);
1184         if(numteams >= 3)
1185                 tdm_spawnteam("Yellow", COLOR_TEAM3-1);
1186         if(numteams >= 4)
1187                 tdm_spawnteam("Pink", COLOR_TEAM4-1);
1188 }
1189
1190 void tdm_delayedinit()
1191 {
1192         // if no teams are found, spawn defaults
1193         if (find(world, classname, "tdm_team") == world)
1194                 tdm_spawnteams();
1195 }
1196
1197 void tdm_init()
1198 {
1199         InitializeEntity(world, tdm_delayedinit, INITPRIO_GAMETYPE);
1200 }