qcsrc/server/t_items.qc

   1 float have_pickup_item(void)
   2 {
   3         // minstagib: only allow filtered items
   4         if(g_minstagib)
   5                 if(self.classname != "minstagib")
   6                         return FALSE;
   7
   8         if(self.flags & FL_POWERUP)
   9         {
  10                 if(autocvar_g_powerups > 0)
  11                         return TRUE;
  12                 if(autocvar_g_powerups == 0)
  13                         return FALSE;
  14                 if(g_lms)
  15                         return FALSE;
  16                 if(g_ca)
  17                         return FALSE;
  18                 if(g_arena)
  19                         return FALSE;
  20         }
  21         else
  22         {
  23                 if(autocvar_g_pickup_items > 0)
  24                         return TRUE;
  25                 if(autocvar_g_pickup_items == 0)
  26                         return FALSE;
  27                 if(g_lms)
  28                         return FALSE;
  29                 if(g_ca)
  30                         return FALSE;
  31                 if(g_weaponarena)
  32                         if(!WEPSET_EMPTY_E(self) || (self.items & IT_AMMO))
  33                                 return FALSE;
  34         }
  35         return TRUE;
  36 }
  37
  38 #define ITEM_RESPAWN_TICKS 10
  39
  40 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
  41         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
  42 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
  43         // range: 10 .. respawntime + respawntimejitter
  44
  45 floatfield Item_CounterField(float it)
  46 {
  47         switch(it)
  48         {
  49                 case IT_SHELLS:      return ammo_shells;
  50                 case IT_NAILS:       return ammo_nails;
  51                 case IT_ROCKETS:     return ammo_rockets;
  52                 case IT_CELLS:       return ammo_cells;
  53                 case IT_FUEL:        return ammo_fuel;
  54                 case IT_5HP:         return health;
  55                 case IT_25HP:        return health;
  56                 case IT_HEALTH:      return health;
  57                 case IT_ARMOR_SHARD: return armorvalue;
  58                 case IT_ARMOR:       return armorvalue;
  59                 // add more things here (health, armor)
  60                 default:             error("requested item has no counter field");
  61         }
  62 }
  63
  64 string Item_CounterFieldName(float it)
  65 {
  66         switch(it)
  67         {
  68                 case IT_SHELLS:      return "shells";
  69                 case IT_NAILS:       return "nails";
  70                 case IT_ROCKETS:     return "rockets";
  71                 case IT_CELLS:       return "cells";
  72                 case IT_FUEL:        return "fuel";
  73
  74                 // add more things here (health, armor)
  75                 default:             error("requested item has no counter field name");
  76         }
  77 }
  78
  79 .float max_armorvalue;
  80 .float pickup_anyway;
  81
  82 float Item_Customize()
  83 {
  84         if(self.spawnshieldtime)
  85                 return TRUE;
  86         if(!WEPSET_CONTAINS_ALL_EE(other, self))
  87         {
  88                 self.colormod = '0 0 0';
  89                 self.glowmod = self.colormod;
  90                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
  91                 return TRUE;
  92         }
  93         else
  94         {
  95                 if(g_ghost_items)
  96                 {
  97                         self.colormod = stov(autocvar_g_ghost_items_color);
  98                         self.glowmod = self.colormod;
  99                         self.alpha = g_ghost_items;
 100                         return TRUE;
 101                 }
 102                 else
 103                         return FALSE;
 104         }
 105 }
 106
 107 void Item_Show (entity e, float mode)
 108 {
 109         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
 110         if (mode > 0)
 111         {
 112                 // make the item look normal, and be touchable
 113                 e.model = e.mdl;
 114                 e.solid = SOLID_TRIGGER;
 115                 e.colormod = '0 0 0';
 116                 self.glowmod = self.colormod;
 117                 e.alpha = 0;
 118                 e.customizeentityforclient = func_null;
 119
 120                 e.spawnshieldtime = 1;
 121         }
 122         else if (mode < 0)
 123         {
 124                 // hide the item completely
 125                 e.model = string_null;
 126                 e.solid = SOLID_NOT;
 127                 e.colormod = '0 0 0';
 128                 self.glowmod = self.colormod;
 129                 e.alpha = 0;
 130                 e.customizeentityforclient = func_null;
 131
 132                 e.spawnshieldtime = 1;
 133         }
 134         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 135         {
 136                 // make the item translucent and not touchable
 137                 e.model = e.mdl;
 138                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 139                 e.colormod = '0 0 0';
 140                 self.glowmod = self.colormod;
 141                 e.effects |= EF_STARDUST;
 142                 e.customizeentityforclient = Item_Customize;
 143
 144                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 145         }
 146         else if(g_ghost_items)
 147         {
 148                 // make the item translucent and not touchable
 149                 e.model = e.mdl;
 150                 e.solid = SOLID_NOT;
 151                 e.colormod = stov(autocvar_g_ghost_items_color);
 152                 e.glowmod = e.colormod;
 153                 e.alpha = g_ghost_items;
 154                 e.customizeentityforclient = func_null;
 155
 156                 e.spawnshieldtime = 1;
 157         }
 158         else
 159         {
 160                 // hide the item completely
 161                 e.model = string_null;
 162                 e.solid = SOLID_NOT;
 163                 e.colormod = '0 0 0';
 164                 e.glowmod = e.colormod;
 165                 e.alpha = 0;
 166                 e.customizeentityforclient = func_null;
 167
 168                 e.spawnshieldtime = 1;
 169         }
 170
 171         if (e.items & (IT_STRENGTH | IT_INVINCIBLE))
 172                 e.effects |= EF_ADDITIVE | EF_FULLBRIGHT;
 173         if (autocvar_g_nodepthtestitems)
 174                 e.effects |= EF_NODEPTHTEST;
 175         if (autocvar_g_fullbrightitems)
 176                 e.effects |= EF_FULLBRIGHT;
 177
 178         // relink entity (because solid may have changed)
 179         setorigin(e, e.origin);
 180 }
 181
 182 void Item_Respawn (void)
 183 {
 184         Item_Show(self, 1);
 185         if(!g_minstagib && self.items == IT_STRENGTH)
 186                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 187         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 188                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 189         else
 190                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
 191         setorigin (self, self.origin);
 192
 193         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 194         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 195 }
 196
 197 void Item_RespawnCountdown (void)
 198 {
 199         if(self.count >= ITEM_RESPAWN_TICKS)
 200         {
 201                 if(self.waypointsprite_attached)
 202                         WaypointSprite_Kill(self.waypointsprite_attached);
 203                 Item_Respawn();
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 self.count += 1;
 209                 if(self.count == 1)
 210                 {
 211                         string name;
 212                         vector rgb;
 213                         name = string_null;
 214                         if(g_minstagib)
 215                         {
 216                                 switch(self.items)
 217                                 {
 218                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 219                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 220                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 221                                 }
 222                         }
 223                         else
 224                         {
 225                                 switch(self.items)
 226                                 {
 227                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 228                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 229                                 }
 230                         }
 231                         switch(self.items)
 232                         {
 233                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 234                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 235                         }
 236                         if(self.flags & FL_WEAPON)
 237                         {
 238                                 entity wi = get_weaponinfo(self.weapon);
 239                                 if(wi)
 240                                 {
 241                                         name = wi.model2;
 242                                         rgb = '1 0 0';
 243                                 }
 244                         }
 245                         if(!name)
 246                         {
 247                                 print("Unknown powerup-marked item is wanting to respawn\n");
 248                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 249                         }
 250                         if(name)
 251                         {
 252                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 253                                 if(self.waypointsprite_attached)
 254                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 255                         }
 256                 }
 257                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
 258                 if(self.waypointsprite_attached)
 259                 {
 260                         WaypointSprite_Ping(self.waypointsprite_attached);
 261                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 262                 }
 263         }
 264 }
 265
 266 void Item_ScheduleRespawnIn(entity e, float t)
 267 {
 268         if((e.flags & FL_POWERUP) || WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
 269         {
 270                 e.think = Item_RespawnCountdown;
 271                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 272                 e.count = 0;
 273         }
 274         else
 275         {
 276                 e.think = Item_Respawn;
 277                 e.nextthink = time + t;
 278         }
 279 }
 280
 281 void Item_ScheduleRespawn(entity e)
 282 {
 283         if(e.respawntime > 0)
 284         {
 285                 Item_Show(e, 0);
 286                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 287         }
 288         else // if respawntime is -1, this item does not respawn
 289                 Item_Show(e, -1);
 290 }
 291
 292 void Item_ScheduleInitialRespawn(entity e)
 293 {
 294         Item_Show(e, 0);
 295         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 296 }
 297
 298 float ITEM_MODE_NONE = 0;
 299 float ITEM_MODE_HEALTH = 1;
 300 float ITEM_MODE_ARMOR = 2;
 301 float ITEM_MODE_FUEL = 3;
 302 float Item_GiveAmmoTo(entity item, entity player, .float ammofield, float ammomax, float mode)
 303 {
 304         if (!item.ammofield)
 305                 return FALSE;
 306
 307         if (item.spawnshieldtime)
 308         {
 309                 if ((player.ammofield < ammomax) || item.pickup_anyway)
 310                 {
 311                         player.ammofield = bound(player.ammofield, ammomax, player.ammofield + item.ammofield);
 312                         goto YEAH;
 313                 }
 314         }
 315         else if(g_weapon_stay == 2)
 316         {
 317                 float mi = min(item.ammofield, ammomax);
 318                 if (player.ammofield < mi)
 319                 {
 320                         player.ammofield = mi;
 321                         goto YEAH;
 322                 }
 323         }
 324
 325         return FALSE;
 326
 327 :YEAH
 328         switch(mode)
 329         {
 330                 case ITEM_MODE_FUEL:
 331                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 332                         break;
 333                 case ITEM_MODE_HEALTH:
 334                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 335                         break;
 336                 case ITEM_MODE_ARMOR:
 337                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 338                         break;
 339                 default:
 340                         break;
 341         }
 342         return TRUE;
 343 }
 344
 345 float Item_GiveTo(entity item, entity player)
 346 {
 347         float _switchweapon;
 348         float pickedup;
 349         float it;
 350         float i;
 351
 352         // if nothing happens to player, just return without taking the item
 353         pickedup = FALSE;
 354         _switchweapon = FALSE;
 355
 356         if (g_minstagib)
 357         {
 358                 float prevcells = player.ammo_cells;
 359
 360                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 361                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, 999, ITEM_MODE_NONE);
 362
 363                 if(player.ammo_cells > prevcells)
 364                 {
 365                         _switchweapon = TRUE;
 366
 367                         // play some cool sounds ;)
 368                         if (clienttype(player) == CLIENTTYPE_REAL)
 369                         {
 370                                 if(player.health <= 5)
 371                                         AnnounceTo(player, "lastsecond");
 372                                 else if(player.health < 50)
 373                                         AnnounceTo(player, "narrowly");
 374                         }
 375                         // sound not available
 376                         // else if(item.items == IT_CELLS)
 377                         //      AnnounceTo(player, "ammo");
 378
 379                         if (WEPSET_CONTAINS_EW(item, WEP_MINSTANEX))
 380                                 W_GiveWeapon (player, WEP_MINSTANEX, item.netname);
 381                         if (item.ammo_cells)
 382                                 player.ammo_cells = bound(player.ammo_cells, 999, player.ammo_cells + autocvar_g_minstagib_ammo_drop);
 383                         player.health = 100;
 384                 }
 385
 386                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 387                 {
 388                         pickedup = TRUE;
 389                         player.items |= it;
 390                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 391                 }
 392
 393                 // extralife powerup
 394                 if (item.max_health)
 395                 {
 396                         pickedup = TRUE;
 397                         // sound not available
 398                         // AnnounceTo(player, "_lives");
 399                         player.armorvalue = bound(player.armorvalue, 999, player.armorvalue + autocvar_g_minstagib_extralives);
 400                         sprint(player, "^3You picked up some extra lives\n");
 401                 }
 402
 403                 // invis powerup
 404                 if (item.strength_finished)
 405                 {
 406                         pickedup = TRUE;
 407                         // sound not available
 408                         // AnnounceTo(player, "invisible");
 409                         player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 410                 }
 411
 412                 // speed powerup
 413                 if (item.invincible_finished)
 414                 {
 415                         pickedup = TRUE;
 416                         // sound not available
 417                         // AnnounceTo(player, "speed");
 418                         player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_strength_time;
 419                 }
 420         }
 421         else
 422         {
 423                 // in case the player has autoswitch enabled do the following:
 424                 // if the player is using their best weapon before items are given, they
 425                 // probably want to switch to an even better weapon after items are given
 426                 if (player.autoswitch)
 427                 if (player.switchweapon == w_getbestweapon(player))
 428                         _switchweapon = TRUE;
 429
 430                 if not(WEPSET_CONTAINS_EW(player, player.switchweapon))
 431                         _switchweapon = TRUE;
 432
 433                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 434                 pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 435                 pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 436                 pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 437                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 438                 pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 439                 pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 440
 441                 if (item.flags & FL_WEAPON)
 442                 {
 443                         WEPSET_DECLARE_A(it);
 444                         WEPSET_COPY_AE(it, item);
 445                         WEPSET_ANDNOT_AE(it, player);
 446
 447                         if (!WEPSET_EMPTY_A(it) || (item.spawnshieldtime && self.pickup_anyway))
 448                         {
 449                                 pickedup = TRUE;
 450                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 451                                         if(WEPSET_CONTAINS_AW(it, i))
 452                                                 W_GiveWeapon (player, i, item.netname);
 453                         }
 454                 }
 455
 456                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 457                 {
 458                         pickedup = TRUE;
 459                         player.items |= it;
 460                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 461                 }
 462
 463                 if (item.strength_finished)
 464                 {
 465                         pickedup = TRUE;
 466                         player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 467                 }
 468                 if (item.invincible_finished)
 469                 {
 470                         pickedup = TRUE;
 471                         player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 472                 }
 473                 if (item.superweapons_finished)
 474                 {
 475                         pickedup = TRUE;
 476                         player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 477                 }
 478         }
 479
 480 :skip
 481         // always eat teamed entities
 482         if(item.team)
 483                 pickedup = TRUE;
 484
 485         if (!pickedup)
 486                 return 0;
 487
 488         if (_switchweapon)
 489                 if (player.switchweapon != w_getbestweapon(player))
 490                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 491
 492         return 1;
 493 }
 494
 495 void Item_Touch (void)
 496 {
 497         entity e, head;
 498
 499         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 500         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 501         {
 502                 remove(self);
 503                 return;
 504         }
 505         if (other.classname != "player")
 506                 return;
 507         if (other.deadflag)
 508                 return;
 509         if (self.solid != SOLID_TRIGGER)
 510                 return;
 511         if (self.owner == other)
 512                 return;
 513
 514         if (self.classname == "droppedweapon")
 515         {
 516                 self.strength_finished = max(0, self.strength_finished - time);
 517                 self.invincible_finished = max(0, self.invincible_finished - time);
 518                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 519         }
 520
 521         if(!Item_GiveTo(self, other))
 522         {
 523                 if (self.classname == "droppedweapon")
 524                 {
 525                         // undo what we did above
 526                         self.strength_finished += time;
 527                         self.invincible_finished += time;
 528                         self.superweapons_finished += time;
 529                 }
 530                 return;
 531         }
 532
 533         other.last_pickup = time;
 534
 535         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 536         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTN_NORM);
 537
 538         if (self.classname == "droppedweapon")
 539                 remove (self);
 540         else if not(self.spawnshieldtime)
 541                 return;
 542         else
 543         {
 544                 if(self.team)
 545                 {
 546                         RandomSelection_Init();
 547                         for(head = world; (head = findfloat(head, team, self.team)); )
 548                         {
 549                                 if(head.flags & FL_ITEM)
 550                                 {
 551                                         Item_Show(head, -1);
 552                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 553                                 }
 554                         }
 555                         e = RandomSelection_chosen_ent;
 556                 }
 557                 else
 558                         e = self;
 559                 Item_ScheduleRespawn(e);
 560         }
 561 }
 562
 563 void Item_Reset()
 564 {
 565         Item_Show(self, !self.state);
 566         setorigin (self, self.origin);
 567
 568         if(self.classname != "droppedweapon")
 569         {
 570                 self.think = SUB_Null;
 571                 self.nextthink = 0;
 572
 573                 if(self.waypointsprite_attached)
 574                         WaypointSprite_Kill(self.waypointsprite_attached);
 575
 576                 if((self.flags & FL_POWERUP) | WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // do not spawn powerups initially!
 577                         Item_ScheduleInitialRespawn(self);
 578         }
 579 }
 580
 581 void Item_FindTeam()
 582 {
 583         entity head, e;
 584
 585         if(self.effects & EF_NODRAW)
 586         {
 587                 // marker for item team search
 588                 dprint("Initializing item team ", ftos(self.team), "\n");
 589                 RandomSelection_Init();
 590                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 591                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 592                 e = RandomSelection_chosen_ent;
 593                 e.state = 0;
 594                 Item_Show(e, 1);
 595
 596                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 597                 {
 598                         if(head != e)
 599                         {
 600                                 // make it a non-spawned item
 601                                 Item_Show(head, -1);
 602                                 head.state = 1; // state 1 = initially hidden item
 603                         }
 604                         head.effects &~= EF_NODRAW;
 605                 }
 606
 607                 Item_Reset();
 608         }
 609 }
 610
 611 // Savage: used for item garbage-collection
 612 // TODO: perhaps nice special effect?
 613 void RemoveItem(void)
 614 {
 615         remove(self);
 616 }
 617
 618 // pickup evaluation functions
 619 // these functions decide how desirable an item is to the bots
 620
 621 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 622
 623 float weapon_pickupevalfunc(entity player, entity item)
 624 {
 625         float c, j, position;
 626
 627         // See if I have it already
 628         if(!WEPSET_CONTAINS_ALL_EE(player, item))
 629         {
 630                 // If I can pick it up
 631                 if(!item.spawnshieldtime)
 632                         c = 0;
 633                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 634                 {
 635                         // Skilled bots will grab more
 636                         c = bound(0, skill / 10, 1) * 0.5;
 637                 }
 638                 else
 639                         c = 0;
 640         }
 641         else
 642                 c = 1;
 643
 644         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 645         if( bot_custom_weapon && c )
 646         {
 647                 // Find the highest position on any range
 648                 position = -1;
 649                 for(j = 0; j < WEP_LAST ; ++j){
 650                         if(
 651                                         bot_weapons_far[j] == item.weapon ||
 652                                         bot_weapons_mid[j] == item.weapon ||
 653                                         bot_weapons_close[j] == item.weapon
 654                           )
 655                         {
 656                                 position = j;
 657                                 break;
 658                         }
 659                 }
 660
 661                 // Rate it
 662                 if (position >= 0 )
 663                 {
 664                         position = WEP_LAST - position;
 665                         // item.bot_pickupbasevalue is overwritten here
 666                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 667                 }
 668         }
 669
 670         return item.bot_pickupbasevalue * c;
 671 }
 672
 673 float commodity_pickupevalfunc(entity player, entity item)
 674 {
 675         float c, i, need_shells, need_nails, need_rockets, need_cells, need_fuel;
 676         entity wi;
 677         c = 0;
 678
 679         // Detect needed ammo
 680         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 681         {
 682                 wi = get_weaponinfo(i);
 683
 684                 if not(WEPSET_CONTAINS_EW(player, i))
 685                         continue;
 686
 687                 if(wi.items & IT_SHELLS)
 688                         need_shells = TRUE;
 689                 else if(wi.items & IT_NAILS)
 690                         need_nails = TRUE;
 691                 else if(wi.items & IT_ROCKETS)
 692                         need_rockets = TRUE;
 693                 else if(wi.items & IT_CELLS)
 694                         need_cells = TRUE;
 695                 else if(wi.items & IT_FUEL)
 696                         need_cells = TRUE;
 697         }
 698
 699         // TODO: figure out if the player even has the weapon this ammo is for?
 700         // may not affect strategy much though...
 701         // find out how much more ammo/armor/health the player can hold
 702         if (need_shells)
 703         if (item.ammo_shells)
 704         if (player.ammo_shells < g_pickup_shells_max)
 705                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 706         if (need_nails)
 707         if (item.ammo_nails)
 708         if (player.ammo_nails < g_pickup_nails_max)
 709                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 710         if (need_rockets)
 711         if (item.ammo_rockets)
 712         if (player.ammo_rockets < g_pickup_rockets_max)
 713                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 714         if (need_cells)
 715         if (item.ammo_cells)
 716         if (player.ammo_cells < g_pickup_cells_max)
 717                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 718         if (need_fuel)
 719         if (item.ammo_fuel)
 720         if (player.ammo_fuel < g_pickup_fuel_max)
 721                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
 722         if (item.armorvalue)
 723         if (player.armorvalue < item.max_armorvalue)
 724                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 725         if (item.health)
 726         if (player.health < item.max_health)
 727                 c = c + max(0, 1 - player.health / item.max_health);
 728
 729         return item.bot_pickupbasevalue * c;
 730 }
 731
 732
 733 .float is_item;
 734 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 735 {
 736         startitem_failed = FALSE;
 737
 738         if(self.model == "")
 739                 self.model = itemmodel;
 740         if(self.item_pickupsound == "")
 741                 self.item_pickupsound = pickupsound;
 742         if(!self.respawntime) // both need to be set
 743         {
 744                 self.respawntime = defaultrespawntime;
 745                 self.respawntimejitter = defaultrespawntimejitter;
 746         }
 747
 748         self.items = itemid;
 749         self.weapon = weaponid;
 750
 751         if(weaponid)
 752                 WEPSET_COPY_EW(self, weaponid);
 753         self.flags = FL_ITEM | itemflags;
 754
 755         if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 756         {
 757                 startitem_failed = TRUE;
 758                 remove(self);
 759                 return;
 760         }
 761
 762         // is it a dropped weapon?
 763         if (self.classname == "droppedweapon")
 764         {
 765                 self.reset = SUB_Remove;
 766                 // it's a dropped weapon
 767                 self.movetype = MOVETYPE_TOSS;
 768
 769                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 770                 self.think = RemoveItem;
 771                 self.nextthink = time + 20;
 772
 773                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
 774                 /*
 775                 if(self.items == 0)
 776                 if(WEPSET_CONTAINS_ALL_AE(WEPBIT_SUPERWEAPONS, self)) // only superweapons
 777                 if(self.ammo_nails == 0)
 778                 if(self.ammo_cells == 0)
 779                 if(self.ammo_rockets == 0)
 780                 if(self.ammo_shells == 0)
 781                 if(self.ammo_fuel == 0)
 782                 if(self.health == 0)
 783                 if(self.armorvalue == 0)
 784                 */
 785                 {
 786                         // if item is worthless after a timer, have it expire then
 787                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
 788                 }
 789
 790                 // don't drop if in a NODROP zone (such as lava)
 791                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 792                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 793                 {
 794                         startitem_failed = TRUE;
 795                         remove(self);
 796                         return;
 797                 }
 798         }
 799         else
 800         {
 801                 if(!have_pickup_item())
 802                 {
 803                         startitem_failed = TRUE;
 804                         remove (self);
 805                         return;
 806                 }
 807
 808                 self.reset = Item_Reset;
 809                 // it's a level item
 810                 if(self.spawnflags & 1)
 811                         self.noalign = 1;
 812                 if (self.noalign)
 813                         self.movetype = MOVETYPE_NONE;
 814                 else
 815                         self.movetype = MOVETYPE_TOSS;
 816                 // do item filtering according to game mode and other things
 817                 if (!self.noalign)
 818                 {
 819                         // first nudge it off the floor a little bit to avoid math errors
 820                         setorigin(self, self.origin + '0 0 1');
 821                         // set item size before we spawn a spawnfunc_waypoint
 822                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 823                                 setsize (self, '-16 -16 0', '16 16 48');
 824                         else
 825                                 setsize (self, '-16 -16 0', '16 16 32');
 826                         // note droptofloor returns FALSE if stuck/or would fall too far
 827                         droptofloor();
 828                         waypoint_spawnforitem(self);
 829                 }
 830
 831                 /*
 832                  * can't do it that way, as it would break maps
 833                  * TODO make a target_give like entity another way, that perhaps has
 834                  * the weapon name in a key
 835                 if(self.targetname)
 836                 {
 837                         // target_give not yet supported; maybe later
 838                         print("removed targeted ", self.classname, "\n");
 839                         startitem_failed = TRUE;
 840                         remove (self);
 841                         return;
 842                 }
 843                 */
 844
 845                 if(autocvar_spawn_debug >= 2)
 846                 {
 847                         entity otheritem;
 848                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 849                         {
 850                                 if(otheritem.is_item)
 851                                 {
 852                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 853                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 854                                         error("Mapper sucks.");
 855                                 }
 856                         }
 857                         self.is_item = TRUE;
 858                 }
 859
 860                 WEPSET_OR_AW(weaponsInMap, weaponid);
 861
 862                 precache_model (self.model);
 863                 precache_sound (self.item_pickupsound);
 864
 865                 precache_sound ("misc/itemrespawncountdown.wav");
 866                 if(!g_minstagib && itemid == IT_STRENGTH)
 867                         precache_sound ("misc/strength_respawn.wav");
 868                 else if(!g_minstagib && itemid == IT_INVINCIBLE)
 869                         precache_sound ("misc/shield_respawn.wav");
 870                 else
 871                         precache_sound ("misc/itemrespawn.wav");
 872
 873                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
 874                         self.target = "###item###"; // for finding the nearest item using find()
 875         }
 876
 877         self.bot_pickup = TRUE;
 878         self.bot_pickupevalfunc = pickupevalfunc;
 879         self.bot_pickupbasevalue = pickupbasevalue;
 880         self.mdl = self.model;
 881         self.netname = itemname;
 882         self.touch = Item_Touch;
 883         setmodel (self, self.mdl); // precision set below
 884         self.effects |= EF_LOWPRECISION;
 885         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 886                 setsize (self, '-16 -16 0', '16 16 48');
 887         else
 888                 setsize (self, '-16 -16 0', '16 16 32');
 889         if(itemflags & FL_WEAPON)
 890                 self.modelflags |= MF_ROTATE;
 891
 892         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 893         if (itemflags & FL_WEAPON)
 894         {
 895                 // neutral team color for pickup weapons
 896                 self.colormap = 1024; // color shirt=0 pants=0 grey
 897         }
 898
 899         self.state = 0;
 900         if(self.team)
 901         {
 902                 if(!self.cnt)
 903                         self.cnt = 1; // item probability weight
 904                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 905                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 906         }
 907         else
 908                 Item_Reset();
 909 }
 910
 911 /* replace items in minstagib
 912  * IT_STRENGTH   = invisibility
 913  * IT_NAILS      = extra lives
 914  * IT_INVINCIBLE = speed
 915  */
 916 void minstagib_items (float itemid)
 917 {
 918         float rnd;
 919         self.classname = "minstagib";
 920
 921         // replace rocket launchers and nex guns with ammo cells
 922         if (itemid == IT_CELLS)
 923         {
 924                 self.ammo_cells = autocvar_g_minstagib_ammo_drop;
 925                 StartItem ("models/items/a_cells.md3",
 926                         "misc/itempickup.wav", 45, 0,
 927                         "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 928                 return;
 929         }
 930
 931         // randomize
 932         rnd = random() * 3;
 933         if (rnd <= 1)
 934                 itemid = IT_STRENGTH;
 935         else if (rnd <= 2)
 936                 itemid = IT_NAILS;
 937         else
 938                 itemid = IT_INVINCIBLE;
 939
 940         // replace with invis
 941         if (itemid == IT_STRENGTH)
 942         {
 943                 if(!self.strength_finished)
 944                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
 945                 StartItem ("models/items/g_strength.md3",
 946                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 947                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 948         }
 949         // replace with extra lives
 950         if (itemid == IT_NAILS)
 951         {
 952                 self.max_health = 1;
 953                 StartItem ("models/items/g_h100.md3",
 954                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 955                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 956         }
 957         // replace with speed
 958         if (itemid == IT_INVINCIBLE)
 959         {
 960                 if(!self.invincible_finished)
 961                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
 962                 StartItem ("models/items/g_invincible.md3",
 963                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 964                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 965         }
 966 }
 967
 968 float minst_no_auto_cells;
 969 void minst_remove_item (void) {
 970         if(minst_no_auto_cells)
 971                 remove(self);
 972 }
 973
 974 float weaponswapping;
 975 float internalteam;
 976
 977 void weapon_defaultspawnfunc(float wpn)
 978 {
 979         entity e;
 980         float t;
 981         var .float ammofield;
 982         string s;
 983         entity oldself;
 984         float i, j;
 985         float f;
 986
 987         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
 988         {
 989                 e = get_weaponinfo(wpn);
 990                 s = W_Apply_Weaponreplace(e.netname);
 991                 ret_string = s;
 992                 other = e;
 993                 MUTATOR_CALLHOOK(SetWeaponreplace);
 994                 s = ret_string;
 995                 if(s == "")
 996                 {
 997                         remove(self);
 998                         startitem_failed = TRUE;
 999                         return;
1000                 }
1001                 t = tokenize_console(s);
1002                 if(t >= 2)
1003                 {
1004                         self.team = --internalteam;
1005                         oldself = self;
1006                         for(i = 1; i < t; ++i)
1007                         {
1008                                 s = argv(i);
1009                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1010                                 {
1011                                         e = get_weaponinfo(j);
1012                                         if(e.netname == s)
1013                                         {
1014                                                 self = spawn();
1015                                                 copyentity(oldself, self);
1016                                                 self.classname = "replacedweapon";
1017                                                 weapon_defaultspawnfunc(j);
1018                                                 break;
1019                                         }
1020                                 }
1021                                 if(j > WEP_LAST)
1022                                 {
1023                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1024                                 }
1025                         }
1026                         self = oldself;
1027                 }
1028                 if(t >= 1) // always the case!
1029                 {
1030                         s = argv(0);
1031                         wpn = 0;
1032                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1033                         {
1034                                 e = get_weaponinfo(j);
1035                                 if(e.netname == s)
1036                                 {
1037                                         wpn = j;
1038                                         break;
1039                                 }
1040                         }
1041                         if(j > WEP_LAST)
1042                         {
1043                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1044                         }
1045                 }
1046                 if(wpn == 0)
1047                 {
1048                         remove(self);
1049                         startitem_failed = TRUE;
1050                         return;
1051                 }
1052         }
1053
1054         e = get_weaponinfo(wpn);
1055
1056         if(!self.respawntime)
1057         {
1058                 if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1059                 {
1060                         self.respawntime = g_pickup_respawntime_superweapon;
1061                         self.respawntimejitter = g_pickup_respawntimejitter_superweapon;
1062                 }
1063                 else
1064                 {
1065                         self.respawntime = g_pickup_respawntime_weapon;
1066                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
1067                 }
1068         }
1069
1070         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1071                 if(!self.superweapons_finished)
1072                         self.superweapons_finished = autocvar_g_balance_superweapons_time;
1073
1074         if(e.items)
1075         {
1076                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1077                 {
1078                         if(e.items & j)
1079                         {
1080                                 ammofield = Item_CounterField(j);
1081                                 if(!self.ammofield)
1082                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1083                         }
1084                 }
1085         }
1086
1087         // pickup anyway
1088         if(g_pickup_weapons_anyway)
1089                 self.pickup_anyway = TRUE;
1090
1091         f = FL_WEAPON;
1092
1093         // no weapon-stay on superweapons
1094         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1095                 f |= FL_NO_WEAPON_STAY;
1096
1097         // weapon stay isn't supported for teamed weapons
1098         if(self.team)
1099                 f |= FL_NO_WEAPON_STAY;
1100
1101         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapon, f, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1102         if (self.modelindex) // don't precache if self was removed
1103                 weapon_action(e.weapon, WR_PRECACHE);
1104 }
1105
1106 void spawnfunc_weapon_shotgun (void);
1107 void spawnfunc_weapon_uzi (void) {
1108         if(autocvar_sv_q3acompat_machineshotgunswap)
1109         if(self.classname != "droppedweapon")
1110         {
1111                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1112                 return;
1113         }
1114         weapon_defaultspawnfunc(WEP_UZI);
1115 }
1116
1117 void spawnfunc_weapon_shotgun (void) {
1118         if(autocvar_sv_q3acompat_machineshotgunswap)
1119         if(self.classname != "droppedweapon")
1120         {
1121                 weapon_defaultspawnfunc(WEP_UZI);
1122                 return;
1123         }
1124         weapon_defaultspawnfunc(WEP_SHOTGUN);
1125 }
1126
1127 void spawnfunc_weapon_nex (void)
1128 {
1129         if (g_minstagib)
1130         {
1131                 minstagib_items(IT_CELLS);
1132                 self.think = minst_remove_item;
1133                 self.nextthink = time;
1134                 return;
1135         }
1136         weapon_defaultspawnfunc(WEP_NEX);
1137 }
1138
1139 void spawnfunc_weapon_minstanex (void)
1140 {
1141         if (g_minstagib)
1142         {
1143                 minstagib_items(IT_CELLS);
1144                 self.think = minst_remove_item;
1145                 self.nextthink = time;
1146                 return;
1147         }
1148         weapon_defaultspawnfunc(WEP_MINSTANEX);
1149 }
1150
1151 void spawnfunc_weapon_rocketlauncher (void)
1152 {
1153         if (g_minstagib)
1154         {
1155                 minstagib_items(IT_CELLS); // replace rocketlauncher with cells
1156                 self.think = minst_remove_item;
1157                 self.nextthink = time;
1158                 return;
1159         }
1160         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1161 }
1162
1163 void spawnfunc_item_rockets (void) {
1164         if(!self.ammo_rockets)
1165                 self.ammo_rockets = g_pickup_rockets;
1166         if(!self.pickup_anyway)
1167                 self.pickup_anyway = g_pickup_ammo_anyway;
1168         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1169 }
1170
1171 void spawnfunc_item_shells (void);
1172 void spawnfunc_item_bullets (void) {
1173         if(!weaponswapping)
1174         if(autocvar_sv_q3acompat_machineshotgunswap)
1175         if(self.classname != "droppedweapon")
1176         {
1177                 weaponswapping = TRUE;
1178                 spawnfunc_item_shells();
1179                 weaponswapping = FALSE;
1180                 return;
1181         }
1182
1183         if(!self.ammo_nails)
1184                 self.ammo_nails = g_pickup_nails;
1185         if(!self.pickup_anyway)
1186                 self.pickup_anyway = g_pickup_ammo_anyway;
1187         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1188 }
1189
1190 void spawnfunc_item_cells (void) {
1191         if(!self.ammo_cells)
1192                 self.ammo_cells = g_pickup_cells;
1193         if(!self.pickup_anyway)
1194                 self.pickup_anyway = g_pickup_ammo_anyway;
1195         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1196 }
1197
1198 void spawnfunc_item_shells (void) {
1199         if(!weaponswapping)
1200         if(autocvar_sv_q3acompat_machineshotgunswap)
1201         if(self.classname != "droppedweapon")
1202         {
1203                 weaponswapping = TRUE;
1204                 spawnfunc_item_bullets();
1205                 weaponswapping = FALSE;
1206                 return;
1207         }
1208
1209         if(!self.ammo_shells)
1210                 self.ammo_shells = g_pickup_shells;
1211         if(!self.pickup_anyway)
1212                 self.pickup_anyway = g_pickup_ammo_anyway;
1213         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1214 }
1215
1216 void spawnfunc_item_armor_small (void) {
1217         if(!self.armorvalue)
1218                 self.armorvalue = g_pickup_armorsmall;
1219         if(!self.max_armorvalue)
1220                 self.max_armorvalue = g_pickup_armorsmall_max;
1221         if(!self.pickup_anyway)
1222                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1223         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1224 }
1225
1226 void spawnfunc_item_armor_medium (void) {
1227         if(!self.armorvalue)
1228                 self.armorvalue = g_pickup_armormedium;
1229         if(!self.max_armorvalue)
1230                 self.max_armorvalue = g_pickup_armormedium_max;
1231         if(!self.pickup_anyway)
1232                 self.pickup_anyway = g_pickup_armormedium_anyway;
1233         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1234 }
1235
1236 void spawnfunc_item_armor_big (void) {
1237         if(!self.armorvalue)
1238                 self.armorvalue = g_pickup_armorbig;
1239         if(!self.max_armorvalue)
1240                 self.max_armorvalue = g_pickup_armorbig_max;
1241         if(!self.pickup_anyway)
1242                 self.pickup_anyway = g_pickup_armorbig_anyway;
1243         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1244 }
1245
1246 void spawnfunc_item_armor_large (void) {
1247         if(!self.armorvalue)
1248                 self.armorvalue = g_pickup_armorlarge;
1249         if(!self.max_armorvalue)
1250                 self.max_armorvalue = g_pickup_armorlarge_max;
1251         if(!self.pickup_anyway)
1252                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1253         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1254 }
1255
1256 void spawnfunc_item_health_small (void) {
1257         if(!self.max_health)
1258                 self.max_health = g_pickup_healthsmall_max;
1259         if(!self.health)
1260                 self.health = g_pickup_healthsmall;
1261         if(!self.pickup_anyway)
1262                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1263         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1264 }
1265
1266 void spawnfunc_item_health_medium (void) {
1267         if(!self.max_health)
1268                 self.max_health = g_pickup_healthmedium_max;
1269         if(!self.health)
1270                 self.health = g_pickup_healthmedium;
1271         if(!self.pickup_anyway)
1272                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1273         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1274 }
1275
1276 void spawnfunc_item_health_large (void) {
1277         if(!self.max_health)
1278                 self.max_health = g_pickup_healthlarge_max;
1279         if(!self.health)
1280                 self.health = g_pickup_healthlarge;
1281         if(!self.pickup_anyway)
1282                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1283         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1284 }
1285
1286 void spawnfunc_item_health_mega (void) {
1287         if(g_minstagib) {
1288                 minstagib_items(IT_NAILS);
1289         } else {
1290                 if(!self.max_health)
1291                         self.max_health = g_pickup_healthmega_max;
1292                 if(!self.health)
1293                         self.health = g_pickup_healthmega;
1294                 if(!self.pickup_anyway)
1295                         self.pickup_anyway = g_pickup_healthmega_anyway;
1296                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1297         }
1298 }
1299
1300 // support old misnamed entities
1301 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1302 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1303 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1304 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1305 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1306
1307 void spawnfunc_item_strength (void) {
1308         if(g_minstagib) {
1309                 minstagib_items(IT_STRENGTH);
1310         } else {
1311                 precache_sound("weapons/strength_fire.wav");
1312                 if(!self.strength_finished)
1313                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1314                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1315         }
1316 }
1317
1318 void spawnfunc_item_invincible (void) {
1319         if(g_minstagib) {
1320                 minstagib_items(IT_INVINCIBLE);
1321         } else {
1322                 if(!self.invincible_finished)
1323                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1324                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1325         }
1326 }
1327
1328 void spawnfunc_item_minst_cells (void) {
1329         if (g_minstagib)
1330         {
1331                 minst_no_auto_cells = 1;
1332                 minstagib_items(IT_CELLS);
1333         }
1334         else
1335                 remove(self);
1336 }
1337
1338 // compatibility:
1339 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1340
1341 float GiveItems(entity e, float beginarg, float endarg);
1342 void target_items_use (void)
1343 {
1344         if(activator.classname == "droppedweapon")
1345         {
1346                 EXACTTRIGGER_TOUCH;
1347                 remove(activator);
1348                 return;
1349         }
1350
1351         if(activator.classname != "player")
1352                 return;
1353         if(activator.deadflag != DEAD_NO)
1354                 return;
1355         EXACTTRIGGER_TOUCH;
1356
1357         entity e;
1358         for(e = world; (e = find(e, classname, "droppedweapon")); )
1359                 if(e.enemy == activator)
1360                         remove(e);
1361
1362         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1363                 centerprint(activator, self.message);
1364 }
1365
1366 void spawnfunc_target_items (void)
1367 {
1368         float n, i, j;
1369         entity e;
1370
1371         self.use = target_items_use;
1372         if(!self.strength_finished)
1373                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1374         if(!self.invincible_finished)
1375                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1376         if(!self.superweapons_finished)
1377                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1378
1379         precache_sound("misc/itempickup.wav");
1380         precache_sound("misc/megahealth.wav");
1381         precache_sound("misc/armor25.wav");
1382         precache_sound("misc/powerup.wav");
1383         precache_sound("misc/poweroff.wav");
1384         precache_sound("weapons/weaponpickup.wav");
1385
1386         n = tokenize_console(self.netname);
1387         if(argv(0) == "give")
1388         {
1389                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1390         }
1391         else
1392         {
1393                 for(i = 0; i < n; ++i)
1394                 {
1395                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1396                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1397                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1398                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1399                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1400                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1401                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1402                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1403                         else
1404                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1405                         {
1406                                 e = get_weaponinfo(j);
1407                                 if(argv(i) == e.netname)
1408                                 {
1409                                         WEPSET_OR_EW(self, j);
1410                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1411                                                 weapon_action(e.weapon, WR_PRECACHE);
1412                                         break;
1413                                 }
1414                         }
1415                         if(j > WEP_LAST)
1416                                 print("target_items: invalid item ", argv(i), "\n");
1417                 }
1418
1419                 string itemprefix, valueprefix;
1420                 if(self.spawnflags == 0)
1421                 {
1422                         itemprefix = "";
1423                         valueprefix = "";
1424                 }
1425                 else if(self.spawnflags == 1)
1426                 {
1427                         itemprefix = "max ";
1428                         valueprefix = "max ";
1429                 }
1430                 else if(self.spawnflags == 2)
1431                 {
1432                         itemprefix = "min ";
1433                         valueprefix = "min ";
1434                 }
1435                 else if(self.spawnflags == 4)
1436                 {
1437                         itemprefix = "minus ";
1438                         valueprefix = "max ";
1439                 }
1440                 else
1441                         error("invalid spawnflags");
1442
1443                 self.netname = "";
1444                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1445                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1446                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1447                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1448                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1449                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1450                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1451                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1452                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1453                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1454                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1455                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1456                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1457                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1458                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1459                 {
1460                         e = get_weaponinfo(j);
1461                         if(e.weapon)
1462                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, WEPSET_CONTAINS_EW(self, j), e.netname);
1463                 }
1464         }
1465         self.netname = strzone(self.netname);
1466         //print(self.netname, "\n");
1467
1468         n = tokenize_console(self.netname);
1469         for(i = 0; i < n; ++i)
1470         {
1471                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1472                 {
1473                         e = get_weaponinfo(j);
1474                         if(argv(i) == e.netname)
1475                         {
1476                                 weapon_action(e.weapon, WR_PRECACHE);
1477                                 break;
1478                         }
1479                 }
1480         }
1481 }
1482
1483 void spawnfunc_item_fuel(void)
1484 {
1485         if(!self.ammo_fuel)
1486                 self.ammo_fuel = g_pickup_fuel;
1487         if(!self.pickup_anyway)
1488                 self.pickup_anyway = g_pickup_ammo_anyway;
1489         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1490 }
1491
1492 void spawnfunc_item_fuel_regen(void)
1493 {
1494         if(start_items & IT_FUEL_REGEN)
1495         {
1496                 spawnfunc_item_fuel();
1497                 return;
1498         }
1499         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1500 }
1501
1502 void spawnfunc_item_jetpack(void)
1503 {
1504         if(g_grappling_hook)
1505                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1506         if(!self.ammo_fuel)
1507                 self.ammo_fuel = g_pickup_fuel_jetpack;
1508         if(start_items & IT_JETPACK)
1509         {
1510                 spawnfunc_item_fuel();
1511                 return;
1512         }
1513         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1514 }
1515
1516
1517 #define OP_SET 0
1518 #define OP_MIN 1
1519 #define OP_MAX 2
1520 #define OP_PLUS 3
1521 #define OP_MINUS 4
1522
1523 float GiveWeapon(entity e, float wpn, float op, float val)
1524 {
1525         float v0, v1;
1526         v0 = WEPSET_CONTAINS_EW(e, wpn);
1527         switch(op)
1528         {
1529                 case OP_SET:
1530                         if(val > 0)
1531                                 WEPSET_OR_EW(e, wpn);
1532                         else
1533                                 WEPSET_ANDNOT_EW(e, wpn);
1534                         break;
1535                 case OP_MIN:
1536                 case OP_PLUS:
1537                         if(val > 0)
1538                                 WEPSET_OR_EW(e, wpn);
1539                         break;
1540                 case OP_MAX:
1541                         if(val <= 0)
1542                                 WEPSET_ANDNOT_EW(e, wpn);
1543                         break;
1544                 case OP_MINUS:
1545                         if(val > 0)
1546                                 WEPSET_ANDNOT_EW(e, wpn);
1547                         break;
1548         }
1549         v1 = WEPSET_CONTAINS_EW(e, wpn);
1550         return (v0 != v1);
1551 }
1552
1553 float GiveBit(entity e, .float fld, float bit, float op, float val)
1554 {
1555         float v0, v1;
1556         v0 = (e.fld & bit);
1557         switch(op)
1558         {
1559                 case OP_SET:
1560                         if(val > 0)
1561                                 e.fld |= bit;
1562                         else
1563                                 e.fld &~= bit;
1564                         break;
1565                 case OP_MIN:
1566                 case OP_PLUS:
1567                         if(val > 0)
1568                                 e.fld |= bit;
1569                         break;
1570                 case OP_MAX:
1571                         if(val <= 0)
1572                                 e.fld &~= bit;
1573                         break;
1574                 case OP_MINUS:
1575                         if(val > 0)
1576                                 e.fld &~= bit;
1577                         break;
1578         }
1579         v1 = (e.fld & bit);
1580         return (v0 != v1);
1581 }
1582
1583 float GiveValue(entity e, .float fld, float op, float val)
1584 {
1585         float v0, v1;
1586         v0 = e.fld;
1587         switch(op)
1588         {
1589                 case OP_SET:
1590                         e.fld = val;
1591                         break;
1592                 case OP_MIN:
1593                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1594                         break;
1595                 case OP_MAX:
1596                         e.fld = min(e.fld, val);
1597                         break;
1598                 case OP_PLUS:
1599                         e.fld += val;
1600                         break;
1601                 case OP_MINUS:
1602                         e.fld -= val;
1603                         break;
1604         }
1605         v1 = e.fld;
1606         return (v0 != v1);
1607 }
1608
1609 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1610 {
1611         if(v1 == v0)
1612                 return;
1613         if(v1 <= v0 - t)
1614         {
1615                 if(snd_decr != "")
1616                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1617         }
1618         else if(v0 >= v0 + t)
1619         {
1620                 if(snd_incr != "")
1621                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1622         }
1623 }
1624
1625 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1626 {
1627         if(v0 < v1)
1628                 e.rotfield = max(e.rotfield, time + rottime);
1629         else if(v0 > v1)
1630                 e.regenfield = max(e.regenfield, time + regentime);
1631 }
1632
1633 #define PREGIVE_WEAPONS(e) WEPSET_DECLARE_A(save_weapons); WEPSET_COPY_AE(save_weapons, e)
1634 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1635 #define POSTGIVE_WEAPON(e,b,snd_incr,snd_decr) GiveSound((e), WEPSET_CONTAINS_AW(save_weapons, b), WEPSET_CONTAINS_EW(e, b), 0, snd_incr, snd_decr)
1636 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1637 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1638 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1639
1640 float GiveItems(entity e, float beginarg, float endarg)
1641 {
1642         float got, i, j, val, op;
1643         float _switchweapon;
1644         entity wi;
1645         string cmd;
1646
1647         val = 999;
1648         op = OP_SET;
1649
1650         got = 0;
1651
1652         _switchweapon = FALSE;
1653         if (e.autoswitch)
1654                 if (e.switchweapon == w_getbestweapon(e))
1655                         _switchweapon = TRUE;
1656
1657         e.strength_finished = max(0, e.strength_finished - time);
1658         e.invincible_finished = max(0, e.invincible_finished - time);
1659         e.superweapons_finished = max(0, e.superweapons_finished - time);
1660
1661         PREGIVE(e, items);
1662         PREGIVE_WEAPONS(e);
1663         PREGIVE(e, strength_finished);
1664         PREGIVE(e, invincible_finished);
1665         PREGIVE(e, superweapons_finished);
1666         PREGIVE(e, ammo_nails);
1667         PREGIVE(e, ammo_cells);
1668         PREGIVE(e, ammo_shells);
1669         PREGIVE(e, ammo_rockets);
1670         PREGIVE(e, ammo_fuel);
1671         PREGIVE(e, armorvalue);
1672         PREGIVE(e, health);
1673
1674         for(i = beginarg; i < endarg; ++i)
1675         {
1676                 cmd = argv(i);
1677
1678                 if(cmd == "0" || stof(cmd))
1679                 {
1680                         val = stof(cmd);
1681                         continue;
1682                 }
1683                 switch(cmd)
1684                 {
1685                         case "no":
1686                                 op = OP_MAX;
1687                                 val = 0;
1688                                 continue;
1689                         case "max":
1690                                 op = OP_MAX;
1691                                 continue;
1692                         case "min":
1693                                 op = OP_MIN;
1694                                 continue;
1695                         case "plus":
1696                                 op = OP_PLUS;
1697                                 continue;
1698                         case "minus":
1699                                 op = OP_MINUS;
1700                                 continue;
1701                         case "ALL":
1702                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1703                                 got += GiveValue(e, strength_finished, op, val);
1704                                 got += GiveValue(e, invincible_finished, op, val);
1705                                 got += GiveValue(e, superweapons_finished, op, val);
1706                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1707                         case "all":
1708                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1709                                 got += GiveValue(e, health, op, val);
1710                                 got += GiveValue(e, armorvalue, op, val);
1711                         case "allweapons":
1712                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1713                                 {
1714                                         wi = get_weaponinfo(j);
1715                                         if(wi.weapon)
1716                                                 if not(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED)
1717                                                         got += GiveWeapon(e, j, op, val);
1718                                 }
1719                         case "allammo":
1720                                 got += GiveValue(e, ammo_cells, op, val);
1721                                 got += GiveValue(e, ammo_shells, op, val);
1722                                 got += GiveValue(e, ammo_nails, op, val);
1723                                 got += GiveValue(e, ammo_rockets, op, val);
1724                                 got += GiveValue(e, ammo_fuel, op, val);
1725                                 break;
1726                         case "unlimited_ammo":
1727                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1728                                 break;
1729                         case "unlimited_weapon_ammo":
1730                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1731                                 break;
1732                         case "unlimited_superweapons":
1733                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1734                                 break;
1735                         case "jetpack":
1736                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1737                                 break;
1738                         case "fuel_regen":
1739                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1740                                 break;
1741                         case "strength":
1742                                 got += GiveValue(e, strength_finished, op, val);
1743                                 break;
1744                         case "invincible":
1745                                 got += GiveValue(e, invincible_finished, op, val);
1746                                 break;
1747                         case "superweapons":
1748                                 got += GiveValue(e, superweapons_finished, op, val);
1749                                 break;
1750                         case "cells":
1751                                 got += GiveValue(e, ammo_cells, op, val);
1752                                 break;
1753                         case "shells":
1754                                 got += GiveValue(e, ammo_shells, op, val);
1755                                 break;
1756                         case "nails":
1757                         case "bullets":
1758                                 got += GiveValue(e, ammo_nails, op, val);
1759                                 break;
1760                         case "rockets":
1761                                 got += GiveValue(e, ammo_rockets, op, val);
1762                                 break;
1763                         case "health":
1764                                 got += GiveValue(e, health, op, val);
1765                                 break;
1766                         case "armor":
1767                                 got += GiveValue(e, armorvalue, op, val);
1768                                 break;
1769                         case "fuel":
1770                                 got += GiveValue(e, ammo_fuel, op, val);
1771                                 break;
1772                         default:
1773                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1774                                 {
1775                                         wi = get_weaponinfo(j);
1776                                         if(cmd == wi.netname)
1777                                         {
1778                                                 got += GiveWeapon(e, j, op, val);
1779                                                 break;
1780                                         }
1781                                 }
1782                                 if(j > WEP_LAST)
1783                                         print("give: invalid item ", cmd, "\n");
1784                                 break;
1785                 }
1786                 val = 999;
1787                 op = OP_SET;
1788         }
1789
1790         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1791         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1792         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1793         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1794         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1795         {
1796                 wi = get_weaponinfo(j);
1797                 if(wi.weapon)
1798                 {
1799                         POSTGIVE_WEAPON(e, j, "weapons/weaponpickup.wav", string_null);
1800                         if not(WEPSET_CONTAINS_AW(save_weapons, j))
1801                                 if(WEPSET_CONTAINS_EW(e, j))
1802                                         weapon_action(wi.weapon, WR_PRECACHE);
1803                 }
1804         }
1805         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1806         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1807         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1808         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1809         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1810         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1811         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1812         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1813         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1814
1815         if(e.superweapons_finished <= 0)
1816                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1817                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1818
1819         if (g_minstagib)
1820         {
1821                 e.health = bound(0, e.health, 100);
1822                 e.armorvalue = bound(0, e.armorvalue, 999);
1823         }
1824
1825         if(e.strength_finished <= 0)
1826                 e.strength_finished = 0;
1827         else
1828                 e.strength_finished += time;
1829         if(e.invincible_finished <= 0)
1830                 e.invincible_finished = 0;
1831         else
1832                 e.invincible_finished += time;
1833         if(e.superweapons_finished <= 0)
1834                 e.superweapons_finished = 0;
1835         else
1836                 e.superweapons_finished += time;
1837
1838         if not(WEPSET_CONTAINS_EW(e, e.switchweapon))
1839                 _switchweapon = TRUE;
1840         if(_switchweapon)
1841                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1842
1843         return got;
1844 }