qcsrc/server/mutators/gamemode_keyhunt.qc

   1 #define FOR_EACH_KH_KEY(v) for(v = kh_worldkeylist; v; v = v.kh_worldkeynext )
   2
   3 // #define KH_PLAYER_USE_ATTACHMENT
   4 // #define KH_PLAYER_USE_CARRIEDMODEL
   5
   6 #ifdef KH_PLAYER_USE_ATTACHMENT
   7 vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
   8 vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
   9 vector KH_PLAYER_ATTACHMENT = '0 0 0';
  10 vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  11 string KH_PLAYER_ATTACHMENT_BONE = "";
  12 #else
  13 float KH_KEY_ZSHIFT = 22;
  14 float KH_KEY_XYDIST = 24;
  15 float KH_KEY_XYSPEED = 45;
  16 #endif
  17 float KH_KEY_WP_ZSHIFT = 20;
  18
  19 vector KH_KEY_MIN = '-10 -10 -46';
  20 vector KH_KEY_MAX = '10 10 3';
  21 float KH_KEY_BRIGHTNESS = 2;
  22
  23 string kh_Controller_Waitmsg;
  24 float kh_no_radar_circles;
  25
  26 // kh_state
  27 //     bits  0- 4: team of key 1, or 0 for no such key, or 30 for dropped, or 31 for self
  28 //     bits  5- 9: team of key 2, or 0 for no such key, or 30 for dropped, or 31 for self
  29 //     bits 10-14: team of key 3, or 0 for no such key, or 30 for dropped, or 31 for self
  30 //     bits 15-19: team of key 4, or 0 for no such key, or 30 for dropped, or 31 for self
  31 .float kh_state;
  32 .float siren_time;  //  time delay the siren
  33 //.float stuff_time;  //  time delay to stuffcmd a cvar
  34
  35 float test[17] = {0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0};
  36 //test[0] = status of dropped keys, test[1 - 16] = player #
  37 //replace 17 with cvar("maxplayers") or similar !!!!!!!!!
  38 //for(i = 0; i < maxplayers; ++i)
  39 //      test[i] = "0";
  40
  41 float kh_Team_ByID(float t)
  42 {
  43         if(t == 0) return COLOR_TEAM1;
  44         if(t == 1) return COLOR_TEAM2;
  45         if(t == 2) return COLOR_TEAM3;
  46         if(t == 3) return COLOR_TEAM4;
  47         return 0;
  48 }
  49
  50 entity kh_worldkeylist;
  51 .entity kh_worldkeynext;
  52 entity kh_controller;
  53 float kh_tracking_enabled;
  54 float kh_teams;
  55 float kh_interferemsg_time, kh_interferemsg_team;
  56 .entity kh_next, kh_prev; // linked list
  57 .float kh_droptime;
  58 .float kh_dropperteam;
  59 .entity kh_previous_owner;
  60 .float kh_previous_owner_playerid;
  61 .float kh_cp_duration;
  62
  63 string kh_sound_capture = "kh/capture.wav";
  64 string kh_sound_destroy = "kh/destroy.wav";
  65 string kh_sound_drop = "kh/drop.wav";
  66 string kh_sound_collect = "kh/collect.wav";
  67 string kh_sound_alarm = "kh/alarm.wav";  // the new siren/alarm
  68
  69 float kh_key_dropped, kh_key_carried;
  70
  71 float kh_KeyCarrier_waypointsprite_visible_for_player(entity e)  // runs all the time
  72 {
  73         if(e.classname != "player" || self.team != e.team)
  74                 if(!kh_tracking_enabled)
  75                         return FALSE;
  76
  77         return TRUE;
  78 }
  79
  80 float kh_Key_waypointsprite_visible_for_player(entity e) // ??
  81 {
  82         if(!kh_tracking_enabled)
  83                 return FALSE;
  84         if(!self.owner)
  85                 return TRUE;
  86         if(!self.owner.owner)
  87                 return TRUE;
  88         return FALSE;  // draw only when key is not owned
  89 }
  90
  91 void kh_update_state()
  92 {
  93         entity player;
  94         entity key;
  95         float s;
  96         float f;
  97
  98         s = 0;
  99         FOR_EACH_KH_KEY(key)
 100         {
 101                 if(key.owner)
 102                         f = key.team;
 103                 else
 104                         f = 30;
 105                 s |= pow(32, key.count) * f;
 106         }
 107
 108         FOR_EACH_CLIENT(player)
 109         {
 110                 player.kh_state = s;
 111         }
 112
 113         FOR_EACH_KH_KEY(key)
 114         {
 115                 if(key.owner)
 116                         key.owner.kh_state |= pow(32, key.count) * 31;
 117         }
 118         //print(ftos((nextent(world)).kh_state), "\n");
 119 }
 120
 121
 122
 123
 124 var kh_Think_t kh_Controller_Thinkfunc;
 125 void kh_Controller_SetThink(float t, string msg, float centerprint_duration, kh_Think_t func)  // runs occasionaly
 126 {
 127         kh_Controller_Thinkfunc = func;
 128         kh_controller.cnt = ceil(t);
 129         if(kh_Controller_Waitmsg != "")
 130                 strunzone(kh_Controller_Waitmsg);
 131         if(msg == "")
 132                 kh_Controller_Waitmsg = "";
 133         else
 134         {
 135                 kh_controller.kh_cp_duration = centerprint_duration;
 136                 kh_Controller_Waitmsg = strzone(msg);
 137         }
 138         if(t == 0)
 139                 kh_controller.nextthink = time; // force
 140 }
 141 void kh_Controller_SetThink_NoMsg(float t, kh_Think_t func)  // runs occasionaly
 142 {
 143         kh_Controller_SetThink(t, "", 0, func);
 144 }
 145
 146 void kh_Controller_Think()  // called a lot
 147 {
 148         entity e;
 149         if(intermission_running)
 150                 return;
 151         if(self.cnt > 0)
 152         {
 153                 if(kh_Controller_Waitmsg != "")
 154                 {
 155                         string s;
 156                         if(substring(kh_Controller_Waitmsg, strlen(kh_Controller_Waitmsg)-1, 1) == " ")
 157                                 s = strcat(kh_Controller_Waitmsg, ftos(self.cnt));
 158                         else
 159                                 s = kh_Controller_Waitmsg;
 160
 161                         //dprint(s, "\n");
 162
 163                         FOR_EACH_PLAYER(e)
 164                                 if(clienttype(e) == CLIENTTYPE_REAL)
 165                                         Send_CSQC_Centerprint_Generic(e, CPID_KH_MSG, s, self.kh_cp_duration, 0);
 166                 }
 167                 self.cnt -= 1;
 168         }
 169         else if(self.cnt == 0)
 170         {
 171                 self.cnt -= 1;
 172                 kh_Controller_Thinkfunc();
 173         }
 174         self.nextthink = time + 1;
 175 }
 176
 177 // frags f: take from cvar * f
 178 // frags 0: no frags
 179 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)  // update the score when a key is captured
 180 {
 181         string s;
 182         if(intermission_running)
 183                 return;
 184
 185         if(frags_player)
 186                 UpdateFrags(player, frags_player);
 187
 188         if(key && key.owner && frags_owner)
 189                 UpdateFrags(key.owner, frags_owner);
 190
 191         if(!autocvar_sv_eventlog)  //output extra info to the console or text file
 192                 return;
 193
 194         s = strcat(":keyhunt:", what, ":", ftos(player.playerid), ":", ftos(frags_player));
 195
 196         if(key && key.owner)
 197                 s = strcat(s, ":", ftos(key.owner.playerid));
 198         else
 199                 s = strcat(s, ":0");
 200
 201         s = strcat(s, ":", ftos(frags_owner), ":");
 202
 203         if(key)
 204                 s = strcat(s, key.netname);
 205
 206         GameLogEcho(s);
 207 }
 208
 209 vector kh_AttachedOrigin(entity e)  // runs when a team captures the flag, it can run 2 or 3 times.
 210 {
 211         if(e.tag_entity)
 212         {
 213                 makevectors(e.tag_entity.angles);
 214                 return e.tag_entity.origin + e.origin_x * v_forward - e.origin_y * v_right + e.origin_z * v_up;
 215         }
 216         else
 217                 return e.origin;
 218 }
 219
 220 void kh_Key_Attach(entity key)  // runs when a player picks up a key and several times when a key is assigned to a player at the start of a round
 221 {
 222 #ifdef KH_PLAYER_USE_ATTACHMENT
 223         entity first;
 224         first = key.owner.kh_next;
 225         if(key == first)
 226         {
 227                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 228                 if(key.kh_next)
 229                 {
 230                         setattachment(key.kh_next, key, "");
 231                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 232                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 233                         key.kh_next.angles = '0 0 0';
 234                 }
 235                 else
 236                         setorigin(key, KH_PLAYER_ATTACHMENT);
 237                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 238         }
 239         else
 240         {
 241                 setattachment(key, key.kh_prev, "");
 242                 if(key.kh_next)
 243                         setattachment(key.kh_next, key, "");
 244                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 245                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 246                 key.angles = '0 0 0';
 247         }
 248 #else
 249         setattachment(key, key.owner, "");
 250         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT);  // fixing x, y in think
 251         key.angles_y -= key.owner.angles_y;
 252 #endif
 253         key.flags = 0;
 254         key.solid = SOLID_NOT;
 255         key.movetype = MOVETYPE_NONE;
 256         key.team = key.owner.team;
 257         key.nextthink = time;
 258         key.damageforcescale = 0;
 259         key.takedamage = DAMAGE_NO;
 260         key.modelindex = kh_key_carried;
 261 }
 262
 263 void kh_Key_Detach(entity key) // runs every time a key is dropped or lost. Runs several times times when all the keys are captured
 264 {
 265 #ifdef KH_PLAYER_USE_ATTACHMENT
 266         entity first;
 267         first = key.owner.kh_next;
 268         if(key == first)
 269         {
 270                 if(key.kh_next)
 271                 {
 272                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 273                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 274                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 275                 }
 276         }
 277         else
 278         {
 279                 if(key.kh_next)
 280                         setattachment(key.kh_next, key.kh_prev, "");
 281                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 282         }
 283         // in any case:
 284         setattachment(key, world, "");
 285         setorigin(key, key.owner.origin + '0 0 1' * (PL_MIN_z - KH_KEY_MIN_z));
 286         key.angles = key.owner.angles;
 287 #else
 288         setorigin(key, key.owner.origin + key.origin_z * '0 0 1');
 289         setattachment(key, world, "");
 290         key.angles_y += key.owner.angles_y;
 291 #endif
 292         key.flags = FL_ITEM;
 293         key.solid = SOLID_TRIGGER;
 294         key.movetype = MOVETYPE_TOSS;
 295         key.pain_finished = time + autocvar_g_balance_keyhunt_delay_return;
 296         key.damageforcescale = autocvar_g_balance_keyhunt_damageforcescale;
 297         key.takedamage = DAMAGE_YES;
 298         // let key.team stay
 299         key.modelindex = kh_key_dropped;
 300         key.kh_previous_owner = key.owner;
 301         key.kh_previous_owner_playerid = key.owner.playerid;
 302 }
 303
 304 void kh_Key_AssignTo(entity key, entity player)  // runs every time a key is picked up or assigned. Runs prior to kh_key_attach
 305 {
 306         entity k;
 307         float ownerteam0, ownerteam;
 308         if(key.owner == player)
 309                 return;
 310
 311         ownerteam0 = kh_Key_AllOwnedByWhichTeam();
 312
 313         if(key.owner)
 314         {
 315                 kh_Key_Detach(key);
 316
 317                 // remove from linked list
 318                 if(key.kh_next)
 319                         key.kh_next.kh_prev = key.kh_prev;
 320                 key.kh_prev.kh_next = key.kh_next;
 321                 key.kh_next = world;
 322                 key.kh_prev = world;
 323
 324                 if(key.owner.kh_next == world)
 325                 {
 326                         // No longer a key carrier
 327                         if(!kh_no_radar_circles)
 328                                 WaypointSprite_Ping(key.owner.waypointsprite_attachedforcarrier);
 329                         WaypointSprite_DetachCarrier(key.owner);
 330                 }
 331         }
 332
 333         key.owner = player;
 334
 335         if(player)
 336         {
 337                 // insert into linked list
 338                 key.kh_next = player.kh_next;
 339                 key.kh_prev = player;
 340                 player.kh_next = key;
 341                 if(key.kh_next)
 342                         key.kh_next.kh_prev = key;
 343
 344                 float i;
 345                 i = test[key.owner.playerid];
 346                         if(key.netname == "^1red key")
 347                                 i += 1;
 348                         if(key.netname == "^4blue key")
 349                                 i += 2;
 350                         if(key.netname == "^3yellow key")
 351                                 i += 4;
 352                         if(key.netname == "^6pink key")
 353                                 i += 8;
 354                 test[key.owner.playerid] = i;
 355
 356                 kh_Key_Attach(key);
 357
 358                 if(key.kh_next == world)
 359                 {
 360                         // player is now a key carrier
 361                         WaypointSprite_AttachCarrier("", player, RADARICON_FLAGCARRIER, colormapPaletteColor(player.team - 1, 0));
 362                         player.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_KeyCarrier_waypointsprite_visible_for_player;
 363                         WaypointSprite_UpdateRule(player.waypointsprite_attachedforcarrier, player.team, SPRITERULE_TEAMPLAY);
 364                         if(player.team == COLOR_TEAM1)
 365                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-red", "keycarrier-friend", "keycarrier-red");
 366                         else if(player.team == COLOR_TEAM2)
 367                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-blue", "keycarrier-friend", "keycarrier-blue");
 368                         else if(player.team == COLOR_TEAM3)
 369                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-yellow", "keycarrier-friend", "keycarrier-yellow");
 370                         else if(player.team == COLOR_TEAM4)
 371                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-pink", "keycarrier-friend", "keycarrier-pink");
 372                         if(!kh_no_radar_circles)
 373                                 WaypointSprite_Ping(player.waypointsprite_attachedforcarrier);
 374                 }
 375         }
 376
 377         // moved that here, also update if there's no player
 378         kh_update_state();
 379
 380         key.pusher = world;
 381
 382         ownerteam = kh_Key_AllOwnedByWhichTeam();
 383         if(ownerteam != ownerteam0)
 384         {
 385                 if(ownerteam != -1)
 386                 {
 387                         kh_interferemsg_time = time + 0.2;
 388                         kh_interferemsg_team = player.team;
 389
 390                         // audit all key carrier sprites, update them to RUN HERE
 391                         FOR_EACH_KH_KEY(k)
 392                         {
 393                                 if(k.owner)
 394                                         WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, k.owner.waypointsprite_attachedforcarrier.model1, "keycarrier-finish", k.owner.waypointsprite_attachedforcarrier.model3);
 395                         }
 396                 }
 397                 else
 398                 {
 399                         kh_interferemsg_time = 0;
 400
 401                         // audit all key carrier sprites, update them to RUN HERE
 402                         FOR_EACH_KH_KEY(k)
 403                         {
 404                                 if(k.owner)
 405                                         WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, k.owner.waypointsprite_attachedforcarrier.model1, "keycarrier-friend", k.owner.waypointsprite_attachedforcarrier.model3);
 406                         }
 407                 }
 408         }
 409 }
 410
 411 void kh_Key_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 412 {
 413         if(self.owner)
 414                 return;
 415         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 416         {
 417                 // touching lava, or hurt trigger
 418                 // what shall we do?
 419                 // immediately return is bad
 420                 // maybe start a shorter countdown?
 421         }
 422         if(vlen(force) <= 0)
 423                 return;
 424         if(time > self.pushltime)
 425                 if(attacker.classname == "player")
 426                         self.team = attacker.team;
 427 }
 428
 429 void kh_Key_Collect(entity key, entity player)  //a player picks up a dropped key
 430 {
 431         sound(player, CH_TRIGGER, kh_sound_collect, VOL_BASE, ATTN_NORM);
 432
 433         if(key.kh_dropperteam != player.team)
 434         {
 435                 kh_Scores_Event(player, key, "collect", autocvar_g_balance_keyhunt_score_collect, 0);
 436                 PlayerScore_Add(player, SP_KH_PICKUPS, 1);
 437         }
 438         key.kh_dropperteam = 0;
 439         bprint(player.netname, "^7 picked up the ", key.netname, "\n");
 440
 441         kh_Key_AssignTo(key, player); // this also updates .kh_state
 442 }
 443
 444 void kh_Key_Touch()  // runs many, many times when a key has been dropped and can be picked up
 445 {
 446         if(intermission_running)
 447                 return;
 448
 449         if(self.owner) // already carried
 450                 return;
 451
 452         if(ITEM_TOUCH_NEEDKILL())
 453         {
 454                 // touching sky, or nodrop
 455                 // what shall we do?
 456                 // immediately return is bad
 457                 // maybe start a shorter countdown?
 458         }
 459
 460         if(other.classname != "player")
 461                 return;
 462         if(other.deadflag != DEAD_NO)
 463                 return;
 464         if(other == self.enemy)
 465                 if(time < self.kh_droptime + autocvar_g_balance_keyhunt_delay_collect)
 466                         return;  // you just dropped it!
 467         kh_Key_Collect(self, other);
 468 }
 469
 470 void kh_Key_Remove(entity key)  // runs after when all the keys have been collected or when a key has been dropped for more than X seconds
 471 {
 472         entity o;
 473         o = key.owner;
 474         kh_Key_AssignTo(key, world);
 475         if(o) // it was attached
 476                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 477         else // it was dropped
 478                 WaypointSprite_DetachCarrier(key);
 479
 480         // remove key from key list
 481         if (kh_worldkeylist == key)
 482                 kh_worldkeylist = kh_worldkeylist.kh_worldkeynext;
 483         else
 484         {
 485                 o = kh_worldkeylist;
 486                 while (o)
 487                 {
 488                         if (o.kh_worldkeynext == key)
 489                         {
 490                                 o.kh_worldkeynext = o.kh_worldkeynext.kh_worldkeynext;
 491                                 break;
 492                         }
 493                         o = o.kh_worldkeynext;
 494                 }
 495         }
 496
 497         remove(key);
 498
 499         kh_update_state();
 500 }
 501
 502 void kh_FinishRound()  // runs when a team captures the keys
 503 {
 504         // prepare next round
 505         kh_interferemsg_time = 0;
 506         entity key;
 507
 508         kh_no_radar_circles = TRUE;
 509         FOR_EACH_KH_KEY(key)
 510                 kh_Key_Remove(key);
 511         kh_no_radar_circles = FALSE;
 512
 513         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round, "Round starts in ", 1, kh_StartRound);
 514 }
 515
 516 void kh_WinnerTeam(float teem)  // runs when a team wins
 517 {
 518         // all key carriers get some points
 519         vector firstorigin, lastorigin, midpoint;
 520         float first;
 521         entity key;
 522         float score;
 523         score = (kh_teams - 1) * autocvar_g_balance_keyhunt_score_capture;
 524         DistributeEvenly_Init(score, kh_teams);
 525         // twice the score for 3 team games, three times the score for 4 team games!
 526         // note: for a win by destroying the key, this should NOT be applied
 527         FOR_EACH_KH_KEY(key)
 528         {
 529                 float f;
 530                 f = DistributeEvenly_Get(1);
 531                 kh_Scores_Event(key.owner, key, "capture", f, 0);
 532                 PlayerTeamScore_Add(key.owner, SP_KH_CAPS, ST_KH_CAPS, 1);
 533         }
 534
 535         first = TRUE;
 536         FOR_EACH_KH_KEY(key)
 537                 if(key.owner.kh_next == key)
 538                 {
 539                         if(!first)
 540                                 bprint("^7, ");
 541                         bprint(key.owner.netname);
 542                         first = FALSE;
 543                 }
 544         bprint("^7 captured the keys for the ", ColoredTeamName(teem), "\n");
 545
 546         first = TRUE;
 547         midpoint = '0 0 0';
 548         FOR_EACH_KH_KEY(key)
 549         {
 550                 vector thisorigin;
 551
 552                 thisorigin = kh_AttachedOrigin(key);
 553                 //dprint("Key origin: ", vtos(thisorigin), "\n");
 554                 midpoint += thisorigin;
 555
 556                 if(!first)
 557                         te_lightning2(world, lastorigin, thisorigin);
 558                 lastorigin = thisorigin;
 559                 if(first)
 560                         firstorigin = thisorigin;
 561                 first = FALSE;
 562         }
 563         if(kh_teams > 2)
 564         {
 565                 te_lightning2(world, lastorigin, firstorigin);
 566         }
 567         midpoint = midpoint * (1 / kh_teams);
 568         te_customflash(midpoint, 1000, 1, TeamColor(teem) * 0.5 + '0.5 0.5 0.5');  // make the color >=0.5 in each component
 569
 570         play2all(kh_sound_capture);
 571         kh_FinishRound();
 572 }
 573
 574 void kh_LoserTeam(float teem, entity lostkey)  // runs when a player pushes a flag carrier off the map
 575 {
 576         entity player, key, attacker;
 577         float players;
 578         float keys;
 579         float f;
 580
 581         attacker = world;
 582         if(lostkey.pusher)
 583                 if(lostkey.pusher.team != teem)
 584                         if(lostkey.pusher.classname == "player")
 585                                 attacker = lostkey.pusher;
 586
 587         players = keys = 0;
 588
 589         if(attacker)
 590         {
 591                 if(lostkey.kh_previous_owner)
 592                         kh_Scores_Event(lostkey.kh_previous_owner, world, "pushed", 0, -autocvar_g_balance_keyhunt_score_push);
 593                         // don't actually GIVE him the -nn points, just log
 594                 kh_Scores_Event(attacker, world, "push", autocvar_g_balance_keyhunt_score_push, 0);
 595                 PlayerScore_Add(attacker, SP_KH_PUSHES, 1);
 596                 centerprint(attacker, "Your push is the best!");
 597                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "^7 when ", attacker.netname, "^7 came\n");
 598         }
 599         else
 600         {
 601                 float of, fragsleft, i, j, thisteam;
 602                 of = autocvar_g_balance_keyhunt_score_destroyed_ownfactor;
 603
 604                 FOR_EACH_PLAYER(player)
 605                         if(player.team != teem)
 606                                 ++players;
 607
 608                 FOR_EACH_KH_KEY(key)
 609                         if(key.owner && key.team != teem)
 610                                 ++keys;
 611
 612                 if(lostkey.kh_previous_owner)
 613                         kh_Scores_Event(lostkey.kh_previous_owner, world, "destroyed", 0, -autocvar_g_balance_keyhunt_score_destroyed);
 614                         // don't actually GIVE him the -nn points, just log
 615
 616                 if(lostkey.kh_previous_owner.playerid == lostkey.kh_previous_owner_playerid)
 617                         PlayerScore_Add(lostkey.kh_previous_owner, SP_KH_DESTROYS, 1);
 618
 619                 DistributeEvenly_Init(autocvar_g_balance_keyhunt_score_destroyed, keys * of + players);
 620
 621                 FOR_EACH_KH_KEY(key)
 622                         if(key.owner && key.team != teem)
 623                         {
 624                                 f = DistributeEvenly_Get(of);
 625                                 kh_Scores_Event(key.owner, world, "destroyed_holdingkey", f, 0);
 626                         }
 627
 628                 fragsleft = DistributeEvenly_Get(players);
 629
 630                 // Now distribute these among all other teams...
 631                 j = kh_teams - 1;
 632                 for(i = 0; i < kh_teams; ++i)
 633                 {
 634                         thisteam = kh_Team_ByID(i);
 635                         if(thisteam == teem) // bad boy, no cookie - this WILL happen
 636                                 continue;
 637
 638                         players = 0;
 639                         FOR_EACH_PLAYER(player)
 640                                 if(player.team == thisteam)
 641                                         ++players;
 642
 643                         DistributeEvenly_Init(fragsleft, j);
 644                         fragsleft = DistributeEvenly_Get(j - 1);
 645                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 646
 647                         FOR_EACH_PLAYER(player)
 648                                 if(player.team == thisteam)
 649                                 {
 650                                         f = DistributeEvenly_Get(1);
 651                                         kh_Scores_Event(player, world, "destroyed", f, 0);
 652                                 }
 653
 654                         --j;
 655                 }
 656
 657                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 658         }
 659         play2all(kh_sound_destroy);
 660         te_tarexplosion(lostkey.origin);
 661
 662         kh_FinishRound();
 663 }
 664
 665 void kh_Key_Think()  // runs all the time
 666 {
 667         entity head;
 668         //entity player;  // needed by FOR_EACH_PLAYER
 669
 670         if(intermission_running)
 671                 return;
 672
 673         if(self.owner)
 674         {
 675 #ifndef KH_PLAYER_USE_ATTACHMENT
 676                 makevectors('0 1 0' * (self.cnt + mod(time, 360) * KH_KEY_XYSPEED));
 677                 setorigin(self, v_forward * KH_KEY_XYDIST + '0 0 1' * self.origin_z);
 678 #endif
 679         }
 680
 681         // if in nodrop or time over, end the round
 682         if(!self.owner)
 683                 if(time > self.pain_finished)
 684                         kh_LoserTeam(self.team, self);
 685
 686         if(self.owner)
 687         if(kh_Key_AllOwnedByWhichTeam() != -1)
 688         {
 689                 if(self.siren_time < time)
 690                 {
 691                         sound(self.owner, CH_TRIGGER, kh_sound_alarm, VOL_BASE, ATTN_NORM);  // play a simple alarm
 692                         self.siren_time = time + 2.5;  // repeat every 2.5 seconds
 693                 }
 694
 695                 entity key;
 696                 vector p;
 697                 p = self.owner.origin;
 698                 FOR_EACH_KH_KEY(key)
 699                         if(vlen(key.owner.origin - p) > autocvar_g_balance_keyhunt_maxdist)
 700                                 goto not_winning;
 701                 kh_WinnerTeam(self.team);
 702 :not_winning
 703         }
 704
 705         if(kh_interferemsg_time && time > kh_interferemsg_time)
 706         {
 707                 kh_interferemsg_time = 0;
 708                 FOR_EACH_PLAYER(head)
 709                 {
 710                         if(head.team == kh_interferemsg_team)
 711                                 if(head.kh_next)
 712                                         Send_CSQC_Centerprint_Generic(head, CPID_KH_MSG, "All keys are in your team's hands!\n\nMeet the other key carriers ^1NOW^7!", 0, 0);
 713                                 else
 714                                         Send_CSQC_Centerprint_Generic(head, CPID_KH_MSG, "All keys are in your team's hands!\n\nHelp the key carriers to meet!", 0, 0);
 715                         else
 716                                 Send_CSQC_Centerprint_Generic(head, CPID_KH_MSG, strcat("All keys are in the ", ColoredTeamName(kh_interferemsg_team), "^7's hands!\n\nInterfere ^1NOW^7!"), 0, 0);
 717                 }
 718         }
 719
 720         self.nextthink = time + 0.05;
 721 }
 722
 723 void key_reset()
 724 {
 725         kh_Key_AssignTo(self, world);
 726         kh_Key_Remove(self);
 727 }
 728
 729 string STR_ITEM_KH_KEY = "item_kh_key";
 730 void kh_Key_Spawn(entity initial_owner, float angle, float i)  // runs every time a new flag is created, ie after all the keys have been collected
 731 {
 732         entity key;
 733         key = spawn();
 734         key.count = i;
 735         key.classname = STR_ITEM_KH_KEY;
 736         key.touch = kh_Key_Touch;
 737         key.think = kh_Key_Think;
 738         key.nextthink = time;
 739         key.items = IT_KEY1 | IT_KEY2;
 740         key.cnt = angle;
 741         key.angles = '0 360 0' * random();
 742         key.event_damage = kh_Key_Damage;
 743         key.takedamage = DAMAGE_YES;
 744         key.modelindex = kh_key_dropped;
 745         key.model = "key";
 746         key.kh_dropperteam = 0;
 747         key.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 748         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 749         key.colormod = TeamColor(initial_owner.team) * KH_KEY_BRIGHTNESS;
 750         key.reset = key_reset;
 751
 752         switch(initial_owner.team)
 753         {
 754                 case COLOR_TEAM1:
 755                         key.netname = "^1red key";
 756                         break;
 757                 case COLOR_TEAM2:
 758                         key.netname = "^4blue key";
 759                         break;
 760                 case COLOR_TEAM3:
 761                         key.netname = "^3yellow key";
 762                         break;
 763                 case COLOR_TEAM4:
 764                         key.netname = "^6pink key";
 765                         break;
 766                 default:
 767                         key.netname = "NETGIER key";
 768                         break;
 769         }
 770
 771         // link into key list
 772         key.kh_worldkeynext = kh_worldkeylist;
 773         kh_worldkeylist = key;
 774
 775         centerprint(initial_owner, strcat("You are starting with the ", key.netname, "\n"));  // message to player at start of round
 776
 777         WaypointSprite_Spawn("key-dropped", 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, world, key.team, key, waypointsprite_attachedforcarrier, FALSE, RADARICON_FLAG, '0 1 1');
 778         key.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_Key_waypointsprite_visible_for_player;
 779
 780         kh_Key_AssignTo(key, initial_owner);
 781 }
 782
 783 // -1 when no team completely owns all keys yet
 784 float kh_Key_AllOwnedByWhichTeam()  // constantly called. check to see if all the keys are owned by the same team
 785 {
 786         entity key;
 787         float teem;
 788         float keys;
 789
 790         teem = -1;
 791         keys = kh_teams;
 792         FOR_EACH_KH_KEY(key)
 793         {
 794                 if(!key.owner)
 795                         return -1;
 796                 if(teem == -1)
 797                         teem = key.team;
 798                 else if(teem != key.team)
 799                         return -1;
 800                 --keys;
 801         }
 802         if(keys != 0)
 803                 return -1;
 804         return teem;
 805 }
 806
 807 void kh_Key_DropOne(entity key)
 808 {
 809         // prevent collecting this one for some time
 810         entity player;
 811         player = key.owner;
 812
 813         key.kh_droptime = time;
 814         key.enemy = player;
 815
 816         kh_Scores_Event(player, key, "dropkey", 0, 0);
 817         PlayerScore_Add(player, SP_KH_LOSSES, 1);
 818         bprint(player.netname, "^7 dropped the ", key.netname, "\n");
 819         kh_Key_AssignTo(key, world);
 820         makevectors(player.v_angle);
 821         key.velocity = W_CalculateProjectileVelocity(player.velocity, autocvar_g_balance_keyhunt_throwvelocity * v_forward, FALSE);
 822         key.pusher = world;
 823         key.pushltime = time + autocvar_g_balance_keyhunt_protecttime;
 824         key.kh_dropperteam = key.team;
 825
 826         sound(player, CH_TRIGGER, kh_sound_drop, VOL_BASE, ATTN_NORM);
 827 }
 828
 829 void kh_Key_DropAll(entity player, float suicide) // runs whenever a player dies
 830 {
 831         entity key;
 832         entity mypusher;
 833         if(player.kh_next)
 834         {
 835                 mypusher = world;
 836                 if(player.pusher)
 837                         if(time < player.pushltime)
 838                                 mypusher = player.pusher;
 839                 while((key = player.kh_next))
 840                 {
 841                         kh_Scores_Event(player, key, "losekey", 0, 0);
 842                         PlayerScore_Add(player, SP_KH_LOSSES, 1);
 843                         bprint(player.netname, "^7 died and lost the ", key.netname, "\n");
 844                         kh_Key_AssignTo(key, world);
 845                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 846                         key.velocity = W_CalculateProjectileVelocity(player.velocity, autocvar_g_balance_keyhunt_dropvelocity * v_forward, FALSE);
 847                         key.pusher = mypusher;
 848                         key.pushltime = time + autocvar_g_balance_keyhunt_protecttime;
 849                         if(suicide)
 850                                 key.kh_dropperteam = player.team;
 851                 }
 852                 sound(player, CH_TRIGGER, kh_sound_drop, VOL_BASE, ATTN_NORM);
 853         }
 854 }
 855
 856 string kh_CheckEnoughPlayers()  // checks enough player are present, runs after every completed round
 857 {
 858         float i, players, teem;
 859         entity player;
 860         string result;
 861         result = "";
 862
 863         // find a random player per team
 864         for(i = 0; i < kh_teams; ++i)
 865         {
 866                 teem = kh_Team_ByID(i);
 867                 players = 0;
 868                 FOR_EACH_PLAYER(player)
 869                         if(player.deadflag == DEAD_NO)
 870                                 if(!player.BUTTON_CHAT)
 871                                         if(player.team == teem)
 872                                                 ++players;
 873                 if(players == 0)
 874                 {
 875                         if(result != "")
 876                                 result = strcat(result, ", ");
 877                         result = strcat(result, ColoredTeamName(teem));
 878                 }
 879         }
 880         return result;
 881 }
 882
 883 void kh_WaitForPlayers()  // delay start of the round until enough players are present
 884 {
 885         string teams_missing;
 886
 887         if(time < game_starttime)
 888         {
 889                 kh_Controller_SetThink_NoMsg(game_starttime - time + 0.1, kh_WaitForPlayers);
 890                 return;
 891         }
 892
 893         teams_missing = kh_CheckEnoughPlayers();
 894         if(teams_missing == "")
 895                 kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round, "Round starts in ", 1, kh_StartRound);
 896         else
 897                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), -1, kh_WaitForPlayers);
 898 }
 899
 900 void kh_EnableTrackingDevice()  // runs after each round
 901 {
 902         entity player;
 903
 904         FOR_EACH_PLAYER(player)
 905                 if(clienttype(player) == CLIENTTYPE_REAL)
 906                         Send_CSQC_Centerprint_Generic_Expire(player, CPID_KH_MSG);
 907
 908         kh_tracking_enabled = TRUE;
 909 }
 910
 911 void kh_StartRound()  // runs at the start of each round
 912 {
 913         string teams_missing;
 914         float i, players, teem;
 915         entity player;
 916
 917         if(time < game_starttime)
 918         {
 919                 kh_Controller_SetThink_NoMsg(game_starttime - time + 0.1, kh_WaitForPlayers);
 920                 return;
 921         }
 922
 923         teams_missing = kh_CheckEnoughPlayers();
 924         if(teams_missing != "")
 925         {
 926                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), -1, kh_WaitForPlayers);
 927                 return;
 928         }
 929
 930         FOR_EACH_PLAYER(player)
 931                 if(clienttype(player) == CLIENTTYPE_REAL)
 932                         Send_CSQC_Centerprint_Generic_Expire(player, CPID_KH_MSG);
 933
 934         for(i = 0; i < kh_teams; ++i)
 935         {
 936                 teem = kh_Team_ByID(i);
 937                 players = 0;
 938                 entity my_player;
 939                 FOR_EACH_PLAYER(player)
 940                         if(player.deadflag == DEAD_NO)
 941                                 if(!player.BUTTON_CHAT)
 942                                         if(player.team == teem)
 943                                         {
 944                                                 ++players;
 945                                                 if(random() * players <= 1)
 946                                                         my_player = player;
 947                                         }
 948                 kh_Key_Spawn(my_player, 360 * i / kh_teams, i);
 949         }
 950
 951         kh_tracking_enabled = FALSE;
 952         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_tracking, "Scanning frequency range...", -1, kh_EnableTrackingDevice);
 953 }
 954
 955 float kh_HandleFrags(entity attacker, entity targ, float f)  // adds to the player score
 956 {
 957         if(attacker == targ)
 958                 return f;
 959
 960         if(targ.kh_next)
 961         {
 962                 if(attacker.team == targ.team)
 963                 {
 964                         entity k;
 965                         float nk;
 966                         nk = 0;
 967                         for(k = targ.kh_next; k != world; k = k.kh_next)
 968                                 ++nk;
 969                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", -nk * autocvar_g_balance_keyhunt_score_collect, 0);
 970                 }
 971                 else
 972                 {
 973                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", autocvar_g_balance_keyhunt_score_carrierfrag-1, 0);
 974                         PlayerScore_Add(attacker, SP_KH_KCKILLS, 1);
 975                         // the frag gets added later
 976                 }
 977         }
 978
 979         return f;
 980 }
 981
 982 void kh_Initialize()  // sets up th KH environment
 983 {
 984         precache_sound(kh_sound_capture);
 985         precache_sound(kh_sound_destroy);
 986         precache_sound(kh_sound_drop);
 987         precache_sound(kh_sound_collect);
 988         precache_sound(kh_sound_alarm);  // the new siren
 989
 990 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 991         precache_model("models/keyhunt/key-carried.md3");
 992 #endif
 993         precache_model("models/keyhunt/key.md3");
 994
 995         // setup variables
 996         kh_teams = autocvar_g_keyhunt_teams_override;
 997         if(kh_teams < 2)
 998                 kh_teams = autocvar_g_keyhunt_teams;
 999         kh_teams = bound(2, kh_teams, 4);
1000
1001         // make a KH entity for controlling the game
1002         kh_controller = spawn();
1003         kh_controller.think = kh_Controller_Think;
1004         kh_Controller_SetThink_NoMsg(0, kh_WaitForPlayers);
1005
1006         setmodel(kh_controller, "models/keyhunt/key.md3");
1007         kh_key_dropped = kh_controller.modelindex;
1008         /*
1009         dprint(vtos(kh_controller.mins));
1010         dprint(vtos(kh_controller.maxs));
1011         dprint("\n");
1012         */
1013 #ifdef KH_PLAYER_USE_CARRIEDMODEL
1014         setmodel(kh_controller, "models/keyhunt/key-carried.md3");
1015         kh_key_carried = kh_controller.modelindex;
1016 #else
1017         kh_key_carried = kh_key_dropped;
1018 #endif
1019
1020         kh_controller.model = "";
1021         kh_controller.modelindex = 0;
1022
1023         addstat(STAT_KH_KEYS, AS_INT, kh_state);
1024
1025         ScoreRules_kh(kh_teams);
1026 }
1027
1028 void kh_finalize()
1029 {
1030         // to be called before intermission
1031         kh_FinishRound();
1032         remove(kh_controller);
1033         kh_controller = world;
1034 }
1035
1036 // register this as a mutator
1037
1038 MUTATOR_HOOKFUNCTION(kh_Key_DropAll)
1039 {
1040         kh_Key_DropAll(self, TRUE);
1041         return 0;
1042 }
1043
1044 MUTATOR_HOOKFUNCTION(kh_PlayerDies)
1045 {
1046         if(self == other)
1047                 kh_Key_DropAll(self, TRUE);
1048         else if(other.classname == "player")
1049                 kh_Key_DropAll(self, FALSE);
1050         else
1051                 kh_Key_DropAll(self, TRUE);
1052         return 0;
1053 }
1054
1055 MUTATOR_HOOKFUNCTION(kh_GiveFragsForKill)
1056 {
1057         frag_score = kh_HandleFrags(frag_attacker, frag_target, frag_score);
1058         return 0;
1059 }
1060
1061 MUTATOR_HOOKFUNCTION(kh_finalize)
1062 {
1063         kh_finalize();
1064         return 0;
1065 }
1066
1067 MUTATOR_HOOKFUNCTION(kh_GetTeamCount)
1068 {
1069         ret_float = kh_teams;
1070         return 0;
1071 }
1072
1073 MUTATOR_HOOKFUNCTION(kh_SpectateCopy)
1074 {
1075         self.kh_state = other.kh_state;
1076         return 0;
1077 }
1078
1079 MUTATOR_HOOKFUNCTION(kh_PlayerUseKey)
1080 {
1081         if(MUTATOR_RETURNVALUE == 0)
1082         {
1083                 entity k;
1084                 k = self.kh_next;
1085                 if(k)
1086                 {
1087                         kh_Key_DropOne(k);
1088                         return 1;
1089                 }
1090         }
1091         return 0;
1092 }
1093
1094 MUTATOR_DEFINITION(gamemode_keyhunt)
1095 {
1096         MUTATOR_HOOK(MakePlayerObserver, kh_Key_DropAll, CBC_ORDER_ANY);
1097         MUTATOR_HOOK(ClientDisconnect, kh_Key_DropAll, CBC_ORDER_ANY);
1098         MUTATOR_HOOK(PlayerDies, kh_PlayerDies, CBC_ORDER_ANY);
1099         MUTATOR_HOOK(GiveFragsForKill, kh_GiveFragsForKill, CBC_ORDER_FIRST);
1100         MUTATOR_HOOK(MatchEnd, kh_finalize, CBC_ORDER_ANY);
1101         MUTATOR_HOOK(GetTeamCount, kh_GetTeamCount, CBC_ORDER_EXCLUSIVE);
1102         MUTATOR_HOOK(SpectateCopy, kh_SpectateCopy, CBC_ORDER_ANY);
1103         MUTATOR_HOOK(PlayerUseKey, kh_PlayerUseKey, CBC_ORDER_ANY);
1104
1105         MUTATOR_ONADD
1106         {
1107                 if(time > 1) // game loads at time 1
1108                         error("This is a game type and it cannot be added at runtime.");
1109                 g_keyhunt = 1;
1110                 kh_Initialize();
1111         }
1112
1113         MUTATOR_ONREMOVE
1114         {
1115                 g_keyhunt = 0;
1116                 error("This is a game type and it cannot be removed at runtime.");
1117         }
1118
1119         return 0;
1120 }