qcsrc/server/mutators/mutator_superspec.qc

   1 #define _SSMAGIX "SUPERSPEC_OPTIONSFILE_V1"
   2 #define _ISLOCAL ((edict_num(1) == self) ? TRUE : FALSE)
   3
   4 #define ASF_STRENGTH        1
   5 #define ASF_SHIELD          2
   6 #define ASF_MEGA_AR         4
   7 #define ASF_MEGA_HP         8
   8 #define ASF_FLAG_GRAB       16
   9 #define ASF_OBSERVER_ONLY   32
  10 #define ASF_SHOWWHAT        64
  11 #define ASF_SSIM            128
  12 #define ASF_ALL             0xFFFFFF
  13 .float autospec_flags;
  14
  15 #define SSF_SILENT          1
  16 #define SSF_VERBOSE         2
  17 #define SSF_ITEMMSG         4
  18 .float superspec_flags;
  19
  20 .string superspec_itemfilter; //"classname1 classname2 ..."
  21
  22 float _spectate(entity _player)
  23 {
  24         if(SpectateNext(_player) == 1)
  25         {
  26                 PutObserverInServer();
  27                 self.classname = "spectator";
  28         }
  29
  30         return TRUE;
  31 }
  32
  33 void superspec_save_client_conf()
  34 {
  35         string fn = "superspec-local.options";
  36         float fh;
  37
  38
  39         if not(_ISLOCAL)
  40         {
  41                 if(self.crypto_idfp == "")
  42                         return;
  43
  44                 fn = sprintf("superspec-%s.options", uri_escape(self.crypto_idfp));
  45         }
  46
  47         if((fh = fopen(fn, FILE_WRITE)) < 0)
  48         {
  49                 dprint("^1ERROR: ^7 superspec can not open ", fn, " for writing.\n");
  50         }
  51         else
  52         {
  53                 fputs(fh, _SSMAGIX);
  54                 fputs(fh, "\n");
  55                 fputs(fh, ftos(self.autospec_flags));
  56                 fputs(fh, "\n");
  57                 fputs(fh, ftos(self.superspec_flags));
  58                 fputs(fh, "\n");
  59                 fputs(fh, self.superspec_itemfilter);
  60                 fputs(fh, "\n");
  61                 fclose(fh);
  62         }
  63 }
  64
  65 void superspec_msg(string _center_title, string _con_title, entity _to, string _msg, float _spamlevel)
  66 {
  67
  68         sprint(_to, strcat(_con_title, _msg));
  69
  70         if(_to.superspec_flags & SSF_SILENT)
  71                 return;
  72
  73         if(_spamlevel > 1)
  74                 if not(_to.superspec_flags & SSF_VERBOSE)
  75                         return;
  76
  77         centerprint(_to, strcat(_center_title, _msg));
  78 }
  79
  80 float superspec_filteritem(entity _for, entity _item)
  81 {
  82         float i;
  83
  84         if(!_for.superspec_itemfilter)
  85                 return TRUE;
  86
  87         if(_for.superspec_itemfilter == "")
  88                 return TRUE;
  89
  90         float l = tokenize_console(_for.superspec_itemfilter);
  91         for(i = 0; i < l; ++i)
  92         {
  93                 if(argv(i) == _item.classname)
  94                         return TRUE;
  95         }
  96
  97         return FALSE;
  98 }
  99
 100 MUTATOR_HOOKFUNCTION(superspec_ItemTouch)
 101 {
 102         entity _oldself = self;
 103         entity _item = self;
 104
 105         FOR_EACH_SPEC(self)
 106         {
 107                 if(self.superspec_flags & SSF_ITEMMSG)
 108                         if(superspec_filteritem(self, _item))
 109                         {
 110                                 if(self.superspec_flags & SSF_VERBOSE)
 111                                         superspec_msg("", "", self, sprintf("Player %s^7 just picked up ^3%s\n", other.netname, _item.netname), 1);
 112                                 else
 113                                         superspec_msg("", "", self, sprintf("Player %s^7 just picked up ^3%s\n^8(%s^8)\n", other.netname, _item.netname, _item.classname), 1);
 114                                 if(self.autospec_flags& ASF_SSIM && self.enemy != other)
 115                                 {
 116                                         _spectate(other);
 117
 118                                         self = _oldself;
 119                                         return FALSE;
 120                                 }
 121                         }
 122
 123
 124                 if((self.autospec_flags & ASF_SHIELD && _item.invincible_finished) ||
 125                                 (self.autospec_flags & ASF_STRENGTH && _item.strength_finished) ||
 126                                 (self.autospec_flags& ASF_MEGA_AR && _item.classname == "item_armor_large") ||
 127                                 (self.autospec_flags& ASF_MEGA_HP && _item.classname == "item_health_mega") ||
 128                                 (self.autospec_flags& ASF_FLAG_GRAB && _item.classname == "item_flag_team"))
 129                 {
 130
 131                         if((self.enemy != other) || self.classname == "observer")
 132                         {
 133                                 if(self.autospec_flags & ASF_OBSERVER_ONLY && self.classname != "observer")
 134                                 {
 135                                         if(self.superspec_flags & SSF_VERBOSE)
 136                                                 superspec_msg("", "", self, sprintf("^8Ignored that %s^8 grabbed %s^8 since the observer_only option is ON\n", other.netname, _item.netname), 2);
 137                                 }
 138                                 else
 139                                 {
 140                                         if(self.autospec_flags & ASF_SHOWWHAT)
 141                                                 superspec_msg("", "", self, sprintf("^7Following %s^7 due to picking up %s\n", other.netname, _item.netname), 2);
 142
 143                                         _spectate(other);
 144                                 }
 145                         }
 146                 }
 147         }
 148
 149         self = _oldself;
 150
 151         return FALSE;
 152 }
 153
 154 MUTATOR_HOOKFUNCTION(superspec_SV_ParseClientCommand)
 155 {
 156 #define OPTIONINFO(flag,var,test,text,long,short) \
 157     var = strcat(var, ((flag & test) ? "^2[ON]  ^7" : "^1[OFF] ^7")); \
 158     var = strcat(var, text," ^7(^3 ", long, "^7 | ^3", short, " ^7)\n")
 159
 160         if(MUTATOR_RETURNVALUE) // command was already handled?
 161                 return FALSE;
 162
 163         if(self.classname == "player")
 164                 return FALSE;
 165
 166         if(cmd_name == "superspec_itemfilter")
 167         {
 168                 if(argv(1) == "help")
 169                 {
 170                         string _aspeco;
 171                         _aspeco = strcat(_aspeco, "^7 superspec_itemfilter ^3\"item_classname1 item_classname2\"^7 only show thise items when ^2superspec ^3item_message^7 is on\n");
 172                         _aspeco = strcat(_aspeco, "^3 clear^7 Remove the filter (show all pickups)\n");
 173                         _aspeco = strcat(_aspeco, "^3 show ^7 Display current filter\n");
 174                         superspec_msg("^3superspec_itemfilter help:\n\n\n", "\n^3superspec_itemfilter help:\n", self, _aspeco, 1);
 175                 }
 176                 else if(argv(1) == "clear")
 177                 {
 178                         if(self.superspec_itemfilter != "")
 179                                 strunzone(self.superspec_itemfilter);
 180
 181                         self.superspec_itemfilter = "";
 182                 }
 183                 else if(argv(1) == "show" || argv(1) == "")
 184                 {
 185                         if(self.superspec_itemfilter == "")
 186                         {
 187                                 superspec_msg("^3superspec_itemfilter^7 is ^1not^7 set", "\n^3superspec_itemfilter^7 is ^1not^7 set\n", self, "", 1);
 188                                 return TRUE;
 189                         }
 190                         float i;
 191                         float l = tokenize_console(self.superspec_itemfilter);
 192                         string _msg;
 193                         for(i = 0; i < l; ++i)
 194                                 _msg = strcat(_msg, "^3#", ftos(i), " ^7", argv(i), "\n");
 195                                 //_msg = sprintf("^3#%d^7 %s\n%s", i, _msg, argv(i));
 196
 197                         _msg = strcat(_msg,"\n");
 198
 199                         superspec_msg("^3superspec_itemfilter is:\n\n\n", "\n^3superspec_itemfilter is:\n", self, _msg, 1);
 200                 }
 201                 else
 202                 {
 203                         if(self.superspec_itemfilter != "")
 204                                 strunzone(self.superspec_itemfilter);
 205
 206                         self.superspec_itemfilter = strzone(argv(1));
 207                 }
 208
 209
 210                 return TRUE;
 211         }
 212
 213         if(cmd_name == "superspec")
 214         {
 215                 string _aspeco;
 216
 217                 if(cmd_argc > 1)
 218                 {
 219                         float i, _bits, _start = 1;
 220                         if(argv(1) == "help")
 221                         {
 222                                 _aspeco = "";
 223                                 _aspeco = strcat(_aspeco, "use cmd superspec [option] [on|off] to set options\n\n");
 224                                 _aspeco = strcat(_aspeco, "^3 silent ^7(short^5 si^7) supress ALL mesagess from superspectate.\n");
 225                                 _aspeco = strcat(_aspeco, "^3 verrbose ^7(short^5 ve^7) makes superspectate print some additional information.\n");
 226                                 _aspeco = strcat(_aspeco, "^3 item_message ^7(short^5 im^7) makes superspectate print items that was picked up.\n");
 227                                 _aspeco = strcat(_aspeco, "^7    Use cmd superspec_itemfilter \"item_class1 item_class2\" to set up a filter of what to show with ^3item_message.\n");
 228                                 superspec_msg("^2Available Super Spectate ^3options:\n\n\n", "\n^2Available Super Spectate ^3options:\n", self, _aspeco, 1);
 229                                 return TRUE;
 230                         }
 231
 232                         if(argv(1) == "clear")
 233                         {
 234                                 self.superspec_flags = 0;
 235                                 _start = 2;
 236                         }
 237
 238                         for(i = _start; i < cmd_argc; ++i)
 239                         {
 240                                 if(argv(i) == "on" || argv(i) == "1")§
 241                                 {
 242                                         self.superspec_flags |= _bits;
 243                                         _bits = 0;
 244                                 }
 245                                 else if(argv(i) == "off" || argv(i) == "0")
 246                                 {
 247                                         if(_start == 1)
 248                                                 self.superspec_flags &~= _bits;
 249
 250                                         _bits = 0;
 251                                 }
 252                                 else
 253                                 {
 254                                         if((argv(i) == "silent") || (argv(i) == "si"§)) _bits |= SSF_SILENT ;
 255                                         if((argv(i) == "verbose") || (argv(i) == "ve")) _bits |= SSF_VERBOSE;
 256                                         if((argv(i) == "item_message") || (argv(i) == "im")) _bits |= SSF_ITEMMSG;
 257                                 }
 258                         }
 259                 }
 260
 261
 262                 OPTIONINFO(self.superspec_flags, _aspeco, SSF_SILENT, "Silent", "silent", "si");
 263                 OPTIONINFO(self.superspec_flags, _aspeco, SSF_VERBOSE, "Verbose", "verbose", "ve");
 264                 OPTIONINFO(self.superspec_flags, _aspeco, SSF_ITEMMSG, "Item pickup messages", "item_message", "im");
 265
 266                 superspec_msg("^3Current Super Spectate options are:\n\n\n\n\n", "\n^3Current Super Spectate options are:\n", self, _aspeco, 1);
 267                 return TRUE;
 268
 269         }
 270
 271 /////////////////////
 272
 273         if(cmd_name == "autospec")
 274         {
 275                 string _aspeco;
 276                 if(cmd_argc > 1)
 277                 {
 278                         if(argv(1) == "help")
 279                         {
 280                                 _aspeco = "";
 281                                 _aspeco = strcat(_aspeco, "use cmd autospec [option] [on|off] to set options\n\n");
 282                                 _aspeco = strcat(_aspeco, "^3 strength ^7(short^5 st^7) for automatic spectate on strength powerup\n");
 283                                 _aspeco = strcat(_aspeco, "^3 shield ^7(short^5 sh^7) for automatic spectate on shield powerup\n");
 284                                 _aspeco = strcat(_aspeco, "^3 mega_health ^7(short^5 mh^7) for automatic spectate on mega health\n");
 285                                 _aspeco = strcat(_aspeco, "^3 mega_armor ^7(short^5 ma^7) for automatic spectate on mega armor\n");
 286                                 _aspeco = strcat(_aspeco, "^3 flag_grab ^7(short^5 fg^7) for automatic spectate on CTF flag grab\n");
 287                                 _aspeco = strcat(_aspeco, "^3 observer_only (short^5 oo^7) for automatic spectate only if in observer mode\n");
 288                                 _aspeco = strcat(_aspeco, "^3 show_what (short^5 sw^7) to display what event triggerd autospectate\n");
 289                                 _aspeco = strcat(_aspeco, "^3 item_msg ^7(short^5 im^7) to autospec when item_message in superspectate is triggerd\n");
 290                                 _aspeco = strcat(_aspeco, "^3 all ^7(short ^5aa^7) turn everything on/off\n");
 291                                 superspec_msg("^2Available Auto Spectate ^3options:\n\n\n", "\n^2Available Auto Spectate ^3options:\n", self, _aspeco, 1);
 292                                 return TRUE;
 293                         }
 294
 295                         float i, _bits, _start = 1;
 296                         if(argv(1) == "clear")
 297                         {
 298                                 self.autospec_flags = 0;
 299                                 _start = 2;
 300                         }
 301
 302                         for(i = _start; i < cmd_argc; ++i)
 303                         {
 304                                 if(argv(i) == "on" || argv(i) == "1")
 305                                 {
 306                                         self.autospec_flags |= _bits;
 307                                         _bits = 0;
 308                                 }
 309                                 else if(argv(i) == "off" || argv(i) == "0")
 310                                 {
 311                                         if(_start == 1)
 312                                                 self.autospec_flags &~= _bits;
 313
 314                                         _bits = 0;
 315                                 }
 316                                 else
 317                                 {
 318                                         if((argv(i) == "strength") || (argv(i) == "st")) _bits |= ASF_STRENGTH;
 319                                         if((argv(i) == "shield") || (argv(i) == "sh")) _bits |= ASF_SHIELD;
 320                                         if((argv(i) == "mega_health") || (argv(i) == "mh")) _bits |= ASF_MEGA_HP;
 321                                         if((argv(i) == "mega_armor") || (argv(i) == "ma")) _bits |= ASF_MEGA_AR;
 322                                         if((argv(i) == "flag_grab") || (argv(i) == "fg")) _bits |= ASF_FLAG_GRAB;
 323                                         if((argv(i) == "observer_only") || (argv(i) == "oo")) _bits |= ASF_OBSERVER_ONLY;
 324                                         if((argv(i) == "show_what") || (argv(i) == "sw")) _bits |= ASF_SHOWWHAT;
 325                                         if((argv(i) == "item_msg") || (argv(i) == "im")) _bits |= ASF_SSIM;
 326                                         if((argv(i) == "all") || (argv(i) == "aa")) _bits |= ASF_ALL;
 327                                 }
 328                         }
 329                 }
 330
 331                 OPTIONINFO(self.autospec_flags, _aspeco, ASF_STRENGTH, "Strength", "strength", "st");
 332                 OPTIONINFO(self.autospec_flags, _aspeco, ASF_SHIELD, "Shiled", "shield", "sh");
 333                 OPTIONINFO(self.autospec_flags, _aspeco, ASF_MEGA_HP, "Mega Health", "mega_health", "mh");
 334                 OPTIONINFO(self.autospec_flags, _aspeco, ASF_MEGA_AR, "Mega Armor", "mega_armor", "ma");
 335                 OPTIONINFO(self.autospec_flags, _aspeco, ASF_FLAG_GRAB, "Flag grab", "flag_grab","fg");
 336                 OPTIONINFO(self.autospec_flags, _aspeco, ASF_OBSERVER_ONLY, "Only switch if Observer", "observer_only", "oo");
 337                 OPTIONINFO(self.autospec_flags, _aspeco, ASF_SHOWWHAT, "Show what item triggered spectate", "show_what", "sw");
 338                 OPTIONINFO(self.autospec_flags, _aspeco, ASF_SSIM, "Switch on superspec item message", "item_msg", "im");
 339
 340                 superspec_msg("^3Current auto spectate options are:\n\n\n\n\n", "\n^3Current auto spectate options are:\n", self, _aspeco, 1);
 341                 return TRUE;
 342         }
 343
 344         if(cmd_name == "followpowerup")
 345         {
 346                 entity _player;
 347                 FOR_EACH_PLAYER(_player)
 348                 {
 349                         if(_player.strength_finished > time || _player.invincible_finished > time)
 350                                 return _spectate(_player);
 351                 }
 352
 353                 superspec_msg("", "", self, "No active powerups\n", 1);
 354                 return TRUE;
 355         }
 356
 357         if(cmd_name == "followstrength")
 358         {
 359                 entity _player;
 360                 FOR_EACH_PLAYER(_player)
 361                 {
 362                         if(_player.strength_finished > time)
 363                                 return _spectate(_player);
 364                 }
 365
 366                 superspec_msg("", "", self, "No active Strength\n", 1);
 367                 return TRUE;
 368         }
 369
 370         if(cmd_name == "followstshield")
 371         {
 372                 entity _player;
 373                 FOR_EACH_PLAYER(_player)
 374                 {
 375                         if(_player.invincible_finished > time)
 376                                 return _spectate(_player);
 377                 }
 378
 379                 superspec_msg("", "", self, "No active Shield\n", 1);
 380                 return TRUE;
 381         }
 382
 383         if(cmd_name == "followfc")
 384         {
 385                 if(!g_ctf)
 386                         return TRUE;
 387
 388                 entity _player;
 389                 float _team;
 390
 391                 if(cmd_argc == 2)
 392                 {
 393                         if(argv(1) == "red")
 394                                 _team = COLOR_TEAM1;
 395                         else
 396                                 _team = COLOR_TEAM2;
 397                 }
 398
 399                 FOR_EACH_PLAYER(_player)
 400                 {
 401                         if(_player.flagcarried && (_player.team == _team || _team == 0))
 402                                 return _spectate(_player);
 403                 }
 404
 405                 superspec_msg("", "", self, "No active flag carrier\n", 1);
 406                 return TRUE;
 407         }
 408
 409         return FALSE;
 410 #undef OPTIONINFO
 411 }
 412
 413 MUTATOR_HOOKFUNCTION(superspec_BuildMutatorsString)
 414 {
 415         ret_string = strcat(ret_string, ":SS");
 416         return 0;
 417 }
 418
 419 MUTATOR_HOOKFUNCTION(superspec_BuildMutatorsPrettyString)
 420 {
 421         ret_string = strcat(ret_string, ", Super Spectators");
 422         return 0;
 423 }
 424
 425 /*
 426 MUTATOR_HOOKFUNCTION(superspec_PlayerSpawn)
 427 {
 428
 429     return FALSE;
 430 }
 431 */
 432
 433 void superspec_hello()
 434 {
 435         if(self.enemy.crypto_idfp == "")
 436                 centerprint(self.enemy, "Your clinet have/allow no crypto id, superspec options will not be saved/restored.");
 437         else
 438                 centerprint(self.enemy, sprintf("Hello %s\nSince your client has a Crypto ID, your superspec preferenses will be presisted on this server.", self.enemy.netname));
 439
 440         remove(self);
 441 }
 442
 443 MUTATOR_HOOKFUNCTION(superspec_ClientConnect)
 444 {
 445         string fn = "superspec-local.options";
 446         float fh;
 447
 448         self.superspec_flags = SSF_VERBOSE;
 449         self.superspec_itemfilter = "";
 450
 451         entity _hello = spawn();
 452         _hello.enemy = self;
 453         _hello.think = superspec_hello;
 454         _hello.nextthink = time + 5;
 455
 456         if not(_ISLOCAL)
 457         {
 458                 if(self.crypto_idfp == "")
 459                         return FALSE;
 460
 461                 fn = sprintf("superspec-%s.options", uri_escape(self.crypto_idfp));
 462         }
 463
 464         if((fh = fopen(fn, FILE_READ)) < 0)
 465         {
 466                 dprint("^1ERROR: ^7 superspec can not open ", fn, " for reading.\n");
 467         }
 468         else
 469         {
 470                 string _magic = fgets(fh);
 471                 if(_magic != _SSMAGIX)
 472                 {
 473                         dprint("^1ERROR^7 While reading superspec options file: unkown magic\n");
 474                 }
 475                 else
 476                 {
 477                         self.autospec_flags = stof(fgets(fh));
 478                         self.superspec_flags = stof(fgets(fh));
 479                         self.superspec_itemfilter = strzone(fgets(fh));
 480                 }
 481                 fclose(fh);
 482         }
 483
 484         return FALSE;
 485 }
 486
 487 MUTATOR_HOOKFUNCTION(superspec_ClientDisconnect)
 488 {
 489         superspec_save_client_conf();
 490         return FALSE;
 491 }
 492
 493
 494 /*
 495 MUTATOR_HOOKFUNCTION(superspec_MakePlayerObserver)
 496 {
 497     return FALSE;
 498 }
 499
 500 MUTATOR_HOOKFUNCTION(superspec_PlayerPreThink)
 501 {
 502     return FALSE;
 503 }
 504 */
 505
 506 MUTATOR_DEFINITION(mutator_superspec)
 507 {
 508
 509         MUTATOR_HOOK(BuildMutatorsString, superspec_BuildMutatorsString, CBC_ORDER_ANY);
 510         MUTATOR_HOOK(BuildMutatorsPrettyString, superspec_BuildMutatorsPrettyString, CBC_ORDER_ANY);
 511         MUTATOR_HOOK(SV_ParseClientCommand, superspec_SV_ParseClientCommand, CBC_ORDER_ANY);
 512         MUTATOR_HOOK(ItemTouch, superspec_ItemTouch, CBC_ORDER_ANY);
 513         MUTATOR_HOOK(ClientConnect, superspec_ClientConnect, CBC_ORDER_ANY);
 514         //MUTATOR_HOOK(PlayerSpawn, superspec_PlayerSpawn, CBC_ORDER_ANY);
 515         //MUTATOR_HOOK(PlayerPreThink, superspec_PlayerPreThink, CBC_ORDER_ANY);
 516         //MUTATOR_HOOK(MakePlayerObserver, superspec_MakePlayerObserver, CBC_ORDER_ANY);
 517         MUTATOR_HOOK(ClientDisconnect, superspec_ClientDisconnect, CBC_ORDER_ANY);
 518
 519         MUTATOR_ONADD
 520         {
 521         }
 522
 523         MUTATOR_ONREMOVE
 524         {
 525         }
 526
 527         return 0;
 528 }