qcsrc/server/mutators/gamemode_freezetag.qc

   1 void freezetag_Initialize()
   2 {
   3         precache_model("models/ice/ice.md3");
   4         warmup = max(time, game_starttime) + autocvar_g_freezetag_warmup;
   5         ScoreRules_freezetag();
   6 }
   7
   8 void freezetag_CheckWinner()
   9 {
  10         if(time <= game_starttime) // game didn't even start yet! nobody can win in that case.
  11                 return;
  12
  13         if(next_round || (time > warmup - autocvar_g_freezetag_warmup && time < warmup))
  14                 return; // already waiting for next round to start
  15
  16         if((redalive >= 1 && bluealive >= 1)
  17                 || (redalive >= 1 && yellowalive >= 1)
  18                 || (redalive >= 1 && pinkalive >= 1)
  19                 || (bluealive >= 1 && yellowalive >= 1)
  20                 || (bluealive >= 1 && pinkalive >= 1)
  21                 || (yellowalive >= 1 && pinkalive >= 1))
  22                 return; // we still have active players on two or more teams, nobody won yet
  23
  24         entity e, winner;
  25         string teamname;
  26         winner = world;
  27
  28         FOR_EACH_PLAYER(e)
  29         {
  30                 if(e.freezetag_frozen == 0 && e.health >= 1) // here's one player from the winning team... good
  31                 {
  32                         winner = e;
  33                         break; // break, we found the winner
  34                 }
  35         }
  36
  37         if(winner != world) // just in case a winner wasn't found
  38         {
  39                 if(winner.team == COLOR_TEAM1)
  40                         teamname = "^1Red Team";
  41                 else if(winner.team == COLOR_TEAM2)
  42                         teamname = "^4Blue Team";
  43                 else if(winner.team == COLOR_TEAM3)
  44                         teamname = "^3Yellow Team";
  45                 else
  46                         teamname = "^6Pink Team";
  47                 FOR_EACH_PLAYER(e) {
  48                         centerprint(e, strcat(teamname, "^5 wins the round, all other teams were frozen.\n"));
  49                 }
  50                 bprint(teamname, "^5 wins the round since all the other teams were frozen.\n");
  51                 TeamScore_AddToTeam(winner.team, ST_SCORE, +1);
  52         }
  53
  54         next_round = time + 5;
  55 }
  56
  57 // this is needed to allow the player to turn his view around (fixangle can't
  58 // be used to freeze his view, as that also changes the angles), while not
  59 // turning that ice object with the player
  60 void freezetag_Ice_Think()
  61 {
  62         setorigin(self, self.owner.origin - '0 0 16');
  63         self.nextthink = time;
  64 }
  65
  66 void freezetag_Freeze(entity attacker)
  67 {
  68         if(self.freezetag_frozen)
  69                 return;
  70         self.freezetag_frozen = 1;
  71         self.freezetag_revive_progress = 0;
  72         self.health = 1;
  73
  74         entity ice;
  75         ice = spawn();
  76         ice.owner = self;
  77         ice.classname = "freezetag_ice";
  78         ice.think = freezetag_Ice_Think;
  79         ice.nextthink = time;
  80         ice.frame = floor(random() * 21); // ice model has 20 different looking frames
  81         setmodel(ice, "models/ice/ice.md3");
  82
  83         entity oldself;
  84         oldself = self;
  85         self = ice;
  86         freezetag_Ice_Think();
  87         self = oldself;
  88
  89         RemoveGrapplingHook(self);
  90
  91         // add waypoint
  92         WaypointSprite_Spawn("freezetag_frozen", 0, 0, self, '0 0 64', world, self.team, self, waypointsprite_attached, TRUE, RADARICON_WAYPOINT, '0.25 0.90 1');
  93
  94         if(attacker == self)
  95         {
  96                 // you froze your own dumb self
  97                 // counted as "suicide" already
  98                 PlayerScore_Add(self, SP_SCORE, -1);
  99         }
 100         else if(attacker.classname == "player")
 101         {
 102                 // got frozen by an enemy
 103                 // counted as "kill" and "death" already
 104                 PlayerScore_Add(self, SP_SCORE, -1);
 105                 PlayerScore_Add(attacker, SP_SCORE, +1);
 106         }
 107         else
 108         {
 109                 // nothing - got frozen by the game type rules themselves
 110         }
 111 }
 112
 113 void freezetag_Unfreeze(entity attacker)
 114 {
 115         self.freezetag_frozen = 0;
 116         self.freezetag_revive_progress = 0;
 117         self.health = autocvar_g_balance_health_start;
 118
 119         // remove the ice block
 120         entity ice;
 121         for(ice = world; (ice = find(ice, classname, "freezetag_ice")); ) if(ice.owner == self)
 122         {
 123                 remove(ice);
 124                 break;
 125         }
 126
 127         // remove waypoint
 128         if(self.waypointsprite_attached)
 129                 WaypointSprite_Kill(self.waypointsprite_attached);
 130 }
 131
 132
 133 // ================
 134 // Bot player logic
 135 // ================
 136
 137 void() havocbot_role_ft_freeing;
 138 void() havocbot_role_ft_offense;
 139
 140 void havocbot_goalrating_freeplayers(float ratingscale, vector org, float sradius)
 141 {
 142         entity head;
 143         float distance;
 144
 145         FOR_EACH_PLAYER(head)
 146         {
 147                 if ((head != self) && (head.team == self.team))
 148                 {
 149                         if (head.freezetag_frozen)
 150                         {
 151                                 distance = vlen(head.origin - org);
 152                                 if (distance > sradius)
 153                                         continue;
 154                                 navigation_routerating(head, ratingscale, 2000);
 155                         }
 156                         else
 157                         {
 158                                 // If teamate is not frozen still seek them out as fight better
 159                                 // in a group.
 160                                 navigation_routerating(head, ratingscale/3, 2000);
 161                         }
 162                 }
 163         }
 164 }
 165
 166 void havocbot_role_ft_offense()
 167 {
 168         entity head;
 169         float unfrozen;
 170
 171         if(self.deadflag != DEAD_NO)
 172                 return;
 173
 174         if (!self.havocbot_role_timeout)
 175                 self.havocbot_role_timeout = time + random() * 10 + 20;
 176
 177         // Count how many players on team are unfrozen.
 178         unfrozen = 0;
 179         FOR_EACH_PLAYER(head)
 180         {
 181                 if ((head.team == self.team) && (!head.freezetag_frozen))
 182                         unfrozen++;
 183         }
 184
 185         // If only one left on team or if role has timed out then start trying to free players.
 186         if (((unfrozen == 0) && (!self.freezetag_frozen)) || (time > self.havocbot_role_timeout))
 187         {
 188                 dprint("changing role to freeing\n");
 189                 self.havocbot_role = havocbot_role_ft_freeing;
 190                 self.havocbot_role_timeout = 0;
 191                 return;
 192         }
 193
 194         if (time > self.bot_strategytime)
 195         {
 196                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 197
 198                 navigation_goalrating_start();
 199                 havocbot_goalrating_items(10000, self.origin, 10000);
 200                 havocbot_goalrating_enemyplayers(20000, self.origin, 10000);
 201                 havocbot_goalrating_freeplayers(9000, self.origin, 10000);
 202                 //havocbot_goalrating_waypoints(1, self.origin, 1000);
 203                 navigation_goalrating_end();
 204         }
 205 }
 206
 207 void havocbot_role_ft_freeing()
 208 {
 209         if(self.deadflag != DEAD_NO)
 210                 return;
 211
 212         if (!self.havocbot_role_timeout)
 213                 self.havocbot_role_timeout = time + random() * 10 + 20;
 214
 215         if (time > self.havocbot_role_timeout)
 216         {
 217                 dprint("changing role to offense\n");
 218                 self.havocbot_role = havocbot_role_ft_offense;
 219                 self.havocbot_role_timeout = 0;
 220                 return;
 221         }
 222
 223         if (time > self.bot_strategytime)
 224         {
 225                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 226
 227                 navigation_goalrating_start();
 228                 havocbot_goalrating_items(8000, self.origin, 10000);
 229                 havocbot_goalrating_enemyplayers(10000, self.origin, 10000);
 230                 havocbot_goalrating_freeplayers(20000, self.origin, 10000);
 231                 //havocbot_goalrating_waypoints(1, self.origin, 1000);
 232                 navigation_goalrating_end();
 233         }
 234 }
 235
 236
 237 // ==============
 238 // Hook Functions
 239 // ==============
 240
 241 MUTATOR_HOOKFUNCTION(freezetag_RemovePlayer)
 242 {
 243         if(self.freezetag_frozen == 0 && self.health >= 1)
 244         {
 245                 if(self.team == COLOR_TEAM1)
 246                         --redalive;
 247                 else if(self.team == COLOR_TEAM2)
 248                         --bluealive;
 249                 else if(self.team == COLOR_TEAM3)
 250                         --yellowalive;
 251                 else if(self.team == COLOR_TEAM4)
 252                         --pinkalive;
 253                 --totalalive;
 254         }
 255
 256         if(total_players > 2) // only check for winners if we had more than two players (one of them left, don't let the other player win just because of that)
 257                 freezetag_CheckWinner();
 258
 259         freezetag_Unfreeze(world);
 260
 261         return 1;
 262 }
 263
 264 MUTATOR_HOOKFUNCTION(freezetag_PlayerDies)
 265 {
 266         if(self.freezetag_frozen == 0)
 267         {
 268                 if(self.team == COLOR_TEAM1)
 269                         --redalive;
 270                 else if(self.team == COLOR_TEAM2)
 271                         --bluealive;
 272                 else if(self.team == COLOR_TEAM3)
 273                         --yellowalive;
 274                 else if(self.team == COLOR_TEAM4)
 275                         --pinkalive;
 276                 --totalalive;
 277
 278                 freezetag_Freeze(frag_attacker);
 279         }
 280
 281         if(frag_attacker == frag_target || frag_attacker == world)
 282         {
 283                 if(frag_target.classname == STR_PLAYER)
 284                         centerprint(frag_target, "^1You froze yourself.\n");
 285                 bprint("^7", frag_target.netname, "^1 froze himself.\n");
 286         }
 287         else
 288         {
 289                 if(frag_target.classname == STR_PLAYER)
 290                         centerprint(frag_target, strcat("^1You were frozen by ^7", frag_attacker.netname, ".\n"));
 291                 if(frag_attacker.classname == STR_PLAYER)
 292                         centerprint(frag_attacker, strcat("^2You froze ^7", frag_target.netname, ".\n"));
 293                 bprint("^7", frag_target.netname, "^1 was frozen by ^7", frag_attacker.netname, ".\n");
 294         }
 295
 296         frag_target.health = 1; // "respawn" the player :P
 297
 298         freezetag_CheckWinner();
 299
 300         return 1;
 301 }
 302
 303 MUTATOR_HOOKFUNCTION(freezetag_PlayerSpawn)
 304 {
 305         if(time <= game_starttime)
 306                 return 1;
 307
 308         freezetag_Unfreeze(world); // start by making sure that all ice blocks are removed
 309
 310         if(total_players == 1) // only one player active on server, start a new match immediately
 311         if(!next_round && warmup && (time < warmup - autocvar_g_freezetag_warmup || time > warmup)) // not awaiting next round
 312         {
 313                 next_round = time;
 314                 return 1;
 315         }
 316         if(warmup && time > warmup) // spawn too late, freeze player
 317         {
 318                 centerprint(self, "^1You spawned after the round started, you'll spawn as frozen.\n");
 319                 freezetag_Freeze(world);
 320         }
 321
 322         return 1;
 323 }
 324
 325 MUTATOR_HOOKFUNCTION(freezetag_GiveFragsForKill)
 326 {
 327         frag_score = 0; // no frags counted in Freeze Tag
 328         return 1;
 329 }
 330
 331 MUTATOR_HOOKFUNCTION(freezetag_PlayerPreThink)
 332 {
 333         float n;
 334         vector revive_extra_size;
 335
 336         revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
 337
 338         entity o;
 339         o = world;
 340         n = 0;
 341         FOR_EACH_PLAYER(other) if(self != other)
 342         {
 343                 if(other.freezetag_frozen == 0)
 344                 {
 345                         if(other.team == self.team)
 346                         {
 347                                 if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
 348                                 {
 349                                         if(!o)
 350                                                 o = other;
 351                                         ++n;
 352                                 }
 353                         }
 354                 }
 355         }
 356
 357         if(n && self.freezetag_frozen) // OK, there is at least one teammate reviving us
 358         {
 359                 self.freezetag_revive_progress = bound(0, self.freezetag_revive_progress + frametime * autocvar_g_freezetag_revive_speed, 1);
 360                 self.health = max(1, self.freezetag_revive_progress * autocvar_g_balance_health_start);
 361
 362                 if(self.freezetag_revive_progress >= 1)
 363                 {
 364                         freezetag_Unfreeze(self);
 365
 366                         // EVERY team mate nearby gets a point (even if multiple!)
 367                         FOR_EACH_PLAYER(other) if(self != other)
 368                         {
 369                                 if(other.freezetag_frozen == 0)
 370                                 {
 371                                         if(other.team == self.team)
 372                                         {
 373                                                 if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
 374                                                 {
 375                                                         PlayerScore_Add(other, SP_FREEZETAG_REVIVALS, +1);
 376                                                         PlayerScore_Add(other, SP_SCORE, +1);
 377                                                 }
 378                                         }
 379                                 }
 380                         }
 381
 382                         if(n > 1)
 383                                 centerprint(self, strcat("^5You were revived by ^7", o.netname, "^5 et al.\n"));
 384                         else
 385                                 centerprint(self, strcat("^5You were revived by ^7", o.netname, "^5.\n"));
 386                         centerprint(o, strcat("^5You revived ^7", self.netname, "^5.\n"));
 387                         if(n > 1)
 388                                 bprint("^7", o.netname, "^5 et al revived ^7", self.netname, "^5.\n");
 389                         else
 390                                 bprint("^7", o.netname, "^5 revived ^7", self.netname, "^5.\n");
 391                 }
 392
 393                 // now find EVERY teammate within reviving radius, set their revive_progress values correct
 394                 FOR_EACH_PLAYER(other) if(self != other)
 395                 {
 396                         if(other.freezetag_frozen == 0)
 397                         {
 398                                 if(other.team == self.team)
 399                                 {
 400                                         if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
 401                                                 other.freezetag_revive_progress = self.freezetag_revive_progress;
 402                                 }
 403                         }
 404                 }
 405         }
 406         else if(!n && self.freezetag_frozen) // only if no teammate is nearby will we reset
 407         {
 408                 self.freezetag_revive_progress = bound(0, self.freezetag_revive_progress - frametime * autocvar_g_freezetag_revive_clearspeed, 1);
 409                 self.health = max(1, self.freezetag_revive_progress * autocvar_g_balance_health_start);
 410         }
 411         else if(!n)
 412         {
 413                 self.freezetag_revive_progress = 0; // thawing nobody
 414         }
 415
 416         return 1;
 417 }
 418
 419 MUTATOR_HOOKFUNCTION(freezetag_PlayerPhysics)
 420 {
 421         if(self.freezetag_frozen)
 422         {
 423                 self.movement = '0 0 0';
 424                 self.disableclientprediction = 1;
 425         }
 426         return 1;
 427 }
 428
 429 MUTATOR_HOOKFUNCTION(freezetag_PlayerDamage_Calculate)
 430 {
 431     if(g_freezetag)
 432     {
 433         if(frag_target.freezetag_frozen == 1 && frag_deathtype != DEATH_HURTTRIGGER)
 434         {
 435             frag_damage = 0;
 436             frag_force = frag_force * autocvar_g_freezetag_frozen_force;
 437         }
 438     }
 439     return 1;
 440 }
 441
 442 MUTATOR_HOOKFUNCTION(freezetag_ForbidThrowCurrentWeapon)
 443 {
 444         if (self.freezetag_frozen)
 445                 return 1;
 446         return 0;
 447 }
 448
 449 MUTATOR_HOOKFUNCTION(freezetag_BotRoles)
 450 {
 451         if not(self.deadflag)
 452         {
 453                 if (random() < 0.5)
 454                         self.havocbot_role = havocbot_role_ft_freeing;
 455                 else
 456                         self.havocbot_role = havocbot_role_ft_offense;
 457         }
 458
 459         return TRUE;
 460 }
 461
 462 MUTATOR_DEFINITION(gamemode_freezetag)
 463 {
 464         MUTATOR_HOOK(MakePlayerObserver, freezetag_RemovePlayer, CBC_ORDER_ANY);
 465         MUTATOR_HOOK(ClientDisconnect, freezetag_RemovePlayer, CBC_ORDER_ANY);
 466         MUTATOR_HOOK(PlayerDies, freezetag_PlayerDies, CBC_ORDER_ANY);
 467         MUTATOR_HOOK(PlayerSpawn, freezetag_PlayerSpawn, CBC_ORDER_ANY);
 468         MUTATOR_HOOK(GiveFragsForKill, freezetag_GiveFragsForKill, CBC_ORDER_FIRST);
 469         MUTATOR_HOOK(PlayerPreThink, freezetag_PlayerPreThink, CBC_ORDER_FIRST);
 470         MUTATOR_HOOK(PlayerPhysics, freezetag_PlayerPhysics, CBC_ORDER_FIRST);
 471         MUTATOR_HOOK(PlayerDamage_Calculate, freezetag_PlayerDamage_Calculate, CBC_ORDER_ANY);
 472         MUTATOR_HOOK(ForbidThrowCurrentWeapon, freezetag_ForbidThrowCurrentWeapon, CBC_ORDER_FIRST); //first, last or any? dunno.
 473         MUTATOR_HOOK(HavocBot_ChooseRule, freezetag_BotRoles, CBC_ORDER_ANY);
 474
 475         MUTATOR_ONADD
 476         {
 477                 if(time > 1) // game loads at time 1
 478                         error("This is a game type and it cannot be added at runtime.");
 479                 freezetag_Initialize();
 480         }
 481
 482         MUTATOR_ONREMOVE
 483         {
 484                 error("This is a game type and it cannot be removed at runtime.");
 485         }
 486
 487         return 0;
 488 }