qcsrc/server/mutators/mutator/gamemode_lms.qc

   1 #ifndef GAMEMODE_LMS_H
   2 #define GAMEMODE_LMS_H
   3
   4 #define autocvar_g_lms_lives_override cvar("g_lms_lives_override")
   5 void lms_Initialize();
   6
   7 REGISTER_MUTATOR(lms, false)
   8 {
   9         MUTATOR_ONADD
  10         {
  11                 if (time > 1) // game loads at time 1
  12                         error("This is a game type and it cannot be added at runtime.");
  13                 lms_Initialize();
  14
  15                 SetLimits(((!autocvar_g_lms_lives_override) ? -1 : autocvar_g_lms_lives_override), 0, -1, -1);
  16         }
  17
  18         MUTATOR_ONROLLBACK_OR_REMOVE
  19         {
  20                 // we actually cannot roll back lms_Initialize here
  21                 // BUT: we don't need to! If this gets called, adding always
  22                 // succeeds.
  23         }
  24
  25         MUTATOR_ONREMOVE
  26         {
  27                 LOG_INFO("This is a game type and it cannot be removed at runtime.");
  28                 return -1;
  29         }
  30
  31         return 0;
  32 }
  33
  34 // scoreboard stuff
  35 const float SP_LMS_LIVES = 4;
  36 const float SP_LMS_RANK = 5;
  37
  38 // lives related defs
  39 float lms_lowest_lives;
  40 float lms_next_place;
  41 float LMS_NewPlayerLives();
  42
  43 #endif
  44
  45 #ifdef IMPLEMENTATION
  46
  47 #include <server/campaign.qh>
  48 #include <server/command/cmd.qh>
  49
  50 int autocvar_g_lms_extra_lives;
  51 bool autocvar_g_lms_join_anytime;
  52 int autocvar_g_lms_last_join;
  53 bool autocvar_g_lms_regenerate;
  54
  55 // main functions
  56 float LMS_NewPlayerLives()
  57 {
  58         float fl;
  59         fl = autocvar_fraglimit;
  60         if(fl == 0)
  61                 fl = 999;
  62
  63         // first player has left the game for dying too much? Nobody else can get in.
  64         if(lms_lowest_lives < 1)
  65                 return 0;
  66
  67         if(!autocvar_g_lms_join_anytime)
  68                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
  69                         return 0;
  70
  71         return bound(1, lms_lowest_lives, fl);
  72 }
  73
  74 // LMS winning condition: game terminates if and only if there's at most one
  75 // one player who's living lives. Top two scores being equal cancels the time
  76 // limit.
  77 int WinningCondition_LMS()
  78 {
  79         entity head, head2;
  80         bool have_player = false;
  81         bool have_players = false;
  82
  83         int l = LMS_NewPlayerLives();
  84
  85         head = find(world, classname, STR_PLAYER);
  86         if(head)
  87                 have_player = true;
  88         head2 = find(head, classname, STR_PLAYER);
  89         if(head2)
  90                 have_players = true;
  91
  92         if(have_player)
  93         {
  94                 // we have at least one player
  95                 if(have_players)
  96                 {
  97                         // two or more active players - continue with the game
  98                 }
  99                 else
 100                 {
 101                         // exactly one player?
 102
 103                         ClearWinners();
 104                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
 105
 106                         if(l)
 107                         {
 108                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
 109                                 return WINNING_NO;
 110                         }
 111                         else
 112                         {
 113                                 // a winner!
 114                                 // and assign him his first place
 115                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
 116                                 return WINNING_YES;
 117                         }
 118                 }
 119         }
 120         else
 121         {
 122                 // nobody is playing at all...
 123                 if(l)
 124                 {
 125                         // wait for players...
 126                 }
 127                 else
 128                 {
 129                         // SNAFU (maybe a draw game?)
 130                         ClearWinners();
 131                         LOG_TRACE("No players, ending game.\n");
 132                         return WINNING_YES;
 133                 }
 134         }
 135
 136         // When we get here, we have at least two players who are actually LIVING,
 137         // now check if the top two players have equal score.
 138         WinningConditionHelper();
 139
 140         ClearWinners();
 141         if(WinningConditionHelper_winner)
 142                 WinningConditionHelper_winner.winning = true;
 143         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
 144                 return WINNING_NEVER;
 145
 146         // Top two have different scores? Way to go for our beloved TIMELIMIT!
 147         return WINNING_NO;
 148 }
 149
 150 // mutator hooks
 151 MUTATOR_HOOKFUNCTION(lms, reset_map_global)
 152 {
 153         lms_lowest_lives = 999;
 154         lms_next_place = player_count;
 155
 156         return false;
 157 }
 158
 159 MUTATOR_HOOKFUNCTION(lms, reset_map_players)
 160 {
 161         if(restart_mapalreadyrestarted || (time < game_starttime))
 162         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(PlayerScore_Add(it, SP_LMS_LIVES, LMS_NewPlayerLives())));
 163         return false;
 164 }
 165
 166 MUTATOR_HOOKFUNCTION(lms, PutClientInServer)
 167 {SELFPARAM();
 168         // player is dead and becomes observer
 169         // FIXME fix LMS scoring for new system
 170         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 171         {
 172                 self.classname = STR_OBSERVER;
 173                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_LMS_NOLIVES);
 174         }
 175
 176         return false;
 177 }
 178
 179 MUTATOR_HOOKFUNCTION(lms, PlayerDies)
 180 {
 181         frag_target.respawn_flags |= RESPAWN_FORCE;
 182         return false;
 183 }
 184
 185 void lms_RemovePlayer(entity player)
 186 {
 187         // Only if the player cannot play at all
 188         if(PlayerScore_Add(player, SP_LMS_RANK, 0) == 666)
 189                 player.frags = FRAGS_SPECTATOR;
 190         else
 191                 player.frags = FRAGS_LMS_LOSER;
 192
 193         if(player.killcount != FRAGS_SPECTATOR)
 194                 if(PlayerScore_Add(player, SP_LMS_RANK, 0) > 0 && player.lms_spectate_warning != 2)
 195                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_NOLIVES, player.netname);
 196                 else
 197                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_FORFEIT, player.netname);
 198 }
 199
 200 MUTATOR_HOOKFUNCTION(lms, ClientDisconnect)
 201 {SELFPARAM();
 202         lms_RemovePlayer(self);
 203         return false;
 204 }
 205
 206 MUTATOR_HOOKFUNCTION(lms, MakePlayerObserver)
 207 {SELFPARAM();
 208         lms_RemovePlayer(self);
 209         return false;
 210 }
 211
 212 MUTATOR_HOOKFUNCTION(lms, ClientConnect)
 213 {SELFPARAM();
 214         self.classname = STR_PLAYER;
 215         campaign_bots_may_start = 1;
 216
 217         if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
 218         {
 219                 PlayerScore_Add(self, SP_LMS_RANK, 666);
 220                 self.frags = FRAGS_SPECTATOR;
 221         }
 222
 223         return false;
 224 }
 225
 226 MUTATOR_HOOKFUNCTION(lms, PlayerPreThink)
 227 {SELFPARAM();
 228         if(self.deadflag == DEAD_DYING)
 229                 self.deadflag = DEAD_RESPAWNING;
 230
 231         return false;
 232 }
 233
 234 MUTATOR_HOOKFUNCTION(lms, PlayerRegen)
 235 {
 236         if(autocvar_g_lms_regenerate)
 237                 return false;
 238         return true;
 239 }
 240
 241 MUTATOR_HOOKFUNCTION(lms, ForbidThrowCurrentWeapon)
 242 {
 243         // forbode!
 244         return true;
 245 }
 246
 247 MUTATOR_HOOKFUNCTION(lms, GiveFragsForKill)
 248 {
 249         // remove a life
 250         float tl;
 251         tl = PlayerScore_Add(frag_target, SP_LMS_LIVES, -1);
 252         if(tl < lms_lowest_lives)
 253                 lms_lowest_lives = tl;
 254         if(tl <= 0)
 255         {
 256                 if(!lms_next_place)
 257                         lms_next_place = player_count;
 258                 else
 259                         lms_next_place = min(lms_next_place, player_count);
 260                 PlayerScore_Add(frag_target, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 261                 --lms_next_place;
 262         }
 263         frag_score = 0;
 264
 265         return true;
 266 }
 267
 268 MUTATOR_HOOKFUNCTION(lms, SetStartItems)
 269 {
 270         start_items &= ~IT_UNLIMITED_AMMO;
 271         start_health       = warmup_start_health       = cvar("g_lms_start_health");
 272         start_armorvalue   = warmup_start_armorvalue   = cvar("g_lms_start_armor");
 273         start_ammo_shells  = warmup_start_ammo_shells  = cvar("g_lms_start_ammo_shells");
 274         start_ammo_nails   = warmup_start_ammo_nails   = cvar("g_lms_start_ammo_nails");
 275         start_ammo_rockets = warmup_start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 276         start_ammo_cells   = warmup_start_ammo_cells   = cvar("g_lms_start_ammo_cells");
 277         start_ammo_plasma  = warmup_start_ammo_plasma  = cvar("g_lms_start_ammo_plasma");
 278         start_ammo_fuel    = warmup_start_ammo_fuel    = cvar("g_lms_start_ammo_fuel");
 279
 280         return false;
 281 }
 282
 283 MUTATOR_HOOKFUNCTION(lms, ForbidPlayerScore_Clear)
 284 {
 285         // don't clear player score
 286         return true;
 287 }
 288
 289 MUTATOR_HOOKFUNCTION(lms, FilterItem)
 290 {SELFPARAM();
 291         if(autocvar_g_lms_extra_lives)
 292         if(self.itemdef == ITEM_ExtraLife)
 293                 return false;
 294
 295         return true;
 296 }
 297
 298 void lms_extralife()
 299 {SELFPARAM();
 300         StartItem(this, ITEM_ExtraLife);
 301 }
 302
 303 MUTATOR_HOOKFUNCTION(lms, OnEntityPreSpawn)
 304 {SELFPARAM();
 305         if (!autocvar_g_powerups) return false;
 306         if (!autocvar_g_lms_extra_lives) return false;
 307
 308         // Can't use .itemdef here
 309         if (self.classname != "item_health_mega") return false;
 310
 311         entity e = spawn();
 312         e.think = lms_extralife;
 313
 314         e.nextthink = time + 0.1;
 315         e.spawnflags = self.spawnflags;
 316         e.noalign = self.noalign;
 317         setorigin(e, self.origin);
 318
 319         return true;
 320 }
 321
 322 MUTATOR_HOOKFUNCTION(lms, ItemTouch)
 323 {SELFPARAM();
 324         if(self.itemdef == ITEM_ExtraLife)
 325         {
 326                 Send_Notification(NOTIF_ONE, other, MSG_CENTER, CENTER_EXTRALIVES);
 327                 PlayerScore_Add(other, SP_LMS_LIVES, autocvar_g_lms_extra_lives);
 328                 return MUT_ITEMTOUCH_PICKUP;
 329         }
 330
 331         return MUT_ITEMTOUCH_CONTINUE;
 332 }
 333
 334 MUTATOR_HOOKFUNCTION(lms, Bot_FixCount, CBC_ORDER_EXCLUSIVE)
 335 {
 336         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
 337                 ++bot_activerealplayers;
 338                 ++bot_realplayers;
 339         ));
 340
 341         return true;
 342 }
 343
 344 MUTATOR_HOOKFUNCTION(lms, ClientCommand_Spectate)
 345 {
 346         if(self.lms_spectate_warning)
 347         {
 348                 // for the forfeit message...
 349                 self.lms_spectate_warning = 2;
 350                 // mark player as spectator
 351                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
 352         }
 353         else
 354         {
 355                 self.lms_spectate_warning = 1;
 356                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 357                 return MUT_SPECCMD_RETURN;
 358         }
 359         return MUT_SPECCMD_CONTINUE;
 360 }
 361
 362 MUTATOR_HOOKFUNCTION(lms, CheckRules_World)
 363 {
 364         ret_float = WinningCondition_LMS();
 365         return true;
 366 }
 367
 368 MUTATOR_HOOKFUNCTION(lms, WantWeapon)
 369 {
 370         want_allguns = true;
 371         return false;
 372 }
 373
 374 MUTATOR_HOOKFUNCTION(lms, GetPlayerStatus)
 375 {
 376         return true;
 377 }
 378
 379 MUTATOR_HOOKFUNCTION(lms, AddPlayerScore)
 380 {
 381         if(gameover)
 382         if(score_field == SP_LMS_RANK)
 383                 return true; // allow writing to this field in intermission as it is needed for newly joining players
 384         return false;
 385 }
 386
 387 // scoreboard stuff
 388 void lms_ScoreRules()
 389 {
 390         ScoreRules_basics(0, 0, 0, false);
 391         ScoreInfo_SetLabel_PlayerScore(SP_LMS_LIVES,    "lives",     SFL_SORT_PRIO_SECONDARY);
 392         ScoreInfo_SetLabel_PlayerScore(SP_LMS_RANK,     "rank",      SFL_LOWER_IS_BETTER | SFL_RANK | SFL_SORT_PRIO_PRIMARY | SFL_ALLOW_HIDE);
 393         ScoreRules_basics_end();
 394 }
 395
 396 void lms_Initialize()
 397 {
 398         lms_lowest_lives = 9999;
 399         lms_next_place = 0;
 400
 401         lms_ScoreRules();
 402 }
 403
 404
 405 #endif