qcsrc/server/mutators/gamemode_towerdefense.qc

   1 // Tower Defense
   2 // Gamemode by Mario
   3
   4 void spawnfunc_td_controller()
   5 {
   6         if not(g_td) { remove(self); return; }
   7
   8         if(autocvar_g_td_force_settings)
   9         {
  10                 // TODO: find a better way to do this?
  11                 self.dontend = FALSE;
  12                 self.maxwaves = 0;
  13                 self.monstercount = 0;
  14                 self.startwave = 0;
  15                 self.maxturrets = 0;
  16                 self.buildtime = 0;
  17                 self.mspeed_walk = 0;
  18                 self.mspeed_run = 0;
  19                 self.spawndelay = 0;
  20                 self.maxcurrent = 0;
  21                 self.ignoreturrets = 0;
  22         }
  23
  24         self.netname = "Tower Defense controller entity";
  25         self.classname = "td_controller";
  26
  27         gensurvived = FALSE;
  28
  29         td_dont_end = ((self.dontend == 0) ? autocvar_g_td_generator_dontend : self.dontend);
  30         max_waves = ((self.maxwaves == 0) ? autocvar_g_td_max_waves : self.maxwaves);
  31         totalmonsters = ((self.monstercount == 0) ? autocvar_g_td_monster_count : self.monstercount);
  32         wave_count = ((self.startwave == 0) ? autocvar_g_td_start_wave : self.startwave);
  33         max_turrets = ((self.maxturrets == 0) ? autocvar_g_td_turret_max : self.maxturrets);
  34         build_time = ((self.buildtime == 0) ? autocvar_g_td_buildphase_time : self.buildtime);
  35         m_speed_walk = ((self.mspeed_walk == 0) ? autocvar_g_td_monsters_speed_walk : self.mspeed_walk);
  36         m_speed_run = ((self.mspeed_run == 0) ? autocvar_g_td_monsters_speed_run : self.mspeed_run);
  37         spawn_delay = ((self.spawndelay == 0) ? autocvar_g_td_monsters_spawn_delay : self.spawndelay);
  38         max_current = ((self.maxcurrent == 0) ? autocvar_g_td_current_monsters : self.maxcurrent);
  39         ignore_turrets = ((self.ignoreturrets == 0) ? autocvar_g_td_monsters_ignore_turrets : self.ignoreturrets);
  40
  41         if(autocvar_g_td_monsters_skill_start)
  42                 monster_skill = autocvar_g_td_monsters_skill_start;
  43
  44         wave_end(TRUE);
  45 }
  46
  47 void td_generator_die()
  48 {
  49         if(autocvar_sv_eventlog)
  50                 GameLogEcho(":gendestroyed");
  51
  52         gendestroyed = TRUE;
  53
  54         pointparticles(particleeffectnum("explosion_medium"), self.origin, '0 0 0', 1);
  55         sound(self, CH_TRIGGER, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
  56
  57         Send_Notification(NOTIF_ALL, world, MSG_MULTI, MULTI_TD_GENDESTROYED);
  58
  59         self.solid                      = SOLID_NOT;
  60         self.takedamage         = DAMAGE_NO;
  61         self.event_damage   = func_null;
  62         self.enemy                      = world;
  63         td_gencount                     -= 1;
  64
  65         WaypointSprite_Kill(self.sprite);
  66 }
  67
  68 void td_generator_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  69 {
  70         if(IS_PLAYER(attacker) || attacker.turrcaps_flags & TFL_TURRCAPS_ISTURRET || attacker.vehicle_flags & VHF_ISVEHICLE || self.takedamage == DAMAGE_NO)
  71                 return;
  72
  73         if (time > self.pain_finished)
  74         {
  75                 self.pain_finished = time + 10;
  76                 play2all("onslaught/generator_underattack.wav");
  77         }
  78
  79         if (random() < 0.5)
  80                 spamsound(self, CH_TRIGGER, "onslaught/ons_hit1.wav", VOL_BASE, ATTN_NORM);
  81         else
  82                 spamsound(self, CH_TRIGGER, "onslaught/ons_hit2.wav", VOL_BASE, ATTN_NORM);
  83
  84         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_TD_GENDAMAGED);
  85
  86         self.health -= damage;
  87
  88         WaypointSprite_UpdateHealth(self.sprite, self.health);
  89
  90         if(self.health <= 0)
  91                 td_generator_die();
  92
  93         self.SendFlags |= GSF_STATUS;
  94 }
  95
  96 void td_generator_setup()
  97 {
  98         self.think                      = func_null;
  99         self.nextthink          = -1;
 100         self.solid                  = SOLID_BBOX;
 101         self.takedamage     = DAMAGE_AIM;
 102         self.event_damage   = td_generator_damage;
 103         self.enemy                  = world;
 104         self.movetype       = MOVETYPE_NONE;
 105         self.monster_attack = TRUE;
 106         self.netname            = "Generator";
 107         self.SendFlags          = GSF_SETUP;
 108
 109         WaypointSprite_SpawnFixed(self.netname, self.origin + '0 0 90', self, sprite, RADARICON_OBJECTIVE, '1 0.5 0');
 110         WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
 111         WaypointSprite_UpdateHealth(self.sprite, self.health);
 112 }
 113
 114 void spawnfunc_td_generator()
 115 {
 116         if not(g_td) { remove(self); return; }
 117
 118         precache_sound("onslaught/generator_underattack.wav");
 119         precache_sound("onslaught/ons_hit1.wav");
 120         precache_sound("onslaught/ons_hit2.wav");
 121         precache_sound("weapons/rocket_impact.wav");
 122
 123         gendestroyed = FALSE;
 124
 125         if not(self.health)
 126                 self.health = autocvar_g_td_generator_health;
 127
 128         self.max_health = self.health;
 129
 130         self.classname = "td_generator";
 131         self.flags = FL_GENERATOR;
 132         td_gencount += 1;
 133
 134         setsize(self, GENERATOR_MIN, GENERATOR_MAX);
 135
 136         setorigin(self, self.origin + '0 0 20');
 137         droptofloor();
 138
 139         generator_link(td_generator_setup);
 140 }
 141
 142 entity PickGenerator()
 143 {
 144         entity generator, head;
 145         if(td_gencount == 1)
 146                 generator = findflags(world, flags, FL_GENERATOR);
 147         else
 148         {
 149                 RandomSelection_Init();
 150                 for(head = world;(head = findflags(head, flags, FL_GENERATOR)); )
 151                 {
 152                         RandomSelection_Add(head, 0, string_null, 1, 1);
 153                 }
 154                 generator = RandomSelection_chosen_ent;
 155         }
 156         return generator;
 157 }
 158
 159 void spawn_td_fuel(float fuel_size)
 160 {
 161         if not(g_td) {remove(self); return; }
 162
 163         self.ammo_fuel = fuel_size * monster_skill;
 164         StartItem("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Turret Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
 165
 166         self.velocity = randomvec() * 175 + '0 0 325';
 167 }
 168
 169 void spawnfunc_td_waypoint()
 170 {
 171         if not(g_td) { remove(self); return; }
 172
 173         self.classname = "td_waypoint";
 174 }
 175
 176 void spawnfunc_monster_swarm()
 177 {
 178         if not(g_td) { remove(self); return; }
 179
 180         self.flags = SWARM_NORMAL; // marked as a spawnpoint
 181         self.classname = "monster_swarm";
 182
 183         if(self.spawntype == SWARM_SWIM) waterspawns_count += 1;
 184         if(self.spawntype == SWARM_FLY) flyspawns_count += 1;
 185
 186         WaypointSprite_SpawnFixed("Monsters", self.origin + '0 0 60', self, sprite, RADARICON_HERE, '0 0 1');
 187
 188         if(self.target == "")
 189                 dprint("Warning: monster_swarm entity without a set target\n");
 190 }
 191
 192 void barricade_touch()
 193 {
 194         if not(other.flags & FL_MONSTER)
 195                 return;
 196
 197         if(time < self.dmg_time)
 198                 return;
 199
 200         Damage(other, self, self, autocvar_g_td_barricade_damage, DEATH_HURTTRIGGER, self.origin, '0 0 0');
 201
 202         self.dmg_time = time + 1;
 203 }
 204
 205 void barricade_die()
 206 {
 207         self.takedamage = DAMAGE_NO;
 208         self.event_damage = func_null;
 209
 210         WaypointSprite_Kill(self.sprite);
 211
 212         pointparticles(particleeffectnum("explosion_medium"), self.origin, '0 0 0', 1);
 213         sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 214
 215         if(self.realowner)
 216                 self.realowner.turret_cnt -= 1;
 217
 218         self.think = SUB_Remove;
 219         self.nextthink = time;
 220 }
 221
 222 void barricade_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 223 {
 224         if not(attacker.flags & FL_MONSTER) return;
 225
 226         self.health -= damage;
 227
 228         WaypointSprite_UpdateHealth(self.sprite, self.health);
 229
 230         if(self.health < 1)
 231                 barricade_die();
 232 }
 233
 234 void spawn_barricade()
 235 {
 236         self.health = 2000;
 237         self.max_health = self.health;
 238         self.dmg_time = time;
 239         self.touch = barricade_touch;
 240         self.think = func_null;
 241         self.nextthink = -1;
 242         self.takedamage = DAMAGE_AIM;
 243         self.turrcaps_flags = TFL_TURRCAPS_ISTURRET; // for turretremove commands etc.
 244         self.solid = SOLID_CORPSE; // hax
 245         self.event_damage = barricade_damage;
 246         self.netname = "Barricade";
 247
 248         WaypointSprite_Spawn(self.netname, 0, 1200, self, '0 0 110', world, 0, self, sprite, FALSE, RADARICON_DOMPOINT, '1 1 0');
 249         WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
 250         WaypointSprite_UpdateHealth(self.sprite, self.health);
 251
 252         precache_model("models/td/barricade.md3");
 253         setmodel(self, "models/td/barricade.md3");
 254
 255         droptofloor();
 256
 257         self.movetype = MOVETYPE_NONE;
 258 }
 259
 260 float td_checkfuel(entity ent, string tur)
 261 {
 262         float turcost = cvar(strcat("g_td_turret_", tur, "_cost"));
 263
 264         if(ent.ammo_fuel < turcost)
 265         {
 266                 Send_Notification(NOTIF_ONE, ent, MSG_MULTI, MULTI_TD_NOFUEL);
 267                 return FALSE;
 268         }
 269
 270         ent.ammo_fuel -= turcost;
 271
 272         return TRUE;
 273 }
 274
 275 void spawnturret(entity spawnedby, entity own, string turet, vector orig)
 276 {
 277         if not(IS_PLAYER(spawnedby)) { dprint("Warning: A non-player entity tried to spawn a turret\n"); return; }
 278         if not(td_checkfuel(spawnedby, turet)) { return; }
 279
 280         entity oldself;
 281
 282         oldself = self;
 283         self = spawn();
 284
 285         setorigin(self, orig);
 286         self.spawnflags = TSL_NO_RESPAWN;
 287         self.monster_attack = TRUE;
 288         self.realowner = own;
 289         self.playerid = own.playerid;
 290         self.angles_y = spawnedby.v_angle_y;
 291         spawnedby.turret_cnt += 1;
 292         self.colormap = spawnedby.colormap;
 293         self.colormod = '1 1 1';
 294
 295         switch(turet)
 296         {
 297                 case "plasma": spawnfunc_turret_plasma(); break;
 298                 case "mlrs": spawnfunc_turret_mlrs(); break;
 299                 case "walker": spawnfunc_turret_walker(); break;
 300                 case "flac": spawnfunc_turret_flac(); break;
 301                 case "towerbuff": spawnfunc_turret_fusionreactor(); break;
 302                 case "barricade": spawn_barricade(); break;
 303                 default: Send_Notification(NOTIF_ONE, spawnedby, MSG_INFO, INFO_TD_INVALID); remove(self); self = oldself; return;
 304         }
 305
 306         Send_Notification(NOTIF_ONE, spawnedby, MSG_MULTI, MULTI_TD_SPAWN);
 307
 308         self = oldself;
 309 }
 310
 311 void buffturret (entity tur, float buff)
 312 {
 313         tur.turret_buff           += 1;
 314         tur.max_health            *= buff;
 315         tur.tur_health             = tur.max_health;
 316         tur.health                         = tur.max_health;
 317         tur.ammo_max              *= buff;
 318         tur.ammo_recharge     *= buff;
 319     tur.shot_dmg          *= buff;
 320     tur.shot_refire       -= buff * 0.2;
 321     tur.shot_radius       *= buff;
 322     tur.shot_speed        *= buff;
 323     tur.shot_spread       *= buff;
 324     tur.shot_force        *= buff;
 325 }
 326
 327 void AnnounceSpawn(string anounce)
 328 {
 329         entity e;
 330         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_TD_ANNOUNCE_SPAWN, anounce);
 331
 332         FOR_EACH_REALCLIENT(e) soundto(MSG_ONE, e, CHAN_AUTO, "kh/alarm.wav", VOL_BASE, ATTN_NONE);
 333 }
 334
 335 entity PickSpawn (float strngth, float type)
 336 {
 337         entity e;
 338         RandomSelection_Init();
 339         for(e = world;(e = find(e, classname, "monster_swarm")); )
 340         {
 341                 if(flyspawns_count > 0 && type == SWARM_FLY && e.spawntype != SWARM_FLY) continue;
 342                 if(waterspawns_count > 0 && type == SWARM_SWIM && e.spawntype != SWARM_SWIM) continue;
 343
 344                 RandomSelection_Add(e, 0, string_null, 1, 1);
 345         }
 346
 347         return RandomSelection_chosen_ent;
 348 }
 349
 350 void TD_SpawnMonster(string mnster, float strngth, float type)
 351 {
 352         entity e, mon;
 353
 354         e = PickSpawn(strngth, type);
 355
 356         if(e == world) // couldn't find anything for our class, so check for normal spawns
 357                 e = PickSpawn(SWARM_NORMAL, SWARM_NORMAL);
 358
 359         if(e == world)
 360         {
 361                 dprint("Warning: couldn't find any monster_swarm spawnpoints, no monsters will spawn!\n");
 362                 return;
 363         }
 364
 365         mon = spawnmonster(mnster, e, e, e.origin, FALSE, 2);
 366         if(e.target2)
 367         {
 368                 if(random() <= 0.5 && e.target)
 369                         mon.target2 = e.target;
 370                 else
 371                         mon.target2 = e.target2;
 372         }
 373         else
 374                 mon.target2 = e.target;
 375 }
 376
 377 float Monster_GetStrength(float mnster)
 378 {
 379         switch(mnster)
 380         {
 381                 default:
 382                 case MONSTER_BRUISER:
 383                 case MONSTER_MARINE:
 384                 case MONSTER_ZOMBIE:
 385                 case MONSTER_SPIDER:
 386                 case MONSTER_SLIME:
 387                 case MONSTER_DOG:
 388                 case MONSTER_WYVERN:
 389                 case MONSTER_FISH:
 390                         return SWARM_WEAK;
 391                 case MONSTER_KNIGHT:
 392                 case MONSTER_OGRE:
 393                 case MONSTER_SHAMBLER:
 394                 case MONSTER_MAGE:
 395                 case MONSTER_ANIMUS:
 396                         return SWARM_STRONG;
 397                 default: return SWARM_NORMAL;
 398         }
 399 }
 400
 401 string monster_type2string(float mnster)
 402 {
 403         switch(mnster)
 404         {
 405                 case MONSTER_ZOMBIE: return "zombie";
 406                 case MONSTER_OGRE: return "ogre";
 407                 case MONSTER_ANIMUS: return "animus";
 408                 case MONSTER_SHAMBLER: return "shambler";
 409                 case MONSTER_BRUISER: return "bruiser";
 410                 case MONSTER_MARINE: return "marine";
 411                 case MONSTER_WYVERN: return "wyvern";
 412                 case MONSTER_DOG: return "dog";
 413                 case MONSTER_SLIME: return "slime";
 414                 case MONSTER_KNIGHT: return "knight";
 415                 case MONSTER_FISH: return "fish";
 416                 case MONSTER_MAGE: return "mage";
 417                 case MONSTER_SPIDER: return "spider";
 418                 default: return "";
 419         }
 420 }
 421
 422 float Monster_GetType(float mnster)
 423 {
 424         switch(mnster)
 425         {
 426                 default:
 427                 case MONSTER_BRUISER:
 428                 case MONSTER_MARINE:
 429                 case MONSTER_ZOMBIE:
 430                 case MONSTER_SPIDER:
 431                 case MONSTER_SLIME:
 432                 case MONSTER_DOG:
 433                 case MONSTER_OGRE:
 434                 case MONSTER_SHAMBLER:
 435                 case MONSTER_MAGE:
 436                 case MONSTER_KNIGHT:
 437                 case MONSTER_ANIMUS:
 438                         return SWARM_NORMAL;
 439                 case MONSTER_WYVERN:
 440                         return SWARM_FLY;
 441                 case MONSTER_FISH:
 442                         return SWARM_SWIM;
 443         }
 444 }
 445
 446 float RandomMonster()
 447 {
 448         RandomSelection_Init();
 449
 450         if(n_animuses) RandomSelection_Add(world, MONSTER_ANIMUS, "", 1, 1);
 451         if(n_mages) RandomSelection_Add(world, MONSTER_MAGE, "", 1, 1);
 452         if(n_soldiers) RandomSelection_Add(world, MONSTER_MARINE, "", 1, 1);
 453         if(n_knights) RandomSelection_Add(world, MONSTER_KNIGHT, "", 1, 1);
 454         if(n_zombies) RandomSelection_Add(world, MONSTER_ZOMBIE, "", 1, 1);
 455         if(n_spiders) RandomSelection_Add(world, MONSTER_SPIDER, "", 1, 1);
 456         if(n_ogres) RandomSelection_Add(world, MONSTER_OGRE, "", 1, 1);
 457         if(n_dogs) RandomSelection_Add(world, MONSTER_DOG, "", 1, 1);
 458         if(n_bruisers) RandomSelection_Add(world, MONSTER_BRUISER, "", 1, 1);
 459         if(n_shamblers) RandomSelection_Add(world, MONSTER_SHAMBLER, "", 0.2, 0.2);
 460         if(n_slimes) RandomSelection_Add(world, MONSTER_SLIME, "", 0.2, 0.2);
 461         if(n_wyverns && flyspawns_count) RandomSelection_Add(world, MONSTER_WYVERN, "", 1, 1);
 462         if(n_fish && waterspawns_count) RandomSelection_Add(world, MONSTER_FISH, "", 0.2, 0.2);
 463
 464         return RandomSelection_chosen_float;
 465 }
 466
 467 void combat_phase()
 468 {
 469         float mstrength, montype, whichmon;
 470
 471         current_phase = PHASE_COMBAT;
 472
 473         if(monster_count <= 0)
 474         {
 475                 wave_end(FALSE);
 476                 return;
 477         }
 478
 479         self.think = combat_phase;
 480
 481         whichmon = RandomMonster();
 482
 483         mstrength = Monster_GetStrength(whichmon);
 484         montype = Monster_GetType(whichmon);
 485
 486         if(current_monsters <= max_current && whichmon)
 487         {
 488                 TD_SpawnMonster(monster_type2string(whichmon), mstrength, montype);
 489                 self.nextthink = time + spawn_delay;
 490         }
 491         else
 492                 self.nextthink = time + 6;
 493 }
 494
 495 void queue_monsters(float maxmonsters)
 496 {
 497         float mc = 10; // note: shambler + slime = 1
 498
 499         if(waterspawns_count > 0)
 500                 mc += 1;
 501         if(flyspawns_count > 0)
 502                 mc += 1;
 503
 504         DistributeEvenly_Init(maxmonsters, mc);
 505         n_animuses      = DistributeEvenly_Get(1);
 506         n_ogres         = DistributeEvenly_Get(1);
 507         n_dogs          = DistributeEvenly_Get(1);
 508         n_bruisers  = DistributeEvenly_Get(1);
 509         n_mages         = DistributeEvenly_Get(1);
 510         n_soldiers  = DistributeEvenly_Get(1);
 511         n_knights   = DistributeEvenly_Get(1);
 512         n_zombies   = DistributeEvenly_Get(1);
 513         n_spiders   = DistributeEvenly_Get(1);
 514         n_slimes        = DistributeEvenly_Get(0.7);
 515         n_shamblers = DistributeEvenly_Get(0.3);
 516         if(flyspawns_count > 0)
 517                 n_wyverns = DistributeEvenly_Get(1);
 518         if(waterspawns_count > 0)
 519                 n_fish = DistributeEvenly_Get(1);
 520 }
 521
 522 void combat_phase_begin()
 523 {
 524         monster_count = totalmonsters;
 525         entity gen;
 526
 527         Send_Notification(NOTIF_ALL, world, MSG_MULTI, MULTI_TD_PHASE_COMBAT);
 528
 529         if(autocvar_sv_eventlog)
 530                 GameLogEcho(":combatphase");
 531
 532         self.think = combat_phase;
 533         self.nextthink = time + 1;
 534
 535         for(gen = world;(gen = findflags(gen, flags, FL_GENERATOR)); )
 536                 gen.takedamage = DAMAGE_AIM;
 537 }
 538
 539 float cphase_updates;
 540 void combat_phase_announce() // TODO: clean up these fail nextthinks...
 541 {
 542         cphase_updates += 1;
 543
 544         if(cphase_updates == 0)
 545                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_PREPARE);
 546         else if(cphase_updates == 3)
 547                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_NUM_3);
 548         else if(cphase_updates == 4)
 549                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_NUM_2);
 550         else if(cphase_updates == 5)
 551                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_NUM_1);
 552         else if(cphase_updates == 6)
 553         {
 554                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_BEGIN);
 555                 combat_phase_begin();
 556         }
 557
 558         if(cphase_updates >= 6)
 559                 return;
 560
 561         self.think = combat_phase_announce;
 562         self.nextthink = time + 1;
 563 }
 564
 565 void build_phase()
 566 {
 567         entity head;
 568         float n_players = 0, gen_washealed = FALSE, mcount, mskill;
 569
 570         current_phase = PHASE_BUILD;
 571
 572         for(head = world;(head = findflags(head, flags, FL_GENERATOR)); )
 573         {
 574                 if(head.health < head.max_health)
 575                 {
 576                         gen_washealed = TRUE;
 577                         pointparticles(particleeffectnum("healing_fx"), head.origin, '0 0 0', 1);
 578                         head.health = head.max_health;
 579                         WaypointSprite_UpdateHealth(head.sprite, head.health);
 580                         head.SendFlags |= GSF_STATUS;
 581                 }
 582                 head.takedamage = DAMAGE_NO;
 583         }
 584
 585         FOR_EACH_PLAYER(head)
 586         {
 587                 if(head.health < 100) head.health = 100;
 588                 if(gen_washealed) PlayerScore_Add(head, SP_TD_SCORE, -autocvar_g_td_generator_damaged_points);
 589
 590         n_players += 1;
 591         }
 592
 593         mcount = autocvar_g_td_monster_count_increment * wave_count;
 594         mskill = n_players * 0.02;
 595
 596         totalmonsters += mcount;
 597         monster_skill += autocvar_g_td_monsters_skill_increment;
 598         monster_skill += mskill;
 599
 600         if(monster_skill < 1) monster_skill = 1;
 601         if(totalmonsters < 1) totalmonsters = ((autocvar_g_td_monster_count > 0) ? autocvar_g_td_monster_count : 10);
 602         if(wave_count < 1) wave_count = 1;
 603
 604         Send_Notification(NOTIF_ALL, world, MSG_MULTI, MULTI_TD_PHASE_BUILD, wave_count, totalmonsters, build_time);
 605
 606     FOR_EACH_MONSTER(head)
 607     {
 608                 if(head.health <= 0)
 609                         continue;
 610
 611         dprint(strcat("Warning: Monster still alive during build phase! Monster name: ", head.netname, "\n"));
 612
 613                 WaypointSprite_Kill(head.sprite);
 614         remove(head);
 615     }
 616
 617         monsters_total = totalmonsters;
 618         monsters_killed = 0;
 619
 620         queue_monsters(totalmonsters);
 621
 622         cphase_updates = -1;
 623
 624         if(autocvar_sv_eventlog)
 625         GameLogEcho(strcat(":buildphase:", ftos(wave_count), ":", ftos(totalmonsters)));
 626
 627         self.think = combat_phase_announce;
 628         self.nextthink = time + build_time - 6;
 629 }
 630
 631 void wave_end(float starting)
 632 {
 633         if not(starting)
 634         {
 635                 Send_Notification(NOTIF_ALL, world, MSG_MULTI, MULTI_TD_VICTORY, ((wave_count >= max_waves) ? "Level" : "Wave"));
 636
 637                 if(autocvar_sv_eventlog)
 638             GameLogEcho(strcat(":wave:", ftos(wave_count), ":victory"));
 639         }
 640
 641         if(wave_count >= max_waves)
 642         {
 643                 gensurvived = TRUE;
 644                 return;
 645         }
 646
 647         if not(starting)
 648                 wave_count += 1;
 649
 650         self.think = build_phase;
 651         self.nextthink = time + 3;
 652 }
 653
 654 void td_ScoreRules()
 655 {
 656         ScoreInfo_SetLabel_PlayerScore(SP_TD_SCORE,             "score",         SFL_SORT_PRIO_PRIMARY);
 657         ScoreInfo_SetLabel_PlayerScore(SP_TD_KILLS,             "kills",         SFL_LOWER_IS_BETTER);
 658         ScoreInfo_SetLabel_PlayerScore(SP_TD_TURKILLS,  "frags",         SFL_LOWER_IS_BETTER);
 659         ScoreInfo_SetLabel_PlayerScore(SP_TD_DEATHS,    "deaths",    SFL_LOWER_IS_BETTER);
 660         ScoreInfo_SetLabel_PlayerScore(SP_TD_SUICIDES,  "suicides",  SFL_LOWER_IS_BETTER | SFL_ALLOW_HIDE);
 661         ScoreRules_basics_end();
 662 }
 663
 664 void td_SpawnController()
 665 {
 666         entity oldself = self;
 667         self = spawn();
 668         self.classname = "td_controller";
 669         spawnfunc_td_controller();
 670         self = oldself;
 671 }
 672
 673 void td_DelayedInit()
 674 {
 675         if(find(world, classname, "td_controller") == world)
 676         {
 677                 print("No ""td_controller"" entity found on this map, creating it anyway.\n");
 678                 td_SpawnController();
 679         }
 680
 681         td_ScoreRules();
 682 }
 683
 684 void td_Initialize()
 685 {
 686         InitializeEntity(world, td_DelayedInit, INITPRIO_GAMETYPE);
 687 }
 688
 689 MUTATOR_HOOKFUNCTION(td_TurretValidateTarget)
 690 {
 691         if(time < game_starttime || current_phase != PHASE_COMBAT || gameover)
 692         {
 693                 turret_target = world;
 694                 return FALSE; // battle hasn't started
 695         }
 696
 697         if(turret_flags & TFL_TARGETSELECT_MISSILESONLY)
 698     if(turret_target.flags & FL_PROJECTILE)
 699         if(turret_target.owner.flags & FL_MONSTER)
 700         return TRUE; // flac support
 701
 702         if(turret.turrcaps_flags & TFL_TURRCAPS_SUPPORT && turret_target.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 703                 return TRUE;
 704         if not(turret_target.flags & FL_MONSTER)
 705                 turret_target = world;
 706
 707         return FALSE;
 708 }
 709
 710 MUTATOR_HOOKFUNCTION(td_PlayerThink)
 711 {
 712         self.stat_current_wave = wave_count;
 713         self.stat_totalwaves = max_waves;
 714
 715         return FALSE;
 716 }
 717
 718 MUTATOR_HOOKFUNCTION(td_PlayerSpawn)
 719 {
 720         self.bot_attack = FALSE;
 721
 722         return FALSE;
 723 }
 724
 725 MUTATOR_HOOKFUNCTION(td_PlayerDies)
 726 {
 727         if(frag_attacker.flags & FL_MONSTER)
 728                 PlayerScore_Add(frag_target, SP_TD_DEATHS, 1);
 729
 730         if(frag_target == frag_attacker)
 731                 PlayerScore_Add(frag_attacker, SP_TD_SUICIDES, 1);
 732
 733         return FALSE;
 734 }
 735
 736 MUTATOR_HOOKFUNCTION(td_GiveFragsForKill)
 737 {
 738         frag_score = 0;
 739
 740         return TRUE; // no frags counted in td
 741 }
 742
 743 MUTATOR_HOOKFUNCTION(td_PlayerDamage)
 744 {
 745         if(frag_attacker.realowner == frag_target)
 746                 frag_damage = 0;
 747
 748         if(frag_target.flags & FL_MONSTER && time < frag_target.spawnshieldtime)
 749                 frag_damage = 0;
 750
 751         if(frag_target.vehicle_flags & VHF_ISVEHICLE && !(frag_attacker.flags & FL_MONSTER))
 752                 frag_damage = 0;
 753
 754         if(frag_attacker.vehicle_flags & VHF_ISVEHICLE && !(frag_target.flags & FL_MONSTER))
 755                 frag_damage = 0;
 756
 757         if(!autocvar_g_td_pvp && frag_attacker != frag_target && IS_PLAYER(frag_target) && IS_PLAYER(frag_attacker))
 758         {
 759                 frag_attacker.typehitsound += 1;
 760                 frag_damage = 0;
 761         }
 762
 763         if(frag_attacker.turrcaps_flags & TFL_TURRCAPS_ISTURRET && IS_PLAYER(frag_target))
 764                 frag_damage = 0;
 765
 766         if((frag_target.turrcaps_flags & TFL_TURRCAPS_ISTURRET) && !(frag_attacker.flags & FL_MONSTER || frag_attacker.turrcaps_flags & TFL_TURRCAPS_SUPPORT))
 767                 frag_damage = 0;
 768
 769         return TRUE;
 770 }
 771
 772 MUTATOR_HOOKFUNCTION(td_TurretDies)
 773 {
 774         if(self.realowner)
 775                 self.realowner.turret_cnt -= 1;
 776
 777         return FALSE;
 778 }
 779
 780 MUTATOR_HOOKFUNCTION(td_MonsterCheckBossFlag)
 781 {
 782         // No minibosses in tower defense
 783         return TRUE;
 784 }
 785
 786 MUTATOR_HOOKFUNCTION(td_MonsterMove)
 787 {
 788         entity head;
 789         float n_players = 0;
 790
 791         FOR_EACH_PLAYER(head) { ++n_players; }
 792         if(n_players < 1) return TRUE;
 793
 794         if not(self.enemy) // don't change targets while attacking
 795         if((vlen(monster_target.origin - self.origin) <= 100 && monster_target.classname == "td_waypoint") || (vlen(monster_target.origin - self.origin) <= 200 && (self.flags & FL_FLY) && monster_target.classname == "td_waypoint"))
 796         {
 797                 if(monster_target.target2)
 798                 {
 799                         if(random() > 0.5)
 800                                 self.target2 = monster_target.target2;
 801                         else
 802                                 self.target2 = monster_target.target;
 803                 }
 804                 else
 805                         self.target2 = monster_target.target;
 806
 807                 monster_target = find(world, targetname, self.target2);
 808
 809                 if(monster_target == world)
 810                         monster_target = PickGenerator();
 811         }
 812
 813         monster_speed_run = (m_speed_run + random() * 4) * monster_skill;
 814         monster_speed_walk = (m_speed_walk + random() * 4) * monster_skill;
 815
 816         return FALSE;
 817 }
 818
 819 MUTATOR_HOOKFUNCTION(td_MonsterSpawn)
 820 {
 821         if(self.realowner == world) // nothing spawned it, so kill it
 822         {
 823                 WaypointSprite_Kill(self.sprite);
 824                 remove(self.weaponentity);
 825                 remove(self);
 826                 return TRUE;
 827         }
 828
 829         current_monsters += 1;
 830
 831         self.spawnshieldtime = time + autocvar_g_td_monsters_spawnshield_time;
 832
 833         self.drop_size = bound(5, self.health * 0.05, autocvar_g_pickup_fuel_max);
 834
 835         self.target_range = 600;
 836
 837         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_CORPSE | DPCONTENTS_MONSTERCLIP;
 838
 839         switch(self.monsterid)
 840         {
 841                 case MONSTER_ZOMBIE: n_zombies -= 1; break;
 842                 case MONSTER_OGRE: n_ogres -= 1; break;
 843                 case MONSTER_ANIMUS: n_animuses -= 1; break;
 844                 case MONSTER_SHAMBLER: n_shamblers -= 1; break;
 845                 case MONSTER_BRUISER: n_bruisers -= 1; break;
 846                 case MONSTER_MARINE: n_soldiers -= 1; break;
 847                 case MONSTER_WYVERN: n_wyverns -= 1; break;
 848                 case MONSTER_DOG: n_dogs -= 1; break;
 849                 case MONSTER_SLIME: n_slimes -= 1; break;
 850                 case MONSTER_KNIGHT: n_knights -= 1; break;
 851                 case MONSTER_FISH: n_fish -= 1; break;
 852                 case MONSTER_MAGE: n_mages -= 1; break;
 853                 case MONSTER_SPIDER: n_spiders -= 1; break;
 854         }
 855
 856         return TRUE;
 857 }
 858
 859 MUTATOR_HOOKFUNCTION(td_MonsterDies)
 860 {
 861         entity oldself;
 862         vector backuporigin;
 863
 864         monster_count -= 1;
 865         current_monsters -= 1;
 866         monsters_killed += 1;
 867
 868         if(IS_PLAYER(frag_attacker))
 869         {
 870                 PlayerScore_Add(frag_attacker, SP_TD_SCORE, autocvar_g_td_kill_points);
 871                 PlayerScore_Add(frag_attacker, SP_TD_KILLS, 1);
 872         }
 873         else if(IS_PLAYER(frag_attacker.realowner))
 874         if(frag_attacker.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 875         {
 876                 PlayerScore_Add(frag_attacker.realowner, SP_TD_SCORE, autocvar_g_td_turretkill_points);
 877                 PlayerScore_Add(frag_attacker.realowner, SP_TD_TURKILLS, 1);
 878         }
 879
 880         backuporigin = self.origin;
 881         oldself = self;
 882         self = spawn();
 883
 884         self.gravity = 1;
 885         setorigin(self, backuporigin + '0 0 5');
 886         spawn_td_fuel(oldself.drop_size);
 887         self.touch = M_Item_Touch;
 888         if(self == world)
 889         {
 890                 self = oldself;
 891                 return FALSE;
 892         }
 893         SUB_SetFade(self, time + autocvar_g_monsters_drop_time, 1);
 894
 895         self = oldself;
 896
 897         return FALSE;
 898 }
 899
 900 MUTATOR_HOOKFUNCTION(td_MonsterFindTarget)
 901 {
 902         float n_players = 0;
 903         entity player;
 904         local entity e;
 905
 906         FOR_EACH_PLAYER(player) { ++n_players; }
 907
 908         if(n_players < 1) // no players online, so do nothing
 909         {
 910                 self.enemy = world;
 911                 return TRUE;
 912         }
 913
 914         for(e = world;(e = findflags(e, monster_attack, TRUE)); )
 915         {
 916                 if(ignore_turrets)
 917                 if(e.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 918                         continue;
 919
 920                 if(monster_isvalidtarget(e, self))
 921                 if((vlen(trace_endpos - self.origin) < 200 && e.turrcaps_flags & TFL_TURRCAPS_ISTURRET) || (vlen(trace_endpos - self.origin) < 200 && !(e.flags & FL_GENERATOR)) || (vlen(trace_endpos - self.origin) < 500 && e.flags & FL_GENERATOR))
 922                 {
 923                         self.enemy = e;
 924                 }
 925         }
 926
 927         return TRUE;
 928 }
 929
 930 MUTATOR_HOOKFUNCTION(td_SetStartItems)
 931 {
 932         start_ammo_fuel = 150; // to be nice...
 933
 934         return FALSE;
 935 }
 936
 937 MUTATOR_HOOKFUNCTION(td_TurretSpawn)
 938 {
 939         if(self.realowner == world)
 940                 return TRUE; // wasn't spawned by a player
 941
 942         self.bot_attack = FALSE;
 943         buffturret(self, 0.5);
 944
 945         return FALSE;
 946 }
 947
 948 MUTATOR_HOOKFUNCTION(td_DisableVehicles)
 949 {
 950         // you shall not spawn!
 951         return TRUE;
 952 }
 953
 954 MUTATOR_HOOKFUNCTION(td_PlayerCommand)
 955 {
 956         if(MUTATOR_RETURNVALUE) { return FALSE; } // command was already handled?
 957
 958         makevectors(self.v_angle);
 959         WarpZone_TraceLine(self.origin, self.origin + v_forward * 100, MOVE_HITMODEL, self);
 960         entity targ = trace_ent;
 961         if(targ.owner.realowner == self)
 962                 targ = targ.owner;
 963
 964         if(cmd_name == "turretspawn")
 965         {
 966                 if(argv(1) == "list")
 967                 {
 968                         Send_Notification(NOTIF_ONE, self, MSG_MULTI, MULTI_TD_LIST, "mlrs walker plasma towerbuff flac barricade");
 969                         return TRUE;
 970                 }
 971                 if(!IS_PLAYER(self) || self.health <= 0)
 972                 {
 973                         Send_Notification(NOTIF_ONE, self, MSG_MULTI, MULTI_TD_CANTSPAWN);
 974                         return TRUE;
 975                 }
 976                 if(max_turrets <= 0)
 977                 {
 978                         Send_Notification(NOTIF_ONE, self, MSG_MULTI, MULTI_TD_DISABLED);
 979                         return TRUE;
 980                 }
 981                 if(self.turret_cnt >= max_turrets)
 982                 {
 983                         Send_Notification(NOTIF_ONE, self, MSG_MULTI, MULTI_TD_MAXTURRETS, max_turrets);
 984                         return TRUE;
 985                 }
 986
 987                 spawnturret(self, self, argv(1), trace_endpos);
 988
 989                 return TRUE;
 990         }
 991         if(cmd_name == "repairturret")
 992         {
 993                 if((targ.playerid != self.playerid || targ.realowner != self) || !(targ.turrcaps_flags & TFL_TURRCAPS_ISTURRET))
 994                 {
 995                         Send_Notification(NOTIF_ONE, self, MSG_MULTI, MULTI_TD_AIM_REPAIR);
 996                         return TRUE;
 997                 }
 998                 if(self.ammo_fuel < autocvar_g_td_turret_repair_cost)
 999                 {
1000                         Send_Notification(NOTIF_ONE, self, MSG_MULTI, MULTI_TD_NOFUEL_REPAIR, autocvar_g_td_turret_repair_cost);
1001                         return TRUE;
1002                 }
1003                 if(targ.health >= targ.max_health)
1004                 {
1005                         Send_Notification(NOTIF_ONE, self, MSG_MULTI, MULTI_TD_MAXHEALTH);
1006                         return TRUE;
1007                 }
1008
1009                 self.ammo_fuel -= autocvar_g_td_turret_repair_cost;
1010                 targ.SendFlags |= TNSF_STATUS;
1011                 targ.health = bound(1, targ.health + 100, targ.max_health);
1012                 WaypointSprite_UpdateHealth(targ.sprite, targ.health);
1013                 Send_Notification(NOTIF_ONE, self, MSG_MULTI, MULTI_TD_REPAIR);
1014
1015                 return TRUE;
1016         }
1017         if(cmd_name == "buffturret")
1018         {
1019                 if((targ.playerid != self.playerid || targ.realowner != self) || !(targ.turrcaps_flags & TFL_TURRCAPS_ISTURRET))
1020                 {
1021                         Send_Notification(NOTIF_ONE, self, MSG_MULTI, MULTI_TD_AIM_UPGRADE);
1022                         return TRUE;
1023                 }
1024                 if(self.ammo_fuel < autocvar_g_td_turret_upgrade_cost)
1025                 {
1026                         Send_Notification(NOTIF_ONE, self, MSG_MULTI, MULTI_TD_NOFUEL_UPGRADE, autocvar_g_td_turret_upgrade_cost);
1027                         return TRUE;
1028                 }
1029                 if(targ.turret_buff >= 5)
1030                 {
1031                         Send_Notification(NOTIF_ONE, self, MSG_MULTI, MULTI_TD_MAXPOWER);
1032                         return TRUE;
1033                 }
1034
1035                 self.ammo_fuel -= autocvar_g_td_turret_upgrade_cost;
1036                 targ.SendFlags |= TNSF_STATUS;
1037                 buffturret(targ, 1.2);
1038                 WaypointSprite_UpdateHealth(targ.sprite, targ.health);
1039                 Send_Notification(NOTIF_ONE, self, MSG_MULTI, MULTI_TD_UPGRADE);
1040
1041                 return TRUE;
1042         }
1043         if(cmd_name == "turretremove")
1044         {
1045                 if((targ.turrcaps_flags & TFL_TURRCAPS_ISTURRET) && (targ.playerid == self.playerid || targ.realowner == self))
1046                 {
1047                         self.turret_cnt -= 1;
1048                         Send_Notification(NOTIF_ONE, self, MSG_MULTI, MULTI_TD_REMOVE);
1049                         WaypointSprite_Kill(targ.sprite);
1050                         remove(targ.tur_head);
1051                         remove(targ);
1052                         return TRUE;
1053                 }
1054                 Send_Notification(NOTIF_ONE, self, MSG_MULTI, MULTI_TD_AIM_REMOVE);
1055                 return TRUE;
1056         }
1057
1058         return FALSE;
1059 }
1060
1061 MUTATOR_HOOKFUNCTION(td_ClientConnect)
1062 {
1063         entity t;
1064
1065         self.turret_cnt = 0;
1066
1067         for(t = world; (t = findflags(t, turrcaps_flags, TFL_TURRCAPS_ISTURRET)); )
1068         if(t.playerid == self.playerid)
1069         {
1070                 t.realowner = self;
1071                 self.turret_cnt += 1;
1072         }
1073
1074         return FALSE;
1075 }
1076
1077 MUTATOR_DEFINITION(gamemode_td)
1078 {
1079         MUTATOR_HOOK(MonsterSpawn, td_MonsterSpawn, CBC_ORDER_ANY);
1080         MUTATOR_HOOK(MonsterDies, td_MonsterDies, CBC_ORDER_ANY);
1081         MUTATOR_HOOK(MonsterMove, td_MonsterMove, CBC_ORDER_ANY);
1082         MUTATOR_HOOK(MonsterFindTarget, td_MonsterFindTarget, CBC_ORDER_ANY);
1083         MUTATOR_HOOK(MonsterCheckBossFlag, td_MonsterCheckBossFlag, CBC_ORDER_ANY);
1084         MUTATOR_HOOK(SetStartItems, td_SetStartItems, CBC_ORDER_ANY);
1085         MUTATOR_HOOK(TurretValidateTarget, td_TurretValidateTarget, CBC_ORDER_ANY);
1086         MUTATOR_HOOK(TurretSpawn, td_TurretSpawn, CBC_ORDER_ANY);
1087         MUTATOR_HOOK(TurretDies, td_TurretDies, CBC_ORDER_ANY);
1088         MUTATOR_HOOK(GiveFragsForKill, td_GiveFragsForKill, CBC_ORDER_ANY);
1089         MUTATOR_HOOK(PlayerPreThink, td_PlayerThink, CBC_ORDER_ANY);
1090         MUTATOR_HOOK(PlayerDies, td_PlayerDies, CBC_ORDER_ANY);
1091         MUTATOR_HOOK(PlayerDamage_Calculate, td_PlayerDamage, CBC_ORDER_ANY);
1092         MUTATOR_HOOK(PlayerSpawn, td_PlayerSpawn, CBC_ORDER_ANY);
1093         MUTATOR_HOOK(VehicleSpawn, td_DisableVehicles, CBC_ORDER_ANY);
1094         MUTATOR_HOOK(SV_ParseClientCommand, td_PlayerCommand, CBC_ORDER_ANY);
1095         MUTATOR_HOOK(ClientConnect, td_ClientConnect, CBC_ORDER_ANY);
1096
1097         MUTATOR_ONADD
1098         {
1099                 if(time > 1) // game loads at time 1
1100                         error("This is a game type and it cannot be added at runtime.");
1101                 cvar_settemp("g_monsters", "1");
1102                 cvar_settemp("g_turrets", "1");
1103                 td_Initialize();
1104         }
1105
1106         MUTATOR_ONROLLBACK_OR_REMOVE
1107         {
1108                 // we actually cannot roll back td_Initialize here
1109                 // BUT: we don't need to! If this gets called, adding always
1110                 // succeeds.
1111         }
1112
1113         MUTATOR_ONREMOVE
1114         {
1115                 error("This is a game type and it cannot be removed at runtime.");
1116                 return -1;
1117         }
1118
1119         return FALSE;
1120 }