qcsrc/server/monsters/monster/shalrath.qc

   1 // size
   2 const vector SHALRATH_MIN = '-36 -36 -24';
   3 const vector SHALRATH_MAX = '36 36 50';
   4
   5 // model
   6 string SHALRATH_MODEL = "models/monsters/mage.dpm";
   7
   8 #ifdef SVQC
   9 // cvars
  10 float autocvar_g_monster_shalrath;
  11 float autocvar_g_monster_shalrath_health;
  12 float autocvar_g_monster_shalrath_speed;
  13 float autocvar_g_monster_shalrath_attack_spike_damage;
  14 float autocvar_g_monster_shalrath_attack_spike_radius;
  15 float autocvar_g_monster_shalrath_attack_spike_delay;
  16 float autocvar_g_monster_shalrath_attack_melee_damage;
  17 float autocvar_g_monster_shalrath_attack_melee_delay;
  18 float autocvar_g_monster_shalrath_heal_self;
  19 float autocvar_g_monster_shalrath_heal_friends;
  20 float autocvar_g_monster_shalrath_heal_minhealth;
  21 float autocvar_g_monster_shalrath_heal_range;
  22 float autocvar_g_monster_shalrath_heal_delay;
  23 float autocvar_g_monster_shalrath_shield_time;
  24 float autocvar_g_monster_shalrath_shield_delay;
  25 float autocvar_g_monster_shalrath_shield_blockpercent;
  26 float autocvar_g_monster_shalrath_attack_grenade_damage;
  27 float autocvar_g_monster_shalrath_attack_grenade_edgedamage;
  28 float autocvar_g_monster_shalrath_attack_grenade_radius;
  29 float autocvar_g_monster_shalrath_attack_grenade_lifetime;
  30 float autocvar_g_monster_shalrath_attack_grenade_force;
  31 float autocvar_g_monster_shalrath_attack_grenade_chance;
  32
  33 // animations
  34 const float shalrath_anim_idle          = 0;
  35 const float shalrath_anim_walk          = 1;
  36 const float shalrath_anim_attack        = 2;
  37 const float shalrath_anim_pain          = 3;
  38 const float shalrath_anim_death         = 4;
  39 const float shalrath_anim_run           = 5;
  40
  41 void() ShalMissile;
  42 float() shal_missile;
  43 void() shalrath_heal;
  44 void() shalrath_shield;
  45 void() shalrath_shield_die;
  46
  47 void shalrath_think ()
  48 {
  49         entity head;
  50         float friend_needshelp = FALSE;
  51
  52         FOR_EACH_PLAYER(head)
  53         {
  54                 if not(IsDifferentTeam(head, self))
  55                 if(head.health > 0)
  56                 if(vlen(head.origin - self.origin) < autocvar_g_monster_shalrath_heal_range * self.scale)
  57                 if((!g_minstagib && head.health < autocvar_g_balance_health_regenstable) || (g_minstagib && head.ammo_cells < start_ammo_cells))
  58                 {
  59                         friend_needshelp = TRUE;
  60                         break; // found 1 player near us who is low on health
  61                 }
  62         }
  63         FOR_EACH_MONSTER(head)
  64         {
  65                 if not(IsDifferentTeam(head, self))
  66                 if(head.health > 0)
  67                 if(vlen(head.origin - self.origin) < autocvar_g_monster_shalrath_heal_range * self.scale)
  68                 if((!g_minstagib && head.health < autocvar_g_balance_health_regenstable) || (g_minstagib && head.ammo_cells < start_ammo_cells))
  69                 {
  70                         friend_needshelp = TRUE;
  71                         break; // found 1 player near us who is low on health
  72                 }
  73         }
  74
  75         self.think = shalrath_think;
  76         self.nextthink = time + self.ticrate;
  77
  78         if(self.weaponentity)
  79         if(time >= self.weaponentity.ltime)
  80                 shalrath_shield_die();
  81
  82         if(self.health < autocvar_g_monster_shalrath_heal_minhealth || friend_needshelp)
  83         if(time >= self.attack_finished_single)
  84         if(random() < 0.5)
  85                 shalrath_heal();
  86
  87         if(self.enemy)
  88         if not(self.spawnflags & MONSTERFLAG_GIANT) // giants are too big to hold a shield
  89         if(self.health < self.max_health)
  90         if(time >= self.lastshielded)
  91         if(random() < 0.5)
  92                 shalrath_shield();
  93
  94         monster_move(autocvar_g_monster_shalrath_speed, autocvar_g_monster_shalrath_speed, 50, shalrath_anim_walk, shalrath_anim_run, shalrath_anim_idle);
  95 }
  96
  97 void shalrath_attack ()
  98 {
  99         monsters_setframe(shalrath_anim_attack);
 100         self.delay = time + 0.2;
 101         self.attack_finished_single = time + autocvar_g_monster_shalrath_attack_spike_delay;
 102         self.monster_delayedattack = ShalMissile;
 103 }
 104
 105 void shalrathattack_melee ()
 106 {
 107         monster_melee(self.enemy, autocvar_g_monster_shalrath_attack_melee_damage, 0.3, DEATH_MONSTER_MAGE, TRUE);
 108 }
 109
 110 void shalrath_attack_melee ()
 111 {
 112         self.monster_delayedattack = shalrathattack_melee;
 113         self.delay = time + 0.2;
 114         monsters_setframe(shalrath_anim_attack);
 115         self.attack_finished_single = time + autocvar_g_monster_shalrath_attack_melee_delay;
 116 }
 117
 118 void shalrath_grenade_explode()
 119 {
 120         pointparticles(particleeffectnum("explosion_small"), self.origin, '0 0 0', 1);
 121
 122         sound(self, CH_SHOTS, "weapons/grenade_impact.wav", VOL_BASE, ATTN_NORM);
 123         RadiusDamage (self, self.realowner, autocvar_g_monster_shalrath_attack_grenade_damage, autocvar_g_monster_shalrath_attack_grenade_edgedamage, autocvar_g_monster_shalrath_attack_grenade_radius, world, autocvar_g_monster_shalrath_attack_grenade_force, DEATH_MONSTER_MAGE, other);
 124         remove(self);
 125 }
 126
 127 void shalrath_grenade_touch()
 128 {
 129         if(IS_PLAYER(other))
 130         {
 131                 PROJECTILE_TOUCH;
 132                 shalrath_grenade_explode();
 133                 return;
 134         }
 135 }
 136
 137 void shalrath_throw_itemgrenade()
 138 {
 139         makevectors(self.angles);
 140
 141         W_SetupShot_ProjectileSize (self, '-64 -64 -64', '64 64 64', FALSE, 4, "", CH_WEAPON_A, autocvar_g_monster_shalrath_attack_grenade_damage);
 142         w_shotdir = v_forward; // no TrueAim for grenades please
 143
 144         entity gren = spawn ();
 145         gren.owner = gren.realowner = self;
 146         gren.classname = "grenade";
 147         gren.bot_dodge = FALSE;
 148         gren.movetype = MOVETYPE_BOUNCE;
 149         gren.solid = SOLID_TRIGGER;
 150         gren.projectiledeathtype = DEATH_MONSTER_MAGE;
 151         setorigin(gren, w_shotorg);
 152         setsize(gren, '-64 -64 -64', '64 64 64');
 153
 154         gren.nextthink = time + autocvar_g_monster_shalrath_attack_grenade_lifetime;
 155         gren.think = shalrath_grenade_explode;
 156         gren.use = shalrath_grenade_explode;
 157         gren.touch = shalrath_grenade_touch;
 158
 159         gren.missile_flags = MIF_SPLASH | MIF_ARC;
 160         W_SETUPPROJECTILEVELOCITY_UP(gren, g_monster_shalrath_attack_grenade);
 161
 162         gren.flags = FL_PROJECTILE;
 163
 164         setmodel(gren, "models/items/g_h50.md3");
 165
 166         self.attack_finished_single = time + 1.5;
 167 }
 168
 169 float shal_missile ()
 170 {
 171         if(random() < autocvar_g_monster_shalrath_attack_grenade_chance / 100)
 172         {
 173                 shalrath_throw_itemgrenade();
 174                 return TRUE;
 175         }
 176
 177         shalrath_attack();
 178
 179         return TRUE;
 180 }
 181
 182 void ShalHome ()
 183 {
 184         local vector dir = '0 0 0', vtemp = self.enemy.origin + '0 0 10';
 185
 186         if (self.enemy.health <= 0 || self.owner.health <= 0 || time >= self.ltime)
 187         {
 188                 remove(self);
 189                 return;
 190         }
 191         dir = normalize(vtemp - self.origin);
 192         UpdateCSQCProjectile(self);
 193         if (monster_skill == 3)
 194                 self.velocity = dir * 350;
 195         else
 196                 self.velocity = dir * 250;
 197         self.nextthink = time + 0.2;
 198         self.think = ShalHome;
 199 }
 200
 201 void shal_spike_explode ()
 202 {
 203         self.event_damage = func_null;
 204
 205         pointparticles(particleeffectnum("explosion_small"), self.origin, '0 0 0', 1);
 206         RadiusDamage (self, self.realowner, autocvar_g_monster_shalrath_attack_spike_damage, autocvar_g_monster_shalrath_attack_spike_damage * 0.5, autocvar_g_monster_shalrath_attack_spike_radius, world, 0, DEATH_MONSTER_MAGE, other);
 207
 208         remove (self);
 209 }
 210
 211 void shal_spike_touchexplode()
 212 {
 213         PROJECTILE_TOUCH;
 214
 215         shal_spike_explode();
 216 }
 217
 218 void ShalMissile ()
 219 {
 220         local   entity  missile = world;
 221         local   vector  dir = '0 0 0';
 222         local   float   dist = 0;
 223
 224         self.effects |= EF_MUZZLEFLASH;
 225
 226         missile = spawn ();
 227         missile.owner = missile.realowner = self;
 228
 229         self.v_angle = self.angles;
 230         makevectors (self.angles);
 231
 232         dir = normalize((self.enemy.origin + '0 0 10') - self.origin);
 233         dist = vlen (self.enemy.origin - self.origin);
 234
 235         missile.think = ShalHome;
 236         missile.ltime = time + 7;
 237         missile.nextthink = time;
 238         missile.solid = SOLID_BBOX;
 239         missile.movetype = MOVETYPE_FLYMISSILE;
 240         missile.flags = FL_PROJECTILE;
 241         setorigin (missile, self.origin + v_forward * 14 + '0 0 30' + v_right * -14);
 242         setsize (missile, '0 0 0', '0 0 0');
 243         missile.velocity = dir * 400;
 244         missile.avelocity = '300 300 300';
 245         missile.enemy = self.enemy;
 246         missile.touch = shal_spike_touchexplode;
 247
 248         CSQCProjectile(missile, TRUE, PROJECTILE_VORE_SPIKE, TRUE);
 249 }
 250
 251 float ShalrathCheckAttack ()
 252 {
 253         vector spot1 = '0 0 0', spot2 = '0 0 0';
 254
 255         if (self.health <= 0)
 256                 return FALSE;
 257
 258         // reset delays when we have no enemy
 259         if not(self.enemy)
 260         {
 261                 self.monster_delayedattack = func_null;
 262                 self.delay = -1;
 263         }
 264
 265         if(self.monster_delayedattack && self.delay != -1)
 266         {
 267                 if(time < self.delay)
 268                         return FALSE;
 269
 270                 self.monster_delayedattack();
 271                 self.delay = -1;
 272                 self.monster_delayedattack = func_null;
 273         }
 274
 275         if(time < self.attack_finished_single)
 276                 return FALSE;
 277
 278         if (vlen(self.enemy.origin - self.origin) <= 120)
 279         {       // melee attack
 280                 if (self.attack_melee)
 281                 {
 282                         monster_sound(self.msound_attack_melee, 0, FALSE); // no delay for attack sounds
 283                         self.attack_melee();
 284                         return TRUE;
 285                 }
 286         }
 287
 288 // see if any entities are in the way of the shot
 289         spot1 = self.origin + self.view_ofs;
 290         spot2 = self.enemy.origin + self.enemy.view_ofs;
 291
 292         traceline (spot1, spot2, FALSE, self);
 293
 294         if (trace_ent != self.enemy && trace_fraction < 1)
 295                 return FALSE; // don't have a clear shot
 296
 297         //if (trace_inopen && trace_inwater)
 298         //      return FALSE; // sight line crossed contents
 299
 300         if (self.attack_ranged())
 301                 return TRUE;
 302
 303         return FALSE;
 304 }
 305
 306 void shalrath_heal()
 307 {
 308         entity head;
 309         if(self.health < self.max_health) // only show our effect if we are healing ourself too
 310                 pointparticles(particleeffectnum("healing_fx"), self.origin, '0 0 0', 1);
 311         self.health = bound(0, self.health + autocvar_g_monster_shalrath_heal_self, self.max_health);
 312         WaypointSprite_UpdateHealth(self.sprite, self.health);
 313         monsters_setframe(shalrath_anim_attack);
 314         self.attack_finished_single = time + autocvar_g_monster_shalrath_heal_delay;
 315
 316         for(head = world; (head = findfloat(head, monster_attack, TRUE)); )
 317         {
 318                 if(head.health > 0)
 319                 if not(head.frozen)
 320                 if(vlen(head.origin - self.origin) < autocvar_g_monster_shalrath_heal_range * self.scale)
 321                 if not(IsDifferentTeam(head, self))
 322                 {
 323                         if(IS_PLAYER(head))
 324                         {
 325                                 if(head.ammo_cells < start_ammo_cells || head.health < g_pickup_healthmedium_max)
 326                                         pointparticles(particleeffectnum(((g_minstagib) ? "ammoregen_fx" : "healing_fx")), head.origin, '0 0 0', 1);
 327                                 if(g_minstagib)
 328                                         head.ammo_cells = bound(0, head.ammo_cells + 1, start_ammo_cells);
 329                                 else
 330                                         head.health = bound(0, head.health + autocvar_g_monster_shalrath_heal_friends, g_pickup_healthmedium_max);
 331                         }
 332                         else
 333                         {
 334                                 if(head.health < head.max_health)
 335                                         pointparticles(particleeffectnum("healing_fx"), head.origin, '0 0 0', 1);
 336                                 head.health = bound(0, head.health + autocvar_g_monster_shalrath_heal_friends, head.max_health);
 337                                 WaypointSprite_UpdateHealth(head.sprite, head.health);
 338                         }
 339                 }
 340         }
 341 }
 342
 343 void shalrath_shield_die()
 344 {
 345         if not(self.weaponentity)
 346                 return; // why would this be called without a shield?
 347
 348         self.armorvalue = 1;
 349
 350         remove(self.weaponentity);
 351
 352         self.weaponentity = world;
 353 }
 354
 355 void shalrath_shield()
 356 {
 357         if(self.weaponentity)
 358                 return; // already have a shield
 359
 360         self.weaponentity = spawn();
 361         self.weaponentity.owner = self.weaponentity.realowner = self;
 362         setmodel(self.weaponentity, "models/onslaught/generator_shield.md3");
 363         setattachment(self.weaponentity, self, "");
 364         self.weaponentity.classname = "shield";
 365         self.weaponentity.ltime = time + autocvar_g_monster_shalrath_shield_time;
 366         self.weaponentity.health = 70;
 367         self.weaponentity.alpha = 0.5;
 368         self.weaponentity.scale = self.scale * 0.6;
 369         self.weaponentity.effects = EF_ADDITIVE;
 370         self.weaponentity.solid = SOLID_NOT;
 371         self.weaponentity.movetype = MOVETYPE_NOCLIP;
 372         self.weaponentity.avelocity = '7 0 11';
 373
 374         self.lastshielded = time + autocvar_g_monster_shalrath_shield_delay;
 375
 376         monsters_setframe(shalrath_anim_attack);
 377         self.attack_finished_single = time + 1;
 378
 379         self.armorvalue = autocvar_g_monster_shalrath_shield_blockpercent / 100;
 380 }
 381
 382 void shalrath_die ()
 383 {
 384         Monster_CheckDropCvars ("shalrath");
 385
 386         self.think = monster_dead_think;
 387         self.nextthink = time + self.ticrate;
 388         self.ltime = time + 5;
 389         monsters_setframe(shalrath_anim_death);
 390
 391         monster_hook_death(); // for post-death mods
 392 }
 393
 394 void shalrath_spawn ()
 395 {
 396         if not(self.health)
 397                 self.health = autocvar_g_monster_shalrath_health * self.scale;
 398
 399         self.damageforcescale   = 0.003;
 400         self.classname                  = "monster_shalrath";
 401         self.checkattack                = ShalrathCheckAttack;
 402         self.attack_ranged              = shal_missile;
 403         self.attack_melee               = shalrath_attack_melee;
 404         self.nextthink                  = time + random() * 0.5 + 0.1;
 405         self.think                              = shalrath_think;
 406
 407         monsters_setframe(shalrath_anim_walk);
 408
 409         monster_setupsounds("shalrath");
 410
 411         monster_hook_spawn(); // for post-spawn mods
 412 }
 413
 414 void spawnfunc_monster_shalrath ()
 415 {
 416         if not(autocvar_g_monster_shalrath) { remove(self); return; }
 417
 418         self.monster_spawnfunc = spawnfunc_monster_shalrath;
 419
 420         if(Monster_CheckAppearFlags(self))
 421                 return;
 422
 423         if not (monster_initialize(
 424                          "Mage", MONSTER_MAGE,
 425                          SHALRATH_MIN, SHALRATH_MAX,
 426                          FALSE,
 427                          shalrath_die, shalrath_spawn))
 428         {
 429                 remove(self);
 430                 return;
 431         }
 432 }
 433
 434 // compatibility with old spawns
 435 void spawnfunc_monster_vore () { spawnfunc_monster_shalrath(); }
 436
 437 #endif // SVQC