qcsrc/server/teamplay.qc

   1 string cache_mutatormsg;
   2 string cache_lastmutatormsg;
   3
   4 // client counts for each team
   5 float c1, c2, c3, c4;
   6 // # of bots on those teams
   7 float cb1, cb2, cb3, cb4;
   8
   9 float audit_teams_time;
  10
  11 float IsTeamBalanceForced()
  12 {
  13         if(intermission_running)
  14                 return 0; // no rebalancing whatsoever please
  15         if(!teamplay)
  16                 return 0;
  17         if(autocvar_g_campaign)
  18                 return 0;
  19         if(autocvar_bot_vs_human && (c3==-1 && c4==-1))
  20                 return 0;
  21         if(!autocvar_g_balance_teams_force)
  22                 return -1;
  23         return 1;
  24 }
  25
  26 void TeamchangeFrags(entity e)
  27 {
  28         PlayerScore_Clear(e);
  29 }
  30
  31 vector TeamColor(float teem)
  32 {
  33         switch(teem)
  34         {
  35                 case COLOR_TEAM1:
  36                         return '1 0.0625 0.0625';
  37                 case COLOR_TEAM2:
  38                         return '0.0625 0.0625 1';
  39                 case COLOR_TEAM3:
  40                         return '1 1 0.0625';
  41                 case COLOR_TEAM4:
  42                         return '1 0.0625 1';
  43                 default:
  44                         return '1 1 1';
  45         }
  46 }
  47
  48 string TeamName(float t)
  49 {
  50         return strcat(Team_ColorName(t), " Team");
  51 }
  52 string ColoredTeamName(float t)
  53 {
  54         return strcat(Team_ColorCode(t), Team_ColorName(t), " Team^7");
  55 }
  56 string TeamNoName(float t)
  57 {
  58         // fixme: Search for team entities and get their .netname's!
  59         if(t == 1)
  60                 return "Red Team";
  61         if(t == 2)
  62                 return "Blue Team";
  63         if(t == 3)
  64                 return "Yellow Team";
  65         if(t == 4)
  66                 return "Pink Team";
  67         return "Neutral Team";
  68 }
  69
  70 void dom_init();
  71 void runematch_init();
  72 void tdm_init();
  73 void entcs_init();
  74
  75 void LogTeamchange(float player_id, float team_number, float type)
  76 {
  77         if(!autocvar_sv_eventlog)
  78                 return;
  79
  80         if(player_id < 1)
  81                 return;
  82
  83         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
  84 }
  85
  86 void default_delayedinit()
  87 {
  88         if(!scores_initialized)
  89                 ScoreRules_generic();
  90 }
  91
  92 void ActivateTeamplay()
  93 {
  94         serverflags |= SERVERFLAG_TEAMPLAY;
  95         teamplay = 1;
  96 }
  97
  98 void InitGameplayMode()
  99 {
 100         float fraglimit_override, timelimit_override, leadlimit_override, qualifying_override;
 101
 102         qualifying_override = -1;
 103
 104         VoteReset();
 105
 106         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 107         get_mi_min_max(1);
 108         world.mins = mi_min;
 109         world.maxs = mi_max;
 110
 111         MapInfo_LoadMapSettings(mapname);
 112         teamplay = 0;
 113         serverflags &~= SERVERFLAG_TEAMPLAY;
 114
 115         if not(cvar_value_issafe(world.fog))
 116         {
 117                 print("The current map contains a potentially harmful fog setting, ignored\n");
 118                 world.fog = string_null;
 119         }
 120         if(MapInfo_Map_fog != "")
 121                 if(MapInfo_Map_fog == "none")
 122                         world.fog = string_null;
 123                 else
 124                         world.fog = strzone(MapInfo_Map_fog);
 125         clientstuff = strzone(MapInfo_Map_clientstuff);
 126
 127         MapInfo_ClearTemps();
 128
 129         // set both here, gamemode can override it later
 130         timelimit_override = autocvar_timelimit_override;
 131         fraglimit_override = autocvar_fraglimit_override;
 132         leadlimit_override = autocvar_leadlimit_override;
 133         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
 134
 135         if(g_dm)
 136         {
 137         }
 138
 139         if(g_tdm)
 140         {
 141                 ActivateTeamplay();
 142                 tdm_init();
 143                 if(autocvar_g_tdm_team_spawns)
 144                         have_team_spawns = -1; // request team spawns
 145         }
 146
 147         if(g_domination)
 148         {
 149                 ActivateTeamplay();
 150                 fraglimit_override = autocvar_g_domination_point_limit;
 151                 leadlimit_override = autocvar_g_domination_point_leadlimit;
 152                 dom_init();
 153                 have_team_spawns = -1; // request team spawns
 154         }
 155
 156         if(g_ctf)
 157         {
 158                 ActivateTeamplay();
 159                 fraglimit_override = autocvar_capturelimit_override;
 160                 leadlimit_override = autocvar_captureleadlimit_override;
 161                 MUTATOR_ADD(gamemode_ctf);
 162                 have_team_spawns = -1; // request team spawns
 163         }
 164
 165         if(g_runematch)
 166         {
 167                 // ActivateTeamplay();
 168                 fraglimit_override = autocvar_g_runematch_point_limit;
 169                 leadlimit_override = autocvar_g_runematch_point_leadlimit;
 170                 runematch_init();
 171         }
 172
 173         if(g_lms)
 174         {
 175                 fraglimit_override = autocvar_g_lms_lives_override;
 176                 leadlimit_override = 0; // not supported by LMS
 177                 if(fraglimit_override == 0)
 178                         fraglimit_override = -1;
 179                 lms_lowest_lives = 9999;
 180                 lms_next_place = 0;
 181                 ScoreRules_lms();
 182         }
 183
 184         if(g_arena)
 185         {
 186                 fraglimit_override = autocvar_g_arena_point_limit;
 187                 leadlimit_override = autocvar_g_arena_point_leadlimit;
 188                 maxspawned = autocvar_g_arena_maxspawned;
 189                 if(maxspawned < 2)
 190                         maxspawned = 2;
 191                 arena_roundbased = autocvar_g_arena_roundbased;
 192         }
 193
 194         if(g_ca)
 195         {
 196                 ActivateTeamplay();
 197                 fraglimit_override = autocvar_g_ca_point_limit;
 198                 leadlimit_override = autocvar_g_ca_point_leadlimit;
 199                 precache_sound("ctf/red_capture.wav");
 200                 precache_sound("ctf/blue_capture.wav");
 201         }
 202         if(g_keyhunt)
 203         {
 204                 ActivateTeamplay();
 205                 fraglimit_override = autocvar_g_keyhunt_point_limit;
 206                 leadlimit_override = autocvar_g_keyhunt_point_leadlimit;
 207                 MUTATOR_ADD(gamemode_keyhunt);
 208         }
 209
 210         if(g_freezetag)
 211         {
 212                 ActivateTeamplay();
 213                 fraglimit_override = autocvar_g_freezetag_point_limit;
 214                 leadlimit_override = autocvar_g_freezetag_point_leadlimit;
 215                 MUTATOR_ADD(gamemode_freezetag);
 216         }
 217
 218         if(g_assault)
 219         {
 220                 ActivateTeamplay();
 221                 ScoreRules_assault();
 222                 have_team_spawns = -1; // request team spawns
 223         }
 224
 225         if(g_onslaught)
 226         {
 227                 ActivateTeamplay();
 228                 have_team_spawns = -1; // request team spawns
 229         }
 230
 231         if(g_race)
 232         {
 233
 234                 if(autocvar_g_race_teams)
 235                 {
 236                         ActivateTeamplay();
 237                         race_teams = bound(2, autocvar_g_race_teams, 4);
 238                         have_team_spawns = -1; // request team spawns
 239                 }
 240                 else
 241                         race_teams = 0;
 242
 243                 qualifying_override = autocvar_g_race_qualifying_timelimit_override;
 244                 fraglimit_override = autocvar_g_race_laps_limit;
 245                 leadlimit_override = 0; // currently not supported by race
 246         }
 247
 248         if(g_cts)
 249         {
 250                 g_race_qualifying = 1;
 251                 fraglimit_override = 0;
 252                 leadlimit_override = 0;
 253         }
 254
 255         if(g_nexball)
 256         {
 257         fraglimit_override = autocvar_g_nexball_goallimit;
 258         leadlimit_override = autocvar_g_nexball_goalleadlimit;
 259         ActivateTeamplay();
 260         have_team_spawns = -1; // request team spawns
 261             MUTATOR_ADD(gamemode_nexball);
 262         }
 263
 264         if(g_keepaway)
 265         {
 266                 MUTATOR_ADD(gamemode_keepaway);
 267         }
 268
 269         if(teamplay)
 270                 entcs_init();
 271
 272         cache_mutatormsg = strzone("");
 273         cache_lastmutatormsg = strzone("");
 274
 275         // enforce the server's universal frag/time limits
 276         if(!autocvar_g_campaign)
 277         {
 278                 if(fraglimit_override >= 0)
 279                         cvar_set("fraglimit", ftos(fraglimit_override));
 280                 if(timelimit_override >= 0)
 281                         cvar_set("timelimit", ftos(timelimit_override));
 282                 if(leadlimit_override >= 0)
 283                         cvar_set("leadlimit", ftos(leadlimit_override));
 284                 if(qualifying_override >= 0)
 285                         cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 286         }
 287
 288         if(g_race)
 289         {
 290                 // we need to find out the correct value for g_race_qualifying
 291                 if(autocvar_g_campaign)
 292                 {
 293                         g_race_qualifying = 1;
 294                 }
 295                 else if(!autocvar_g_campaign && autocvar_g_race_qualifying_timelimit > 0)
 296                 {
 297                         g_race_qualifying = 2;
 298                         race_fraglimit = autocvar_fraglimit;
 299                         race_leadlimit = autocvar_leadlimit;
 300                         race_timelimit = autocvar_timelimit;
 301                         cvar_set("fraglimit", "0");
 302                         cvar_set("leadlimit", "0");
 303                         cvar_set("timelimit", ftos(autocvar_g_race_qualifying_timelimit));
 304                 }
 305                 else
 306                         g_race_qualifying = 0;
 307         }
 308
 309         if(g_race || g_cts)
 310         {
 311                 if(g_race_qualifying)
 312                         independent_players = 1;
 313
 314                 ScoreRules_race();
 315         }
 316
 317         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 318 }
 319
 320 string GetClientVersionMessage() {
 321         string versionmsg;
 322         if (self.version_mismatch) {
 323                 if(self.version < autocvar_gameversion) {
 324                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
 325                 } else {
 326                         versionmsg = "^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
 327                 }
 328         } else {
 329                 versionmsg = "^2client version and server version are compatible.^8";
 330         }
 331         return versionmsg;
 332 }
 333
 334 string getwelcomemessage(void)
 335 {
 336         string s, modifications, motd;
 337
 338         ret_string = "";
 339         MUTATOR_CALLHOOK(BuildMutatorsPrettyString);
 340         modifications = ret_string;
 341
 342         if(g_minstagib)
 343                 modifications = strcat(modifications, ", MinstaGib");
 344         if(g_weaponarena)
 345         {
 346                 if(g_weaponarena_random)
 347                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
 348                 else
 349                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 350         }
 351         if(autocvar_g_start_weapon_laser == 0)
 352                 modifications = strcat(modifications, ", No start weapons");
 353         if(autocvar_sv_gravity < 800)
 354                 modifications = strcat(modifications, ", Low gravity");
 355         if(g_cloaked && !g_cts)
 356                 modifications = strcat(modifications, ", Cloaked");
 357         if(g_grappling_hook)
 358                 modifications = strcat(modifications, ", Hook");
 359         if(g_midair)
 360                 modifications = strcat(modifications, ", Midair");
 361         if(g_pinata)
 362                 modifications = strcat(modifications, ", Piñata");
 363         if(g_weapon_stay && !g_cts)
 364                 modifications = strcat(modifications, ", Weapons stay");
 365         if(g_bloodloss > 0)
 366                 modifications = strcat(modifications, ", Blood loss");
 367         if(g_jetpack)
 368                 modifications = strcat(modifications, ", Jet pack");
 369         if(autocvar_g_powerups == 0)
 370                 modifications = strcat(modifications, ", No powerups");
 371         if(autocvar_g_powerups > 0)
 372                 modifications = strcat(modifications, ", Powerups");
 373         modifications = substring(modifications, 2, strlen(modifications) - 2);
 374
 375         string versionmessage;
 376         versionmessage = GetClientVersionMessage();
 377
 378         s = strcat("This is Xonotic ", autocvar_g_xonoticversion, "\n", versionmessage);
 379         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 380
 381         if(modifications != "")
 382                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 383
 384         if (g_grappling_hook)
 385                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
 386
 387         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
 388         {
 389                 if(cache_lastmutatormsg)
 390                         strunzone(cache_lastmutatormsg);
 391                 if(cache_mutatormsg)
 392                         strunzone(cache_mutatormsg);
 393                 cache_lastmutatormsg = strzone(autocvar_g_mutatormsg);
 394                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 395         }
 396
 397         if (cache_mutatormsg != "") {
 398                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 399         }
 400
 401         motd = autocvar_sv_motd;
 402         if (motd != "") {
 403                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 404         }
 405         return s;
 406 }
 407
 408 void SetPlayerColors(entity pl, float _color)
 409 {
 410         /*string s;
 411         s = ftos(cl);
 412         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 413         pl.team = cl + 1;
 414         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 415         pl.clientcolors = 16*cl + cl;*/
 416
 417         float pants, shirt;
 418         pants = _color & 0x0F;
 419         shirt = _color & 0xF0;
 420
 421
 422         if(teamplay) {
 423                 setcolor(pl, 16*pants + pants);
 424         } else {
 425                 setcolor(pl, shirt + pants);
 426         }
 427 }
 428
 429 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 430 {
 431         float _color;
 432
 433         if(t == 4)
 434                 _color = COLOR_TEAM4 - 1;
 435         else if(t == 3)
 436                 _color = COLOR_TEAM3 - 1;
 437         else if(t == 2)
 438                 _color = COLOR_TEAM2 - 1;
 439         else
 440                 _color = COLOR_TEAM1 - 1;
 441
 442         SetPlayerColors(pl,_color);
 443
 444         if(t != s) {
 445                 LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
 446
 447                 if(!noprint)
 448                 bprint(pl.netname, "^7 has changed from ", TeamNoName(s), " to ", TeamNoName(t), "\n");
 449         }
 450
 451 }
 452
 453 // set c1...c4 to show what teams are allowed
 454 void CheckAllowedTeams (entity for_whom)
 455 {
 456         float dm;
 457         entity head;
 458         string teament_name;
 459
 460         c1 = c2 = c3 = c4 = -1;
 461         cb1 = cb2 = cb3 = cb4 = 0;
 462
 463         teament_name = string_null;
 464         if(g_onslaught)
 465         {
 466                 // onslaught is special
 467                 head = findchain(classname, "onslaught_generator");
 468                 while (head)
 469                 {
 470                         if (head.team == COLOR_TEAM1) c1 = 0;
 471                         if (head.team == COLOR_TEAM2) c2 = 0;
 472                         if (head.team == COLOR_TEAM3) c3 = 0;
 473                         if (head.team == COLOR_TEAM4) c4 = 0;
 474                         head = head.chain;
 475                 }
 476         }
 477         else if(g_domination)
 478                 teament_name = "dom_team";
 479         else if(g_ctf)
 480                 teament_name = "ctf_team";
 481         else if(g_tdm)
 482                 teament_name = "tdm_team";
 483         else if(g_nexball)
 484                 teament_name = "nexball_team";
 485         else if(g_assault)
 486                 c1 = c2 = 0; // Assault always has 2 teams
 487         else
 488         {
 489                 // cover anything else by treating it like tdm with no teams spawned
 490                 if(g_race)
 491                         dm = race_teams;
 492                 else
 493                         dm = 2;
 494
 495                 ret_float = dm;
 496                 MUTATOR_CALLHOOK(GetTeamCount);
 497                 dm = ret_float;
 498
 499                 if(dm >= 4)
 500                         c1 = c2 = c3 = c4 = 0;
 501                 else if(dm >= 3)
 502                         c1 = c2 = c3 = 0;
 503                 else
 504                         c1 = c2 = 0;
 505         }
 506
 507         // find out what teams are allowed if necessary
 508         if(teament_name)
 509         {
 510                 head = find(world, classname, teament_name);
 511                 while(head)
 512                 {
 513                         if(!(g_domination && head.netname == ""))
 514                         {
 515                                 if(head.team == COLOR_TEAM1)
 516                                         c1 = 0;
 517                                 else if(head.team == COLOR_TEAM2)
 518                                         c2 = 0;
 519                                 else if(head.team == COLOR_TEAM3)
 520                                         c3 = 0;
 521                                 else if(head.team == COLOR_TEAM4)
 522                                         c4 = 0;
 523                         }
 524                         head = find(head, classname, teament_name);
 525                 }
 526         }
 527
 528         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
 529         if(c3==-1 && c4==-1)
 530         if(autocvar_bot_vs_human && for_whom)
 531         {
 532                 if(autocvar_bot_vs_human > 0)
 533                 {
 534                         // bots are all blue
 535                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 536                                 c1 = c3 = c4 = -1;
 537                         else
 538                                 c2 = -1;
 539                 }
 540                 else
 541                 {
 542                         // bots are all red
 543                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 544                                 c2 = c3 = c4 = -1;
 545                         else
 546                                 c1 = -1;
 547                 }
 548         }
 549
 550         // if player has a forced team, ONLY allow that one
 551         if(self.team_forced == COLOR_TEAM1 && c1 >= 0)
 552                 c2 = c3 = c4 = -1;
 553         else if(self.team_forced == COLOR_TEAM2 && c2 >= 0)
 554                 c1 = c3 = c4 = -1;
 555         else if(self.team_forced == COLOR_TEAM3 && c3 >= 0)
 556                 c1 = c2 = c4 = -1;
 557         else if(self.team_forced == COLOR_TEAM4 && c4 >= 0)
 558                 c1 = c2 = c3 = -1;
 559 }
 560
 561 float PlayerValue(entity p)
 562 {
 563         if(IsTeamBalanceForced() == 1)
 564                 return 1;
 565         return 1;
 566         // FIXME: it always returns 1...
 567 }
 568
 569 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 570 // teams that are allowed will now have their player counts stored in c1...c4
 571 void GetTeamCounts(entity ignore)
 572 {
 573         entity head;
 574         float value, bvalue;
 575         // now count how many players are on each team already
 576
 577         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 578         // also remember the lowest-scoring player
 579
 580         FOR_EACH_CLIENT(head)
 581         {
 582                 float t;
 583                 if(head.classname == "player")
 584                         t = head.team;
 585                 else if(head.team_forced > 0)
 586                         t = head.team_forced; // reserve the spot
 587                 else
 588                         continue;
 589                 if(head != ignore)// && head.netname != "")
 590                 {
 591                         value = PlayerValue(head);
 592                         if(clienttype(head) == CLIENTTYPE_BOT)
 593                                 bvalue = value;
 594                         else
 595                                 bvalue = 0;
 596                         if(t == COLOR_TEAM1)
 597                         {
 598                                 if(c1 >= 0)
 599                                 {
 600                                         c1 = c1 + value;
 601                                         cb1 = cb1 + bvalue;
 602                                 }
 603                         }
 604                         if(t == COLOR_TEAM2)
 605                         {
 606                                 if(c2 >= 0)
 607                                 {
 608                                         c2 = c2 + value;
 609                                         cb2 = cb2 + bvalue;
 610                                 }
 611                         }
 612                         if(t == COLOR_TEAM3)
 613                         {
 614                                 if(c3 >= 0)
 615                                 {
 616                                         c3 = c3 + value;
 617                                         cb3 = cb3 + bvalue;
 618                                 }
 619                         }
 620                         if(t == COLOR_TEAM4)
 621                         {
 622                                 if(c4 >= 0)
 623                                 {
 624                                         c4 = c4 + value;
 625                                         cb4 = cb4 + bvalue;
 626                                 }
 627                         }
 628                 }
 629         }
 630
 631         // if the player who has a forced team has not joined yet, reserve the spot
 632         if(autocvar_g_campaign)
 633         {
 634                 switch(autocvar_g_campaign_forceteam)
 635                 {
 636                         case 1: if(c1 == cb1) ++c1; break;
 637                         case 2: if(c2 == cb2) ++c2; break;
 638                         case 3: if(c3 == cb3) ++c3; break;
 639                         case 4: if(c4 == cb4) ++c4; break;
 640                 }
 641         }
 642 }
 643
 644 // returns # of smallest team (1, 2, 3, 4)
 645 // NOTE: Assumes CheckAllowedTeams has already been called!
 646 float FindSmallestTeam(entity pl, float ignore_pl)
 647 {
 648         float totalteams, balance_type, maxc;
 649         totalteams = 0;
 650
 651         // find out what teams are available
 652         //CheckAllowedTeams();
 653
 654         // make sure there are at least 2 teams to join
 655         if(c1 >= 0)
 656                 totalteams = totalteams + 1;
 657         if(c2 >= 0)
 658                 totalteams = totalteams + 1;
 659         if(c3 >= 0)
 660                 totalteams = totalteams + 1;
 661         if(c4 >= 0)
 662                 totalteams = totalteams + 1;
 663
 664         if((autocvar_bot_vs_human || pl.team_forced > 0) && totalteams == 1)
 665                 totalteams += 1;
 666
 667         if(totalteams <= 1)
 668         {
 669                 if(autocvar_g_campaign && pl && clienttype(pl) == CLIENTTYPE_REAL)
 670                         return 1; // special case for campaign and player joining
 671                 else if(g_domination)
 672                         error("Too few teams available for domination\n");
 673                 else if(g_ctf)
 674                         error("Too few teams available for ctf\n");
 675                 else if(g_keyhunt)
 676                         error("Too few teams available for key hunt\n");
 677                 else if(g_freezetag)
 678                         error("Too few teams available for freeze tag\n");
 679                 else
 680                         error("Too few teams available for team deathmatch\n");
 681         }
 682
 683         // count how many players are in each team
 684         if(ignore_pl)
 685                 GetTeamCounts(pl);
 686         else
 687                 GetTeamCounts(world);
 688
 689         // c1...c4 now have counts of each team
 690         // figure out which is smallest, giving priority to the team the player is already on as a tie-breaker
 691
 692         // 2 gives priority to what team you're already on, 1 goes in order
 693         // 2 doesn't seem to work though...
 694         balance_type = 1;
 695
 696         if(bots_would_leave)
 697         //if(pl.classname != "player")
 698         if(clienttype(pl) != CLIENTTYPE_BOT)
 699         {
 700                 c1 -= cb1 * 255.0/256.0;
 701                 c2 -= cb2 * 255.0/256.0;
 702                 c3 -= cb3 * 255.0/256.0;
 703                 c4 -= cb4 * 255.0/256.0;
 704         }
 705         maxc = max4(c1, c2, c3, c4);
 706
 707         RandomSelection_Init();
 708         if(balance_type == 1)
 709         {
 710                 // 1: use team count, then score (note: can only use 8 significant bits of score)
 711                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + float2range01(-team1_score) / 256.0);
 712                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c2) + float2range01(-team2_score) / 256.0);
 713                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c3) + float2range01(-team3_score) / 256.0);
 714                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c4) + float2range01(-team4_score) / 256.0);
 715         }
 716         else if(balance_type == 2)
 717         {
 718                 // 1: use team count, if equal prefer own team
 719                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM1) / 512.0);
 720                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM2) / 512.0);
 721                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM3) / 512.0);
 722                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM4) / 512.0);
 723         }
 724         else if(balance_type == 3)
 725         {
 726                 // 1: use team count, then score, if equal prefer own team (probably fails due to float accuracy problems)
 727                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + float2range01(-team1_score + 0.5 * (self.team == COLOR_TEAM1)) / 256.0);
 728                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c2) + float2range01(-team2_score + 0.5 * (self.team == COLOR_TEAM2)) / 256.0);
 729                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c3) + float2range01(-team3_score + 0.5 * (self.team == COLOR_TEAM3)) / 256.0);
 730                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c4) + float2range01(-team4_score + 0.5 * (self.team == COLOR_TEAM4)) / 256.0);
 731         }
 732         return RandomSelection_chosen_float;
 733 }
 734
 735 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
 736 {
 737         float smallest, selectedteam;
 738
 739         // don't join a team if we're not playing a team game
 740         if(!teamplay)
 741                 return 0;
 742
 743         // find out what teams are available
 744         CheckAllowedTeams(pl);
 745
 746         // if we don't care what team he ends up on, put him on whatever team he entered as.
 747         // if he's not on a valid team, then let other code put him on the smallest team
 748         if(!forcebestteam)
 749         {
 750                 if(     c1 >= 0 && pl.team == COLOR_TEAM1)
 751                         selectedteam = pl.team;
 752                 else if(c2 >= 0 && pl.team == COLOR_TEAM2)
 753                         selectedteam = pl.team;
 754                 else if(c3 >= 0 && pl.team == COLOR_TEAM3)
 755                         selectedteam = pl.team;
 756                 else if(c4 >= 0 && pl.team == COLOR_TEAM4)
 757                         selectedteam = pl.team;
 758                 else
 759                         selectedteam = -1;
 760
 761                 if(selectedteam > 0)
 762                 {
 763                         if(!only_return_best)
 764                         {
 765                                 SetPlayerColors(pl, selectedteam - 1);
 766
 767                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
 768                                 // when JoinBestTeam is called by cl_client.qc/ClientConnect the player_id is 0 the log attempt is rejected
 769                                 LogTeamchange(pl.playerid, pl.team, 99);
 770                         }
 771                         return selectedteam;
 772                 }
 773                 // otherwise end up on the smallest team (handled below)
 774         }
 775
 776         smallest = FindSmallestTeam(pl, TRUE);
 777
 778         if(!only_return_best && !pl.bot_forced_team)
 779         {
 780                 TeamchangeFrags(self);
 781                 if(smallest == 1)
 782                 {
 783                         SetPlayerColors(pl, COLOR_TEAM1 - 1);
 784                 }
 785                 else if(smallest == 2)
 786                 {
 787                         SetPlayerColors(pl, COLOR_TEAM2 - 1);
 788                 }
 789                 else if(smallest == 3)
 790                 {
 791                         SetPlayerColors(pl, COLOR_TEAM3 - 1);
 792                 }
 793                 else if(smallest == 4)
 794                 {
 795                         SetPlayerColors(pl, COLOR_TEAM4 - 1);
 796                 }
 797                 else
 798                 {
 799                         error("smallest team: invalid team\n");
 800                 }
 801
 802                 LogTeamchange(pl.playerid, pl.team, 2); // log auto join
 803
 804                 if(pl.deadflag == DEAD_NO)
 805                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
 806         }
 807
 808         return smallest;
 809 }
 810
 811 //void() ctf_playerchanged;
 812 void SV_ChangeTeam(float _color)
 813 {
 814         float scolor, dcolor, steam, dteam, dbotcount, scount, dcount;
 815
 816         // in normal deathmatch we can just apply the color and we're done
 817         if(!teamplay) {
 818                 SetPlayerColors(self, _color);
 819                 return;
 820         }
 821
 822         scolor = self.clientcolors & 0x0F;
 823         dcolor = _color & 0x0F;
 824
 825         if(scolor == COLOR_TEAM1 - 1)
 826                 steam = 1;
 827         else if(scolor == COLOR_TEAM2 - 1)
 828                 steam = 2;
 829         else if(scolor == COLOR_TEAM3 - 1)
 830                 steam = 3;
 831         else // if(scolor == COLOR_TEAM4 - 1)
 832                 steam = 4;
 833         if(dcolor == COLOR_TEAM1 - 1)
 834                 dteam = 1;
 835         else if(dcolor == COLOR_TEAM2 - 1)
 836                 dteam = 2;
 837         else if(dcolor == COLOR_TEAM3 - 1)
 838                 dteam = 3;
 839         else // if(dcolor == COLOR_TEAM4 - 1)
 840                 dteam = 4;
 841
 842         CheckAllowedTeams(self);
 843
 844         if(dteam == 1 && c1 < 0) dteam = 4;
 845         if(dteam == 4 && c4 < 0) dteam = 3;
 846         if(dteam == 3 && c3 < 0) dteam = 2;
 847         if(dteam == 2 && c2 < 0) dteam = 1;
 848
 849         // not changing teams
 850         if(scolor == dcolor)
 851         {
 852                 //bprint("same team change\n");
 853                 SetPlayerTeam(self, dteam, steam, TRUE);
 854                 return;
 855         }
 856
 857         if((autocvar_g_campaign) || (autocvar_g_changeteam_banned && self.wasplayer)) {
 858                 sprint(self, "Team changes not allowed\n");
 859                 return; // changing teams is not allowed
 860         }
 861
 862         if(autocvar_g_balance_teams_prevent_imbalance)
 863         {
 864                 // only allow changing to a smaller or equal size team
 865
 866                 // find out what teams are available
 867                 //CheckAllowedTeams();
 868                 // count how many players on each team
 869                 GetTeamCounts(world);
 870
 871                 // get desired team
 872                 if(dteam == 1 && c1 >= 0)//dcolor == COLOR_TEAM1 - 1)
 873                 {
 874                         dcount = c1;
 875                         dbotcount = cb1;
 876                 }
 877                 else if(dteam == 2 && c2 >= 0)//dcolor == COLOR_TEAM2 - 1)
 878                 {
 879                         dcount = c2;
 880                         dbotcount = cb2;
 881                 }
 882                 else if(dteam == 3 && c3 >= 0)//dcolor == COLOR_TEAM3 - 1)
 883                 {
 884                         dcount = c3;
 885                         dbotcount = cb3;
 886                 }
 887                 else if(dteam == 4 && c4 >= 0)//dcolor == COLOR_TEAM4 - 1)
 888                 {
 889                         dcount = c4;
 890                         dbotcount = cb4;
 891                 }
 892                 else
 893                 {
 894                         sprint(self, "Cannot change to an invalid team\n");
 895
 896                         return;
 897                 }
 898
 899                 // get starting team
 900                 if(steam == 1)//scolor == COLOR_TEAM1 - 1)
 901                         scount = c1;
 902                 else if(steam == 2)//scolor == COLOR_TEAM2 - 1)
 903                         scount = c2;
 904                 else if(steam == 3)//scolor == COLOR_TEAM3 - 1)
 905                         scount = c3;
 906                 else // if(steam == 4)//scolor == COLOR_TEAM4 - 1)
 907                         scount = c4;
 908
 909                 if(scount) // started at a valid, nonempty team
 910                 {
 911                         // check if we're trying to change to a larger team that doens't have bots to swap with
 912                         if(dcount >= scount && dbotcount <= 0)
 913                         {
 914                                 sprint(self, "Cannot change to a larger team\n");
 915                                 return; // can't change to a larger team
 916                         }
 917                 }
 918         }
 919
 920 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
 921
 922         if(self.classname == "player" && steam != dteam)
 923         {
 924                 // reduce frags during a team change
 925                 TeamchangeFrags(self);
 926         }
 927
 928         SetPlayerTeam(self, dteam, steam, FALSE);
 929
 930         if(self.classname == "player" && steam != dteam)
 931         {
 932                 // kill player when changing teams
 933                 if(self.deadflag == DEAD_NO)
 934                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
 935         }
 936 }
 937
 938 void ShufflePlayerOutOfTeam (float source_team)
 939 {
 940         float smallestteam, smallestteam_count, steam;
 941         float lowest_bot_score, lowest_player_score;
 942         entity head, lowest_bot, lowest_player, selected;
 943
 944         smallestteam = 0;
 945         smallestteam_count = 999999999;
 946
 947         if(c1 >= 0 && c1 < smallestteam_count)
 948         {
 949                 smallestteam = 1;
 950                 smallestteam_count = c1;
 951         }
 952         if(c2 >= 0 && c2 < smallestteam_count)
 953         {
 954                 smallestteam = 2;
 955                 smallestteam_count = c2;
 956         }
 957         if(c3 >= 0 && c3 < smallestteam_count)
 958         {
 959                 smallestteam = 3;
 960                 smallestteam_count = c3;
 961         }
 962         if(c4 >= 0 && c4 < smallestteam_count)
 963         {
 964                 smallestteam = 4;
 965                 smallestteam_count = c4;
 966         }
 967
 968         if(!smallestteam)
 969         {
 970                 bprint("warning: no smallest team\n");
 971                 return;
 972         }
 973
 974         if(source_team == 1)
 975                 steam = COLOR_TEAM1;
 976         else if(source_team == 2)
 977                 steam = COLOR_TEAM2;
 978         else if(source_team == 3)
 979                 steam = COLOR_TEAM3;
 980         else // if(source_team == 4)
 981                 steam = COLOR_TEAM4;
 982
 983         lowest_bot = world;
 984         lowest_bot_score = 999999999;
 985         lowest_player = world;
 986         lowest_player_score = 999999999;
 987
 988         // find the lowest-scoring player & bot of that team
 989         FOR_EACH_PLAYER(head)
 990         {
 991                 if(head.team == steam)
 992                 {
 993                         if(head.isbot)
 994                         {
 995                                 if(head.totalfrags < lowest_bot_score)
 996                                 {
 997                                         lowest_bot = head;
 998                                         lowest_bot_score = head.totalfrags;
 999                                 }
1000                         }
1001                         else
1002                         {
1003                                 if(head.totalfrags < lowest_player_score)
1004                                 {
1005                                         lowest_player = head;
1006                                         lowest_player_score = head.totalfrags;
1007                                 }
1008                         }
1009                 }
1010         }
1011
1012         // prefers to move a bot...
1013         if(lowest_bot != world)
1014                 selected = lowest_bot;
1015         // but it will move a player if it has to
1016         else
1017                 selected = lowest_player;
1018         // don't do anything if it couldn't find anyone
1019         if(!selected)
1020         {
1021                 bprint("warning: couldn't find a player to move from team\n");
1022                 return;
1023         }
1024
1025         // smallest team gains a member
1026         if(smallestteam == 1)
1027         {
1028                 c1 = c1 + 1;
1029         }
1030         else if(smallestteam == 2)
1031         {
1032                 c2 = c2 + 1;
1033         }
1034         else if(smallestteam == 3)
1035         {
1036                 c3 = c3 + 1;
1037         }
1038         else if(smallestteam == 4)
1039         {
1040                 c4 = c4 + 1;
1041         }
1042         else
1043         {
1044                 bprint("warning: destination team invalid\n");
1045                 return;
1046         }
1047         // source team loses a member
1048         if(source_team == 1)
1049         {
1050                 c1 = c1 + 1;
1051         }
1052         else if(source_team == 2)
1053         {
1054                 c2 = c2 + 2;
1055         }
1056         else if(source_team == 3)
1057         {
1058                 c3 = c3 + 3;
1059         }
1060         else if(source_team == 4)
1061         {
1062                 c4 = c4 + 4;
1063         }
1064         else
1065         {
1066                 bprint("warning: source team invalid\n");
1067                 return;
1068         }
1069
1070         // move the player to the new team
1071         TeamchangeFrags(selected);
1072         SetPlayerTeam(selected, smallestteam, source_team, FALSE);
1073
1074         if(selected.deadflag == DEAD_NO)
1075                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
1076         centerprint(selected, strcat("You have been moved into a different team to improve team balance\nYou are now on: ", ColoredTeamName(selected.team)));
1077 }
1078
1079 void CauseRebalance(float source_team, float howmany_toomany)
1080 {
1081         if(IsTeamBalanceForced() == 1)
1082         {
1083                 bprint("Rebalancing Teams\n");
1084                 ShufflePlayerOutOfTeam(source_team);
1085         }
1086 }
1087
1088 // part of g_balance_teams_force
1089 // occasionally perform an audit of the teams to make
1090 // sure they're more or less balanced in player count.
1091 void AuditTeams()
1092 {
1093         float numplayers, numteams, smallest, toomany;
1094         float balance;
1095         balance = IsTeamBalanceForced();
1096         if(balance == 0)
1097                 return;
1098
1099         if(audit_teams_time > time)
1100                 return;
1101
1102         audit_teams_time = time + 4 + random();
1103
1104 //      bprint("Auditing teams\n");
1105
1106         CheckAllowedTeams(world);
1107         GetTeamCounts(world);
1108
1109
1110         numteams = numplayers = smallest = 0;
1111         if(c1 >= 0)
1112         {
1113                 numteams = numteams + 1;
1114                 numplayers = numplayers + c1;
1115                 smallest = c1;
1116         }
1117         if(c2 >= 0)
1118         {
1119                 numteams = numteams + 1;
1120                 numplayers = numplayers + c2;
1121                 if(c2 < smallest)
1122                         smallest = c2;
1123         }
1124         if(c3 >= 0)
1125         {
1126                 numteams = numteams + 1;
1127                 numplayers = numplayers + c3;
1128                 if(c3 < smallest)
1129                         smallest = c3;
1130         }
1131         if(c4 >= 0)
1132         {
1133                 numteams = numteams + 1;
1134                 numplayers = numplayers + c4;
1135                 if(c4 < smallest)
1136                         smallest = c4;
1137         }
1138
1139         if(numplayers <= 0)
1140                 return; // no players to move around
1141         if(numteams < 2)
1142                 return; // don't bother shuffling if for some reason there aren't any teams
1143
1144         toomany = smallest + 1;
1145
1146         if(c1 && c1 > toomany)
1147                 CauseRebalance(1, c1 - toomany);
1148         if(c2 && c2 > toomany)
1149                 CauseRebalance(2, c2 - toomany);
1150         if(c3 && c3 > toomany)
1151                 CauseRebalance(3, c3 - toomany);
1152         if(c4 && c4 > toomany)
1153                 CauseRebalance(4, c4 - toomany);
1154
1155         // if teams are still unbalanced, balance them further in the next audit,
1156         // which will happen sooner (keep doing rapid audits until things are in order)
1157         audit_teams_time = time + 0.7 + random()*0.3;
1158 }
1159
1160 // code from here on is just to support maps that don't have team entities
1161 void tdm_spawnteam (string teamname, float teamcolor)
1162 {
1163         entity e;
1164         e = spawn();
1165         e.classname = "tdm_team";
1166         e.netname = teamname;
1167         e.cnt = teamcolor;
1168         e.team = e.cnt + 1;
1169 }
1170
1171 // spawn some default teams if the map is not set up for tdm
1172 void tdm_spawnteams()
1173 {
1174         float numteams;
1175
1176         numteams = autocvar_g_tdm_teams_override;
1177         if(numteams < 2)
1178                 numteams = autocvar_g_tdm_teams;
1179         numteams = bound(2, numteams, 4);
1180
1181         tdm_spawnteam("Red", COLOR_TEAM1-1);
1182         tdm_spawnteam("Blue", COLOR_TEAM2-1);
1183         if(numteams >= 3)
1184                 tdm_spawnteam("Yellow", COLOR_TEAM3-1);
1185         if(numteams >= 4)
1186                 tdm_spawnteam("Pink", COLOR_TEAM4-1);
1187 }
1188
1189 void tdm_delayedinit()
1190 {
1191         // if no teams are found, spawn defaults
1192         if (find(world, classname, "tdm_team") == world)
1193                 tdm_spawnteams();
1194 }
1195
1196 void tdm_init()
1197 {
1198         InitializeEntity(world, tdm_delayedinit, INITPRIO_GAMETYPE);
1199 }