qcsrc/server/mutators/gamemode_invasion.qc

   1 void invasion_spawnpoint()
   2 {
   3         if not(g_invasion) { remove(self); return; }
   4
   5         self.classname = "invasion_spawnpoint";
   6 }
   7
   8 float invasion_PickMonster()
   9 {
  10         if(autocvar_g_invasion_zombies_only)
  11                 return MONSTER_ZOMBIE;
  12
  13         float i;
  14
  15         RandomSelection_Init();
  16
  17         for(i = MONSTER_FIRST + 1; i < MONSTER_LAST; ++i)
  18         {
  19                 if(i == MONSTER_STINGRAY || i == MONSTER_WYVERN)
  20                         continue; // flying/swimming monsters not yet supported
  21
  22                 RandomSelection_Add(world, i, "", 1, 1);
  23         }
  24
  25         return RandomSelection_chosen_float;
  26 }
  27
  28 entity invasion_PickSpawn()
  29 {
  30         entity e;
  31
  32         RandomSelection_Init();
  33
  34         for(e = world;(e = find(e, classname, "invasion_spawnpoint")); )
  35                 RandomSelection_Add(e, 0, string_null, 1, 1);
  36
  37         return RandomSelection_chosen_ent;
  38 }
  39
  40 void invasion_SpawnChosenMonster(float mon)
  41 {
  42         entity spawn_point, monster;
  43
  44         spawn_point = invasion_PickSpawn();
  45
  46         if(spawn_point == world)
  47         {
  48                 dprint("Warning: couldn't find any invasion_spawnpoint spawnpoints, no monsters will spawn!\n");
  49                 return;
  50         }
  51
  52         monster = spawnmonster("", mon, spawn_point, spawn_point, spawn_point.origin, FALSE, 2);
  53 }
  54
  55 void invasion_SpawnMonsters()
  56 {
  57         float chosen_monster = invasion_PickMonster();
  58
  59         invasion_SpawnChosenMonster(chosen_monster);
  60 }
  61
  62 float Invasion_CheckWinner()
  63 {
  64         entity head;
  65         if(round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0)
  66         {
  67                 FOR_EACH_MONSTER(head)
  68                 {
  69                         WaypointSprite_Kill(head.sprite);
  70                         if(head.weaponentity) remove(head.weaponentity);
  71                         remove(head);
  72                 }
  73
  74                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_OVER);
  75                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_OVER);
  76                 round_handler_Init(5, autocvar_g_invasion_warmup, autocvar_g_invasion_round_timelimit);
  77                 return 1;
  78         }
  79
  80         if((numspawned + numkilled) < maxspawned)
  81         {
  82                 if(time >= last_check)
  83                 {
  84                         invasion_SpawnMonsters();
  85                         last_check = time + 2;
  86                 }
  87
  88                 return 0;
  89         }
  90
  91         if(numspawned < 1 || numkilled < numspawned)
  92                 return 0; // nothing has spawned yet, or there are still alive monsters
  93
  94         if(roundcnt >= maxrounds)
  95         {
  96                 NextLevel();
  97                 return 1;
  98         }
  99
 100         entity winner = world;
 101         float winning_score = 0;
 102
 103         FOR_EACH_PLAYER(head)
 104         {
 105                 if(PlayerScore_Add(head, SP_INVASION_KILLS, 0) > winning_score)
 106                         winner = head;
 107         }
 108
 109         if(winner != world)
 110         {
 111                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_PLAYER_WIN, winner.netname);
 112                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_PLAYER_WIN, winner.netname);
 113         }
 114
 115         round_handler_Init(5, autocvar_g_invasion_warmup, autocvar_g_invasion_round_timelimit);
 116
 117         return 1;
 118 }
 119
 120 float Invasion_CheckPlayers()
 121 {
 122         return TRUE;
 123 }
 124
 125 void Invasion_RoundStart()
 126 {
 127         entity e;
 128         float numplayers = 0;
 129         FOR_EACH_PLAYER(e)
 130         {
 131                 ++numplayers;
 132                 e.player_blocked = 0;
 133         }
 134
 135         roundcnt += 1;
 136
 137         numspawned = 0;
 138         numkilled = 0;
 139
 140         if(roundcnt > 1)
 141                 maxspawned = rint(autocvar_g_invasion_monster_count * roundcnt / 0.7);
 142         else
 143                 maxspawned = autocvar_g_invasion_monster_count;
 144
 145         monster_skill += 0.01 * numplayers;
 146 }
 147
 148 MUTATOR_HOOKFUNCTION(invasion_MonsterDies)
 149 {
 150         numkilled += 1;
 151
 152         if(IS_PLAYER(frag_attacker))
 153                 PlayerScore_Add(frag_attacker, SP_INVASION_KILLS, +1);
 154
 155         return FALSE;
 156 }
 157
 158 MUTATOR_HOOKFUNCTION(invasion_MonsterSpawn)
 159 {
 160         if(self.realowner == world)
 161         {
 162                 WaypointSprite_Kill(self.sprite);
 163                 if(self.weaponentity) remove(self.weaponentity);
 164                 remove(self);
 165                 return FALSE;
 166         }
 167
 168         numspawned += 1;
 169
 170         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
 171
 172         return FALSE;
 173 }
 174
 175 MUTATOR_HOOKFUNCTION(invasion_PlayerThink)
 176 {
 177         monsters_total = maxspawned; // TODO: make sure numspawned never exceeds maxspawned
 178         monsters_killed = numkilled;
 179
 180         return FALSE;
 181 }
 182
 183 MUTATOR_HOOKFUNCTION(invasion_PlayerSpawn)
 184 {
 185         self.bot_attack = FALSE;
 186         return FALSE;
 187 }
 188
 189 MUTATOR_HOOKFUNCTION(invasion_PlayerDamage)
 190 {
 191         if(IS_PLAYER(frag_attacker) && IS_PLAYER(frag_target))
 192         {
 193                 frag_damage = 0;
 194                 frag_force = '0 0 0';
 195         }
 196
 197         if(frag_attacker.flags & FL_MONSTER && frag_target.flags & FL_MONSTER)
 198                 frag_damage = 0;
 199
 200         return FALSE;
 201 }
 202
 203 void invasion_ScoreRules()
 204 {
 205         ScoreRules_basics(0, SFL_SORT_PRIO_SECONDARY, 0, FALSE);
 206         ScoreInfo_SetLabel_PlayerScore(SP_INVASION_KILLS, "kills", SFL_SORT_PRIO_PRIMARY);
 207         ScoreRules_basics_end();
 208 }
 209
 210 void invasion_Initialize()
 211 {
 212         invasion_ScoreRules();
 213
 214         round_handler_Spawn(Invasion_CheckPlayers, Invasion_CheckWinner, Invasion_RoundStart);
 215         round_handler_Init(5, autocvar_g_invasion_warmup, autocvar_g_invasion_round_timelimit);
 216
 217         allowed_to_spawn = TRUE;
 218
 219         monster_skill = 0.01;
 220
 221         roundcnt = 0;
 222 }
 223
 224 MUTATOR_DEFINITION(gamemode_invasion)
 225 {
 226         MUTATOR_HOOK(MonsterDies, invasion_MonsterDies, CBC_ORDER_ANY);
 227         MUTATOR_HOOK(MonsterSpawn, invasion_MonsterSpawn, CBC_ORDER_ANY);
 228         MUTATOR_HOOK(PlayerPreThink, invasion_PlayerThink, CBC_ORDER_ANY);
 229         MUTATOR_HOOK(PlayerSpawn, invasion_PlayerSpawn, CBC_ORDER_ANY);
 230         MUTATOR_HOOK(PlayerDamage_Calculate, invasion_PlayerDamage, CBC_ORDER_ANY);
 231
 232         MUTATOR_ONADD
 233         {
 234                 if(time > 1) // game loads at time 1
 235                         error("This is a game type and it cannot be added at runtime.");
 236                 invasion_Initialize();
 237
 238                 cvar_settemp("g_monsters", "1");
 239         }
 240
 241         MUTATOR_ONROLLBACK_OR_REMOVE
 242         {
 243                 // we actually cannot roll back invasion_Initialize here
 244                 // BUT: we don't need to! If this gets called, adding always
 245                 // succeeds.
 246         }
 247
 248         MUTATOR_ONREMOVE
 249         {
 250                 print("This is a game type and it cannot be removed at runtime.");
 251                 return -1;
 252         }
 253
 254         return 0;
 255 }