qcsrc/server/mutators/gamemode_freezetag.qc

   1 .float freezetag_frozen_time;
   2 .float freezetag_frozen_timeout;
   3 .float freezetag_revive_progress;
   4 .entity freezetag_ice;
   5 #define ICE_MAX_ALPHA 0.6
   6 #define ICE_MIN_ALPHA 0.1
   7 float freezetag_teams;
   8
   9 float freezetag_CheckTeams();
  10 float freezetag_CheckWinner();
  11 void freezetag_Initialize()
  12 {
  13         precache_model("models/ice/ice.md3");
  14         ScoreRules_freezetag();
  15
  16         round_handler_Spawn(freezetag_CheckTeams, freezetag_CheckWinner, func_null);
  17         round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
  18
  19         addstat(STAT_REDALIVE, AS_INT, redalive_stat);
  20         addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
  21         addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
  22         addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
  23
  24         addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
  25         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
  26 }
  27
  28 void freezetag_count_alive_players()
  29 {
  30         entity e;
  31         total_players = redalive = bluealive = yellowalive = pinkalive = 0;
  32         FOR_EACH_PLAYER(e) {
  33                 if(e.team == COLOR_TEAM1 && e.health >= 1)
  34                 {
  35                         ++total_players;
  36                         if (!e.freezetag_frozen) ++redalive;
  37                 }
  38                 else if(e.team == COLOR_TEAM2 && e.health >= 1)
  39                 {
  40                         ++total_players;
  41                         if (!e.freezetag_frozen) ++bluealive;
  42                 }
  43                 else if(e.team == COLOR_TEAM3 && e.health >= 1)
  44                 {
  45                         ++total_players;
  46                         if (!e.freezetag_frozen) ++yellowalive;
  47                 }
  48                 else if(e.team == COLOR_TEAM4 && e.health >= 1)
  49                 {
  50                         ++total_players;
  51                         if (!e.freezetag_frozen) ++pinkalive;
  52                 }
  53         }
  54         FOR_EACH_REALCLIENT(e) {
  55                 e.redalive_stat = redalive;
  56                 e.bluealive_stat = bluealive;
  57                 e.yellowalive_stat = yellowalive;
  58                 e.pinkalive_stat = pinkalive;
  59         }
  60 }
  61 #define FREEZETAG_ALIVE_TEAMS() ((redalive > 0) + (bluealive > 0) + (yellowalive > 0) + (pinkalive > 0))
  62 #define FREEZETAG_ALIVE_TEAMS_OK() (FREEZETAG_ALIVE_TEAMS() == freezetag_teams)
  63
  64 float prev_total_players;
  65 float freezetag_CheckTeams()
  66 {
  67         entity e;
  68         if(FREEZETAG_ALIVE_TEAMS_OK())
  69         {
  70                 if(prev_total_players != -1)
  71                 {
  72                         FOR_EACH_REALCLIENT(e)
  73                                 Send_CSQC_Centerprint_Generic_Expire(e, CPID_WAITING_PLAYERS);
  74                 }
  75                 prev_total_players = -1;
  76                 return 1;
  77         }
  78         if(prev_total_players != total_players)
  79         {
  80                 string teams_missing = "";
  81                 if(!redalive)   teams_missing = strcat(teams_missing, ColoredTeamName(COLOR_TEAM1), ", ");
  82                 if(!bluealive)  teams_missing = strcat(teams_missing, ColoredTeamName(COLOR_TEAM2), ", ");
  83                 if(freezetag_teams >= 3)
  84                 if(!yellowalive)        teams_missing = strcat(teams_missing, ColoredTeamName(COLOR_TEAM3), ", ");
  85                 if(freezetag_teams == 4)
  86                 if(!pinkalive)  teams_missing = strcat(teams_missing, ColoredTeamName(COLOR_TEAM4), ", ");
  87                 teams_missing = substring(teams_missing, 0, strlen(teams_missing)-2);
  88
  89                 FOR_EACH_REALCLIENT(e)
  90                         Send_CSQC_Centerprint_Generic(e, CPID_WAITING_PLAYERS, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), -1, 0);
  91                 prev_total_players = total_players;
  92         }
  93         return 0;
  94 }
  95
  96 float freezetag_getWinnerTeam()
  97 {
  98         float winner_team = 0;
  99         if(redalive >= 1)
 100                 winner_team = COLOR_TEAM1;
 101         if(bluealive >= 1)
 102         {
 103                 if(winner_team) return 0;
 104                 winner_team = COLOR_TEAM2;
 105         }
 106         if(yellowalive >= 1)
 107         {
 108                 if(winner_team) return 0;
 109                 winner_team = COLOR_TEAM3;
 110         }
 111         if(pinkalive >= 1)
 112         {
 113                 if(winner_team) return 0;
 114                 winner_team = COLOR_TEAM4;
 115         }
 116         if(winner_team)
 117                 return winner_team;
 118         return -1; // no player left
 119 }
 120
 121 float freezetag_CheckWinner()
 122 {
 123         entity e;
 124         if(round_handler_GetTimeLeft() <= 0)
 125         {
 126                 FOR_EACH_REALCLIENT(e)
 127                         centerprint(e, "Round over, there's no winner");
 128                 bprint("Round over, there's no winner.\n");
 129                 FOR_EACH_PLAYER(e)
 130                         e.freezetag_frozen_timeout = 0;
 131                 round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
 132                 return 1;
 133         }
 134
 135         if(FREEZETAG_ALIVE_TEAMS() > 1)
 136                 return 0;
 137
 138         float winner_team;
 139         string teamname;
 140         winner_team = freezetag_getWinnerTeam();
 141         if(winner_team > 0)
 142         {
 143                 teamname = ColoredTeamName(winner_team);
 144                 FOR_EACH_REALCLIENT(e)
 145                         centerprint(e, strcat(teamname, "^5 wins the round, all other teams were frozen."));
 146                 bprint(teamname, "^5 wins the round since all the other teams were frozen.\n");
 147                 TeamScore_AddToTeam(winner_team, ST_SCORE, +1);
 148         }
 149         else if(winner_team == -1)
 150         {
 151                 FOR_EACH_REALCLIENT(e)
 152                         centerprint(e, "^5Round tied! All teams were frozen.");
 153                 bprint("^5Round tied! All teams were frozen.\n");
 154         }
 155
 156         FOR_EACH_PLAYER(e)
 157                 e.freezetag_frozen_timeout = 0;
 158         round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
 159         return 1;
 160 }
 161
 162 // this is needed to allow the player to turn his view around (fixangle can't
 163 // be used to freeze his view, as that also changes the angles), while not
 164 // turning that ice object with the player
 165 void freezetag_Ice_Think()
 166 {
 167         setorigin(self, self.owner.origin - '0 0 16');
 168         self.nextthink = time;
 169 }
 170
 171 void freezetag_Add_Score(entity attacker)
 172 {
 173         if(attacker == self)
 174         {
 175                 // you froze your own dumb self
 176                 // counted as "suicide" already
 177                 PlayerScore_Add(self, SP_SCORE, -1);
 178         }
 179         else if(attacker.classname == "player")
 180         {
 181                 // got frozen by an enemy
 182                 // counted as "kill" and "death" already
 183                 PlayerScore_Add(self, SP_SCORE, -1);
 184                 PlayerScore_Add(attacker, SP_SCORE, +1);
 185         }
 186         // else nothing - got frozen by the game type rules themselves
 187 }
 188
 189 void freezetag_Freeze(entity attacker)
 190 {
 191         if(self.freezetag_frozen)
 192                 return;
 193         self.freezetag_frozen = 1;
 194         self.freezetag_frozen_time = time;
 195         self.freezetag_revive_progress = 0;
 196         self.health = 1;
 197         if(autocvar_g_freezetag_frozen_maxtime > 0)
 198                 self.freezetag_frozen_timeout = time + autocvar_g_freezetag_frozen_maxtime;
 199
 200         freezetag_count_alive_players();
 201
 202         entity ice;
 203         ice = spawn();
 204         ice.owner = self;
 205         ice.classname = "freezetag_ice";
 206         ice.think = freezetag_Ice_Think;
 207         ice.nextthink = time;
 208         ice.frame = floor(random() * 21); // ice model has 20 different looking frames
 209         ice.alpha = ICE_MAX_ALPHA;
 210         setmodel(ice, "models/ice/ice.md3");
 211
 212         self.freezetag_ice = ice;
 213
 214         RemoveGrapplingHook(self);
 215
 216         // add waypoint
 217         WaypointSprite_Spawn("freezetag_frozen", 0, 0, self, '0 0 64', world, self.team, self, waypointsprite_attached, TRUE, RADARICON_WAYPOINT, '0.25 0.90 1');
 218
 219         freezetag_Add_Score(attacker);
 220 }
 221
 222 void freezetag_Unfreeze(entity attacker)
 223 {
 224         self.freezetag_frozen = 0;
 225         self.freezetag_frozen_time = 0;
 226         self.freezetag_frozen_timeout = 0;
 227         self.freezetag_revive_progress = 0;
 228
 229         remove(self.freezetag_ice);
 230         self.freezetag_ice = world;
 231
 232         if(self.waypointsprite_attached)
 233                 WaypointSprite_Kill(self.waypointsprite_attached);
 234 }
 235
 236
 237 // ================
 238 // Bot player logic
 239 // ================
 240
 241 void() havocbot_role_ft_freeing;
 242 void() havocbot_role_ft_offense;
 243
 244 void havocbot_goalrating_freeplayers(float ratingscale, vector org, float sradius)
 245 {
 246         entity head;
 247         float distance;
 248
 249         FOR_EACH_PLAYER(head)
 250         {
 251                 if ((head != self) && (head.team == self.team))
 252                 {
 253                         if (head.freezetag_frozen)
 254                         {
 255                                 distance = vlen(head.origin - org);
 256                                 if (distance > sradius)
 257                                         continue;
 258                                 navigation_routerating(head, ratingscale, 2000);
 259                         }
 260                         else
 261                         {
 262                                 // If teamate is not frozen still seek them out as fight better
 263                                 // in a group.
 264                                 navigation_routerating(head, ratingscale/3, 2000);
 265                         }
 266                 }
 267         }
 268 }
 269
 270 void havocbot_role_ft_offense()
 271 {
 272         entity head;
 273         float unfrozen;
 274
 275         if(self.deadflag != DEAD_NO)
 276                 return;
 277
 278         if (!self.havocbot_role_timeout)
 279                 self.havocbot_role_timeout = time + random() * 10 + 20;
 280
 281         // Count how many players on team are unfrozen.
 282         unfrozen = 0;
 283         FOR_EACH_PLAYER(head)
 284         {
 285                 if ((head.team == self.team) && (!head.freezetag_frozen))
 286                         unfrozen++;
 287         }
 288
 289         // If only one left on team or if role has timed out then start trying to free players.
 290         if (((unfrozen == 0) && (!self.freezetag_frozen)) || (time > self.havocbot_role_timeout))
 291         {
 292                 dprint("changing role to freeing\n");
 293                 self.havocbot_role = havocbot_role_ft_freeing;
 294                 self.havocbot_role_timeout = 0;
 295                 return;
 296         }
 297
 298         if (time > self.bot_strategytime)
 299         {
 300                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 301
 302                 navigation_goalrating_start();
 303                 havocbot_goalrating_items(10000, self.origin, 10000);
 304                 havocbot_goalrating_enemyplayers(20000, self.origin, 10000);
 305                 havocbot_goalrating_freeplayers(9000, self.origin, 10000);
 306                 //havocbot_goalrating_waypoints(1, self.origin, 1000);
 307                 navigation_goalrating_end();
 308         }
 309 }
 310
 311 void havocbot_role_ft_freeing()
 312 {
 313         if(self.deadflag != DEAD_NO)
 314                 return;
 315
 316         if (!self.havocbot_role_timeout)
 317                 self.havocbot_role_timeout = time + random() * 10 + 20;
 318
 319         if (time > self.havocbot_role_timeout)
 320         {
 321                 dprint("changing role to offense\n");
 322                 self.havocbot_role = havocbot_role_ft_offense;
 323                 self.havocbot_role_timeout = 0;
 324                 return;
 325         }
 326
 327         if (time > self.bot_strategytime)
 328         {
 329                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 330
 331                 navigation_goalrating_start();
 332                 havocbot_goalrating_items(8000, self.origin, 10000);
 333                 havocbot_goalrating_enemyplayers(10000, self.origin, 10000);
 334                 havocbot_goalrating_freeplayers(20000, self.origin, 10000);
 335                 //havocbot_goalrating_waypoints(1, self.origin, 1000);
 336                 navigation_goalrating_end();
 337         }
 338 }
 339
 340
 341 // ==============
 342 // Hook Functions
 343 // ==============
 344
 345 MUTATOR_HOOKFUNCTION(freezetag_RemovePlayer)
 346 {
 347         self.health = 0; // neccessary to update correctly alive stats
 348         freezetag_Unfreeze(world);
 349         freezetag_count_alive_players();
 350         return 1;
 351 }
 352
 353 MUTATOR_HOOKFUNCTION(freezetag_PlayerDies)
 354 {
 355         if(round_handler_IsActive())
 356         if(round_handler_CountdownRunning())
 357         {
 358                 if(self.freezetag_frozen)
 359                         freezetag_Unfreeze(world);
 360                 freezetag_count_alive_players();
 361                 return 1; // let the player die so that he can respawn whenever he wants
 362         }
 363
 364         // Cases DEATH_TEAMCHANGE and DEATH_AUTOTEAMCHANGE are needed to fix a bug whe
 365         // you succeed changing team through the menu: you both really die (gibbing) and get frozen
 366         if(ITEM_DAMAGE_NEEDKILL(frag_deathtype)
 367                 || frag_deathtype == DEATH_TEAMCHANGE || frag_deathtype == DEATH_AUTOTEAMCHANGE)
 368         {
 369                 // let the player die, he will be automatically frozen when he respawns
 370                 if(!self.freezetag_frozen)
 371                 {
 372                         freezetag_Add_Score(frag_attacker);
 373                         freezetag_count_alive_players();
 374                 }
 375                 else
 376                         freezetag_Unfreeze(world); // remove ice
 377                 self.freezetag_frozen_timeout = -2; // freeze on respawn
 378                 return 1;
 379         }
 380
 381         if(self.freezetag_frozen)
 382                 return 1;
 383
 384         freezetag_Freeze(frag_attacker);
 385
 386         if(frag_attacker == frag_target || frag_attacker == world)
 387         {
 388                 if(frag_target.classname == STR_PLAYER)
 389                         centerprint(frag_target, "^1You froze yourself.\n");
 390                 bprint("^7", frag_target.netname, "^1 froze himself.\n");
 391         }
 392         else
 393         {
 394                 if(frag_target.classname == STR_PLAYER)
 395                         centerprint(frag_target, strcat("^1You were frozen by ^7", frag_attacker.netname, ".\n"));
 396                 if(frag_attacker.classname == STR_PLAYER)
 397                         centerprint(frag_attacker, strcat("^2You froze ^7", frag_target.netname, ".\n"));
 398                 bprint("^7", frag_target.netname, "^1 was frozen by ^7", frag_attacker.netname, ".\n");
 399         }
 400
 401         frag_target.health = 1; // "respawn" the player :P
 402
 403         return 1;
 404 }
 405
 406 MUTATOR_HOOKFUNCTION(freezetag_PlayerSpawn)
 407 {
 408         if(self.freezetag_frozen_timeout == -1) // if PlayerSpawn is called by reset_map_players
 409                 return 1; // do nothing, round is starting right now
 410
 411         if(self.freezetag_frozen_timeout == -2) // player was dead
 412         {
 413                 freezetag_Freeze(world);
 414                 return 1;
 415         }
 416
 417         freezetag_count_alive_players();
 418
 419         if(round_handler_IsActive())
 420         if(round_handler_IsRoundStarted())
 421         {
 422                 centerprint(self, "^1Round already started, you spawn as frozen.");
 423                 freezetag_Freeze(world);
 424         }
 425
 426         return 1;
 427 }
 428
 429 MUTATOR_HOOKFUNCTION(freezetag_reset_map_players)
 430 {
 431         FOR_EACH_PLAYER(self)
 432         {
 433                 if (self.freezetag_frozen)
 434                         freezetag_Unfreeze(world);
 435                 self.freezetag_frozen_timeout = -1;
 436                 PutClientInServer();
 437                 self.freezetag_frozen_timeout = 0;
 438         }
 439         freezetag_count_alive_players();
 440         return 1;
 441 }
 442
 443 MUTATOR_HOOKFUNCTION(freezetag_GiveFragsForKill)
 444 {
 445         frag_score = 0; // no frags counted in Freeze Tag
 446         return 1;
 447 }
 448
 449 .float reviving; // temp var
 450 MUTATOR_HOOKFUNCTION(freezetag_PlayerPreThink)
 451 {
 452         float n;
 453
 454         if(gameover)
 455                 return 1;
 456
 457         if(self.freezetag_frozen)
 458         {
 459                 // keep health = 1
 460                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen;
 461         }
 462
 463         if(round_handler_IsActive())
 464         if(!round_handler_IsRoundStarted())
 465                 return 1;
 466
 467         entity o;
 468         o = world;
 469         if(self.freezetag_frozen_timeout > 0 && time < self.freezetag_frozen_timeout)
 470                 self.freezetag_ice.alpha = ICE_MIN_ALPHA + (ICE_MAX_ALPHA - ICE_MIN_ALPHA) * (self.freezetag_frozen_timeout - time) / (self.freezetag_frozen_timeout - self.freezetag_frozen_time);
 471
 472         if(self.freezetag_frozen_timeout > 0 && time >= self.freezetag_frozen_timeout)
 473                 n = -1;
 474         else
 475         {
 476                 vector revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
 477                 n = 0;
 478                 FOR_EACH_PLAYER(other) if(self != other)
 479                 {
 480                         if(other.freezetag_frozen == 0)
 481                         {
 482                                 if(other.team == self.team)
 483                                 {
 484                                         if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
 485                                         {
 486                                                 if(!o)
 487                                                         o = other;
 488                                                 if(self.freezetag_frozen)
 489                                                         other.reviving = TRUE;
 490                                                 ++n;
 491                                         }
 492                                 }
 493                         }
 494                 }
 495         }
 496
 497         if(n && self.freezetag_frozen) // OK, there is at least one teammate reviving us
 498         {
 499                 self.freezetag_revive_progress = bound(0, self.freezetag_revive_progress + frametime * autocvar_g_freezetag_revive_speed, 1);
 500                 self.health = max(1, self.freezetag_revive_progress * autocvar_g_balance_health_start);
 501
 502                 if(self.freezetag_revive_progress >= 1)
 503                 {
 504                         freezetag_Unfreeze(self);
 505                         freezetag_count_alive_players();
 506
 507                         if(n == -1)
 508                         {
 509                                 string s = ftos(autocvar_g_freezetag_frozen_maxtime);
 510                                 centerprint(self, strcat("^5You were automatically revived after ", s, " seconds^5.\n"));
 511                                 bprint("^7", self.netname, "^5 were automatically revived after ", s, " seconds^5.\n");
 512                                 return 1;
 513                         }
 514
 515                         // EVERY team mate nearby gets a point (even if multiple!)
 516                         FOR_EACH_PLAYER(other)
 517                         {
 518                                 if(other.reviving)
 519                                 {
 520                                         PlayerScore_Add(other, SP_FREEZETAG_REVIVALS, +1);
 521                                         PlayerScore_Add(other, SP_SCORE, +1);
 522                                 }
 523                         }
 524
 525                         if(n > 1)
 526                                 centerprint(self, strcat("^5You were revived by ^7", o.netname, "^5 et al.\n"));
 527                         else
 528                                 centerprint(self, strcat("^5You were revived by ^7", o.netname, "^5.\n"));
 529                         centerprint(o, strcat("^5You revived ^7", self.netname, "^5.\n"));
 530                         if(n > 1)
 531                                 bprint("^7", o.netname, "^5 et al revived ^7", self.netname, "^5.\n");
 532                         else
 533                                 bprint("^7", o.netname, "^5 revived ^7", self.netname, "^5.\n");
 534                 }
 535
 536                 FOR_EACH_PLAYER(other)
 537                 {
 538                         if(other.reviving)
 539                         {
 540                                 other.freezetag_revive_progress = self.freezetag_revive_progress;
 541                                 other.reviving = FALSE;
 542                         }
 543                 }
 544         }
 545         else if(!n && self.freezetag_frozen) // only if no teammate is nearby will we reset
 546         {
 547                 self.freezetag_revive_progress = bound(0, self.freezetag_revive_progress - frametime * autocvar_g_freezetag_revive_clearspeed, 1);
 548                 self.health = max(1, self.freezetag_revive_progress * autocvar_g_balance_health_start);
 549         }
 550         else if(!n)
 551         {
 552                 self.freezetag_revive_progress = 0; // thawing nobody
 553         }
 554
 555         return 1;
 556 }
 557
 558 MUTATOR_HOOKFUNCTION(freezetag_PlayerPhysics)
 559 {
 560         if(self.freezetag_frozen)
 561         {
 562                 self.movement = '0 0 0';
 563                 self.disableclientprediction = 1;
 564         }
 565         return 1;
 566 }
 567
 568 MUTATOR_HOOKFUNCTION(freezetag_PlayerDamage_Calculate)
 569 {
 570         if(frag_target.freezetag_frozen && frag_deathtype != DEATH_HURTTRIGGER)
 571         {
 572                 frag_damage = 0;
 573                 frag_force = frag_force * autocvar_g_freezetag_frozen_force;
 574         }
 575         return 1;
 576 }
 577
 578 MUTATOR_HOOKFUNCTION(freezetag_ForbidThrowCurrentWeapon)
 579 {
 580         if (self.freezetag_frozen)
 581                 return 1;
 582         return 0;
 583 }
 584
 585 MUTATOR_HOOKFUNCTION(freezetag_BotRoles)
 586 {
 587         if not(self.deadflag)
 588         {
 589                 if (random() < 0.5)
 590                         self.havocbot_role = havocbot_role_ft_freeing;
 591                 else
 592                         self.havocbot_role = havocbot_role_ft_offense;
 593         }
 594
 595         return TRUE;
 596 }
 597
 598 MUTATOR_HOOKFUNCTION(freezetag_SpectateCopy)
 599 {
 600         self.freezetag_frozen = other.freezetag_frozen;
 601         self.freezetag_revive_progress = other.freezetag_revive_progress;
 602         return 0;
 603 }
 604
 605 MUTATOR_HOOKFUNCTION(freezetag_GetTeamCount)
 606 {
 607         freezetag_teams = autocvar_g_freezetag_teams_override;
 608         if(freezetag_teams < 2)
 609                 freezetag_teams = autocvar_g_freezetag_teams;
 610         freezetag_teams = bound(2, freezetag_teams, 4);
 611         ret_float = freezetag_teams;
 612         return 0;
 613 }
 614
 615 MUTATOR_DEFINITION(gamemode_freezetag)
 616 {
 617         MUTATOR_HOOK(MakePlayerObserver, freezetag_RemovePlayer, CBC_ORDER_ANY);
 618         MUTATOR_HOOK(ClientDisconnect, freezetag_RemovePlayer, CBC_ORDER_ANY);
 619         MUTATOR_HOOK(PlayerDies, freezetag_PlayerDies, CBC_ORDER_ANY);
 620         MUTATOR_HOOK(PlayerSpawn, freezetag_PlayerSpawn, CBC_ORDER_ANY);
 621         MUTATOR_HOOK(reset_map_players, freezetag_reset_map_players, CBC_ORDER_ANY);
 622         MUTATOR_HOOK(GiveFragsForKill, freezetag_GiveFragsForKill, CBC_ORDER_FIRST);
 623         MUTATOR_HOOK(PlayerPreThink, freezetag_PlayerPreThink, CBC_ORDER_FIRST);
 624         MUTATOR_HOOK(PlayerPhysics, freezetag_PlayerPhysics, CBC_ORDER_FIRST);
 625         MUTATOR_HOOK(PlayerDamage_Calculate, freezetag_PlayerDamage_Calculate, CBC_ORDER_ANY);
 626         MUTATOR_HOOK(ForbidThrowCurrentWeapon, freezetag_ForbidThrowCurrentWeapon, CBC_ORDER_ANY);
 627         MUTATOR_HOOK(HavocBot_ChooseRule, freezetag_BotRoles, CBC_ORDER_ANY);
 628         MUTATOR_HOOK(SpectateCopy, freezetag_SpectateCopy, CBC_ORDER_ANY);
 629         MUTATOR_HOOK(GetTeamCount, freezetag_GetTeamCount, CBC_ORDER_EXCLUSIVE);
 630
 631         MUTATOR_ONADD
 632         {
 633                 if(time > 1) // game loads at time 1
 634                         error("This is a game type and it cannot be added at runtime.");
 635                 freezetag_Initialize();
 636         }
 637
 638         MUTATOR_ONROLLBACK_OR_REMOVE
 639         {
 640                 // we actually cannot roll back freezetag_Initialize here
 641                 // BUT: we don't need to! If this gets called, adding always
 642                 // succeeds.
 643         }
 644
 645         MUTATOR_ONREMOVE
 646         {
 647                 print("This is a game type and it cannot be removed at runtime.");
 648                 return -1;
 649         }
 650
 651         return 0;
 652 }