qcsrc/server/mutators/mutator_buffs.qc

   1 #include "../../common/triggers/target/music.qh"
   2 #include "mutator_buffs.qh"
   3 #include "../_all.qh"
   4
   5 #include "mutator.qh"
   6
   7 #include "../../common/buffs.qh"
   8
   9 entity buff_FirstFromFlags(int _buffs)
  10 {
  11         if (flags)
  12         {
  13                 FOREACH(BUFFS, 0, BUFFS_COUNT,
  14                         it.m_itemid & _buffs,
  15                         LAMBDA({
  16                                 return it;
  17                         })
  18                 );
  19         }
  20         return BUFF_NULL;
  21 }
  22
  23 float buffs_BuffModel_Customize()
  24 {
  25         entity player, myowner;
  26         float same_team;
  27
  28         player = WaypointSprite_getviewentity(other);
  29         myowner = self.owner;
  30         same_team = (SAME_TEAM(player, myowner) || SAME_TEAM(player, myowner));
  31
  32         if(myowner.alpha <= 0.5 && !same_team && myowner.alpha != 0)
  33                 return false;
  34
  35         if(player == myowner || (IS_SPEC(other) && other.enemy == myowner))
  36         {
  37                 // somewhat hide the model, but keep the glow
  38                 self.effects = 0;
  39                 self.alpha = -1;
  40         }
  41         else
  42         {
  43                 self.effects = EF_FULLBRIGHT | EF_LOWPRECISION;
  44                 self.alpha = 1;
  45         }
  46         return true;
  47 }
  48
  49 void buffs_BuffModel_Spawn(entity player)
  50 {
  51         player.buff_model = spawn();
  52         setmodel(player.buff_model, BUFF_MODEL);
  53         setsize(player.buff_model, '0 0 -40', '0 0 40');
  54         setattachment(player.buff_model, player, "");
  55         setorigin(player.buff_model, '0 0 1' * (player.buff_model.maxs.z * 1));
  56         player.buff_model.owner = player;
  57         player.buff_model.scale = 0.7;
  58         player.buff_model.pflags = PFLAGS_FULLDYNAMIC;
  59         player.buff_model.light_lev = 200;
  60         player.buff_model.customizeentityforclient = buffs_BuffModel_Customize;
  61 }
  62
  63 vector buff_GlowColor(entity buff)
  64 {
  65         //if(buff.team) { return Team_ColorRGB(buff.team); }
  66         return buff.m_color;
  67 }
  68
  69 void buff_Effect(entity player, string eff)
  70 {
  71         if(!autocvar_g_buffs_effects) { return; }
  72
  73         if(time >= self.buff_effect_delay)
  74         {
  75                 pointparticles(particleeffectnum(eff), player.origin + ((player.mins + player.maxs) * 0.5), '0 0 0', 1);
  76                 self.buff_effect_delay = time + 0.05; // prevent spam
  77         }
  78 }
  79
  80 // buff item
  81 float buff_Waypoint_visible_for_player(entity plr)
  82 {
  83         if(!self.owner.buff_active && !self.owner.buff_activetime)
  84                 return false;
  85
  86         if (plr.buffs)
  87         {
  88                 return plr.cvar_cl_buffs_autoreplace == false || plr.buffs != self.owner.buffs;
  89         }
  90
  91         return WaypointSprite_visible_for_player(plr);
  92 }
  93
  94 void buff_Waypoint_Spawn(entity e)
  95 {
  96         entity buff = buff_FirstFromFlags(e.buffs);
  97         WaypointSprite_Spawn(buff.m_sprite, 0, autocvar_g_buffs_waypoint_distance, e, '0 0 1' * e.maxs.z, world, e.team, e, buff_waypoint, true, RADARICON_POWERUP, e.glowmod);
  98         WaypointSprite_UpdateTeamRadar(e.buff_waypoint, RADARICON_POWERUP, e.glowmod);
  99         e.buff_waypoint.waypointsprite_visible_for_player = buff_Waypoint_visible_for_player;
 100 }
 101
 102 void buff_SetCooldown(float cd)
 103 {
 104         cd = max(0, cd);
 105
 106         if(!self.buff_waypoint)
 107                 buff_Waypoint_Spawn(self);
 108
 109         WaypointSprite_UpdateBuildFinished(self.buff_waypoint, time + cd);
 110         self.buff_activetime = cd;
 111         self.buff_active = !cd;
 112 }
 113
 114 void buff_Respawn(entity ent)
 115 {
 116         if(gameover) { return; }
 117
 118         vector oldbufforigin = ent.origin;
 119
 120         if(!MoveToRandomMapLocation(ent, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, ((autocvar_g_buffs_random_location_attempts > 0) ? autocvar_g_buffs_random_location_attempts : 10), 1024, 256))
 121         {
 122                 entity spot = SelectSpawnPoint(true);
 123                 setorigin(ent, ((spot.origin + '0 0 200') + (randomvec() * 300)));
 124                 ent.angles = spot.angles;
 125         }
 126
 127         tracebox(ent.origin, ent.mins * 1.5, self.maxs * 1.5, ent.origin, MOVE_NOMONSTERS, ent);
 128
 129         setorigin(ent, trace_endpos); // attempt to unstick
 130
 131         ent.movetype = MOVETYPE_TOSS;
 132
 133         makevectors(ent.angles);
 134         ent.velocity = '0 0 200';
 135         ent.angles = '0 0 0';
 136         if(autocvar_g_buffs_random_lifetime > 0)
 137                 ent.lifetime = time + autocvar_g_buffs_random_lifetime;
 138
 139         pointparticles(particleeffectnum("electro_combo"), oldbufforigin + ((ent.mins + ent.maxs) * 0.5), '0 0 0', 1);
 140         pointparticles(particleeffectnum("electro_combo"), CENTER_OR_VIEWOFS(ent), '0 0 0', 1);
 141
 142         WaypointSprite_Ping(ent.buff_waypoint);
 143
 144         sound(ent, CH_TRIGGER, "keepaway/respawn.wav", VOL_BASE, ATTEN_NONE); // ATTEN_NONE (it's a sound intended to be heard anywhere)
 145 }
 146
 147 void buff_Touch()
 148 {
 149         if(gameover) { return; }
 150
 151         if(ITEM_TOUCH_NEEDKILL())
 152         {
 153                 buff_Respawn(self);
 154                 return;
 155         }
 156
 157         if((self.team && DIFF_TEAM(other, self))
 158         || (other.frozen)
 159         || (other.vehicle)
 160         || (!IS_PLAYER(other))
 161         || (!self.buff_active)
 162         )
 163         {
 164                 // can't touch this
 165                 return;
 166         }
 167
 168         if (other.buffs)
 169         {
 170                 if (other.cvar_cl_buffs_autoreplace && other.buffs != self.buffs)
 171                 {
 172                         int buffid = buff_FirstFromFlags(other.buffs).m_id;
 173                         //Send_Notification(NOTIF_ONE, other, MSG_MULTI, ITEM_BUFF_DROP, other.buffs);
 174                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ITEM_BUFF_LOST, other.netname, buffid);
 175
 176                         other.buffs = 0;
 177                         //sound(other, CH_TRIGGER, "relics/relic_effect.wav", VOL_BASE, ATTN_NORM);
 178                 }
 179                 else { return; } // do nothing
 180         }
 181
 182         self.owner = other;
 183         self.buff_active = false;
 184         self.lifetime = 0;
 185         int buffid = buff_FirstFromFlags(self.buffs).m_id;
 186         Send_Notification(NOTIF_ONE, other, MSG_MULTI, ITEM_BUFF_GOT, buffid);
 187         Send_Notification(NOTIF_ALL_EXCEPT, other, MSG_INFO, INFO_ITEM_BUFF, other.netname, buffid);
 188
 189         pointparticles(particleeffectnum("item_pickup"), CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 190         sound(other, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);
 191         other.buffs |= (self.buffs);
 192 }
 193
 194 float buff_Available(entity buff)
 195 {
 196         if (buff == BUFF_NULL)
 197                 return false;
 198         if (buff == BUFF_AMMO && ((start_items & IT_UNLIMITED_WEAPON_AMMO) || (start_items & IT_UNLIMITED_AMMO) || (cvar("g_melee_only"))))
 199                 return false;
 200         if (buff == BUFF_VAMPIRE && cvar("g_vampire"))
 201                 return false;
 202         return cvar(strcat("g_buffs_", buff.m_name));
 203 }
 204
 205 .int buff_seencount;
 206
 207 void buff_NewType(entity ent, float cb)
 208 {
 209         RandomSelection_Init();
 210         FOREACH(BUFFS, 0, BUFFS_COUNT,
 211                 buff_Available(it),
 212                 LAMBDA({
 213                         it.buff_seencount += 1;
 214                         // if it's already been chosen, give it a lower priority
 215                         RandomSelection_Add(world, it.m_itemid, string_null, 1, max(0.2, 1 / it.buff_seencount));
 216                 })
 217         );
 218         ent.buffs = RandomSelection_chosen_float;
 219 }
 220
 221 void buff_Think()
 222 {
 223         if(self.buffs != self.oldbuffs)
 224         {
 225                 entity buff = buff_FirstFromFlags(self.buffs);
 226                 self.color = buff.m_color;
 227                 self.glowmod = buff_GlowColor(buff);
 228                 self.skin = buff.m_skin;
 229
 230                 setmodel(self, BUFF_MODEL);
 231
 232                 if(self.buff_waypoint)
 233                 {
 234                         //WaypointSprite_Disown(self.buff_waypoint, 1);
 235                         WaypointSprite_Kill(self.buff_waypoint);
 236                         buff_Waypoint_Spawn(self);
 237                         if(self.buff_activetime)
 238                                 WaypointSprite_UpdateBuildFinished(self.buff_waypoint, time + self.buff_activetime - frametime);
 239                 }
 240
 241                 self.oldbuffs = self.buffs;
 242         }
 243
 244         if(!gameover)
 245         if((round_handler_IsActive() && !round_handler_IsRoundStarted()) || time >= game_starttime)
 246         if(!self.buff_activetime_updated)
 247         {
 248                 buff_SetCooldown(self.buff_activetime);
 249                 self.buff_activetime_updated = true;
 250         }
 251
 252         if(!self.buff_active && !self.buff_activetime)
 253         if(!self.owner || self.owner.frozen || self.owner.deadflag != DEAD_NO || !self.owner.iscreature || !(self.owner.buffs & self.buffs))
 254         {
 255                 buff_SetCooldown(autocvar_g_buffs_cooldown_respawn + frametime);
 256                 self.owner = world;
 257                 if(autocvar_g_buffs_randomize)
 258                         buff_NewType(self, self.buffs);
 259
 260                 if(autocvar_g_buffs_random_location || (self.spawnflags & 64))
 261                         buff_Respawn(self);
 262         }
 263
 264         if(self.buff_activetime)
 265         if(!gameover)
 266         if((round_handler_IsActive() && !round_handler_IsRoundStarted()) || time >= game_starttime)
 267         {
 268                 self.buff_activetime = max(0, self.buff_activetime - frametime);
 269
 270                 if(!self.buff_activetime)
 271                 {
 272                         self.buff_active = true;
 273                         sound(self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);
 274                         pointparticles(particleeffectnum("item_respawn"), CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 275                 }
 276         }
 277
 278         if(self.buff_active)
 279         {
 280                 if(self.team && !self.buff_waypoint)
 281                         buff_Waypoint_Spawn(self);
 282
 283                 if(self.lifetime)
 284                 if(time >= self.lifetime)
 285                         buff_Respawn(self);
 286         }
 287
 288         self.nextthink = time;
 289         //self.angles_y = time * 110.1;
 290 }
 291
 292 void buff_Waypoint_Reset()
 293 {
 294         WaypointSprite_Kill(self.buff_waypoint);
 295
 296         if(self.buff_activetime) { buff_Waypoint_Spawn(self); }
 297 }
 298
 299 void buff_Reset()
 300 {
 301         if(autocvar_g_buffs_randomize)
 302                 buff_NewType(self, self.buffs);
 303         self.owner = world;
 304         buff_SetCooldown(autocvar_g_buffs_cooldown_activate);
 305         buff_Waypoint_Reset();
 306         self.buff_activetime_updated = false;
 307
 308         if(autocvar_g_buffs_random_location || (self.spawnflags & 64))
 309                 buff_Respawn(self);
 310 }
 311
 312 float buff_Customize()
 313 {
 314         entity player = WaypointSprite_getviewentity(other);
 315         if(!self.buff_active || (self.team && DIFF_TEAM(player, self)))
 316         {
 317                 self.alpha = 0.3;
 318                 if(self.effects & EF_FULLBRIGHT) { self.effects &= ~(EF_FULLBRIGHT); }
 319                 self.pflags = 0;
 320         }
 321         else
 322         {
 323                 self.alpha = 1;
 324                 if(!(self.effects & EF_FULLBRIGHT)) { self.effects |= EF_FULLBRIGHT; }
 325                 self.light_lev = 220 + 36 * sin(time);
 326                 self.pflags = PFLAGS_FULLDYNAMIC;
 327         }
 328         return true;
 329 }
 330
 331 void buff_Init(entity ent)
 332 {
 333         if(!cvar("g_buffs")) { remove(ent); return; }
 334
 335         if(!teamplay && ent.team) { ent.team = 0; }
 336
 337         entity buff = buff_FirstFromFlags(self.buffs);
 338
 339         entity oldself = self;
 340         self = ent;
 341         if(!self.buffs || buff_Available(buff))
 342                 buff_NewType(self, 0);
 343
 344         self.classname = "item_buff";
 345         self.solid = SOLID_TRIGGER;
 346         self.flags = FL_ITEM;
 347         self.think = buff_Think;
 348         self.touch = buff_Touch;
 349         self.reset = buff_Reset;
 350         self.nextthink = time + 0.1;
 351         self.gravity = 1;
 352         self.movetype = MOVETYPE_TOSS;
 353         self.scale = 1;
 354         self.skin = buff.m_skin;
 355         self.effects = EF_FULLBRIGHT | EF_STARDUST | EF_NOSHADOW;
 356         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 357         self.customizeentityforclient = buff_Customize;
 358         //self.gravity = 100;
 359         self.color = buff.m_color;
 360         self.glowmod = buff_GlowColor(self);
 361         buff_SetCooldown(autocvar_g_buffs_cooldown_activate + game_starttime);
 362         self.buff_active = !self.buff_activetime;
 363         self.pflags = PFLAGS_FULLDYNAMIC;
 364
 365         if(self.spawnflags & 1)
 366                 self.noalign = true;
 367
 368         if(self.noalign)
 369                 self.movetype = MOVETYPE_NONE; // reset by random location
 370
 371         setmodel(self, BUFF_MODEL);
 372         setsize(self, BUFF_MIN, BUFF_MAX);
 373
 374         if(cvar("g_buffs_random_location") || (self.spawnflags & 64))
 375                 buff_Respawn(self);
 376
 377         self = oldself;
 378 }
 379
 380 void buff_Init_Compat(entity ent, entity replacement)
 381 {
 382         if (ent.spawnflags & 2)
 383                 ent.team = NUM_TEAM_1;
 384         else if (ent.spawnflags & 4)
 385                 ent.team = NUM_TEAM_2;
 386
 387         ent.buffs = replacement.m_itemid;
 388
 389         buff_Init(ent);
 390 }
 391
 392 void buff_SpawnReplacement(entity ent, entity old)
 393 {
 394         setorigin(ent, old.origin);
 395         ent.angles = old.angles;
 396         ent.noalign = (old.noalign || (old.spawnflags & 1));
 397
 398         buff_Init(ent);
 399 }
 400
 401 void buff_Vengeance_DelayedDamage()
 402 {
 403         if(self.enemy)
 404                 Damage(self.enemy, self.owner, self.owner, self.dmg, DEATH_BUFF, self.enemy.origin, '0 0 0');
 405
 406         remove(self);
 407         return;
 408 }
 409
 410 float buff_Inferno_CalculateTime(float x, float offset_x, float offset_y, float intersect_x, float intersect_y, float base)
 411 {
 412         return offset_y + (intersect_y - offset_y) * logn(((x - offset_x) * ((base - 1) / intersect_x)) + 1, base);
 413 }
 414
 415 // mutator hooks
 416 MUTATOR_HOOKFUNCTION(buffs_PlayerDamage_SplitHealthArmor)
 417 {
 418         if(frag_deathtype == DEATH_BUFF) { return false; }
 419
 420         if(frag_target.buffs & BUFF_RESISTANCE.m_itemid)
 421         {
 422                 vector v = healtharmor_applydamage(50, autocvar_g_buffs_resistance_blockpercent, frag_deathtype, frag_damage);
 423                 damage_take = v.x;
 424                 damage_save = v.y;
 425         }
 426
 427         return false;
 428 }
 429
 430 MUTATOR_HOOKFUNCTION(buffs_PlayerDamage_Calculate)
 431 {
 432         if(frag_deathtype == DEATH_BUFF) { return false; }
 433
 434         if(frag_target.buffs & BUFF_SPEED.m_itemid)
 435         if(frag_target != frag_attacker)
 436                 frag_damage *= autocvar_g_buffs_speed_damage_take;
 437
 438         if(frag_target.buffs & BUFF_MEDIC.m_itemid)
 439         if((frag_target.health - frag_damage) <= 0)
 440         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 441         if(frag_attacker)
 442         if(random() <= autocvar_g_buffs_medic_survive_chance)
 443                 frag_damage = max(5, frag_target.health - autocvar_g_buffs_medic_survive_health);
 444
 445         if(frag_target.buffs & BUFF_JUMP.m_itemid)
 446         if(frag_deathtype == DEATH_FALL)
 447                 frag_damage = 0;
 448
 449         if(frag_target.buffs & BUFF_VENGEANCE.m_itemid)
 450         if(frag_attacker)
 451         if(frag_attacker != frag_target)
 452         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 453         {
 454                 entity dmgent = spawn();
 455
 456                 dmgent.dmg = frag_damage * autocvar_g_buffs_vengeance_damage_multiplier;
 457                 dmgent.enemy = frag_attacker;
 458                 dmgent.owner = frag_target;
 459                 dmgent.think = buff_Vengeance_DelayedDamage;
 460                 dmgent.nextthink = time + 0.1;
 461         }
 462
 463         if(frag_target.buffs & BUFF_BASH.m_itemid)
 464         if(frag_attacker != frag_target)
 465         if(vlen(frag_force))
 466                 frag_force = '0 0 0';
 467
 468         if(frag_attacker.buffs & BUFF_BASH.m_itemid)
 469         if(vlen(frag_force))
 470         if(frag_attacker == frag_target)
 471                 frag_force *= autocvar_g_buffs_bash_force_self;
 472         else
 473                 frag_force *= autocvar_g_buffs_bash_force;
 474
 475         if(frag_attacker.buffs & BUFF_DISABILITY.m_itemid)
 476         if(frag_target != frag_attacker)
 477                 frag_target.buff_disability_time = time + autocvar_g_buffs_disability_slowtime;
 478
 479         if(frag_attacker.buffs & BUFF_MEDIC.m_itemid)
 480         if(DEATH_WEAPONOF(frag_deathtype) != WEP_ARC)
 481         if(SAME_TEAM(frag_attacker, frag_target))
 482         if(frag_attacker != frag_target)
 483         {
 484                 frag_target.health = min(g_pickup_healthmega_max, frag_target.health + frag_damage);
 485                 frag_damage = 0;
 486         }
 487
 488         if(frag_attacker.buffs & BUFF_INFERNO.m_itemid)
 489         if(frag_target != frag_attacker) {
 490                 float time = buff_Inferno_CalculateTime(
 491                         frag_damage,
 492                         0,
 493                         autocvar_g_buffs_inferno_burntime_min_time,
 494                         autocvar_g_buffs_inferno_burntime_target_damage,
 495                         autocvar_g_buffs_inferno_burntime_target_time,
 496                         autocvar_g_buffs_inferno_burntime_factor
 497                 );
 498                 Fire_AddDamage(frag_target, frag_attacker, (frag_damage * autocvar_g_buffs_inferno_damagemultiplier) * time, time, DEATH_BUFF);
 499         }
 500
 501         // this... is ridiculous (TODO: fix!)
 502         if(frag_attacker.buffs & BUFF_VAMPIRE.m_itemid)
 503         if(!frag_target.vehicle)
 504         if(DEATH_WEAPONOF(frag_deathtype) != WEP_ARC)
 505         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 506         if(frag_target.deadflag == DEAD_NO)
 507         if(IS_PLAYER(frag_target) || (frag_target.flags & FL_MONSTER))
 508         if(frag_attacker != frag_target)
 509         if(!frag_target.frozen)
 510         if(frag_target.takedamage)
 511         if(DIFF_TEAM(frag_attacker, frag_target))
 512         {
 513                 frag_attacker.health = bound(0, frag_attacker.health + bound(0, frag_damage * autocvar_g_buffs_vampire_damage_steal, frag_target.health), g_pickup_healthsmall_max);
 514                 if(frag_target.armorvalue)
 515                         frag_attacker.armorvalue = bound(0, frag_attacker.armorvalue + bound(0, frag_damage * autocvar_g_buffs_vampire_damage_steal, frag_target.armorvalue), g_pickup_armorsmall_max);
 516         }
 517
 518         return false;
 519 }
 520
 521 MUTATOR_HOOKFUNCTION(buffs_PlayerSpawn)
 522 {
 523         self.buffs = 0;
 524         // reset timers here to prevent them continuing after re-spawn
 525         self.buff_disability_time = 0;
 526         self.buff_disability_effect_time = 0;
 527         return false;
 528 }
 529
 530 MUTATOR_HOOKFUNCTION(buffs_PlayerPhysics)
 531 {
 532         if(self.buffs & BUFF_SPEED.m_itemid)
 533         {
 534                 self.stat_sv_maxspeed *= autocvar_g_buffs_speed_speed;
 535                 self.stat_sv_airspeedlimit_nonqw *= autocvar_g_buffs_speed_speed;
 536         }
 537
 538         if(time < self.buff_disability_time)
 539         {
 540                 self.stat_sv_maxspeed *= autocvar_g_buffs_disability_speed;
 541                 self.stat_sv_airspeedlimit_nonqw *= autocvar_g_buffs_disability_speed;
 542         }
 543
 544         if(self.buffs & BUFF_JUMP.m_itemid)
 545         {
 546                 // automatically reset, no need to worry
 547                 self.stat_sv_jumpvelocity = autocvar_g_buffs_jump_height;
 548         }
 549
 550         return false;
 551 }
 552
 553 MUTATOR_HOOKFUNCTION(buffs_PlayerJump)
 554 {
 555         if(self.buffs & BUFF_JUMP.m_itemid)
 556                 player_jumpheight = autocvar_g_buffs_jump_height;
 557
 558         return false;
 559 }
 560
 561 MUTATOR_HOOKFUNCTION(buffs_MonsterMove)
 562 {
 563         if(time < self.buff_disability_time)
 564         {
 565                 monster_speed_walk *= autocvar_g_buffs_disability_speed;
 566                 monster_speed_run *= autocvar_g_buffs_disability_speed;
 567         }
 568
 569         return false;
 570 }
 571
 572 MUTATOR_HOOKFUNCTION(buffs_PlayerDies)
 573 {
 574         if(self.buffs)
 575         {
 576                 int buffid = buff_FirstFromFlags(self.buffs).m_id;
 577                 Send_Notification(NOTIF_ALL_EXCEPT, self, MSG_INFO, INFO_ITEM_BUFF_LOST, self.netname, buffid);
 578                 self.buffs = 0;
 579
 580                 if(self.buff_model)
 581                 {
 582                         remove(self.buff_model);
 583                         self.buff_model = world;
 584                 }
 585         }
 586         return false;
 587 }
 588
 589 MUTATOR_HOOKFUNCTION(buffs_PlayerUseKey)
 590 {
 591         if(MUTATOR_RETURNVALUE || gameover) { return false; }
 592         if(self.buffs)
 593         {
 594                 int buffid = buff_FirstFromFlags(self.buffs).m_id;
 595                 Send_Notification(NOTIF_ONE, self, MSG_MULTI, ITEM_BUFF_DROP, buffid);
 596                 Send_Notification(NOTIF_ALL_EXCEPT, self, MSG_INFO, INFO_ITEM_BUFF_LOST, self.netname, buffid);
 597
 598                 self.buffs = 0;
 599                 sound(self, CH_TRIGGER, "relics/relic_effect.wav", VOL_BASE, ATTN_NORM);
 600                 return true;
 601         }
 602         return false;
 603 }
 604
 605 MUTATOR_HOOKFUNCTION(buffs_PlayerThrowKey)
 606 {
 607         if(MUTATOR_RETURNVALUE || gameover) { return false; }
 608
 609         if(self.buffs & BUFF_SWAPPER.m_itemid)
 610         {
 611                 float best_distance = autocvar_g_buffs_swapper_range;
 612                 entity closest = world;
 613                 entity player;
 614                 FOR_EACH_PLAYER(player)
 615                 if(DIFF_TEAM(self, player))
 616                 if(player.deadflag == DEAD_NO && !player.frozen && !player.vehicle)
 617                 if(vlen(self.origin - player.origin) <= best_distance)
 618                 {
 619                         best_distance = vlen(self.origin - player.origin);
 620                         closest = player;
 621                 }
 622
 623                 if(closest)
 624                 {
 625                         vector my_org, my_vel, my_ang, their_org, their_vel, their_ang;
 626
 627                         my_org = self.origin;
 628                         my_vel = self.velocity;
 629                         my_ang = self.angles;
 630                         their_org = closest.origin;
 631                         their_vel = closest.velocity;
 632                         their_ang = closest.angles;
 633
 634                         if(closest.ballcarried)
 635                         if(g_keepaway) { ka_DropEvent(closest); }
 636                         else { DropBall(closest.ballcarried, closest.origin, closest.velocity);}
 637                         if(closest.flagcarried) { ctf_Handle_Throw(closest, world, DROP_THROW); }
 638                         if(closest.nade) { toss_nade(closest, '0 0 0', time + 0.05); }
 639
 640                         MUTATOR_CALLHOOK(PortalTeleport); // initiate flag dropper
 641
 642                         setorigin(self, their_org);
 643                         setorigin(closest, my_org);
 644
 645                         closest.velocity = my_vel;
 646                         closest.angles = my_ang;
 647                         closest.fixangle = true;
 648                         closest.oldorigin = my_org;
 649                         closest.oldvelocity = my_vel;
 650                         self.velocity = their_vel;
 651                         self.angles = their_ang;
 652                         self.fixangle = true;
 653                         self.oldorigin = their_org;
 654                         self.oldvelocity = their_vel;
 655
 656                         // set pusher so self gets the kill if they fall into void
 657                         closest.pusher = self;
 658                         closest.pushltime = time + autocvar_g_maxpushtime;
 659                         closest.istypefrag = closest.BUTTON_CHAT;
 660
 661                         pointparticles(particleeffectnum("electro_combo"), their_org, '0 0 0', 1);
 662                         pointparticles(particleeffectnum("electro_combo"), my_org, '0 0 0', 1);
 663
 664                         sound(self, CH_TRIGGER, "keepaway/respawn.wav", VOL_BASE, ATTEN_NORM);
 665                         sound(closest, CH_TRIGGER, "keepaway/respawn.wav", VOL_BASE, ATTEN_NORM);
 666
 667                         // TODO: add a counter to handle how many times one can teleport, and a delay to prevent spam
 668                         self.buffs = 0;
 669                         return true;
 670                 }
 671         }
 672         return false;
 673 }
 674
 675 MUTATOR_HOOKFUNCTION(buffs_RemovePlayer)
 676 {
 677         if(self.buff_model)
 678         {
 679                 remove(self.buff_model);
 680                 self.buff_model = world;
 681         }
 682
 683         // also reset timers here to prevent them continuing after spectating
 684         self.buff_disability_time = 0;
 685         self.buff_disability_effect_time = 0;
 686
 687         return false;
 688 }
 689
 690 MUTATOR_HOOKFUNCTION(buffs_CustomizeWaypoint)
 691 {
 692         entity e = WaypointSprite_getviewentity(other);
 693
 694         // if you have the invisibility powerup, sprites ALWAYS are restricted to your team
 695         // but only apply this to real players, not to spectators
 696         if((self.owner.flags & FL_CLIENT) && (self.owner.buffs & BUFF_INVISIBLE.m_itemid) && (e == other))
 697         if(DIFF_TEAM(self.owner, e))
 698                 return true;
 699
 700         return false;
 701 }
 702
 703 MUTATOR_HOOKFUNCTION(buffs_OnEntityPreSpawn)
 704 {
 705         if(autocvar_g_buffs_replace_powerups)
 706         switch(self.classname)
 707         {
 708                 case "item_strength":
 709                 case "item_invincible":
 710                 {
 711                         entity e = spawn();
 712                         buff_SpawnReplacement(e, self);
 713                         return true;
 714                 }
 715         }
 716         return false;
 717 }
 718
 719 MUTATOR_HOOKFUNCTION(buffs_WeaponRate)
 720 {
 721         if(self.buffs & BUFF_SPEED.m_itemid)
 722                 weapon_rate *= autocvar_g_buffs_speed_rate;
 723
 724         if(time < self.buff_disability_time)
 725                 weapon_rate *= autocvar_g_buffs_disability_rate;
 726
 727         return false;
 728 }
 729
 730 MUTATOR_HOOKFUNCTION(buffs_WeaponSpeed)
 731 {
 732         if(self.buffs & BUFF_SPEED.m_itemid)
 733                 ret_float *= autocvar_g_buffs_speed_weaponspeed;
 734
 735         if(time < self.buff_disability_time)
 736                 ret_float *= autocvar_g_buffs_disability_weaponspeed;
 737
 738         return false;
 739 }
 740
 741 .float buff_time;
 742
 743 MUTATOR_HOOKFUNCTION(buffs_PlayerThink)
 744 {
 745         if(gameover || self.deadflag != DEAD_NO) { return false; }
 746
 747         if(time < self.buff_disability_time)
 748         if(time >= self.buff_disability_effect_time)
 749         {
 750                 pointparticles(particleeffectnum("smoking"), self.origin + ((self.mins + self.maxs) * 0.5), '0 0 0', 1);
 751                 self.buff_disability_effect_time = time + 0.5;
 752         }
 753
 754         // handle buff lost status
 755         // 1: notify everyone else
 756         // 2: notify carrier as well
 757         int buff_lost = 0;
 758
 759         if(self.buff_time)
 760         if(time >= self.buff_time)
 761                 buff_lost = 2;
 762
 763         if(self.frozen) { buff_lost = 1; }
 764
 765         if(buff_lost)
 766         {
 767                 if(self.buffs)
 768                 {
 769                         int buffid = buff_FirstFromFlags(self.buffs).m_id;
 770                         Send_Notification(NOTIF_ALL_EXCEPT, self, MSG_INFO, INFO_ITEM_BUFF_LOST, self.netname, buffid);
 771                         if(buff_lost >= 2)
 772                         {
 773                                 Send_Notification(NOTIF_ONE, self, MSG_MULTI, ITEM_BUFF_DROP, buffid); // TODO: special timeout message?
 774                                 sound(self, CH_TRIGGER, "relics/relic_effect.wav", VOL_BASE, ATTN_NORM);
 775                         }
 776                         self.buffs = 0;
 777                 }
 778         }
 779
 780         if(self.buffs & BUFF_MAGNET.m_itemid)
 781         {
 782                 vector pickup_size = '1 1 1' * autocvar_g_buffs_magnet_range_item;
 783                 for(other = world; (other = findflags(other, flags, FL_ITEM)); )
 784                 if(boxesoverlap(self.absmin - pickup_size, self.absmax + pickup_size, other.absmin, other.absmax))
 785                 {
 786                         entity oldself = self;
 787                         self = other;
 788                         other = oldself;
 789                         if(self.touch)
 790                                 self.touch();
 791                         other = self;
 792                         self = oldself;
 793                 }
 794         }
 795
 796         if(self.buffs & BUFF_AMMO.m_itemid)
 797         if(self.clip_size)
 798                 self.clip_load = self.(weapon_load[self.switchweapon]) = self.clip_size;
 799
 800         if((self.buffs & BUFF_INVISIBLE.m_itemid) && (self.oldbuffs & BUFF_INVISIBLE.m_itemid))
 801         if(self.alpha != autocvar_g_buffs_invisible_alpha)
 802                 self.alpha = autocvar_g_buffs_invisible_alpha; // powerups reset alpha, so we must enforce this (TODO)
 803
 804 #define BUFF_ONADD(b) if ( (self.buffs & (b).m_itemid) && !(self.oldbuffs & (b).m_itemid))
 805 #define BUFF_ONREM(b) if (!(self.buffs & (b).m_itemid) &&  (self.oldbuffs & (b).m_itemid))
 806
 807         if(self.buffs != self.oldbuffs)
 808         {
 809                 entity buff = buff_FirstFromFlags(self.buffs);
 810                 float bufftime = buff != BUFF_NULL ? buff.m_time(buff) : 0;
 811                 self.buff_time = (bufftime) ? time + bufftime : 0;
 812
 813                 BUFF_ONADD(BUFF_AMMO)
 814                 {
 815                         self.buff_ammo_prev_infitems = (self.items & IT_UNLIMITED_WEAPON_AMMO);
 816                         self.items |= IT_UNLIMITED_WEAPON_AMMO;
 817
 818                         if(self.clip_load)
 819                                 self.buff_ammo_prev_clipload = self.clip_load;
 820                         self.clip_load = self.(weapon_load[self.switchweapon]) = self.clip_size;
 821                 }
 822
 823                 BUFF_ONREM(BUFF_AMMO)
 824                 {
 825                         if(self.buff_ammo_prev_infitems)
 826                                 self.items |= IT_UNLIMITED_WEAPON_AMMO;
 827                         else
 828                                 self.items &= ~IT_UNLIMITED_WEAPON_AMMO;
 829
 830                         if(self.buff_ammo_prev_clipload)
 831                                 self.clip_load = self.buff_ammo_prev_clipload;
 832                 }
 833
 834                 BUFF_ONADD(BUFF_INVISIBLE)
 835                 {
 836                         if(time < self.strength_finished && g_instagib)
 837                                 self.alpha = autocvar_g_instagib_invis_alpha;
 838                         else
 839                                 self.alpha = self.buff_invisible_prev_alpha;
 840                         self.alpha = autocvar_g_buffs_invisible_alpha;
 841                 }
 842
 843                 BUFF_ONREM(BUFF_INVISIBLE)
 844                         self.alpha = self.buff_invisible_prev_alpha;
 845
 846                 BUFF_ONADD(BUFF_FLIGHT)
 847                 {
 848                         self.buff_flight_prev_gravity = self.gravity;
 849                         self.gravity = autocvar_g_buffs_flight_gravity;
 850                 }
 851
 852                 BUFF_ONREM(BUFF_FLIGHT)
 853                         self.gravity = self.buff_flight_prev_gravity;
 854
 855                 self.oldbuffs = self.buffs;
 856                 if(self.buffs)
 857                 {
 858                         if(!self.buff_model)
 859                                 buffs_BuffModel_Spawn(self);
 860
 861                         self.buff_model.color = buff.m_color;
 862                         self.buff_model.glowmod = buff_GlowColor(self.buff_model);
 863                         self.buff_model.skin = buff.m_skin;
 864
 865                         self.effects |= EF_NOSHADOW;
 866                 }
 867                 else
 868                 {
 869                         remove(self.buff_model);
 870                         self.buff_model = world;
 871
 872                         self.effects &= ~(EF_NOSHADOW);
 873                 }
 874         }
 875
 876         if(self.buff_model)
 877         {
 878                 self.buff_model.effects = self.effects;
 879                 self.buff_model.effects |= EF_LOWPRECISION;
 880                 self.buff_model.effects = self.buff_model.effects & EFMASK_CHEAP; // eat performance
 881
 882                 self.buff_model.alpha = self.alpha;
 883         }
 884
 885 #undef BUFF_ONADD
 886 #undef BUFF_ONREM
 887         return false;
 888 }
 889
 890 MUTATOR_HOOKFUNCTION(buffs_SpectateCopy)
 891 {
 892         self.buffs = other.buffs;
 893         return false;
 894 }
 895
 896 MUTATOR_HOOKFUNCTION(buffs_VehicleEnter)
 897 {
 898         vh_vehicle.buffs = vh_player.buffs;
 899         vh_player.buffs = 0;
 900         return false;
 901 }
 902
 903 MUTATOR_HOOKFUNCTION(buffs_VehicleExit)
 904 {
 905         vh_player.buffs = vh_vehicle.buffs;
 906         vh_vehicle.buffs = 0;
 907         return false;
 908 }
 909
 910 MUTATOR_HOOKFUNCTION(buffs_PlayerRegen)
 911 {
 912         if(self.buffs & BUFF_MEDIC.m_itemid)
 913         {
 914                 regen_mod_rot = autocvar_g_buffs_medic_rot;
 915                 regen_mod_limit = regen_mod_max = autocvar_g_buffs_medic_max;
 916                 regen_mod_regen = autocvar_g_buffs_medic_regen;
 917         }
 918
 919         if(self.buffs & BUFF_SPEED.m_itemid)
 920                 regen_mod_regen = autocvar_g_buffs_speed_regen;
 921
 922         return false;
 923 }
 924
 925 MUTATOR_HOOKFUNCTION(buffs_GetCvars)
 926 {
 927         GetCvars_handleFloat(get_cvars_s, get_cvars_f, cvar_cl_buffs_autoreplace, "cl_buffs_autoreplace");
 928         return false;
 929 }
 930
 931 MUTATOR_HOOKFUNCTION(buffs_BuildMutatorsString)
 932 {
 933         ret_string = strcat(ret_string, ":Buffs");
 934         return false;
 935 }
 936
 937 MUTATOR_HOOKFUNCTION(buffs_BuildMutatorsPrettyString)
 938 {
 939         ret_string = strcat(ret_string, ", Buffs");
 940         return false;
 941 }
 942
 943 void buffs_DelayedInit()
 944 {
 945         if(autocvar_g_buffs_spawn_count > 0)
 946         if(find(world, classname, "item_buff") == world)
 947         {
 948                 float i;
 949                 for(i = 0; i < autocvar_g_buffs_spawn_count; ++i)
 950                 {
 951                         entity e = spawn();
 952                         e.spawnflags |= 64; // always randomize
 953                         e.velocity = randomvec() * 250; // this gets reset anyway if random location works
 954                         buff_Init(e);
 955                 }
 956         }
 957 }
 958
 959 void buffs_Initialize()
 960 {
 961         precache_model(BUFF_MODEL);
 962         precache_sound("misc/strength_respawn.wav");
 963         precache_sound("misc/shield_respawn.wav");
 964         precache_sound("relics/relic_effect.wav");
 965         precache_sound("weapons/rocket_impact.wav");
 966         precache_sound("keepaway/respawn.wav");
 967
 968         addstat(STAT_BUFFS, AS_INT, buffs);
 969         addstat(STAT_BUFF_TIME, AS_FLOAT, buff_time);
 970
 971         InitializeEntity(world, buffs_DelayedInit, INITPRIO_FINDTARGET);
 972 }
 973
 974 MUTATOR_DEFINITION(mutator_buffs)
 975 {
 976         MUTATOR_HOOK(PlayerDamage_SplitHealthArmor, buffs_PlayerDamage_SplitHealthArmor, CBC_ORDER_ANY);
 977         MUTATOR_HOOK(PlayerDamage_Calculate, buffs_PlayerDamage_Calculate, CBC_ORDER_ANY);
 978         MUTATOR_HOOK(PlayerSpawn, buffs_PlayerSpawn, CBC_ORDER_ANY);
 979         MUTATOR_HOOK(PlayerPhysics, buffs_PlayerPhysics, CBC_ORDER_ANY);
 980         MUTATOR_HOOK(PlayerJump, buffs_PlayerJump, CBC_ORDER_ANY);
 981         MUTATOR_HOOK(MonsterMove, buffs_MonsterMove, CBC_ORDER_ANY);
 982         MUTATOR_HOOK(SpectateCopy, buffs_SpectateCopy, CBC_ORDER_ANY);
 983         MUTATOR_HOOK(VehicleEnter, buffs_VehicleEnter, CBC_ORDER_ANY);
 984         MUTATOR_HOOK(VehicleExit, buffs_VehicleExit, CBC_ORDER_ANY);
 985         MUTATOR_HOOK(PlayerRegen, buffs_PlayerRegen, CBC_ORDER_ANY);
 986         MUTATOR_HOOK(PlayerDies, buffs_PlayerDies, CBC_ORDER_ANY);
 987         MUTATOR_HOOK(PlayerUseKey, buffs_PlayerUseKey, CBC_ORDER_FIRST);
 988         MUTATOR_HOOK(ForbidThrowCurrentWeapon, buffs_PlayerThrowKey, CBC_ORDER_ANY);
 989         MUTATOR_HOOK(MakePlayerObserver, buffs_RemovePlayer, CBC_ORDER_ANY);
 990         MUTATOR_HOOK(ClientDisconnect, buffs_RemovePlayer, CBC_ORDER_ANY);
 991         MUTATOR_HOOK(OnEntityPreSpawn, buffs_OnEntityPreSpawn, CBC_ORDER_LAST);
 992         MUTATOR_HOOK(CustomizeWaypoint, buffs_CustomizeWaypoint, CBC_ORDER_ANY);
 993         MUTATOR_HOOK(WeaponRateFactor, buffs_WeaponRate, CBC_ORDER_ANY);
 994         MUTATOR_HOOK(WeaponSpeedFactor, buffs_WeaponSpeed, CBC_ORDER_ANY);
 995         MUTATOR_HOOK(PlayerPreThink, buffs_PlayerThink, CBC_ORDER_ANY);
 996         MUTATOR_HOOK(GetCvars, buffs_GetCvars, CBC_ORDER_ANY);
 997         MUTATOR_HOOK(BuildMutatorsString, buffs_BuildMutatorsString, CBC_ORDER_ANY);
 998         MUTATOR_HOOK(BuildMutatorsPrettyString, buffs_BuildMutatorsPrettyString, CBC_ORDER_ANY);
 999
1000         MUTATOR_ONADD
1001         {
1002                 buffs_Initialize();
1003         }
1004
1005         return false;
1006 }