qcsrc/server/mutators/mutator_minstagib.qc

   1 void spawnfunc_item_minst_cells (void)
   2 {
   3         if not(g_minstagib) { remove(self); return; }
   4         if not(self.ammo_cells)
   5                 self.ammo_cells = autocvar_g_minstagib_ammo_drop;
   6
   7         StartItem ("models/items/a_cells.md3",
   8                            "misc/itempickup.wav", 45, 0,
   9                            "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
  10 }
  11
  12 void minstagib_health_mega()
  13 {
  14         self.max_health = 1;
  15         StartItem ("models/items/g_h100.md3",
  16                            "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
  17                            "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
  18 }
  19
  20 .float minstagib_nextthink;
  21 .float minstagib_needammo;
  22 void minstagib_stop_countdown(entity e)
  23 {
  24         if (!e.minstagib_needammo)
  25                 return;
  26         Kill_Notification(NOTIF_ONE_ONLY, e, MSG_CENTER_CPID, CPID_MINSTA_FINDAMMO);
  27         e.minstagib_needammo = FALSE;
  28 }
  29 void minstagib_ammocheck()
  30 {
  31         if not(IS_PLAYER(self))
  32                 return; // not a player
  33         if (time < self.minstagib_nextthink)
  34                 return;
  35
  36         if (self.deadflag || gameover)
  37                 minstagib_stop_countdown(self);
  38         else if (self.ammo_cells > 0 || (self.items & IT_UNLIMITED_WEAPON_AMMO))
  39                 minstagib_stop_countdown(self);
  40         else
  41         {
  42                 self.minstagib_needammo = TRUE;
  43                 if (self.health == 5)
  44                 {
  45                         Damage(self, self, self, 5, DEATH_NOAMMO, self.origin, '0 0 0');
  46                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_MINSTAGIB_TERMINATED);
  47                 }
  48                 else if (self.health == 10)
  49                 {
  50                         Damage(self, self, self, 5, DEATH_NOAMMO, self.origin, '0 0 0');
  51                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_1);
  52                 }
  53                 else if (self.health == 20)
  54                 {
  55                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
  56                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_2);
  57                 }
  58                 else if (self.health == 30)
  59                 {
  60                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
  61                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_3);
  62                 }
  63                 else if (self.health == 40)
  64                 {
  65                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
  66                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_4);
  67                 }
  68                 else if (self.health == 50)
  69                 {
  70                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
  71                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_5);
  72                 }
  73                 else if (self.health == 60)
  74                 {
  75                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
  76                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_6);
  77                 }
  78                 else if (self.health == 70)
  79                 {
  80                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
  81                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_7);
  82                 }
  83                 else if (self.health == 80)
  84                 {
  85                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
  86                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_8);
  87                 }
  88                 else if (self.health == 90)
  89                 {
  90                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MINSTA_FINDAMMO);
  91                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
  92                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_9);
  93                 }
  94                 else if (self.health == 100)
  95                 {
  96                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_MULTI, MULTI_MINSTA_FINDAMMO);
  97                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
  98                 }
  99         }
 100         self.minstagib_nextthink = time + 1;
 101 }
 102
 103 MUTATOR_HOOKFUNCTION(minstagib_MatchEnd)
 104 {
 105         entity head;
 106         FOR_EACH_PLAYER(head)
 107                 minstagib_stop_countdown(head);
 108
 109         return FALSE;
 110 }
 111
 112 MUTATOR_HOOKFUNCTION(minstagib_MonsterLoot)
 113 {
 114         other.monster_loot = spawnfunc_item_minst_cells;
 115
 116         return FALSE;
 117 }
 118
 119 MUTATOR_HOOKFUNCTION(minstagib_MonsterSpawn)
 120 {
 121         // always refill ammo
 122         if(self.monsterid == MONSTER_MAGE)
 123                 self.skin = 1;
 124
 125         return FALSE;
 126 }
 127
 128 MUTATOR_HOOKFUNCTION(minstagib_BotShouldAttack)
 129 {
 130         if(checkentity.items & IT_STRENGTH)
 131                 return TRUE;
 132
 133         return FALSE;
 134 }
 135
 136 MUTATOR_HOOKFUNCTION(minstagib_MakePlayerObserver)
 137 {
 138         minstagib_stop_countdown(self);
 139         return FALSE;
 140 }
 141
 142 MUTATOR_HOOKFUNCTION(minstagib_PlayerSpawn)
 143 {
 144         self.effects |= EF_FULLBRIGHT;
 145         return FALSE;
 146 }
 147
 148 MUTATOR_HOOKFUNCTION(minstagib_PlayerPreThink)
 149 {
 150         minstagib_ammocheck();
 151         return FALSE;
 152 }
 153
 154 MUTATOR_HOOKFUNCTION(minstagib_PlayerPowerups)
 155 {
 156         if not(self.effects & EF_FULLBRIGHT)
 157                 self.effects |= EF_FULLBRIGHT;
 158
 159         if (self.items & IT_STRENGTH)
 160         {
 161                 play_countdown(self.strength_finished, "misc/poweroff.wav");
 162                 if (time > self.strength_finished)
 163                 {
 164                         self.alpha = default_player_alpha;
 165                         self.exteriorweaponentity.alpha = default_weapon_alpha;
 166                         self.items &~= IT_STRENGTH;
 167                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_INVISIBILITY);
 168                 }
 169         }
 170         else
 171         {
 172                 if (time < self.strength_finished)
 173                 {
 174                         self.alpha = autocvar_g_minstagib_invis_alpha;
 175                         self.exteriorweaponentity.alpha = autocvar_g_minstagib_invis_alpha;
 176                         self.items |= IT_STRENGTH;
 177                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_INVISIBILITY, self.netname);
 178                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_INVISIBILITY);
 179                 }
 180         }
 181
 182         if (self.items & IT_INVINCIBLE)
 183         {
 184                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
 185                 if (time > self.invincible_finished)
 186                 {
 187                         self.items &~= IT_INVINCIBLE;
 188                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SPEED);
 189                 }
 190         }
 191         else
 192         {
 193                 if (time < self.invincible_finished)
 194                 {
 195                         self.items |= IT_INVINCIBLE;
 196                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SPEED, self.netname);
 197                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SPEED);
 198                 }
 199         }
 200         return FALSE;
 201 }
 202
 203 MUTATOR_HOOKFUNCTION(minstagib_PlayerPhysics)
 204 {
 205         if(self.items & IT_INVINCIBLE)
 206                 self.stat_sv_maxspeed = self.stat_sv_maxspeed * autocvar_g_minstagib_speed_highspeed;
 207
 208         return FALSE;
 209 }
 210
 211 MUTATOR_HOOKFUNCTION(minstagib_SplitHealthArmor)
 212 {
 213         damage_save = 0;
 214         damage_take = frag_damage;
 215
 216         return FALSE;
 217 }
 218
 219 MUTATOR_HOOKFUNCTION(minstagib_ForbidThrowing)
 220 {
 221         // weapon dropping on death handled by FilterItem
 222
 223         return TRUE;
 224 }
 225
 226 MUTATOR_HOOKFUNCTION(minstagib_PlayerDamage)
 227 {
 228         if(autocvar_g_friendlyfire == 0 && !IsDifferentTeam(frag_target, frag_attacker) && IS_PLAYER(frag_target) && IS_PLAYER(frag_attacker))
 229                 frag_damage = 0;
 230
 231         if(IS_PLAYER(frag_target))
 232         {
 233                 if ((frag_deathtype == DEATH_FALL)  ||
 234                         (frag_deathtype == DEATH_DROWN) ||
 235                         (frag_deathtype == DEATH_SLIME) ||
 236                         (frag_deathtype == DEATH_LAVA))
 237                 {
 238                         frag_damage = 0;
 239                 }
 240
 241                 if(IS_PLAYER(frag_attacker))
 242                 if(DEATH_ISWEAPON(frag_deathtype, WEP_MINSTANEX))
 243                 if(frag_target.armorvalue)
 244                 {
 245                         frag_target.armorvalue -= 1;
 246                         Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_MINSTA_LIVES_REMAINING, frag_target.armorvalue);
 247                         frag_damage = 0;
 248                         frag_target.hitsound += 1;
 249                         frag_attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
 250                 }
 251
 252                 if(IS_PLAYER(frag_attacker))
 253                 if (DEATH_ISWEAPON(frag_deathtype, WEP_LASER))
 254                 {
 255                         frag_damage = 0;
 256                         frag_mirrordamage = 0;
 257                         if (frag_target != frag_attacker)
 258                         {
 259                                 if (frag_target.health >= 1)
 260                                         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_MINSTA_SECONDARY);
 261                                 frag_force = '0 0 0';
 262                                 // keep mirrorfrag_force
 263                                 //frag_attacker = frag_target;
 264                         }
 265                 }
 266         }
 267
 268         if(IS_PLAYER(frag_attacker))
 269         if(frag_mirrordamage > 0)
 270         {
 271                 // just lose extra LIVES, don't kill the player for mirror damage
 272                 if(frag_attacker.armorvalue > 0)
 273                 {
 274                         frag_attacker.armorvalue -= 1;
 275                         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_MINSTA_LIVES_REMAINING, frag_attacker.armorvalue);
 276                         frag_attacker.hitsound += 1;
 277                 }
 278                 frag_mirrordamage = 0;
 279         }
 280
 281         if(frag_target.items & IT_STRENGTH)
 282                 yoda = 1;
 283
 284         return FALSE;
 285 }
 286
 287 MUTATOR_HOOKFUNCTION(minstagib_SetStartItems)
 288 {
 289         start_ammo_cells = cvar("g_minstagib_ammo_start");
 290
 291         start_health = 100;
 292         start_armorvalue = 0;
 293         WEPSET_COPY_AW(start_weapons, WEP_MINSTANEX);
 294         start_items |= IT_UNLIMITED_SUPERWEAPONS;
 295
 296         return FALSE;
 297 }
 298
 299 MUTATOR_HOOKFUNCTION(minstagib_FilterItem)
 300 {
 301         if(self.classname == "item_cells")
 302                 return TRUE; // no normal cells?
 303
 304         if(self.weapon == WEP_MINSTANEX && self.classname == "droppedweapon")
 305         {
 306                 self.ammo_cells = autocvar_g_minstagib_ammo_drop;
 307                 return FALSE;
 308         }
 309
 310         if(self.weapon == WEP_ROCKET_LAUNCHER || self.weapon == WEP_NEX)
 311         {
 312                 entity e = spawn();
 313                 setorigin(e, self.origin);
 314                 entity oldself;
 315                 oldself = self;
 316                 self = e;
 317                 spawnfunc_item_minst_cells();
 318                 self = oldself;
 319                 return TRUE;
 320         }
 321
 322         if(self.flags & FL_POWERUP)
 323                 return FALSE;
 324
 325         if(self.ammo_cells > autocvar_g_minstagib_ammo_drop && self.classname != "item_minst_cells")
 326                 self.ammo_cells = autocvar_g_minstagib_ammo_drop;
 327
 328         if(self.ammo_cells && !self.weapon)
 329                 return FALSE;
 330
 331         return TRUE;
 332 }
 333
 334 MUTATOR_HOOKFUNCTION(minstagib_CustomizeWaypoint)
 335 {
 336         entity e = WaypointSprite_getviewentity(other);
 337
 338         // if you have the invisibility powerup, sprites ALWAYS are restricted to your team
 339         // but only apply this to real players, not to spectators
 340         if((self.owner.flags & FL_CLIENT) && (self.owner.items & IT_STRENGTH) && (e == other))
 341         if(IsDifferentTeam(self.owner, e))
 342                 return TRUE;
 343
 344         return FALSE;
 345 }
 346
 347 MUTATOR_HOOKFUNCTION(minstagib_ItemCountdown)
 348 {
 349         switch(self.items)
 350         {
 351                 case IT_STRENGTH:   item_name = "item-invis"; item_color = '0 0 1'; break;
 352                 case IT_NAILS:      item_name = "item-extralife"; item_color = '1 0 0'; break;
 353                 case IT_INVINCIBLE: item_name = "item-speed"; item_color = '1 0 1'; break;
 354         }
 355         return FALSE;
 356 }
 357
 358 MUTATOR_HOOKFUNCTION(minstagib_ItemTouch)
 359 {
 360         if(self.ammo_cells)
 361         {
 362                 // play some cool sounds ;)
 363                 if (IS_CLIENT(other))
 364                 {
 365                         if(other.health <= 5)
 366                                 Send_Notification(NOTIF_ONE, other, MSG_ANNCE, ANNCE_MINSTAGIB_LASTSECOND);
 367                         else if(other.health < 50)
 368                                 Send_Notification(NOTIF_ONE, other, MSG_ANNCE, ANNCE_MINSTAGIB_NARROWLY);
 369                 }
 370
 371                 if(other.health < 100)
 372                         other.health = 100;
 373
 374                 return MUT_ITEMTOUCH_CONTINUE;
 375         }
 376
 377         if(self.max_health)
 378         {
 379                 other.armorvalue = bound(other.armorvalue, 999, other.armorvalue + autocvar_g_minstagib_extralives);
 380                 Send_Notification(NOTIF_ONE, other, MSG_CENTER, CENTER_EXTRALIVES);
 381                 return MUT_ITEMTOUCH_PICKUP;
 382         }
 383
 384         return MUT_ITEMTOUCH_CONTINUE;
 385 }
 386
 387 MUTATOR_HOOKFUNCTION(minstagib_OnEntityPreSpawn)
 388 {
 389         if not(autocvar_g_powerups) { return FALSE; }
 390         if not(self.classname == "item_strength" || self.classname == "item_invincible" || self.classname == "item_health_mega")
 391                 return FALSE;
 392
 393         entity e = spawn();
 394
 395         if(random() < 0.3)
 396                 e.think = spawnfunc_item_strength;
 397         else if(random() < 0.6)
 398                 e.think = minstagib_health_mega;
 399         else
 400                 e.think = spawnfunc_item_invincible;
 401
 402         e.nextthink = time + 0.1;
 403         e.spawnflags = self.spawnflags;
 404         e.noalign = self.noalign;
 405         setorigin(e, self.origin);
 406
 407         return TRUE;
 408 }
 409
 410 MUTATOR_HOOKFUNCTION(minstagib_BuildMutatorsString)
 411 {
 412         ret_string = strcat(ret_string, ":MinstaGib");
 413         return FALSE;
 414 }
 415
 416 MUTATOR_HOOKFUNCTION(minstagib_BuildMutatorsPrettyString)
 417 {
 418         ret_string = strcat(ret_string, ", MinstaGib");
 419         return FALSE;
 420 }
 421
 422 MUTATOR_DEFINITION(mutator_minstagib)
 423 {
 424         MUTATOR_HOOK(MatchEnd, minstagib_MatchEnd, CBC_ORDER_ANY);
 425         MUTATOR_HOOK(MonsterDropItem, minstagib_MonsterLoot, CBC_ORDER_ANY);
 426         MUTATOR_HOOK(MonsterSpawn, minstagib_MonsterSpawn, CBC_ORDER_ANY);
 427         MUTATOR_HOOK(BotShouldAttack, minstagib_BotShouldAttack, CBC_ORDER_ANY);
 428         MUTATOR_HOOK(PlayerPhysics, minstagib_PlayerPhysics, CBC_ORDER_ANY);
 429         MUTATOR_HOOK(PlayerSpawn, minstagib_PlayerSpawn, CBC_ORDER_ANY);
 430         MUTATOR_HOOK(PlayerDamage_Calculate, minstagib_PlayerDamage, CBC_ORDER_ANY);
 431         MUTATOR_HOOK(MakePlayerObserver, minstagib_MakePlayerObserver, CBC_ORDER_ANY);
 432         MUTATOR_HOOK(SetStartItems, minstagib_SetStartItems, CBC_ORDER_ANY);
 433         MUTATOR_HOOK(ItemTouch, minstagib_ItemTouch, CBC_ORDER_ANY);
 434         MUTATOR_HOOK(FilterItem, minstagib_FilterItem, CBC_ORDER_ANY);
 435         MUTATOR_HOOK(CustomizeWaypoint, minstagib_CustomizeWaypoint, CBC_ORDER_ANY);
 436         MUTATOR_HOOK(Item_RespawnCountdown, minstagib_ItemCountdown, CBC_ORDER_ANY);
 437         MUTATOR_HOOK(PlayerDamage_SplitHealthArmor, minstagib_SplitHealthArmor, CBC_ORDER_ANY);
 438         MUTATOR_HOOK(PlayerPowerups, minstagib_PlayerPowerups, CBC_ORDER_ANY);
 439         MUTATOR_HOOK(ForbidThrowCurrentWeapon, minstagib_ForbidThrowing, CBC_ORDER_ANY);
 440         MUTATOR_HOOK(PlayerPreThink, minstagib_PlayerPreThink, CBC_ORDER_ANY);
 441         MUTATOR_HOOK(OnEntityPreSpawn, minstagib_OnEntityPreSpawn, CBC_ORDER_ANY);
 442         MUTATOR_HOOK(BuildMutatorsString, minstagib_BuildMutatorsString, CBC_ORDER_ANY);
 443         MUTATOR_HOOK(BuildMutatorsPrettyString, minstagib_BuildMutatorsPrettyString, CBC_ORDER_ANY);
 444
 445         return FALSE;
 446 }