qcsrc/server/race.qc

   1 #include "race.qh"
   2
   3 #include "client.qh"
   4 #include "portals.qh"
   5 #include "scores.qh"
   6 #include "spawnpoints.qh"
   7 #include "bot/api.qh"
   8 #include "command/getreplies.qh"
   9 #include "../common/deathtypes/all.qh"
  10 #include "../common/notifications/all.qh"
  11 #include "../common/mapinfo.qh"
  12 #include <common/net_linked.qh>
  13 #include "../common/triggers/subs.qh"
  14 #include "../lib/warpzone/util_server.qh"
  15 #include "../lib/warpzone/common.qh"
  16 #include "../common/mutators/mutator/waypoints/waypointsprites.qh"
  17
  18 IntrusiveList g_race_targets;
  19 STATIC_INIT(g_race_targets) { g_race_targets = IL_NEW(); }
  20
  21 void race_InitSpectator()
  22 {
  23         if(g_race_qualifying)
  24                 if(msg_entity.enemy.race_laptime)
  25                         race_SendNextCheckpoint(msg_entity.enemy, 1);
  26 }
  27
  28 void W_Porto_Fail(entity this, float failhard);
  29
  30 float race_readTime(string map, float pos)
  31 {
  32         string rr = ((g_cts) ? CTS_RECORD : ((g_ctf) ? CTF_RECORD : RACE_RECORD));
  33
  34         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
  35 }
  36
  37 string race_readUID(string map, float pos)
  38 {
  39         string rr = ((g_cts) ? CTS_RECORD : ((g_ctf) ? CTF_RECORD : RACE_RECORD));
  40
  41         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
  42 }
  43
  44 float race_readPos(string map, float t)
  45 {
  46         for(int i = 1; i <= RANKINGS_CNT; ++i)
  47         {
  48                 int mytime = race_readTime(map, i);
  49                 if(!mytime || mytime > t)
  50                         return i;
  51         }
  52
  53         return 0; // pos is zero if unranked
  54 }
  55
  56 void race_writeTime(string map, float t, string myuid)
  57 {
  58         string rr = ((g_cts) ? CTS_RECORD : ((g_ctf) ? CTF_RECORD : RACE_RECORD));
  59
  60         float newpos;
  61         newpos = race_readPos(map, t);
  62
  63         float i, prevpos = 0;
  64         for(i = 1; i <= RANKINGS_CNT; ++i)
  65         {
  66                 if(race_readUID(map, i) == myuid)
  67                         prevpos = i;
  68         }
  69         if (prevpos)
  70         {
  71                 // player improved his existing record, only have to iterate on ranks between new and old recs
  72                 for (i = prevpos; i > newpos; --i)
  73                 {
  74                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
  75                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
  76                 }
  77         }
  78         else
  79         {
  80                 // player has no ranked record yet
  81                 for (i = RANKINGS_CNT; i > newpos; --i)
  82                 {
  83                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
  84                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
  85                 }
  86         }
  87
  88         // store new time itself
  89         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
  90         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
  91 }
  92
  93 string race_readName(string map, float pos)
  94 {
  95         string rr = ((g_cts) ? CTS_RECORD : ((g_ctf) ? CTF_RECORD : RACE_RECORD));
  96
  97         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
  98 }
  99
 100
 101 const float MAX_CHECKPOINTS = 255;
 102
 103 spawnfunc(target_checkpoint);
 104
 105 .float race_penalty;
 106 .float race_penalty_accumulator;
 107 .string race_penalty_reason;
 108 .float race_checkpoint; // player: next checkpoint that has to be reached
 109 .entity race_lastpenalty;
 110
 111 .entity sprite;
 112
 113 float race_checkpoint_records[MAX_CHECKPOINTS];
 114 string race_checkpoint_recordholders[MAX_CHECKPOINTS];
 115 float race_checkpoint_lasttimes[MAX_CHECKPOINTS];
 116 float race_checkpoint_lastlaps[MAX_CHECKPOINTS];
 117 entity race_checkpoint_lastplayers[MAX_CHECKPOINTS];
 118
 119 float race_highest_checkpoint;
 120 float race_timed_checkpoint;
 121
 122 float defrag_ents;
 123 float defragcpexists;
 124
 125 float race_NextCheckpoint(float f)
 126 {
 127         if(f >= race_highest_checkpoint)
 128                 return 0;
 129         else
 130                 return f + 1;
 131 }
 132
 133 float race_PreviousCheckpoint(float f)
 134 {
 135         if(f == -1)
 136                 return 0;
 137         else if(f == 0)
 138                 return race_highest_checkpoint;
 139         else
 140                 return f - 1;
 141 }
 142
 143 // encode as:
 144 //   0 = common start/finish
 145 // 254 = start
 146 // 255 = finish
 147 float race_CheckpointNetworkID(float f)
 148 {
 149         if(race_timed_checkpoint)
 150         {
 151                 if(f == 0)
 152                         return 254; // start
 153                 else if(f == race_timed_checkpoint)
 154                         return 255; // finish
 155         }
 156         return f;
 157 }
 158
 159 void race_SendNextCheckpoint(entity e, float spec) // qualifying only
 160 {
 161         float recordtime;
 162         string recordholder;
 163         float cp;
 164
 165         if(!e.race_laptime)
 166                 return;
 167
 168         cp = e.race_checkpoint;
 169         recordtime = race_checkpoint_records[cp];
 170         recordholder = race_checkpoint_recordholders[cp];
 171         if(recordholder == e.netname)
 172                 recordholder = "";
 173
 174         if(!IS_REAL_CLIENT(e))
 175                 return;
 176
 177         if(!spec)
 178                 msg_entity = e;
 179         WRITESPECTATABLE_MSG_ONE(msg_entity, {
 180                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
 181                 if(spec)
 182                 {
 183                         WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING);
 184                         //WriteCoord(MSG_ONE, e.race_laptime - e.race_penalty_accumulator);
 185                         WriteCoord(MSG_ONE, time - e.race_movetime - e.race_penalty_accumulator);
 186                 }
 187                 else
 188                         WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_NEXT_QUALIFYING);
 189                 WriteByte(MSG_ONE, race_CheckpointNetworkID(cp)); // checkpoint the player will be at next
 190                 WriteInt24_t(MSG_ONE, recordtime);
 191                 WriteString(MSG_ONE, recordholder);
 192         });
 193 }
 194
 195 void race_send_recordtime(float msg)
 196 {
 197         // send the server best time
 198         WriteHeader(msg, TE_CSQC_RACE);
 199         WriteByte(msg, RACE_NET_SERVER_RECORD);
 200         WriteInt24_t(msg, race_readTime(GetMapname(), 1));
 201 }
 202
 203
 204 void race_send_speedaward(float msg)
 205 {
 206         // send the best speed of the round
 207         WriteHeader(msg, TE_CSQC_RACE);
 208         WriteByte(msg, RACE_NET_SPEED_AWARD);
 209         WriteInt24_t(msg, floor(speedaward_speed+0.5));
 210         WriteString(msg, speedaward_holder);
 211 }
 212
 213 void race_send_speedaward_alltimebest(float msg)
 214 {
 215         // send the best speed
 216         WriteHeader(msg, TE_CSQC_RACE);
 217         WriteByte(msg, RACE_NET_SPEED_AWARD_BEST);
 218         WriteInt24_t(msg, floor(speedaward_alltimebest+0.5));
 219         WriteString(msg, speedaward_alltimebest_holder);
 220 }
 221
 222 void race_SendRankings(float pos, float prevpos, float del, float msg)
 223 {
 224         WriteHeader(msg, TE_CSQC_RACE);
 225         WriteByte(msg, RACE_NET_SERVER_RANKINGS);
 226         WriteShort(msg, pos);
 227         WriteShort(msg, prevpos);
 228         WriteShort(msg, del);
 229         WriteString(msg, race_readName(GetMapname(), pos));
 230         WriteInt24_t(msg, race_readTime(GetMapname(), pos));
 231 }
 232
 233 void race_SendStatus(float id, entity e)
 234 {
 235         if(!IS_REAL_CLIENT(e))
 236                 return;
 237
 238         float msg;
 239         if (id == 0)
 240                 msg = MSG_ONE;
 241         else
 242                 msg = MSG_ALL;
 243         msg_entity = e;
 244         WRITESPECTATABLE_MSG_ONE(msg_entity, {
 245                 WriteHeader(msg, TE_CSQC_RACE);
 246                 WriteByte(msg, RACE_NET_SERVER_STATUS);
 247                 WriteShort(msg, id);
 248                 WriteString(msg, e.netname);
 249         });
 250 }
 251
 252 void race_setTime(string map, float t, string myuid, string mynetname, entity e, bool showmessage)
 253 {
 254         // netname only used TEMPORARILY for printing
 255         int newpos = race_readPos(map, t);
 256
 257         int player_prevpos = 0;
 258         for(int i = 1; i <= RANKINGS_CNT; ++i)
 259         {
 260                 if(race_readUID(map, i) == myuid)
 261                         player_prevpos = i;
 262         }
 263
 264         float oldrec;
 265         string oldrec_holder;
 266         if (player_prevpos && (player_prevpos < newpos || !newpos))
 267         {
 268                 oldrec = race_readTime(GetMapname(), player_prevpos);
 269                 race_SendStatus(0, e); // "fail"
 270                 if(showmessage)
 271                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_FAIL_RANKED, mynetname, player_prevpos, t, oldrec);
 272                 return;
 273         }
 274         else if (!newpos)
 275         {
 276                 // no ranking, time worse than the worst ranked
 277                 oldrec = race_readTime(GetMapname(), RANKINGS_CNT);
 278                 race_SendStatus(0, e); // "fail"
 279                 if(showmessage)
 280                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_FAIL_UNRANKED, mynetname, RANKINGS_CNT, t, oldrec);
 281                 return;
 282         }
 283
 284         // if we didn't hit a return yet, we have a new record!
 285
 286         // if the player does not have a UID we can unfortunately not store the record, as the rankings system relies on UIDs
 287         if(myuid == "")
 288         {
 289                 if(showmessage)
 290                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_NEW_MISSING_UID, mynetname, t);
 291                 return;
 292         }
 293
 294         if(uid2name(myuid) == "^1Unregistered Player")
 295         {
 296                 if(showmessage)
 297                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_NEW_MISSING_NAME, mynetname, t);
 298                 return;
 299         }
 300
 301         oldrec = race_readTime(GetMapname(), newpos);
 302         oldrec_holder = race_readName(GetMapname(), newpos);
 303
 304         // store new ranking
 305         race_writeTime(GetMapname(), t, myuid);
 306
 307         if (newpos == 1 && showmessage)
 308         {
 309                 write_recordmarker(e, time - TIME_DECODE(t), TIME_DECODE(t));
 310                 race_send_recordtime(MSG_ALL);
 311         }
 312
 313         race_SendRankings(newpos, player_prevpos, 0, MSG_ALL);
 314         if(rankings_reply)
 315                 strunzone(rankings_reply);
 316         rankings_reply = strzone(getrankings());
 317
 318         if(newpos == player_prevpos)
 319         {
 320                 if(showmessage)
 321                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_NEW_IMPROVED, mynetname, newpos, t, oldrec);
 322                 if(newpos == 1) { race_SendStatus(3, e); } // "new server record"
 323                 else { race_SendStatus(1, e); } // "new time"
 324         }
 325         else if(oldrec == 0)
 326         {
 327                 if(showmessage)
 328                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_NEW_SET, mynetname, newpos, t);
 329                 if(newpos == 1) { race_SendStatus(3, e); } // "new server record"
 330                 else { race_SendStatus(2, e); } // "new rank"
 331         }
 332         else
 333         {
 334                 if(showmessage)
 335                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_NEW_BROKEN, mynetname, oldrec_holder, newpos, t, oldrec);
 336                 if(newpos == 1) { race_SendStatus(3, e); } // "new server record"
 337                 else { race_SendStatus(2, e); } // "new rank"
 338         }
 339 }
 340
 341 void race_deleteTime(string map, float pos)
 342 {
 343         string rr = ((g_cts) ? CTS_RECORD : ((g_ctf) ? CTF_RECORD : RACE_RECORD));
 344
 345         for(int i = pos; i <= RANKINGS_CNT; ++i)
 346         {
 347                 string therank = ftos(i);
 348                 if (i == RANKINGS_CNT)
 349                 {
 350                         db_remove(ServerProgsDB, strcat(map, rr, "time", therank));
 351                         db_remove(ServerProgsDB, strcat(map, rr, "crypto_idfp", therank));
 352                 }
 353                 else
 354                 {
 355                         db_put(ServerProgsDB, strcat(map, rr, "time", therank), ftos(race_readTime(GetMapname(), i+1)));
 356                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", therank), race_readUID(GetMapname(), i+1));
 357                 }
 358         }
 359
 360         race_SendRankings(pos, 0, 1, MSG_ALL);
 361         if(pos == 1)
 362                 race_send_recordtime(MSG_ALL);
 363
 364         if(rankings_reply)
 365                 strunzone(rankings_reply);
 366         rankings_reply = strzone(getrankings());
 367 }
 368
 369 void race_SendTime(entity e, float cp, float t, float tvalid)
 370 {
 371         float snew, l;
 372
 373         if(g_race_qualifying)
 374                 t += e.race_penalty_accumulator;
 375
 376         t = TIME_ENCODE(t); // make integer
 377
 378         if(tvalid)
 379         if(cp == race_timed_checkpoint) // finish line
 380         if (!e.race_completed)
 381         {
 382                 float s;
 383                 if(g_race_qualifying)
 384                 {
 385                         s = PlayerScore_Add(e, SP_RACE_FASTEST, 0);
 386                         if(!s || t < s)
 387                                 PlayerScore_Add(e, SP_RACE_FASTEST, t - s);
 388                 }
 389                 else
 390                 {
 391                         s = PlayerScore_Add(e, SP_RACE_FASTEST, 0);
 392                         if(!s || t < s)
 393                                 PlayerScore_Add(e, SP_RACE_FASTEST, t - s);
 394
 395                         s = PlayerScore_Add(e, SP_RACE_TIME, 0);
 396                         snew = TIME_ENCODE(time - game_starttime);
 397                         PlayerScore_Add(e, SP_RACE_TIME, snew - s);
 398                         l = PlayerTeamScore_Add(e, SP_RACE_LAPS, ST_RACE_LAPS, 1);
 399
 400                         if(autocvar_fraglimit)
 401                                 if(l >= autocvar_fraglimit)
 402                                         race_StartCompleting();
 403
 404                         if(race_completing)
 405                         {
 406                                 e.race_completed = 1;
 407                                 MAKE_INDEPENDENT_PLAYER(e);
 408                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_FINISHED, e.netname);
 409                                 ClientData_Touch(e);
 410                         }
 411                 }
 412         }
 413
 414         float recordtime;
 415         string recordholder;
 416         if(g_race_qualifying)
 417         {
 418                 if(tvalid)
 419                 {
 420                         recordtime = race_checkpoint_records[cp];
 421                         recordholder = strcat1(race_checkpoint_recordholders[cp]); // make a tempstring copy, as we'll possibly strunzone it!
 422                         if(recordholder == e.netname)
 423                                 recordholder = "";
 424
 425                         if(t != 0)
 426                         {
 427                                 if(cp == race_timed_checkpoint)
 428                                 {
 429                                         race_setTime(GetMapname(), t, e.crypto_idfp, e.netname, e, true);
 430                                         MUTATOR_CALLHOOK(Race_FinalCheckpoint, e);
 431                                 }
 432                                 if(t < recordtime || recordtime == 0)
 433                                 {
 434                                         race_checkpoint_records[cp] = t;
 435                                         if(race_checkpoint_recordholders[cp])
 436                                                 strunzone(race_checkpoint_recordholders[cp]);
 437                                         race_checkpoint_recordholders[cp] = strzone(e.netname);
 438                                         if(g_race_qualifying)
 439                                         {
 440                                                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && it.race_checkpoint == cp, LAMBDA(race_SendNextCheckpoint(it, 0)));
 441                                         }
 442                                 }
 443                         }
 444                 }
 445                 else
 446                 {
 447                         // dummies
 448                         t = 0;
 449                         recordtime = 0;
 450                         recordholder = "";
 451                 }
 452
 453                 if(IS_REAL_CLIENT(e))
 454                 {
 455                         msg_entity = e;
 456                         if(g_race_qualifying)
 457                         {
 458                                 WRITESPECTATABLE_MSG_ONE(msg_entity, {
 459                                         WriteHeader(MSG_ONE, TE_CSQC_RACE);
 460                                         WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_HIT_QUALIFYING);
 461                                         WriteByte(MSG_ONE, race_CheckpointNetworkID(cp)); // checkpoint the player now is at
 462                                         WriteInt24_t(MSG_ONE, t); // time to that intermediate
 463                                         WriteInt24_t(MSG_ONE, recordtime); // previously best time
 464                                         WriteString(MSG_ONE, recordholder); // record holder
 465                                 });
 466                         }
 467                 }
 468         }
 469         else // RACE! Not Qualifying
 470         {
 471                 float mylaps, lother, othtime;
 472                 entity oth;
 473                 oth = race_checkpoint_lastplayers[cp];
 474                 if(oth)
 475                 {
 476                         mylaps = PlayerScore_Add(e, SP_RACE_LAPS, 0);
 477                         lother = race_checkpoint_lastlaps[cp];
 478                         othtime = race_checkpoint_lasttimes[cp];
 479                 }
 480                 else
 481                         mylaps = lother = othtime = 0;
 482
 483                 if(IS_REAL_CLIENT(e))
 484                 {
 485                         msg_entity = e;
 486                         WRITESPECTATABLE_MSG_ONE(msg_entity, {
 487                                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
 488                                 WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_HIT_RACE);
 489                                 WriteByte(MSG_ONE, race_CheckpointNetworkID(cp)); // checkpoint the player now is at
 490                                 if(e == oth)
 491                                 {
 492                                         WriteInt24_t(MSG_ONE, 0);
 493                                         WriteByte(MSG_ONE, 0);
 494                                         WriteString(MSG_ONE, "");
 495                                 }
 496                                 else
 497                                 {
 498                                         WriteInt24_t(MSG_ONE, TIME_ENCODE(time - race_checkpoint_lasttimes[cp]));
 499                                         WriteByte(MSG_ONE, mylaps - lother);
 500                                         WriteString(MSG_ONE, oth.netname); // record holder
 501                                 }
 502                         });
 503                 }
 504
 505                 race_checkpoint_lastplayers[cp] = e;
 506                 race_checkpoint_lasttimes[cp] = time;
 507                 race_checkpoint_lastlaps[cp] = mylaps;
 508
 509                 if(IS_REAL_CLIENT(oth))
 510                 {
 511                         msg_entity = oth;
 512                         WRITESPECTATABLE_MSG_ONE(msg_entity, {
 513                                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
 514                                 WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT);
 515                                 WriteByte(MSG_ONE, race_CheckpointNetworkID(cp)); // checkpoint the player now is at
 516                                 if(e == oth)
 517                                 {
 518                                         WriteInt24_t(MSG_ONE, 0);
 519                                         WriteByte(MSG_ONE, 0);
 520                                         WriteString(MSG_ONE, "");
 521                                 }
 522                                 else
 523                                 {
 524                                         WriteInt24_t(MSG_ONE, TIME_ENCODE(time - othtime));
 525                                         WriteByte(MSG_ONE, lother - mylaps);
 526                                         WriteString(MSG_ONE, e.netname); // record holder
 527                                 }
 528                         });
 529                 }
 530         }
 531 }
 532
 533 void race_ClearTime(entity e)
 534 {
 535         e.race_checkpoint = 0;
 536         e.race_laptime = 0;
 537         e.race_movetime = e.race_movetime_frac = e.race_movetime_count = 0;
 538         e.race_penalty_accumulator = 0;
 539         e.race_lastpenalty = NULL;
 540
 541         if(!IS_REAL_CLIENT(e))
 542                 return;
 543
 544         msg_entity = e;
 545         WRITESPECTATABLE_MSG_ONE(msg_entity, {
 546                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
 547                 WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_CLEAR); // next
 548         });
 549 }
 550
 551 void checkpoint_passed(entity this, entity player)
 552 {
 553         if(player.personal && autocvar_g_allow_checkpoints)
 554                 return; // practice mode!
 555
 556         if(player.classname == "porto")
 557         {
 558                 // do not allow portalling through checkpoints
 559                 trace_plane_normal = normalize(-1 * player.velocity);
 560                 W_Porto_Fail(player, 0);
 561                 return;
 562         }
 563
 564         string oldmsg; // used twice
 565
 566         /*
 567          * Trigger targets
 568          */
 569         if (!((this.spawnflags & 2) && (IS_PLAYER(player))))
 570         {
 571                 oldmsg = this.message;
 572                 this.message = "";
 573                 SUB_UseTargets(this, player, player);
 574                 this.message = oldmsg;
 575         }
 576
 577         if (!IS_PLAYER(player))
 578                 return;
 579
 580         /*
 581          * Remove unauthorized equipment
 582          */
 583         Portal_ClearAll(player);
 584
 585         player.porto_forbidden = 2; // decreased by 1 each StartFrame
 586
 587         if(defrag_ents)
 588         {
 589                 if(this.race_checkpoint == -2)
 590                 {
 591                         this.race_checkpoint = player.race_checkpoint;
 592                 }
 593
 594                 int cp_amount = 0, largest_cp_id = 0;
 595                 IL_EACH(g_race_targets, it.classname == "target_checkpoint",
 596                 {
 597                         cp_amount += 1;
 598                         if(it.race_checkpoint > largest_cp_id) // update the finish id if someone hit a new checkpoint
 599                         {
 600                                 if(!largest_cp_id)
 601                                 {
 602                                         IL_EACH(g_race_targets, it.classname == "target_checkpoint",
 603                                         {
 604                                                 if(it.race_checkpoint == -2) // set defragcpexists to -1 so that the cp id file will be rewritten when someone finishes
 605                                                         defragcpexists = -1;
 606                                         });
 607                                 }
 608
 609                                 largest_cp_id = it.race_checkpoint;
 610                                 IL_EACH(g_race_targets, it.classname == "target_stopTimer",
 611                                 {
 612                                         it.race_checkpoint = largest_cp_id + 1; // finish line
 613                                 });
 614                                 race_highest_checkpoint = largest_cp_id + 1;
 615                                 race_timed_checkpoint = largest_cp_id + 1;
 616                         }
 617                 });
 618
 619                 if(!cp_amount)
 620                 {
 621                         IL_EACH(g_race_targets, it.classname == "target_stopTimer",
 622                         {
 623                                 it.race_checkpoint = 1;
 624                         });
 625                         race_highest_checkpoint = 1;
 626                         race_timed_checkpoint = 1;
 627                 }
 628         }
 629
 630         if((player.race_checkpoint == -1 && this.race_checkpoint == 0) || (player.race_checkpoint == this.race_checkpoint))
 631         {
 632                 if(this.race_penalty)
 633                 {
 634                         if(player.race_lastpenalty != this)
 635                         {
 636                                 player.race_lastpenalty = this;
 637                                 race_ImposePenaltyTime(player, this.race_penalty, this.race_penalty_reason);
 638                         }
 639                 }
 640
 641                 if(player.race_penalty)
 642                         return;
 643
 644                 /*
 645                  * Trigger targets
 646                  */
 647                 if(this.spawnflags & 2)
 648                 {
 649                         oldmsg = this.message;
 650                         this.message = "";
 651                         SUB_UseTargets(this, player, player); // TODO: should we be using other for the trigger here?
 652                         this.message = oldmsg;
 653                 }
 654
 655                 if(player.race_respawn_checkpoint != this.race_checkpoint || !player.race_started)
 656                         player.race_respawn_spotref = this; // this is not a spot but a CP, but spawnpoint selection will deal with that
 657                 player.race_respawn_checkpoint = this.race_checkpoint;
 658                 player.race_checkpoint = race_NextCheckpoint(this.race_checkpoint);
 659                 player.race_started = 1;
 660
 661                 race_SendTime(player, this.race_checkpoint, player.race_movetime, boolean(player.race_laptime));
 662
 663                 if(!this.race_checkpoint) // start line
 664                 {
 665                         player.race_laptime = time;
 666                         player.race_movetime = player.race_movetime_frac = player.race_movetime_count = 0;
 667                         player.race_penalty_accumulator = 0;
 668                         player.race_lastpenalty = NULL;
 669                 }
 670
 671                 if(g_race_qualifying)
 672                         race_SendNextCheckpoint(player, 0);
 673
 674                 if(defrag_ents && defragcpexists < 0 && this.classname == "target_stopTimer")
 675                 {
 676                         float fh;
 677                         defragcpexists = fh = fopen(strcat("maps/", GetMapname(), ".defragcp"), FILE_WRITE);
 678                         if(fh >= 0)
 679                         {
 680                                 IL_EACH(g_race_targets, it.classname == "target_checkpoint",
 681                                 {
 682                                         fputs(fh, strcat(it.targetname, " ", ftos(it.race_checkpoint), "\n"));
 683                                 });
 684                         }
 685                         fclose(fh);
 686                 }
 687         }
 688         else if(player.race_checkpoint == race_NextCheckpoint(this.race_checkpoint))
 689         {
 690                 // ignored
 691         }
 692         else
 693         {
 694                 if(this.spawnflags & 4)
 695                         Damage (player, this, this, 10000, DEATH_HURTTRIGGER.m_id, player.origin, '0 0 0');
 696         }
 697 }
 698
 699 void checkpoint_touch(entity this, entity toucher)
 700 {
 701         EXACTTRIGGER_TOUCH(this, toucher);
 702         checkpoint_passed(this, toucher);
 703 }
 704
 705 void checkpoint_use(entity this, entity actor, entity trigger)
 706 {
 707         if(trigger.classname == "info_player_deathmatch") // a spawn, a spawn
 708                 return;
 709
 710         checkpoint_passed(this, actor);
 711 }
 712
 713 bool race_waypointsprite_visible_for_player(entity this, entity player, entity view)
 714 {
 715         entity own = this.owner;
 716         if(this.realowner)
 717                 own = this.realowner; // target support
 718
 719         if(view.race_checkpoint == -1 || own.race_checkpoint == -2)
 720                 return true;
 721         else if(view.race_checkpoint == own.race_checkpoint)
 722                 return true;
 723         else
 724                 return false;
 725 }
 726
 727 void trigger_race_checkpoint_verify(entity this)
 728 {
 729     static bool have_verified;
 730         if (have_verified) return;
 731         have_verified = true;
 732
 733         bool qual = g_race_qualifying;
 734
 735         int pl_race_checkpoint = 0;
 736         int pl_race_place = 0;
 737
 738         if (g_race) {
 739                 for (int i = 0; i <= race_highest_checkpoint; ++i) {
 740                         pl_race_checkpoint = race_NextCheckpoint(i);
 741
 742                         // race only (middle of the race)
 743                         g_race_qualifying = false;
 744                         pl_race_place = 0;
 745                         if (!Spawn_FilterOutBadSpots(this, findchain(classname, "info_player_deathmatch"), 0, false)) {
 746                                 error(strcat("Checkpoint ", ftos(i), " misses a spawnpoint with race_place==", ftos(pl_race_place), " (used for respawning in race) - bailing out"));
 747             }
 748
 749                         if (i == 0) {
 750                                 // qualifying only
 751                                 g_race_qualifying = 1;
 752                                 pl_race_place = race_lowest_place_spawn;
 753                                 if (!Spawn_FilterOutBadSpots(this, findchain(classname, "info_player_deathmatch"), 0, false)) {
 754                                         error(strcat("Checkpoint ", ftos(i), " misses a spawnpoint with race_place==", ftos(pl_race_place), " (used for qualifying) - bailing out"));
 755                 }
 756
 757                                 // race only (initial spawn)
 758                                 g_race_qualifying = 0;
 759                                 for (int p = 1; p <= race_highest_place_spawn; ++p) {
 760                                         pl_race_place = p;
 761                                         if (!Spawn_FilterOutBadSpots(this, findchain(classname, "info_player_deathmatch"), 0, false)) {
 762                                                 error(strcat("Checkpoint ", ftos(i), " misses a spawnpoint with race_place==", ftos(pl_race_place), " (used for initially spawning in race) - bailing out"));
 763                     }
 764                                 }
 765                         }
 766                 }
 767         } else if (!defrag_ents) {
 768                 // qualifying only
 769                 pl_race_checkpoint = race_NextCheckpoint(0);
 770                 g_race_qualifying = 1;
 771                 pl_race_place = race_lowest_place_spawn;
 772                 if (!Spawn_FilterOutBadSpots(this, findchain(classname, "info_player_deathmatch"), 0, false)) {
 773                         error(strcat("Checkpoint 0 misses a spawnpoint with race_place==", ftos(pl_race_place), " (used for qualifying) - bailing out"));
 774         }
 775         } else {
 776                 pl_race_checkpoint = race_NextCheckpoint(0);
 777                 g_race_qualifying = 1;
 778                 pl_race_place = 0; // there's only one spawn on defrag maps
 779
 780                 // check if a defragcp file already exists, then read it and apply the checkpoint order
 781                 float fh;
 782                 float len;
 783                 string l;
 784
 785                 defragcpexists = fh = fopen(strcat("maps/", GetMapname(), ".defragcp"), FILE_READ);
 786                 if (fh >= 0) {
 787                         while ((l = fgets(fh))) {
 788                                 len = tokenize_console(l);
 789                                 if (len != 2) {
 790                                         defragcpexists = -1; // something's wrong in the defrag cp file, set defragcpexists to -1 so that it will be rewritten when someone finishes
 791                                         continue;
 792                                 }
 793                                 for (entity cp = NULL; (cp = find(cp, classname, "target_checkpoint"));) {
 794                                         if (argv(0) == cp.targetname) {
 795                                                 cp.race_checkpoint = stof(argv(1));
 796                     }
 797                 }
 798                         }
 799                         fclose(fh);
 800                 }
 801         }
 802
 803         g_race_qualifying = qual;
 804
 805         IL_EACH(g_race_targets, true,
 806         {
 807                 entity cpt = it;
 808                 FOREACH_ENTITY_STRING(target, cpt.targetname,
 809                 {
 810                         vector org = (it.absmin + it.absmax) * 0.5;
 811                         if(cpt.race_checkpoint == 0)
 812                                 WaypointSprite_SpawnFixed(WP_RaceStart, org, it, sprite, RADARICON_NONE);
 813                         else
 814                                 WaypointSprite_SpawnFixed(WP_RaceCheckpoint, org, it, sprite, RADARICON_NONE);
 815
 816                         it.sprite.realowner = cpt;
 817                         it.sprite.waypointsprite_visible_for_player = race_waypointsprite_visible_for_player;
 818                 });
 819         });
 820
 821         if (race_timed_checkpoint) {
 822                 if (defrag_ents) {
 823                         IL_EACH(g_race_targets, true,
 824                         {
 825                                 entity cpt = it;
 826                                 if(it.classname == "target_startTimer" || it.classname == "target_stopTimer") {
 827                                         FOREACH_ENTITY_STRING(target, cpt.targetname, {
 828                                                 WaypointSprite_UpdateSprites(it.sprite, ((cpt.classname == "target_startTimer") ? WP_RaceStart : WP_RaceFinish), WP_Null, WP_Null);
 829                                         });
 830                                 }
 831                                 if(it.classname == "target_checkpoint") {
 832                                         if(it.race_checkpoint == -2)
 833                                                 defragcpexists = -1; // something's wrong with the defrag cp file or it has not been written yet, set defragcpexists to -1 so that it will be rewritten when someone finishes
 834                                 }
 835                         });
 836                         if (defragcpexists != -1) {
 837                                 float largest_cp_id = 0;
 838                                 for (entity cp = NULL; (cp = find(cp, classname, "target_checkpoint"));) {
 839                                         if (cp.race_checkpoint > largest_cp_id) {
 840                                                 largest_cp_id = cp.race_checkpoint;
 841                     }
 842                 }
 843                                 for (entity cp = NULL; (cp = find(cp, classname, "target_stopTimer"));) {
 844                                         cp.race_checkpoint = largest_cp_id + 1; // finish line
 845                 }
 846                                 race_highest_checkpoint = largest_cp_id + 1;
 847                                 race_timed_checkpoint = largest_cp_id + 1;
 848                         } else {
 849                                 for (entity cp = NULL; (cp = find(cp, classname, "target_stopTimer"));) {
 850                                         cp.race_checkpoint = 255; // finish line
 851                 }
 852                                 race_highest_checkpoint = 255;
 853                                 race_timed_checkpoint = 255;
 854                         }
 855                 } else {
 856                         IL_EACH(g_racecheckpoints, it.sprite,
 857                         {
 858                                 if (it.race_checkpoint == 0) {
 859                                         WaypointSprite_UpdateSprites(it.sprite, WP_RaceStart, WP_Null, WP_Null);
 860                 } else if (it.race_checkpoint == race_timed_checkpoint) {
 861                                         WaypointSprite_UpdateSprites(it.sprite, WP_RaceFinish, WP_Null, WP_Null);
 862                                 }
 863             });
 864                 }
 865         }
 866
 867         if (defrag_ents) {
 868                 for (entity trigger = NULL; (trigger = find(trigger, classname, "trigger_multiple")); ) {
 869                         for (entity targ = NULL; (targ = find(targ, targetname, trigger.target)); ) {
 870                                 if (targ.classname == "target_checkpoint" || targ.classname == "target_startTimer" || targ.classname == "target_stopTimer") {
 871                                         trigger.wait = 0;
 872                                         trigger.delay = 0;
 873                                         targ.wait = 0;
 874                                         targ.delay = 0;
 875
 876                     // These just make the game crash on some maps with oddly shaped triggers.
 877                     // (on the other hand they used to fix the case when two players ran through a checkpoint at once,
 878                     // and often one of them just passed through without being registered. Hope it's fixed  in a better way now.
 879                     // (happened on item triggers too)
 880                     //
 881                                         //targ.wait = -2;
 882                                         //targ.delay = 0;
 883
 884                                         //setsize(targ, trigger.mins, trigger.maxs);
 885                                         //setorigin(targ, trigger.origin);
 886                                         //remove(trigger);
 887                                 }
 888             }
 889         }
 890         }
 891 }
 892
 893 vector trigger_race_checkpoint_spawn_evalfunc(entity this, entity player, entity spot, vector current)
 894 {
 895         if(g_race_qualifying)
 896         {
 897                 // spawn at first
 898                 if(this.race_checkpoint != 0)
 899                         return '-1 0 0';
 900                 if(spot.race_place != race_lowest_place_spawn)
 901                         return '-1 0 0';
 902         }
 903         else
 904         {
 905                 if(this.race_checkpoint != player.race_respawn_checkpoint)
 906                         return '-1 0 0';
 907                 // try reusing the previous spawn
 908                 if(this == player.race_respawn_spotref || spot == player.race_respawn_spotref)
 909                         current.x += SPAWN_PRIO_RACE_PREVIOUS_SPAWN;
 910                 if(this.race_checkpoint == 0)
 911                 {
 912                         int pl = player.race_place;
 913                         if(pl > race_highest_place_spawn)
 914                                 pl = 0;
 915                         if(pl == 0 && !player.race_started)
 916                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 917                         if(spot.race_place != pl)
 918                                 return '-1 0 0';
 919                 }
 920         }
 921         return current;
 922 }
 923
 924 spawnfunc(trigger_race_checkpoint)
 925 {
 926         vector o;
 927         if(!g_race && !g_cts) { delete(this); return; }
 928
 929         EXACTTRIGGER_INIT;
 930
 931         this.use = checkpoint_use;
 932         if (!(this.spawnflags & 1))
 933                 settouch(this, checkpoint_touch);
 934
 935         o = (this.absmin + this.absmax) * 0.5;
 936         tracebox(o, PL_MIN_CONST, PL_MAX_CONST, o - '0 0 1' * (o.z - this.absmin.z), MOVE_NORMAL, this);
 937         waypoint_spawnforitem_force(this, trace_endpos);
 938         this.nearestwaypointtimeout = -1;
 939
 940         if(this.message == "")
 941                 this.message = "went backwards";
 942         if (this.message2 == "")
 943                 this.message2 = "was pushed backwards by";
 944         if (this.race_penalty_reason == "")
 945                 this.race_penalty_reason = "missing a checkpoint";
 946
 947         this.race_checkpoint = this.cnt;
 948
 949         if(this.race_checkpoint > race_highest_checkpoint)
 950         {
 951                 race_highest_checkpoint = this.race_checkpoint;
 952                 if(this.spawnflags & 8)
 953                         race_timed_checkpoint = this.race_checkpoint;
 954                 else
 955                         race_timed_checkpoint = 0;
 956         }
 957
 958         if(!this.race_penalty)
 959         {
 960                 if(this.race_checkpoint)
 961                         WaypointSprite_SpawnFixed(WP_RaceCheckpoint, o, this, sprite, RADARICON_NONE);
 962                 else
 963                         WaypointSprite_SpawnFixed(WP_RaceStartFinish, o, this, sprite, RADARICON_NONE);
 964         }
 965
 966         this.sprite.waypointsprite_visible_for_player = race_waypointsprite_visible_for_player;
 967         this.spawn_evalfunc = trigger_race_checkpoint_spawn_evalfunc;
 968
 969         IL_PUSH(g_racecheckpoints, this);
 970
 971         InitializeEntity(this, trigger_race_checkpoint_verify, INITPRIO_FINDTARGET);
 972 }
 973
 974 spawnfunc(target_checkpoint) // defrag entity
 975 {
 976         if(!g_race && !g_cts) { delete(this); return; }
 977         defrag_ents = 1;
 978
 979         // if this is targeted, then it probably isn't a trigger
 980         bool is_trigger = !boolean(!this.nottargeted && this.targetname != "");
 981
 982         if(is_trigger)
 983                 EXACTTRIGGER_INIT;
 984
 985         this.use = checkpoint_use;
 986         if (is_trigger && !(this.spawnflags & 1))
 987                 settouch(this, checkpoint_touch);
 988
 989         vector org = this.origin;
 990
 991         // bots should only pathfind to this if it is a valid touchable trigger
 992         if(is_trigger)
 993         {
 994                 org = (this.absmin + this.absmax) * 0.5;
 995                 tracebox(org, PL_MIN_CONST, PL_MAX_CONST, org - '0 0 1' * (org.z - this.absmin.z), MOVE_NORMAL, this);
 996                 waypoint_spawnforitem_force(this, trace_endpos);
 997                 this.nearestwaypointtimeout = -1;
 998         }
 999
1000         if(this.message == "")
1001                 this.message = "went backwards";
1002         if (this.message2 == "")
1003                 this.message2 = "was pushed backwards by";
1004         if (this.race_penalty_reason == "")
1005                 this.race_penalty_reason = "missing a checkpoint";
1006
1007         if(this.classname == "target_startTimer")
1008                 this.race_checkpoint = 0;
1009         else
1010                 this.race_checkpoint = -2;
1011
1012         race_timed_checkpoint = 1;
1013
1014         IL_PUSH(g_race_targets, this);
1015
1016         InitializeEntity(this, trigger_race_checkpoint_verify, INITPRIO_FINDTARGET);
1017 }
1018
1019 spawnfunc(target_startTimer) { spawnfunc_target_checkpoint(this); }
1020 spawnfunc(target_stopTimer) { spawnfunc_target_checkpoint(this); }
1021
1022 void race_AbandonRaceCheck(entity p)
1023 {
1024         if(race_completing && !p.race_completed)
1025         {
1026                 p.race_completed = 1;
1027                 MAKE_INDEPENDENT_PLAYER(p);
1028                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_ABANDONED, p.netname);
1029                 ClientData_Touch(p);
1030         }
1031 }
1032
1033 void race_StartCompleting()
1034 {
1035         race_completing = 1;
1036         FOREACH_CLIENT(IS_PLAYER(it) && IS_DEAD(it), LAMBDA(race_AbandonRaceCheck(it)));
1037 }
1038
1039 void race_PreparePlayer(entity this)
1040 {
1041         race_ClearTime(this);
1042         this.race_place = 0;
1043         this.race_started = 0;
1044         this.race_respawn_checkpoint = 0;
1045         this.race_respawn_spotref = NULL;
1046 }
1047
1048 void race_RetractPlayer(entity this)
1049 {
1050         if(!g_race && !g_cts)
1051                 return;
1052         if(this.race_respawn_checkpoint == 0 || this.race_respawn_checkpoint == race_timed_checkpoint)
1053                 race_ClearTime(this);
1054         this.race_checkpoint = this.race_respawn_checkpoint;
1055 }
1056
1057 spawnfunc(info_player_race)
1058 {
1059         if(!g_race && !g_cts) { delete(this); return; }
1060         ++race_spawns;
1061         spawnfunc_info_player_deathmatch(this);
1062
1063         if(this.race_place > race_highest_place_spawn)
1064                 race_highest_place_spawn = this.race_place;
1065         if(this.race_place < race_lowest_place_spawn)
1066                 race_lowest_place_spawn = this.race_place;
1067 }
1068
1069 void race_ClearRecords()
1070 {
1071         float i;
1072
1073         for(i = 0; i < MAX_CHECKPOINTS; ++i)
1074         {
1075                 race_checkpoint_records[i] = 0;
1076                 if(race_checkpoint_recordholders[i])
1077                         strunzone(race_checkpoint_recordholders[i]);
1078                 race_checkpoint_recordholders[i] = string_null;
1079         }
1080
1081         FOREACH_CLIENT(true, LAMBDA(
1082                 float p = it.race_place;
1083                 race_PreparePlayer(it);
1084                 it.race_place = p;
1085         ));
1086 }
1087
1088 void race_ImposePenaltyTime(entity pl, float penalty, string reason)
1089 {
1090         if(g_race_qualifying)
1091         {
1092                 pl.race_penalty_accumulator += penalty;
1093                 if(IS_REAL_CLIENT(pl))
1094                 {
1095                         msg_entity = pl;
1096                         WRITESPECTATABLE_MSG_ONE(msg_entity, {
1097                                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
1098                                 WriteByte(MSG_ONE, RACE_NET_PENALTY_QUALIFYING);
1099                                 WriteShort(MSG_ONE, TIME_ENCODE(penalty));
1100                                 WriteString(MSG_ONE, reason);
1101                         });
1102                 }
1103         }
1104         else
1105         {
1106                 pl.race_penalty = time + penalty;
1107                 if(IS_REAL_CLIENT(pl))
1108                 {
1109                         msg_entity = pl;
1110                         WRITESPECTATABLE_MSG_ONE(msg_entity, {
1111                                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
1112                                 WriteByte(MSG_ONE, RACE_NET_PENALTY_RACE);
1113                                 WriteShort(MSG_ONE, TIME_ENCODE(penalty));
1114                                 WriteString(MSG_ONE, reason);
1115                         });
1116                 }
1117         }
1118 }
1119
1120 void penalty_touch(entity this, entity toucher)
1121 {
1122         EXACTTRIGGER_TOUCH(this, toucher);
1123         if(toucher.race_lastpenalty != this)
1124         {
1125                 toucher.race_lastpenalty = this;
1126                 race_ImposePenaltyTime(toucher, this.race_penalty, this.race_penalty_reason);
1127         }
1128 }
1129
1130 void penalty_use(entity this, entity actor, entity trigger)
1131 {
1132         race_ImposePenaltyTime(actor, this.race_penalty, this.race_penalty_reason);
1133 }
1134
1135 spawnfunc(trigger_race_penalty)
1136 {
1137         // TODO: find out why this wasnt done:
1138         //if(!g_cts && !g_race) { remove(this); return; }
1139
1140         EXACTTRIGGER_INIT;
1141
1142         this.use = penalty_use;
1143         if (!(this.spawnflags & 1))
1144                 settouch(this, penalty_touch);
1145
1146         if (this.race_penalty_reason == "")
1147                 this.race_penalty_reason = "missing a checkpoint";
1148         if (!this.race_penalty)
1149                 this.race_penalty = 5;
1150 }
1151
1152 float race_GetFractionalLapCount(entity e)
1153 {
1154         // interesting metrics (idea by KrimZon) to maybe sort players in the
1155         // scoreboard, immediately updates when overtaking
1156         //
1157         // requires the track to be built so you never get farther away from the
1158         // next checkpoint, though, and current Xonotic race maps are not built that
1159         // way
1160         //
1161         // also, this code is slow and would need optimization (i.e. "next CP"
1162         // links on CP entities)
1163
1164         float l;
1165         l = PlayerScore_Add(e, SP_RACE_LAPS, 0);
1166         if(e.race_completed)
1167                 return l; // not fractional
1168
1169         vector o0, o1;
1170         float bestfraction, fraction;
1171         entity lastcp;
1172         float nextcpindex, lastcpindex;
1173
1174         nextcpindex = max(e.race_checkpoint, 0);
1175         lastcpindex = e.race_respawn_checkpoint;
1176         lastcp = e.race_respawn_spotref;
1177
1178         if(nextcpindex == lastcpindex)
1179                 return l; // finish
1180
1181         bestfraction = 1;
1182         IL_EACH(g_racecheckpoints, true,
1183         {
1184                 if(it.race_checkpoint != lastcpindex)
1185                         continue;
1186                 if(lastcp)
1187                         if(it != lastcp)
1188                                 continue;
1189                 o0 = (it.absmin + it.absmax) * 0.5;
1190                 IL_EACH(g_racecheckpoints, true,
1191                 {
1192                         if(it.race_checkpoint != nextcpindex)
1193                                 continue;
1194                         o1 = (it.absmin + it.absmax) * 0.5;
1195                         if(o0 == o1)
1196                                 continue;
1197                         fraction = bound(0.0001, vlen(e.origin - o1) / vlen(o0 - o1), 1);
1198                         if(fraction < bestfraction)
1199                                 bestfraction = fraction;
1200                 });
1201         });
1202
1203         // we are at CP "nextcpindex - bestfraction"
1204         // race_timed_checkpoint == 4: then nextcp==4 means 0.9999x, nextcp==0 means 0.0000x
1205         // race_timed_checkpoint == 0: then nextcp==0 means 0.9999x
1206         float c, nc;
1207         nc = race_highest_checkpoint + 1;
1208         c = ((nextcpindex - race_timed_checkpoint + nc + nc - 1) % nc) + 1 - bestfraction;
1209
1210         return l + c / nc;
1211 }