qcsrc/server/mutators/mutator_nades.qc

   1 .entity nade_spawnloc;
   2
   3 void nade_timer_think()
   4 {
   5         self.skin = 8 - (self.owner.wait - time) / (autocvar_g_nades_nade_lifetime / 10);
   6         self.nextthink = time;
   7         if(!self.owner || wasfreed(self.owner))
   8                 remove(self);
   9 }
  10
  11 void nade_burn_spawn(entity _nade)
  12 {
  13         CSQCProjectile(_nade, TRUE, Nade_ProjectileFromID(_nade.nade_type, TRUE), TRUE);
  14 }
  15
  16 void nade_spawn(entity _nade)
  17 {
  18         entity timer = spawn();
  19         setmodel(timer, "models/ok_nade_counter/ok_nade_counter.md3");
  20         setattachment(timer, _nade, "");
  21         timer.classname = "nade_timer";
  22         timer.colormap = _nade.colormap;
  23         timer.glowmod = _nade.glowmod;
  24         timer.think = nade_timer_think;
  25         timer.nextthink = time;
  26         timer.wait = _nade.wait;
  27         timer.owner = _nade;
  28         timer.skin = 10;
  29
  30         _nade.effects |= EF_LOWPRECISION;
  31
  32         CSQCProjectile(_nade, TRUE, Nade_ProjectileFromID(_nade.nade_type, FALSE), TRUE);
  33 }
  34
  35 void napalm_damage(float dist, float damage, float edgedamage, float burntime)
  36 {
  37         entity e;
  38         float d;
  39         vector p;
  40
  41         if ( damage < 0 )
  42                 return;
  43
  44         RandomSelection_Init();
  45         for(e = WarpZone_FindRadius(self.origin, dist, TRUE); e; e = e.chain)
  46                 if(e.takedamage == DAMAGE_AIM)
  47                 if(self.realowner != e || autocvar_g_nades_napalm_selfdamage)
  48                 if(!IS_PLAYER(e) || !self.realowner || DIFF_TEAM(e, self))
  49                 if(!e.frozen)
  50                 {
  51                         p = e.origin;
  52                         p_x += e.mins_x + random() * (e.maxs_x - e.mins_x);
  53                         p_y += e.mins_y + random() * (e.maxs_y - e.mins_y);
  54                         p_z += e.mins_z + random() * (e.maxs_z - e.mins_z);
  55                         d = vlen(WarpZone_UnTransformOrigin(e, self.origin) - p);
  56                         if(d < dist)
  57                         {
  58                                 e.fireball_impactvec = p;
  59                                 RandomSelection_Add(e, 0, string_null, 1 / (1 + d), !Fire_IsBurning(e));
  60                         }
  61                 }
  62         if(RandomSelection_chosen_ent)
  63         {
  64                 d = vlen(WarpZone_UnTransformOrigin(RandomSelection_chosen_ent, self.origin) - RandomSelection_chosen_ent.fireball_impactvec);
  65                 d = damage + (edgedamage - damage) * (d / dist);
  66                 Fire_AddDamage(RandomSelection_chosen_ent, self.realowner, d * burntime, burntime, self.projectiledeathtype | HITTYPE_BOUNCE);
  67                 //trailparticles(self, particleeffectnum("fireball_laser"), self.origin, RandomSelection_chosen_ent.fireball_impactvec);
  68                 pointparticles(particleeffectnum("fireball_laser"), self.origin, RandomSelection_chosen_ent.fireball_impactvec - self.origin, 1);
  69         }
  70 }
  71
  72
  73 void napalm_ball_think()
  74 {
  75         if(round_handler_IsActive())
  76         if(!round_handler_IsRoundStarted())
  77         {
  78                 remove(self);
  79                 return;
  80         }
  81
  82         if(time > self.pushltime)
  83         {
  84                 remove(self);
  85                 return;
  86         }
  87
  88         vector midpoint = ((self.absmin + self.absmax) * 0.5);
  89         if(pointcontents(midpoint) == CONTENT_WATER)
  90         {
  91                 self.velocity = self.velocity * 0.5;
  92
  93                 if(pointcontents(midpoint + '0 0 16') == CONTENT_WATER)
  94                         { self.velocity_z = 200; }
  95         }
  96
  97         self.angles = vectoangles(self.velocity);
  98
  99         napalm_damage(autocvar_g_nades_napalm_ball_radius,autocvar_g_nades_napalm_ball_damage,
 100                                   autocvar_g_nades_napalm_ball_damage,autocvar_g_nades_napalm_burntime);
 101
 102         self.nextthink = time + 0.1;
 103 }
 104
 105
 106 void nade_napalm_ball()
 107 {
 108         entity proj;
 109         vector kick;
 110
 111         spamsound(self, CH_SHOTS, "weapons/fireball_fire.wav", VOL_BASE, ATTEN_NORM);
 112
 113         proj = spawn ();
 114         proj.owner = self.owner;
 115         proj.realowner = self.realowner;
 116         proj.team = self.owner.team;
 117         proj.classname = "grenade";
 118         proj.bot_dodge = TRUE;
 119         proj.bot_dodgerating = autocvar_g_nades_napalm_ball_damage;
 120         proj.movetype = MOVETYPE_BOUNCE;
 121         proj.projectiledeathtype = DEATH_NADE_NAPALM;
 122         PROJECTILE_MAKETRIGGER(proj);
 123         setmodel(proj, "null");
 124         proj.scale = 1;//0.5;
 125         setsize(proj, '-4 -4 -4', '4 4 4');
 126         setorigin(proj, self.origin);
 127         proj.think = napalm_ball_think;
 128         proj.nextthink = time;
 129         proj.damageforcescale = autocvar_g_nades_napalm_ball_damageforcescale;
 130         proj.effects = EF_LOWPRECISION | EF_FLAME;
 131
 132         kick_x =(random() - 0.5) * 2 * autocvar_g_nades_napalm_ball_spread;
 133         kick_y = (random() - 0.5) * 2 * autocvar_g_nades_napalm_ball_spread;
 134         kick_z = (random()/2+0.5) * autocvar_g_nades_napalm_ball_spread;
 135         proj.velocity = kick;
 136
 137         proj.pushltime = time + autocvar_g_nades_napalm_ball_lifetime;
 138
 139         proj.angles = vectoangles(proj.velocity);
 140         proj.flags = FL_PROJECTILE;
 141         proj.missile_flags = MIF_SPLASH | MIF_PROXY | MIF_ARC;
 142
 143         //CSQCProjectile(proj, TRUE, PROJECTILE_NAPALM_FIRE, TRUE);
 144 }
 145
 146
 147 void napalm_fountain_think()
 148 {
 149
 150         if(round_handler_IsActive())
 151         if(!round_handler_IsRoundStarted())
 152         {
 153                 remove(self);
 154                 return;
 155         }
 156
 157         if(time >= self.ltime)
 158         {
 159                 remove(self);
 160                 return;
 161         }
 162
 163         vector midpoint = ((self.absmin + self.absmax) * 0.5);
 164         if(pointcontents(midpoint) == CONTENT_WATER)
 165         {
 166                 self.velocity = self.velocity * 0.5;
 167
 168                 if(pointcontents(midpoint + '0 0 16') == CONTENT_WATER)
 169                         { self.velocity_z = 200; }
 170
 171                 UpdateCSQCProjectile(self);
 172         }
 173
 174         napalm_damage(autocvar_g_nades_napalm_fountain_radius, autocvar_g_nades_napalm_fountain_damage,
 175                 autocvar_g_nades_napalm_fountain_edgedamage, autocvar_g_nades_napalm_burntime);
 176
 177         self.nextthink = time + 0.1;
 178         if(time >= self.nade_special_time)
 179         {
 180                 self.nade_special_time = time + autocvar_g_nades_napalm_fountain_delay;
 181                 nade_napalm_ball();
 182         }
 183 }
 184
 185 void nade_napalm_boom()
 186 {
 187         entity fountain;
 188         local float c;
 189         for (c = 0; c < autocvar_g_nades_napalm_ball_count; c ++)
 190                 nade_napalm_ball();
 191
 192
 193         fountain = spawn();
 194         fountain.owner = self.owner;
 195         fountain.realowner = self.realowner;
 196         fountain.origin = self.origin;
 197         setorigin(fountain, fountain.origin);
 198         fountain.think = napalm_fountain_think;
 199         fountain.nextthink = time;
 200         fountain.ltime = time + autocvar_g_nades_napalm_fountain_lifetime;
 201         fountain.pushltime = fountain.ltime;
 202         fountain.team = self.team;
 203         fountain.movetype = MOVETYPE_TOSS;
 204         fountain.projectiledeathtype = DEATH_NADE_NAPALM;
 205         fountain.bot_dodge = TRUE;
 206         fountain.bot_dodgerating = autocvar_g_nades_napalm_fountain_damage;
 207         fountain.nade_special_time = time;
 208         setsize(fountain, '-16 -16 -16', '16 16 16');
 209         CSQCProjectile(fountain, TRUE, PROJECTILE_NAPALM_FOUNTAIN, TRUE);
 210 }
 211
 212 void nade_ice_freeze(entity freezefield, entity frost_target, float freeze_time)
 213 {
 214         frost_target.frozen_by = freezefield.realowner;
 215         pointparticles(particleeffectnum("electro_impact"), frost_target.origin, '0 0 0', 1);
 216         Freeze(frost_target, 1/freeze_time, 3, FALSE);
 217         if(frost_target.ballcarried)
 218         if(g_keepaway) { ka_DropEvent(frost_target); }
 219         else { DropBall(frost_target.ballcarried, frost_target.origin, frost_target.velocity);}
 220         if(frost_target.flagcarried) { ctf_Handle_Throw(frost_target, world, DROP_THROW); }
 221         if(frost_target.nade) { toss_nade(frost_target, '0 0 0', time + 0.05); }
 222
 223         kh_Key_DropAll(frost_target, FALSE);
 224 }
 225
 226 void nade_ice_think()
 227 {
 228
 229         if(round_handler_IsActive())
 230         if(!round_handler_IsRoundStarted())
 231         {
 232                 remove(self);
 233                 return;
 234         }
 235
 236         if(time >= self.ltime)
 237         {
 238                 if ( autocvar_g_nades_ice_explode )
 239                 {
 240                         string expef;
 241                         switch(self.realowner.team)
 242                         {
 243                                 case NUM_TEAM_1: expef = "nade_red_explode"; break;
 244                                 case NUM_TEAM_2: expef = "nade_blue_explode"; break;
 245                                 case NUM_TEAM_3: expef = "nade_yellow_explode"; break;
 246                                 case NUM_TEAM_4: expef = "nade_pink_explode"; break;
 247                                 default:                 expef = "nade_neutral_explode"; break;
 248                         }
 249                         pointparticles(particleeffectnum(expef), self.origin + '0 0 1', '0 0 0', 1);
 250                         sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_NORM);
 251
 252                         RadiusDamage(self, self.realowner, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
 253                                 autocvar_g_nades_nade_radius, self, autocvar_g_nades_nade_force, self.projectiledeathtype, self.enemy);
 254                         Damage_DamageInfo(self.origin, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
 255                                 autocvar_g_nades_nade_radius, '1 1 1' * autocvar_g_nades_nade_force, self.projectiledeathtype, 0, self);
 256                 }
 257                 remove(self);
 258                 return;
 259         }
 260
 261
 262         self.nextthink = time+0.1;
 263
 264         // gaussian
 265         float randomr;
 266         randomr = random();
 267         randomr = exp(-5*randomr*randomr)*autocvar_g_nades_nade_radius;
 268         float randomw;
 269         randomw = random()*M_PI*2;
 270         vector randomp;
 271         randomp_x = randomr*cos(randomw);
 272         randomp_y = randomr*sin(randomw);
 273         randomp_z = 1;
 274         pointparticles(particleeffectnum("electro_muzzleflash"), self.origin + randomp, '0 0 0', 1);
 275
 276         if(time >= self.nade_special_time)
 277         {
 278                 self.nade_special_time = time+0.7;
 279
 280
 281                 pointparticles(particleeffectnum("electro_impact"), self.origin, '0 0 0', 1);
 282                 pointparticles(particleeffectnum("icefield"), self.origin, '0 0 0', 1);
 283         }
 284
 285
 286         float current_freeze_time = self.ltime - time - 0.1;
 287
 288         entity e;
 289         for(e = findradius(self.origin, autocvar_g_nades_nade_radius); e; e = e.chain)
 290         if(e != self)
 291         if(!autocvar_g_nades_ice_teamcheck || (DIFF_TEAM(e, self.realowner) || e == self.realowner))
 292         if(e.takedamage && e.deadflag == DEAD_NO)
 293         if(e.health > 0)
 294         if(!e.revival_time || ((time - e.revival_time) >= 1.5))
 295         if(!e.frozen)
 296         if(current_freeze_time > 0)
 297                 nade_ice_freeze(self, e, current_freeze_time);
 298 }
 299
 300 void nade_ice_boom()
 301 {
 302         entity fountain;
 303         fountain = spawn();
 304         fountain.owner = self.owner;
 305         fountain.realowner = self.realowner;
 306         fountain.origin = self.origin;
 307         setorigin(fountain, fountain.origin);
 308         fountain.think = nade_ice_think;
 309         fountain.nextthink = time;
 310         fountain.ltime = time + autocvar_g_nades_ice_freeze_time;
 311         fountain.pushltime = fountain.wait = fountain.ltime;
 312         fountain.team = self.team;
 313         fountain.movetype = MOVETYPE_TOSS;
 314         fountain.projectiledeathtype = DEATH_NADE_ICE;
 315         fountain.bot_dodge = FALSE;
 316         setsize(fountain, '-16 -16 -16', '16 16 16');
 317         fountain.nade_special_time = time+0.3;
 318         fountain.angles = self.angles;
 319
 320         if ( autocvar_g_nades_ice_explode )
 321         {
 322                 setmodel(fountain, "models/grenademodel.md3");
 323                 entity timer = spawn();
 324                 setmodel(timer, "models/ok_nade_counter/ok_nade_counter.md3");
 325                 setattachment(timer, fountain, "");
 326                 timer.classname = "nade_timer";
 327                 timer.colormap = self.colormap;
 328                 timer.glowmod = self.glowmod;
 329                 timer.think = nade_timer_think;
 330                 timer.nextthink = time;
 331                 timer.wait = fountain.ltime;
 332                 timer.owner = fountain;
 333                 timer.skin = 10;
 334         }
 335         else
 336                 setmodel(fountain, "null");
 337 }
 338
 339 void nade_translocate_boom()
 340 {
 341         if(self.realowner.vehicle)
 342                 return;
 343
 344         vector locout = self.origin + '0 0 1' * (1 - self.realowner.mins_z - 24);
 345
 346         makevectors(self.realowner.angles);
 347
 348         entity oldself = self;
 349         self = self.realowner;
 350         MUTATOR_CALLHOOK(PortalTeleport);
 351         self.realowner = self;
 352         self = oldself;
 353
 354         TeleportPlayer(self, self.realowner, locout, self.realowner.mangle, v_forward * vlen(self.realowner.velocity), '0 0 0', '0 0 0', TELEPORT_FLAGS_TELEPORTER);
 355 }
 356
 357 void nade_spawn_boom()
 358 {
 359         entity spawnloc = spawn();
 360         setorigin(spawnloc, self.origin);
 361         setsize(spawnloc, self.realowner.mins, self.realowner.maxs);
 362         spawnloc.movetype = MOVETYPE_NONE;
 363         spawnloc.solid = SOLID_NOT;
 364         spawnloc.drawonlytoclient = self.realowner;
 365         spawnloc.effects = EF_STARDUST;
 366         spawnloc.cnt = autocvar_g_nades_spawn_count;
 367
 368         if(self.realowner.nade_spawnloc)
 369         {
 370                 remove(self.realowner.nade_spawnloc);
 371                 self.realowner.nade_spawnloc = world;
 372         }
 373
 374         self.realowner.nade_spawnloc = spawnloc;
 375 }
 376
 377 void nade_heal_think()
 378 {
 379         if(time >= self.ltime)
 380         {
 381                 remove(self);
 382                 return;
 383         }
 384
 385         self.nextthink = time;
 386
 387         if(time >= self.nade_special_time)
 388         {
 389                 self.nade_special_time = time+0.25;
 390                 self.nade_show_particles = 1;
 391         }
 392         else
 393                 self.nade_show_particles = 0;
 394 }
 395
 396 void nade_heal_touch()
 397 {
 398         float maxhealth;
 399         float health_factor;
 400         if(IS_PLAYER(other) || (other.flags & FL_MONSTER))
 401         if(other.deadflag == DEAD_NO)
 402         if(!other.frozen)
 403         {
 404                 health_factor = autocvar_g_nades_heal_rate*frametime/2;
 405                 if ( other != self.realowner )
 406                 {
 407                         if ( SAME_TEAM(other,self) )
 408                                 health_factor *= autocvar_g_nades_heal_friend;
 409                         else
 410                                 health_factor *= autocvar_g_nades_heal_foe;
 411                 }
 412                 if ( health_factor > 0 )
 413                 {
 414                         maxhealth = (other.flags & FL_MONSTER) ? other.max_health : g_pickup_healthmega_max;
 415                         if ( other.health < maxhealth )
 416                         {
 417                                 if ( self.nade_show_particles )
 418                                         pointparticles(particleeffectnum("healing_fx"), other.origin, '0 0 0', 1);
 419                                 other.health = min(other.health+health_factor, maxhealth);
 420                         }
 421                         other.pauserothealth_finished = max(other.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 422                 }
 423                 else if ( health_factor < 0 )
 424                 {
 425                         Damage(other,self,self.realowner,-health_factor,DEATH_NADE_HEAL,other.origin,'0 0 0');
 426                 }
 427
 428         }
 429
 430         if ( IS_REAL_CLIENT(other) || (other.vehicle_flags & VHF_ISVEHICLE) )
 431         {
 432                 entity show_red = (other.vehicle_flags & VHF_ISVEHICLE) ? other.owner : other;
 433                 show_red.stat_healing_orb = time+0.1;
 434                 show_red.stat_healing_orb_alpha = 0.75 * (self.ltime - time) / self.healer_lifetime;
 435         }
 436 }
 437
 438 void nade_heal_boom()
 439 {
 440         entity healer;
 441         healer = spawn();
 442         healer.owner = self.owner;
 443         healer.realowner = self.realowner;
 444         setorigin(healer, self.origin);
 445         healer.healer_lifetime = autocvar_g_nades_heal_time; // save the cvar
 446         healer.ltime = time + healer.healer_lifetime;
 447         healer.team = self.realowner.team;
 448         healer.bot_dodge = FALSE;
 449         healer.solid = SOLID_TRIGGER;
 450         healer.touch = nade_heal_touch;
 451
 452         setmodel(healer, "models/ctf/shield.md3");
 453         healer.healer_radius = autocvar_g_nades_nade_radius;
 454         vector size = '1 1 1' * healer.healer_radius / 2;
 455         setsize(healer,-size,size);
 456
 457         Net_LinkEntity(healer, TRUE, 0, healer_send);
 458
 459         healer.think = nade_heal_think;
 460         healer.nextthink = time;
 461         healer.SendFlags |= 1;
 462 }
 463
 464 void nade_monster_boom()
 465 {
 466         entity e = spawnmonster(self.pokenade_type, 0, self.realowner, self.realowner, self.origin, FALSE, 1);
 467
 468         //e.monster_lifetime = time + autocvar_g_nades_pokenade_monster_lifetime;
 469         e.monster_skill = MONSTER_SKILL_INSANE;
 470 }
 471
 472 void nade_boom()
 473 {
 474         string expef;
 475         float nade_blast = 1;
 476
 477         switch ( self.nade_type )
 478         {
 479                 case NADE_TYPE_NAPALM:
 480                         nade_blast = autocvar_g_nades_napalm_blast;
 481                         expef = "explosion_medium";
 482                         break;
 483                 case NADE_TYPE_ICE:
 484                         nade_blast = 0;
 485                         expef = "electro_combo"; // hookbomb_explode electro_combo bigplasma_impact
 486                         break;
 487                 case NADE_TYPE_TRANSLOCATE:
 488                         nade_blast = 0;
 489                         expef = "";
 490                         break;
 491                 case NADE_TYPE_MONSTER:
 492                 case NADE_TYPE_SPAWN:
 493                         nade_blast = 0;
 494                         switch(self.realowner.team)
 495                         {
 496                                 case NUM_TEAM_1: expef = "spawn_event_red"; break;
 497                                 case NUM_TEAM_2: expef = "spawn_event_blue"; break;
 498                                 case NUM_TEAM_3: expef = "spawn_event_yellow"; break;
 499                                 case NUM_TEAM_4: expef = "spawn_event_pink"; break;
 500                                 default: expef = "spawn_event_neutral"; break;
 501                         }
 502                         break;
 503                 case NADE_TYPE_HEAL:
 504                         nade_blast = 0;
 505                         expef = "spawn_event_red";
 506                         break;
 507
 508                 default:
 509                 case NADE_TYPE_NORMAL:
 510                         switch(self.realowner.team)
 511                         {
 512                                 case NUM_TEAM_1: expef = "nade_red_explode"; break;
 513                                 case NUM_TEAM_2: expef = "nade_blue_explode"; break;
 514                                 case NUM_TEAM_3: expef = "nade_yellow_explode"; break;
 515                                 case NUM_TEAM_4: expef = "nade_pink_explode"; break;
 516                                 default:                 expef = "nade_neutral_explode"; break;
 517                         }
 518         }
 519
 520         pointparticles(particleeffectnum(expef), self.origin + '0 0 1', '0 0 0', 1);
 521
 522         sound(self, CH_SHOTS_SINGLE, "misc/null.wav", VOL_BASE, ATTEN_NORM);
 523         sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_NORM);
 524
 525         self.takedamage = DAMAGE_NO;
 526
 527         if(nade_blast)
 528         {
 529                 RadiusDamage(self, self.realowner, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
 530                                  autocvar_g_nades_nade_radius, self, autocvar_g_nades_nade_force, self.projectiledeathtype, self.enemy);
 531                 Damage_DamageInfo(self.origin, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage, autocvar_g_nades_nade_radius, '1 1 1' * autocvar_g_nades_nade_force, self.projectiledeathtype, 0, self);
 532         }
 533
 534         switch ( self.nade_type )
 535         {
 536                 case NADE_TYPE_NAPALM: nade_napalm_boom(); break;
 537                 case NADE_TYPE_ICE: nade_ice_boom(); break;
 538                 case NADE_TYPE_TRANSLOCATE: nade_translocate_boom(); break;
 539                 case NADE_TYPE_SPAWN: nade_spawn_boom(); break;
 540                 case NADE_TYPE_HEAL: nade_heal_boom(); break;
 541                 case NADE_TYPE_MONSTER: nade_monster_boom(); break;
 542         }
 543
 544         remove(self);
 545 }
 546
 547 void nade_touch()
 548 {
 549         PROJECTILE_TOUCH;
 550         //setsize(self, '-2 -2 -2', '2 2 2');
 551         //UpdateCSQCProjectile(self);
 552         if(self.health == self.max_health)
 553         {
 554                 spamsound(self, CH_SHOTS, strcat("weapons/grenade_bounce", ftos(1 + rint(random() * 5)), ".wav"), VOL_BASE, ATTEN_NORM);
 555                 return;
 556         }
 557
 558         self.enemy = other;
 559         nade_boom();
 560 }
 561
 562 void nade_beep()
 563 {
 564         sound(self, CH_SHOTS_SINGLE, "overkill/grenadebip.ogg", VOL_BASE, 0.5 *(ATTEN_LARGE + ATTEN_MAX));
 565         self.think = nade_boom;
 566         self.nextthink = max(self.wait, time);
 567 }
 568
 569 void nade_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 570 {
 571         if(self.nade_type == NADE_TYPE_TRANSLOCATE || self.nade_type == NADE_TYPE_SPAWN)
 572                 return;
 573
 574         if(DEATH_ISWEAPON(deathtype, WEP_LASER))
 575                 return;
 576
 577         if(DEATH_ISWEAPON(deathtype, WEP_NEX) || DEATH_ISWEAPON(deathtype, WEP_MINSTANEX))
 578         {
 579                 force *= 6;
 580                 damage = self.max_health * 0.55;
 581         }
 582
 583         if(DEATH_ISWEAPON(deathtype, WEP_UZI))
 584                 damage = self.max_health * 0.1;
 585
 586         if(DEATH_ISWEAPON(deathtype, WEP_SHOTGUN))
 587         if(deathtype & HITTYPE_SECONDARY)
 588         {
 589                 damage = self.max_health * 0.1;
 590                 force *= 10;
 591         }
 592         else
 593                 damage = self.max_health * 1.1;
 594
 595         self.velocity += force;
 596
 597         if(!damage || (self.flags & FL_ONGROUND && IS_PLAYER(attacker)))
 598                 return;
 599
 600         if(self.health == self.max_health)
 601         {
 602                 sound(self, CH_SHOTS_SINGLE, "misc/null.wav", VOL_BASE, 0.5 *(ATTEN_LARGE + ATTEN_MAX));
 603                 self.nextthink = max(time + autocvar_g_nades_nade_lifetime, time);
 604                 self.think = nade_beep;
 605         }
 606
 607         self.health       -= damage;
 608
 609         if ( self.nade_type != NADE_TYPE_HEAL || IS_PLAYER(attacker) )
 610                 self.realowner = attacker;
 611
 612         if(self.health <= 0)
 613                 W_PrepareExplosionByDamage(attacker, nade_boom);
 614         else
 615                 nade_burn_spawn(self);
 616 }
 617
 618 void toss_nade(entity e, vector _velocity, float _time)
 619 {
 620         if(e.nade == world)
 621                 return;
 622
 623         entity _nade = e.nade;
 624         e.nade = world;
 625
 626         remove(e.fake_nade);
 627         e.fake_nade = world;
 628
 629         makevectors(e.v_angle);
 630
 631         W_SetupShot(e, FALSE, FALSE, "", CH_WEAPON_A, 0);
 632
 633         Kill_Notification(NOTIF_ONE_ONLY, e, MSG_CENTER_CPID, CPID_NADES);
 634
 635         setorigin(_nade, w_shotorg + (v_right * 25) * -1);
 636         //setmodel(_nade, "models/weapons/v_ok_grenade.md3");
 637         //setattachment(_nade, world, "");
 638         PROJECTILE_MAKETRIGGER(_nade);
 639         setsize(_nade, '-16 -16 -16', '16 16 16');
 640         _nade.movetype = MOVETYPE_BOUNCE;
 641
 642         tracebox(_nade.origin, _nade.mins, _nade.maxs, _nade.origin, FALSE, _nade);
 643         if (trace_startsolid)
 644                 setorigin(_nade, e.origin);
 645
 646         if(self.v_angle_x >= 70 && self.v_angle_x <= 110)
 647                 _nade.velocity = '0 0 100';
 648         else if(autocvar_g_nades_nade_newton_style == 1)
 649                 _nade.velocity = e.velocity + _velocity;
 650         else if(autocvar_g_nades_nade_newton_style == 2)
 651                 _nade.velocity = _velocity;
 652         else
 653                 _nade.velocity = W_CalculateProjectileVelocity(e.velocity, _velocity, TRUE);
 654
 655         _nade.touch = nade_touch;
 656         _nade.health = autocvar_g_nades_nade_health;
 657         _nade.max_health = _nade.health;
 658         _nade.takedamage = DAMAGE_AIM;
 659         _nade.event_damage = nade_damage;
 660         _nade.customizeentityforclient = func_null;
 661         _nade.exteriormodeltoclient = world;
 662         _nade.traileffectnum = 0;
 663         _nade.teleportable = TRUE;
 664         _nade.pushable = TRUE;
 665         _nade.gravity = 1;
 666         _nade.missile_flags = MIF_SPLASH | MIF_ARC;
 667         _nade.damagedbycontents = TRUE;
 668         _nade.angles = vectoangles(_nade.velocity);
 669         _nade.flags = FL_PROJECTILE;
 670         _nade.projectiledeathtype = DEATH_NADE;
 671         _nade.toss_time = time;
 672         _nade.solid = SOLID_CORPSE; //((_nade.nade_type == NADE_TYPE_TRANSLOCATE) ? SOLID_CORPSE : SOLID_BBOX);
 673
 674         nade_spawn(_nade);
 675
 676         if(_time)
 677         {
 678                 _nade.think = nade_boom;
 679                 _nade.nextthink = _time;
 680         }
 681
 682         e.nade_refire = time + autocvar_g_nades_nade_refire;
 683         e.nade_timer = 0;
 684 }
 685
 686 void nades_GiveBonus(entity player, float score)
 687 {
 688         if (autocvar_g_nades)
 689         if (autocvar_g_nades_bonus)
 690         if (IS_REAL_CLIENT(player))
 691         if (IS_PLAYER(player) && player.bonus_nades < autocvar_g_nades_bonus_max)
 692         if (player.frozen == 0)
 693         if (player.deadflag == DEAD_NO)
 694         {
 695                 if ( player.bonus_nade_score < 1 )
 696                         player.bonus_nade_score += score/autocvar_g_nades_bonus_score_max;
 697
 698                 if ( player.bonus_nade_score >= 1 )
 699                 {
 700                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_NADE_BONUS);
 701                         play2(player,"kh/alarm.wav");
 702                         player.bonus_nades++;
 703                         player.bonus_nade_score -= 1;
 704                 }
 705         }
 706 }
 707
 708 void nades_RemoveBonus(entity player)
 709 {
 710         player.bonus_nades = player.bonus_nade_score = 0;
 711 }
 712
 713 float nade_customize()
 714 {
 715         //if(IS_SPEC(other)) { return FALSE; }
 716         if(other == self.realowner || (IS_SPEC(other) && other.enemy == self.realowner))
 717         {
 718                 // somewhat hide the model, but keep the glow
 719                 //self.effects = 0;
 720                 //self.alpha = -1;
 721                 return FALSE; // or not
 722         }
 723         else
 724         {
 725                 //self.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 726                 self.alpha = 1;
 727         }
 728
 729         return TRUE;
 730 }
 731
 732 void nade_prime()
 733 {
 734         if(self.nade)
 735                 remove(self.nade);
 736
 737         if(self.fake_nade)
 738                 remove(self.fake_nade);
 739
 740         entity n = spawn(), fn = spawn();
 741
 742         n.classname = "nade";
 743         fn.classname = "fake_nade";
 744
 745         if(self.items & IT_STRENGTH && autocvar_g_nades_bonus_onstrength)
 746                 n.nade_type = self.nade_type;
 747         else if (self.bonus_nades >= 1)
 748         {
 749                 n.nade_type = self.nade_type;
 750                 n.pokenade_type = self.pokenade_type;
 751                 self.bonus_nades -= 1;
 752         }
 753         else
 754         {
 755                 n.nade_type = ((autocvar_g_nades_client_select) ? self.cvar_cl_nade_type : autocvar_g_nades_nade_type);
 756                 n.pokenade_type = ((autocvar_g_nades_client_select) ? self.cvar_cl_pokenade_type : autocvar_g_nades_pokenade_monster_type);
 757         }
 758
 759         n.nade_type = bound(1, n.nade_type, NADE_TYPE_LAST);
 760
 761         setmodel(n, "models/weapons/v_ok_grenade.md3");
 762         //setattachment(n, self, "bip01 l hand");
 763         n.exteriormodeltoclient = self;
 764         n.customizeentityforclient = nade_customize;
 765         n.traileffectnum = particleeffectnum(Nade_TrailEffect(Nade_ProjectileFromID(n.nade_type, FALSE), self.team));
 766         n.colormod = Nade_Color(n.nade_type);
 767         n.realowner = self;
 768         n.colormap = self.colormap;
 769         n.glowmod = self.glowmod;
 770         n.wait = time + autocvar_g_nades_nade_lifetime;
 771         n.lifetime = time;
 772         n.think = nade_beep;
 773         n.nextthink = max(n.wait - 3, time);
 774         n.projectiledeathtype = DEATH_NADE;
 775
 776         setmodel(fn, "models/weapons/h_ok_grenade.iqm");
 777         setattachment(fn, self.weaponentity, "");
 778         fn.realowner = fn.owner = self;
 779         fn.colormod = Nade_Color(n.nade_type);
 780         fn.colormap = self.colormap;
 781         fn.glowmod = self.glowmod;
 782         fn.think = SUB_Remove;
 783         fn.nextthink = n.wait;
 784
 785         self.nade = n;
 786         self.fake_nade = fn;
 787 }
 788
 789 float CanThrowNade()
 790 {
 791         if(self.vehicle)
 792                 return FALSE;
 793
 794         if(gameover)
 795                 return FALSE;
 796
 797         if(self.deadflag != DEAD_NO)
 798                 return FALSE;
 799
 800         if (!autocvar_g_nades)
 801                 return FALSE; // allow turning them off mid match
 802
 803         if(forbidWeaponUse())
 804                 return FALSE;
 805
 806         if (!IS_PLAYER(self))
 807                 return FALSE;
 808
 809         return TRUE;
 810 }
 811
 812 void nades_CheckThrow()
 813 {
 814         if(!CanThrowNade())
 815                 return;
 816
 817         if(!self.nade)
 818         {
 819                 if(self.nade_refire < time)
 820                 {
 821                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_NADE_THROW);
 822                         nade_prime();
 823                         self.nade_refire = time + autocvar_g_nades_nade_refire;
 824                 }
 825         }
 826         else
 827         {
 828                 if(time - self.nade.lifetime >= 1)
 829                 {
 830                         makevectors(self.v_angle);
 831                         float _force = time - self.nade.lifetime;
 832                         _force /= autocvar_g_nades_nade_lifetime;
 833                         _force = autocvar_g_nades_nade_minforce + (_force * (autocvar_g_nades_nade_maxforce - autocvar_g_nades_nade_minforce));
 834                         toss_nade(self, (v_forward * 0.75 + v_up * 0.2 + v_right * 0.05) * _force, 0);
 835                 }
 836         }
 837 }
 838
 839 void nades_Clear(entity player)
 840 {
 841         if(player.nade)
 842                 remove(player.nade);
 843         if(player.fake_nade)
 844                 remove(player.fake_nade);
 845
 846         player.nade = player.fake_nade = world;
 847         player.nade_timer = 0;
 848 }
 849
 850 MUTATOR_HOOKFUNCTION(nades_CheckThrow)
 851 {
 852         if(MUTATOR_RETURNVALUE) { nades_CheckThrow(); }
 853         return FALSE;
 854 }
 855
 856 MUTATOR_HOOKFUNCTION(nades_VehicleEnter)
 857 {
 858         if(vh_player.nade)
 859                 toss_nade(vh_player, '0 0 100', max(vh_player.nade.wait, time + 0.05));
 860
 861         return FALSE;
 862 }
 863
 864 MUTATOR_HOOKFUNCTION(nades_PlayerPreThink)
 865 {
 866         if(!IS_PLAYER(self)) { return FALSE; }
 867
 868         float key_pressed = self.BUTTON_HOOK;
 869         float time_score;
 870
 871         if(g_grappling_hook || client_hasweapon(self, WEP_HOOK, FALSE, FALSE) || (weaponsInMap & WEPSET_HOOK) || g_jetpack || self.items & IT_JETPACK)
 872                 key_pressed = self.button16; // if hook/jetpack is enabled, use an alternate key
 873
 874         if(self.nade)
 875         {
 876                 self.nade_timer = bound(0, (time - self.nade.lifetime) / autocvar_g_nades_nade_lifetime, 1);
 877                 //print(sprintf("%d %d\n", self.nade_timer, time - self.nade.lifetime));
 878                 makevectors(self.angles);
 879                 self.nade.velocity = self.velocity;
 880
 881                 setorigin(self.nade, self.origin + self.view_ofs + v_forward * 8 + v_right * -8 + v_up * 0);
 882                 self.nade.angles_y = self.angles_y;
 883         }
 884
 885         if(self.nade)
 886         if(self.nade.wait - 0.1 <= time)
 887                 toss_nade(self, '0 0 0', time + 0.05);
 888
 889         if(CanThrowNade())
 890         if(self.nade_refire < time)
 891         {
 892                 if(key_pressed)
 893                 {
 894                         if(!self.nade)
 895                                 nade_prime();
 896                 }
 897                 else if(time - self.nade.lifetime >= 1)
 898                 {
 899                         if(self.nade)
 900                         {
 901                                 makevectors(self.v_angle);
 902                                 float _force = time - self.nade.lifetime;
 903                                 _force /= autocvar_g_nades_nade_lifetime;
 904                                 _force = autocvar_g_nades_nade_minforce + (_force * (autocvar_g_nades_nade_maxforce - autocvar_g_nades_nade_minforce));
 905                                 toss_nade(self, (v_forward * 0.7 + v_up * 0.2 + v_right * 0.1) * _force, 0);
 906                         }
 907                 }
 908         }
 909
 910         if(IS_PLAYER(self))
 911         {
 912                 if ( autocvar_g_nades_bonus && autocvar_g_nades )
 913                 {
 914                         entity key;
 915                         float key_count = 0;
 916                         FOR_EACH_KH_KEY(key) if(key.owner == self) { ++key_count; }
 917
 918                         if(self.flagcarried || self.ballcarried) // this player is important
 919                                 time_score = autocvar_g_nades_bonus_score_time_flagcarrier;
 920                         else
 921                                 time_score = autocvar_g_nades_bonus_score_time;
 922
 923                         if(key_count)
 924                                 time_score = autocvar_g_nades_bonus_score_time_flagcarrier * key_count; // multiply by the number of keys the player is holding
 925
 926                         if(autocvar_g_nades_bonus_client_select)
 927                         {
 928                                 self.nade_type = self.cvar_cl_nade_type;
 929                                 self.pokenade_type = self.cvar_cl_pokenade_type;
 930                         }
 931                         else
 932                         {
 933                                 self.nade_type = autocvar_g_nades_bonus_type;
 934                                 self.pokenade_type = autocvar_g_nades_pokenade_monster_type;
 935                         }
 936
 937                         self.nade_type = bound(1, self.nade_type, NADE_TYPE_LAST);
 938
 939                         if(self.bonus_nade_score >= 0 && autocvar_g_nades_bonus_score_max)
 940                                 nades_GiveBonus(self, time_score / autocvar_g_nades_bonus_score_max);
 941                 }
 942                 else
 943                 {
 944                         self.bonus_nades = self.bonus_nade_score = 0;
 945                 }
 946         }
 947
 948         float n = 0;
 949         entity o = world;
 950         if(self.freezetag_frozen_timeout > 0 && time >= self.freezetag_frozen_timeout)
 951                 n = -1;
 952         else
 953         {
 954                 vector revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
 955                 n = 0;
 956                 FOR_EACH_PLAYER(other) if(self != other)
 957                 {
 958                         if(other.deadflag == DEAD_NO)
 959                         if(other.frozen == 0)
 960                         if(SAME_TEAM(other, self))
 961                         if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
 962                         {
 963                                 if(!o)
 964                                         o = other;
 965                                 if(self.frozen == 1)
 966                                         other.reviving = TRUE;
 967                                 ++n;
 968                         }
 969                 }
 970         }
 971
 972         if(n && self.frozen == 3) // OK, there is at least one teammate reviving us
 973         {
 974                 self.revive_progress = bound(0, self.revive_progress + frametime * max(1/60, autocvar_g_freezetag_revive_speed), 1);
 975                 self.health = max(1, self.revive_progress * start_health);
 976
 977                 if(self.revive_progress >= 1)
 978                 {
 979                         Unfreeze(self);
 980
 981                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_FREEZETAG_REVIVED, o.netname);
 982                         Send_Notification(NOTIF_ONE, o, MSG_CENTER, CENTER_FREEZETAG_REVIVE, self.netname);
 983                 }
 984
 985                 FOR_EACH_PLAYER(other) if(other.reviving)
 986                 {
 987                         other.revive_progress = self.revive_progress;
 988                         other.reviving = FALSE;
 989                 }
 990         }
 991
 992         return FALSE;
 993 }
 994
 995 MUTATOR_HOOKFUNCTION(nades_PlayerSpawn)
 996 {
 997         if(autocvar_g_nades_spawn)
 998                 self.nade_refire = time + autocvar_g_spawnshieldtime;
 999         else
1000                 self.nade_refire  = time + autocvar_g_nades_nade_refire;
1001
1002         if(autocvar_g_nades_bonus_client_select)
1003                 self.nade_type = self.cvar_cl_nade_type;
1004
1005         self.nade_timer = 0;
1006
1007         if(self.nade_spawnloc)
1008         {
1009                 setorigin(self, self.nade_spawnloc.origin);
1010                 self.nade_spawnloc.cnt -= 1;
1011
1012                 if(self.nade_spawnloc.cnt <= 0)
1013                 {
1014                         remove(self.nade_spawnloc);
1015                         self.nade_spawnloc = world;
1016                 }
1017         }
1018
1019         return FALSE;
1020 }
1021
1022 MUTATOR_HOOKFUNCTION(nades_PlayerDies)
1023 {
1024         if(frag_target.nade)
1025         if(!frag_target.frozen || !autocvar_g_freezetag_revive_nade)
1026                 toss_nade(frag_target, '0 0 100', max(frag_target.nade.wait, time + 0.05));
1027
1028         float killcount_bonus = ((frag_attacker.killcount >= 1) ? bound(0, autocvar_g_nades_bonus_score_minor * frag_attacker.killcount, autocvar_g_nades_bonus_score_medium) : autocvar_g_nades_bonus_score_minor);
1029
1030         if(IS_PLAYER(frag_attacker))
1031         {
1032                 if (SAME_TEAM(frag_attacker, frag_target) || frag_attacker == frag_target)
1033                         nades_RemoveBonus(frag_attacker);
1034                 else if(frag_target.flagcarried)
1035                         nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_medium);
1036                 else if(autocvar_g_nades_bonus_score_spree && frag_attacker.killcount > 1)
1037                 {
1038                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
1039                                 case counta: { nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_spree); break; }
1040                         switch(frag_attacker.killcount)
1041                         {
1042                                 KILL_SPREE_LIST
1043                                 default: nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_minor); break;
1044                         }
1045                         #undef SPREE_ITEM
1046                 }
1047                 else
1048                         nades_GiveBonus(frag_attacker, killcount_bonus);
1049         }
1050
1051         nades_RemoveBonus(frag_target);
1052
1053         return FALSE;
1054 }
1055
1056 MUTATOR_HOOKFUNCTION(nades_PlayerDamage)
1057 {
1058         if(frag_target.frozen)
1059         if(autocvar_g_freezetag_revive_nade)
1060         if(frag_attacker == frag_target)
1061         if(frag_deathtype == DEATH_NADE)
1062         if(time - frag_inflictor.toss_time <= 0.1)
1063         {
1064                 Unfreeze(frag_target);
1065                 frag_target.health = autocvar_g_freezetag_revive_nade_health;
1066                 pointparticles(particleeffectnum("iceorglass"), frag_target.origin, '0 0 0', 3);
1067                 frag_damage = 0;
1068                 frag_force = '0 0 0';
1069                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_FREEZETAG_REVIVED_NADE, frag_target.netname);
1070                 Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_FREEZETAG_REVIVE_SELF);
1071         }
1072
1073         return FALSE;
1074 }
1075
1076 MUTATOR_HOOKFUNCTION(nades_MonsterDies)
1077 {
1078         if(IS_PLAYER(frag_attacker))
1079         if(DIFF_TEAM(frag_attacker, self))
1080         if(!(self.spawnflags & MONSTERFLAG_SPAWNED))
1081                 nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_minor);
1082
1083         return FALSE;
1084 }
1085
1086 MUTATOR_HOOKFUNCTION(nades_RemovePlayer)
1087 {
1088         nades_Clear(self);
1089         nades_RemoveBonus(self);
1090         return FALSE;
1091 }
1092
1093 MUTATOR_HOOKFUNCTION(nades_SpectateCopy)
1094 {
1095         self.nade_timer = other.nade_timer;
1096         self.nade_type = other.nade_type;
1097         self.pokenade_type = other.pokenade_type;
1098         self.bonus_nades = other.bonus_nades;
1099         self.bonus_nade_score = other.bonus_nade_score;
1100         self.stat_healing_orb = other.stat_healing_orb;
1101         self.stat_healing_orb_alpha = other.stat_healing_orb_alpha;
1102         return FALSE;
1103 }
1104
1105 MUTATOR_HOOKFUNCTION(nades_GetCvars)
1106 {
1107         GetCvars_handleFloat(get_cvars_s, get_cvars_f, cvar_cl_nade_type, "cl_nade_type");
1108         GetCvars_handleString(get_cvars_s, get_cvars_f, cvar_cl_pokenade_type, "cl_pokenade_type");
1109
1110         return FALSE;
1111 }
1112
1113 MUTATOR_HOOKFUNCTION(nades_BuildMutatorsString)
1114 {
1115         ret_string = strcat(ret_string, ":Nades");
1116         return FALSE;
1117 }
1118
1119 MUTATOR_HOOKFUNCTION(nades_BuildMutatorsPrettyString)
1120 {
1121         ret_string = strcat(ret_string, ", Nades");
1122         return FALSE;
1123 }
1124
1125 void nades_Initialize()
1126 {
1127         addstat(STAT_NADE_TIMER, AS_FLOAT, nade_timer);
1128         addstat(STAT_NADE_BONUS, AS_FLOAT, bonus_nades);
1129         addstat(STAT_NADE_BONUS_TYPE, AS_INT, nade_type);
1130         addstat(STAT_NADE_BONUS_SCORE, AS_FLOAT, bonus_nade_score);
1131         addstat(STAT_HEALING_ORB, AS_FLOAT, stat_healing_orb);
1132         addstat(STAT_HEALING_ORB_ALPHA, AS_FLOAT, stat_healing_orb_alpha);
1133
1134         precache_model("models/ok_nade_counter/ok_nade_counter.md3");
1135         precache_model("models/weapons/h_ok_grenade.iqm");
1136         precache_model("models/weapons/v_ok_grenade.md3");
1137         precache_model("models/ctf/shield.md3");
1138
1139         precache_sound("weapons/rocket_impact.wav");
1140         precache_sound("weapons/grenade_bounce1.wav");
1141         precache_sound("weapons/grenade_bounce2.wav");
1142         precache_sound("weapons/grenade_bounce3.wav");
1143         precache_sound("weapons/grenade_bounce4.wav");
1144         precache_sound("weapons/grenade_bounce5.wav");
1145         precache_sound("weapons/grenade_bounce6.wav");
1146         precache_sound("overkill/grenadebip.ogg");
1147 }
1148
1149 MUTATOR_DEFINITION(mutator_nades)
1150 {
1151         MUTATOR_HOOK(ForbidThrowCurrentWeapon, nades_CheckThrow, CBC_ORDER_LAST);
1152         MUTATOR_HOOK(VehicleEnter, nades_VehicleEnter, CBC_ORDER_ANY);
1153         MUTATOR_HOOK(PlayerPreThink, nades_PlayerPreThink, CBC_ORDER_ANY);
1154         MUTATOR_HOOK(PlayerSpawn, nades_PlayerSpawn, CBC_ORDER_ANY);
1155         MUTATOR_HOOK(PlayerDies, nades_PlayerDies, CBC_ORDER_LAST);
1156         MUTATOR_HOOK(PlayerDamage_Calculate, nades_PlayerDamage, CBC_ORDER_ANY);
1157         MUTATOR_HOOK(MonsterDies, nades_MonsterDies, CBC_ORDER_ANY);
1158         MUTATOR_HOOK(MakePlayerObserver, nades_RemovePlayer, CBC_ORDER_ANY);
1159         MUTATOR_HOOK(ClientDisconnect, nades_RemovePlayer, CBC_ORDER_ANY);
1160         MUTATOR_HOOK(SpectateCopy, nades_SpectateCopy, CBC_ORDER_ANY);
1161         MUTATOR_HOOK(GetCvars, nades_GetCvars, CBC_ORDER_ANY);
1162         MUTATOR_HOOK(reset_map_global, nades_RemovePlayer, CBC_ORDER_ANY);
1163         MUTATOR_HOOK(BuildMutatorsString, nades_BuildMutatorsString, CBC_ORDER_ANY);
1164         MUTATOR_HOOK(BuildMutatorsPrettyString, nades_BuildMutatorsPrettyString, CBC_ORDER_ANY);
1165
1166         MUTATOR_ONADD
1167         {
1168                 nades_Initialize();
1169         }
1170
1171         return FALSE;
1172 }