qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void crosshair_trace_plusvisibletriggers(entity pl)
  12 {
  13         entity first;
  14         entity e;
  15         first = findchainfloat(solid, SOLID_TRIGGER);
  16
  17         for (e = first; e; e = e.chain)
  18                 if (e.model != "")
  19                         e.solid = SOLID_BSP;
  20
  21         crosshair_trace(pl);
  22
  23         for (e = first; e; e = e.chain)
  24                 e.solid = SOLID_TRIGGER;
  25 }
  26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  27 void WarpZone_crosshair_trace(entity pl)
  28 {
  29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  30 }
  31
  32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  33 void() spawnpoint_use;
  34 string GetMapname();
  35
  36 string admin_name(void)
  37 {
  38         if(autocvar_sv_adminnick != "")
  39                 return autocvar_sv_adminnick;
  40         else
  41                 return "SERVER ADMIN";
  42 }
  43
  44 float DistributeEvenly_amount;
  45 float DistributeEvenly_totalweight;
  46 void DistributeEvenly_Init(float amount, float totalweight)
  47 {
  48     if (DistributeEvenly_amount)
  49     {
  50         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  51         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  52     }
  53     if (totalweight == 0)
  54         DistributeEvenly_amount = 0;
  55     else
  56         DistributeEvenly_amount = amount;
  57     DistributeEvenly_totalweight = totalweight;
  58 }
  59 float DistributeEvenly_Get(float weight)
  60 {
  61     float f;
  62     if (weight <= 0)
  63         return 0;
  64     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  65     DistributeEvenly_totalweight -= weight;
  66     DistributeEvenly_amount -= f;
  67     return f;
  68 }
  69 float DistributeEvenly_GetRandomized(float weight)
  70 {
  71     float f;
  72     if (weight <= 0)
  73         return 0;
  74     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  75     DistributeEvenly_totalweight -= weight;
  76     DistributeEvenly_amount -= f;
  77     return f;
  78 }
  79
  80 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  81
  82 const string STR_PLAYER = "player";
  83 const string STR_SPECTATOR = "spectator";
  84 const string STR_OBSERVER = "observer";
  85
  86 #define IS_PLAYER(v)                    (v.classname == STR_PLAYER)
  87 #define IS_SPEC(v)                              (v.classname == STR_SPECTATOR)
  88 #define IS_OBSERVER(v)                  (v.classname == STR_OBSERVER)
  89 #define IS_CLIENT(v)                    (v.flags & FL_CLIENT)
  90 #define IS_BOT_CLIENT(v)                (clienttype(v) == CLIENTTYPE_BOT)
  91 #define IS_REAL_CLIENT(v)               (clienttype(v) == CLIENTTYPE_REAL)
  92 #define IS_NOT_A_CLIENT(v)              (clienttype(v) == CLIENTTYPE_NOTACLIENT)
  93
  94 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  95 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(IS_CLIENT(v))
  96 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(IS_REAL_CLIENT(v))
  97
  98 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(IS_PLAYER(v))
  99 #define FOR_EACH_SPEC(v) FOR_EACH_CLIENT(v) if (!IS_PLAYER(v)) // Samual: shouldn't this be IS_SPEC(v)? and rather create a separate macro to include observers too
 100 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(IS_PLAYER(v))
 101
 102 #define CENTER_OR_VIEWOFS(ent) (ent.origin + (IS_PLAYER(ent) ? ent.view_ofs : ((ent.mins + ent.maxs) * 0.5)))
 103
 104 // copies a string to a tempstring (so one can strunzone it)
 105 string strcat1(string s) = #115; // FRIK_FILE
 106
 107 float logfile_open;
 108 float logfile;
 109
 110 void GameLogEcho(string s)
 111 {
 112     string fn;
 113     float matches;
 114
 115     if (autocvar_sv_eventlog_files)
 116     {
 117         if (!logfile_open)
 118         {
 119             logfile_open = TRUE;
 120             matches = autocvar_sv_eventlog_files_counter + 1;
 121             cvar_set("sv_eventlog_files_counter", ftos(matches));
 122             fn = ftos(matches);
 123             if (strlen(fn) < 8)
 124                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 125             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 126             logfile = fopen(fn, FILE_APPEND);
 127             fputs(logfile, ":logversion:3\n");
 128         }
 129         if (logfile >= 0)
 130         {
 131             if (autocvar_sv_eventlog_files_timestamps)
 132                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 133             else
 134                 fputs(logfile, strcat(s, "\n"));
 135         }
 136     }
 137     if (autocvar_sv_eventlog_console)
 138     {
 139         print(s, "\n");
 140     }
 141 }
 142
 143 void GameLogInit()
 144 {
 145     logfile_open = 0;
 146     // will be opened later
 147 }
 148
 149 void GameLogClose()
 150 {
 151     if (logfile_open && logfile >= 0)
 152     {
 153         fclose(logfile);
 154         logfile = -1;
 155     }
 156 }
 157
 158 #define strstr strstrofs
 159 /*
 160 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 161 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 162 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 163 // BE CONSTANT OR strzoneD!
 164 float strstr(string haystack, string needle, float offset)
 165 {
 166         float len, endpos;
 167         string found;
 168         len = strlen(needle);
 169         endpos = strlen(haystack) - len;
 170         while(offset <= endpos)
 171         {
 172                 found = substring(haystack, offset, len);
 173                 if(found == needle)
 174                         return offset;
 175                 offset = offset + 1;
 176         }
 177         return -1;
 178 }
 179 */
 180
 181 const float NUM_NEAREST_ENTITIES = 4;
 182 entity nearest_entity[NUM_NEAREST_ENTITIES];
 183 float nearest_length[NUM_NEAREST_ENTITIES];
 184 entity findnearest(vector point, .string field, string value, vector axismod)
 185 {
 186     entity localhead;
 187     float i;
 188     float j;
 189     float len;
 190     vector dist;
 191
 192     float num_nearest;
 193     num_nearest = 0;
 194
 195     localhead = find(world, field, value);
 196     while (localhead)
 197     {
 198         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 199             dist = localhead.oldorigin;
 200         else
 201             dist = localhead.origin;
 202         dist = dist - point;
 203         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 204         len = vlen(dist);
 205
 206         for (i = 0; i < num_nearest; ++i)
 207         {
 208             if (len < nearest_length[i])
 209                 break;
 210         }
 211
 212         // now i tells us where to insert at
 213         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 214         if (i < NUM_NEAREST_ENTITIES)
 215         {
 216             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 217             {
 218                 nearest_length[j + 1] = nearest_length[j];
 219                 nearest_entity[j + 1] = nearest_entity[j];
 220             }
 221             nearest_length[i] = len;
 222             nearest_entity[i] = localhead;
 223             if (num_nearest < NUM_NEAREST_ENTITIES)
 224                 num_nearest = num_nearest + 1;
 225         }
 226
 227         localhead = find(localhead, field, value);
 228     }
 229
 230     // now use the first one from our list that we can see
 231     for (i = 0; i < num_nearest; ++i)
 232     {
 233         traceline(point, nearest_entity[i].origin, TRUE, world);
 234         if (trace_fraction == 1)
 235         {
 236             if (i != 0)
 237             {
 238                 dprint("Nearest point (");
 239                 dprint(nearest_entity[0].netname);
 240                 dprint(") is not visible, using a visible one.\n");
 241             }
 242             return nearest_entity[i];
 243         }
 244     }
 245
 246     if (num_nearest == 0)
 247         return world;
 248
 249     dprint("Not seeing any location point, using nearest as fallback.\n");
 250     /* DEBUGGING CODE:
 251     dprint("Candidates were: ");
 252     for(j = 0; j < num_nearest; ++j)
 253     {
 254         if(j != 0)
 255                 dprint(", ");
 256         dprint(nearest_entity[j].netname);
 257     }
 258     dprint("\n");
 259     */
 260
 261     return nearest_entity[0];
 262 }
 263
 264 void spawnfunc_target_location()
 265 {
 266     self.classname = "target_location";
 267     // location name in netname
 268     // eventually support: count, teamgame selectors, line of sight?
 269 }
 270
 271 void spawnfunc_info_location()
 272 {
 273     self.classname = "target_location";
 274     self.message = self.netname;
 275 }
 276
 277 string NearestLocation(vector p)
 278 {
 279     entity loc;
 280     string ret;
 281     ret = "somewhere";
 282     loc = findnearest(p, classname, "target_location", '1 1 1');
 283     if (loc)
 284     {
 285         ret = loc.message;
 286     }
 287     else
 288     {
 289         loc = findnearest(p, target, "###item###", '1 1 4');
 290         if (loc)
 291             ret = loc.netname;
 292     }
 293     return ret;
 294 }
 295
 296 string formatmessage(string msg)
 297 {
 298         float p, p1, p2;
 299         float n;
 300         vector cursor;
 301         entity cursor_ent;
 302         string escape;
 303         string replacement;
 304         p = 0;
 305         n = 7;
 306
 307         WarpZone_crosshair_trace(self);
 308         cursor = trace_endpos;
 309         cursor_ent = trace_ent;
 310
 311         while (1) {
 312                 if (n < 1)
 313                         break; // too many replacements
 314
 315                 n = n - 1;
 316                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 317                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 318
 319                 if (p1 < 0)
 320                         p1 = p2;
 321
 322                 if (p2 < 0)
 323                         p2 = p1;
 324
 325                 p = min(p1, p2);
 326
 327                 if (p < 0)
 328                         break;
 329
 330                 replacement = substring(msg, p, 2);
 331                 escape = substring(msg, p + 1, 1);
 332
 333                 if (escape == "%")
 334                         replacement = "%";
 335                 else if (escape == "\\")
 336                         replacement = "\\";
 337                 else if (escape == "n")
 338                         replacement = "\n";
 339                 else if (escape == "a")
 340                         replacement = ftos(floor(self.armorvalue));
 341                 else if (escape == "h")
 342                         replacement = ftos(floor(self.health));
 343                 else if (escape == "l")
 344                         replacement = NearestLocation(self.origin);
 345                 else if (escape == "y")
 346                         replacement = NearestLocation(cursor);
 347                 else if (escape == "d")
 348                         replacement = NearestLocation(self.death_origin);
 349                 else if (escape == "w") {
 350                         float wep;
 351                         wep = self.weapon;
 352                         if (!wep)
 353                                 wep = self.switchweapon;
 354                         if (!wep)
 355                                 wep = self.cnt;
 356                         replacement = W_Name(wep);
 357                 } else if (escape == "W") {
 358                         if (self.items & IT_SHELLS) replacement = "shells";
 359                         else if (self.items & IT_NAILS) replacement = "bullets";
 360                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 361                         else if (self.items & IT_CELLS) replacement = "cells";
 362                         else replacement = "batteries"; // ;)
 363                 } else if (escape == "x") {
 364                         replacement = cursor_ent.netname;
 365                         if (replacement == "" || !cursor_ent)
 366                                 replacement = "nothing";
 367                 } else if (escape == "s")
 368                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 369                 else if (escape == "S")
 370                         replacement = ftos(vlen(self.velocity));
 371
 372                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 373                 p = p + strlen(replacement);
 374         }
 375         return msg;
 376 }
 377
 378 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 379         return (value == 0) ? FALSE : TRUE;
 380 }
 381
 382 /*
 383 =============
 384 GetCvars
 385 =============
 386 Called with:
 387   0:  sends the request
 388   >0: receives a cvar from name=argv(f) value=argv(f+1)
 389 */
 390 void GetCvars_handleString(string thisname, float f, .string field, string name)
 391 {
 392         if (f < 0)
 393         {
 394                 if (self.field)
 395                         strunzone(self.field);
 396                 self.field = string_null;
 397         }
 398         else if (f > 0)
 399         {
 400                 if (thisname == name)
 401                 {
 402                         if (self.field)
 403                                 strunzone(self.field);
 404                         self.field = strzone(argv(f + 1));
 405                 }
 406         }
 407         else
 408                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 409 }
 410 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 411 {
 412         GetCvars_handleString(thisname, f, field, name);
 413         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 414                 if (thisname == name)
 415                 {
 416                         string s;
 417                         s = func(strcat1(self.field));
 418                         if (s != self.field)
 419                         {
 420                                 strunzone(self.field);
 421                                 self.field = strzone(s);
 422                         }
 423                 }
 424 }
 425 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 426 {
 427         if (f < 0)
 428         {
 429         }
 430         else if (f > 0)
 431         {
 432                 if (thisname == name)
 433                         self.field = stof(argv(f + 1));
 434         }
 435         else
 436                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 437 }
 438 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 439 {
 440         if (f < 0)
 441         {
 442         }
 443         else if (f > 0)
 444         {
 445                 if (thisname == name)
 446                 {
 447                         if(!self.field)
 448                         {
 449                                 self.field = stof(argv(f + 1));
 450                                 if(!self.field)
 451                                         self.field = -1;
 452                         }
 453                 }
 454         }
 455         else
 456         {
 457                 if(!self.field)
 458                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 459         }
 460 }
 461 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 462 {
 463         string o;
 464         o = W_FixWeaponOrder_ForceComplete(wo);
 465         if(self.weaponorder_byimpulse)
 466         {
 467                 strunzone(self.weaponorder_byimpulse);
 468                 self.weaponorder_byimpulse = string_null;
 469         }
 470         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 471         return o;
 472 }
 473 void GetCvars(float f)
 474 {
 475         string s = string_null;
 476
 477         if (f > 0)
 478                 s = strcat1(argv(f));
 479
 480         get_cvars_f = f;
 481         get_cvars_s = s;
 482
 483         MUTATOR_CALLHOOK(GetCvars);
 484
 485         Notification_GetCvars();
 486
 487         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 488         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 489         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 490         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 491         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 492         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 493         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 494         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 495         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 496         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 497         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 498         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 499         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 500         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 501         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 502         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 503         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 504         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 505         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 506         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 507         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 508         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 509         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 510
 511         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 512         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 513
 514         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 515         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 516         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 517         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 518         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 519
 520         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 521         if (f > 0)
 522         {
 523                 if (s == "cl_weaponpriority")
 524                         self.switchweapon = w_getbestweapon(self);
 525                 if (s == "cl_allow_uidtracking")
 526                         PlayerStats_AddPlayer(self);
 527         }
 528 }
 529
 530 // decolorizes and team colors the player name when needed
 531 string playername(entity p)
 532 {
 533     string t;
 534     if (teamplay && !intermission_running && IS_PLAYER(p))
 535     {
 536         t = Team_ColorCode(p.team);
 537         return strcat(t, strdecolorize(p.netname));
 538     }
 539     else
 540         return p.netname;
 541 }
 542
 543 vector randompos(vector m1, vector m2)
 544 {
 545     vector v;
 546     m2 = m2 - m1;
 547     v_x = m2_x * random() + m1_x;
 548     v_y = m2_y * random() + m1_y;
 549     v_z = m2_z * random() + m1_z;
 550     return  v;
 551 }
 552
 553 //#NO AUTOCVARS START
 554
 555 float g_pickup_shells;
 556 float g_pickup_shells_max;
 557 float g_pickup_nails;
 558 float g_pickup_nails_max;
 559 float g_pickup_rockets;
 560 float g_pickup_rockets_max;
 561 float g_pickup_cells;
 562 float g_pickup_cells_max;
 563 float g_pickup_fuel;
 564 float g_pickup_fuel_jetpack;
 565 float g_pickup_fuel_max;
 566 float g_pickup_armorsmall;
 567 float g_pickup_armorsmall_max;
 568 float g_pickup_armorsmall_anyway;
 569 float g_pickup_armormedium;
 570 float g_pickup_armormedium_max;
 571 float g_pickup_armormedium_anyway;
 572 float g_pickup_armorbig;
 573 float g_pickup_armorbig_max;
 574 float g_pickup_armorbig_anyway;
 575 float g_pickup_armorlarge;
 576 float g_pickup_armorlarge_max;
 577 float g_pickup_armorlarge_anyway;
 578 float g_pickup_healthsmall;
 579 float g_pickup_healthsmall_max;
 580 float g_pickup_healthsmall_anyway;
 581 float g_pickup_healthmedium;
 582 float g_pickup_healthmedium_max;
 583 float g_pickup_healthmedium_anyway;
 584 float g_pickup_healthlarge;
 585 float g_pickup_healthlarge_max;
 586 float g_pickup_healthlarge_anyway;
 587 float g_pickup_healthmega;
 588 float g_pickup_healthmega_max;
 589 float g_pickup_healthmega_anyway;
 590 float g_pickup_ammo_anyway;
 591 float g_pickup_weapons_anyway;
 592 float g_weaponarena;
 593 WepSet g_weaponarena_weapons;
 594 float g_weaponarena_random;
 595 float g_weaponarena_random_with_laser;
 596 string g_weaponarena_list;
 597 float g_weaponspeedfactor;
 598 float g_weaponratefactor;
 599 float g_weapondamagefactor;
 600 float g_weaponforcefactor;
 601 float g_weaponspreadfactor;
 602
 603 WepSet start_weapons;
 604 WepSet start_weapons_default;
 605 WepSet start_weapons_defaultmask;
 606 float start_items;
 607 float start_ammo_shells;
 608 float start_ammo_nails;
 609 float start_ammo_rockets;
 610 float start_ammo_cells;
 611 float start_ammo_fuel;
 612 float start_health;
 613 float start_armorvalue;
 614 WepSet warmup_start_weapons;
 615 WepSet warmup_start_weapons_default;
 616 WepSet warmup_start_weapons_defaultmask;
 617 #define WARMUP_START_WEAPONS ((g_warmup_allguns == 1) ? (warmup_start_weapons & (weaponsInMap | start_weapons)) : warmup_start_weapons)
 618 float warmup_start_ammo_shells;
 619 float warmup_start_ammo_nails;
 620 float warmup_start_ammo_rockets;
 621 float warmup_start_ammo_cells;
 622 float warmup_start_ammo_fuel;
 623 float warmup_start_health;
 624 float warmup_start_armorvalue;
 625 float g_weapon_stay;
 626
 627 entity get_weaponinfo(float w);
 628
 629 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 630 {
 631         var float i = weaponinfo.weapon;
 632         var float d = 0;
 633
 634         if (!i)
 635                 return 0;
 636
 637         if (g_lms || g_ca || allguns)
 638         {
 639                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 640                         d = TRUE;
 641                 else
 642                         d = FALSE;
 643         }
 644         else if (g_cts)
 645                 d = (i == WEP_SHOTGUN); // todo: how to handle shotgun in CTS mode? we're removing it.. so....
 646         else if (g_nexball)
 647                 d = 0; // weapon is set a few lines later
 648         else
 649                 d = (i == WEP_LASER || i == WEP_SHOTGUN);
 650
 651         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 652                 d |= (i == WEP_HOOK);
 653         if(weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED) // never default mutator blocked guns
 654                 d = 0;
 655
 656         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 657
 658         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 659
 660         // bit order in t:
 661         // 1: want or not
 662         // 2: is default?
 663         // 4: is set by default?
 664         if(t < 0)
 665                 t = 4 | (3 * d);
 666         else
 667                 t |= (2 * d);
 668
 669         return t;
 670 }
 671
 672 void readplayerstartcvars()
 673 {
 674         entity e;
 675         float i, j, t;
 676         string s;
 677
 678         // initialize starting values for players
 679         start_weapons = '0 0 0';
 680         start_weapons_default = '0 0 0';
 681         start_weapons_defaultmask = '0 0 0';
 682         start_items = 0;
 683         start_ammo_shells = 0;
 684         start_ammo_nails = 0;
 685         start_ammo_rockets = 0;
 686         start_ammo_cells = 0;
 687         start_health = cvar("g_balance_health_start");
 688         start_armorvalue = cvar("g_balance_armor_start");
 689
 690         g_weaponarena = 0;
 691         g_weaponarena_weapons = '0 0 0';
 692
 693         s = cvar_string("g_weaponarena");
 694         if (s == "0" || s == "")
 695         {
 696                 if(g_ca)
 697                         s = "most";
 698         }
 699
 700         if (s == "0" || s == "")
 701         {
 702                 // no arena
 703         }
 704         else if (s == "off")
 705         {
 706                 // forcibly turn off weaponarena
 707         }
 708         else if (s == "all")
 709         {
 710                 g_weaponarena = 1;
 711                 g_weaponarena_list = "All Weapons";
 712                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 713                 {
 714                         e = get_weaponinfo(j);
 715                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 716                                 g_weaponarena_weapons |= WepSet_FromWeapon(j);
 717                 }
 718         }
 719         else if (s == "most")
 720         {
 721                 g_weaponarena = 1;
 722                 g_weaponarena_list = "Most Weapons";
 723                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 724                 {
 725                         e = get_weaponinfo(j);
 726                         if (!(e.spawnflags & WEP_FLAG_MUTATORBLOCKED))
 727                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 728                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 729                 }
 730         }
 731         else if (s == "none")
 732         {
 733                 g_weaponarena = 1;
 734                 g_weaponarena_list = "No Weapons";
 735         }
 736         else
 737         {
 738                 g_weaponarena = 1;
 739                 t = tokenize_console(s);
 740                 g_weaponarena_list = "";
 741                 for (i = 0; i < t; ++i)
 742                 {
 743                         s = argv(i);
 744                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 745                         {
 746                                 e = get_weaponinfo(j);
 747                                 if (e.netname == s)
 748                                 {
 749                                         g_weaponarena_weapons |= WepSet_FromWeapon(j);
 750                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 751                                         break;
 752                                 }
 753                         }
 754                         if (j > WEP_LAST)
 755                         {
 756                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 757                         }
 758                 }
 759                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 760         }
 761
 762         if(g_weaponarena)
 763                 g_weaponarena_random = cvar("g_weaponarena_random");
 764         else
 765                 g_weaponarena_random = 0;
 766         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 767
 768         if (g_weaponarena)
 769         {
 770                 g_weapon_stay = 0; // incompatible
 771                 start_weapons = g_weaponarena_weapons;
 772                 start_items |= IT_UNLIMITED_AMMO;
 773         }
 774         else
 775         {
 776                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 777                 {
 778                         e = get_weaponinfo(i);
 779                         float w = want_weapon("g_start_weapon_", e, FALSE);
 780                         if(w & 1)
 781                                 start_weapons |= WepSet_FromWeapon(i);
 782                         if(w & 2)
 783                                 start_weapons_default |= WepSet_FromWeapon(i);
 784                         if(w & 4)
 785                                 start_weapons_defaultmask |= WepSet_FromWeapon(i);
 786                 }
 787         }
 788
 789         if(!cvar("g_use_ammunition"))
 790                 start_items |= IT_UNLIMITED_AMMO;
 791
 792         if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 793         {
 794                 start_ammo_rockets = 999;
 795                 start_ammo_shells = 999;
 796                 start_ammo_cells = 999;
 797                 start_ammo_nails = 999;
 798                 start_ammo_fuel = 999;
 799         }
 800         else
 801         {
 802                 start_ammo_shells = cvar("g_start_ammo_shells");
 803                 start_ammo_nails = cvar("g_start_ammo_nails");
 804                 start_ammo_rockets = cvar("g_start_ammo_rockets");
 805                 start_ammo_cells = cvar("g_start_ammo_cells");
 806                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 807         }
 808
 809         if (warmup_stage)
 810         {
 811                 warmup_start_ammo_shells = start_ammo_shells;
 812                 warmup_start_ammo_nails = start_ammo_nails;
 813                 warmup_start_ammo_rockets = start_ammo_rockets;
 814                 warmup_start_ammo_cells = start_ammo_cells;
 815                 warmup_start_ammo_fuel = start_ammo_fuel;
 816                 warmup_start_health = start_health;
 817                 warmup_start_armorvalue = start_armorvalue;
 818                 warmup_start_weapons = start_weapons;
 819                 warmup_start_weapons_default = start_weapons_default;
 820                 warmup_start_weapons_defaultmask = start_weapons_defaultmask;
 821
 822                 if (!g_weaponarena && !g_ca)
 823                 {
 824                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 825                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 826                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 827                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 828                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 829                         warmup_start_health = cvar("g_warmup_start_health");
 830                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 831                         warmup_start_weapons = '0 0 0';
 832                         warmup_start_weapons_default = '0 0 0';
 833                         warmup_start_weapons_defaultmask = '0 0 0';
 834                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 835                         {
 836                                 e = get_weaponinfo(i);
 837                                 float w = want_weapon("g_start_weapon_", e, g_warmup_allguns);
 838                                 if(w & 1)
 839                                         warmup_start_weapons |= WepSet_FromWeapon(i);
 840                                 if(w & 2)
 841                                         warmup_start_weapons_default |= WepSet_FromWeapon(i);
 842                                 if(w & 4)
 843                                         warmup_start_weapons_defaultmask |= WepSet_FromWeapon(i);
 844                         }
 845                 }
 846         }
 847
 848         if (g_jetpack)
 849                 start_items |= IT_JETPACK;
 850
 851         MUTATOR_CALLHOOK(SetStartItems);
 852
 853         if ((start_items & IT_JETPACK) || (g_grappling_hook && (start_weapons & WEPSET_HOOK)))
 854         {
 855                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
 856                 start_items |= IT_FUEL_REGEN;
 857                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 858                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 859         }
 860
 861         WepSet precache_weapons = start_weapons;
 862         if (g_warmup_allguns != 1)
 863                 precache_weapons |= warmup_start_weapons;
 864         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 865         {
 866                 e = get_weaponinfo(i);
 867                 if(precache_weapons & WepSet_FromWeapon(i))
 868                         WEP_ACTION(i, WR_INIT);
 869         }
 870
 871         start_ammo_shells = max(0, start_ammo_shells);
 872         start_ammo_nails = max(0, start_ammo_nails);
 873         start_ammo_cells = max(0, start_ammo_cells);
 874         start_ammo_rockets = max(0, start_ammo_rockets);
 875         start_ammo_fuel = max(0, start_ammo_fuel);
 876
 877         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 878         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 879         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 880         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 881         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 882 }
 883
 884 float g_bugrigs;
 885 float g_bugrigs_planar_movement;
 886 float g_bugrigs_planar_movement_car_jumping;
 887 float g_bugrigs_reverse_spinning;
 888 float g_bugrigs_reverse_speeding;
 889 float g_bugrigs_reverse_stopping;
 890 float g_bugrigs_air_steering;
 891 float g_bugrigs_angle_smoothing;
 892 float g_bugrigs_friction_floor;
 893 float g_bugrigs_friction_brake;
 894 float g_bugrigs_friction_air;
 895 float g_bugrigs_accel;
 896 float g_bugrigs_speed_ref;
 897 float g_bugrigs_speed_pow;
 898 float g_bugrigs_steer;
 899
 900 float sv_autotaunt;
 901 float sv_taunt;
 902
 903 string GetGametype(); // g_world.qc
 904 void readlevelcvars(void)
 905 {
 906         // load mutators
 907         #define CHECK_MUTATOR_ADD(mut_cvar,mut_name,dependence) \
 908                 { if(cvar(mut_cvar) && dependence) { MUTATOR_ADD(mut_name); } }
 909
 910         CHECK_MUTATOR_ADD("g_dodging", mutator_dodging, 1);
 911         CHECK_MUTATOR_ADD("g_spawn_near_teammate", mutator_spawn_near_teammate, 1);
 912         CHECK_MUTATOR_ADD("g_physical_items", mutator_physical_items, 1);
 913         CHECK_MUTATOR_ADD("g_touchexplode", mutator_touchexplode, 1);
 914         CHECK_MUTATOR_ADD("g_minstagib", mutator_minstagib, 1);
 915         CHECK_MUTATOR_ADD("g_invincible_projectiles", mutator_invincibleprojectiles, !cvar("g_minstagib"));
 916         CHECK_MUTATOR_ADD("g_new_toys", mutator_new_toys, !cvar("g_minstagib"));
 917         CHECK_MUTATOR_ADD("g_nix", mutator_nix, !cvar("g_minstagib"));
 918         CHECK_MUTATOR_ADD("g_rocket_flying", mutator_rocketflying, !cvar("g_minstagib"));
 919         CHECK_MUTATOR_ADD("g_vampire", mutator_vampire, !cvar("g_minstagib"));
 920         CHECK_MUTATOR_ADD("g_superspectate", mutator_superspec, 1);
 921         CHECK_MUTATOR_ADD("g_pinata", mutator_pinata, !cvar("g_minstagib"));
 922         CHECK_MUTATOR_ADD("g_midair", mutator_midair, 1);
 923         CHECK_MUTATOR_ADD("g_bloodloss", mutator_bloodloss, !cvar("g_minstagib"));
 924         CHECK_MUTATOR_ADD("g_random_gravity", mutator_random_gravity, 1);
 925         CHECK_MUTATOR_ADD("g_multijump", mutator_multijump, 1);
 926         CHECK_MUTATOR_ADD("g_melee_only", mutator_melee_only, !cvar("g_minstagib"));
 927         CHECK_MUTATOR_ADD("g_nades", mutator_nades, 1);
 928         CHECK_MUTATOR_ADD("g_sandbox", sandbox, 1);
 929         CHECK_MUTATOR_ADD("g_campcheck", mutator_campcheck, 1);
 930
 931         #undef CHECK_MUTATOR_ADD
 932
 933         if(cvar("sv_allow_fullbright"))
 934                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
 935
 936     g_bugrigs = cvar("g_bugrigs");
 937     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
 938     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
 939     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
 940     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
 941     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
 942     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
 943     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
 944     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
 945     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
 946     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
 947     g_bugrigs_accel = cvar("g_bugrigs_accel");
 948     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
 949     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
 950     g_bugrigs_steer = cvar("g_bugrigs_steer");
 951
 952         g_minstagib = cvar("g_minstagib");
 953
 954         sv_clones = cvar("sv_clones");
 955         sv_foginterval = cvar("sv_foginterval");
 956         g_cloaked = cvar("g_cloaked");
 957     if(g_cts)
 958         g_cloaked = 1; // always enable cloak in CTS
 959         g_footsteps = cvar("g_footsteps");
 960         g_grappling_hook = cvar("g_grappling_hook");
 961         g_jetpack = cvar("g_jetpack");
 962         sv_maxidle = cvar("sv_maxidle");
 963         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
 964         sv_autotaunt = cvar("sv_autotaunt");
 965         sv_taunt = cvar("sv_taunt");
 966
 967         warmup_stage = cvar("g_warmup");
 968         g_warmup_limit = cvar("g_warmup_limit");
 969         g_warmup_allguns = cvar("g_warmup_allguns");
 970         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
 971
 972         if ((g_race && g_race_qualifying == 2) || g_assault || cvar("g_campaign"))
 973                 warmup_stage = 0; // these modes cannot work together, sorry
 974
 975         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
 976         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
 977         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
 978         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
 979         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
 980         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
 981         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
 982         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
 983         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
 984         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
 985         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
 986         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
 987         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
 988         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
 989
 990         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
 991         g_weaponratefactor = cvar("g_weaponratefactor");
 992         g_weapondamagefactor = cvar("g_weapondamagefactor");
 993         g_weaponforcefactor = cvar("g_weaponforcefactor");
 994         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
 995
 996         g_pickup_shells = cvar("g_pickup_shells");
 997         g_pickup_shells_max = cvar("g_pickup_shells_max");
 998         g_pickup_nails = cvar("g_pickup_nails");
 999         g_pickup_nails_max = cvar("g_pickup_nails_max");
1000         g_pickup_rockets = cvar("g_pickup_rockets");
1001         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1002         g_pickup_cells = cvar("g_pickup_cells");
1003         g_pickup_cells_max = cvar("g_pickup_cells_max");
1004         g_pickup_fuel = cvar("g_pickup_fuel");
1005         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1006         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1007         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1008         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1009         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1010         g_pickup_armormedium = cvar("g_pickup_armormedium");
1011         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1012         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1013         g_pickup_armorbig = cvar("g_pickup_armorbig");
1014         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1015         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1016         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1017         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1018         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1019         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1020         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1021         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1022         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1023         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1024         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1025         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1026         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1027         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1028         g_pickup_healthmega = cvar("g_pickup_healthmega");
1029         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1030         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1031
1032         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1033         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1034
1035     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1036     if(!g_weapon_stay)
1037         g_weapon_stay = cvar("g_weapon_stay");
1038
1039         if (!warmup_stage)
1040                 game_starttime = time + cvar("g_start_delay");
1041
1042         readplayerstartcvars();
1043 }
1044
1045 //#NO AUTOCVARS END
1046
1047 // Sound functions
1048 string precache_sound (string s) = #19;
1049 float precache_sound_index (string s) = #19;
1050
1051 #define SND_VOLUME      1
1052 #define SND_ATTENUATION 2
1053 #define SND_LARGEENTITY 8
1054 #define SND_LARGESOUND  16
1055
1056 float sound_allowed(float dest, entity e)
1057 {
1058     // sounds from world may always pass
1059     for (;;)
1060     {
1061         if (e.classname == "body")
1062             e = e.enemy;
1063         else if (e.realowner && e.realowner != e)
1064             e = e.realowner;
1065         else if (e.owner && e.owner != e)
1066             e = e.owner;
1067         else
1068             break;
1069     }
1070     // sounds to self may always pass
1071     if (dest == MSG_ONE)
1072         if (e == msg_entity)
1073             return TRUE;
1074     // sounds by players can be removed
1075     if (autocvar_bot_sound_monopoly)
1076         if (IS_REAL_CLIENT(e))
1077             return FALSE;
1078     // anything else may pass
1079     return TRUE;
1080 }
1081
1082 #ifdef COMPAT_XON010_CHANNELS
1083 void(entity e, float chan, string samp, float vol, float atten) builtin_sound = #8;
1084 void sound(entity e, float chan, string samp, float vol, float atten)
1085 {
1086     if (!sound_allowed(MSG_BROADCAST, e))
1087         return;
1088     builtin_sound(e, chan, samp, vol, atten);
1089 }
1090 #else
1091 #undef sound
1092 void sound(entity e, float chan, string samp, float vol, float atten)
1093 {
1094     if (!sound_allowed(MSG_BROADCAST, e))
1095         return;
1096     sound7(e, chan, samp, vol, atten, 0, 0);
1097 }
1098 #endif
1099
1100 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1101 {
1102     float entno, idx;
1103
1104     if (!sound_allowed(dest, e))
1105         return;
1106
1107     entno = num_for_edict(e);
1108     idx = precache_sound_index(samp);
1109
1110     float sflags;
1111     sflags = 0;
1112
1113     atten = floor(atten * 64);
1114     vol = floor(vol * 255);
1115
1116     if (vol != 255)
1117         sflags |= SND_VOLUME;
1118     if (atten != 64)
1119         sflags |= SND_ATTENUATION;
1120     if (entno >= 8192 || chan < 0 || chan > 7)
1121         sflags |= SND_LARGEENTITY;
1122     if (idx >= 256)
1123         sflags |= SND_LARGESOUND;
1124
1125     WriteByte(dest, SVC_SOUND);
1126     WriteByte(dest, sflags);
1127     if (sflags & SND_VOLUME)
1128         WriteByte(dest, vol);
1129     if (sflags & SND_ATTENUATION)
1130         WriteByte(dest, atten);
1131     if (sflags & SND_LARGEENTITY)
1132     {
1133         WriteShort(dest, entno);
1134         WriteByte(dest, chan);
1135     }
1136     else
1137     {
1138         WriteShort(dest, entno * 8 + chan);
1139     }
1140     if (sflags & SND_LARGESOUND)
1141         WriteShort(dest, idx);
1142     else
1143         WriteByte(dest, idx);
1144
1145     WriteCoord(dest, o_x);
1146     WriteCoord(dest, o_y);
1147     WriteCoord(dest, o_z);
1148 }
1149 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1150 {
1151     vector o;
1152
1153     if (!sound_allowed(dest, e))
1154         return;
1155
1156     o = e.origin + 0.5 * (e.mins + e.maxs);
1157     soundtoat(dest, e, o, chan, samp, vol, atten);
1158 }
1159 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1160 {
1161     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1162 }
1163 void stopsoundto(float dest, entity e, float chan)
1164 {
1165     float entno;
1166
1167     if (!sound_allowed(dest, e))
1168         return;
1169
1170     entno = num_for_edict(e);
1171
1172     if (entno >= 8192 || chan < 0 || chan > 7)
1173     {
1174         float idx, sflags;
1175         idx = precache_sound_index("misc/null.wav");
1176         sflags = SND_LARGEENTITY;
1177         if (idx >= 256)
1178             sflags |= SND_LARGESOUND;
1179         WriteByte(dest, SVC_SOUND);
1180         WriteByte(dest, sflags);
1181         WriteShort(dest, entno);
1182         WriteByte(dest, chan);
1183         if (sflags & SND_LARGESOUND)
1184             WriteShort(dest, idx);
1185         else
1186             WriteByte(dest, idx);
1187         WriteCoord(dest, e.origin_x);
1188         WriteCoord(dest, e.origin_y);
1189         WriteCoord(dest, e.origin_z);
1190     }
1191     else
1192     {
1193         WriteByte(dest, SVC_STOPSOUND);
1194         WriteShort(dest, entno * 8 + chan);
1195     }
1196 }
1197 void stopsound(entity e, float chan)
1198 {
1199     if (!sound_allowed(MSG_BROADCAST, e))
1200         return;
1201
1202     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1203     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1204 }
1205
1206 void play2(entity e, string filename)
1207 {
1208     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1209     msg_entity = e;
1210     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTEN_NONE);
1211 }
1212
1213 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1214 .float spamtime;
1215 float spamsound(entity e, float chan, string samp, float vol, float atten)
1216 {
1217     if (!sound_allowed(MSG_BROADCAST, e))
1218         return FALSE;
1219
1220     if (time > e.spamtime)
1221     {
1222         e.spamtime = time;
1223         sound(e, chan, samp, vol, atten);
1224         return TRUE;
1225     }
1226     return FALSE;
1227 }
1228
1229 void play2team(float t, string filename)
1230 {
1231     entity head;
1232
1233     if (autocvar_bot_sound_monopoly)
1234         return;
1235
1236     FOR_EACH_REALPLAYER(head)
1237     {
1238         if (head.team == t)
1239             play2(head, filename);
1240     }
1241 }
1242
1243 void play2all(string samp)
1244 {
1245     if (autocvar_bot_sound_monopoly)
1246         return;
1247
1248     sound(world, CH_INFO, samp, VOL_BASE, ATTEN_NONE);
1249 }
1250
1251 void PrecachePlayerSounds(string f);
1252 void precache_playermodel(string m)
1253 {
1254         float globhandle, i, n;
1255         string f;
1256
1257         if(substring(m, -9,5) == "_lod1")
1258                 return;
1259         if(substring(m, -9,5) == "_lod2")
1260                 return;
1261         precache_model(m);
1262         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1263         if(fexists(f))
1264                 precache_model(f);
1265         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1266         if(fexists(f))
1267                 precache_model(f);
1268
1269         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1270         if (globhandle < 0)
1271                 return;
1272         n = search_getsize(globhandle);
1273         for (i = 0; i < n; ++i)
1274         {
1275                 //print(search_getfilename(globhandle, i), "\n");
1276                 f = search_getfilename(globhandle, i);
1277                 PrecachePlayerSounds(f);
1278         }
1279         search_end(globhandle);
1280 }
1281 void precache_all_playermodels(string pattern)
1282 {
1283         float globhandle, i, n;
1284         string f;
1285
1286         globhandle = search_begin(pattern, TRUE, FALSE);
1287         if (globhandle < 0)
1288                 return;
1289         n = search_getsize(globhandle);
1290         for (i = 0; i < n; ++i)
1291         {
1292                 //print(search_getfilename(globhandle, i), "\n");
1293                 f = search_getfilename(globhandle, i);
1294                 precache_playermodel(f);
1295         }
1296         search_end(globhandle);
1297 }
1298
1299 void precache()
1300 {
1301     // gamemode related things
1302     precache_model ("models/misc/chatbubble.spr");
1303
1304 #ifdef TTURRETS_ENABLED
1305     if (autocvar_g_turrets)
1306         turrets_precash();
1307 #endif
1308
1309     // Precache all player models if desired
1310     if (autocvar_sv_precacheplayermodels)
1311     {
1312         PrecachePlayerSounds("sound/player/default.sounds");
1313         precache_all_playermodels("models/player/*.zym");
1314         precache_all_playermodels("models/player/*.dpm");
1315         precache_all_playermodels("models/player/*.md3");
1316         precache_all_playermodels("models/player/*.psk");
1317         precache_all_playermodels("models/player/*.iqm");
1318     }
1319
1320     if (autocvar_sv_defaultcharacter)
1321     {
1322         string s;
1323         s = autocvar_sv_defaultplayermodel_red;
1324         if (s != "")
1325             precache_playermodel(s);
1326         s = autocvar_sv_defaultplayermodel_blue;
1327         if (s != "")
1328             precache_playermodel(s);
1329         s = autocvar_sv_defaultplayermodel_yellow;
1330         if (s != "")
1331             precache_playermodel(s);
1332         s = autocvar_sv_defaultplayermodel_pink;
1333         if (s != "")
1334             precache_playermodel(s);
1335         s = autocvar_sv_defaultplayermodel;
1336         if (s != "")
1337             precache_playermodel(s);
1338     }
1339
1340     if (g_footsteps)
1341     {
1342         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1343         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1344     }
1345
1346     // gore and miscellaneous sounds
1347     //precache_sound ("misc/h2ohit.wav");
1348     precache_model ("models/hook.md3");
1349     precache_sound ("misc/armorimpact.wav");
1350     precache_sound ("misc/bodyimpact1.wav");
1351     precache_sound ("misc/bodyimpact2.wav");
1352     precache_sound ("misc/gib.wav");
1353     precache_sound ("misc/gib_splat01.wav");
1354     precache_sound ("misc/gib_splat02.wav");
1355     precache_sound ("misc/gib_splat03.wav");
1356     precache_sound ("misc/gib_splat04.wav");
1357     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1358     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1359     precache_sound ("misc/null.wav");
1360     precache_sound ("misc/spawn.wav");
1361     precache_sound ("misc/talk.wav");
1362     precache_sound ("misc/teleport.wav");
1363     precache_sound ("misc/poweroff.wav");
1364     precache_sound ("player/lava.wav");
1365     precache_sound ("player/slime.wav");
1366
1367     precache_model ("models/sprites/0.spr32");
1368     precache_model ("models/sprites/1.spr32");
1369     precache_model ("models/sprites/2.spr32");
1370     precache_model ("models/sprites/3.spr32");
1371     precache_model ("models/sprites/4.spr32");
1372     precache_model ("models/sprites/5.spr32");
1373     precache_model ("models/sprites/6.spr32");
1374     precache_model ("models/sprites/7.spr32");
1375     precache_model ("models/sprites/8.spr32");
1376     precache_model ("models/sprites/9.spr32");
1377     precache_model ("models/sprites/10.spr32");
1378
1379     // common weapon precaches
1380         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1381     precache_sound ("weapons/weapon_switch.wav");
1382     precache_sound ("weapons/weaponpickup.wav");
1383     precache_sound ("weapons/unavailable.wav");
1384     precache_sound ("weapons/dryfire.wav");
1385     if (g_grappling_hook)
1386     {
1387         precache_sound ("weapons/hook_fire.wav"); // hook
1388         precache_sound ("weapons/hook_impact.wav"); // hook
1389     }
1390
1391     precache_model("models/elaser.mdl");
1392     precache_model("models/laser.mdl");
1393     precache_model("models/ebomb.mdl");
1394
1395 #if 0
1396     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1397
1398     if (!self.noise && self.music) // quake 3 uses the music field
1399         self.noise = self.music;
1400
1401     // plays music for the level if there is any
1402     if (self.noise)
1403     {
1404         precache_sound (self.noise);
1405         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTEN_NONE);
1406     }
1407 #endif
1408
1409 #include "precache-for-csqc.inc"
1410 }
1411
1412 // WARNING: this kills the trace globals
1413 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1414 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1415
1416 #define INITPRIO_FIRST              0
1417 #define INITPRIO_GAMETYPE           0
1418 #define INITPRIO_GAMETYPE_FALLBACK  1
1419 #define INITPRIO_FINDTARGET        10
1420 #define INITPRIO_DROPTOFLOOR       20
1421 #define INITPRIO_SETLOCATION       90
1422 #define INITPRIO_LINKDOORS         91
1423 #define INITPRIO_LAST              99
1424
1425 .void(void) initialize_entity;
1426 .float initialize_entity_order;
1427 .entity initialize_entity_next;
1428 entity initialize_entity_first;
1429
1430 void make_safe_for_remove(entity e)
1431 {
1432     if (e.initialize_entity)
1433     {
1434         entity ent, prev = world;
1435         for (ent = initialize_entity_first; ent; )
1436         {
1437             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1438             {
1439                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1440                 // skip it in linked list
1441                 if (prev)
1442                 {
1443                     prev.initialize_entity_next = ent.initialize_entity_next;
1444                     ent = prev.initialize_entity_next;
1445                 }
1446                 else
1447                 {
1448                     initialize_entity_first = ent.initialize_entity_next;
1449                     ent = initialize_entity_first;
1450                 }
1451             }
1452             else
1453             {
1454                 prev = ent;
1455                 ent = ent.initialize_entity_next;
1456             }
1457         }
1458     }
1459 }
1460
1461 void objerror(string s)
1462 {
1463     make_safe_for_remove(self);
1464     builtin_objerror(s);
1465 }
1466
1467 .float remove_except_protected_forbidden;
1468 void remove_except_protected(entity e)
1469 {
1470         if(e.remove_except_protected_forbidden)
1471                 error("not allowed to remove this at this point");
1472         builtin_remove(e);
1473 }
1474
1475 void remove_unsafely(entity e)
1476 {
1477     if(e.classname == "spike")
1478         error("Removing spikes is forbidden (crylink bug), please report");
1479     builtin_remove(e);
1480 }
1481
1482 void remove_safely(entity e)
1483 {
1484     make_safe_for_remove(e);
1485     builtin_remove(e);
1486 }
1487
1488 void InitializeEntity(entity e, void(void) func, float order)
1489 {
1490     entity prev, cur;
1491
1492     if (!e || e.initialize_entity)
1493     {
1494         // make a proxy initializer entity
1495         entity e_old;
1496         e_old = e;
1497         e = spawn();
1498         e.classname = "initialize_entity";
1499         e.enemy = e_old;
1500     }
1501
1502     e.initialize_entity = func;
1503     e.initialize_entity_order = order;
1504
1505     cur = initialize_entity_first;
1506     prev = world;
1507     for (;;)
1508     {
1509         if (!cur || cur.initialize_entity_order > order)
1510         {
1511             // insert between prev and cur
1512             if (prev)
1513                 prev.initialize_entity_next = e;
1514             else
1515                 initialize_entity_first = e;
1516             e.initialize_entity_next = cur;
1517             return;
1518         }
1519         prev = cur;
1520         cur = cur.initialize_entity_next;
1521     }
1522 }
1523 void InitializeEntitiesRun()
1524 {
1525     entity startoflist;
1526     startoflist = initialize_entity_first;
1527     initialize_entity_first = world;
1528     remove = remove_except_protected;
1529     for (self = startoflist; self; self = self.initialize_entity_next)
1530     {
1531         self.remove_except_protected_forbidden = 1;
1532     }
1533     for (self = startoflist; self; )
1534     {
1535         entity e;
1536         var void(void) func;
1537         e = self.initialize_entity_next;
1538         func = self.initialize_entity;
1539         self.initialize_entity_order = 0;
1540         self.initialize_entity = func_null;
1541         self.initialize_entity_next = world;
1542         self.remove_except_protected_forbidden = 0;
1543         if (self.classname == "initialize_entity")
1544         {
1545             entity e_old;
1546             e_old = self.enemy;
1547             builtin_remove(self);
1548             self = e_old;
1549         }
1550         //dprint("Delayed initialization: ", self.classname, "\n");
1551         if(func)
1552             func();
1553         else
1554         {
1555             eprint(self);
1556             backtrace(strcat("Null function in: ", self.classname, "\n"));
1557         }
1558         self = e;
1559     }
1560     remove = remove_unsafely;
1561 }
1562
1563 .float uncustomizeentityforclient_set;
1564 .void(void) uncustomizeentityforclient;
1565 void UncustomizeEntitiesRun()
1566 {
1567     entity oldself;
1568     oldself = self;
1569     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1570         self.uncustomizeentityforclient();
1571     self = oldself;
1572 }
1573 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1574 {
1575     e.customizeentityforclient = customizer;
1576     e.uncustomizeentityforclient = uncustomizer;
1577     e.uncustomizeentityforclient_set = !!uncustomizer;
1578 }
1579
1580 .float nottargeted;
1581 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1582
1583 void() SUB_Remove;
1584 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1585 {
1586     vector mi, ma;
1587
1588     if (e.classname == "")
1589         e.classname = "net_linked";
1590
1591     if (e.model == "" || self.modelindex == 0)
1592     {
1593         mi = e.mins;
1594         ma = e.maxs;
1595         setmodel(e, "null");
1596         setsize(e, mi, ma);
1597     }
1598
1599     e.SendEntity = sendfunc;
1600     e.SendFlags = 0xFFFFFF;
1601
1602     if (!docull)
1603         e.effects |= EF_NODEPTHTEST;
1604
1605     if (dt)
1606     {
1607         e.nextthink = time + dt;
1608         e.think = SUB_Remove;
1609     }
1610 }
1611
1612 void adaptor_think2touch()
1613 {
1614     entity o;
1615     o = other;
1616     other = world;
1617     self.touch();
1618     other = o;
1619 }
1620
1621 void adaptor_think2use()
1622 {
1623     entity o, a;
1624     o = other;
1625     a = activator;
1626     activator = world;
1627     other = world;
1628     self.use();
1629     other = o;
1630     activator = a;
1631 }
1632
1633 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1634 {
1635         if(!(self.flags & FL_ONGROUND)) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1636                 self.projectiledeathtype |= HITTYPE_SPLASH;
1637         adaptor_think2use();
1638 }
1639
1640 // deferred dropping
1641 void DropToFloor_Handler()
1642 {
1643     builtin_droptofloor();
1644     self.dropped_origin = self.origin;
1645 }
1646
1647 void droptofloor()
1648 {
1649     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1650 }
1651
1652
1653
1654 float trace_hits_box_a0, trace_hits_box_a1;
1655
1656 float trace_hits_box_1d(float end, float thmi, float thma)
1657 {
1658     if (end == 0)
1659     {
1660         // just check if x is in range
1661         if (0 < thmi)
1662             return FALSE;
1663         if (0 > thma)
1664             return FALSE;
1665     }
1666     else
1667     {
1668         // do the trace with respect to x
1669         // 0 -> end has to stay in thmi -> thma
1670         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1671         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1672         if (trace_hits_box_a0 > trace_hits_box_a1)
1673             return FALSE;
1674     }
1675     return TRUE;
1676 }
1677
1678 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1679 {
1680     end -= start;
1681     thmi -= start;
1682     thma -= start;
1683     // now it is a trace from 0 to end
1684
1685     trace_hits_box_a0 = 0;
1686     trace_hits_box_a1 = 1;
1687
1688     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1689         return FALSE;
1690     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1691         return FALSE;
1692     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1693         return FALSE;
1694
1695     return TRUE;
1696 }
1697
1698 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1699 {
1700     return trace_hits_box(start, end, thmi - ma, thma - mi);
1701 }
1702
1703 float SUB_NoImpactCheck()
1704 {
1705         // zero hitcontents = this is not the real impact, but either the
1706         // mirror-impact of something hitting the projectile instead of the
1707         // projectile hitting the something, or a touchareagrid one. Neither of
1708         // these stop the projectile from moving, so...
1709         if(trace_dphitcontents == 0)
1710         {
1711                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1712                 dprint(sprintf("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n", num_for_edict(self), self.classname, vtos(self.origin)));
1713                 checkclient();
1714         }
1715     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1716         return 1;
1717     if (other == world && self.size != '0 0 0')
1718     {
1719         vector tic;
1720         tic = self.velocity * sys_frametime;
1721         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1722         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1723         if (trace_fraction >= 1)
1724         {
1725             dprint("Odd... did not hit...?\n");
1726         }
1727         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1728         {
1729             dprint("Detected and prevented the sky-grapple bug.\n");
1730             return 1;
1731         }
1732     }
1733
1734     return 0;
1735 }
1736
1737 #define SUB_OwnerCheck() (other && (other == self.owner))
1738
1739 void RemoveGrapplingHook(entity pl);
1740 void W_Crylink_Dequeue(entity e);
1741 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1742 {
1743         if(SUB_OwnerCheck())
1744                 return TRUE;
1745         if(SUB_NoImpactCheck())
1746         {
1747                 if(self.classname == "grapplinghook")
1748                         RemoveGrapplingHook(self.realowner);
1749                 else if(self.classname == "spike")
1750                 {
1751                         W_Crylink_Dequeue(self);
1752                         remove(self);
1753                 }
1754                 else
1755                         remove(self);
1756                 return TRUE;
1757         }
1758         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1759                 UpdateCSQCProjectile(self);
1760         return FALSE;
1761 }
1762 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1763
1764 #define ITEM_TOUCH_NEEDKILL() (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
1765 #define ITEM_DAMAGE_NEEDKILL(dt) (((dt) == DEATH_HURTTRIGGER) || ((dt) == DEATH_SLIME) || ((dt) == DEATH_LAVA) || ((dt) == DEATH_SWAMP))
1766
1767 void URI_Get_Callback(float id, float status, string data)
1768 {
1769         if(url_URI_Get_Callback(id, status, data))
1770         {
1771                 // handled
1772         }
1773         else if (id == URI_GET_DISCARD)
1774         {
1775                 // discard
1776         }
1777         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1778         {
1779                 // sv_cmd curl
1780                 Curl_URI_Get_Callback(id, status, data);
1781         }
1782         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1783         {
1784                 // online ban list
1785                 OnlineBanList_URI_Get_Callback(id, status, data);
1786         }
1787         else
1788         {
1789                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1790         }
1791 }
1792
1793 string uid2name(string myuid) {
1794         string s;
1795         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1796
1797         // FIXME remove this later after 0.6 release
1798         // convert old style broken records to correct style
1799         if(s == "")
1800         {
1801                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1802                 if(s != "")
1803                 {
1804                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1805                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
1806                 }
1807         }
1808
1809         if(s == "")
1810                 s = "^1Unregistered Player";
1811         return s;
1812 }
1813
1814 float race_readTime(string map, float pos)
1815 {
1816         string rr;
1817         if(g_cts)
1818                 rr = CTS_RECORD;
1819         else
1820                 rr = RACE_RECORD;
1821
1822         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
1823 }
1824
1825 string race_readUID(string map, float pos)
1826 {
1827         string rr;
1828         if(g_cts)
1829                 rr = CTS_RECORD;
1830         else
1831                 rr = RACE_RECORD;
1832
1833         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
1834 }
1835
1836 float race_readPos(string map, float t) {
1837         float i;
1838         for (i = 1; i <= RANKINGS_CNT; ++i)
1839                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
1840                         return i;
1841
1842         return 0; // pos is zero if unranked
1843 }
1844
1845 void race_writeTime(string map, float t, string myuid)
1846 {
1847         string rr;
1848         if(g_cts)
1849                 rr = CTS_RECORD;
1850         else
1851                 rr = RACE_RECORD;
1852
1853         float newpos;
1854         newpos = race_readPos(map, t);
1855
1856         float i, prevpos = 0;
1857         for(i = 1; i <= RANKINGS_CNT; ++i)
1858         {
1859                 if(race_readUID(map, i) == myuid)
1860                         prevpos = i;
1861         }
1862         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
1863                 for (i = prevpos; i > newpos; --i) {
1864                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1865                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1866                 }
1867         } else { // player has no ranked record yet
1868                 for (i = RANKINGS_CNT; i > newpos; --i) {
1869                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1870                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1871                 }
1872         }
1873
1874         // store new time itself
1875         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
1876         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
1877 }
1878
1879 string race_readName(string map, float pos)
1880 {
1881         string rr;
1882         if(g_cts)
1883                 rr = CTS_RECORD;
1884         else
1885                 rr = RACE_RECORD;
1886
1887         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
1888 }
1889
1890 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1891 {
1892     float m, i;
1893     vector start, org, delta, end, enddown, mstart;
1894     entity sp;
1895
1896     m = e.dphitcontentsmask;
1897     e.dphitcontentsmask = goodcontents | badcontents;
1898
1899     org = world.mins;
1900     delta = world.maxs - world.mins;
1901
1902     start = end = org;
1903
1904     for (i = 0; i < attempts; ++i)
1905     {
1906         start_x = org_x + random() * delta_x;
1907         start_y = org_y + random() * delta_y;
1908         start_z = org_z + random() * delta_z;
1909
1910         // rule 1: start inside world bounds, and outside
1911         // solid, and don't start from somewhere where you can
1912         // fall down to evil
1913         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
1914         if (trace_fraction >= 1)
1915             continue;
1916         if (trace_startsolid)
1917             continue;
1918         if (trace_dphitcontents & badcontents)
1919             continue;
1920         if (trace_dphitq3surfaceflags & badsurfaceflags)
1921             continue;
1922
1923         // rule 2: if we are too high, lower the point
1924         if (trace_fraction * delta_z > maxaboveground)
1925             start = trace_endpos + '0 0 1' * maxaboveground;
1926         enddown = trace_endpos;
1927
1928         // rule 3: make sure we aren't outside the map. This only works
1929         // for somewhat well formed maps. A good rule of thumb is that
1930         // the map should have a convex outside hull.
1931         // these can be traceLINES as we already verified the starting box
1932         mstart = start + 0.5 * (e.mins + e.maxs);
1933         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
1934         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1935             continue;
1936         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
1937         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1938             continue;
1939         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
1940         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1941             continue;
1942         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
1943         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1944             continue;
1945         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
1946         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1947             continue;
1948
1949         // rule 4: we must "see" some spawnpoint or item
1950         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
1951                 if(checkpvs(mstart, sp))
1952                         if((traceline(mstart, sp.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1953                                 break;
1954         if(!sp)
1955         {
1956                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
1957                         if(checkpvs(mstart, sp))
1958                                 if((traceline(mstart, sp.origin + (sp.mins + sp.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1959                                         break;
1960                 if(!sp)
1961                         continue;
1962         }
1963
1964         // find a random vector to "look at"
1965         end_x = org_x + random() * delta_x;
1966         end_y = org_y + random() * delta_y;
1967         end_z = org_z + random() * delta_z;
1968         end = start + normalize(end - start) * vlen(delta);
1969
1970         // rule 4: start TO end must not be too short
1971         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1972         if (trace_startsolid)
1973             continue;
1974         if (trace_fraction < minviewdistance / vlen(delta))
1975             continue;
1976
1977         // rule 5: don't want to look at sky
1978         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1979             continue;
1980
1981         // rule 6: we must not end up in trigger_hurt
1982         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1983             continue;
1984
1985         break;
1986     }
1987
1988     e.dphitcontentsmask = m;
1989
1990     if (i < attempts)
1991     {
1992         setorigin(e, start);
1993         e.angles = vectoangles(end - start);
1994         dprint("Needed ", ftos(i + 1), " attempts\n");
1995         return TRUE;
1996     }
1997     else
1998         return FALSE;
1999 }
2000
2001 float zcurveparticles_effectno;
2002 vector zcurveparticles_start;
2003 float zcurveparticles_spd;
2004
2005 void endzcurveparticles()
2006 {
2007         if(zcurveparticles_effectno)
2008         {
2009                 // terminator
2010                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2011         }
2012         zcurveparticles_effectno = 0;
2013 }
2014
2015 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2016 {
2017         spd = bound(0, floor(spd / 16), 32767);
2018         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2019         {
2020                 endzcurveparticles();
2021                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2022                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2023                 WriteShort(MSG_BROADCAST, effectno);
2024                 WriteCoord(MSG_BROADCAST, start_x);
2025                 WriteCoord(MSG_BROADCAST, start_y);
2026                 WriteCoord(MSG_BROADCAST, start_z);
2027                 zcurveparticles_effectno = effectno;
2028                 zcurveparticles_start = start;
2029         }
2030         else
2031                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2032         WriteCoord(MSG_BROADCAST, end_x);
2033         WriteCoord(MSG_BROADCAST, end_y);
2034         WriteCoord(MSG_BROADCAST, end_z);
2035         WriteCoord(MSG_BROADCAST, end_dz);
2036         zcurveparticles_spd = spd;
2037 }
2038
2039 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2040 {
2041         float end_dz;
2042         vector vecxy, velxy;
2043
2044         vecxy = end - start;
2045         vecxy_z = 0;
2046         velxy = vel;
2047         velxy_z = 0;
2048
2049         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2050         {
2051                 endzcurveparticles();
2052                 trailparticles(world, effectno, start, end);
2053                 return;
2054         }
2055
2056         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2057         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2058 }
2059
2060 void write_recordmarker(entity pl, float tstart, float dt)
2061 {
2062     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2063
2064     // also write a marker into demo files for demotc-race-record-extractor to find
2065     stuffcmd(pl,
2066              strcat(
2067                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2068                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2069 }
2070
2071 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2072 {
2073         switch(algn)
2074         {
2075                 default:
2076                 case 3: // right
2077                         break;
2078
2079                 case 4: // left
2080                         vecs_y = -vecs_y;
2081                         break;
2082
2083                 case 1:
2084                         if(allowcenter) // 2: allow center handedness
2085                         {
2086                                 // center
2087                                 vecs_y = 0;
2088                                 vecs_z -= 2;
2089                         }
2090                         else
2091                         {
2092                                 // right
2093                         }
2094                         break;
2095
2096                 case 2:
2097                         if(allowcenter) // 2: allow center handedness
2098                         {
2099                                 // center
2100                                 vecs_y = 0;
2101                                 vecs_z -= 2;
2102                         }
2103                         else
2104                         {
2105                                 // left
2106                                 vecs_y = -vecs_y;
2107                         }
2108                         break;
2109         }
2110         return vecs;
2111 }
2112
2113 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2114 {
2115         string s;
2116         vector v;
2117
2118         if (autocvar_g_shootfromeye)
2119         {
2120                 if (visual)
2121                 {
2122                         if (autocvar_g_shootfromclient) { vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn); }
2123                         else { vecs_y = 0; vecs_z -= 2; }
2124                 }
2125                 else
2126                 {
2127                         vecs_y = 0;
2128                         vecs_z = 0;
2129                 }
2130         }
2131         else if (autocvar_g_shootfromcenter)
2132         {
2133                 vecs_y = 0;
2134                 vecs_z -= 2;
2135         }
2136         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2137         {
2138                 v = stov(s);
2139                 if (y_is_right)
2140                         v_y = -v_y;
2141                 if (v_x != 0)
2142                         vecs_x = v_x;
2143                 vecs_y = v_y;
2144                 vecs_z = v_z;
2145         }
2146         else if (autocvar_g_shootfromclient)
2147         {
2148                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2149         }
2150         return vecs;
2151 }
2152
2153 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2154 {
2155         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2156 }
2157
2158
2159 void attach_sameorigin(entity e, entity to, string tag)
2160 {
2161     vector org, t_forward, t_left, t_up, e_forward, e_up;
2162     float tagscale;
2163
2164     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2165     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2166     t_forward = v_forward * tagscale;
2167     t_left = v_right * -tagscale;
2168     t_up = v_up * tagscale;
2169
2170     e.origin_x = org * t_forward;
2171     e.origin_y = org * t_left;
2172     e.origin_z = org * t_up;
2173
2174     // current forward and up directions
2175     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2176                 e.angles = AnglesTransform_FromVAngles(e.angles);
2177         else
2178                 e.angles = AnglesTransform_FromAngles(e.angles);
2179     fixedmakevectors(e.angles);
2180
2181     // untransform forward, up!
2182     e_forward_x = v_forward * t_forward;
2183     e_forward_y = v_forward * t_left;
2184     e_forward_z = v_forward * t_up;
2185     e_up_x = v_up * t_forward;
2186     e_up_y = v_up * t_left;
2187     e_up_z = v_up * t_up;
2188
2189     e.angles = fixedvectoangles2(e_forward, e_up);
2190     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2191                 e.angles = AnglesTransform_ToVAngles(e.angles);
2192         else
2193                 e.angles = AnglesTransform_ToAngles(e.angles);
2194
2195     setattachment(e, to, tag);
2196     setorigin(e, e.origin);
2197 }
2198
2199 void detach_sameorigin(entity e)
2200 {
2201     vector org;
2202     org = gettaginfo(e, 0);
2203     e.angles = fixedvectoangles2(v_forward, v_up);
2204     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2205                 e.angles = AnglesTransform_ToVAngles(e.angles);
2206         else
2207                 e.angles = AnglesTransform_ToAngles(e.angles);
2208     setorigin(e, org);
2209     setattachment(e, world, "");
2210     setorigin(e, e.origin);
2211 }
2212
2213 void follow_sameorigin(entity e, entity to)
2214 {
2215     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2216     e.aiment = to; // make the hole follow bmodel
2217     e.punchangle = to.angles; // the original angles of bmodel
2218     e.view_ofs = e.origin - to.origin; // relative origin
2219     e.v_angle = e.angles - to.angles; // relative angles
2220 }
2221
2222 void unfollow_sameorigin(entity e)
2223 {
2224     e.movetype = MOVETYPE_NONE;
2225 }
2226
2227 entity gettaginfo_relative_ent;
2228 vector gettaginfo_relative(entity e, float tag)
2229 {
2230     if (!gettaginfo_relative_ent)
2231     {
2232         gettaginfo_relative_ent = spawn();
2233         gettaginfo_relative_ent.effects = EF_NODRAW;
2234     }
2235     gettaginfo_relative_ent.model = e.model;
2236     gettaginfo_relative_ent.modelindex = e.modelindex;
2237     gettaginfo_relative_ent.frame = e.frame;
2238     return gettaginfo(gettaginfo_relative_ent, tag);
2239 }
2240
2241 .float scale2;
2242
2243 float modeleffect_SendEntity(entity to, float sf)
2244 {
2245         float f;
2246         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2247
2248         f = 0;
2249         if(self.velocity != '0 0 0')
2250                 f |= 1;
2251         if(self.angles != '0 0 0')
2252                 f |= 2;
2253         if(self.avelocity != '0 0 0')
2254                 f |= 4;
2255
2256         WriteByte(MSG_ENTITY, f);
2257         WriteShort(MSG_ENTITY, self.modelindex);
2258         WriteByte(MSG_ENTITY, self.skin);
2259         WriteByte(MSG_ENTITY, self.frame);
2260         WriteCoord(MSG_ENTITY, self.origin_x);
2261         WriteCoord(MSG_ENTITY, self.origin_y);
2262         WriteCoord(MSG_ENTITY, self.origin_z);
2263         if(f & 1)
2264         {
2265                 WriteCoord(MSG_ENTITY, self.velocity_x);
2266                 WriteCoord(MSG_ENTITY, self.velocity_y);
2267                 WriteCoord(MSG_ENTITY, self.velocity_z);
2268         }
2269         if(f & 2)
2270         {
2271                 WriteCoord(MSG_ENTITY, self.angles_x);
2272                 WriteCoord(MSG_ENTITY, self.angles_y);
2273                 WriteCoord(MSG_ENTITY, self.angles_z);
2274         }
2275         if(f & 4)
2276         {
2277                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2278                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2279                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2280         }
2281         WriteShort(MSG_ENTITY, self.scale * 256.0);
2282         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2283         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2284         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2285         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2286
2287         return TRUE;
2288 }
2289
2290 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2291 {
2292         entity e;
2293         float sz;
2294         e = spawn();
2295         e.classname = "modeleffect";
2296         setmodel(e, m);
2297         e.frame = f;
2298         setorigin(e, o);
2299         e.velocity = v;
2300         e.angles = ang;
2301         e.avelocity = angv;
2302         e.alpha = a;
2303         e.teleport_time = t1;
2304         e.fade_time = t2;
2305         e.skin = s;
2306         if(s0 >= 0)
2307                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2308         else
2309                 e.scale = -s0;
2310         if(s2 >= 0)
2311                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2312         else
2313                 e.scale2 = -s2;
2314         sz = max(e.scale, e.scale2);
2315         setsize(e, e.mins * sz, e.maxs * sz);
2316         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2317 }
2318
2319 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2320 {
2321         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2322 }
2323
2324 float randombit(float bits)
2325 {
2326         if(!(bits & (bits-1))) // this ONLY holds for powers of two!
2327                 return bits;
2328
2329         float n, f, b, r;
2330
2331         r = random();
2332         b = 0;
2333         n = 0;
2334
2335         for(f = 1; f <= bits; f *= 2)
2336         {
2337                 if(bits & f)
2338                 {
2339                         ++n;
2340                         r *= n;
2341                         if(r <= 1)
2342                                 b = f;
2343                         else
2344                                 r = (r - 1) / (n - 1);
2345                 }
2346         }
2347
2348         return b;
2349 }
2350
2351 float randombits(float bits, float k, float error_return)
2352 {
2353         float r;
2354         r = 0;
2355         while(k > 0 && bits != r)
2356         {
2357                 r += randombit(bits - r);
2358                 --k;
2359         }
2360         if(error_return)
2361                 if(k > 0)
2362                         return -1; // all
2363         return r;
2364 }
2365
2366 void randombit_test(float bits, float iter)
2367 {
2368         while(iter > 0)
2369         {
2370                 print(ftos(randombit(bits)), "\n");
2371                 --iter;
2372         }
2373 }
2374
2375 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2376 {
2377         if(halflifedist > 0)
2378                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2379         else if(halflifedist < 0)
2380                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2381         else
2382                 return 1;
2383 }
2384
2385
2386
2387
2388 #ifdef RELEASE
2389 #define cvar_string_normal builtin_cvar_string
2390 #define cvar_normal builtin_cvar
2391 #else
2392 string cvar_string_normal(string n)
2393 {
2394         if (!(cvar_type(n) & 1))
2395                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2396         return builtin_cvar_string(n);
2397 }
2398
2399 float cvar_normal(string n)
2400 {
2401         return stof(cvar_string_normal(n));
2402 }
2403 #endif
2404 #define cvar_set_normal builtin_cvar_set
2405
2406 void defer_think()
2407 {
2408     entity oself;
2409
2410     oself           = self;
2411     self            = self.owner;
2412     oself.think     = SUB_Remove;
2413     oself.nextthink = time;
2414
2415     oself.use();
2416 }
2417
2418 /*
2419     Execute func() after time + fdelay.
2420     self when func is executed = self when defer is called
2421 */
2422 void defer(float fdelay, void() func)
2423 {
2424     entity e;
2425
2426     e           = spawn();
2427     e.owner     = self;
2428     e.use       = func;
2429     e.think     = defer_think;
2430     e.nextthink = time + fdelay;
2431 }
2432
2433 .string aiment_classname;
2434 .float aiment_deadflag;
2435 void SetMovetypeFollow(entity ent, entity e)
2436 {
2437         // FIXME this may not be warpzone aware
2438         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2439         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2440         ent.aiment = e; // make the hole follow bmodel
2441         ent.punchangle = e.angles; // the original angles of bmodel
2442         ent.view_ofs = ent.origin - e.origin; // relative origin
2443         ent.v_angle = ent.angles - e.angles; // relative angles
2444         ent.aiment_classname = strzone(e.classname);
2445         ent.aiment_deadflag = e.deadflag;
2446 }
2447 void UnsetMovetypeFollow(entity ent)
2448 {
2449         ent.movetype = MOVETYPE_FLY;
2450         PROJECTILE_MAKETRIGGER(ent);
2451         ent.aiment = world;
2452 }
2453 float LostMovetypeFollow(entity ent)
2454 {
2455 /*
2456         if(ent.movetype != MOVETYPE_FOLLOW)
2457                 if(ent.aiment)
2458                         error("???");
2459 */
2460         if(ent.aiment)
2461         {
2462                 if(ent.aiment.classname != ent.aiment_classname)
2463                         return 1;
2464                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2465                         return 1;
2466         }
2467         return 0;
2468 }
2469
2470 float isPushable(entity e)
2471 {
2472         if(e.iscreature)
2473                 return TRUE;
2474         if(e.pushable)
2475                 return TRUE;
2476         switch(e.classname)
2477         {
2478                 case "body":
2479                 case "droppedweapon":
2480                 case "keepawayball":
2481                 case "nexball_basketball":
2482                 case "nexball_football":
2483                         return TRUE;
2484                 case "bullet": // antilagged bullets can't hit this either
2485                         return FALSE;
2486         }
2487         if (e.projectiledeathtype)
2488                 return TRUE;
2489         return FALSE;
2490 }