qcsrc/server/mutators/mutator/mutator_overkill.qc

   1 #ifdef IMPLEMENTATION
   2 .vector ok_deathloc;
   3 .float ok_spawnsys_timer;
   4 .float ok_lastwep;
   5 .float ok_item;
   6
   7 .float ok_notice_time;
   8 .float ammo_charge[Weapons_MAX];
   9 .float ok_use_ammocharge;
  10 .float ok_ammo_charge;
  11
  12 .float ok_pauseregen_finished;
  13
  14 void(entity ent, float wep) ok_DecreaseCharge;
  15
  16 void ok_Initialize();
  17
  18 REGISTER_MUTATOR(ok, cvar("g_overkill") && !cvar("g_instagib") && !g_nexball && cvar_string("g_mod_balance") == "Overkill")
  19 {
  20         MUTATOR_ONADD
  21         {
  22                 ok_Initialize();
  23         }
  24
  25         MUTATOR_ONREMOVE
  26         {
  27                 WEP_RPC.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
  28                 WEP_HMG.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
  29         }
  30
  31         return false;
  32 }
  33
  34 void W_Blaster_Attack(entity, float, float, float, float, float, float, float, float, float, float);
  35 spawnfunc(weapon_hmg);
  36 spawnfunc(weapon_rpc);
  37
  38 void ok_DecreaseCharge(entity ent, int wep)
  39 {
  40         if(!ent.ok_use_ammocharge) return;
  41
  42         entity wepent = get_weaponinfo(wep);
  43
  44         if(wepent.weapon == 0)
  45                 return; // dummy
  46
  47         ent.ammo_charge[wep] -= max(0, cvar(sprintf("g_overkill_ammo_decharge_%s", wepent.netname)));
  48 }
  49
  50 void ok_IncreaseCharge(entity ent, int wep)
  51 {
  52         entity wepent = get_weaponinfo(wep);
  53
  54         if(wepent.weapon == 0)
  55                 return; // dummy
  56
  57         if(ent.ok_use_ammocharge)
  58         if(!ent.BUTTON_ATCK) // not while attacking?
  59                 ent.ammo_charge[wep] = min(autocvar_g_overkill_ammo_charge_limit, ent.ammo_charge[wep] + cvar(sprintf("g_overkill_ammo_charge_rate_%s", wepent.netname)) * frametime / W_TICSPERFRAME);
  60 }
  61
  62 float ok_CheckWeaponCharge(entity ent, int wep)
  63 {
  64         if(!ent.ok_use_ammocharge) return true;
  65
  66         entity wepent = get_weaponinfo(wep);
  67
  68         if(wepent.weapon == 0)
  69                 return 0; // dummy
  70
  71         return (ent.ammo_charge[wep] >= cvar(sprintf("g_overkill_ammo_decharge_%s", wepent.netname)));
  72 }
  73
  74 MUTATOR_HOOKFUNCTION(ok, PlayerDamage_Calculate, CBC_ORDER_LAST)
  75 {
  76         if(IS_PLAYER(frag_attacker) && IS_PLAYER(frag_target))
  77         if(DEATH_ISWEAPON(frag_deathtype, WEP_BLASTER))
  78         {
  79                 frag_damage = 0;
  80
  81                 if(frag_attacker != frag_target)
  82                 if(frag_target.health > 0)
  83                 if(frag_target.frozen == 0)
  84                 if(frag_target.deadflag == DEAD_NO)
  85                 {
  86                         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_SECONDARY_NODAMAGE);
  87                         frag_force = '0 0 0';
  88                 }
  89         }
  90
  91         return false;
  92 }
  93
  94 MUTATOR_HOOKFUNCTION(ok, PlayerDamage_SplitHealthArmor)
  95 {SELFPARAM();
  96         if(damage_take)
  97                 self.ok_pauseregen_finished = max(self.ok_pauseregen_finished, time + 2);
  98         return false;
  99 }
 100
 101 MUTATOR_HOOKFUNCTION(ok, PlayerDies)
 102 {SELFPARAM();
 103         entity targ = ((frag_attacker) ? frag_attacker : frag_target);
 104
 105         if(IS_MONSTER(self))
 106         {
 107                 remove(other); // remove default item
 108                 other = world;
 109         }
 110
 111         setself(new(droppedweapon)); // hax
 112         self.ok_item = true;
 113         self.noalign = true;
 114         self.pickup_anyway = true;
 115         spawnfunc_item_armor_small(this);
 116         self.movetype = MOVETYPE_TOSS;
 117         self.gravity = 1;
 118         self.reset = SUB_Remove;
 119         setorigin(self, frag_target.origin + '0 0 32');
 120         self.velocity = '0 0 200' + normalize(targ.origin - self.origin) * 500;
 121         SUB_SetFade(self, time + 5, 1);
 122         setself(this);
 123
 124         self.ok_lastwep = self.switchweapon;
 125
 126         return false;
 127 }
 128 MUTATOR_HOOKFUNCTION(ok, MonsterDropItem) { ok_PlayerDies(); }
 129
 130 MUTATOR_HOOKFUNCTION(ok, PlayerRegen)
 131 {SELFPARAM();
 132         // overkill's values are different, so use custom regen
 133         if(!self.frozen)
 134         {
 135                 self.armorvalue = CalcRotRegen(self.armorvalue, autocvar_g_balance_armor_regenstable, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, 1 * frametime * (time > self.ok_pauseregen_finished), 0, 0, 1, 1 * frametime * (time > self.pauserotarmor_finished), autocvar_g_balance_armor_limit);
 136                 self.health = CalcRotRegen(self.health, autocvar_g_balance_health_regenstable, 0, 100, 1 * frametime * (time > self.ok_pauseregen_finished), 200, 0, autocvar_g_balance_health_rotlinear, 1 * frametime * (time > self.pauserothealth_finished), autocvar_g_balance_health_limit);
 137
 138                 float minf, maxf, limitf;
 139
 140                 maxf = autocvar_g_balance_fuel_rotstable;
 141                 minf = autocvar_g_balance_fuel_regenstable;
 142                 limitf = autocvar_g_balance_fuel_limit;
 143
 144                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
 145         }
 146         return true; // return true anyway, as frozen uses no regen
 147 }
 148
 149 MUTATOR_HOOKFUNCTION(ok, ForbidThrowCurrentWeapon)
 150 {
 151         return true;
 152 }
 153
 154 MUTATOR_HOOKFUNCTION(ok, PlayerPreThink)
 155 {SELFPARAM();
 156         if(intermission_running || gameover)
 157                 return false;
 158
 159         if(self.deadflag != DEAD_NO || !IS_PLAYER(self) || self.frozen)
 160                 return false;
 161
 162         if(self.ok_lastwep)
 163         {
 164                 self.switchweapon = self.ok_lastwep;
 165                 self.ok_lastwep = 0;
 166         }
 167
 168         ok_IncreaseCharge(self, self.weapon);
 169
 170         if(self.BUTTON_ATCK2)
 171         if(!forbidWeaponUse(self) || self.weapon_blocked) // allow if weapon is blocked
 172         if(time >= self.jump_interval)
 173         {
 174                 self.jump_interval = time + WEP_CVAR_PRI(blaster, refire) * W_WeaponRateFactor();
 175                 makevectors(self.v_angle);
 176
 177                 int oldwep = self.weapon;
 178                 self.weapon = WEP_BLASTER.m_id;
 179                 W_Blaster_Attack(
 180                         self,
 181                         WEP_BLASTER.m_id | HITTYPE_SECONDARY,
 182                         WEP_CVAR_SEC(vaporizer, shotangle),
 183                         WEP_CVAR_SEC(vaporizer, damage),
 184                         WEP_CVAR_SEC(vaporizer, edgedamage),
 185                         WEP_CVAR_SEC(vaporizer, radius),
 186                         WEP_CVAR_SEC(vaporizer, force),
 187                         WEP_CVAR_SEC(vaporizer, speed),
 188                         WEP_CVAR_SEC(vaporizer, spread),
 189                         WEP_CVAR_SEC(vaporizer, delay),
 190                         WEP_CVAR_SEC(vaporizer, lifetime)
 191                 );
 192                 self.weapon = oldwep;
 193         }
 194
 195         self.weapon_blocked = false;
 196
 197         self.ok_ammo_charge = self.ammo_charge[self.weapon];
 198
 199         if(self.ok_use_ammocharge)
 200         if(!ok_CheckWeaponCharge(self, self.weapon))
 201         {
 202                 if(autocvar_g_overkill_ammo_charge_notice && time > self.ok_notice_time && self.BUTTON_ATCK && IS_REAL_CLIENT(self) && self.weapon == self.switchweapon)
 203                 {
 204                         //Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_OVERKILL_CHARGE);
 205                         self.ok_notice_time = time + 2;
 206                         play2(self, SND(DRYFIRE));
 207                 }
 208                 Weapon wpn = get_weaponinfo(self.weapon);
 209                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 210                 if(self.(weaponentity).state != WS_CLEAR)
 211                         w_ready(wpn, self, weaponentity, (self.BUTTON_ATCK ? 1 : 0) | (self.BUTTON_ATCK2 ? 2 : 0));
 212
 213                 self.weapon_blocked = true;
 214         }
 215
 216         self.BUTTON_ATCK2 = 0;
 217
 218         return false;
 219 }
 220
 221 MUTATOR_HOOKFUNCTION(ok, PlayerSpawn)
 222 {SELFPARAM();
 223         if(autocvar_g_overkill_ammo_charge)
 224         {
 225                 for(int i = WEP_FIRST; i <= WEP_LAST; ++i)
 226                         self.ammo_charge[i] = autocvar_g_overkill_ammo_charge_limit;
 227
 228                 self.ok_use_ammocharge = 1;
 229                 self.ok_notice_time = time;
 230         }
 231         else
 232                 self.ok_use_ammocharge = 0;
 233
 234         self.ok_pauseregen_finished = time + 2;
 235
 236         return false;
 237 }
 238
 239 void _spawnfunc_weapon_hmg() { SELFPARAM(); spawnfunc_weapon_hmg(this); }
 240 void _spawnfunc_weapon_rpc() { SELFPARAM(); spawnfunc_weapon_rpc(this); }
 241
 242 MUTATOR_HOOKFUNCTION(ok, OnEntityPreSpawn)
 243 {SELFPARAM();
 244         if(autocvar_g_powerups)
 245         if(autocvar_g_overkill_powerups_replace)
 246         {
 247                 if(self.classname == "item_strength")
 248                 {
 249                         entity wep = new(weapon_hmg);
 250                         setorigin(wep, self.origin);
 251                         setmodel(wep, MDL_OK_HMG);
 252                         wep.ok_item = true;
 253                         wep.noalign = self.noalign;
 254                         wep.cnt = self.cnt;
 255                         wep.team = self.team;
 256                         wep.respawntime = autocvar_g_overkill_superguns_respawn_time;
 257                         wep.pickup_anyway = true;
 258                         wep.think = _spawnfunc_weapon_hmg;
 259                         wep.nextthink = time + 0.1;
 260                         return true;
 261                 }
 262
 263                 if(self.classname == "item_invincible")
 264                 {
 265                         entity wep = new(weapon_rpc);
 266                         setorigin(wep, self.origin);
 267                         setmodel(wep, MDL_OK_RPC);
 268                         wep.ok_item = true;
 269                         wep.noalign = self.noalign;
 270                         wep.cnt = self.cnt;
 271                         wep.team = self.team;
 272                         wep.respawntime = autocvar_g_overkill_superguns_respawn_time;
 273                         wep.pickup_anyway = true;
 274                         wep.think = _spawnfunc_weapon_rpc;
 275                         wep.nextthink = time + 0.1;
 276                         return true;
 277                 }
 278         }
 279
 280         return false;
 281 }
 282
 283 MUTATOR_HOOKFUNCTION(ok, FilterItem)
 284 {SELFPARAM();
 285         if(self.ok_item)
 286                 return false;
 287
 288         switch(self.items)
 289         {
 290                 case ITEM_HealthMega.m_itemid: return !(autocvar_g_overkill_100h_anyway);
 291                 case ITEM_ArmorMega.m_itemid: return !(autocvar_g_overkill_100a_anyway);
 292         }
 293
 294         return true;
 295 }
 296
 297 MUTATOR_HOOKFUNCTION(ok, SpectateCopy)
 298 {SELFPARAM();
 299         self.ammo_charge[self.weapon] = other.ammo_charge[other.weapon];
 300         self.ok_use_ammocharge = other.ok_use_ammocharge;
 301
 302         return false;
 303 }
 304
 305 MUTATOR_HOOKFUNCTION(ok, SetStartItems)
 306 {
 307         WepSet ok_start_items = (WEPSET(MACHINEGUN) | WEPSET(VORTEX) | WEPSET(SHOTGUN));
 308
 309         if(WEP_RPC.weaponstart > 0) { ok_start_items |= WEPSET(RPC); }
 310         if(WEP_HMG.weaponstart > 0) { ok_start_items |= WEPSET(HMG); }
 311
 312         start_items |= IT_UNLIMITED_WEAPON_AMMO;
 313         start_weapons = warmup_start_weapons = ok_start_items;
 314
 315         return false;
 316 }
 317
 318 MUTATOR_HOOKFUNCTION(ok, BuildMutatorsString)
 319 {
 320         ret_string = strcat(ret_string, ":OK");
 321         return false;
 322 }
 323
 324 MUTATOR_HOOKFUNCTION(ok, BuildMutatorsPrettyString)
 325 {
 326         ret_string = strcat(ret_string, ", Overkill");
 327         return false;
 328 }
 329
 330 MUTATOR_HOOKFUNCTION(ok, SetModname)
 331 {
 332         modname = "Overkill";
 333         return true;
 334 }
 335
 336 void ok_SetCvars()
 337 {
 338         // hack to force overkill playermodels
 339         cvar_settemp("sv_defaultcharacter", "1");
 340         cvar_settemp("sv_defaultplayermodel", "models/ok_player/okrobot1.dpm models/ok_player/okrobot2.dpm models/ok_player/okrobot3.dpm models/ok_player/okrobot4.dpm models/ok_player/okmale1.dpm models/ok_player/okmale2.dpm models/ok_player/okmale3.dpm models/ok_player/okmale4.dpm");
 341         cvar_settemp("sv_defaultplayermodel_red", "models/ok_player/okrobot1.dpm models/ok_player/okrobot2.dpm models/ok_player/okrobot3.dpm models/ok_player/okrobot4.dpm");
 342         cvar_settemp("sv_defaultplayermodel_blue", "models/ok_player/okmale1.dpm models/ok_player/okmale2.dpm models/ok_player/okmale3.dpm models/ok_player/okmale4.dpm");
 343 }
 344
 345 void ok_Initialize()
 346 {
 347         ok_SetCvars();
 348
 349         precache_all_playermodels("models/ok_player/*.dpm");
 350
 351         addstat(STAT_OK_AMMO_CHARGE, AS_FLOAT, ok_use_ammocharge);
 352         addstat(STAT_OK_AMMO_CHARGEPOOL, AS_FLOAT, ok_ammo_charge);
 353
 354         WEP_RPC.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 355         WEP_HMG.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 356
 357         WEP_SHOTGUN.mdl = "ok_shotgun";
 358         WEP_MACHINEGUN.mdl = "ok_mg";
 359         WEP_VORTEX.mdl = "ok_sniper";
 360 }
 361 #endif