qcsrc/server/mutators/gamemode_freezetag.qc

   1 .float freezetag_frozen_time;
   2 .float freezetag_frozen_timeout;
   3 .float freezetag_revive_progress;
   4 .entity freezetag_ice;
   5 #define ICE_MAX_ALPHA 1
   6 #define ICE_MIN_ALPHA 0.1
   7 float freezetag_teams;
   8
   9 float freezetag_CheckTeams();
  10 float freezetag_CheckWinner();
  11 void freezetag_Initialize()
  12 {
  13         precache_model("models/ice/ice.md3");
  14         ScoreRules_freezetag();
  15
  16         round_handler_Spawn(freezetag_CheckTeams, freezetag_CheckWinner, func_null);
  17         round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
  18
  19         addstat(STAT_REDALIVE, AS_INT, redalive_stat);
  20         addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
  21         addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
  22         addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
  23
  24         addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
  25         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
  26 }
  27
  28 void freezetag_count_alive_players()
  29 {
  30         entity e;
  31         total_players = redalive = bluealive = yellowalive = pinkalive = 0;
  32         FOR_EACH_PLAYER(e) {
  33                 if(e.team == COLOR_TEAM1 && e.health >= 1)
  34                 {
  35                         ++total_players;
  36                         if (!e.freezetag_frozen) ++redalive;
  37                 }
  38                 else if(e.team == COLOR_TEAM2 && e.health >= 1)
  39                 {
  40                         ++total_players;
  41                         if (!e.freezetag_frozen) ++bluealive;
  42                 }
  43                 else if(e.team == COLOR_TEAM3 && e.health >= 1)
  44                 {
  45                         ++total_players;
  46                         if (!e.freezetag_frozen) ++yellowalive;
  47                 }
  48                 else if(e.team == COLOR_TEAM4 && e.health >= 1)
  49                 {
  50                         ++total_players;
  51                         if (!e.freezetag_frozen) ++pinkalive;
  52                 }
  53         }
  54         FOR_EACH_REALCLIENT(e) {
  55                 e.redalive_stat = redalive;
  56                 e.bluealive_stat = bluealive;
  57                 e.yellowalive_stat = yellowalive;
  58                 e.pinkalive_stat = pinkalive;
  59         }
  60 }
  61 #define FREEZETAG_ALIVE_TEAMS() ((redalive > 0) + (bluealive > 0) + (yellowalive > 0) + (pinkalive > 0))
  62 #define FREEZETAG_ALIVE_TEAMS_OK() (FREEZETAG_ALIVE_TEAMS() == freezetag_teams)
  63
  64 float prev_total_players;
  65 float freezetag_CheckTeams()
  66 {
  67         entity e;
  68         if(FREEZETAG_ALIVE_TEAMS_OK())
  69         {
  70                 if(prev_total_players != -1)
  71                 {
  72                         FOR_EACH_REALCLIENT(e)
  73                                 Send_CSQC_Centerprint_Generic_Expire(e, CPID_WAITING_PLAYERS);
  74                 }
  75                 prev_total_players = -1;
  76                 return 1;
  77         }
  78         if(prev_total_players != total_players)
  79         {
  80                 string teams_missing = "";
  81                 if(!redalive)   teams_missing = strcat(teams_missing, ColoredTeamName(COLOR_TEAM1), ", ");
  82                 if(!bluealive)  teams_missing = strcat(teams_missing, ColoredTeamName(COLOR_TEAM2), ", ");
  83                 if(freezetag_teams >= 3)
  84                 if(!yellowalive)        teams_missing = strcat(teams_missing, ColoredTeamName(COLOR_TEAM3), ", ");
  85                 if(freezetag_teams == 4)
  86                 if(!pinkalive)  teams_missing = strcat(teams_missing, ColoredTeamName(COLOR_TEAM4), ", ");
  87                 teams_missing = substring(teams_missing, 0, strlen(teams_missing)-2);
  88
  89                 FOR_EACH_REALCLIENT(e)
  90                         Send_CSQC_Centerprint_Generic(e, CPID_WAITING_PLAYERS, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), -1, 0);
  91                 prev_total_players = total_players;
  92         }
  93         return 0;
  94 }
  95
  96 float freezetag_getWinnerTeam()
  97 {
  98         float winner_team = 0;
  99         if(redalive >= 1)
 100                 winner_team = COLOR_TEAM1;
 101         if(bluealive >= 1)
 102         {
 103                 if(winner_team) return 0;
 104                 winner_team = COLOR_TEAM2;
 105         }
 106         if(yellowalive >= 1)
 107         {
 108                 if(winner_team) return 0;
 109                 winner_team = COLOR_TEAM3;
 110         }
 111         if(pinkalive >= 1)
 112         {
 113                 if(winner_team) return 0;
 114                 winner_team = COLOR_TEAM4;
 115         }
 116         if(winner_team)
 117                 return winner_team;
 118         return -1; // no player left
 119 }
 120
 121 float freezetag_CheckWinner()
 122 {
 123         entity e;
 124         if(round_handler_GetTimeLeft() <= 0)
 125         {
 126                 FOR_EACH_REALCLIENT(e)
 127                         centerprint(e, "Round over, there's no winner");
 128                 bprint("Round over, there's no winner.\n");
 129                 FOR_EACH_PLAYER(e)
 130                         e.freezetag_frozen_timeout = 0;
 131                 round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
 132                 return 1;
 133         }
 134
 135         if(FREEZETAG_ALIVE_TEAMS() > 1)
 136                 return 0;
 137
 138         float winner_team;
 139         string teamname;
 140         winner_team = freezetag_getWinnerTeam();
 141         if(winner_team > 0)
 142         {
 143                 teamname = ColoredTeamName(winner_team);
 144                 FOR_EACH_REALCLIENT(e)
 145                         centerprint(e, strcat(teamname, "^5 wins the round, all other teams were frozen."));
 146                 bprint(teamname, "^5 wins the round since all the other teams were frozen.\n");
 147                 TeamScore_AddToTeam(winner_team, ST_SCORE, +1);
 148         }
 149         else if(winner_team == -1)
 150         {
 151                 FOR_EACH_REALCLIENT(e)
 152                         centerprint(e, "^5Round tied! All teams were frozen.");
 153                 bprint("^5Round tied! All teams were frozen.\n");
 154         }
 155
 156         FOR_EACH_PLAYER(e)
 157                 e.freezetag_frozen_timeout = 0;
 158         round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
 159         return 1;
 160 }
 161
 162 // this is needed to allow the player to turn his view around (fixangle can't
 163 // be used to freeze his view, as that also changes the angles), while not
 164 // turning that ice object with the player
 165 void freezetag_Ice_Think()
 166 {
 167         setorigin(self, self.owner.origin - '0 0 16');
 168         self.nextthink = time;
 169 }
 170
 171 void freezetag_Add_Score(entity attacker)
 172 {
 173         if(attacker == self)
 174         {
 175                 // you froze your own dumb self
 176                 // counted as "suicide" already
 177                 PlayerScore_Add(self, SP_SCORE, -1);
 178         }
 179         else if(attacker.classname == "player")
 180         {
 181                 // got frozen by an enemy
 182                 // counted as "kill" and "death" already
 183                 PlayerScore_Add(self, SP_SCORE, -1);
 184                 PlayerScore_Add(attacker, SP_SCORE, +1);
 185         }
 186         // else nothing - got frozen by the game type rules themselves
 187 }
 188
 189 void freezetag_Freeze(entity attacker)
 190 {
 191         if(self.freezetag_frozen)
 192                 return;
 193         self.freezetag_frozen = 1;
 194         self.freezetag_frozen_time = time;
 195         self.freezetag_revive_progress = 0;
 196         self.health = 1;
 197         if(autocvar_g_freezetag_frozen_maxtime > 0)
 198                 self.freezetag_frozen_timeout = time + autocvar_g_freezetag_frozen_maxtime;
 199
 200         freezetag_count_alive_players();
 201
 202         entity ice;
 203         ice = spawn();
 204         ice.owner = self;
 205         ice.classname = "freezetag_ice";
 206         ice.think = freezetag_Ice_Think;
 207         ice.nextthink = time;
 208         ice.frame = floor(random() * 21); // ice model has 20 different looking frames
 209         ice.alpha = ICE_MAX_ALPHA;
 210         ice.colormod = TeamColor(self.team);
 211         setmodel(ice, "models/ice/ice.md3");
 212
 213         self.freezetag_ice = ice;
 214
 215         RemoveGrapplingHook(self);
 216
 217         // add waypoint
 218         WaypointSprite_Spawn("freezetag_frozen", 0, 0, self, '0 0 64', world, self.team, self, waypointsprite_attached, TRUE, RADARICON_WAYPOINT, '0.25 0.90 1');
 219
 220         freezetag_Add_Score(attacker);
 221 }
 222
 223 void freezetag_Unfreeze(entity attacker)
 224 {
 225         self.freezetag_frozen = 0;
 226         self.freezetag_frozen_time = 0;
 227         self.freezetag_frozen_timeout = 0;
 228         self.freezetag_revive_progress = 0;
 229
 230         remove(self.freezetag_ice);
 231         self.freezetag_ice = world;
 232
 233         if(self.waypointsprite_attached)
 234                 WaypointSprite_Kill(self.waypointsprite_attached);
 235 }
 236
 237
 238 // ================
 239 // Bot player logic
 240 // ================
 241
 242 void() havocbot_role_ft_freeing;
 243 void() havocbot_role_ft_offense;
 244
 245 void havocbot_goalrating_freeplayers(float ratingscale, vector org, float sradius)
 246 {
 247         entity head;
 248         float distance;
 249
 250         FOR_EACH_PLAYER(head)
 251         {
 252                 if ((head != self) && (head.team == self.team))
 253                 {
 254                         if (head.freezetag_frozen)
 255                         {
 256                                 distance = vlen(head.origin - org);
 257                                 if (distance > sradius)
 258                                         continue;
 259                                 navigation_routerating(head, ratingscale, 2000);
 260                         }
 261                         else
 262                         {
 263                                 // If teamate is not frozen still seek them out as fight better
 264                                 // in a group.
 265                                 navigation_routerating(head, ratingscale/3, 2000);
 266                         }
 267                 }
 268         }
 269 }
 270
 271 void havocbot_role_ft_offense()
 272 {
 273         entity head;
 274         float unfrozen;
 275
 276         if(self.deadflag != DEAD_NO)
 277                 return;
 278
 279         if (!self.havocbot_role_timeout)
 280                 self.havocbot_role_timeout = time + random() * 10 + 20;
 281
 282         // Count how many players on team are unfrozen.
 283         unfrozen = 0;
 284         FOR_EACH_PLAYER(head)
 285         {
 286                 if ((head.team == self.team) && (!head.freezetag_frozen))
 287                         unfrozen++;
 288         }
 289
 290         // If only one left on team or if role has timed out then start trying to free players.
 291         if (((unfrozen == 0) && (!self.freezetag_frozen)) || (time > self.havocbot_role_timeout))
 292         {
 293                 dprint("changing role to freeing\n");
 294                 self.havocbot_role = havocbot_role_ft_freeing;
 295                 self.havocbot_role_timeout = 0;
 296                 return;
 297         }
 298
 299         if (time > self.bot_strategytime)
 300         {
 301                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 302
 303                 navigation_goalrating_start();
 304                 havocbot_goalrating_items(10000, self.origin, 10000);
 305                 havocbot_goalrating_enemyplayers(20000, self.origin, 10000);
 306                 havocbot_goalrating_freeplayers(9000, self.origin, 10000);
 307                 //havocbot_goalrating_waypoints(1, self.origin, 1000);
 308                 navigation_goalrating_end();
 309         }
 310 }
 311
 312 void havocbot_role_ft_freeing()
 313 {
 314         if(self.deadflag != DEAD_NO)
 315                 return;
 316
 317         if (!self.havocbot_role_timeout)
 318                 self.havocbot_role_timeout = time + random() * 10 + 20;
 319
 320         if (time > self.havocbot_role_timeout)
 321         {
 322                 dprint("changing role to offense\n");
 323                 self.havocbot_role = havocbot_role_ft_offense;
 324                 self.havocbot_role_timeout = 0;
 325                 return;
 326         }
 327
 328         if (time > self.bot_strategytime)
 329         {
 330                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 331
 332                 navigation_goalrating_start();
 333                 havocbot_goalrating_items(8000, self.origin, 10000);
 334                 havocbot_goalrating_enemyplayers(10000, self.origin, 10000);
 335                 havocbot_goalrating_freeplayers(20000, self.origin, 10000);
 336                 //havocbot_goalrating_waypoints(1, self.origin, 1000);
 337                 navigation_goalrating_end();
 338         }
 339 }
 340
 341
 342 // ==============
 343 // Hook Functions
 344 // ==============
 345
 346 MUTATOR_HOOKFUNCTION(freezetag_RemovePlayer)
 347 {
 348         self.health = 0; // neccessary to update correctly alive stats
 349         freezetag_Unfreeze(world);
 350         freezetag_count_alive_players();
 351         return 1;
 352 }
 353
 354 MUTATOR_HOOKFUNCTION(freezetag_PlayerDies)
 355 {
 356         if(round_handler_IsActive())
 357         if(round_handler_CountdownRunning())
 358         {
 359                 if(self.freezetag_frozen)
 360                         freezetag_Unfreeze(world);
 361                 freezetag_count_alive_players();
 362                 return 1; // let the player die so that he can respawn whenever he wants
 363         }
 364
 365         // Cases DEATH_TEAMCHANGE and DEATH_AUTOTEAMCHANGE are needed to fix a bug whe
 366         // you succeed changing team through the menu: you both really die (gibbing) and get frozen
 367         if(ITEM_DAMAGE_NEEDKILL(frag_deathtype)
 368                 || frag_deathtype == DEATH_TEAMCHANGE || frag_deathtype == DEATH_AUTOTEAMCHANGE)
 369         {
 370                 // let the player die, he will be automatically frozen when he respawns
 371                 if(!self.freezetag_frozen)
 372                 {
 373                         freezetag_Add_Score(frag_attacker);
 374                         freezetag_count_alive_players();
 375                 }
 376                 else
 377                         freezetag_Unfreeze(world); // remove ice
 378                 self.freezetag_frozen_timeout = -2; // freeze on respawn
 379                 return 1;
 380         }
 381
 382         if(self.freezetag_frozen)
 383                 return 1;
 384
 385         freezetag_Freeze(frag_attacker);
 386
 387         if(frag_attacker == frag_target || frag_attacker == world)
 388         {
 389                 if(frag_target.classname == STR_PLAYER)
 390                         centerprint(frag_target, "^1You froze yourself.\n");
 391                 bprint("^7", frag_target.netname, "^1 froze himself.\n");
 392         }
 393         else
 394         {
 395                 if(frag_target.classname == STR_PLAYER)
 396                         centerprint(frag_target, strcat("^1You were frozen by ^7", frag_attacker.netname, ".\n"));
 397                 if(frag_attacker.classname == STR_PLAYER)
 398                         centerprint(frag_attacker, strcat("^2You froze ^7", frag_target.netname, ".\n"));
 399                 bprint("^7", frag_target.netname, "^1 was frozen by ^7", frag_attacker.netname, ".\n");
 400         }
 401
 402         frag_target.health = 1; // "respawn" the player :P
 403
 404         return 1;
 405 }
 406
 407 MUTATOR_HOOKFUNCTION(freezetag_PlayerSpawn)
 408 {
 409         if(self.freezetag_frozen_timeout == -1) // if PlayerSpawn is called by reset_map_players
 410                 return 1; // do nothing, round is starting right now
 411
 412         if(self.freezetag_frozen_timeout == -2) // player was dead
 413         {
 414                 freezetag_Freeze(world);
 415                 return 1;
 416         }
 417
 418         freezetag_count_alive_players();
 419
 420         if(round_handler_IsActive())
 421         if(round_handler_IsRoundStarted())
 422         {
 423                 centerprint(self, "^1Round already started, you spawn as frozen.");
 424                 freezetag_Freeze(world);
 425         }
 426
 427         return 1;
 428 }
 429
 430 MUTATOR_HOOKFUNCTION(freezetag_reset_map_players)
 431 {
 432         FOR_EACH_PLAYER(self)
 433         {
 434                 if (self.freezetag_frozen)
 435                         freezetag_Unfreeze(world);
 436                 self.freezetag_frozen_timeout = -1;
 437                 PutClientInServer();
 438                 self.freezetag_frozen_timeout = 0;
 439         }
 440         freezetag_count_alive_players();
 441         return 1;
 442 }
 443
 444 MUTATOR_HOOKFUNCTION(freezetag_GiveFragsForKill)
 445 {
 446         frag_score = 0; // no frags counted in Freeze Tag
 447         return 1;
 448 }
 449
 450 .float reviving; // temp var
 451 MUTATOR_HOOKFUNCTION(freezetag_PlayerPreThink)
 452 {
 453         float n;
 454
 455         if(gameover)
 456                 return 1;
 457
 458         if(self.freezetag_frozen)
 459         {
 460                 // keep health = 1
 461                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen;
 462         }
 463
 464         if(round_handler_IsActive())
 465         if(!round_handler_IsRoundStarted())
 466                 return 1;
 467
 468         entity o;
 469         o = world;
 470         if(self.freezetag_frozen_timeout > 0 && time < self.freezetag_frozen_timeout)
 471                 self.freezetag_ice.alpha = ICE_MIN_ALPHA + (ICE_MAX_ALPHA - ICE_MIN_ALPHA) * (self.freezetag_frozen_timeout - time) / (self.freezetag_frozen_timeout - self.freezetag_frozen_time);
 472
 473         if(self.freezetag_frozen_timeout > 0 && time >= self.freezetag_frozen_timeout)
 474                 n = -1;
 475         else
 476         {
 477                 vector revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
 478                 n = 0;
 479                 FOR_EACH_PLAYER(other) if(self != other)
 480                 {
 481                         if(other.freezetag_frozen == 0)
 482                         {
 483                                 if(other.team == self.team)
 484                                 {
 485                                         if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
 486                                         {
 487                                                 if(!o)
 488                                                         o = other;
 489                                                 if(self.freezetag_frozen)
 490                                                         other.reviving = TRUE;
 491                                                 ++n;
 492                                         }
 493                                 }
 494                         }
 495                 }
 496         }
 497
 498         if(n && self.freezetag_frozen) // OK, there is at least one teammate reviving us
 499         {
 500                 self.freezetag_revive_progress = bound(0, self.freezetag_revive_progress + frametime * autocvar_g_freezetag_revive_speed, 1);
 501                 self.health = max(1, self.freezetag_revive_progress * autocvar_g_balance_health_start);
 502
 503                 if(self.freezetag_revive_progress >= 1)
 504                 {
 505                         freezetag_Unfreeze(self);
 506                         freezetag_count_alive_players();
 507
 508                         if(n == -1)
 509                         {
 510                                 string s = ftos(autocvar_g_freezetag_frozen_maxtime);
 511                                 centerprint(self, strcat("^5You were automatically revived after ", s, " seconds^5.\n"));
 512                                 bprint("^7", self.netname, "^5 were automatically revived after ", s, " seconds^5.\n");
 513                                 return 1;
 514                         }
 515
 516                         // EVERY team mate nearby gets a point (even if multiple!)
 517                         FOR_EACH_PLAYER(other)
 518                         {
 519                                 if(other.reviving)
 520                                 {
 521                                         PlayerScore_Add(other, SP_FREEZETAG_REVIVALS, +1);
 522                                         PlayerScore_Add(other, SP_SCORE, +1);
 523                                 }
 524                         }
 525
 526                         if(n > 1)
 527                                 centerprint(self, strcat("^5You were revived by ^7", o.netname, "^5 et al.\n"));
 528                         else
 529                                 centerprint(self, strcat("^5You were revived by ^7", o.netname, "^5.\n"));
 530                         centerprint(o, strcat("^5You revived ^7", self.netname, "^5.\n"));
 531                         if(n > 1)
 532                                 bprint("^7", o.netname, "^5 et al revived ^7", self.netname, "^5.\n");
 533                         else
 534                                 bprint("^7", o.netname, "^5 revived ^7", self.netname, "^5.\n");
 535                 }
 536
 537                 FOR_EACH_PLAYER(other)
 538                 {
 539                         if(other.reviving)
 540                         {
 541                                 other.freezetag_revive_progress = self.freezetag_revive_progress;
 542                                 other.reviving = FALSE;
 543                         }
 544                 }
 545         }
 546         else if(!n && self.freezetag_frozen) // only if no teammate is nearby will we reset
 547         {
 548                 self.freezetag_revive_progress = bound(0, self.freezetag_revive_progress - frametime * autocvar_g_freezetag_revive_clearspeed, 1);
 549                 self.health = max(1, self.freezetag_revive_progress * autocvar_g_balance_health_start);
 550         }
 551         else if(!n)
 552         {
 553                 self.freezetag_revive_progress = 0; // thawing nobody
 554         }
 555
 556         return 1;
 557 }
 558
 559 MUTATOR_HOOKFUNCTION(freezetag_PlayerPhysics)
 560 {
 561         if(self.freezetag_frozen)
 562         {
 563                 self.movement = '0 0 0';
 564                 self.disableclientprediction = 1;
 565         }
 566         return 1;
 567 }
 568
 569 MUTATOR_HOOKFUNCTION(freezetag_PlayerDamage_Calculate)
 570 {
 571         if(frag_target.freezetag_frozen && frag_deathtype != DEATH_HURTTRIGGER)
 572         {
 573                 frag_damage = 0;
 574                 frag_force = frag_force * autocvar_g_freezetag_frozen_force;
 575         }
 576         return 1;
 577 }
 578
 579 MUTATOR_HOOKFUNCTION(freezetag_ForbidThrowCurrentWeapon)
 580 {
 581         if (self.freezetag_frozen)
 582                 return 1;
 583         return 0;
 584 }
 585
 586 MUTATOR_HOOKFUNCTION(freezetag_BotRoles)
 587 {
 588         if not(self.deadflag)
 589         {
 590                 if (random() < 0.5)
 591                         self.havocbot_role = havocbot_role_ft_freeing;
 592                 else
 593                         self.havocbot_role = havocbot_role_ft_offense;
 594         }
 595
 596         return TRUE;
 597 }
 598
 599 MUTATOR_HOOKFUNCTION(freezetag_SpectateCopy)
 600 {
 601         self.freezetag_frozen = other.freezetag_frozen;
 602         self.freezetag_revive_progress = other.freezetag_revive_progress;
 603         return 0;
 604 }
 605
 606 MUTATOR_HOOKFUNCTION(freezetag_GetTeamCount)
 607 {
 608         freezetag_teams = autocvar_g_freezetag_teams_override;
 609         if(freezetag_teams < 2)
 610                 freezetag_teams = autocvar_g_freezetag_teams;
 611         freezetag_teams = bound(2, freezetag_teams, 4);
 612         ret_float = freezetag_teams;
 613         return 0;
 614 }
 615
 616 MUTATOR_DEFINITION(gamemode_freezetag)
 617 {
 618         MUTATOR_HOOK(MakePlayerObserver, freezetag_RemovePlayer, CBC_ORDER_ANY);
 619         MUTATOR_HOOK(ClientDisconnect, freezetag_RemovePlayer, CBC_ORDER_ANY);
 620         MUTATOR_HOOK(PlayerDies, freezetag_PlayerDies, CBC_ORDER_ANY);
 621         MUTATOR_HOOK(PlayerSpawn, freezetag_PlayerSpawn, CBC_ORDER_ANY);
 622         MUTATOR_HOOK(reset_map_players, freezetag_reset_map_players, CBC_ORDER_ANY);
 623         MUTATOR_HOOK(GiveFragsForKill, freezetag_GiveFragsForKill, CBC_ORDER_FIRST);
 624         MUTATOR_HOOK(PlayerPreThink, freezetag_PlayerPreThink, CBC_ORDER_FIRST);
 625         MUTATOR_HOOK(PlayerPhysics, freezetag_PlayerPhysics, CBC_ORDER_FIRST);
 626         MUTATOR_HOOK(PlayerDamage_Calculate, freezetag_PlayerDamage_Calculate, CBC_ORDER_ANY);
 627         MUTATOR_HOOK(ForbidThrowCurrentWeapon, freezetag_ForbidThrowCurrentWeapon, CBC_ORDER_ANY);
 628         MUTATOR_HOOK(HavocBot_ChooseRule, freezetag_BotRoles, CBC_ORDER_ANY);
 629         MUTATOR_HOOK(SpectateCopy, freezetag_SpectateCopy, CBC_ORDER_ANY);
 630         MUTATOR_HOOK(GetTeamCount, freezetag_GetTeamCount, CBC_ORDER_EXCLUSIVE);
 631
 632         MUTATOR_ONADD
 633         {
 634                 if(time > 1) // game loads at time 1
 635                         error("This is a game type and it cannot be added at runtime.");
 636                 freezetag_Initialize();
 637         }
 638
 639         MUTATOR_ONROLLBACK_OR_REMOVE
 640         {
 641                 // we actually cannot roll back freezetag_Initialize here
 642                 // BUT: we don't need to! If this gets called, adding always
 643                 // succeeds.
 644         }
 645
 646         MUTATOR_ONREMOVE
 647         {
 648                 print("This is a game type and it cannot be removed at runtime.");
 649                 return -1;
 650         }
 651
 652         return 0;
 653 }