qcsrc/server/monsters/lib/monsters.qc

   1 // TODO: clean up this file?
   2
   3 void M_Item_Touch ()
   4 {
   5         if(self && other.classname == STR_PLAYER && other.deadflag == DEAD_NO)
   6         {
   7                 Item_Touch();
   8                 self.think = SUB_Remove;
   9                 self.nextthink = time + 0.1;
  10         }
  11 }
  12
  13 void Monster_DropItem (string itype, string itemsize)
  14 {
  15         vector backuporigin = self.origin + ((self.mins + self.maxs) * 0.5);
  16         entity oldself;
  17
  18         oldself = self;
  19         self = spawn();
  20
  21         if (itype == "armor")
  22         {
  23                 if(itemsize == "large") spawnfunc_item_armor_large();
  24                 else if (itemsize == "small") spawnfunc_item_armor_small();
  25                 else if (itemsize == "medium") spawnfunc_item_armor_medium();
  26                 else print("Invalid monster drop item selected.\n");
  27         }
  28         else if (itype == "health")
  29         {
  30                 if(itemsize == "large") spawnfunc_item_health_large();
  31                 else if (itemsize == "small") spawnfunc_item_health_small();
  32                 else if (itemsize == "medium") spawnfunc_item_health_medium();
  33                 else if (itemsize == "mega") spawnfunc_item_health_mega();
  34                 else print("Invalid monster drop item selected.\n");
  35         }
  36         else if (itype == "ammo")
  37         {
  38                 if(itemsize == "shells") spawnfunc_item_shells();
  39                 else if (itemsize == "cells") spawnfunc_item_cells();
  40                 else if (itemsize == "bullets") spawnfunc_item_bullets();
  41                 else if (itemsize == "rockets") spawnfunc_item_rockets();
  42                 else print("Invalid monster drop item selected.\n");
  43         }
  44         else
  45         {
  46                 print("Invalid monster drop item selected.\n");
  47                 self = oldself;
  48                 return;
  49         }
  50
  51         self.velocity = randomvec() * 175 + '0 0 325';
  52
  53         self.gravity = 1;
  54         self.origin = backuporigin;
  55
  56         self.touch = M_Item_Touch;
  57
  58         SUB_SetFade(self, time + 5, 1);
  59
  60         self = oldself;
  61 }
  62
  63 float monster_isvalidtarget (entity targ, entity ent, float neutral)
  64 {
  65         if(!targ || !ent)
  66                 return FALSE; // this check should fix a crash
  67
  68         if(targ.vehicle_flags & VHF_ISVEHICLE)
  69                 targ = targ.vehicle;
  70
  71         if(time < game_starttime)
  72                 return FALSE; // monsters do nothing before the match has started
  73
  74         traceline(ent.origin, targ.origin, FALSE, ent);
  75
  76         if(vlen(targ.origin - ent.origin) >= ent.target_range)
  77                 return FALSE; // enemy is too far away
  78
  79         if(trace_ent != targ)
  80                 return FALSE; // we can't see the enemy
  81
  82         if(neutral == TRUE)
  83                 return TRUE; // we come in peace!
  84
  85         if(targ.takedamage == DAMAGE_NO)
  86                 return FALSE; // enemy can't be damaged
  87
  88         if(targ.items & IT_INVISIBILITY)
  89                 return FALSE; // enemy is invisible
  90
  91         if(targ.classname == STR_SPECTATOR || targ.classname == STR_OBSERVER)
  92                 return FALSE; // enemy is a spectator
  93
  94         if(targ.deadflag != DEAD_NO || ent.deadflag != DEAD_NO || targ.health <= 0 || ent.health <= 0)
  95                 return FALSE; // enemy/self is dead
  96
  97         if(targ.monster_owner == ent || ent.monster_owner == targ)
  98                 return FALSE; // enemy owns us, or we own them
  99
 100         if(targ.flags & FL_NOTARGET)
 101                 return FALSE; // enemy can't be targetted
 102
 103         if not(autocvar_g_monsters_typefrag)
 104         if(targ.BUTTON_CHAT)
 105                 return FALSE; // no typefragging!
 106
 107         if not(IsDifferentTeam(targ, ent))
 108                 return FALSE; // enemy is on our team
 109
 110         return TRUE;
 111 }
 112
 113 float enemy_stillvalidtarget(entity targ, entity e)
 114 {
 115         if(targ.health < 1 || targ.deadflag)
 116                 return FALSE; // let's not keep hurting a corpse
 117
 118         if not(autocvar_g_monsters_typefrag)
 119         if(targ.BUTTON_CHAT)
 120                 return FALSE; // no typefrags!
 121
 122         if(vlen(targ.origin - e.origin) > e.target_range)
 123                 return FALSE; // out of our reach
 124
 125         if not(targ.takedamage)
 126                 return FALSE; // can't hurt it
 127
 128         if(targ.flags & FL_NOTARGET)
 129                 return FALSE; // can't target it
 130
 131         if(targ.items & IT_INVISIBILITY)
 132                 return FALSE; // currently not used
 133
 134         if(!IsDifferentTeam(targ, e))
 135                 return FALSE;
 136
 137         return TRUE; // all is good, keep going!
 138 }
 139
 140 entity FindTarget (entity ent)
 141 {
 142         if(MUTATOR_CALLHOOK(MonsterFindTarget)) { return ent.enemy; } // Handled by a mutator
 143         local entity e;
 144         for(e = world; (e = findflags(e, monster_attack, TRUE)); )
 145         {
 146                 if(monster_isvalidtarget(e, ent, FALSE))
 147                 {
 148                         return e;
 149                 }
 150         }
 151         return world;
 152 }
 153
 154 void MonsterTouch ()
 155 {
 156         if(other == world)
 157                 return;
 158
 159         if(self.enemy != other)
 160         if not(other.flags & FL_MONSTER)
 161         if(monster_isvalidtarget(other, self, FALSE))
 162                 self.enemy = other;
 163 }
 164
 165 void monster_sound(string msound, float sound_delay, float delaytoo)
 166 {
 167         if(delaytoo && time < self.msound_delay)
 168                 return; // too early
 169
 170         if(msound == "")
 171                 return; // sound doesn't exist
 172
 173         sound(self, CH_PAIN_SINGLE, msound, VOL_BASE, ATTN_NORM);
 174
 175         self.msound_delay = time + sound_delay;
 176 }
 177
 178 void monster_precachesounds()
 179 {
 180         precache_sound(self.msound_idle);
 181         precache_sound(self.msound_death);
 182         precache_sound(self.msound_attack_melee);
 183         precache_sound(self.msound_attack_ranged);
 184         precache_sound(self.msound_sight);
 185         precache_sound(self.msound_pain);
 186 }
 187
 188 void monster_melee (entity targ, float damg, float er, float deathtype)
 189 {
 190         float bigdmg = 0, rdmg = damg * random();
 191
 192         if (self.health <= 0)
 193                 return;
 194         if (targ == world)
 195                 return;
 196
 197         if (vlen(self.origin - targ.origin) > er * self.scale)
 198                 return;
 199
 200         bigdmg = rdmg * self.scale;
 201
 202         Damage(targ, self, self, bigdmg * monster_skill, deathtype, targ.origin, normalize(targ.origin - self.origin));
 203 }
 204
 205 void Monster_CheckDropCvars (string mon)
 206 {
 207         string dropitem;
 208         string dropsize;
 209
 210         dropitem = cvar_string(strcat("g_monster_", mon, "_drop"));
 211         dropsize = cvar_string(strcat("g_monster_", mon, "_drop_size"));
 212
 213         monster_dropitem = dropitem;
 214         monster_dropsize = dropsize;
 215         MUTATOR_CALLHOOK(MonsterDropItem);
 216         dropitem = monster_dropitem;
 217         dropsize = monster_dropsize;
 218
 219         if(autocvar_g_monsters_forcedrop)
 220                 Monster_DropItem(autocvar_g_monsters_drop_type, autocvar_g_monsters_drop_size);
 221         else if(dropitem != "")
 222                 Monster_DropItem(dropitem, dropsize);
 223         else
 224                 Monster_DropItem("armor", "medium");
 225 }
 226
 227 void ScaleMonster (float scle)
 228 {
 229         // this should prevent monster from falling through floor when scale changes
 230         self.scale = scle;
 231         setorigin(self, self.origin + ('0 0 30' * scle));
 232 }
 233
 234 void Monster_CheckMinibossFlag ()
 235 {
 236         if(MUTATOR_CALLHOOK(MonsterCheckBossFlag))
 237                 return;
 238
 239         float r = random() * 4, chance = random() * 100;
 240
 241         // g_monsters_miniboss_chance cvar or spawnflags 64 causes a monster to be a miniboss
 242         if ((self.spawnflags & MONSTERFLAG_MINIBOSS) || (chance < autocvar_g_monsters_miniboss_chance))
 243         {
 244                 self.health += autocvar_g_monsters_miniboss_healthboost;
 245                 ScaleMonster(1.5);
 246                 self.flags |= MONSTERFLAG_MINIBOSS;
 247
 248                 if (r < 2 || self.team == COLOR_TEAM2)
 249                 {
 250                         self.strength_finished = -1;
 251                         self.effects |= (EF_FULLBRIGHT | EF_BLUE);
 252                 }
 253                 else if (r >= 1 || self.team == COLOR_TEAM1)
 254                 {
 255                         self.invincible_finished = -1;
 256                         self.effects |= (EF_FULLBRIGHT | EF_RED);
 257                 }
 258                 else
 259                         self.effects |= (EF_FULLBRIGHT | EF_RED | EF_BLUE);
 260
 261                 if(teamplay)
 262                 if(self.team)
 263                         return;
 264
 265                 self.colormod = randomvec() * 4;
 266         }
 267 }
 268
 269 float Monster_CanRespawn(entity ent)
 270 {
 271         other = ent;
 272         if(MUTATOR_CALLHOOK(MonsterRespawn))
 273                 return TRUE; // enabled by a mutator
 274
 275         if(ent.spawnflags & MONSTERFLAG_NORESPAWN)
 276                 return FALSE;
 277
 278         if not(autocvar_g_monsters_respawn)
 279                 return FALSE;
 280
 281         return TRUE;
 282 }
 283
 284 void Monster_Fade ()
 285 {
 286         if(Monster_CanRespawn(self))
 287         {
 288                 self.monster_respawned = TRUE;
 289                 setmodel(self, "");
 290                 self.think = self.monster_spawnfunc;
 291                 self.nextthink = time + self.respawntime;
 292                 setorigin(self, self.pos1);
 293                 self.angles = self.pos2;
 294                 self.health = self.max_health; // TODO: check if resetting to max_health is wise here
 295                 return;
 296         }
 297         self.think = SUB_Remove;
 298         self.nextthink = time + 4;
 299         SUB_SetFade(self, time + 3, 1);
 300 }
 301
 302 float Monster_CanJump (vector vel)
 303 {
 304         local vector old = self.velocity;
 305
 306         self.velocity = vel;
 307         tracetoss(self, self);
 308         self.velocity = old;
 309         if (trace_ent != self.enemy)
 310                 return FALSE;
 311
 312         return TRUE;
 313 }
 314
 315 float monster_leap (float anm, void() touchfunc, vector vel, float anim_finished)
 316 {
 317         if not(self.flags & FL_ONGROUND)
 318                 return FALSE;
 319         if(self.health < 1)
 320                 return FALSE; // called when dead?
 321         if not(Monster_CanJump(vel))
 322                 return FALSE;
 323
 324         self.frame = anm;
 325         self.state = MONSTER_STATE_ATTACK_LEAP;
 326         self.touch = touchfunc;
 327         self.origin_z += 1;
 328         self.velocity = vel;
 329         if (self.flags & FL_ONGROUND)
 330                 self.flags -= FL_ONGROUND;
 331
 332         self.attack_finished_single = time + anim_finished;
 333
 334         return TRUE;
 335 }
 336
 337 float GenericCheckAttack ()
 338 {
 339         // checking attack while dead?
 340         if (self.health <= 0 || self.enemy == world)
 341                 return FALSE;
 342
 343         if(self.monster_delayedattack && self.delay != -1)
 344         {
 345                 if(time < self.delay)
 346                         return FALSE;
 347
 348                 self.monster_delayedattack();
 349         }
 350
 351         if (time < self.attack_finished_single)
 352                 return FALSE;
 353
 354         if (enemy_range() > 2000) // long traces are slow
 355                 return FALSE;
 356
 357         if(self.attack_melee)
 358         if(enemy_range() <= 100 * self.scale)
 359         {
 360                 monster_sound(self.msound_attack_melee, 0, FALSE); // no delay for attack sounds
 361                 self.attack_melee(); // don't wait for nextthink - too slow
 362                 return TRUE;
 363         }
 364
 365         // monster doesn't have a ranged attack function, so stop here
 366         if not(self.attack_ranged)
 367                 return FALSE;
 368
 369         // see if any entities are in the way of the shot
 370         if not(findtrajectorywithleading(self.origin, '0 0 0', '0 0 0', self.enemy, 800, 0, 2.5, 0, self))
 371                 return FALSE;
 372
 373         if(self.attack_ranged())
 374         {
 375                 monster_sound(self.msound_attack_ranged, 0, FALSE); // no delay for attack sounds
 376                 return TRUE;
 377         }
 378
 379         return FALSE;
 380 }
 381
 382 void monster_use ()
 383 {
 384         if (self.enemy)
 385                 return;
 386         if (self.health <= 0)
 387                 return;
 388
 389         if(!monster_isvalidtarget(activator, self, -1))
 390                 return;
 391
 392         self.enemy = activator;
 393 }
 394
 395 float trace_path(vector from, vector to)
 396 {
 397         vector dir = normalize(to - from) * 15, offset = '0 0 0';
 398         float trace1 = trace_fraction;
 399
 400         offset_x = dir_y;
 401         offset_y = -dir_x;
 402         traceline (from+offset, to+offset, TRUE, self);
 403
 404         traceline(from-offset, to-offset, TRUE, self);
 405
 406         return ((trace1 < trace_fraction) ? trace1 : trace_fraction);
 407 }
 408
 409 vector monster_pickmovetarget(entity targ)
 410 {
 411         // enemy is always preferred target
 412         if(self.enemy)
 413         {
 414                 self.monster_movestate = MONSTER_MOVE_ENEMY;
 415                 return self.enemy.origin;
 416         }
 417         if(targ)
 418         {
 419                 self.monster_movestate = MONSTER_MOVE_WANDER;
 420                 return targ.origin;
 421         }
 422
 423         switch(self.monster_moveflags)
 424         {
 425                 case MONSTER_MOVE_OWNER:
 426                 {
 427                         self.monster_movestate = MONSTER_MOVE_OWNER;
 428                         if(self.monster_owner && self.monster_owner.classname != "monster_swarm")
 429                                 return self.monster_owner.origin;
 430                 }
 431                 case MONSTER_MOVE_WANDER:
 432                 {
 433                         self.monster_movestate = MONSTER_MOVE_WANDER;
 434
 435                         self.angles_y = random() * 500;
 436                         makevectors(self.angles);
 437                         return self.origin + v_forward * 600;
 438                 }
 439                 case MONSTER_MOVE_SPAWNLOC:
 440                 {
 441                         self.monster_movestate = MONSTER_MOVE_SPAWNLOC;
 442                         return self.pos1;
 443                 }
 444                 default:
 445                 case MONSTER_MOVE_NOMOVE:
 446                 {
 447                         self.monster_movestate = MONSTER_MOVE_NOMOVE;
 448                         return self.origin;
 449                 }
 450         }
 451 }
 452
 453 .float last_trace;
 454 void monster_move(float runspeed, float walkspeed, float stopspeed, float manim_run, float manim_walk, float manim_idle)
 455 {
 456         if(self.target)
 457                 self.goalentity = find(world, targetname, self.target);
 458
 459         entity targ;
 460
 461         if(self.frozen)
 462         {
 463                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
 464                 self.health = max(1, self.max_health * self.revive_progress);
 465
 466                 if(self.sprite) WaypointSprite_UpdateHealth(self.sprite, self.health);
 467
 468                 movelib_beak_simple(stopspeed);
 469
 470                 self.velocity = '0 0 0';
 471                 self.enemy = world;
 472                 self.nextthink = time + 0.1;
 473
 474                 if(self.revive_progress >= 1)
 475                         Unfreeze(self); // wait for next think before attacking
 476
 477                 return; // no moving while frozen
 478         }
 479
 480         if(self.flags & FL_SWIM)
 481         {
 482                 if(self.waterlevel < WATERLEVEL_WETFEET)
 483                 {
 484                         if(time >= self.last_trace)
 485                         {
 486                                 self.last_trace = time + 0.4;
 487                                 self.angles = '0 0 -90';
 488                                 Damage (self, world, world, 2, DEATH_DROWN, self.origin, '0 0 0');
 489                                 if(random() < 0.5)
 490                                 {
 491                                         self.velocity_y += random() * 50;
 492                                         self.velocity_x -= random() * 50;
 493                                 }
 494                                 else
 495                                 {
 496                                         self.velocity_y -= random() * 50;
 497                                         self.velocity_x += random() * 50;
 498                                 }
 499                                 //self.velocity_z += random() * 150;
 500                                 self.movetype = MOVETYPE_BOUNCE;
 501                                 self.velocity_z = -200;
 502                         }
 503                         return;
 504                 }
 505                 else
 506                 {
 507                         self.angles = '0 0 0';
 508                         self.movetype = MOVETYPE_WALK;
 509                 }
 510         }
 511
 512         if(gameover || time < game_starttime)
 513         {
 514                 runspeed = walkspeed = 0;
 515                 self.frame = manim_idle;
 516                 movelib_beak_simple(stopspeed);
 517                 return;
 518         }
 519
 520         targ = self.goalentity;
 521
 522         monster_target = targ;
 523         monster_speed_run = runspeed;
 524         monster_speed_walk = walkspeed;
 525         MUTATOR_CALLHOOK(MonsterMove);
 526         targ = monster_target;
 527         runspeed = monster_speed_run;
 528         walkspeed = monster_speed_walk;
 529
 530         if(IsDifferentTeam(self.monster_owner, self))
 531                 self.monster_owner = world;
 532
 533         if(!enemy_stillvalidtarget(self.enemy, self))
 534                 self.enemy = world;
 535
 536         if not(self.enemy)
 537         {
 538                 self.enemy = FindTarget(self);
 539                 if(self.enemy)
 540                         monster_sound(self.msound_sight, 0, FALSE);
 541         }
 542
 543         if(time >= self.last_trace)
 544         {
 545                 if(self.monster_movestate == MONSTER_MOVE_WANDER && self.goalentity.classname != "td_waypoint")
 546                         self.last_trace = time + 2;
 547                 else
 548                         self.last_trace = time + 0.5;
 549                 self.moveto = monster_pickmovetarget(targ);
 550         }
 551
 552         if not(self.enemy)
 553                 monster_sound(self.msound_idle, 5, TRUE);
 554
 555         vector angles_face = vectoangles(self.moveto - self.origin);
 556         vector owner_face = vectoangles(self.monster_owner.origin - self.origin);
 557         self.angles_y = angles_face_y;
 558
 559         if(self.state == MONSTER_STATE_ATTACK_LEAP && (self.flags & FL_ONGROUND))
 560         {
 561                 self.state = 0;
 562                 self.touch = MonsterTouch;
 563         }
 564
 565         v_forward = normalize(self.moveto - self.origin);
 566
 567         float l = vlen(self.moveto - self.origin);
 568         float t1 = trace_path(self.origin+'0 0 10', self.moveto+'0 0 10');
 569         float t2 = trace_path(self.origin-'0 0 15', self.moveto-'0 0 15');
 570
 571         if(t1*l-t2*l>50 && (t1*l > 100 || t1 > 0.8))
 572         if(self.flags & FL_ONGROUND)
 573                 movelib_jump_simple(100);
 574
 575         if(vlen(self.origin - self.moveto) > 64)
 576         {
 577                 if(self.flags & FL_FLY)
 578                         movelib_move_simple(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 579                 else
 580                         movelib_move_simple_gravity(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 581                 if(time > self.pain_finished)
 582                 if(time > self.attack_finished_single)
 583                         self.frame = ((self.enemy) ? manim_run : manim_walk);
 584         }
 585         else
 586         {
 587                 movelib_beak_simple(stopspeed);
 588                 if(time > self.attack_finished_single)
 589                 if(time > self.pain_finished)
 590                 if (vlen(self.velocity) <= 30)
 591                 {
 592                         self.frame = manim_idle;
 593                         self.angles_y = ((self.monster_owner) ? owner_face_y : self.pos2_y); // reset looking angle now?
 594                 }
 595         }
 596
 597         if(self.enemy && self.checkattack)
 598                 self.checkattack();
 599 }
 600
 601 void monsters_setstatus()
 602 {
 603         self.stat_monsters_total = monsters_total;
 604         self.stat_monsters_killed = monsters_killed;
 605 }
 606
 607 void Monster_Appear ()
 608 {
 609         self.enemy = activator;
 610         self.spawnflags &~= MONSTERFLAG_APPEAR;
 611         self.monster_spawnfunc();
 612 }
 613
 614 void monsters_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 615 {
 616         if(self.frozen)
 617                 return;
 618
 619         if(time < self.pain_finished)
 620                 return;
 621
 622         if((ignore_turrets && !(attacker.turrcaps_flags & TFL_TURRCAPS_ISTURRET)) || !ignore_turrets)
 623         if(monster_isvalidtarget(attacker, self, FALSE))
 624                 self.enemy = attacker;
 625
 626         self.health -= damage;
 627
 628         if(self.sprite)
 629                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 630
 631         self.dmg_time = time;
 632
 633         if(sound_allowed(MSG_BROADCAST, attacker) && deathtype != DEATH_DROWN)
 634                 spamsound (self, CH_PAIN, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);  // FIXME: PLACEHOLDER
 635
 636         self.velocity += force * self.damageforcescale;
 637
 638         if(deathtype != DEATH_DROWN)
 639         {
 640                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 641                 if (damage > 50)
 642                         Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 643                 if (damage > 100)
 644                         Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 645         }
 646
 647         if(self.health <= 0)
 648         {
 649                 if(self.sprite)
 650                 {
 651                         // Update one more time to avoid waypoint fading without emptying healthbar
 652                         WaypointSprite_UpdateHealth(self.sprite, 0);
 653                 }
 654
 655                 if(self.flags & MONSTERFLAG_MINIBOSS) // TODO: cvarise the weapon drop?
 656                         W_ThrowNewWeapon(self, WEP_NEX, 0, self.origin, self.velocity);
 657
 658                 activator = attacker;
 659                 other = self.enemy;
 660                 self.target = self.target2;
 661                 self.target2 = "";
 662                 SUB_UseTargets();
 663
 664                 self.monster_die();
 665
 666                 frag_attacker = attacker;
 667                 frag_target = self;
 668                 MUTATOR_CALLHOOK(MonsterDies);
 669         }
 670 }
 671
 672 // used to hook into monster post death functions without a mutator
 673 void monster_hook_death()
 674 {
 675         if(self.sprite)
 676         WaypointSprite_Kill(self.sprite);
 677
 678         monster_sound(self.msound_death, 0, FALSE);
 679
 680         if(!(self.spawnflags & MONSTERFLAG_SPAWNED) && !self.monster_respawned)
 681                 monsters_killed += 1;
 682
 683         if(self.realowner.classname == "monster_spawner")
 684                 self.realowner.spawner_monstercount -= 1;
 685
 686         if(self.realowner.flags & FL_CLIENT)
 687                 self.realowner.monstercount -= 1;
 688
 689         totalspawned -= 1;
 690 }
 691
 692 // used to hook into monster post spawn functions without a mutator
 693 void monster_hook_spawn()
 694 {
 695         Monster_CheckMinibossFlag();
 696
 697         self.max_health = self.health;
 698         self.pain_finished = self.nextthink;
 699
 700         monster_precachesounds();
 701
 702         if(teamplay && self.team)
 703         {
 704                 self.colormod = TeamColor(self.team);
 705                 self.monster_attack = TRUE;
 706         }
 707
 708         if (self.target)
 709         {
 710                 self.target2 = self.target;
 711                 self.goalentity = find(world, targetname, self.target);
 712         }
 713
 714         if(autocvar_g_monsters_healthbars)
 715         {
 716                 WaypointSprite_Spawn(self.netname, 0, 600, self, '0 0 1' * self.sprite_height, world, 0, self, sprite, FALSE, RADARICON_DANGER, ((teamplay) ? TeamColor(self.team) : '1 0 0'));
 717                 WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
 718                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 719         }
 720
 721         monster_sound(self.msound_spawn, 0, FALSE);
 722
 723         MUTATOR_CALLHOOK(MonsterSpawn);
 724 }
 725
 726 float monster_initialize(string  net_name,
 727                                                  string  bodymodel,
 728                                                  vector  min_s,
 729                                                  vector  max_s,
 730                                                  float   nodrop,
 731                                                  void() dieproc,
 732                                                  void() spawnproc)
 733 {
 734         if not(autocvar_g_monsters)
 735                 return FALSE;
 736
 737         // support for quake style removing monsters based on skill
 738         if(monster_skill <= autocvar_g_monsters_skill_easy && (self.spawnflags & MONSTERSKILL_NOTEASY)) { return FALSE; }
 739         if(monster_skill == autocvar_g_monsters_skill_normal && (self.spawnflags & MONSTERSKILL_NOTMEDIUM)) { return FALSE; }
 740         if(monster_skill == autocvar_g_monsters_skill_hard && (self.spawnflags & MONSTERSKILL_NOTHARD)) { return FALSE; }
 741         if(monster_skill == autocvar_g_monsters_skill_insane && (self.spawnflags & MONSTERSKILL_NOTINSANE)) { return FALSE; }
 742         if(monster_skill >= autocvar_g_monsters_skill_nightmare && (self.spawnflags & MONSTERSKILL_NOTNIGHTMARE)) { return FALSE; }
 743
 744         if(self.model == "")
 745         if(bodymodel == "")
 746                 error("monsters: missing bodymodel!");
 747
 748         if(self.netname == "")
 749         {
 750                 if(net_name != "" && self.realowner.classname == STR_PLAYER)
 751                         net_name = strzone(strdecolorize(sprintf("%s's %s", self.realowner.netname, net_name)));
 752                 self.netname = ((net_name == "") ? self.classname : net_name);
 753         }
 754
 755         if not(self.scale)
 756                 self.scale = 1;
 757
 758         if(self.spawnflags & MONSTERFLAG_GIANT && !autocvar_g_monsters_nogiants)
 759                 ScaleMonster(5);
 760         else
 761                 ScaleMonster(self.scale);
 762
 763         min_s *= self.scale;
 764         max_s *= self.scale;
 765
 766         if(self.team && !teamplay)
 767                 self.team = 0;
 768
 769         self.flags = FL_MONSTER;
 770
 771         if(self.model != "")
 772                 bodymodel = self.model;
 773
 774         if not(self.spawnflags & MONSTERFLAG_SPAWNED) // naturally spawned monster
 775         if not(self.monster_respawned)
 776                 monsters_total += 1;
 777
 778         precache_model(bodymodel);
 779
 780         setmodel(self, bodymodel);
 781
 782         setsize(self, min_s, max_s);
 783
 784         self.takedamage                 = DAMAGE_AIM;
 785         self.bot_attack                 = TRUE;
 786         self.iscreature                 = TRUE;
 787         self.teleportable               = TRUE;
 788         self.damagedbycontents  = TRUE;
 789         self.damageforcescale   = 0.003;
 790         self.monster_die                = dieproc;
 791         self.event_damage               = monsters_damage;
 792         self.touch                              = MonsterTouch;
 793         self.use                                = monster_use;
 794         self.solid                              = SOLID_BBOX;
 795         self.movetype                   = MOVETYPE_WALK;
 796         self.delay                              = -1; // used in attack delay code
 797         monsters_spawned           += 1;
 798         self.think                              = spawnproc;
 799         self.nextthink                  = time;
 800         self.enemy                              = world;
 801         self.velocity                   = '0 0 0';
 802         self.moveto                             = self.origin;
 803         self.pos1                               = self.origin;
 804         self.pos2                               = self.angles;
 805
 806         if not(self.target_range)
 807                 self.target_range = autocvar_g_monsters_target_range;
 808
 809         if not(self.respawntime)
 810                 self.respawntime = autocvar_g_monsters_respawn_delay;
 811
 812         if not(self.monster_moveflags)
 813                 self.monster_moveflags = MONSTER_MOVE_WANDER;
 814
 815         if(autocvar_g_nodepthtestplayers)
 816                 self.effects |= EF_NODEPTHTEST;
 817
 818         if(autocvar_g_fullbrightplayers)
 819                 self.effects |= EF_FULLBRIGHT;
 820
 821         if not(nodrop)
 822         {
 823                 setorigin(self, self.origin);
 824                 tracebox(self.origin + '0 0 100', min_s, max_s, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
 825                 setorigin(self, trace_endpos);
 826         }
 827
 828         return TRUE;
 829 }