qcsrc/server/mutators/base.qh

   1 #define CBC_ORDER_EXCLUSIVE 3
   2 #define CBC_ORDER_FIRST 1
   3 #define CBC_ORDER_LAST 2
   4 #define CBC_ORDER_ANY 4
   5
   6 float CallbackChain_ReturnValue; // read-only field of the current return value
   7
   8 entity CallbackChain_New(string name);
   9 float CallbackChain_Add(entity cb, float() func, float order);
  10 float CallbackChain_Remove(entity cb, float() func);
  11 // a callback function is like this:
  12 // float mycallback(entity me)
  13 // {
  14 //   do something
  15 //   return r;
  16 // }
  17 float CallbackChain_Call(entity cb);
  18
  19 #define MUTATOR_REMOVING 0
  20 #define MUTATOR_ADDING 1
  21 typedef float(float) mutatorfunc_t;
  22 float Mutator_Add(mutatorfunc_t func, string name);
  23 void Mutator_Remove(mutatorfunc_t func, string name); // calls error() on fail
  24
  25 #define MUTATOR_ADD(name) Mutator_Add(MUTATOR_##name, #name)
  26 #define MUTATOR_REMOVE(name) Mutator_Remove(MUTATOR_##name, #name)
  27 #define MUTATOR_DEFINITION(name) float MUTATOR_##name(float mode)
  28 #define MUTATOR_DECLARATION(name) float MUTATOR_##name(float mode)
  29 #define MUTATOR_HOOKFUNCTION(name) float HOOKFUNCTION_##name()
  30 #define MUTATOR_HOOK(cb,func,order) do { if(mode == MUTATOR_ADDING) { if(!HOOK_##cb) HOOK_##cb = CallbackChain_New(#cb); if(!CallbackChain_Add(HOOK_##cb,HOOKFUNCTION_##func,order)) { print("HOOK FAILED: ", #func, "\n"); return 1; } } else if(mode == MUTATOR_REMOVING) { if(HOOK_##cb) CallbackChain_Remove(HOOK_##cb,HOOKFUNCTION_##func); } } while(0)
  31 #define MUTATOR_ONADD if(mode == MUTATOR_ADDING)
  32 #define MUTATOR_ONREMOVE if(mode == MUTATOR_REMOVING)
  33
  34 #define MUTATOR_HOOKABLE(cb) entity HOOK_##cb
  35 #define MUTATOR_CALLHOOK(cb) CallbackChain_Call(HOOK_##cb)
  36
  37 #define MUTATOR_RETURNVALUE CallbackChain_ReturnValue
  38
  39
  40
  41
  42 // register all possible hooks here
  43
  44 MUTATOR_HOOKABLE(MakePlayerObserver);
  45         // called when a player becomes observer, after shared setup
  46
  47 MUTATOR_HOOKABLE(PlayerSpawn);
  48         entity spawn_spot; // spot that was used, or world
  49         // called when a player spawns as player, after shared setup, before his weapon is chosen (so items may be changed in here)
  50
  51 MUTATOR_HOOKABLE(ClientDisconnect);
  52         // called when a player disconnects
  53
  54 MUTATOR_HOOKABLE(PlayerDies);
  55         // called when a player dies to e.g. remove stuff he was carrying.
  56         // INPUT:
  57                 entity frag_inflictor;
  58                 entity frag_attacker;
  59                 entity frag_target; // same as self
  60
  61 MUTATOR_HOOKABLE(GiveFragsForKill);
  62         // called when someone was fragged by "self", and is expected to change frag_score to adjust scoring for the kill
  63         // INPUT:
  64                 entity frag_attacker; // same as self
  65                 entity frag_target;
  66         // INPUT, OUTPUT:
  67                 float frag_score;
  68
  69 MUTATOR_HOOKABLE(MatchEnd);
  70         // called when the match ends
  71
  72 MUTATOR_HOOKABLE(GetTeamCount);
  73         // should adjust ret_float to contain the team count
  74         // INPUT, OUTPUT:
  75                 float ret_float;
  76
  77 MUTATOR_HOOKABLE(SpectateCopy);
  78         // copies variables for spectating "other" to "self"
  79         // INPUT:
  80                 entity other;
  81
  82 MUTATOR_HOOKABLE(ForbidThrowCurrentWeapon);
  83         // returns 1 if throwing the current weapon shall not be allowed
  84
  85 MUTATOR_HOOKABLE(SetStartItems);
  86         // adjusts {warmup_}start_{items,weapons,ammo_{cells,rockets,nails,shells,fuel}}
  87
  88 MUTATOR_HOOKABLE(BuildMutatorsString);
  89         // appends ":mutatorname" to ret_string for logging
  90         // INPUT, OUTPUT:
  91                 string ret_string;
  92
  93 MUTATOR_HOOKABLE(BuildMutatorsPrettyString);
  94         // appends ", Mutator name" to ret_string for display
  95         // INPUT, OUTPUT:
  96                 string ret_string;
  97
  98 MUTATOR_HOOKABLE(FilterItem);
  99         // checks if the current item may be spawned (self.items and self.weapons may be read and written to, as well as the ammo_ fields)
 100         // return error to request removal
 101
 102 MUTATOR_HOOKABLE(TurretSpawn);
 103         // return error to request removal
 104         // INPUT: self - turret
 105
 106 MUTATOR_HOOKABLE(OnEntityPreSpawn);
 107         // return error to prevent entity spawn, or modify the entity
 108
 109 MUTATOR_HOOKABLE(PlayerPreThink);
 110         // runs in the event loop for players; is called for ALL player entities, also bots, also the dead, or spectators
 111
 112 MUTATOR_HOOKABLE(GetPressedKeys);
 113         // TODO change this into a general PlayerPostThink hook?
 114
 115 MUTATOR_HOOKABLE(PlayerPhysics);
 116         // called before any player physics, may adjust variables for movement,
 117         // is run AFTER bot code and idle checking
 118
 119 MUTATOR_HOOKABLE(GetCvars);
 120         // is meant to call GetCvars_handle*(get_cvars_s, get_cvars_f, cvarfield, "cvarname") for cvars this mutator needs from the client
 121         // INPUT:
 122                 float get_cvars_f;
 123                 string get_cvars_s;
 124
 125 MUTATOR_HOOKABLE(PlayStrengthSound);
 126         // called when a player fires a weapon with the strength powerup
 127
 128 MUTATOR_HOOKABLE(EditProjectile);
 129         // can edit any "just fired" projectile
 130         // INPUT:
 131                 entity self;
 132                 entity other;
 133
 134 MUTATOR_HOOKABLE(PlayerDamage_SplitHealthArmor);
 135         // called when a player gets damaged to e.g. remove stuff he was carrying.
 136         // INPUT:
 137                 entity frag_inflictor;
 138                 entity frag_attacker;
 139                 entity frag_target; // same as self
 140                 vector damage_force; // NOTE: this force already HAS been applied
 141         // INPUT, OUTPUT:
 142                 float damage_take;
 143                 float damage_save;
 144
 145 MUTATOR_HOOKABLE(PlayerDamage_Calculate);
 146         // called to adjust damage and force values which are applied to the player, used for e.g. strength damage/force multiplier or runematch runes
 147         // i'm not sure if I should change this around slightly (Naming of the entities, and also how they're done in g_damage).
 148         // INPUT:
 149                 entity frag_attacker;
 150                 entity frag_target;
 151                 float frag_deathtype;
 152         // INPUT, OUTPUT:
 153                 float frag_damage;
 154                 float frag_mirrordamage;
 155                 vector frag_force;
 156
 157 MUTATOR_HOOKABLE(PlayerPowerups);
 158         // called at the end of player_powerups() in cl_client.qc, used for manipulating the values which are set by powerup items.
 159         // INPUT
 160         entity self;
 161         float olditems; // also technically output, but since it is at the end of the function it's useless for that :P
 162
 163 MUTATOR_HOOKABLE(PlayerUseKey);
 164         // called when the use key is pressed
 165         // if MUTATOR_RETURNVALUE is 1, don't do anything
 166         // return 1 if the use key actually did something
 167
 168 MUTATOR_HOOKABLE(SV_ParseClientCommand);
 169         // called when a client command is parsed
 170         // NOTE: hooks MUST start with if(MUTATOR_RETURNVALUE) return 0;
 171         // NOTE: return 1 if you handled the command, return 0 to continue handling
 172         // NOTE: THESE HOOKS MUST NEVER EVER CALL tokenize()
 173         // INPUT
 174         string cmd_name; // command name
 175         float cmd_argc; // also, argv() can be used
 176         string cmd_string; // whole command, use only if you really have to
 177         /*
 178                 // example:
 179                 MUTATOR_HOOKFUNCTION(foo_SV_ParseClientCommand)
 180                 {
 181                         if(MUTATOR_RETURNVALUE) // command was already handled?
 182                                 return 0;
 183                         if(cmd_name == "echocvar" && cmd_argc >= 2)
 184                         {
 185                                 print(cvar_string(argv(1)), "\n");
 186                                 return 1;
 187                         }
 188                         if(cmd_name == "echostring" && cmd_argc >= 2)
 189                         {
 190                                 print(substring(cmd_string, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), "\n");
 191                                 return 1;
 192                         }
 193                         return 0;
 194                 }
 195         */
 196
 197 MUTATOR_HOOKABLE(Spawn_Score);
 198         // called when a spawnpoint is being evaluated
 199         // return 1 to make the spawnpoint unusable
 200         // INPUT
 201         entity self; // player wanting to spawn
 202         entity spawn_spot; // spot to be evaluated
 203         // IN+OUT
 204         vector spawn_score; // _x is priority, _y is "distance"
 205
 206 MUTATOR_HOOKABLE(SV_StartFrame);
 207         // runs globally each server frame
 208
 209 MUTATOR_HOOKABLE(SetModname);
 210         // OUT
 211         string modname; // name of the mutator/mod if it warrants showing as such in the server browser
 212
 213 MUTATOR_HOOKABLE(SetWeaponreplace);
 214         // IN
 215                 entity self; // map entity
 216                 entity other; // weapon info
 217         // IN+OUT
 218                 string ret_string;
 219
 220 MUTATOR_HOOKABLE(Item_RespawnCountdown);
 221         // called when an item is about to respawn
 222         // INPUT+OUTPUT:
 223         string item_name;
 224         vector item_color;
 225
 226 MUTATOR_HOOKABLE(Item_GiveTo);
 227         // called when an item is given to a player
 228         entity giveplayer;
 229         entity giveitem;
 230         float player_wswitch;
 231         float player_pickedup;
 232
 233 MUTATOR_HOOKABLE(BotShouldAttack);
 234         // called when a bot checks a target to attack
 235         // INPUT
 236         entity checkentity;
 237
 238 MUTATOR_HOOKABLE(PortalTeleport);
 239         // called whenever a player goes through a portal gun teleport
 240         // allows you to strip a player of an item if they go through the teleporter to help prevent cheating
 241         // INPUT
 242         entity self;
 243
 244 MUTATOR_HOOKABLE(HelpMePing);
 245         // called whenever a player uses impulse 33 (help me) in cl_impulse.qc
 246         // normally help me ping uses self.waypointsprite_attachedforcarrier,
 247         // but if your mutator uses something different then you can handle it
 248         // in a special manner using this hook
 249         // INPUT
 250         entity self; // the player who pressed impulse 33
 251
 252 MUTATOR_HOOKABLE(VehicleEnter);
 253         // called when a player enters a vehicle
 254         // allows mutators to set special settings in this event
 255         // INPUT
 256         entity vh_player; // player
 257         entity vh_vehicle; // vehicle
 258
 259 MUTATOR_HOOKABLE(VehicleExit);
 260         // called when a player exits a vehicle
 261         // allows mutators to set special settings in this event
 262         // INPUT
 263         entity vh_player; // player
 264         entity vh_vehicle; // vehicle
 265
 266 MUTATOR_HOOKABLE(AbortSpeedrun);
 267         // called when a speedrun is aborted and the player is teleported back to start position
 268         // INPUT
 269         entity self; // player
 270
 271 MUTATOR_HOOKABLE(ItemTouch);
 272         // called at when a item is touched. Called early, can edit item properties.
 273         entity self;    // item
 274         entity other;   // player
 275
 276 MUTATOR_HOOKABLE(ClientConnect);
 277         // called at when a player connect
 278         entity self;    // player
 279
 280 MUTATOR_HOOKABLE(HavocBot_ChooseRule);
 281         entity self;