qcsrc/server/scores.qc

   1 #include "scores.qh"
   2
   3 #include <common/mapinfo.qh>
   4 #include <common/mutators/base.qh>
   5 #include <common/net_linked.qh>
   6 #include <common/playerstats.qh>
   7 #include <common/scores.qh>
   8 #include <common/state.qh>
   9 #include <common/stats.qh>
  10 #include <common/teams.qh>
  11 #include <common/weapons/_all.qh>
  12 #include <server/client.qh>
  13 #include <server/command/common.qh>
  14 #include <server/intermission.qh>
  15 #include <server/mutators/_mod.qh>
  16 #include <server/round_handler.qh>
  17 #include <server/world.qh>
  18
  19 .entity scorekeeper;
  20 entity teamscorekeepers[16];
  21 float teamscores_entities_count;
  22 var .float scores_primary;
  23 var .float teamscores_primary;
  24 float scores_flags_primary;
  25 float teamscores_flags_primary;
  26
  27 vector ScoreField_Compare(entity t1, entity t2, .float field, float fieldflags, vector previous, bool strict) // returns: cmp value, best prio
  28 {
  29         if(!strict && !(fieldflags & SFL_SORT_PRIO_MASK)) // column does not sort
  30                 return previous;
  31         if((fieldflags & SFL_SORT_PRIO_MASK) < previous.y)
  32                 return previous;
  33         if (t1.(field) == t2.(field))
  34                 return previous;
  35
  36         previous.y = fieldflags & SFL_SORT_PRIO_MASK;
  37
  38         if(fieldflags & SFL_ZERO_IS_WORST)
  39         {
  40                 if (t1.(field) == 0)
  41                 {
  42                         previous.x = -1;
  43                         return previous;
  44                 }
  45                 else if (t2.(field) == 0)
  46                 {
  47                         previous.x = +1;
  48                         return previous;
  49                 }
  50         }
  51
  52         if (fieldflags & SFL_LOWER_IS_BETTER)
  53                 previous.x = (t2.(field) - t1.(field));
  54         else
  55                 previous.x = (t1.(field) - t2.(field));
  56
  57         return previous;
  58 }
  59
  60 /*
  61  * teamscore entities
  62  */
  63
  64 bool TeamScore_SendEntity(entity this, entity to, float sendflags)
  65 {
  66         float i, longflags;
  67
  68         WriteHeader(MSG_ENTITY, ENT_CLIENT_TEAMSCORES);
  69         int t = this.team - 1;
  70         assert(t, eprint(this));
  71         WriteByte(MSG_ENTITY, t);
  72
  73         longflags = 0;
  74         for(i = 0; i < MAX_TEAMSCORE; ++i)
  75                 if(this.(teamscores(i)) > 127 || this.(teamscores(i)) <= -128)
  76                         longflags |= BIT(i);
  77
  78 #if MAX_TEAMSCORE <= 8
  79         WriteByte(MSG_ENTITY, sendflags);
  80         WriteByte(MSG_ENTITY, longflags);
  81 #else
  82         WriteShort(MSG_ENTITY, sendflags);
  83         WriteShort(MSG_ENTITY, longflags);
  84 #endif
  85         for(i = 0; i < MAX_TEAMSCORE; ++i)
  86                 if(sendflags & BIT(i))
  87                 {
  88                         if(longflags & BIT(i))
  89                                 WriteInt24_t(MSG_ENTITY, this.(teamscores(i)));
  90                         else
  91                                 WriteChar(MSG_ENTITY, this.(teamscores(i)));
  92                 }
  93
  94         return true;
  95 }
  96
  97 void TeamScore_Spawn(float t, string name)
  98 {
  99         entity ts = new_pure(csqc_score_team);
 100         ts.netname = name; // not used yet, FIXME
 101         ts.team = t;
 102         Net_LinkEntity(ts, false, 0, TeamScore_SendEntity);
 103         teamscorekeepers[t - 1] = ts;
 104         ++teamscores_entities_count;
 105         PlayerStats_GameReport_AddTeam(t);
 106 }
 107
 108 float TeamScore_AddToTeam(int t, float scorefield, float score)
 109 {
 110         entity s;
 111
 112         if(game_stopped)
 113         {
 114                 score = 0;
 115         }
 116
 117         if(!scores_initialized) return 0; // FIXME remove this when everything uses this system
 118         if(t <= 0 || t >= 16)
 119         {
 120                 if(game_stopped)
 121                         return 0;
 122                 error("Adding score to invalid team!");
 123         }
 124         s = teamscorekeepers[t - 1];
 125         if(!s)
 126         {
 127                 if(game_stopped)
 128                         return 0;
 129                 error("Adding score to unknown team!");
 130         }
 131         if(score)
 132                 if(teamscores_label(scorefield) != "")
 133                         s.SendFlags |= BIT(scorefield);
 134         return (s.(teamscores(scorefield)) += score);
 135 }
 136
 137 float TeamScore_Add(entity player, float scorefield, float score)
 138 {
 139         return TeamScore_AddToTeam(player.team, scorefield, score);
 140 }
 141
 142 float TeamScore_Compare(entity t1, entity t2, bool strict)
 143 {
 144         if(!t1 || !t2) return (!t2) - !t1;
 145
 146         vector result = '0 0 0';
 147         float i;
 148         for(i = 0; i < MAX_TEAMSCORE; ++i)
 149         {
 150                 var .float f;
 151                 f = teamscores(i);
 152                 result = ScoreField_Compare(t1, t2, f, teamscores_flags(i), result, strict);
 153         }
 154
 155         if (result.x == 0 && strict)
 156                 result.x = t1.team - t2.team;
 157
 158         return result.x;
 159 }
 160
 161 /*
 162  * the scoreinfo entity
 163  */
 164
 165 void ScoreInfo_SetLabel_PlayerScore(PlayerScoreField i, string label, float scoreflags)
 166 {
 167         scores_label(i) = label;
 168         scores_flags(i) = scoreflags;
 169         if((scoreflags & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 170         {
 171                 scores_primary = scores(i);
 172                 scores_flags_primary = scoreflags;
 173         }
 174         if(label != "")
 175         {
 176                 PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_TOTAL, label));
 177                 PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_SCOREBOARD, label));
 178         }
 179 }
 180
 181 void ScoreInfo_SetLabel_TeamScore(float i, string label, float scoreflags)
 182 {
 183         teamscores_label(i) = label;
 184         teamscores_flags(i) = scoreflags;
 185         if((scoreflags & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 186         {
 187                 teamscores_primary = teamscores(i);
 188                 teamscores_flags_primary = scoreflags;
 189         }
 190         if(label != "")
 191         {
 192                 PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_TOTAL, label));
 193                 PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_SCOREBOARD, label));
 194         }
 195 }
 196
 197 bool ScoreInfo_SendEntity(entity this, entity to, int sf)
 198 {
 199         float i;
 200         WriteHeader(MSG_ENTITY, ENT_CLIENT_SCORES_INFO);
 201         WriteRegistered(Gametypes, MSG_ENTITY, MapInfo_LoadedGametype);
 202         FOREACH(Scores, true, {
 203                 WriteString(MSG_ENTITY, scores_label(it));
 204                 WriteByte(MSG_ENTITY, scores_flags(it));
 205         });
 206         for(i = 0; i < MAX_TEAMSCORE; ++i)
 207         {
 208                 WriteString(MSG_ENTITY, teamscores_label(i));
 209                 WriteByte(MSG_ENTITY, teamscores_flags(i));
 210         }
 211         return true;
 212 }
 213
 214 void ScoreInfo_Init(int teams)
 215 {
 216         if(scores_initialized)
 217         {
 218                 scores_initialized.SendFlags |= 1; // force a resend
 219         }
 220         else
 221         {
 222                 scores_initialized = new_pure(ent_client_scoreinfo);
 223                 Net_LinkEntity(scores_initialized, false, 0, ScoreInfo_SendEntity);
 224         }
 225         if(teams & BIT(0))
 226                 TeamScore_Spawn(NUM_TEAM_1, "Red");
 227         if(teams & BIT(1))
 228                 TeamScore_Spawn(NUM_TEAM_2, "Blue");
 229         if(teams & BIT(2))
 230                 TeamScore_Spawn(NUM_TEAM_3, "Yellow");
 231         if(teams & BIT(3))
 232                 TeamScore_Spawn(NUM_TEAM_4, "Pink");
 233 }
 234
 235 /*
 236  * per-player score entities
 237  */
 238
 239 bool PlayerScore_SendEntity(entity this, entity to, float sendflags)
 240 {
 241         WriteHeader(MSG_ENTITY, ENT_CLIENT_SCORES);
 242         WriteByte(MSG_ENTITY, etof(this.owner));
 243
 244         int longflags = 0;
 245         FOREACH(Scores, true, {
 246             int p = 1 << (i % 16);
 247                 if (this.(scores(it)) > 127 || this.(scores(it)) <= -128)
 248                         longflags |= p;
 249     });
 250
 251         WriteShort(MSG_ENTITY, sendflags);
 252         WriteShort(MSG_ENTITY, longflags);
 253         FOREACH(Scores, true, {
 254             int p = 1 << (i % 16);
 255                 if (sendflags & p)
 256                 {
 257                         if(longflags & p)
 258                                 WriteInt24_t(MSG_ENTITY, this.(scores(it)));
 259                         else
 260                                 WriteChar(MSG_ENTITY, this.(scores(it)));
 261                 }
 262     });
 263
 264         return true;
 265 }
 266
 267 float PlayerScore_Clear(entity player)
 268 {
 269         entity sk;
 270
 271         if(teamscores_entities_count)
 272                 return 0;
 273
 274         if(MUTATOR_CALLHOOK(ForbidPlayerScore_Clear)) return 0;
 275
 276         sk = CS(player).scorekeeper;
 277         FOREACH(Scores, true, {
 278                 if(sk.(scores(it)) != 0)
 279                         //if(scores_label(it) != "")
 280                         sk.SendFlags |= (2 ** (i % 16));
 281                 if(i != SP_ELO.m_id)
 282                         sk.(scores(it)) = 0;
 283         });
 284
 285         return 1;
 286 }
 287
 288 void Score_ClearAll()
 289 {
 290         entity sk;
 291         float t;
 292         FOREACH_CLIENTSLOT(true, {
 293                 sk = CS(it).scorekeeper;
 294                 if (!sk) continue;
 295                 FOREACH(Scores, true, {
 296                         if(sk.(scores(it)) != 0)
 297                                 //if(scores_label(it) != "")
 298                                 sk.SendFlags |= (2 ** (i % 16));
 299                         if(i != SP_ELO.m_id)
 300                                 sk.(scores(it)) = 0;
 301                 });
 302         });
 303         for(t = 0; t < 16; ++t)
 304         {
 305                 sk = teamscorekeepers[t];
 306                 if(!sk)
 307                         continue;
 308                 for(int j = 0; j < MAX_TEAMSCORE; ++j)
 309                 {
 310                         if(sk.(teamscores(j)) != 0)
 311                                 //if(teamscores_label(j) != "")
 312                                 sk.SendFlags |= (2 ** j);
 313                         sk.(teamscores(j)) = 0;
 314                 }
 315         }
 316 }
 317
 318 void PlayerScore_Attach(entity player)
 319 {
 320         if(CS(player).scorekeeper)
 321                 error("player already has a scorekeeper");
 322         entity sk = new_pure(scorekeeper);
 323         sk.owner = player;
 324         Net_LinkEntity(sk, false, 0, PlayerScore_SendEntity);
 325         CS(player).scorekeeper = sk;
 326 }
 327
 328 void PlayerScore_Detach(entity player)
 329 {
 330         if(!CS(player).scorekeeper)
 331                 error("player has no scorekeeper");
 332         delete(CS(player).scorekeeper);
 333         CS(player).scorekeeper = NULL;
 334 }
 335
 336 float PlayerScore_Add(entity player, PlayerScoreField scorefield, float score)
 337 {
 338         bool mutator_returnvalue = MUTATOR_CALLHOOK(AddPlayerScore, scorefield, score, player);
 339         score = M_ARGV(1, float);
 340
 341         if(!mutator_returnvalue && game_stopped)
 342         {
 343                 score = 0;
 344         }
 345
 346         if(!scores_initialized) return 0; // FIXME remove this when everything uses this system
 347         entity s = CS(player).scorekeeper;
 348         if(!s)
 349         {
 350                 if(game_stopped)
 351                         return 0;
 352                 LOG_WARN("Adding score to unknown player!");
 353                 return 0;
 354         }
 355         if(!score)
 356         {
 357                 return s.(scores(scorefield));
 358         }
 359         //if(scores_label(scorefield) != "")
 360         s.SendFlags |= (2 ** (scorefield.m_id % 16));
 361         if(!warmup_stage)
 362                 PlayerStats_GameReport_Event_Player(s.owner, strcat(PLAYERSTATS_TOTAL, scores_label(scorefield)), score);
 363         s.(scores(scorefield)) += score;
 364         MUTATOR_CALLHOOK(AddedPlayerScore, scorefield, score, player);
 365         return s.(scores(scorefield));
 366 }
 367
 368 float PlayerScore_Set(entity player, PlayerScoreField scorefield, float score)
 369 {
 370         if(!scores_initialized) return 0; // FIXME remove this when everything uses this system
 371         entity s = CS(player).scorekeeper;
 372         if(!s)
 373         {
 374                 if(game_stopped)
 375                         return 0;
 376                 LOG_WARN("Setting score of unknown player!");
 377                 return 0;
 378         }
 379
 380         float oldscore = s.(scores(scorefield));
 381         if(oldscore == score)
 382                 return oldscore;
 383
 384         if(scores_label(scorefield) != "")
 385                 s.SendFlags |= BIT(scorefield.m_id % 16);
 386         s.(scores(scorefield)) = score;
 387         return s.(scores(scorefield));
 388 }
 389
 390 float PlayerTeamScore_Add(entity player, PlayerScoreField pscorefield, float tscorefield, float score)
 391 {
 392         float r;
 393         r = PlayerScore_Add(player, pscorefield, score);
 394         if(teamscores_entities_count) // only for teamplay
 395                 r = TeamScore_Add(player, tscorefield, score);
 396         return r;
 397 }
 398
 399 float PlayerScore_Compare(entity t1, entity t2, bool strict)
 400 {
 401         if(!t1 || !t2) return (!t2) - !t1;
 402
 403         vector result = '0 0 0';
 404         FOREACH(Scores, true, {
 405                 var .float f = scores(it);
 406                 result = ScoreField_Compare(t1, t2, f, scores_flags(it), result, strict);
 407         });
 408
 409         if (result.x == 0 && strict)
 410                 result.x = t1.owner.playerid - t2.owner.playerid;
 411
 412         return result.x;
 413 }
 414
 415 bool Score_NewLeader()
 416 {
 417         if(teamplay) {
 418                 if (WinningConditionHelper_winnerteam != WinningConditionHelper_winnerteam_last && (WinningConditionHelper_secondteam || WinningConditionHelper_equality))
 419                 {
 420                         WinningConditionHelper_winnerteam_last = WinningConditionHelper_winnerteam;
 421                         return true;
 422                 }
 423         } else {
 424                 if (WinningConditionHelper_winner != WinningConditionHelper_winner_last && (WinningConditionHelper_second || WinningConditionHelper_equality))
 425                 {
 426                         WinningConditionHelper_winner_last = WinningConditionHelper_winner;
 427                         return true;
 428                 }
 429         }
 430         return false;
 431 }
 432
 433 void WinningConditionHelper(entity this)
 434 {
 435         float c;
 436         string s;
 437         float fullstatus;
 438         entity winnerscorekeeper;
 439         entity secondscorekeeper;
 440         entity sk;
 441
 442         // format:
 443         // gametype:P<pure>:S<slots>::plabel,plabel:tlabel,tlabel:teamid:tscore,tscore:teamid:tscore,tscore
 444         // score labels always start with a symbol or with lower case
 445         // so to match pure, match for :P0:
 446         // to match full, match for :S0:
 447
 448         fullstatus = autocvar_g_full_getstatus_responses;
 449
 450         s = GetGametype();
 451         s = strcat(s, ":", autocvar_g_xonoticversion);
 452         s = strcat(s, ":P", ftos(cvar_purechanges_count));
 453         s = strcat(s, ":S", ftos(nJoinAllowed(this, NULL)));
 454         s = strcat(s, ":F", ftos(serverflags));
 455         s = strcat(s, ":M", modname);
 456         s = strcat(s, "::", GetPlayerScoreString(NULL, (fullstatus ? 1 : 2)));
 457
 458         if(teamscores_entities_count)
 459         {
 460                 float t;
 461
 462                 s = strcat(s, ":", GetTeamScoreString(0, 1));
 463                 for(t = 0; t < 16; ++t)
 464                         if(teamscorekeepers[t])
 465                                 s = strcat(s, ":", ftos(t+1), ":", GetTeamScoreString(t+1, 1));
 466
 467                 WinningConditionHelper_winnerteam = -1;
 468                 WinningConditionHelper_secondteam = -1;
 469                 winnerscorekeeper = NULL;
 470                 secondscorekeeper = NULL;
 471                 for(t = 0; t < 16; ++t)
 472                 {
 473                         sk = teamscorekeepers[t];
 474                         c = TeamScore_Compare(winnerscorekeeper, sk, 1);
 475                         if(c < 0)
 476                         {
 477                                 WinningConditionHelper_secondteam = WinningConditionHelper_winnerteam;
 478                                 WinningConditionHelper_winnerteam = t + 1;
 479                                 secondscorekeeper = winnerscorekeeper;
 480                                 winnerscorekeeper = sk;
 481                         }
 482                         else
 483                         {
 484                                 c = TeamScore_Compare(secondscorekeeper, sk, 1);
 485                                 if(c < 0)
 486                                 {
 487                                         WinningConditionHelper_secondteam = t + 1;
 488                                         secondscorekeeper = sk;
 489                                 }
 490                         }
 491                 }
 492
 493                 WinningConditionHelper_equality = (TeamScore_Compare(winnerscorekeeper, secondscorekeeper, 0) == 0);
 494                 if(WinningConditionHelper_equality)
 495                         WinningConditionHelper_winnerteam = WinningConditionHelper_secondteam = -1;
 496
 497                 WinningConditionHelper_topscore = winnerscorekeeper.teamscores_primary;
 498                 WinningConditionHelper_secondscore = secondscorekeeper.teamscores_primary;
 499                 WinningConditionHelper_lowerisbetter = (teamscores_flags_primary & SFL_LOWER_IS_BETTER);
 500                 WinningConditionHelper_zeroisworst = (teamscores_flags_primary & SFL_ZERO_IS_WORST);
 501
 502                 WinningConditionHelper_winner = NULL; // not supported in teamplay
 503                 WinningConditionHelper_second = NULL; // not supported in teamplay
 504         }
 505         else
 506         {
 507                 WinningConditionHelper_winner = NULL;
 508                 WinningConditionHelper_second = NULL;
 509                 winnerscorekeeper = NULL;
 510                 secondscorekeeper = NULL;
 511                 FOREACH_CLIENT(IS_PLAYER(it), {
 512                         sk = CS(it).scorekeeper;
 513                         c = PlayerScore_Compare(winnerscorekeeper, sk, true);
 514                         if(c < 0)
 515                         {
 516                                 WinningConditionHelper_second = WinningConditionHelper_winner;
 517                                 WinningConditionHelper_winner = it;
 518                                 secondscorekeeper = winnerscorekeeper;
 519                                 winnerscorekeeper = sk;
 520                         }
 521                         else
 522                         {
 523                                 c = PlayerScore_Compare(secondscorekeeper, sk, true);
 524                                 if(c < 0)
 525                                 {
 526                                         WinningConditionHelper_second = it;
 527                                         secondscorekeeper = sk;
 528                                 }
 529                         }
 530                 });
 531
 532                 WinningConditionHelper_equality = (PlayerScore_Compare(winnerscorekeeper, secondscorekeeper, false) == 0);
 533                 if(WinningConditionHelper_equality)
 534                 {
 535                         WinningConditionHelper_equality_one = WinningConditionHelper_winner;
 536                         WinningConditionHelper_equality_two = WinningConditionHelper_second;
 537                         WinningConditionHelper_winner = WinningConditionHelper_second = NULL;
 538                 }
 539                 else
 540                 {
 541                         WinningConditionHelper_equality_one = WinningConditionHelper_equality_two = NULL;
 542                 }
 543
 544                 WinningConditionHelper_topscore = winnerscorekeeper.scores_primary;
 545                 WinningConditionHelper_secondscore = secondscorekeeper.scores_primary;
 546                 WinningConditionHelper_lowerisbetter = (scores_flags_primary & SFL_LOWER_IS_BETTER);
 547                 WinningConditionHelper_zeroisworst = (scores_flags_primary & SFL_ZERO_IS_WORST);
 548
 549                 WinningConditionHelper_winnerteam = -1; // no teamplay
 550                 WinningConditionHelper_secondteam = -1; // no teamplay
 551         }
 552
 553         if(WinningConditionHelper_topscore == 0)
 554         {
 555                 if(scores_flags_primary & SFL_ZERO_IS_WORST)
 556                 {
 557                         if(WinningConditionHelper_lowerisbetter)
 558                                 WinningConditionHelper_topscore = 999999999;
 559                         else
 560                                 WinningConditionHelper_topscore = -999999999;
 561                 }
 562                 if(player_count == 0) // special case: empty servers DO end the match at a 0:0 tie
 563                         WinningConditionHelper_equality = 0;
 564         }
 565
 566         if(WinningConditionHelper_secondscore == 0)
 567         {
 568                 if(scores_flags_primary & SFL_ZERO_IS_WORST)
 569                 {
 570                         if(WinningConditionHelper_lowerisbetter)
 571                                 WinningConditionHelper_secondscore = 999999999;
 572                         else
 573                                 WinningConditionHelper_secondscore = -999999999;
 574                 }
 575         }
 576
 577         strcpy(worldstatus, s);
 578
 579         FOREACH_CLIENT(true, {
 580                 string s = "";
 581                 if(fullstatus)
 582                 {
 583                         s = GetPlayerScoreString(it, 1);
 584                         s = strcat(s, IS_REAL_CLIENT(it) ? ":human" : ":bot");
 585                         if(!IS_PLAYER(it) && !MUTATOR_CALLHOOK(GetPlayerStatus, it))
 586                                 s = strcat(s, ":spectator");
 587                 }
 588                 else
 589                 {
 590                         if (IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it))
 591                                 s = GetPlayerScoreString(it, 2);
 592                         else
 593                                 s = "-666";
 594                 }
 595
 596                 strcpy(it.clientstatus, s);
 597         });
 598 }
 599
 600 string GetScoreLogLabel(string label, float fl)
 601 {
 602         if(fl & SFL_LOWER_IS_BETTER)
 603                 label = strcat(label, "<");
 604         if((fl & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 605                 label = strcat(label, "!!");
 606         else if((fl & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
 607                 label = strcat(label, "!");
 608         return label;
 609 }
 610
 611 string GetPlayerScoreString(entity pl, float shortString)
 612 {
 613         string out;
 614         entity sk;
 615         float f;
 616         string l;
 617
 618         out = "";
 619         if(!pl)
 620         {
 621                 // label
 622                 FOREACH(Scores, true, {
 623                         if ((scores_flags(it) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 624                         {
 625                                 f = scores_flags(it);
 626                                 l = scores_label(it);
 627                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 628                         }
 629         });
 630                 if(shortString < 2)
 631                 FOREACH(Scores, true, {
 632                         if((scores_flags(it) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
 633                         {
 634                                 f = scores_flags(it);
 635                                 l = scores_label(it);
 636                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 637                         }
 638         });
 639                 if(shortString < 1)
 640                 FOREACH(Scores, true, {
 641                         if((scores_flags(it) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_PRIMARY)
 642                         if((scores_flags(it) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_SECONDARY)
 643                         {
 644                                 f = scores_flags(it);
 645                                 l = scores_label(it);
 646                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 647                         }
 648         });
 649                 out = substring(out, 0, strlen(out) - 1);
 650         }
 651         else if((sk = CS(pl).scorekeeper))
 652         {
 653                 FOREACH(Scores, true, {
 654                         if ((scores_flags(it) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 655                                 out = strcat(out, ftos(sk.(scores(it))), ",");
 656         });
 657                 if(shortString < 2)
 658                 FOREACH(Scores, true, {
 659                         if ((scores_flags(it) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
 660                                 out = strcat(out, ftos(sk.(scores(it))), ",");
 661         });
 662                 if(shortString < 1)
 663                 FOREACH(Scores, true, {
 664                         if((scores_flags(it) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_PRIMARY)
 665                         if((scores_flags(it) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_SECONDARY)
 666                                 out = strcat(out, ftos(sk.(scores(it))), ",");
 667         });
 668                 out = substring(out, 0, strlen(out) - 1);
 669         }
 670         return out;
 671 }
 672
 673 string GetTeamScoreString(float tm, float shortString)
 674 {
 675         string out;
 676         entity sk;
 677         float i, f;
 678         string l;
 679
 680         out = "";
 681         if(tm == 0)
 682         {
 683                 // label
 684                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 685                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 686                         {
 687                                 f = teamscores_flags(i);
 688                                 l = teamscores_label(i);
 689                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 690                         }
 691                 if(shortString < 2)
 692                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 693                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
 694                         {
 695                                 f = teamscores_flags(i);
 696                                 l = teamscores_label(i);
 697                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 698                         }
 699                 if(shortString < 1)
 700                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 701                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_PRIMARY)
 702                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_SECONDARY)
 703                         {
 704                                 f = teamscores_flags(i);
 705                                 l = teamscores_label(i);
 706                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 707                         }
 708                 out = substring(out, 0, strlen(out) - 1);
 709         }
 710         else if((sk = teamscorekeepers[tm - 1]))
 711         {
 712                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 713                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 714                                 out = strcat(out, ftos(sk.(teamscores(i))), ",");
 715                 if(shortString < 2)
 716                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 717                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
 718                                 out = strcat(out, ftos(sk.(teamscores(i))), ",");
 719                 if(shortString < 1)
 720                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 721                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_PRIMARY)
 722                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_SECONDARY)
 723                                 out = strcat(out, ftos(sk.(teamscores(i))), ",");
 724                 out = substring(out, 0, strlen(out) - 1);
 725         }
 726         return out;
 727 }
 728
 729 float PlayerTeamScore_Compare(entity p1, entity p2, float teams, bool strict)
 730 {
 731         if(teams && teamscores_entities_count)
 732         {
 733                 if(p1.team != p2.team)
 734                 {
 735                         entity t1, t2;
 736                         float r;
 737                         t1 = teamscorekeepers[p1.team - 1];
 738                         t2 = teamscorekeepers[p2.team - 1];
 739                         r = TeamScore_Compare(t1, t2, ((teams >= 0) ? 1 : strict));
 740                         return r;
 741                 }
 742                 if(teams < 0)
 743                         return 0;
 744         }
 745
 746         return PlayerScore_Compare(CS(p1).scorekeeper, CS(p2).scorekeeper, strict);
 747 }
 748
 749 entity PlayerScore_Sort(.float field, int teams, bool strict, bool nospectators)
 750 {
 751         entity p, plist, pprev, pbest, pbestprev, pfirst, plast;
 752         float i, j;
 753
 754         plist = NULL;
 755
 756         FOREACH_CLIENT(true, { it.(field) = 0; });
 757
 758         FOREACH_CLIENT(CS(it).scorekeeper,
 759         {
 760                 if(nospectators)
 761                         if(it.frags == FRAGS_SPECTATOR)
 762                                 continue;
 763
 764                 it.chain = plist;
 765                 plist = it;
 766         });
 767         // Now plist points to the whole list.
 768
 769         pfirst = plast = NULL;
 770
 771         i = j = 0;
 772         while(plist)
 773         {
 774                 pprev = pbestprev = NULL;
 775                 pbest = plist;
 776                 for(p = plist; (pprev = p), (p = p.chain); )
 777                 {
 778                         if(PlayerTeamScore_Compare(p, pbest, teams, strict) > 0)
 779                         {
 780                                 pbest = p;
 781                                 pbestprev = pprev;
 782                         }
 783                 }
 784
 785                 // remove pbest out of the chain
 786                 if(pbestprev == NULL)
 787                         plist = pbest.chain;
 788                 else
 789                         pbestprev.chain = pbest.chain;
 790                 pbest.chain = NULL;
 791
 792                 ++i;
 793                 if(!plast || PlayerTeamScore_Compare(plast, pbest, teams, strict))
 794                         j = i;
 795
 796                 pbest.(field) = j;
 797
 798                 if (!pfirst)
 799                         pfirst = pbest;
 800                 if(plast)
 801                         plast.chain = pbest;
 802                 plast = pbest;
 803         }
 804
 805         return pfirst;
 806 }
 807
 808 float TeamScore_GetCompareValue(float t)
 809 {
 810         float s;
 811         entity sk;
 812
 813         if(t <= 0 || t >= 16)
 814         {
 815                 if(game_stopped)
 816                         return 0;
 817                 error("Reading score of invalid team!");
 818         }
 819
 820         sk = teamscorekeepers[t - 1];
 821         if (!sk)
 822                 return -999999999;
 823         s = sk.teamscores_primary;
 824         if(teamscores_flags_primary & SFL_ZERO_IS_WORST)
 825                 if(!s)
 826                         return -999999999;
 827         if(teamscores_flags_primary & SFL_LOWER_IS_BETTER)
 828                 s = -s;
 829         return s;
 830 }
 831
 832 const float NAMEWIDTH = 22;
 833 const float SCORESWIDTH = 58;
 834 // TODO put this somewhere in common?
 835 string Score_NicePrint_ItemColor(float vflags)
 836 {
 837         if(vflags & SFL_SORT_PRIO_PRIMARY)
 838                 return "^3";
 839         else if(vflags & SFL_SORT_PRIO_SECONDARY)
 840                 return "^5";
 841         else
 842                 return "^7";
 843 }
 844
 845 void Score_NicePrint_Team(entity to, float t, float w)
 846 {
 847         string s, s2;
 848         float i;
 849         entity sk;
 850         float fl, sc;
 851         s = "";
 852
 853         sk = teamscorekeepers[t - 1];
 854         if(sk)
 855         {
 856                 s = strcat(s, Team_ColoredFullName(t));
 857                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 858                         if(teamscores_label(i) != "")
 859                         {
 860                                 fl = teamscores_flags(i);
 861                                 sc = sk.(teamscores(i));
 862                                 s = strcat(s, " ", Score_NicePrint_ItemColor(fl), ScoreString(fl, sc));
 863                         }
 864         }
 865         else
 866                 s = "Scores:";
 867
 868         s = strcat(s, strpad(max(0, NAMEWIDTH - strlennocol(s)), ""));
 869
 870         FOREACH(Scores, true, {
 871                 if(scores_label(it) != "")
 872                 {
 873                         fl = scores_flags(it);
 874                         s2 = scores_label(it);
 875                         s = strcat(s, " ", Score_NicePrint_ItemColor(fl), strpad(-w, substring(s2, 0, w)));
 876                 }
 877     });
 878
 879         print_to(to, s);
 880 }
 881
 882 void Score_NicePrint_Player(entity to, entity p, float w)
 883 {
 884         string s;
 885         float i;
 886         entity sk;
 887         float fl, sc;
 888         s = "  ";
 889
 890         sk = CS(p).scorekeeper;
 891
 892         s = strcat(s, playername(p.netname, p.team, false));
 893         for (;;)
 894         {
 895                 i = strlennocol(s) - NAMEWIDTH;
 896                 if(i > 0)
 897                         s = substring(s, 0, strlen(s) - i);
 898                 else
 899                 {
 900                         s = strcat(s, strpad(i, ""));
 901                         break;
 902                 }
 903         }
 904
 905         FOREACH(Scores, true, {
 906                 if(scores_label(it) != "")
 907                 {
 908                         fl = scores_flags(it);
 909                         sc = sk.(scores(it));
 910                         s = strcat(s, " ", Score_NicePrint_ItemColor(fl), strpad(-w, ScoreString(fl, sc)));
 911                 }
 912     });
 913
 914         print_to(to, s);
 915 }
 916
 917 void Score_NicePrint_Spectators(entity to)
 918 {
 919         print_to(to, "Spectators:");
 920 }
 921
 922 void Score_NicePrint_Spectator(entity to, entity p)
 923 {
 924         print_to(to, strcat("  ", playername(p.netname, p.team, false)));
 925 }
 926
 927 .float score_dummyfield;
 928 void Score_NicePrint(entity to)
 929 {
 930         entity p;
 931         float w;
 932
 933         int t = 0;
 934         FOREACH(Scores, true, {
 935                 if(scores_label(it) != "")
 936                         ++t;
 937     });
 938         w = bound(6, floor(SCORESWIDTH / t - 1), 9);
 939
 940         p = PlayerScore_Sort(score_dummyfield, 1, true, false);
 941         t = -1;
 942
 943         if(!teamscores_entities_count)
 944                 Score_NicePrint_Team(to, t, w);
 945         while(p)
 946         {
 947                 if(teamscores_entities_count)
 948                         if(t != p.team)
 949                                 Score_NicePrint_Team(to, p.team, w);
 950                 Score_NicePrint_Player(to, p, w);
 951                 t = p.team;
 952                 p = p.chain;
 953         }
 954
 955         t = 0;
 956         FOREACH_CLIENT(!IS_PLAYER(it), {
 957                 if (!t)
 958                         Score_NicePrint_Spectators(to);
 959                 Score_NicePrint_Spectator(to, it);
 960                 t = 1;
 961         });
 962 }
 963
 964 void PlayerScore_PlayerStats(entity p)
 965 {
 966         entity s = CS(p).scorekeeper;
 967         FOREACH(Scores, true, {
 968                 if(s.(scores(it)) != 0 && scores_label(it) != "")
 969                         PlayerStats_GameReport_Event_Player(s.owner,
 970                                 strcat(PLAYERSTATS_SCOREBOARD, scores_label(it)), s.(scores(it)));
 971         });
 972 }
 973
 974 void PlayerScore_TeamStats()
 975 {
 976         entity sk;
 977         float t, i;
 978         for(t = 0; t < 16; ++t)
 979         {
 980                 sk = teamscorekeepers[t];
 981                 if(!sk)
 982                         continue;
 983                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 984                         if(sk.(teamscores(i)) != 0 && teamscores_label(i) != "")
 985                                 // the +1 is important here!
 986                                 PlayerStats_GameReport_Event_Team(t+1,
 987                                         strcat(PLAYERSTATS_SCOREBOARD, teamscores_label(i)), sk.(teamscores(i)));
 988         }
 989 }