qcsrc/server/mutators/mutator_buffs.qc

   1 float buffs_BuffModel_Customize()
   2 {
   3         entity player, myowner;
   4         float same_team;
   5
   6         player = WaypointSprite_getviewentity(other);
   7         myowner = self.owner;
   8         same_team = (SAME_TEAM(player, myowner) || SAME_TEAM(player, myowner));
   9
  10         if(myowner.alpha <= 0.5 && !same_team && myowner.alpha != 0)
  11                 return false;
  12
  13         if(player == myowner || (IS_SPEC(other) && other.enemy == myowner))
  14         {
  15                 // somewhat hide the model, but keep the glow
  16                 self.effects = 0;
  17                 self.alpha = -1;
  18         }
  19         else
  20         {
  21                 self.effects = EF_FULLBRIGHT | EF_LOWPRECISION;
  22                 self.alpha = 1;
  23         }
  24         return true;
  25 }
  26
  27 vector buff_GlowColor(entity buff)
  28 {
  29         //if(buff.team) { return Team_ColorRGB(buff.team); }
  30         return buff.color;
  31 }
  32
  33 // buff item
  34 float buff_Waypoint_visible_for_player(entity plr)
  35 {
  36     if(!self.owner.buff_active && !self.owner.buff_activetime)
  37         return false;
  38
  39         if(plr.buffs)
  40         {
  41                 if(plr.cvar_cl_buffs_autoreplace)
  42                 {
  43                         if(plr.buffs == self.owner.buffs)
  44                                 return false;
  45                 }
  46                 else
  47                         return false;
  48         }
  49
  50     return WaypointSprite_visible_for_player(plr);
  51 }
  52
  53 void buff_Waypoint_Spawn(entity e)
  54 {
  55     WaypointSprite_Spawn(Buff_Sprite(e.buffs), 0, autocvar_g_buffs_waypoint_distance, e, '0 0 1' * e.maxs.z, world, e.team, e, buff_waypoint, true, RADARICON_POWERUP, e.glowmod);
  56     WaypointSprite_UpdateTeamRadar(e.buff_waypoint, RADARICON_POWERUP, e.glowmod);
  57     e.buff_waypoint.waypointsprite_visible_for_player = buff_Waypoint_visible_for_player;
  58 }
  59
  60 void buff_SetCooldown(float cd)
  61 {
  62         cd = max(0, cd);
  63
  64         if(!self.buff_waypoint)
  65                 buff_Waypoint_Spawn(self);
  66
  67         WaypointSprite_UpdateBuildFinished(self.buff_waypoint, time + cd);
  68         self.buff_activetime = cd;
  69         self.buff_active = !cd;
  70 }
  71
  72 void buff_Respawn(entity ent)
  73 {
  74         if(gameover) { return; }
  75
  76         vector oldbufforigin = ent.origin;
  77
  78         if(!MoveToRandomMapLocation(ent, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, ((autocvar_g_buffs_random_location_attempts > 0) ? autocvar_g_buffs_random_location_attempts : 10), 1024, 256))
  79         {
  80                 entity spot = SelectSpawnPoint(true);
  81                 setorigin(ent, ((spot.origin + '0 0 200') + (randomvec() * 300)));
  82                 ent.angles = spot.angles;
  83         }
  84
  85         tracebox(ent.origin, ent.mins * 1.5, self.maxs * 1.5, ent.origin, MOVE_NOMONSTERS, ent);
  86
  87         setorigin(ent, trace_endpos); // attempt to unstick
  88
  89         ent.movetype = MOVETYPE_TOSS;
  90
  91         makevectors(ent.angles);
  92         ent.velocity = '0 0 200';
  93         ent.angles = '0 0 0';
  94         if(autocvar_g_buffs_random_lifetime > 0)
  95                 ent.lifetime = time + autocvar_g_buffs_random_lifetime;
  96
  97         pointparticles(particleeffectnum("electro_combo"), oldbufforigin + ((ent.mins + ent.maxs) * 0.5), '0 0 0', 1);
  98         pointparticles(particleeffectnum("electro_combo"), CENTER_OR_VIEWOFS(ent), '0 0 0', 1);
  99
 100         WaypointSprite_Ping(ent.buff_waypoint);
 101
 102         sound(ent, CH_TRIGGER, "keepaway/respawn.wav", VOL_BASE, ATTEN_NONE); // ATTEN_NONE (it's a sound intended to be heard anywhere)
 103 }
 104
 105 void buff_Touch()
 106 {
 107         if(gameover) { return; }
 108
 109         if(ITEM_TOUCH_NEEDKILL())
 110         {
 111                 buff_Respawn(self);
 112                 return;
 113         }
 114
 115         if((self.team && DIFF_TEAM(other, self))
 116         || (other.frozen)
 117         || (other.vehicle)
 118         || (!IS_PLAYER(other))
 119         || (!self.buff_active)
 120         )
 121         {
 122                 // can't touch this
 123                 return;
 124         }
 125
 126         if(other.buffs)
 127         {
 128                 if(other.cvar_cl_buffs_autoreplace && other.buffs != self.buffs)
 129                 {
 130                         //Send_Notification(NOTIF_ONE, other, MSG_MULTI, ITEM_BUFF_DROP, other.buffs);
 131                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ITEM_BUFF_LOST, other.netname, other.buffs);
 132
 133                         other.buffs = 0;
 134                         //sound(other, CH_TRIGGER, "relics/relic_effect.wav", VOL_BASE, ATTN_NORM);
 135                 }
 136                 else { return; } // do nothing
 137         }
 138
 139         self.owner = other;
 140         self.buff_active = false;
 141         self.lifetime = 0;
 142
 143         Send_Notification(NOTIF_ONE, other, MSG_MULTI, ITEM_BUFF_GOT, self.buffs);
 144         Send_Notification(NOTIF_ALL_EXCEPT, other, MSG_INFO, INFO_ITEM_BUFF, other.netname, self.buffs);
 145
 146         pointparticles(particleeffectnum("item_pickup"), CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 147         sound(other, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);
 148         other.buffs |= (self.buffs);
 149 }
 150
 151 float buff_Available(float buffid)
 152 {
 153         if(buffid == BUFF_AMMO && ((start_items & IT_UNLIMITED_WEAPON_AMMO) || (start_items & IT_UNLIMITED_AMMO) || (cvar("g_melee_only"))))
 154                 return false;
 155
 156         if(buffid == BUFF_VAMPIRE && cvar("g_vampire"))
 157                 return false;
 158
 159         if(!cvar(strcat("g_buffs_", Buff_Name(buffid))))
 160                 return false;
 161
 162         return true;
 163 }
 164
 165 void buff_NewType(entity ent, float cb)
 166 {
 167         entity e;
 168         RandomSelection_Init();
 169         for(e = Buff_Type_first; e; e = e.enemy)
 170         if(buff_Available(e.items))
 171         {
 172                 RandomSelection_Add(world, e.items, string_null, 1, 1 / e.count); // if it's already been chosen, give it a lower priority
 173                 e.count += 1;
 174         }
 175         ent.buffs = RandomSelection_chosen_float;
 176 }
 177
 178 void buff_Think()
 179 {
 180         if(self.buffs != self.oldbuffs)
 181         {
 182                 self.color = Buff_Color(self.buffs);
 183                 self.glowmod = buff_GlowColor(self);
 184                 self.skin = Buff_Skin(self.buffs);
 185
 186                 setmodel(self, "models/relics/relic.md3");
 187
 188                 if(self.buff_waypoint)
 189                 {
 190                         //WaypointSprite_Disown(self.buff_waypoint, 1);
 191                         WaypointSprite_Kill(self.buff_waypoint);
 192                         buff_Waypoint_Spawn(self);
 193                         if(self.buff_activetime)
 194                                 WaypointSprite_UpdateBuildFinished(self.buff_waypoint, time + self.buff_activetime - frametime);
 195                 }
 196
 197                 self.oldbuffs = self.buffs;
 198         }
 199
 200         if(!gameover)
 201         if((round_handler_IsActive() && !round_handler_IsRoundStarted()) || time >= game_starttime)
 202         if(!self.buff_activetime_updated)
 203         {
 204                 buff_SetCooldown(self.buff_activetime);
 205                 self.buff_activetime_updated = true;
 206     }
 207
 208         if(!self.buff_active && !self.buff_activetime)
 209         if(!self.owner || self.owner.frozen || self.owner.deadflag != DEAD_NO || !self.owner.iscreature || !(self.owner.buffs & self.buffs))
 210         {
 211                 buff_SetCooldown(autocvar_g_buffs_cooldown_respawn + frametime);
 212                 self.owner = world;
 213                 if(autocvar_g_buffs_randomize)
 214                         buff_NewType(self, self.buffs);
 215
 216                 if(autocvar_g_buffs_random_location || (self.spawnflags & 1))
 217                         buff_Respawn(self);
 218         }
 219
 220         if(self.buff_activetime)
 221         if(!gameover)
 222         if((round_handler_IsActive() && !round_handler_IsRoundStarted()) || time >= game_starttime)
 223         {
 224                 self.buff_activetime = max(0, self.buff_activetime - frametime);
 225
 226                 if(!self.buff_activetime)
 227                 {
 228                         self.buff_active = true;
 229                         sound(self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);
 230                         pointparticles(particleeffectnum("item_respawn"), CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 231                 }
 232         }
 233
 234         if(self.buff_active)
 235         {
 236                 if(self.team && !self.buff_waypoint)
 237                         buff_Waypoint_Spawn(self);
 238
 239                 if(self.lifetime)
 240                 if(time >= self.lifetime)
 241                         buff_Respawn(self);
 242         }
 243
 244         self.nextthink = time;
 245         //self.angles_y = time * 110.1;
 246 }
 247
 248 void buff_Waypoint_Reset()
 249 {
 250         WaypointSprite_Kill(self.buff_waypoint);
 251
 252         if(self.buff_activetime) { buff_Waypoint_Spawn(self); }
 253 }
 254
 255 void buff_Reset()
 256 {
 257         if(autocvar_g_buffs_randomize)
 258                 buff_NewType(self, self.buffs);
 259         self.owner = world;
 260         buff_SetCooldown(autocvar_g_buffs_cooldown_activate);
 261         buff_Waypoint_Reset();
 262         self.buff_activetime_updated = false;
 263
 264         if(autocvar_g_buffs_random_location || (self.spawnflags & 1))
 265                 buff_Respawn(self);
 266 }
 267
 268 float buff_Customize()
 269 {
 270         entity player = WaypointSprite_getviewentity(other);
 271         if(!self.buff_active || (self.team && DIFF_TEAM(player, self)))
 272         {
 273                 self.alpha = 0.3;
 274                 if(self.effects & EF_FULLBRIGHT) { self.effects &= ~(EF_FULLBRIGHT); }
 275                 self.pflags = 0;
 276         }
 277         else
 278         {
 279                 self.alpha = 1;
 280                 if(!(self.effects & EF_FULLBRIGHT)) { self.effects |= EF_FULLBRIGHT; }
 281                 self.light_lev = 220 + 36 * sin(time);
 282                 self.pflags = PFLAGS_FULLDYNAMIC;
 283         }
 284         return true;
 285 }
 286
 287 void buff_Init(entity ent)
 288 {
 289         if(!cvar("g_buffs")) { remove(self); return; }
 290
 291         if(!teamplay && self.team) { self.team = 0; }
 292
 293         entity oldself = self;
 294         self = ent;
 295         if(!self.buffs || buff_Available(self.buffs))
 296                 buff_NewType(self, 0);
 297
 298         self.classname = "item_buff";
 299         self.solid = SOLID_TRIGGER;
 300         self.flags = FL_ITEM;
 301         self.think = buff_Think;
 302         self.touch = buff_Touch;
 303         self.reset = buff_Reset;
 304         self.nextthink = time + 0.1;
 305         self.gravity = 1;
 306         self.movetype = MOVETYPE_TOSS;
 307         self.scale = 1;
 308         self.skin = Buff_Skin(self.buffs);
 309         self.effects = EF_FULLBRIGHT | EF_STARDUST | EF_NOSHADOW;
 310         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 311         self.customizeentityforclient = buff_Customize;
 312         //self.gravity = 100;
 313         self.color = Buff_Color(self.buffs);
 314         self.glowmod = buff_GlowColor(self);
 315         buff_SetCooldown(autocvar_g_buffs_cooldown_activate + game_starttime);
 316         self.buff_active = !self.buff_activetime;
 317         self.pflags = PFLAGS_FULLDYNAMIC;
 318
 319         if(self.noalign)
 320                 self.movetype = MOVETYPE_NONE; // reset by random location
 321
 322         setmodel(self, "models/relics/relic.md3");
 323         setsize(self, BUFF_MIN, BUFF_MAX);
 324
 325         if(cvar("g_buffs_random_location") || (self.spawnflags & 1))
 326                 buff_Respawn(self);
 327
 328         self = oldself;
 329 }
 330
 331 void buff_Init_Compat(entity ent, float replacement)
 332 {
 333         if(ent.spawnflags & 2)
 334                 ent.team = NUM_TEAM_1;
 335         else if(ent.spawnflags & 4)
 336                 ent.team = NUM_TEAM_2;
 337
 338         ent.buffs = replacement;
 339
 340         buff_Init(ent);
 341 }
 342
 343 void buff_SpawnReplacement(entity ent, entity old)
 344 {
 345         setorigin(ent, old.origin);
 346         ent.angles = old.angles;
 347         ent.noalign = old.noalign;
 348
 349         buff_Init(ent);
 350 }
 351
 352 // mutator hooks
 353 MUTATOR_HOOKFUNCTION(buffs_PlayerDamage_SplitHealthArmor)
 354 {
 355         if(frag_deathtype == DEATH_BUFF) { return false; }
 356
 357         if(frag_target.buffs & BUFF_RESISTANCE)
 358         {
 359                 vector v = healtharmor_applydamage(50, autocvar_g_buffs_resistance_blockpercent, frag_deathtype, frag_damage);
 360                 damage_take = v.x;
 361                 damage_save = v.y;
 362         }
 363
 364         return false;
 365 }
 366
 367 void buff_Vengeance_DelayedDamage()
 368 {
 369         if(self.enemy)
 370                 Damage(self.enemy, self.owner, self.owner, self.dmg, DEATH_BUFF, self.enemy.origin, '0 0 0');
 371
 372         remove(self);
 373         return;
 374 }
 375
 376 MUTATOR_HOOKFUNCTION(buffs_PlayerDamage_Calculate)
 377 {
 378         if(frag_deathtype == DEATH_BUFF) { return false; }
 379
 380         if(frag_target.buffs & BUFF_SPEED)
 381         if(frag_target != frag_attacker)
 382                 frag_damage *= autocvar_g_buffs_speed_damage_take;
 383
 384         if(frag_target.buffs & BUFF_MEDIC)
 385         if((frag_target.health - frag_damage) <= 0)
 386         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 387         if(frag_attacker)
 388         if(random() <= autocvar_g_buffs_medic_survive_chance)
 389         if(frag_target.health - autocvar_g_buffs_medic_survive_health > 0) // not if the final result would be less than 0, medic must get health
 390                 frag_damage = frag_target.health - autocvar_g_buffs_medic_survive_health;
 391
 392         if(frag_target.buffs & BUFF_VENGEANCE)
 393         if(frag_attacker)
 394         if(frag_attacker != frag_target)
 395         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 396         {
 397                 entity dmgent = spawn();
 398
 399                 dmgent.dmg = frag_damage * autocvar_g_buffs_vengeance_damage_multiplier;
 400                 dmgent.enemy = frag_attacker;
 401                 dmgent.owner = frag_target;
 402                 dmgent.think = buff_Vengeance_DelayedDamage;
 403                 dmgent.nextthink = time + 0.1;
 404         }
 405
 406         if(frag_target.buffs & BUFF_BASH)
 407         if(frag_attacker != frag_target)
 408         if(vlen(frag_force))
 409                 frag_force = '0 0 0';
 410
 411         if(frag_attacker.buffs & BUFF_BASH)
 412         if(vlen(frag_force))
 413         if(frag_attacker == frag_target)
 414                 frag_force *= autocvar_g_buffs_bash_force_self;
 415         else
 416                 frag_force *= autocvar_g_buffs_bash_force;
 417
 418         if(frag_attacker.buffs & BUFF_DISABILITY)
 419         if(frag_target != frag_attacker)
 420                 frag_target.buff_disability_time = time + autocvar_g_buffs_disability_time;
 421
 422         if(frag_attacker.buffs & BUFF_MEDIC)
 423         if(DEATH_WEAPONOF(frag_deathtype) != WEP_ARC)
 424         if(SAME_TEAM(frag_attacker, frag_target))
 425         if(frag_attacker != frag_target)
 426         {
 427                 frag_target.health = min(g_pickup_healthmega_max, frag_target.health + frag_damage);
 428                 frag_damage = 0;
 429         }
 430
 431         if(frag_attacker.buffs & BUFF_INFERNO)
 432         if(frag_target != frag_attacker)
 433                 Fire_AddDamage(frag_target, frag_attacker, (frag_damage * autocvar_g_buffs_inferno_damagemultiplier) * autocvar_g_buffs_inferno_burntime, autocvar_g_buffs_inferno_burntime, DEATH_BUFF);
 434
 435         // this... is ridiculous (TODO: fix!)
 436         if(frag_attacker.buffs & BUFF_VAMPIRE)
 437         if(!frag_target.vehicle)
 438         if(DEATH_WEAPONOF(frag_deathtype) != WEP_ARC)
 439         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 440         if(frag_target.deadflag == DEAD_NO)
 441         if(IS_PLAYER(frag_target) || (frag_target.flags & FL_MONSTER))
 442         if(frag_attacker != frag_target)
 443         if(!frag_target.frozen)
 444         if(frag_target.takedamage)
 445         if(DIFF_TEAM(frag_attacker, frag_target))
 446                 frag_attacker.health = bound(0, frag_attacker.health + bound(0, frag_damage * autocvar_g_buffs_vampire_damage_steal, frag_target.health), g_pickup_healthsmall_max);
 447
 448         return false;
 449 }
 450
 451 MUTATOR_HOOKFUNCTION(buffs_PlayerSpawn)
 452 {
 453         self.buffs = 0;
 454         // reset timers here to prevent them continuing after re-spawn
 455         self.buff_disability_time = 0;
 456         self.buff_disability_effect_time = 0;
 457         return false;
 458 }
 459
 460 MUTATOR_HOOKFUNCTION(buffs_PlayerPhysics)
 461 {
 462         if(self.buffs & BUFF_SPEED)
 463         {
 464                 self.stat_sv_maxspeed *= autocvar_g_buffs_speed_speed;
 465                 self.stat_sv_airspeedlimit_nonqw *= autocvar_g_buffs_speed_speed;
 466         }
 467
 468         if(time < self.buff_disability_time)
 469         {
 470                 self.stat_sv_maxspeed *= autocvar_g_buffs_disability_speed;
 471                 self.stat_sv_airspeedlimit_nonqw *= autocvar_g_buffs_disability_speed;
 472         }
 473
 474         return false;
 475 }
 476
 477 MUTATOR_HOOKFUNCTION(buffs_PlayerJump)
 478 {
 479         if(self.buffs & BUFF_JUMP)
 480                 player_jumpheight = autocvar_g_buffs_jump_height;
 481         self.stat_jumpheight = player_jumpheight;
 482
 483         return false;
 484 }
 485
 486 MUTATOR_HOOKFUNCTION(buffs_MonsterMove)
 487 {
 488         if(time < self.buff_disability_time)
 489         {
 490                 monster_speed_walk *= autocvar_g_buffs_disability_speed;
 491                 monster_speed_run *= autocvar_g_buffs_disability_speed;
 492         }
 493
 494         return false;
 495 }
 496
 497 MUTATOR_HOOKFUNCTION(buffs_PlayerDies)
 498 {
 499         if(self.buffs)
 500         {
 501                 Send_Notification(NOTIF_ALL_EXCEPT, self, MSG_INFO, INFO_ITEM_BUFF_LOST, self.netname, self.buffs);
 502                 self.buffs = 0;
 503
 504                 if(self.buff_model)
 505                 {
 506                         remove(self.buff_model);
 507                         self.buff_model = world;
 508                 }
 509         }
 510         return false;
 511 }
 512
 513 MUTATOR_HOOKFUNCTION(buffs_PlayerUseKey)
 514 {
 515         if(MUTATOR_RETURNVALUE || gameover) { return false; }
 516         if(self.buffs)
 517         {
 518                 Send_Notification(NOTIF_ONE, self, MSG_MULTI, ITEM_BUFF_DROP, self.buffs);
 519                 Send_Notification(NOTIF_ALL_EXCEPT, self, MSG_INFO, INFO_ITEM_BUFF_LOST, self.netname, self.buffs);
 520
 521                 self.buffs = 0;
 522                 sound(self, CH_TRIGGER, "relics/relic_effect.wav", VOL_BASE, ATTN_NORM);
 523                 return true;
 524         }
 525         return false;
 526 }
 527
 528 MUTATOR_HOOKFUNCTION(buffs_RemovePlayer)
 529 {
 530         if(self.buff_model)
 531         {
 532                 remove(self.buff_model);
 533                 self.buff_model = world;
 534         }
 535
 536         // also reset timers here to prevent them continuing after spectating
 537         self.buff_disability_time = 0;
 538         self.buff_disability_effect_time = 0;
 539
 540         return false;
 541 }
 542
 543 MUTATOR_HOOKFUNCTION(buffs_CustomizeWaypoint)
 544 {
 545         entity e = WaypointSprite_getviewentity(other);
 546
 547         // if you have the invisibility powerup, sprites ALWAYS are restricted to your team
 548         // but only apply this to real players, not to spectators
 549         if((self.owner.flags & FL_CLIENT) && (self.owner.buffs & BUFF_INVISIBLE) && (e == other))
 550         if(DIFF_TEAM(self.owner, e))
 551                 return true;
 552
 553         return false;
 554 }
 555
 556 MUTATOR_HOOKFUNCTION(buffs_OnEntityPreSpawn)
 557 {
 558         if(autocvar_g_buffs_replace_powerups)
 559         switch(self.classname)
 560         {
 561                 case "item_strength":
 562                 case "item_invincible":
 563                 {
 564                         entity e = spawn();
 565                         buff_SpawnReplacement(e, self);
 566                         return true;
 567                 }
 568         }
 569         return false;
 570 }
 571
 572 MUTATOR_HOOKFUNCTION(buffs_WeaponRate)
 573 {
 574         if(self.buffs & BUFF_SPEED)
 575                 weapon_rate *= autocvar_g_buffs_speed_rate;
 576
 577         if(time < self.buff_disability_time)
 578                 weapon_rate *= autocvar_g_buffs_disability_rate;
 579
 580         return false;
 581 }
 582
 583 MUTATOR_HOOKFUNCTION(buffs_PlayerThink)
 584 {
 585         if(gameover || self.deadflag != DEAD_NO) { return false; }
 586
 587         if(time < self.buff_disability_time)
 588         if(time >= self.buff_disability_effect_time)
 589         {
 590                 pointparticles(particleeffectnum("smoking"), self.origin + ((self.mins + self.maxs) * 0.5), '0 0 0', 1);
 591                 self.buff_disability_effect_time = time + 0.5;
 592         }
 593
 594         if(self.frozen)
 595         {
 596                 if(self.buffs)
 597                 {
 598                         Send_Notification(NOTIF_ALL_EXCEPT, self, MSG_INFO, INFO_ITEM_BUFF_LOST, self.netname, self.buffs);
 599                         self.buffs = 0;
 600                 }
 601         }
 602
 603         if((self.buffs & BUFF_INVISIBLE) && (self.oldbuffs & BUFF_INVISIBLE))
 604         if(self.alpha != autocvar_g_buffs_invisible_alpha)
 605                 self.alpha = autocvar_g_buffs_invisible_alpha;
 606
 607         if(self.buffs != self.oldbuffs)
 608         {
 609                 if(self.oldbuffs & BUFF_AMMO)
 610                 {
 611                         if(self.buff_ammo_prev_infitems)
 612                                 self.items |= IT_UNLIMITED_WEAPON_AMMO;
 613                         else
 614                                 self.items &= ~IT_UNLIMITED_WEAPON_AMMO;
 615                 }
 616                 else if(self.buffs & BUFF_AMMO)
 617                 {
 618                         self.buff_ammo_prev_infitems = (self.items & IT_UNLIMITED_WEAPON_AMMO);
 619                         self.items |= IT_UNLIMITED_WEAPON_AMMO;
 620                         if(!self.ammo_shells) { self.ammo_shells = 20; }
 621                         if(!self.ammo_cells) { self.ammo_cells = 20; }
 622                         if(!self.ammo_rockets) { self.ammo_rockets = 20; }
 623                         if(!self.ammo_nails) { self.ammo_nails = 20; }
 624                         if(!self.ammo_fuel) { self.ammo_fuel = 20; }
 625                 }
 626
 627                 if(self.oldbuffs & BUFF_INVISIBLE)
 628                 {
 629                         if(time < self.strength_finished && g_instagib)
 630                                 self.alpha = autocvar_g_instagib_invis_alpha;
 631                         else
 632                                 self.alpha = self.buff_invisible_prev_alpha;
 633                 }
 634                 else if(self.buffs & BUFF_INVISIBLE)
 635                 {
 636                         if(time < self.strength_finished && g_instagib)
 637                                 self.buff_invisible_prev_alpha = default_player_alpha;
 638                         else
 639                                 self.buff_invisible_prev_alpha = self.alpha;
 640                         self.alpha = autocvar_g_buffs_invisible_alpha;
 641                 }
 642
 643                 if(self.oldbuffs & BUFF_FLIGHT)
 644                         self.gravity = self.buff_flight_prev_gravity;
 645                 else if(self.buffs & BUFF_FLIGHT)
 646                 {
 647                         self.buff_flight_prev_gravity = self.gravity;
 648                         self.gravity = autocvar_g_buffs_flight_gravity;
 649                 }
 650
 651                 self.oldbuffs = self.buffs;
 652                 if(self.buffs)
 653                 {
 654                         if(!self.buff_model)
 655                         {
 656                                 self.buff_model = spawn();
 657                                 setmodel(self.buff_model, "models/relics/relic.md3");
 658                                 setsize(self.buff_model, '0 0 -40', '0 0 40');
 659                                 setattachment(self.buff_model, self, "");
 660                                 setorigin(self.buff_model, '0 0 1' * (self.buff_model.maxs.z * 1));
 661                                 self.buff_model.owner = self;
 662                                 self.buff_model.scale = 0.7;
 663                                 self.buff_model.pflags = PFLAGS_FULLDYNAMIC;
 664                                 self.buff_model.light_lev = 200;
 665                                 self.buff_model.customizeentityforclient = buffs_BuffModel_Customize;
 666                         }
 667                         self.buff_model.color = Buff_Color(self.buffs);
 668                         self.buff_model.glowmod = buff_GlowColor(self.buff_model);
 669                         self.buff_model.skin = Buff_Skin(self.buffs);
 670
 671                         self.effects |= EF_NOSHADOW;
 672                 }
 673                 else
 674                 {
 675                         remove(self.buff_model);
 676                         self.buff_model = world;
 677
 678                         self.effects &= ~(EF_NOSHADOW);
 679                 }
 680         }
 681
 682         if(self.buff_model)
 683         {
 684                 self.buff_model.effects = self.effects;
 685                 self.buff_model.effects |= EF_LOWPRECISION;
 686                 self.buff_model.effects = self.buff_model.effects & EFMASK_CHEAP; // eat performance
 687
 688                 self.buff_model.alpha = self.alpha;
 689         }
 690
 691         return false;
 692 }
 693
 694 MUTATOR_HOOKFUNCTION(buffs_SpectateCopy)
 695 {
 696         self.buffs = other.buffs;
 697         return false;
 698 }
 699
 700 MUTATOR_HOOKFUNCTION(buffs_VehicleEnter)
 701 {
 702         vh_vehicle.buffs = vh_player.buffs;
 703         vh_player.buffs = 0;
 704         return false;
 705 }
 706
 707 MUTATOR_HOOKFUNCTION(buffs_VehicleExit)
 708 {
 709         vh_player.buffs = vh_vehicle.buffs;
 710         vh_vehicle.buffs = 0;
 711         return false;
 712 }
 713
 714 MUTATOR_HOOKFUNCTION(buffs_PlayerRegen)
 715 {
 716         if(self.buffs & BUFF_MEDIC)
 717         {
 718                 regen_mod_rot = autocvar_g_buffs_medic_rot;
 719                 regen_mod_limit = regen_mod_max = autocvar_g_buffs_medic_max;
 720                 regen_mod_regen = autocvar_g_buffs_medic_regen;
 721         }
 722
 723         if(self.buffs & BUFF_SPEED)
 724                 regen_mod_regen = autocvar_g_buffs_speed_regen;
 725
 726         return false;
 727 }
 728
 729 MUTATOR_HOOKFUNCTION(buffs_GetCvars)
 730 {
 731         GetCvars_handleFloat(get_cvars_s, get_cvars_f, cvar_cl_buffs_autoreplace, "cl_buffs_autoreplace");
 732         return false;
 733 }
 734
 735 MUTATOR_HOOKFUNCTION(buffs_BuildMutatorsString)
 736 {
 737         ret_string = strcat(ret_string, ":Buffs");
 738         return false;
 739 }
 740
 741 MUTATOR_HOOKFUNCTION(buffs_BuildMutatorsPrettyString)
 742 {
 743         ret_string = strcat(ret_string, ", Buffs");
 744         return false;
 745 }
 746
 747 void buffs_DelayedInit()
 748 {
 749         if(autocvar_g_buffs_spawn_count > 0)
 750         if(find(world, classname, "item_buff") == world)
 751         {
 752                 float i;
 753                 for(i = 0; i < autocvar_g_buffs_spawn_count; ++i)
 754                 {
 755                         entity e = spawn();
 756                         e.spawnflags |= 1; // always randomize
 757                         e.velocity = randomvec() * 250; // this gets reset anyway if random location works
 758                         buff_Init(e);
 759                 }
 760         }
 761 }
 762
 763 void buffs_Initialize()
 764 {
 765         precache_model("models/relics/relic.md3");
 766         precache_sound("misc/strength_respawn.wav");
 767         precache_sound("misc/shield_respawn.wav");
 768         precache_sound("relics/relic_effect.wav");
 769         precache_sound("weapons/rocket_impact.wav");
 770         precache_sound("keepaway/respawn.wav");
 771
 772         addstat(STAT_BUFFS, AS_INT, buffs);
 773         addstat(STAT_MOVEVARS_JUMPVELOCITY, AS_FLOAT, stat_jumpheight);
 774
 775         InitializeEntity(world, buffs_DelayedInit, INITPRIO_FINDTARGET);
 776 }
 777
 778 MUTATOR_DEFINITION(mutator_buffs)
 779 {
 780         MUTATOR_HOOK(PlayerDamage_SplitHealthArmor, buffs_PlayerDamage_SplitHealthArmor, CBC_ORDER_ANY);
 781         MUTATOR_HOOK(PlayerDamage_Calculate, buffs_PlayerDamage_Calculate, CBC_ORDER_ANY);
 782         MUTATOR_HOOK(PlayerSpawn, buffs_PlayerSpawn, CBC_ORDER_ANY);
 783         MUTATOR_HOOK(PlayerPhysics, buffs_PlayerPhysics, CBC_ORDER_ANY);
 784         MUTATOR_HOOK(PlayerJump, buffs_PlayerJump, CBC_ORDER_ANY);
 785         MUTATOR_HOOK(MonsterMove, buffs_MonsterMove, CBC_ORDER_ANY);
 786         MUTATOR_HOOK(SpectateCopy, buffs_SpectateCopy, CBC_ORDER_ANY);
 787         MUTATOR_HOOK(VehicleEnter, buffs_VehicleEnter, CBC_ORDER_ANY);
 788         MUTATOR_HOOK(VehicleExit, buffs_VehicleExit, CBC_ORDER_ANY);
 789         MUTATOR_HOOK(PlayerRegen, buffs_PlayerRegen, CBC_ORDER_ANY);
 790         MUTATOR_HOOK(PlayerDies, buffs_PlayerDies, CBC_ORDER_ANY);
 791         MUTATOR_HOOK(PlayerUseKey, buffs_PlayerUseKey, CBC_ORDER_FIRST);
 792         MUTATOR_HOOK(MakePlayerObserver, buffs_RemovePlayer, CBC_ORDER_ANY);
 793         MUTATOR_HOOK(ClientDisconnect, buffs_RemovePlayer, CBC_ORDER_ANY);
 794         MUTATOR_HOOK(OnEntityPreSpawn, buffs_OnEntityPreSpawn, CBC_ORDER_ANY);
 795         MUTATOR_HOOK(CustomizeWaypoint, buffs_CustomizeWaypoint, CBC_ORDER_ANY);
 796         MUTATOR_HOOK(WeaponRateFactor, buffs_WeaponRate, CBC_ORDER_ANY);
 797         MUTATOR_HOOK(PlayerPreThink, buffs_PlayerThink, CBC_ORDER_ANY);
 798         MUTATOR_HOOK(GetCvars, buffs_GetCvars, CBC_ORDER_ANY);
 799         MUTATOR_HOOK(BuildMutatorsString, buffs_BuildMutatorsString, CBC_ORDER_ANY);
 800         MUTATOR_HOOK(BuildMutatorsPrettyString, buffs_BuildMutatorsPrettyString, CBC_ORDER_ANY);
 801
 802         MUTATOR_ONADD
 803         {
 804                 buffs_Initialize();
 805         }
 806
 807         return false;
 808 }