qcsrc/server/mutators/gamemode_freezetag.qc

   1 float freezetag_CheckTeams();
   2 float freezetag_CheckWinner();
   3 void freezetag_Initialize()
   4 {
   5         precache_model("models/ice/ice.md3");
   6         ScoreRules_freezetag();
   7
   8         round_handler_Spawn(freezetag_CheckTeams, freezetag_CheckWinner, 5, autocvar_g_freezetag_warmup);
   9
  10         addstat(STAT_REDALIVE, AS_INT, redalive_stat);
  11         addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
  12         addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
  13         addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
  14
  15         addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
  16         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
  17 }
  18
  19 void freezetag_count_alive_players()
  20 {
  21         entity e;
  22         total_players = redalive = bluealive = yellowalive = pinkalive = 0;
  23         FOR_EACH_PLAYER(e) {
  24                 if(e.team == COLOR_TEAM1 && e.health >= 1)
  25                 {
  26                         ++total_players;
  27                         if (!e.freezetag_frozen) ++redalive;
  28                 }
  29                 else if(e.team == COLOR_TEAM2 && e.health >= 1)
  30                 {
  31                         ++total_players;
  32                         if (!e.freezetag_frozen) ++bluealive;
  33                 }
  34                 else if(e.team == COLOR_TEAM3 && e.health >= 1)
  35                 {
  36                         ++total_players;
  37                         if (!e.freezetag_frozen) ++yellowalive;
  38                 }
  39                 else if(e.team == COLOR_TEAM4 && e.health >= 1)
  40                 {
  41                         ++total_players;
  42                         if (!e.freezetag_frozen) ++pinkalive;
  43                 }
  44         }
  45         FOR_EACH_REALCLIENT(e) {
  46                 e.redalive_stat = redalive;
  47                 e.bluealive_stat = bluealive;
  48                 e.yellowalive_stat = yellowalive;
  49                 e.pinkalive_stat = pinkalive;
  50         }
  51 }
  52
  53 float freezetag_TeamsCanPlay()
  54 {
  55         if((redalive >= 1 && bluealive >= 1)
  56                 || (redalive >= 1 && yellowalive >= 1)
  57                 || (redalive >= 1 && pinkalive >= 1)
  58                 || (bluealive >= 1 && yellowalive >= 1)
  59                 || (bluealive >= 1 && pinkalive >= 1)
  60                 || (yellowalive >= 1 && pinkalive >= 1))
  61                 return 1; // we still have active players on two or more teams, nobody won yet
  62         return 0;
  63 }
  64
  65 float prev_total_players;
  66 float freezetag_CheckTeams()
  67 {
  68         entity e;
  69         if(freezetag_TeamsCanPlay())
  70         {
  71                 if(prev_total_players != -1)
  72                 {
  73                         FOR_EACH_REALCLIENT(e)
  74                                 Send_CSQC_Centerprint_Generic_Expire(e, CPID_WAITING_PLAYERS);
  75                 }
  76                 prev_total_players = -1;
  77                 return 1;
  78         }
  79         if(prev_total_players != total_players)
  80         {
  81                 string teams_missing;
  82                 if(!redalive)   teams_missing = strcat(teams_missing, ColoredTeamName(COLOR_TEAM1), ", ");
  83                 if(!bluealive)  teams_missing = strcat(teams_missing, ColoredTeamName(COLOR_TEAM2), ", ");
  84                 teams_missing = substring(teams_missing, 0, strlen(teams_missing)-2);
  85
  86                 FOR_EACH_REALCLIENT(e)
  87                         Send_CSQC_Centerprint_Generic(e, CPID_WAITING_PLAYERS, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), -1, 0);
  88                 prev_total_players = total_players;
  89         }
  90         return 0;
  91 }
  92 float freezetag_CheckWinner()
  93 {
  94         if(freezetag_TeamsCanPlay())
  95                 return 0;
  96
  97         entity e, winner;
  98         string teamname;
  99         winner = world;
 100
 101         FOR_EACH_PLAYER(e)
 102         {
 103                 if(e.freezetag_frozen == 0 && e.health >= 1) // here's one player from the winning team... good
 104                 {
 105                         winner = e;
 106                         break; // break, we found the winner
 107                 }
 108         }
 109
 110         if(winner != world) // just in case a winner wasn't found
 111         {
 112                 teamname = ColoredTeamName(winner.team);
 113                 FOR_EACH_REALCLIENT(e)
 114                         centerprint(e, strcat(teamname, "^5 wins the round, all other teams were frozen."));
 115                 bprint(teamname, "^5 wins the round since all the other teams were frozen.\n");
 116                 TeamScore_AddToTeam(winner.team, ST_SCORE, +1);
 117         }
 118
 119         return 1;
 120 }
 121
 122 // this is needed to allow the player to turn his view around (fixangle can't
 123 // be used to freeze his view, as that also changes the angles), while not
 124 // turning that ice object with the player
 125 void freezetag_Ice_Think()
 126 {
 127         setorigin(self, self.owner.origin - '0 0 16');
 128         self.nextthink = time;
 129 }
 130
 131 void freezetag_Add_Score(entity attacker)
 132 {
 133         if(attacker == self)
 134         {
 135                 // you froze your own dumb self
 136                 // counted as "suicide" already
 137                 PlayerScore_Add(self, SP_SCORE, -1);
 138         }
 139         else if(attacker.classname == "player")
 140         {
 141                 // got frozen by an enemy
 142                 // counted as "kill" and "death" already
 143                 PlayerScore_Add(self, SP_SCORE, -1);
 144                 PlayerScore_Add(attacker, SP_SCORE, +1);
 145         }
 146         // else nothing - got frozen by the game type rules themselves
 147 }
 148
 149 void freezetag_Freeze(entity attacker)
 150 {
 151         if(self.freezetag_frozen)
 152                 return;
 153         self.freezetag_frozen = 1;
 154         self.freezetag_revive_progress = 0;
 155         self.health = 1;
 156         // if(inWarmupStage)
 157                 // self.freezetag_frozen_timeout = time + 5;
 158
 159         freezetag_count_alive_players();
 160
 161         entity ice;
 162         ice = spawn();
 163         ice.owner = self;
 164         ice.classname = "freezetag_ice";
 165         ice.think = freezetag_Ice_Think;
 166         ice.nextthink = time;
 167         ice.frame = floor(random() * 21); // ice model has 20 different looking frames
 168         setmodel(ice, "models/ice/ice.md3");
 169
 170         entity oldself;
 171         oldself = self;
 172         self = ice;
 173         freezetag_Ice_Think();
 174         self = oldself;
 175
 176         RemoveGrapplingHook(self);
 177
 178         // add waypoint
 179         WaypointSprite_Spawn("freezetag_frozen", 0, 0, self, '0 0 64', world, self.team, self, waypointsprite_attached, TRUE, RADARICON_WAYPOINT, '0.25 0.90 1');
 180
 181         freezetag_Add_Score(attacker);
 182 }
 183
 184 void freezetag_Unfreeze(entity attacker)
 185 {
 186         self.freezetag_frozen = 0;
 187         self.freezetag_frozen_timeout = 0;
 188         self.freezetag_revive_progress = 0;
 189
 190         // remove the ice block
 191         entity ice;
 192         for(ice = world; (ice = find(ice, classname, "freezetag_ice")); ) if(ice.owner == self)
 193         {
 194                 remove(ice);
 195                 break;
 196         }
 197
 198         // remove waypoint
 199         if(self.waypointsprite_attached)
 200                 WaypointSprite_Kill(self.waypointsprite_attached);
 201 }
 202
 203
 204 // ================
 205 // Bot player logic
 206 // ================
 207
 208 void() havocbot_role_ft_freeing;
 209 void() havocbot_role_ft_offense;
 210
 211 void havocbot_goalrating_freeplayers(float ratingscale, vector org, float sradius)
 212 {
 213         entity head;
 214         float distance;
 215
 216         FOR_EACH_PLAYER(head)
 217         {
 218                 if ((head != self) && (head.team == self.team))
 219                 {
 220                         if (head.freezetag_frozen)
 221                         {
 222                                 distance = vlen(head.origin - org);
 223                                 if (distance > sradius)
 224                                         continue;
 225                                 navigation_routerating(head, ratingscale, 2000);
 226                         }
 227                         else
 228                         {
 229                                 // If teamate is not frozen still seek them out as fight better
 230                                 // in a group.
 231                                 navigation_routerating(head, ratingscale/3, 2000);
 232                         }
 233                 }
 234         }
 235 }
 236
 237 void havocbot_role_ft_offense()
 238 {
 239         entity head;
 240         float unfrozen;
 241
 242         if(self.deadflag != DEAD_NO)
 243                 return;
 244
 245         if (!self.havocbot_role_timeout)
 246                 self.havocbot_role_timeout = time + random() * 10 + 20;
 247
 248         // Count how many players on team are unfrozen.
 249         unfrozen = 0;
 250         FOR_EACH_PLAYER(head)
 251         {
 252                 if ((head.team == self.team) && (!head.freezetag_frozen))
 253                         unfrozen++;
 254         }
 255
 256         // If only one left on team or if role has timed out then start trying to free players.
 257         if (((unfrozen == 0) && (!self.freezetag_frozen)) || (time > self.havocbot_role_timeout))
 258         {
 259                 dprint("changing role to freeing\n");
 260                 self.havocbot_role = havocbot_role_ft_freeing;
 261                 self.havocbot_role_timeout = 0;
 262                 return;
 263         }
 264
 265         if (time > self.bot_strategytime)
 266         {
 267                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 268
 269                 navigation_goalrating_start();
 270                 havocbot_goalrating_items(10000, self.origin, 10000);
 271                 havocbot_goalrating_enemyplayers(20000, self.origin, 10000);
 272                 havocbot_goalrating_freeplayers(9000, self.origin, 10000);
 273                 //havocbot_goalrating_waypoints(1, self.origin, 1000);
 274                 navigation_goalrating_end();
 275         }
 276 }
 277
 278 void havocbot_role_ft_freeing()
 279 {
 280         if(self.deadflag != DEAD_NO)
 281                 return;
 282
 283         if (!self.havocbot_role_timeout)
 284                 self.havocbot_role_timeout = time + random() * 10 + 20;
 285
 286         if (time > self.havocbot_role_timeout)
 287         {
 288                 dprint("changing role to offense\n");
 289                 self.havocbot_role = havocbot_role_ft_offense;
 290                 self.havocbot_role_timeout = 0;
 291                 return;
 292         }
 293
 294         if (time > self.bot_strategytime)
 295         {
 296                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 297
 298                 navigation_goalrating_start();
 299                 havocbot_goalrating_items(8000, self.origin, 10000);
 300                 havocbot_goalrating_enemyplayers(10000, self.origin, 10000);
 301                 havocbot_goalrating_freeplayers(20000, self.origin, 10000);
 302                 //havocbot_goalrating_waypoints(1, self.origin, 1000);
 303                 navigation_goalrating_end();
 304         }
 305 }
 306
 307
 308 // ==============
 309 // Hook Functions
 310 // ==============
 311
 312 MUTATOR_HOOKFUNCTION(freezetag_RemovePlayer)
 313 {
 314         self.health = 0; // neccessary to update correctly alive stats
 315         freezetag_Unfreeze(world);
 316         freezetag_count_alive_players();
 317         return 1;
 318 }
 319
 320 MUTATOR_HOOKFUNCTION(freezetag_PlayerDies)
 321 {
 322         if(round_handler_IsActive())
 323         if(round_handler_CountdownRunning())
 324         {
 325                 if(self.freezetag_frozen)
 326                         freezetag_Unfreeze(world);
 327                 freezetag_count_alive_players();
 328                 return 1; // let the player die so that he can respawn whenever he wants
 329         }
 330
 331         switch(frag_deathtype)
 332         {
 333                 case DEATH_HURTTRIGGER:
 334                 case DEATH_FALL:
 335                 case DEATH_DROWN:
 336                 case DEATH_LAVA:
 337                 case DEATH_SLIME:
 338                 case DEATH_SWAMP:
 339                 case DEATH_TEAMCHANGE:
 340                 case DEATH_AUTOTEAMCHANGE:
 341                 {
 342                         // let the player die, he will be automatically frozen when he respawns
 343                         if(!self.freezetag_frozen)
 344                         {
 345                                 freezetag_Add_Score(frag_attacker);
 346                                 freezetag_count_alive_players();
 347                         }
 348                         else
 349                                 freezetag_Unfreeze(world); // remove ice
 350                         self.freezetag_frozen_timeout = -2; // freeze on respawn
 351                         return 1;
 352                 }
 353         }
 354
 355         if(self.freezetag_frozen)
 356                 return 1;
 357
 358         freezetag_Freeze(frag_attacker);
 359
 360         if(frag_attacker == frag_target || frag_attacker == world)
 361         {
 362                 if(frag_target.classname == STR_PLAYER)
 363                         centerprint(frag_target, "^1You froze yourself.\n");
 364                 bprint("^7", frag_target.netname, "^1 froze himself.\n");
 365         }
 366         else
 367         {
 368                 if(frag_target.classname == STR_PLAYER)
 369                         centerprint(frag_target, strcat("^1You were frozen by ^7", frag_attacker.netname, ".\n"));
 370                 if(frag_attacker.classname == STR_PLAYER)
 371                         centerprint(frag_attacker, strcat("^2You froze ^7", frag_target.netname, ".\n"));
 372                 bprint("^7", frag_target.netname, "^1 was frozen by ^7", frag_attacker.netname, ".\n");
 373         }
 374
 375         frag_target.health = 1; // "respawn" the player :P
 376
 377         return 1;
 378 }
 379
 380 MUTATOR_HOOKFUNCTION(freezetag_PlayerSpawn)
 381 {
 382         if(self.freezetag_frozen_timeout == -1) // if PlayerSpawn is called by reset_map_players
 383                 return 1; // do nothing, round is starting right now
 384
 385         if(self.freezetag_frozen_timeout == -2) // player was dead
 386         {
 387                 freezetag_Freeze(world);
 388                 return 1;
 389         }
 390
 391         freezetag_count_alive_players();
 392
 393         if(round_handler_IsActive())
 394         if(round_handler_IsRoundStarted())
 395         {
 396                 centerprint(self, "^1Round already started, you spawn as frozen.");
 397                 freezetag_Freeze(world);
 398         }
 399
 400         return 1;
 401 }
 402
 403 MUTATOR_HOOKFUNCTION(freezetag_reset_map_players)
 404 {
 405         FOR_EACH_PLAYER(self)
 406         {
 407                 if (self.freezetag_frozen)
 408                         freezetag_Unfreeze(world);
 409                 self.freezetag_frozen_timeout = -1;
 410                 PutClientInServer();
 411                 self.freezetag_frozen_timeout = 0;
 412         }
 413         freezetag_count_alive_players();
 414         return 1;
 415 }
 416
 417 MUTATOR_HOOKFUNCTION(freezetag_GiveFragsForKill)
 418 {
 419         frag_score = 0; // no frags counted in Freeze Tag
 420         return 1;
 421 }
 422
 423 MUTATOR_HOOKFUNCTION(freezetag_PlayerPreThink)
 424 {
 425         float n;
 426         vector revive_extra_size;
 427
 428         if(gameover)
 429                 return 1;
 430
 431         if(self.freezetag_frozen)
 432         {
 433                 // keep health = 1
 434                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen;
 435
 436                 if(self.freezetag_frozen_timeout > 0 && time >= self.freezetag_frozen_timeout)
 437                 {
 438                         self.health = autocvar_g_balance_health_start;
 439                         freezetag_Unfreeze(world);
 440                         freezetag_count_alive_players();
 441                         return 1;
 442                 }
 443         }
 444
 445         if(round_handler_IsActive())
 446         if(!round_handler_IsRoundStarted())
 447                 return 1;
 448
 449         revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
 450
 451         entity o;
 452         o = world;
 453         n = 0;
 454         FOR_EACH_PLAYER(other) if(self != other)
 455         {
 456                 if(other.freezetag_frozen == 0)
 457                 {
 458                         if(other.team == self.team)
 459                         {
 460                                 if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
 461                                 {
 462                                         if(!o)
 463                                                 o = other;
 464                                         ++n;
 465                                 }
 466                         }
 467                 }
 468         }
 469
 470         if(n && self.freezetag_frozen) // OK, there is at least one teammate reviving us
 471         {
 472                 self.freezetag_revive_progress = bound(0, self.freezetag_revive_progress + frametime * autocvar_g_freezetag_revive_speed, 1);
 473                 self.health = max(1, self.freezetag_revive_progress * autocvar_g_balance_health_start);
 474
 475                 if(self.freezetag_revive_progress >= 1)
 476                 {
 477                         freezetag_Unfreeze(self);
 478                         freezetag_count_alive_players();
 479
 480                         // EVERY team mate nearby gets a point (even if multiple!)
 481                         FOR_EACH_PLAYER(other) if(self != other)
 482                         {
 483                                 if(other.freezetag_frozen == 0)
 484                                 {
 485                                         if(other.team == self.team)
 486                                         {
 487                                                 if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
 488                                                 {
 489                                                         PlayerScore_Add(other, SP_FREEZETAG_REVIVALS, +1);
 490                                                         PlayerScore_Add(other, SP_SCORE, +1);
 491                                                 }
 492                                         }
 493                                 }
 494                         }
 495
 496                         if(n > 1)
 497                                 centerprint(self, strcat("^5You were revived by ^7", o.netname, "^5 et al.\n"));
 498                         else
 499                                 centerprint(self, strcat("^5You were revived by ^7", o.netname, "^5.\n"));
 500                         centerprint(o, strcat("^5You revived ^7", self.netname, "^5.\n"));
 501                         if(n > 1)
 502                                 bprint("^7", o.netname, "^5 et al revived ^7", self.netname, "^5.\n");
 503                         else
 504                                 bprint("^7", o.netname, "^5 revived ^7", self.netname, "^5.\n");
 505                 }
 506
 507                 // now find EVERY teammate within reviving radius, set their revive_progress values correct
 508                 FOR_EACH_PLAYER(other) if(self != other)
 509                 {
 510                         if(other.freezetag_frozen == 0)
 511                         {
 512                                 if(other.team == self.team)
 513                                 {
 514                                         if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
 515                                                 other.freezetag_revive_progress = self.freezetag_revive_progress;
 516                                 }
 517                         }
 518                 }
 519         }
 520         else if(!n && self.freezetag_frozen) // only if no teammate is nearby will we reset
 521         {
 522                 self.freezetag_revive_progress = bound(0, self.freezetag_revive_progress - frametime * autocvar_g_freezetag_revive_clearspeed, 1);
 523                 self.health = max(1, self.freezetag_revive_progress * autocvar_g_balance_health_start);
 524         }
 525         else if(!n)
 526         {
 527                 self.freezetag_revive_progress = 0; // thawing nobody
 528         }
 529
 530         return 1;
 531 }
 532
 533 MUTATOR_HOOKFUNCTION(freezetag_PlayerPhysics)
 534 {
 535         if(self.freezetag_frozen)
 536         {
 537                 self.movement = '0 0 0';
 538                 self.disableclientprediction = 1;
 539         }
 540         return 1;
 541 }
 542
 543 MUTATOR_HOOKFUNCTION(freezetag_PlayerDamage_Calculate)
 544 {
 545         if(frag_target.freezetag_frozen == 1 && frag_deathtype != DEATH_HURTTRIGGER)
 546         {
 547                 frag_damage = 0;
 548                 frag_force = frag_force * autocvar_g_freezetag_frozen_force;
 549         }
 550         return 1;
 551 }
 552
 553 MUTATOR_HOOKFUNCTION(freezetag_ForbidThrowCurrentWeapon)
 554 {
 555         if (self.freezetag_frozen)
 556                 return 1;
 557         return 0;
 558 }
 559
 560 MUTATOR_HOOKFUNCTION(freezetag_BotRoles)
 561 {
 562         if not(self.deadflag)
 563         {
 564                 if (random() < 0.5)
 565                         self.havocbot_role = havocbot_role_ft_freeing;
 566                 else
 567                         self.havocbot_role = havocbot_role_ft_offense;
 568         }
 569
 570         return TRUE;
 571 }
 572
 573 MUTATOR_HOOKFUNCTION(freezetag_SpectateCopy)
 574 {
 575         self.freezetag_frozen = other.freezetag_frozen;
 576         self.freezetag_revive_progress = other.freezetag_revive_progress;
 577         return 0;
 578 }
 579
 580 MUTATOR_DEFINITION(gamemode_freezetag)
 581 {
 582         MUTATOR_HOOK(MakePlayerObserver, freezetag_RemovePlayer, CBC_ORDER_ANY);
 583         MUTATOR_HOOK(ClientDisconnect, freezetag_RemovePlayer, CBC_ORDER_ANY);
 584         MUTATOR_HOOK(PlayerDies, freezetag_PlayerDies, CBC_ORDER_ANY);
 585         MUTATOR_HOOK(PlayerSpawn, freezetag_PlayerSpawn, CBC_ORDER_ANY);
 586         MUTATOR_HOOK(reset_map_players, freezetag_reset_map_players, CBC_ORDER_ANY);
 587         MUTATOR_HOOK(GiveFragsForKill, freezetag_GiveFragsForKill, CBC_ORDER_FIRST);
 588         MUTATOR_HOOK(PlayerPreThink, freezetag_PlayerPreThink, CBC_ORDER_FIRST);
 589         MUTATOR_HOOK(PlayerPhysics, freezetag_PlayerPhysics, CBC_ORDER_FIRST);
 590         MUTATOR_HOOK(PlayerDamage_Calculate, freezetag_PlayerDamage_Calculate, CBC_ORDER_ANY);
 591         MUTATOR_HOOK(ForbidThrowCurrentWeapon, freezetag_ForbidThrowCurrentWeapon, CBC_ORDER_ANY);
 592         MUTATOR_HOOK(HavocBot_ChooseRule, freezetag_BotRoles, CBC_ORDER_ANY);
 593         MUTATOR_HOOK(SpectateCopy, freezetag_SpectateCopy, CBC_ORDER_ANY);
 594
 595         MUTATOR_ONADD
 596         {
 597                 if(time > 1) // game loads at time 1
 598                         error("This is a game type and it cannot be added at runtime.");
 599                 freezetag_Initialize();
 600         }
 601
 602         MUTATOR_ONREMOVE
 603         {
 604                 error("This is a game type and it cannot be removed at runtime.");
 605         }
 606
 607         return 0;
 608 }