qcsrc/server/mutators/gamemode_freezetag.qc

   1 .float freezetag_frozen_time;
   2 .float freezetag_frozen_timeout;
   3 .float freezetag_revive_progress;
   4 .entity freezetag_ice;
   5 #define ICE_MAX_ALPHA 1
   6 #define ICE_MIN_ALPHA 0.1
   7 float freezetag_teams;
   8
   9 float freezetag_CheckTeams();
  10 float freezetag_CheckWinner();
  11 void freezetag_Initialize()
  12 {
  13         precache_model("models/ice/ice.md3");
  14         ScoreRules_freezetag();
  15
  16         round_handler_Spawn(freezetag_CheckTeams, freezetag_CheckWinner, func_null);
  17         round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
  18
  19         addstat(STAT_REDALIVE, AS_INT, redalive_stat);
  20         addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
  21         addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
  22         addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
  23
  24         addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
  25         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
  26 }
  27
  28 void freezetag_count_alive_players()
  29 {
  30         entity e;
  31         total_players = redalive = bluealive = yellowalive = pinkalive = 0;
  32         FOR_EACH_PLAYER(e) {
  33                 if(e.team == COLOR_TEAM1 && e.health >= 1)
  34                 {
  35                         ++total_players;
  36                         if (!e.freezetag_frozen) ++redalive;
  37                 }
  38                 else if(e.team == COLOR_TEAM2 && e.health >= 1)
  39                 {
  40                         ++total_players;
  41                         if (!e.freezetag_frozen) ++bluealive;
  42                 }
  43                 else if(e.team == COLOR_TEAM3 && e.health >= 1)
  44                 {
  45                         ++total_players;
  46                         if (!e.freezetag_frozen) ++yellowalive;
  47                 }
  48                 else if(e.team == COLOR_TEAM4 && e.health >= 1)
  49                 {
  50                         ++total_players;
  51                         if (!e.freezetag_frozen) ++pinkalive;
  52                 }
  53         }
  54         FOR_EACH_REALCLIENT(e) {
  55                 e.redalive_stat = redalive;
  56                 e.bluealive_stat = bluealive;
  57                 e.yellowalive_stat = yellowalive;
  58                 e.pinkalive_stat = pinkalive;
  59         }
  60 }
  61 #define FREEZETAG_ALIVE_TEAMS() ((redalive > 0) + (bluealive > 0) + (yellowalive > 0) + (pinkalive > 0))
  62 #define FREEZETAG_ALIVE_TEAMS_OK() (FREEZETAG_ALIVE_TEAMS() == freezetag_teams)
  63
  64 float prev_total_players;
  65 float freezetag_CheckTeams()
  66 {
  67         entity e;
  68         if(FREEZETAG_ALIVE_TEAMS_OK())
  69         {
  70                 if(prev_total_players != -1)
  71                 {
  72                         FOR_EACH_REALCLIENT(e)
  73                                 Send_CSQC_Centerprint_Generic_Expire(e, CPID_WAITING_PLAYERS);
  74                 }
  75                 prev_total_players = -1;
  76                 return 1;
  77         }
  78         if(prev_total_players != total_players)
  79         {
  80                 string teams_missing = "";
  81                 if(!redalive)   teams_missing = strcat(teams_missing, ColoredTeamName(COLOR_TEAM1), ", ");
  82                 if(!bluealive)  teams_missing = strcat(teams_missing, ColoredTeamName(COLOR_TEAM2), ", ");
  83                 if(freezetag_teams >= 3)
  84                 if(!yellowalive)        teams_missing = strcat(teams_missing, ColoredTeamName(COLOR_TEAM3), ", ");
  85                 if(freezetag_teams == 4)
  86                 if(!pinkalive)  teams_missing = strcat(teams_missing, ColoredTeamName(COLOR_TEAM4), ", ");
  87                 teams_missing = substring(teams_missing, 0, strlen(teams_missing)-2);
  88
  89                 FOR_EACH_REALCLIENT(e)
  90                         Send_CSQC_Centerprint_Generic(e, CPID_WAITING_PLAYERS, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), -1, 0);
  91                 prev_total_players = total_players;
  92         }
  93         return 0;
  94 }
  95
  96 float freezetag_getWinnerTeam()
  97 {
  98         float winner_team = 0;
  99         if(redalive >= 1)
 100                 winner_team = COLOR_TEAM1;
 101         if(bluealive >= 1)
 102         {
 103                 if(winner_team) return 0;
 104                 winner_team = COLOR_TEAM2;
 105         }
 106         if(yellowalive >= 1)
 107         {
 108                 if(winner_team) return 0;
 109                 winner_team = COLOR_TEAM3;
 110         }
 111         if(pinkalive >= 1)
 112         {
 113                 if(winner_team) return 0;
 114                 winner_team = COLOR_TEAM4;
 115         }
 116         if(winner_team)
 117                 return winner_team;
 118         return -1; // no player left
 119 }
 120
 121 float freezetag_CheckWinner()
 122 {
 123         entity e;
 124         if(round_handler_GetTimeLeft() <= 0)
 125         {
 126                 FOR_EACH_REALCLIENT(e)
 127                         centerprint(e, "Round over, there's no winner");
 128                 bprint("Round over, there's no winner.\n");
 129                 FOR_EACH_PLAYER(e)
 130                         e.freezetag_frozen_timeout = 0;
 131                 round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
 132                 return 1;
 133         }
 134
 135         if(FREEZETAG_ALIVE_TEAMS() > 1)
 136                 return 0;
 137
 138         float winner_team;
 139         string teamname;
 140         winner_team = freezetag_getWinnerTeam();
 141         if(winner_team > 0)
 142         {
 143                 teamname = ColoredTeamName(winner_team);
 144                 FOR_EACH_REALCLIENT(e)
 145                         centerprint(e, strcat(teamname, "^5 wins the round, all other teams were frozen."));
 146                 bprint(teamname, "^5 wins the round since all the other teams were frozen.\n");
 147                 TeamScore_AddToTeam(winner_team, ST_SCORE, +1);
 148         }
 149         else if(winner_team == -1)
 150         {
 151                 FOR_EACH_REALCLIENT(e)
 152                         centerprint(e, "^5Round tied! All teams were frozen.");
 153                 bprint("^5Round tied! All teams were frozen.\n");
 154         }
 155
 156         FOR_EACH_PLAYER(e)
 157                 e.freezetag_frozen_timeout = 0;
 158         round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
 159         return 1;
 160 }
 161
 162 // this is needed to allow the player to turn his view around (fixangle can't
 163 // be used to freeze his view, as that also changes the angles), while not
 164 // turning that ice object with the player
 165 void freezetag_Ice_Think()
 166 {
 167         setorigin(self, self.owner.origin - '0 0 16');
 168         self.nextthink = time;
 169 }
 170
 171 void freezetag_Add_Score(entity attacker)
 172 {
 173         if(attacker == self)
 174         {
 175                 // you froze your own dumb self
 176                 // counted as "suicide" already
 177                 PlayerScore_Add(self, SP_SCORE, -1);
 178         }
 179         else if(attacker.classname == "player")
 180         {
 181                 // got frozen by an enemy
 182                 // counted as "kill" and "death" already
 183                 PlayerScore_Add(self, SP_SCORE, -1);
 184                 PlayerScore_Add(attacker, SP_SCORE, +1);
 185         }
 186         // else nothing - got frozen by the game type rules themselves
 187 }
 188
 189 void freezetag_Freeze(entity attacker)
 190 {
 191         if(self.freezetag_frozen)
 192                 return;
 193         self.freezetag_frozen = 1;
 194         self.freezetag_frozen_time = time;
 195         self.freezetag_revive_progress = 0;
 196         self.health = 1;
 197         if(autocvar_g_freezetag_frozen_maxtime > 0)
 198                 self.freezetag_frozen_timeout = time + autocvar_g_freezetag_frozen_maxtime;
 199
 200         freezetag_count_alive_players();
 201
 202         entity ice;
 203         ice = spawn();
 204         ice.owner = self;
 205         ice.classname = "freezetag_ice";
 206         ice.think = freezetag_Ice_Think;
 207         ice.nextthink = time;
 208         ice.frame = floor(random() * 21); // ice model has 20 different looking frames
 209         ice.alpha = ICE_MAX_ALPHA;
 210         ice.colormod = TeamColor(self.team);
 211         ice.glowmod = ice.colormod;
 212         setmodel(ice, "models/ice/ice.md3");
 213
 214         self.freezetag_ice = ice;
 215
 216         RemoveGrapplingHook(self);
 217
 218         // add waypoint
 219         WaypointSprite_Spawn("freezetag_frozen", 0, 0, self, '0 0 64', world, self.team, self, waypointsprite_attached, TRUE, RADARICON_WAYPOINT, '0.25 0.90 1');
 220
 221         freezetag_Add_Score(attacker);
 222 }
 223
 224 void freezetag_Unfreeze(entity attacker)
 225 {
 226         self.freezetag_frozen = 0;
 227         self.freezetag_frozen_time = 0;
 228         self.freezetag_frozen_timeout = 0;
 229         self.freezetag_revive_progress = 0;
 230
 231         remove(self.freezetag_ice);
 232         self.freezetag_ice = world;
 233
 234         if(self.waypointsprite_attached)
 235                 WaypointSprite_Kill(self.waypointsprite_attached);
 236 }
 237
 238
 239 // ================
 240 // Bot player logic
 241 // ================
 242
 243 void() havocbot_role_ft_freeing;
 244 void() havocbot_role_ft_offense;
 245
 246 void havocbot_goalrating_freeplayers(float ratingscale, vector org, float sradius)
 247 {
 248         entity head;
 249         float distance;
 250
 251         FOR_EACH_PLAYER(head)
 252         {
 253                 if ((head != self) && (head.team == self.team))
 254                 {
 255                         if (head.freezetag_frozen)
 256                         {
 257                                 distance = vlen(head.origin - org);
 258                                 if (distance > sradius)
 259                                         continue;
 260                                 navigation_routerating(head, ratingscale, 2000);
 261                         }
 262                         else
 263                         {
 264                                 // If teamate is not frozen still seek them out as fight better
 265                                 // in a group.
 266                                 navigation_routerating(head, ratingscale/3, 2000);
 267                         }
 268                 }
 269         }
 270 }
 271
 272 void havocbot_role_ft_offense()
 273 {
 274         entity head;
 275         float unfrozen;
 276
 277         if(self.deadflag != DEAD_NO)
 278                 return;
 279
 280         if (!self.havocbot_role_timeout)
 281                 self.havocbot_role_timeout = time + random() * 10 + 20;
 282
 283         // Count how many players on team are unfrozen.
 284         unfrozen = 0;
 285         FOR_EACH_PLAYER(head)
 286         {
 287                 if ((head.team == self.team) && (!head.freezetag_frozen))
 288                         unfrozen++;
 289         }
 290
 291         // If only one left on team or if role has timed out then start trying to free players.
 292         if (((unfrozen == 0) && (!self.freezetag_frozen)) || (time > self.havocbot_role_timeout))
 293         {
 294                 dprint("changing role to freeing\n");
 295                 self.havocbot_role = havocbot_role_ft_freeing;
 296                 self.havocbot_role_timeout = 0;
 297                 return;
 298         }
 299
 300         if (time > self.bot_strategytime)
 301         {
 302                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 303
 304                 navigation_goalrating_start();
 305                 havocbot_goalrating_items(10000, self.origin, 10000);
 306                 havocbot_goalrating_enemyplayers(20000, self.origin, 10000);
 307                 havocbot_goalrating_freeplayers(9000, self.origin, 10000);
 308                 //havocbot_goalrating_waypoints(1, self.origin, 1000);
 309                 navigation_goalrating_end();
 310         }
 311 }
 312
 313 void havocbot_role_ft_freeing()
 314 {
 315         if(self.deadflag != DEAD_NO)
 316                 return;
 317
 318         if (!self.havocbot_role_timeout)
 319                 self.havocbot_role_timeout = time + random() * 10 + 20;
 320
 321         if (time > self.havocbot_role_timeout)
 322         {
 323                 dprint("changing role to offense\n");
 324                 self.havocbot_role = havocbot_role_ft_offense;
 325                 self.havocbot_role_timeout = 0;
 326                 return;
 327         }
 328
 329         if (time > self.bot_strategytime)
 330         {
 331                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 332
 333                 navigation_goalrating_start();
 334                 havocbot_goalrating_items(8000, self.origin, 10000);
 335                 havocbot_goalrating_enemyplayers(10000, self.origin, 10000);
 336                 havocbot_goalrating_freeplayers(20000, self.origin, 10000);
 337                 //havocbot_goalrating_waypoints(1, self.origin, 1000);
 338                 navigation_goalrating_end();
 339         }
 340 }
 341
 342
 343 // ==============
 344 // Hook Functions
 345 // ==============
 346
 347 MUTATOR_HOOKFUNCTION(freezetag_RemovePlayer)
 348 {
 349         self.health = 0; // neccessary to update correctly alive stats
 350         freezetag_Unfreeze(world);
 351         freezetag_count_alive_players();
 352         return 1;
 353 }
 354
 355 MUTATOR_HOOKFUNCTION(freezetag_PlayerDies)
 356 {
 357         if(round_handler_IsActive())
 358         if(round_handler_CountdownRunning())
 359         {
 360                 if(self.freezetag_frozen)
 361                         freezetag_Unfreeze(world);
 362                 freezetag_count_alive_players();
 363                 return 1; // let the player die so that he can respawn whenever he wants
 364         }
 365
 366         // Cases DEATH_TEAMCHANGE and DEATH_AUTOTEAMCHANGE are needed to fix a bug whe
 367         // you succeed changing team through the menu: you both really die (gibbing) and get frozen
 368         if(ITEM_DAMAGE_NEEDKILL(frag_deathtype)
 369                 || frag_deathtype == DEATH_TEAMCHANGE || frag_deathtype == DEATH_AUTOTEAMCHANGE)
 370         {
 371                 // let the player die, he will be automatically frozen when he respawns
 372                 if(!self.freezetag_frozen)
 373                 {
 374                         freezetag_Add_Score(frag_attacker);
 375                         freezetag_count_alive_players();
 376                 }
 377                 else
 378                         freezetag_Unfreeze(world); // remove ice
 379                 self.freezetag_frozen_timeout = -2; // freeze on respawn
 380                 return 1;
 381         }
 382
 383         if(self.freezetag_frozen)
 384                 return 1;
 385
 386         freezetag_Freeze(frag_attacker);
 387
 388         if(frag_attacker == frag_target || frag_attacker == world)
 389         {
 390                 if(frag_target.classname == STR_PLAYER)
 391                         centerprint(frag_target, "^1You froze yourself.\n");
 392                 bprint("^7", frag_target.netname, "^1 froze himself.\n");
 393         }
 394         else
 395         {
 396                 if(frag_target.classname == STR_PLAYER)
 397                         centerprint(frag_target, strcat("^1You were frozen by ^7", frag_attacker.netname, ".\n"));
 398                 if(frag_attacker.classname == STR_PLAYER)
 399                         centerprint(frag_attacker, strcat("^2You froze ^7", frag_target.netname, ".\n"));
 400                 bprint("^7", frag_target.netname, "^1 was frozen by ^7", frag_attacker.netname, ".\n");
 401         }
 402
 403         frag_target.health = 1; // "respawn" the player :P
 404
 405         return 1;
 406 }
 407
 408 MUTATOR_HOOKFUNCTION(freezetag_PlayerSpawn)
 409 {
 410         if(self.freezetag_frozen_timeout == -1) // if PlayerSpawn is called by reset_map_players
 411                 return 1; // do nothing, round is starting right now
 412
 413         if(self.freezetag_frozen_timeout == -2) // player was dead
 414         {
 415                 freezetag_Freeze(world);
 416                 return 1;
 417         }
 418
 419         freezetag_count_alive_players();
 420
 421         if(round_handler_IsActive())
 422         if(round_handler_IsRoundStarted())
 423         {
 424                 centerprint(self, "^1Round already started, you spawn as frozen.");
 425                 freezetag_Freeze(world);
 426         }
 427
 428         return 1;
 429 }
 430
 431 MUTATOR_HOOKFUNCTION(freezetag_reset_map_players)
 432 {
 433         FOR_EACH_PLAYER(self)
 434         {
 435                 if (self.freezetag_frozen)
 436                         freezetag_Unfreeze(world);
 437                 self.freezetag_frozen_timeout = -1;
 438                 PutClientInServer();
 439                 self.freezetag_frozen_timeout = 0;
 440         }
 441         freezetag_count_alive_players();
 442         return 1;
 443 }
 444
 445 MUTATOR_HOOKFUNCTION(freezetag_GiveFragsForKill)
 446 {
 447         frag_score = 0; // no frags counted in Freeze Tag
 448         return 1;
 449 }
 450
 451 .float reviving; // temp var
 452 MUTATOR_HOOKFUNCTION(freezetag_PlayerPreThink)
 453 {
 454         float n;
 455
 456         if(gameover)
 457                 return 1;
 458
 459         if(self.freezetag_frozen)
 460         {
 461                 // keep health = 1
 462                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen;
 463         }
 464
 465         if(round_handler_IsActive())
 466         if(!round_handler_IsRoundStarted())
 467                 return 1;
 468
 469         entity o;
 470         o = world;
 471         if(self.freezetag_frozen_timeout > 0 && time < self.freezetag_frozen_timeout)
 472                 self.freezetag_ice.alpha = ICE_MIN_ALPHA + (ICE_MAX_ALPHA - ICE_MIN_ALPHA) * (self.freezetag_frozen_timeout - time) / (self.freezetag_frozen_timeout - self.freezetag_frozen_time);
 473
 474         if(self.freezetag_frozen_timeout > 0 && time >= self.freezetag_frozen_timeout)
 475                 n = -1;
 476         else
 477         {
 478                 vector revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
 479                 n = 0;
 480                 FOR_EACH_PLAYER(other) if(self != other)
 481                 {
 482                         if(other.freezetag_frozen == 0)
 483                         {
 484                                 if(other.team == self.team)
 485                                 {
 486                                         if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
 487                                         {
 488                                                 if(!o)
 489                                                         o = other;
 490                                                 if(self.freezetag_frozen)
 491                                                         other.reviving = TRUE;
 492                                                 ++n;
 493                                         }
 494                                 }
 495                         }
 496                 }
 497         }
 498
 499         if(n && self.freezetag_frozen) // OK, there is at least one teammate reviving us
 500         {
 501                 self.freezetag_revive_progress = bound(0, self.freezetag_revive_progress + frametime * autocvar_g_freezetag_revive_speed, 1);
 502                 self.health = max(1, self.freezetag_revive_progress * autocvar_g_balance_health_start);
 503
 504                 if(self.freezetag_revive_progress >= 1)
 505                 {
 506                         freezetag_Unfreeze(self);
 507                         freezetag_count_alive_players();
 508
 509                         if(n == -1)
 510                         {
 511                                 string s = ftos(autocvar_g_freezetag_frozen_maxtime);
 512                                 centerprint(self, strcat("^5You were automatically revived after ", s, " seconds^5.\n"));
 513                                 bprint("^7", self.netname, "^5 were automatically revived after ", s, " seconds^5.\n");
 514                                 return 1;
 515                         }
 516
 517                         // EVERY team mate nearby gets a point (even if multiple!)
 518                         FOR_EACH_PLAYER(other)
 519                         {
 520                                 if(other.reviving)
 521                                 {
 522                                         PlayerScore_Add(other, SP_FREEZETAG_REVIVALS, +1);
 523                                         PlayerScore_Add(other, SP_SCORE, +1);
 524                                 }
 525                         }
 526
 527                         if(n > 1)
 528                                 centerprint(self, strcat("^5You were revived by ^7", o.netname, "^5 et al.\n"));
 529                         else
 530                                 centerprint(self, strcat("^5You were revived by ^7", o.netname, "^5.\n"));
 531                         centerprint(o, strcat("^5You revived ^7", self.netname, "^5.\n"));
 532                         if(n > 1)
 533                                 bprint("^7", o.netname, "^5 et al revived ^7", self.netname, "^5.\n");
 534                         else
 535                                 bprint("^7", o.netname, "^5 revived ^7", self.netname, "^5.\n");
 536                 }
 537
 538                 FOR_EACH_PLAYER(other)
 539                 {
 540                         if(other.reviving)
 541                         {
 542                                 other.freezetag_revive_progress = self.freezetag_revive_progress;
 543                                 other.reviving = FALSE;
 544                         }
 545                 }
 546         }
 547         else if(!n && self.freezetag_frozen) // only if no teammate is nearby will we reset
 548         {
 549                 self.freezetag_revive_progress = bound(0, self.freezetag_revive_progress - frametime * autocvar_g_freezetag_revive_clearspeed, 1);
 550                 self.health = max(1, self.freezetag_revive_progress * autocvar_g_balance_health_start);
 551         }
 552         else if(!n)
 553         {
 554                 self.freezetag_revive_progress = 0; // thawing nobody
 555         }
 556
 557         return 1;
 558 }
 559
 560 MUTATOR_HOOKFUNCTION(freezetag_PlayerPhysics)
 561 {
 562         if(self.freezetag_frozen)
 563         {
 564                 self.movement = '0 0 0';
 565                 self.disableclientprediction = 1;
 566         }
 567         return 1;
 568 }
 569
 570 MUTATOR_HOOKFUNCTION(freezetag_PlayerDamage_Calculate)
 571 {
 572         if(frag_target.freezetag_frozen && frag_deathtype != DEATH_HURTTRIGGER)
 573         {
 574                 frag_damage = 0;
 575                 frag_force = frag_force * autocvar_g_freezetag_frozen_force;
 576         }
 577         return 1;
 578 }
 579
 580 MUTATOR_HOOKFUNCTION(freezetag_ForbidThrowCurrentWeapon)
 581 {
 582         if (self.freezetag_frozen)
 583                 return 1;
 584         return 0;
 585 }
 586
 587 MUTATOR_HOOKFUNCTION(freezetag_BotRoles)
 588 {
 589         if not(self.deadflag)
 590         {
 591                 if (random() < 0.5)
 592                         self.havocbot_role = havocbot_role_ft_freeing;
 593                 else
 594                         self.havocbot_role = havocbot_role_ft_offense;
 595         }
 596
 597         return TRUE;
 598 }
 599
 600 MUTATOR_HOOKFUNCTION(freezetag_SpectateCopy)
 601 {
 602         self.freezetag_frozen = other.freezetag_frozen;
 603         self.freezetag_revive_progress = other.freezetag_revive_progress;
 604         return 0;
 605 }
 606
 607 MUTATOR_HOOKFUNCTION(freezetag_GetTeamCount)
 608 {
 609         freezetag_teams = autocvar_g_freezetag_teams_override;
 610         if(freezetag_teams < 2)
 611                 freezetag_teams = autocvar_g_freezetag_teams;
 612         freezetag_teams = bound(2, freezetag_teams, 4);
 613         ret_float = freezetag_teams;
 614         return 0;
 615 }
 616
 617 MUTATOR_DEFINITION(gamemode_freezetag)
 618 {
 619         MUTATOR_HOOK(MakePlayerObserver, freezetag_RemovePlayer, CBC_ORDER_ANY);
 620         MUTATOR_HOOK(ClientDisconnect, freezetag_RemovePlayer, CBC_ORDER_ANY);
 621         MUTATOR_HOOK(PlayerDies, freezetag_PlayerDies, CBC_ORDER_ANY);
 622         MUTATOR_HOOK(PlayerSpawn, freezetag_PlayerSpawn, CBC_ORDER_ANY);
 623         MUTATOR_HOOK(reset_map_players, freezetag_reset_map_players, CBC_ORDER_ANY);
 624         MUTATOR_HOOK(GiveFragsForKill, freezetag_GiveFragsForKill, CBC_ORDER_FIRST);
 625         MUTATOR_HOOK(PlayerPreThink, freezetag_PlayerPreThink, CBC_ORDER_FIRST);
 626         MUTATOR_HOOK(PlayerPhysics, freezetag_PlayerPhysics, CBC_ORDER_FIRST);
 627         MUTATOR_HOOK(PlayerDamage_Calculate, freezetag_PlayerDamage_Calculate, CBC_ORDER_ANY);
 628         MUTATOR_HOOK(ForbidThrowCurrentWeapon, freezetag_ForbidThrowCurrentWeapon, CBC_ORDER_ANY);
 629         MUTATOR_HOOK(HavocBot_ChooseRule, freezetag_BotRoles, CBC_ORDER_ANY);
 630         MUTATOR_HOOK(SpectateCopy, freezetag_SpectateCopy, CBC_ORDER_ANY);
 631         MUTATOR_HOOK(GetTeamCount, freezetag_GetTeamCount, CBC_ORDER_EXCLUSIVE);
 632
 633         MUTATOR_ONADD
 634         {
 635                 if(time > 1) // game loads at time 1
 636                         error("This is a game type and it cannot be added at runtime.");
 637                 freezetag_Initialize();
 638         }
 639
 640         MUTATOR_ONROLLBACK_OR_REMOVE
 641         {
 642                 // we actually cannot roll back freezetag_Initialize here
 643                 // BUT: we don't need to! If this gets called, adding always
 644                 // succeeds.
 645         }
 646
 647         MUTATOR_ONREMOVE
 648         {
 649                 print("This is a game type and it cannot be removed at runtime.");
 650                 return -1;
 651         }
 652
 653         return 0;
 654 }