qcsrc/server/t_items.qc

   1 #define ITEM_RESPAWN_TICKS 10
   2
   3 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
   4         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
   5 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
   6         // range: 10 .. respawntime + respawntimejitter
   7
   8 floatfield Item_CounterField(float it)
   9 {
  10         switch(it)
  11         {
  12                 case IT_SHELLS:      return ammo_shells;
  13                 case IT_NAILS:       return ammo_nails;
  14                 case IT_ROCKETS:     return ammo_rockets;
  15                 case IT_CELLS:       return ammo_cells;
  16                 case IT_FUEL:        return ammo_fuel;
  17                 case IT_5HP:         return health;
  18                 case IT_25HP:        return health;
  19                 case IT_HEALTH:      return health;
  20                 case IT_ARMOR_SHARD: return armorvalue;
  21                 case IT_ARMOR:       return armorvalue;
  22                 // add more things here (health, armor)
  23                 default:             error("requested item has no counter field");
  24         }
  25 }
  26
  27 string Item_CounterFieldName(float it)
  28 {
  29         switch(it)
  30         {
  31                 case IT_SHELLS:      return "shells";
  32                 case IT_NAILS:       return "nails";
  33                 case IT_ROCKETS:     return "rockets";
  34                 case IT_CELLS:       return "cells";
  35                 case IT_FUEL:        return "fuel";
  36
  37                 // add more things here (health, armor)
  38                 default:             error("requested item has no counter field name");
  39         }
  40 }
  41
  42 .float max_armorvalue;
  43 .float pickup_anyway;
  44
  45 float Item_Customize()
  46 {
  47         if(self.spawnshieldtime)
  48                 return TRUE;
  49         if(self.weapons != (self.weapons & other.weapons))
  50         {
  51                 self.colormod = '0 0 0';
  52                 self.glowmod = self.colormod;
  53                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
  54                 return TRUE;
  55         }
  56         else
  57         {
  58                 if(g_ghost_items)
  59                 {
  60                         self.colormod = stov(autocvar_g_ghost_items_color);
  61                         self.glowmod = self.colormod;
  62                         self.alpha = g_ghost_items;
  63                         return TRUE;
  64                 }
  65                 else
  66                         return FALSE;
  67         }
  68 }
  69
  70 void Item_Show (entity e, float mode)
  71 {
  72         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
  73         if (mode > 0)
  74         {
  75                 // make the item look normal, and be touchable
  76                 e.model = e.mdl;
  77                 e.solid = SOLID_TRIGGER;
  78                 e.colormod = '0 0 0';
  79                 self.glowmod = self.colormod;
  80                 e.alpha = 0;
  81                 e.customizeentityforclient = func_null;
  82
  83                 e.spawnshieldtime = 1;
  84         }
  85         else if (mode < 0)
  86         {
  87                 // hide the item completely
  88                 e.model = string_null;
  89                 e.solid = SOLID_NOT;
  90                 e.colormod = '0 0 0';
  91                 self.glowmod = self.colormod;
  92                 e.alpha = 0;
  93                 e.customizeentityforclient = func_null;
  94
  95                 e.spawnshieldtime = 1;
  96         }
  97         else if((e.flags & FL_WEAPON) && (g_weapon_stay == 3))
  98         {
  99                 // make the item translucent and not touchable
 100                 e.model = e.mdl;
 101                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 102                 e.colormod = '0 0 0';
 103                 self.glowmod = self.colormod;
 104                 e.effects |= EF_STARDUST;
 105                 e.customizeentityforclient = Item_Customize;
 106
 107                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 108         }
 109         else if(g_ghost_items)
 110         {
 111                 // make the item translucent and not touchable
 112                 e.model = e.mdl;
 113                 e.solid = SOLID_NOT;
 114                 e.colormod = stov(autocvar_g_ghost_items_color);
 115                 e.glowmod = e.colormod;
 116                 e.alpha = g_ghost_items;
 117                 e.customizeentityforclient = func_null;
 118
 119                 e.spawnshieldtime = 1;
 120         }
 121         else
 122         {
 123                 // hide the item completely
 124                 e.model = string_null;
 125                 e.solid = SOLID_NOT;
 126                 e.colormod = '0 0 0';
 127                 e.glowmod = e.colormod;
 128                 e.alpha = 0;
 129                 e.customizeentityforclient = func_null;
 130
 131                 e.spawnshieldtime = 1;
 132         }
 133
 134         if (e.strength_finished || e.invincible_finished)
 135                 e.effects |= EF_ADDITIVE | EF_FULLBRIGHT;
 136         if (autocvar_g_nodepthtestitems)
 137                 e.effects |= EF_NODEPTHTEST;
 138         if (autocvar_g_fullbrightitems)
 139                 e.effects |= EF_FULLBRIGHT;
 140
 141         // relink entity (because solid may have changed)
 142         setorigin(e, e.origin);
 143 }
 144
 145 float it_armor_large_time;
 146 float it_health_mega_time;
 147 float it_strength_time;
 148 float it_invisible_time;
 149 float it_extralife_time;
 150 float it_speed_time;
 151 float it_shield_time;
 152 float it_fuelregen_time;
 153 float it_jetpack_time;
 154
 155 void Item_ClearItemsTime()
 156 {
 157         self.item_armor_large_time = 0;
 158         self.item_health_mega_time = 0;
 159         self.item_strength_time = 0;
 160         self.item_invisible_time = 0;
 161         self.item_extralife_time = 0;
 162         self.item_speed_time = 0;
 163         self.item_shield_time = 0;
 164         self.item_fuelregen_time = 0;
 165         self.item_jetpack_time = 0;
 166 }
 167 void Item_GetItemsTime(entity e)
 168 {
 169         e.item_armor_large_time = it_armor_large_time;
 170         e.item_health_mega_time = it_health_mega_time;
 171         e.item_strength_time = it_strength_time;
 172         e.item_invisible_time = it_invisible_time;
 173         e.item_extralife_time = it_extralife_time;
 174         e.item_speed_time = it_speed_time;
 175         e.item_shield_time = it_shield_time;
 176         e.item_fuelregen_time = it_fuelregen_time;
 177         e.item_jetpack_time = it_jetpack_time;
 178 }
 179 void Item_UpdateTime(entity e, float t)
 180 {
 181         if(g_minstagib)
 182         {
 183                 switch(e.items)
 184                 {
 185                         case IT_STRENGTH://"item-invis"
 186                                 if (it_invisible_time > time && t > it_invisible_time)
 187                                         return;
 188                                 it_invisible_time = t;
 189                                 return;
 190                         case IT_NAILS://"item-extralife"
 191                                 if (it_extralife_time > time && t > it_extralife_time)
 192                                         return;
 193                                 it_extralife_time = t;
 194                                 return;
 195                         case IT_INVINCIBLE://"item-speed"
 196                                 if (it_speed_time > time && t > it_speed_time)
 197                                         return;
 198                                 it_speed_time = t;
 199                                 return;
 200                 }
 201         }
 202         else
 203         {
 204                 switch(e.items)
 205                 {
 206                         case IT_HEALTH:
 207                                 if (e.classname == "item_health_mega")
 208                                 {
 209                                         if (it_health_mega_time > time && t > it_health_mega_time)
 210                                                 return;
 211                                         it_health_mega_time = t;
 212                                 }
 213                                 return;
 214                         case IT_ARMOR:
 215                                 if (e.classname == "item_armor_large")
 216                                 {
 217                                         if (it_armor_large_time > time && t > it_armor_large_time)
 218                                                 return;
 219                                         it_armor_large_time = t;
 220                                 }
 221                                 return;
 222                         case IT_STRENGTH://"item-strength"
 223                                 if (it_strength_time > time && t > it_strength_time)
 224                                         return;
 225                                 it_strength_time = t;
 226                                 return;
 227                         case IT_INVINCIBLE://"item-shield"
 228                                 if (it_shield_time > time && t > it_shield_time)
 229                                         return;
 230                                 it_shield_time = t;
 231                                 return;
 232                 }
 233         }
 234         switch(e.items)
 235         {
 236                 case IT_FUEL_REGEN://"item-fuelregen"
 237                         if (it_fuelregen_time > time && t > it_fuelregen_time)
 238                                 return;
 239                         it_fuelregen_time = t;
 240                         return;
 241                 case IT_JETPACK://"item-jetpack"
 242                         if (it_jetpack_time > time && t > it_jetpack_time)
 243                                 return;
 244                         it_jetpack_time = t;
 245                         return;
 246         }
 247 }
 248
 249 void Item_Respawn (void)
 250 {
 251         float t;
 252         entity head;
 253         Item_Show(self, 1);
 254         if(!g_minstagib && self.items == IT_STRENGTH)
 255                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 256         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 257                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 258         else
 259                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
 260         setorigin (self, self.origin);
 261
 262         if (self.flags & FL_POWERUP || self.classname == "item_armor_large" || self.classname == "item_health_mega")
 263         {
 264                 for(t = 0, head = world; (head = find(head, classname, self.classname)); )
 265                 {
 266                         // in minstagib .classname is "minstagib" for every item
 267                         if (g_minstagib && self.items != head.items)
 268                                 continue;
 269                         if (head.scheduledrespawntime > time)
 270                                 if (t == 0 || head.scheduledrespawntime < t)
 271                                         t = head.scheduledrespawntime;
 272                 }
 273                 Item_UpdateTime(self, t);
 274                 FOR_EACH_REALCLIENT(head)
 275                 {
 276                         if (head.classname != "player")
 277                                 Item_GetItemsTime(head);
 278                 }
 279         }
 280
 281         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 282         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 283 }
 284
 285 void Item_RespawnCountdown (void)
 286 {
 287         if(self.count >= ITEM_RESPAWN_TICKS)
 288         {
 289                 if(self.waypointsprite_attached)
 290                         WaypointSprite_Kill(self.waypointsprite_attached);
 291                 Item_Respawn();
 292         }
 293         else
 294         {
 295                 self.nextthink = time + 1;
 296                 self.count += 1;
 297                 if(self.count == 1)
 298                 {
 299                         string name;
 300                         vector rgb;
 301                         name = string_null;
 302                         if(g_minstagib)
 303                         {
 304                                 switch(self.items)
 305                                 {
 306                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 307                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 308                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 309                                 }
 310                         }
 311                         else
 312                         {
 313                                 switch(self.items)
 314                                 {
 315                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 316                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 317                                 }
 318                         }
 319                         switch(self.items)
 320                         {
 321                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 322                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 323                         }
 324                         if(name)
 325                         {
 326                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 327                                 if(self.waypointsprite_attached)
 328                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 329                         }
 330                 }
 331                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
 332                 if(self.waypointsprite_attached)
 333                 {
 334                         WaypointSprite_Ping(self.waypointsprite_attached);
 335                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 336                 }
 337         }
 338 }
 339
 340 void Item_ScheduleRespawnIn(entity e, float t)
 341 {
 342         if(e.flags & FL_POWERUP)
 343         {
 344                 e.think = Item_RespawnCountdown;
 345                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 346                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 347                 e.count = 0;
 348         }
 349         else
 350         {
 351                 e.think = Item_Respawn;
 352                 e.nextthink = time + t;
 353                 e.scheduledrespawntime = e.nextthink;
 354         }
 355         Item_UpdateTime(e, e.scheduledrespawntime);
 356         FOR_EACH_REALCLIENT(e)
 357         {
 358                 if (e.classname != "player")
 359                         Item_GetItemsTime(e);
 360         }
 361 }
 362
 363 void Item_ScheduleRespawn(entity e)
 364 {
 365         if(e.respawntime > 0)
 366         {
 367                 Item_Show(e, 0);
 368                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 369         }
 370         else // if respawntime is -1, this item does not respawn
 371                 Item_Show(e, -1);
 372 }
 373
 374 void Item_ScheduleInitialRespawn(entity e)
 375 {
 376         Item_Show(e, 0);
 377         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 378 }
 379
 380 float Item_GiveTo(entity item, entity player)
 381 {
 382         float _switchweapon;
 383         float pickedup;
 384         float it;
 385         float i;
 386         entity e;
 387
 388         // if nothing happens to player, just return without taking the item
 389         pickedup = FALSE;
 390         _switchweapon = FALSE;
 391
 392         if (g_minstagib)
 393         {
 394                 if(item.spawnshieldtime)
 395                 {
 396                         if (item.ammo_fuel)
 397                         if (player.ammo_fuel < g_pickup_fuel_max)
 398                         {
 399                                 pickedup = TRUE;
 400                                 player.ammo_fuel = bound(player.ammo_fuel, g_pickup_fuel_max, player.ammo_fuel + item.ammo_fuel);
 401                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 402                         }
 403                         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 404                         {
 405                                 pickedup = TRUE;
 406                                 player.items |= it;
 407                                 sprint (player, strcat("You got the ^2", item.netname, "\n"));
 408                         }
 409
 410                         _switchweapon = TRUE;
 411                         if (item.ammo_cells)
 412                         {
 413                                 pickedup = TRUE;
 414                                 // play some cool sounds ;)
 415                                 if (clienttype(player) == CLIENTTYPE_REAL)
 416                                 {
 417                                         if(player.health <= 5)
 418                                                 AnnounceTo(player, "lastsecond");
 419                                         else if(player.health < 50)
 420                                                 AnnounceTo(player, "narrowly");
 421                                 }
 422                                 // sound not available
 423                                 // else if(item.items == IT_CELLS)
 424                                 //      AnnounceTo(player, "ammo");
 425
 426                                 if (item.weapons & WEPBIT_MINSTANEX)
 427                                         W_GiveWeapon (player, WEP_MINSTANEX, item.netname);
 428                                 if (item.ammo_cells)
 429                                         player.ammo_cells = bound(player.ammo_cells, 999, player.ammo_cells + autocvar_g_minstagib_ammo_drop);
 430                                 player.health = 100;
 431                         }
 432
 433                         // extralife powerup
 434                         if (item.max_health)
 435                         {
 436                                 pickedup = TRUE;
 437                                 // sound not available
 438                                 // AnnounceTo(player, "_lives");
 439                                 player.armorvalue = bound(player.armorvalue, 999, player.armorvalue + autocvar_g_minstagib_extralives);
 440                                 sprint(player, "^3You picked up some extra lives\n");
 441                         }
 442
 443                         // invis powerup
 444                         if (item.strength_finished)
 445                         {
 446                                 pickedup = TRUE;
 447                                 // sound not available
 448                                 // AnnounceTo(player, "invisible");
 449                                 player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 450                         }
 451
 452                         // speed powerup
 453                         if (item.invincible_finished)
 454                         {
 455                                 pickedup = TRUE;
 456                                 // sound not available
 457                                 // AnnounceTo(player, "speed");
 458                                 player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_strength_time;
 459                         }
 460                 }
 461         }
 462         else
 463         {
 464                 if (g_weapon_stay == 1)
 465                 if not(item.flags & FL_NO_WEAPON_STAY)
 466                 if (item.flags & FL_WEAPON)
 467                 {
 468                         if(item.classname == "droppedweapon")
 469                         {
 470                                 if (player.weapons & item.weapons)      // don't let players stack ammo by tossing weapons
 471                                         goto skip;
 472                         }
 473                         else
 474                         {
 475                                 if (player.weapons & item.weapons)
 476                                         goto skip;
 477                         }
 478                 }
 479
 480                 // in case the player has autoswitch enabled do the following:
 481                 // if the player is using their best weapon before items are given, they
 482                 // probably want to switch to an even better weapon after items are given
 483                 if (player.autoswitch)
 484                 if (player.switchweapon == w_getbestweapon(player))
 485                         _switchweapon = TRUE;
 486
 487                 if not(player.weapons & W_WeaponBit(player.switchweapon))
 488                         _switchweapon = TRUE;
 489
 490                 if(item.spawnshieldtime)
 491                 {
 492                         if (item.ammo_shells)
 493                         if ((player.ammo_shells < g_pickup_shells_max) || item.pickup_anyway)
 494                         {
 495                                 pickedup = TRUE;
 496                                 player.ammo_shells = bound(player.ammo_shells, g_pickup_shells_max, player.ammo_shells + item.ammo_shells);
 497                         }
 498                         if (item.ammo_nails)
 499                         if ((player.ammo_nails < g_pickup_nails_max) || item.pickup_anyway)
 500                         {
 501                                 pickedup = TRUE;
 502                                 player.ammo_nails = bound(player.ammo_nails, g_pickup_nails_max, player.ammo_nails + item.ammo_nails);
 503                         }
 504                         if (item.ammo_rockets)
 505                         if ((player.ammo_rockets < g_pickup_rockets_max) || item.pickup_anyway)
 506                         {
 507                                 pickedup = TRUE;
 508                                 player.ammo_rockets = bound(player.ammo_rockets, g_pickup_rockets_max, player.ammo_rockets + item.ammo_rockets);
 509                         }
 510                         if (item.ammo_cells)
 511                         if ((player.ammo_cells < g_pickup_cells_max) || item.pickup_anyway)
 512                         {
 513                                 pickedup = TRUE;
 514                                 player.ammo_cells = bound(player.ammo_cells, g_pickup_cells_max, player.ammo_cells + item.ammo_cells);
 515                         }
 516                         if (item.ammo_fuel)
 517                         if ((player.ammo_fuel < g_pickup_fuel_max) || item.pickup_anyway)
 518                         {
 519                                 pickedup = TRUE;
 520                                 player.ammo_fuel = bound(player.ammo_fuel, g_pickup_fuel_max, player.ammo_fuel + item.ammo_fuel);
 521                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 522                         }
 523                 }
 524
 525                 if (item.flags & FL_WEAPON)
 526                         if ((it = item.weapons - (item.weapons & player.weapons)) || (g_pickup_weapons_anyway && g_weapon_stay == 0))
 527                 {
 528                         pickedup = TRUE;
 529                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 530                         {
 531                                 e = get_weaponinfo(i);
 532                                 if(it & e.weapons)
 533                                         W_GiveWeapon (player, e.weapon, item.netname);
 534                         }
 535                 }
 536
 537                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 538                 {
 539                         pickedup = TRUE;
 540                         player.items |= it;
 541                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 542                 }
 543
 544                 if(item.spawnshieldtime)
 545                 {
 546                         if (item.strength_finished)
 547                         {
 548                                 pickedup = TRUE;
 549                                 player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 550                         }
 551                         if (item.invincible_finished)
 552                         {
 553                                 pickedup = TRUE;
 554                                 player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_invincible_time;
 555                         }
 556
 557                         if (item.health)
 558                         if ((player.health < item.max_health) || item.pickup_anyway)
 559                         {
 560                                 pickedup = TRUE;
 561                                 player.health = bound(player.health, item.max_health, player.health + item.health);
 562                                 player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 563                         }
 564                         if (item.armorvalue)
 565                         if ((player.armorvalue < item.max_armorvalue) || item.pickup_anyway)
 566                         {
 567                                 pickedup = TRUE;
 568                                 player.armorvalue = bound(player.armorvalue, item.max_armorvalue, player.armorvalue + item.armorvalue);
 569                                 player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 570                         }
 571                 }
 572         }
 573
 574 :skip
 575         // always eat teamed entities
 576         if(item.team)
 577                 pickedup = TRUE;
 578
 579         if (!pickedup)
 580                 return 0;
 581
 582         sound (player, CH_TRIGGER, item.item_pickupsound, VOL_BASE, ATTN_NORM);
 583         if (_switchweapon)
 584                 if (player.switchweapon != w_getbestweapon(player))
 585                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 586
 587         return 1;
 588 }
 589
 590 void Item_Touch (void)
 591 {
 592         entity e, head;
 593
 594         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 595         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 596         {
 597                 remove(self);
 598                 return;
 599         }
 600         if (other.classname != "player")
 601                 return;
 602         if (other.deadflag)
 603                 return;
 604         if (self.solid != SOLID_TRIGGER)
 605                 return;
 606         if (self.owner == other)
 607                 return;
 608
 609         if(!Item_GiveTo(self, other))
 610                 return;
 611
 612         other.last_pickup = time;
 613
 614         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 615
 616         if (self.classname == "droppedweapon")
 617                 remove (self);
 618         else if not(self.spawnshieldtime)
 619                 return;
 620         else if((self.flags & FL_WEAPON) && !(self.flags & FL_NO_WEAPON_STAY) && (g_weapon_stay == 1 || g_weapon_stay == 2))
 621                 return;
 622         else
 623         {
 624                 if(self.team)
 625                 {
 626                         RandomSelection_Init();
 627                         for(head = world; (head = findfloat(head, team, self.team)); )
 628                         {
 629                                 if(head.flags & FL_ITEM)
 630                                 {
 631                                         Item_Show(head, -1);
 632                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 633                                 }
 634                         }
 635                         e = RandomSelection_chosen_ent;
 636                 }
 637                 else
 638                         e = self;
 639                 Item_ScheduleRespawn(e);
 640         }
 641 }
 642
 643 void Item_FindTeam()
 644 {
 645         entity head, e;
 646
 647         if(self.effects & EF_NODRAW)
 648         {
 649                 // marker for item team search
 650                 dprint("Initializing item team ", ftos(self.team), "\n");
 651                 RandomSelection_Init();
 652                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 653                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 654                 e = RandomSelection_chosen_ent;
 655                 e.state = 0;
 656                 Item_Show(e, 1);
 657
 658                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 659                 {
 660                         if(head != e)
 661                         {
 662                                 // make it a non-spawned item
 663                                 Item_Show(head, -1);
 664                                 head.state = 1; // state 1 = initially hidden item
 665                         }
 666                         head.effects &~= EF_NODRAW;
 667                 }
 668
 669                 if(e.flags & FL_POWERUP) // do not spawn powerups initially!
 670                         Item_ScheduleInitialRespawn(e);
 671         }
 672 }
 673
 674 void Item_Reset()
 675 {
 676         Item_Show(self, !self.state);
 677         setorigin (self, self.origin);
 678         self.think = SUB_Null;
 679         self.nextthink = 0;
 680
 681         if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 682                 Item_ScheduleInitialRespawn(self);
 683 }
 684
 685 // Savage: used for item garbage-collection
 686 // TODO: perhaps nice special effect?
 687 void RemoveItem(void)
 688 {
 689         remove(self);
 690 }
 691
 692 // pickup evaluation functions
 693 // these functions decide how desirable an item is to the bots
 694
 695 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 696
 697 float weapon_pickupevalfunc(entity player, entity item)
 698 {
 699         float c, i, j, position;
 700
 701         // See if I have it already
 702         if(player.weapons & item.weapons == item.weapons)
 703         {
 704                 // If I can pick it up
 705                 if(g_weapon_stay == 1 || g_weapon_stay == 2 || !item.spawnshieldtime)
 706                         c = 0;
 707                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 708                 {
 709                         // Skilled bots will grab more
 710                         c = bound(0, skill / 10, 1) * 0.5;
 711                 }
 712                 else
 713                         c = 0;
 714         }
 715         else
 716                 c = 1;
 717
 718         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 719         if( bot_custom_weapon && c )
 720         {
 721                 for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 722                 {
 723                         // Find weapon
 724                         if( (get_weaponinfo(i)).weapons & item.weapons  != item.weapons )
 725                                 continue;
 726
 727                         // Find the highest position on any range
 728                         position = -1;
 729                         for(j = 0; j < WEP_LAST ; ++j){
 730                                 if(
 731                                                 bot_weapons_far[j] == i ||
 732                                                 bot_weapons_mid[j] == i ||
 733                                                 bot_weapons_close[j] == i
 734                                   )
 735                                 {
 736                                         position = j;
 737                                         break;
 738                                 }
 739                         }
 740
 741                         // Rate it
 742                         if (position >= 0 )
 743                         {
 744                                 position = WEP_LAST - position;
 745                                 // item.bot_pickupbasevalue is overwritten here
 746                                 return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 747                         }
 748                 }
 749         }
 750
 751         return item.bot_pickupbasevalue * c;
 752 }
 753
 754 float commodity_pickupevalfunc(entity player, entity item)
 755 {
 756         float c, i, need_shells, need_nails, need_rockets, need_cells;
 757         entity wi;
 758         c = 0;
 759
 760         // Detect needed ammo
 761         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 762         {
 763                 wi = get_weaponinfo(i);
 764
 765                 if not(wi.weapons & player.weapons)
 766                         continue;
 767
 768                 if(wi.items & IT_SHELLS)
 769                         need_shells = TRUE;
 770                 else if(wi.items & IT_NAILS)
 771                         need_nails = TRUE;
 772                 else if(wi.items & IT_ROCKETS)
 773                         need_rockets = TRUE;
 774                 else if(wi.items & IT_CELLS)
 775                         need_cells = TRUE;
 776         }
 777
 778         // TODO: figure out if the player even has the weapon this ammo is for?
 779         // may not affect strategy much though...
 780         // find out how much more ammo/armor/health the player can hold
 781         if (need_shells)
 782         if (item.ammo_shells)
 783         if (player.ammo_shells < g_pickup_shells_max)
 784                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 785         if (need_nails)
 786         if (item.ammo_nails)
 787         if (player.ammo_nails < g_pickup_nails_max)
 788                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 789         if (need_rockets)
 790         if (item.ammo_rockets)
 791         if (player.ammo_rockets < g_pickup_rockets_max)
 792                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 793         if (need_cells)
 794         if (item.ammo_cells)
 795         if (player.ammo_cells < g_pickup_cells_max)
 796                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 797         if (item.armorvalue)
 798         if (player.armorvalue < item.max_armorvalue)
 799                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 800         if (item.health)
 801         if (player.health < item.max_health)
 802                 c = c + max(0, 1 - player.health / item.max_health);
 803
 804         return item.bot_pickupbasevalue * c;
 805 }
 806
 807
 808 .float is_item;
 809 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 810 {
 811         startitem_failed = FALSE;
 812
 813         self.items = itemid;
 814         self.weapons = weaponid;
 815
 816         // is it a dropped weapon?
 817         if (self.classname == "droppedweapon")
 818         {
 819                 self.reset = SUB_Remove;
 820                 // it's a dropped weapon
 821                 self.movetype = MOVETYPE_TOSS;
 822                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 823                 self.think = RemoveItem;
 824                 self.nextthink = time + 60;
 825                 // don't drop if in a NODROP zone (such as lava)
 826                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 827                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 828                 {
 829                         startitem_failed = TRUE;
 830                         remove(self);
 831                         return;
 832                 }
 833         }
 834         else
 835         {
 836                 if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 837                 {
 838                         startitem_failed = TRUE;
 839                         remove(self);
 840                         return;
 841                 }
 842
 843                 self.reset = Item_Reset;
 844                 // it's a level item
 845                 if(self.spawnflags & 1)
 846                         self.noalign = 1;
 847                 if (self.noalign)
 848                         self.movetype = MOVETYPE_NONE;
 849                 else
 850                         self.movetype = MOVETYPE_TOSS;
 851                 // do item filtering according to game mode and other things
 852                 if (!self.noalign)
 853                 {
 854                         // first nudge it off the floor a little bit to avoid math errors
 855                         setorigin(self, self.origin + '0 0 1');
 856                         // set item size before we spawn a spawnfunc_waypoint
 857                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 858                                 setsize (self, '-16 -16 0', '16 16 48');
 859                         else
 860                                 setsize (self, '-16 -16 0', '16 16 32');
 861                         // note droptofloor returns FALSE if stuck/or would fall too far
 862                         droptofloor();
 863                         waypoint_spawnforitem(self);
 864                 }
 865
 866                 /*
 867                  * can't do it that way, as it would break maps
 868                  * TODO make a target_give like entity another way, that perhaps has
 869                  * the weapon name in a key
 870                 if(self.targetname)
 871                 {
 872                         // target_give not yet supported; maybe later
 873                         print("removed targeted ", self.classname, "\n");
 874                         startitem_failed = TRUE;
 875                         remove (self);
 876                         return;
 877                 }
 878                 */
 879
 880                 if(autocvar_spawn_debug >= 2)
 881                 {
 882                         entity otheritem;
 883                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 884                         {
 885                                 if(otheritem.is_item)
 886                                 {
 887                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 888                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 889                                         error("Mapper sucks.");
 890                                 }
 891                         }
 892                         self.is_item = TRUE;
 893                 }
 894
 895                 if(g_lms || g_ca)
 896                 {
 897                         startitem_failed = TRUE;
 898                         remove(self);
 899                         return;
 900                 }
 901                 else if (g_weaponarena && ((weaponid & WEPBIT_ALL) || (itemid & IT_AMMO)))
 902                 {
 903                         startitem_failed = TRUE;
 904                         remove(self);
 905                         return;
 906                 }
 907                 else if (g_minstagib)
 908                 {
 909                         // don't remove dropped items and powerups
 910                         if (self.classname != "minstagib")
 911                         {
 912                                 startitem_failed = TRUE;
 913                                 remove (self);
 914                                 return;
 915                         }
 916                 }
 917                 else if (!autocvar_g_pickup_items && itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemid != IT_HEALTH)
 918                 {
 919                         startitem_failed = TRUE;
 920                         remove (self);
 921                         return;
 922                 }
 923
 924                 weaponsInMap |= weaponid;
 925
 926                 precache_model (itemmodel);
 927                 precache_sound (pickupsound);
 928
 929                 precache_sound ("misc/itemrespawncountdown.wav");
 930                 if(!g_minstagib && itemid == IT_STRENGTH)
 931                         precache_sound ("misc/strength_respawn.wav");
 932                 else if(!g_minstagib && itemid == IT_INVINCIBLE)
 933                         precache_sound ("misc/shield_respawn.wav");
 934                 else
 935                         precache_sound ("misc/itemrespawn.wav");
 936
 937                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
 938                         self.target = "###item###"; // for finding the nearest item using find()
 939         }
 940
 941         self.bot_pickup = TRUE;
 942         self.bot_pickupevalfunc = pickupevalfunc;
 943         self.bot_pickupbasevalue = pickupbasevalue;
 944         self.mdl = itemmodel;
 945         self.item_pickupsound = pickupsound;
 946         // let mappers override respawntime
 947         if(!self.respawntime) // both set
 948         {
 949                 self.respawntime = defaultrespawntime;
 950                 self.respawntimejitter = defaultrespawntimejitter;
 951         }
 952         self.netname = itemname;
 953         self.flags = FL_ITEM | itemflags;
 954         self.touch = Item_Touch;
 955         setmodel (self, self.mdl); // precision set below
 956         self.effects |= EF_LOWPRECISION;
 957         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 958                 setsize (self, '-16 -16 0', '16 16 48');
 959         else
 960                 setsize (self, '-16 -16 0', '16 16 32');
 961         if(itemflags & FL_WEAPON)
 962                 self.modelflags |= MF_ROTATE;
 963
 964         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 965         if (itemflags & FL_WEAPON)
 966         {
 967                 // neutral team color for pickup weapons
 968                 self.colormap = 1024; // color shirt=0 pants=0 grey
 969         }
 970
 971         Item_Show(self, 1);
 972         self.state = 0;
 973         if(self.team)
 974         {
 975                 if(!self.cnt)
 976                         self.cnt = 1; // item probability weight
 977                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 978                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 979         }
 980         else if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 981                 Item_ScheduleInitialRespawn(self);
 982 }
 983
 984 /* replace items in minstagib
 985  * IT_STRENGTH   = invisibility
 986  * IT_NAILS      = extra lives
 987  * IT_INVINCIBLE = speed
 988  */
 989 void minstagib_items (float itemid)
 990 {
 991         float rnd;
 992         self.classname = "minstagib";
 993
 994         // replace rocket launchers and nex guns with ammo cells
 995         if (itemid == IT_CELLS)
 996         {
 997                 self.ammo_cells = 1;
 998                 StartItem ("models/items/a_cells.md3",
 999                         "misc/itempickup.wav", 45, 0,
1000                         "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
1001                 return;
1002         }
1003
1004         // randomize
1005         rnd = random() * 3;
1006         if (rnd <= 1)
1007                 itemid = IT_STRENGTH;
1008         else if (rnd <= 2)
1009                 itemid = IT_NAILS;
1010         else
1011                 itemid = IT_INVINCIBLE;
1012
1013         // replace with invis
1014         if (itemid == IT_STRENGTH)
1015         {
1016                 self.strength_finished = 30;
1017                 StartItem ("models/items/g_strength.md3",
1018                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
1019                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
1020         }
1021         // replace with extra lives
1022         if (itemid == IT_NAILS)
1023         {
1024                 self.max_health = 1;
1025                 StartItem ("models/items/g_h100.md3",
1026                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
1027                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1028         }
1029         // replace with speed
1030         if (itemid == IT_INVINCIBLE)
1031         {
1032                 self.invincible_finished = 30;
1033                 StartItem ("models/items/g_invincible.md3",
1034                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
1035                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
1036         }
1037 }
1038
1039 float minst_no_auto_cells;
1040 void minst_remove_item (void) {
1041         if(minst_no_auto_cells)
1042                 remove(self);
1043 }
1044
1045 float weaponswapping;
1046 float internalteam;
1047
1048 void weapon_defaultspawnfunc(float wpn)
1049 {
1050         entity e;
1051         float t;
1052         var .float ammofield;
1053         string s;
1054         entity oldself;
1055         float i, j;
1056
1057         // set the respawntime in advance (so replaced weapons can copy it)
1058
1059         if(!self.respawntime)
1060         {
1061                 e = get_weaponinfo(wpn);
1062                 if(e.items == IT_SUPERWEAPON)
1063                 {
1064                         self.respawntime = g_pickup_respawntime_powerup;
1065                         self.respawntimejitter = g_pickup_respawntimejitter_powerup;
1066                 }
1067                 else
1068                 {
1069                         self.respawntime = g_pickup_respawntime_weapon;
1070                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
1071                 }
1072         }
1073
1074         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
1075         {
1076                 e = get_weaponinfo(wpn);
1077                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
1078                 if(s == "0")
1079                 {
1080                         remove(self);
1081                         startitem_failed = TRUE;
1082                         return;
1083                 }
1084                 t = tokenize_console(s);
1085                 if(t >= 2)
1086                 {
1087                         self.team = --internalteam;
1088                         oldself = self;
1089                         for(i = 1; i < t; ++i)
1090                         {
1091                                 s = argv(i);
1092                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1093                                 {
1094                                         e = get_weaponinfo(j);
1095                                         if(e.netname == s)
1096                                         {
1097                                                 self = spawn();
1098                                                 copyentity(oldself, self);
1099                                                 self.classname = "replacedweapon";
1100                                                 weapon_defaultspawnfunc(j);
1101                                                 break;
1102                                         }
1103                                 }
1104                                 if(j > WEP_LAST)
1105                                 {
1106                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1107                                 }
1108                         }
1109                         self = oldself;
1110                 }
1111                 if(t >= 1)
1112                 {
1113                         s = argv(0);
1114                         wpn = 0;
1115                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1116                         {
1117                                 e = get_weaponinfo(j);
1118                                 if(e.netname == s)
1119                                 {
1120                                         wpn = j;
1121                                         break;
1122                                 }
1123                         }
1124                         if(j > WEP_LAST)
1125                         {
1126                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1127                         }
1128                 }
1129                 if(wpn == 0)
1130                 {
1131                         remove(self);
1132                         startitem_failed = TRUE;
1133                         return;
1134                 }
1135         }
1136
1137         e = get_weaponinfo(wpn);
1138
1139         if(e.items && e.items != IT_SUPERWEAPON)
1140         {
1141                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1142                 {
1143                         if(e.items & j)
1144                         {
1145                                 ammofield = Item_CounterField(j);
1146                                 if(!self.ammofield)
1147                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1148                         }
1149                 }
1150         }
1151         else
1152         {
1153                 self.flags |= FL_NO_WEAPON_STAY;
1154         }
1155
1156         // weapon stay isn't supported for teamed weapons
1157         if(self.team)
1158                 self.flags |= FL_NO_WEAPON_STAY;
1159
1160         if(g_weapon_stay == 2 && self.classname != "droppedweapon")
1161         {
1162                 self.ammo_shells = 0;
1163                 self.ammo_nails = 0;
1164                 self.ammo_cells = 0;
1165                 self.ammo_rockets = 0;
1166                 // weapon stay 2: don't use ammo on weapon pickups; instead
1167                 // initialize all ammo types to the pickup ammo unless set by g_start_ammo_*
1168         }
1169
1170         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, FL_WEAPON, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1171         if (self.modelindex) // don't precache if self was removed
1172                 weapon_action(e.weapon, WR_PRECACHE);
1173 }
1174
1175 void spawnfunc_weapon_shotgun (void);
1176 void spawnfunc_weapon_uzi (void) {
1177         if(autocvar_sv_q3acompat_machineshotgunswap)
1178         if(self.classname != "droppedweapon")
1179         {
1180                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1181                 return;
1182         }
1183         weapon_defaultspawnfunc(WEP_UZI);
1184 }
1185
1186 void spawnfunc_weapon_shotgun (void) {
1187         if(autocvar_sv_q3acompat_machineshotgunswap)
1188         if(self.classname != "droppedweapon")
1189         {
1190                 weapon_defaultspawnfunc(WEP_UZI);
1191                 return;
1192         }
1193         weapon_defaultspawnfunc(WEP_SHOTGUN);
1194 }
1195
1196 void spawnfunc_weapon_nex (void)
1197 {
1198         if (g_minstagib)
1199         {
1200                 minstagib_items(IT_CELLS);
1201                 self.think = minst_remove_item;
1202                 self.nextthink = time;
1203                 return;
1204         }
1205         weapon_defaultspawnfunc(WEP_NEX);
1206 }
1207
1208 void spawnfunc_weapon_minstanex (void)
1209 {
1210         if (g_minstagib)
1211         {
1212                 minstagib_items(IT_CELLS);
1213                 self.think = minst_remove_item;
1214                 self.nextthink = time;
1215                 return;
1216         }
1217         weapon_defaultspawnfunc(WEP_MINSTANEX);
1218 }
1219
1220 void spawnfunc_weapon_rocketlauncher (void)
1221 {
1222         if (g_minstagib)
1223         {
1224                 minstagib_items(IT_CELLS); // replace rocketlauncher with cells
1225                 self.think = minst_remove_item;
1226                 self.nextthink = time;
1227                 return;
1228         }
1229         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1230 }
1231
1232 void spawnfunc_item_rockets (void) {
1233         if(!self.ammo_rockets)
1234                 self.ammo_rockets = g_pickup_rockets;
1235         if(!self.pickup_anyway)
1236                 self.pickup_anyway = g_pickup_ammo_anyway;
1237         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1238 }
1239
1240 void spawnfunc_item_shells (void);
1241 void spawnfunc_item_bullets (void) {
1242         if(!weaponswapping)
1243         if(autocvar_sv_q3acompat_machineshotgunswap)
1244         if(self.classname != "droppedweapon")
1245         {
1246                 weaponswapping = TRUE;
1247                 spawnfunc_item_shells();
1248                 weaponswapping = FALSE;
1249                 return;
1250         }
1251
1252         if(!self.ammo_nails)
1253                 self.ammo_nails = g_pickup_nails;
1254         if(!self.pickup_anyway)
1255                 self.pickup_anyway = g_pickup_ammo_anyway;
1256         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1257 }
1258
1259 void spawnfunc_item_cells (void) {
1260         if(!self.ammo_cells)
1261                 self.ammo_cells = g_pickup_cells;
1262         if(!self.pickup_anyway)
1263                 self.pickup_anyway = g_pickup_ammo_anyway;
1264         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1265 }
1266
1267 void spawnfunc_item_shells (void) {
1268         if(!weaponswapping)
1269         if(autocvar_sv_q3acompat_machineshotgunswap)
1270         if(self.classname != "droppedweapon")
1271         {
1272                 weaponswapping = TRUE;
1273                 spawnfunc_item_bullets();
1274                 weaponswapping = FALSE;
1275                 return;
1276         }
1277
1278         if(!self.ammo_shells)
1279                 self.ammo_shells = g_pickup_shells;
1280         if(!self.pickup_anyway)
1281                 self.pickup_anyway = g_pickup_ammo_anyway;
1282         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1283 }
1284
1285 void spawnfunc_item_armor_small (void) {
1286         if(!self.armorvalue)
1287                 self.armorvalue = g_pickup_armorsmall;
1288         if(!self.max_armorvalue)
1289                 self.max_armorvalue = g_pickup_armorsmall_max;
1290         if(!self.pickup_anyway)
1291                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1292         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1293 }
1294
1295 void spawnfunc_item_armor_medium (void) {
1296         if(!self.armorvalue)
1297                 self.armorvalue = g_pickup_armormedium;
1298         if(!self.max_armorvalue)
1299                 self.max_armorvalue = g_pickup_armormedium_max;
1300         if(!self.pickup_anyway)
1301                 self.pickup_anyway = g_pickup_armormedium_anyway;
1302         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1303 }
1304
1305 void spawnfunc_item_armor_big (void) {
1306         if(!self.armorvalue)
1307                 self.armorvalue = g_pickup_armorbig;
1308         if(!self.max_armorvalue)
1309                 self.max_armorvalue = g_pickup_armorbig_max;
1310         if(!self.pickup_anyway)
1311                 self.pickup_anyway = g_pickup_armorbig_anyway;
1312         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1313 }
1314
1315 void spawnfunc_item_armor_large (void) {
1316         if(!self.armorvalue)
1317                 self.armorvalue = g_pickup_armorlarge;
1318         if(!self.max_armorvalue)
1319                 self.max_armorvalue = g_pickup_armorlarge_max;
1320         if(!self.pickup_anyway)
1321                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1322         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1323 }
1324
1325 void spawnfunc_item_health_small (void) {
1326         if(!self.max_health)
1327                 self.max_health = g_pickup_healthsmall_max;
1328         if(!self.health)
1329                 self.health = g_pickup_healthsmall;
1330         if(!self.pickup_anyway)
1331                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1332         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1333 }
1334
1335 void spawnfunc_item_health_medium (void) {
1336         if(!self.max_health)
1337                 self.max_health = g_pickup_healthmedium_max;
1338         if(!self.health)
1339                 self.health = g_pickup_healthmedium;
1340         if(!self.pickup_anyway)
1341                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1342         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1343 }
1344
1345 void spawnfunc_item_health_large (void) {
1346         if(!self.max_health)
1347                 self.max_health = g_pickup_healthlarge_max;
1348         if(!self.health)
1349                 self.health = g_pickup_healthlarge;
1350         if(!self.pickup_anyway)
1351                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1352         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1353 }
1354
1355 void spawnfunc_item_health_mega (void) {
1356         if(!autocvar_g_powerup_superhealth)
1357                 return;
1358
1359         if((g_arena || g_ca) && !autocvar_g_arena_powerups)
1360                 return;
1361
1362         if(g_minstagib) {
1363                 minstagib_items(IT_NAILS);
1364         } else {
1365                 if(!self.max_health)
1366                         self.max_health = g_pickup_healthmega_max;
1367                 if(!self.health)
1368                         self.health = g_pickup_healthmega;
1369                 if(!self.pickup_anyway)
1370                         self.pickup_anyway = g_pickup_healthmega_anyway;
1371                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1372         }
1373 }
1374
1375 // support old misnamed entities
1376 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1377 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1378 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1379 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1380 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1381
1382 void spawnfunc_item_strength (void) {
1383         if(!autocvar_g_powerup_strength)
1384                 return;
1385
1386         if((g_arena || g_ca) && !autocvar_g_arena_powerups)
1387                 return;
1388
1389         if(g_minstagib) {
1390                 minstagib_items(IT_STRENGTH);
1391         } else {
1392                 precache_sound("weapons/strength_fire.wav");
1393                 self.strength_finished = 30;
1394                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1395         }
1396 }
1397
1398 void spawnfunc_item_invincible (void) {
1399         if(!autocvar_g_powerup_shield)
1400                 return;
1401
1402         if((g_arena || g_ca) && !autocvar_g_arena_powerups)
1403                 return;
1404
1405         if(g_minstagib) {
1406                 minstagib_items(IT_INVINCIBLE);
1407         } else {
1408                 self.invincible_finished = 30;
1409                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1410         }
1411 }
1412
1413 void spawnfunc_item_minst_cells (void) {
1414         if (g_minstagib)
1415         {
1416                 minst_no_auto_cells = 1;
1417                 minstagib_items(IT_CELLS);
1418         }
1419         else
1420                 remove(self);
1421 }
1422
1423 // compatibility:
1424 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1425
1426 float GiveItems(entity e, float beginarg, float endarg);
1427 void target_items_use (void)
1428 {
1429         if(activator.classname == "droppedweapon")
1430         {
1431                 EXACTTRIGGER_TOUCH;
1432                 remove(activator);
1433                 return;
1434         }
1435
1436         if(activator.classname != "player")
1437                 return;
1438         if(activator.deadflag != DEAD_NO)
1439                 return;
1440         EXACTTRIGGER_TOUCH;
1441
1442         entity e;
1443         for(e = world; (e = find(e, classname, "droppedweapon")); )
1444                 if(e.enemy == activator)
1445                         remove(e);
1446
1447         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1448                 centerprint(activator, self.message);
1449 }
1450
1451 void spawnfunc_target_items (void)
1452 {
1453         float n, i, j;
1454         entity e;
1455
1456         self.use = target_items_use;
1457         if(!self.strength_finished)
1458                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1459         if(!self.invincible_finished)
1460                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1461
1462         precache_sound("misc/itempickup.wav");
1463         precache_sound("misc/megahealth.wav");
1464         precache_sound("misc/armor25.wav");
1465         precache_sound("misc/powerup.wav");
1466         precache_sound("misc/poweroff.wav");
1467         precache_sound("weapons/weaponpickup.wav");
1468
1469         n = tokenize_console(self.netname);
1470         if(argv(0) == "give")
1471         {
1472                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1473         }
1474         else
1475         {
1476                 for(i = 0; i < n; ++i)
1477                 {
1478                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1479                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1480                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1481                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1482                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1483                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1484                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1485                         else
1486                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1487                         {
1488                                 e = get_weaponinfo(j);
1489                                 if(argv(i) == e.netname)
1490                                 {
1491                                         self.weapons |= e.weapons;
1492                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1493                                                 weapon_action(e.weapon, WR_PRECACHE);
1494                                         break;
1495                                 }
1496                         }
1497                         if(j > WEP_LAST)
1498                                 print("target_items: invalid item ", argv(i), "\n");
1499                 }
1500
1501                 string itemprefix, valueprefix;
1502                 if(self.spawnflags == 0)
1503                 {
1504                         itemprefix = "";
1505                         valueprefix = "";
1506                 }
1507                 else if(self.spawnflags == 1)
1508                 {
1509                         itemprefix = "max ";
1510                         valueprefix = "max ";
1511                 }
1512                 else if(self.spawnflags == 2)
1513                 {
1514                         itemprefix = "min ";
1515                         valueprefix = "min ";
1516                 }
1517                 else if(self.spawnflags == 4)
1518                 {
1519                         itemprefix = "minus ";
1520                         valueprefix = "max ";
1521                 }
1522                 else
1523                         error("invalid spawnflags");
1524
1525                 self.netname = "";
1526                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1527                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1528                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1529                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1530                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1531                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1532                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1533                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1534                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1535                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1536                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1537                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1538                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1539                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1540                 {
1541                         e = get_weaponinfo(j);
1542                         if(e.weapons)
1543                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & e.weapons), e.netname);
1544                 }
1545         }
1546         self.netname = strzone(self.netname);
1547         //print(self.netname, "\n");
1548
1549         n = tokenize_console(self.netname);
1550         for(i = 0; i < n; ++i)
1551         {
1552                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1553                 {
1554                         e = get_weaponinfo(j);
1555                         if(argv(i) == e.netname)
1556                         {
1557                                 weapon_action(e.weapon, WR_PRECACHE);
1558                                 break;
1559                         }
1560                 }
1561         }
1562 }
1563
1564 void spawnfunc_item_fuel(void)
1565 {
1566         if(!self.ammo_fuel)
1567                 self.ammo_fuel = g_pickup_fuel;
1568         if(!self.pickup_anyway)
1569                 self.pickup_anyway = g_pickup_ammo_anyway;
1570         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1571 }
1572
1573 void spawnfunc_item_fuel_regen(void)
1574 {
1575         if(start_items & IT_FUEL_REGEN)
1576         {
1577                 spawnfunc_item_fuel();
1578                 return;
1579         }
1580         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1581 }
1582
1583 void spawnfunc_item_jetpack(void)
1584 {
1585         if(g_grappling_hook)
1586                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1587         if(!self.ammo_fuel)
1588                 self.ammo_fuel = g_pickup_fuel_jetpack;
1589         if(start_items & IT_JETPACK)
1590         {
1591                 spawnfunc_item_fuel();
1592                 return;
1593         }
1594         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1595 }
1596
1597
1598 #define OP_SET 0
1599 #define OP_MIN 1
1600 #define OP_MAX 2
1601 #define OP_PLUS 3
1602 #define OP_MINUS 4
1603
1604 float GiveBit(entity e, .float fld, float bit, float op, float val)
1605 {
1606         float v0, v1;
1607         v0 = (e.fld & bit);
1608         switch(op)
1609         {
1610                 case OP_SET:
1611                         if(val > 0)
1612                                 e.fld |= bit;
1613                         else
1614                                 e.fld &~= bit;
1615                         break;
1616                 case OP_MIN:
1617                 case OP_PLUS:
1618                         if(val > 0)
1619                                 e.fld |= bit;
1620                         break;
1621                 case OP_MAX:
1622                         if(val <= 0)
1623                                 e.fld &~= bit;
1624                         break;
1625                 case OP_MINUS:
1626                         if(val > 0)
1627                                 e.fld &~= bit;
1628                         break;
1629         }
1630         v1 = (e.fld & bit);
1631         return (v0 != v1);
1632 }
1633
1634 float GiveValue(entity e, .float fld, float op, float val)
1635 {
1636         float v0, v1;
1637         v0 = e.fld;
1638         switch(op)
1639         {
1640                 case OP_SET:
1641                         e.fld = val;
1642                         break;
1643                 case OP_MIN:
1644                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1645                         break;
1646                 case OP_MAX:
1647                         e.fld = min(e.fld, val);
1648                         break;
1649                 case OP_PLUS:
1650                         e.fld += val;
1651                         break;
1652                 case OP_MINUS:
1653                         e.fld -= val;
1654                         break;
1655         }
1656         v1 = e.fld;
1657         return (v0 != v1);
1658 }
1659
1660 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1661 {
1662         if(v1 == v0)
1663                 return;
1664         if(v1 <= v0 - t)
1665         {
1666                 if(snd_decr != "")
1667                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1668         }
1669         else if(v0 >= v0 + t)
1670         {
1671                 if(snd_incr != "")
1672                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1673         }
1674 }
1675
1676 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1677 {
1678         if(v0 < v1)
1679                 e.rotfield = max(e.rotfield, time + rottime);
1680         else if(v0 > v1)
1681                 e.regenfield = max(e.regenfield, time + regentime);
1682 }
1683
1684 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1685 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1686 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1687 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1688
1689 float GiveItems(entity e, float beginarg, float endarg)
1690 {
1691         float got, i, j, val, op;
1692         float _switchweapon;
1693         entity wi;
1694         string cmd;
1695
1696         val = 999;
1697         op = OP_SET;
1698
1699         got = 0;
1700
1701         _switchweapon = FALSE;
1702         if (e.autoswitch)
1703                 if (e.switchweapon == w_getbestweapon(e))
1704                         _switchweapon = TRUE;
1705
1706         e.strength_finished = max(0, e.strength_finished - time);
1707         e.invincible_finished = max(0, e.invincible_finished - time);
1708
1709         PREGIVE(e, items);
1710         PREGIVE(e, weapons);
1711         PREGIVE(e, strength_finished);
1712         PREGIVE(e, invincible_finished);
1713         PREGIVE(e, ammo_nails);
1714         PREGIVE(e, ammo_cells);
1715         PREGIVE(e, ammo_shells);
1716         PREGIVE(e, ammo_rockets);
1717         PREGIVE(e, ammo_fuel);
1718         PREGIVE(e, armorvalue);
1719         PREGIVE(e, health);
1720
1721         for(i = beginarg; i < endarg; ++i)
1722         {
1723                 cmd = argv(i);
1724
1725                 if(cmd == "0" || stof(cmd))
1726                 {
1727                         val = stof(cmd);
1728                         continue;
1729                 }
1730                 switch(cmd)
1731                 {
1732                         case "no":
1733                                 op = OP_MAX;
1734                                 val = 0;
1735                                 continue;
1736                         case "max":
1737                                 op = OP_MAX;
1738                                 continue;
1739                         case "min":
1740                                 op = OP_MIN;
1741                                 continue;
1742                         case "plus":
1743                                 op = OP_PLUS;
1744                                 continue;
1745                         case "minus":
1746                                 op = OP_MINUS;
1747                                 continue;
1748                         case "ALL":
1749                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1750                                 got += GiveValue(e, strength_finished, op, time);
1751                                 got += GiveValue(e, invincible_finished, op, time);
1752                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1753                         case "all":
1754                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1755                                 got += GiveValue(e, health, op, val);
1756                                 got += GiveValue(e, armorvalue, op, val);
1757                         case "allweapons":
1758                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1759                                 {
1760                                         wi = get_weaponinfo(j);
1761                                         if(wi.weapons)
1762                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1763                                 }
1764                         case "allammo":
1765                                 got += GiveValue(e, ammo_cells, op, val);
1766                                 got += GiveValue(e, ammo_shells, op, val);
1767                                 got += GiveValue(e, ammo_nails, op, val);
1768                                 got += GiveValue(e, ammo_rockets, op, val);
1769                                 got += GiveValue(e, ammo_fuel, op, val);
1770                                 break;
1771                         case "unlimited_ammo":
1772                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1773                                 break;
1774                         case "unlimited_weapon_ammo":
1775                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1776                                 break;
1777                         case "unlimited_superweapons":
1778                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1779                                 break;
1780                         case "jetpack":
1781                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1782                                 break;
1783                         case "fuel_regen":
1784                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1785                                 break;
1786                         case "strength":
1787                                 got += GiveValue(e, strength_finished, op, val);
1788                                 break;
1789                         case "invincible":
1790                                 got += GiveValue(e, invincible_finished, op, val);
1791                                 break;
1792                         case "cells":
1793                                 got += GiveValue(e, ammo_cells, op, val);
1794                                 break;
1795                         case "shells":
1796                                 got += GiveValue(e, ammo_shells, op, val);
1797                                 break;
1798                         case "nails":
1799                         case "bullets":
1800                                 got += GiveValue(e, ammo_nails, op, val);
1801                                 break;
1802                         case "rockets":
1803                                 got += GiveValue(e, ammo_rockets, op, val);
1804                                 break;
1805                         case "health":
1806                                 got += GiveValue(e, health, op, val);
1807                                 break;
1808                         case "armor":
1809                                 got += GiveValue(e, armorvalue, op, val);
1810                                 break;
1811                         case "fuel":
1812                                 got += GiveValue(e, ammo_fuel, op, val);
1813                                 break;
1814                         default:
1815                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1816                                 {
1817                                         wi = get_weaponinfo(j);
1818                                         if(cmd == wi.netname)
1819                                         {
1820                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1821                                                 break;
1822                                         }
1823                                 }
1824                                 if(j > WEP_LAST)
1825                                         print("give: invalid item ", cmd, "\n");
1826                                 break;
1827                 }
1828                 val = 999;
1829                 op = OP_SET;
1830         }
1831
1832         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1833         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1834         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1835         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1836         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1837         {
1838                 wi = get_weaponinfo(j);
1839                 if(wi.weapons)
1840                 {
1841                         POSTGIVE_BIT(e, weapons, wi.weapons, "weapons/weaponpickup.wav", string_null);
1842                         if not(save_weapons & wi.weapons)
1843                                 if(e.weapons & wi.weapons)
1844                                         weapon_action(wi.weapon, WR_PRECACHE);
1845                 }
1846         }
1847         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1848         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1849         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1850         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1851         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1852         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1853         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1854         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1855         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1856
1857         if (g_minstagib)
1858         {
1859                 e.health = bound(0, e.health, 100);
1860                 e.armorvalue = bound(0, e.armorvalue, 999);
1861         }
1862
1863         if(e.strength_finished <= 0)
1864                 e.strength_finished = 0;
1865         else
1866                 e.strength_finished += time;
1867         if(e.invincible_finished <= 0)
1868                 e.invincible_finished = 0;
1869         else
1870                 e.invincible_finished += time;
1871
1872         if not(e.weapons & W_WeaponBit(e.switchweapon))
1873                 _switchweapon = TRUE;
1874         if(_switchweapon)
1875                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1876
1877         return got;
1878 }