qcsrc/server/round_handler.qc

   1 #include "round_handler.qh"
   2
   3 #include <common/mapobjects/triggers.qh>
   4 #include <common/util.qh>
   5 #include <server/campaign.qh>
   6 #include <server/command/vote.qh>
   7 #include <server/world.qh>
   8
   9 void round_handler_Think(entity this)
  10 {
  11         if (game_timeout) { this.nextthink = time + 1; return; }
  12
  13         if (intermission_running)
  14         {
  15                 round_handler_Reset(0);
  16                 round_handler_Remove();
  17                 return;
  18         }
  19
  20         if (time < game_starttime)
  21         {
  22                 round_handler_Reset(game_starttime);
  23                 return;
  24         }
  25
  26         game_stopped = false;
  27
  28         if (this.wait)
  29         {
  30                 this.wait = false;
  31                 this.cnt = this.count + 1;  // init countdown
  32                 round_starttime = time + this.count;
  33                 reset_map(true);
  34         }
  35
  36         if (this.cnt > 0)  // countdown running
  37         {
  38                 if (this.canRoundStart() && !(autocvar_g_campaign && !campaign_bots_may_start))
  39                 {
  40                         if (this.cnt == this.count + 1) round_starttime = time + this.count;
  41                         int f = this.cnt - 1;
  42                         if (f == 0)
  43                         {
  44                                 this.cnt = 0;
  45                                 this.round_endtime = (this.round_timelimit) ? time + this.round_timelimit : 0;
  46                                 this.nextthink = time;
  47                                 if (this.roundStart) this.roundStart();
  48                                 return;
  49                         }
  50                         this.cnt = this.cnt - 1;
  51                 }
  52                 else
  53                 {
  54                         round_handler_Reset(0);
  55                 }
  56                 this.nextthink = time + 1;  // canRoundStart every second
  57         }
  58         else
  59         {
  60                 if (this.canRoundEnd())
  61                 {
  62                         // schedule a new round
  63                         this.wait = true;
  64                         this.nextthink = time + this.delay;
  65                 }
  66                 else
  67                 {
  68                         this.nextthink = time;  // canRoundEnd every frame
  69                 }
  70         }
  71 }
  72
  73 void round_handler_Init(float the_delay, float the_count, float the_round_timelimit)
  74 {
  75         entity this = round_handler;
  76         this.delay = (the_delay > 0) ? the_delay : 0;
  77         this.count = fabs(floor(the_count));
  78         this.cnt = this.count + 1;
  79         this.round_timelimit = (the_round_timelimit > 0) ? the_round_timelimit : 0;
  80 }
  81
  82 // NOTE: this is only needed because if round_handler spawns at time 1
  83 // game_starttime isn't initialized yet
  84 void round_handler_FirstThink(entity this)
  85 {
  86         round_starttime = max(time, game_starttime) + this.count;
  87         setthink(this, round_handler_Think);
  88         this.nextthink = max(time, game_starttime);
  89 }
  90
  91 void round_handler_Spawn(bool() canRoundStart_func, bool() canRoundEnd_func, void() roundStart_func)
  92 {
  93         if (round_handler)
  94         {
  95                 backtrace("Can't spawn round_handler again!");
  96                 return;
  97         }
  98         entity this = round_handler = new_pure(round_handler);
  99
 100
 101         this.canRoundStart = canRoundStart_func;
 102         this.canRoundEnd = canRoundEnd_func;
 103         this.roundStart = roundStart_func;
 104         this.wait = false;
 105         round_handler_Init(5, 5, 180);
 106
 107 }
 108
 109 void round_handler_Activate(bool active) {
 110         if (round_handler) {
 111                 entity this = round_handler;
 112
 113                 this.isactive = active;
 114                 if(active) {
 115                         setthink(this, round_handler_FirstThink);
 116                         this.nextthink = time;
 117                 }
 118         }
 119 }
 120
 121 void round_handler_Reset(float next_think)
 122 {
 123         entity this = round_handler;
 124         this.wait = false;
 125         if (this.count)
 126                 if (this.cnt < this.count + 1) this.cnt = this.count + 1;
 127         this.nextthink = next_think;
 128         round_starttime = (next_think) ? (next_think + this.count) : -1;
 129 }
 130
 131 void round_handler_Remove()
 132 {
 133         delete(round_handler);
 134         round_handler = NULL;
 135 }