qcsrc/server/monsters/monster/ogre.qc

   1 // size
   2 const vector OGRE_MIN = '-36 -36 -20';
   3 const vector OGRE_MAX = '36 36 50';
   4
   5 // model
   6 string OGRE_MODEL = "models/monsters/ogre.dpm";
   7
   8 #ifdef SVQC
   9 // cvars
  10 float autocvar_g_monster_ogre;
  11 float autocvar_g_monster_ogre_health;
  12 float autocvar_g_monster_ogre_chainsaw_damage;
  13 float autocvar_g_monster_ogre_speed_walk;
  14 float autocvar_g_monster_ogre_speed_run;
  15 float autocvar_g_monster_ogre_attack_uzi_bullets;
  16 float autocvar_g_monster_ogre_attack_uzi_damage;
  17 float autocvar_g_monster_ogre_attack_uzi_force;
  18 float autocvar_g_monster_ogre_attack_uzi_chance;
  19 float autocvar_g_monster_ogre_attack_grenade_damage;
  20 float autocvar_g_monster_ogre_attack_grenade_edgedamage;
  21 float autocvar_g_monster_ogre_attack_grenade_force;
  22 float autocvar_g_monster_ogre_attack_grenade_radius;
  23
  24 // animations
  25 const float ogre_anim_idle              = 0;
  26 const float ogre_anim_walk              = 1;
  27 const float ogre_anim_run               = 2;
  28 const float ogre_anim_pain              = 3;
  29 const float ogre_anim_swing     = 4;
  30 const float ogre_anim_die               = 5;
  31
  32 void ogre_think()
  33 {
  34         self.think = ogre_think;
  35         self.nextthink = time + self.ticrate;
  36
  37         monster_move(autocvar_g_monster_ogre_speed_run, autocvar_g_monster_ogre_speed_walk, 300, ogre_anim_run, ogre_anim_walk, ogre_anim_idle);
  38 }
  39
  40 .float ogre_cycles;
  41 void ogre_swing()
  42 {
  43         self.ogre_cycles += 1;
  44         monsters_setframe(ogre_anim_swing);
  45         if(self.ogre_cycles == 1)
  46                 self.attack_finished_single = time + 1.3;
  47         self.angles_y = self.angles_y + random()* 25;
  48         self.delay = time + 0.2;
  49         self.monster_delayedattack = ogre_swing;
  50
  51         monster_melee(self.enemy, autocvar_g_monster_ogre_chainsaw_damage, 0.3, DEATH_MONSTER_OGRE_CHAINSAW, TRUE);
  52
  53         if(self.ogre_cycles >= 4)
  54         {
  55                 self.monster_delayedattack = func_null;
  56                 self.delay = -1;
  57         }
  58 }
  59
  60 void ogre_uzi_fire()
  61 {
  62         self.ogre_cycles += 1;
  63
  64         if(self.ogre_cycles > autocvar_g_monster_ogre_attack_uzi_bullets)
  65         {
  66                 self.monster_delayedattack = func_null;
  67                 self.delay = -1;
  68                 return;
  69         }
  70
  71         monster_makevectors(self.enemy);
  72
  73         W_SetupShot (self, autocvar_g_antilag_bullets && 18000 >= autocvar_g_antilag_bullets, 0, "weapons/uzi_fire.wav", CH_WEAPON_A, autocvar_g_monster_ogre_attack_uzi_damage);
  74         fireBallisticBullet(w_shotorg, w_shotdir, 0.02, 18000, 5, autocvar_g_monster_ogre_attack_uzi_damage, autocvar_g_monster_ogre_attack_uzi_force, DEATH_MONSTER_OGRE_UZI, 0, 1, 115);
  75         endFireBallisticBullet();
  76
  77         self.delay = time + 0.1;
  78         self.monster_delayedattack = ogre_uzi_fire;
  79 }
  80
  81 void ogre_uzi()
  82 {
  83         monsters_setframe(ogre_anim_pain);
  84         self.attack_finished_single = time + 0.8;
  85         self.delay = time + 0.1;
  86         self.monster_delayedattack = ogre_uzi_fire;
  87 }
  88
  89 void ogre_grenade_explode()
  90 {
  91         pointparticles(particleeffectnum("grenade_explode"), self.origin, '0 0 0', 1);
  92         sound(self, CH_SHOTS, "weapons/grenade_impact.wav", VOL_BASE, ATTN_NORM);
  93
  94         self.event_damage = func_null;
  95         self.takedamage = DAMAGE_NO;
  96
  97         if(self.movetype == MOVETYPE_NONE)
  98                 self.velocity = self.oldvelocity;
  99
 100         RadiusDamage (self, self.realowner, autocvar_g_monster_ogre_attack_grenade_damage, autocvar_g_monster_ogre_attack_grenade_edgedamage, autocvar_g_monster_ogre_attack_grenade_radius, world, autocvar_g_monster_ogre_attack_grenade_force, self.projectiledeathtype, other);
 101
 102         remove (self);
 103 }
 104
 105 void ogre_grenade_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 106 {
 107         if (self.health <= 0)
 108                 return;
 109
 110         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 111                 return; // g_projectiles_damage says to halt
 112
 113         self.health = self.health - damage;
 114
 115         if (self.health <= 0)
 116                 W_PrepareExplosionByDamage(attacker, self.use);
 117 }
 118
 119 void ogre_grenade_touch()
 120 {
 121         PROJECTILE_TOUCH;
 122
 123         self.use ();
 124 }
 125
 126 void ogre_grenade_think()
 127 {
 128         self.nextthink = time;
 129         if (time > self.cnt)
 130         {
 131                 other = world;
 132                 ogre_grenade_explode();
 133                 return;
 134         }
 135 }
 136
 137 void ogre_gl()
 138 {
 139         entity gren;
 140
 141         monster_makevectors(self.enemy);
 142
 143         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 4, "weapons/grenade_fire.wav", CH_WEAPON_A, autocvar_g_monster_ogre_attack_grenade_damage);
 144         w_shotdir = v_forward; // no TrueAim for grenades please
 145
 146         gren = spawn ();
 147         gren.owner = gren.realowner = self;
 148         gren.classname = "grenade";
 149         gren.bot_dodge = TRUE;
 150         gren.bot_dodgerating = autocvar_g_monster_ogre_attack_grenade_damage;
 151         gren.movetype = MOVETYPE_BOUNCE;
 152         PROJECTILE_MAKETRIGGER(gren);
 153         gren.projectiledeathtype = DEATH_MONSTER_OGRE_GRENADE;
 154         setorigin(gren, w_shotorg);
 155         setsize(gren, '-3 -3 -3', '3 3 3');
 156
 157         gren.cnt = time + 5;
 158         gren.nextthink = time;
 159         gren.think = ogre_grenade_think;
 160         gren.use = ogre_grenade_explode;
 161         gren.touch = ogre_grenade_touch;
 162
 163         gren.takedamage = DAMAGE_YES;
 164         gren.health = autocvar_g_balance_grenadelauncher_primary_health;
 165         gren.damageforcescale = autocvar_g_balance_grenadelauncher_primary_damageforcescale;
 166         gren.event_damage = ogre_grenade_damage;
 167         gren.damagedbycontents = TRUE;
 168         gren.missile_flags = MIF_SPLASH | MIF_ARC;
 169         W_SETUPPROJECTILEVELOCITY_UP(gren, g_balance_grenadelauncher_primary);
 170
 171         gren.angles = vectoangles (gren.velocity);
 172         gren.flags = FL_PROJECTILE;
 173
 174         CSQCProjectile(gren, TRUE, PROJECTILE_GRENADE, TRUE);
 175
 176
 177         monsters_setframe(ogre_anim_pain);
 178         self.attack_finished_single = time + 1.2;
 179 }
 180
 181 float ogre_missile()
 182 {
 183         self.ogre_cycles = 0;
 184         if (random() <= autocvar_g_monster_ogre_attack_uzi_chance)
 185         {
 186                 ogre_uzi();
 187                 return TRUE;
 188         }
 189         else
 190         {
 191                 ogre_gl();
 192                 return TRUE;
 193         }
 194 }
 195
 196 float ogre_melee()
 197 {
 198         self.ogre_cycles = 0;
 199         ogre_swing();
 200         return TRUE;
 201 }
 202
 203 void ogre_die()
 204 {
 205         Monster_CheckDropCvars ("ogre");
 206
 207         self.think = monster_dead_think;
 208         self.nextthink = time + self.ticrate;
 209         self.ltime = time + 5;
 210         monsters_setframe(ogre_anim_die);
 211
 212         monster_hook_death(); // for post-death mods
 213 }
 214
 215 void ogre_spawn()
 216 {
 217         if not(self.health)
 218                 self.health = autocvar_g_monster_ogre_health;
 219
 220         self.damageforcescale   = 0.003;
 221         self.classname                  = "monster_ogre";
 222         self.checkattack                = GenericCheckAttack;
 223         self.attack_melee               = ogre_melee;
 224         self.attack_ranged              = ogre_missile;
 225         self.nextthink                  = time + random() * 0.5 + 0.1;
 226         self.think                              = ogre_think;
 227         self.weapon                             = WEP_GRENADE_LAUNCHER;
 228
 229         monsters_setframe(ogre_anim_idle);
 230
 231         monster_setupsounds("ogre");
 232
 233         monster_hook_spawn(); // for post-spawn mods
 234 }
 235
 236 void spawnfunc_monster_ogre()
 237 {
 238         if not(autocvar_g_monster_ogre) { remove(self); return; }
 239
 240         self.monster_spawnfunc = spawnfunc_monster_ogre;
 241
 242         if(Monster_CheckAppearFlags(self))
 243                 return;
 244
 245         if not (monster_initialize(
 246                          "Ogre", MONSTER_OGRE,
 247                          OGRE_MIN, OGRE_MAX,
 248                          FALSE,
 249                          ogre_die, ogre_spawn))
 250         {
 251                 remove(self);
 252                 return;
 253         }
 254
 255         weapon_action(WEP_GRENADE_LAUNCHER, WR_PRECACHE);
 256 }
 257
 258 #endif // SVQC