qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void crosshair_trace_plusvisibletriggers(entity pl)
  12 {
  13         entity first;
  14         entity e;
  15         first = findchainfloat(solid, SOLID_TRIGGER);
  16
  17         for (e = first; e; e = e.chain)
  18                 if (e.model != "")
  19                         e.solid = SOLID_BSP;
  20
  21         crosshair_trace(pl);
  22
  23         for (e = first; e; e = e.chain)
  24                 e.solid = SOLID_TRIGGER;
  25 }
  26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  27 void WarpZone_crosshair_trace(entity pl)
  28 {
  29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  30 }
  31
  32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  33 void() spawnpoint_use;
  34 string GetMapname();
  35
  36 string admin_name(void)
  37 {
  38         if(autocvar_sv_adminnick != "")
  39                 return autocvar_sv_adminnick;
  40         else
  41                 return "SERVER ADMIN";
  42 }
  43
  44 float DistributeEvenly_amount;
  45 float DistributeEvenly_totalweight;
  46 void DistributeEvenly_Init(float amount, float totalweight)
  47 {
  48     if (DistributeEvenly_amount)
  49     {
  50         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  51         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  52     }
  53     if (totalweight == 0)
  54         DistributeEvenly_amount = 0;
  55     else
  56         DistributeEvenly_amount = amount;
  57     DistributeEvenly_totalweight = totalweight;
  58 }
  59 float DistributeEvenly_Get(float weight)
  60 {
  61     float f;
  62     if (weight <= 0)
  63         return 0;
  64     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  65     DistributeEvenly_totalweight -= weight;
  66     DistributeEvenly_amount -= f;
  67     return f;
  68 }
  69 float DistributeEvenly_GetRandomized(float weight)
  70 {
  71     float f;
  72     if (weight <= 0)
  73         return 0;
  74     f = floor(random() + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  75     DistributeEvenly_totalweight -= weight;
  76     DistributeEvenly_amount -= f;
  77     return f;
  78 }
  79
  80 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  81
  82 string STR_PLAYER = "player";
  83 string STR_SPECTATOR = "spectator";
  84 string STR_OBSERVER = "observer";
  85
  86 #define IS_PLAYER(v)                    (v.classname == STR_PLAYER)
  87 #define IS_SPEC(v)                              (v.classname == STR_SPECTATOR)
  88 #define IS_OBSERVER(v)                  (v.classname == STR_OBSERVER)
  89 #define IS_CLIENT(v)                    (v.flags & FL_CLIENT)
  90 #define IS_BOT_CLIENT(v)                (clienttype(v) == CLIENTTYPE_BOT)
  91 #define IS_REAL_CLIENT(v)               (clienttype(v) == CLIENTTYPE_REAL)
  92 #define IS_NOT_A_CLIENT(v)              (clienttype(v) == CLIENTTYPE_NOTACLIENT)
  93
  94 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  95 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(IS_CLIENT(v))
  96 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(IS_REAL_CLIENT(v))
  97
  98 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(IS_PLAYER(v))
  99 #define FOR_EACH_SPEC(v) FOR_EACH_CLIENT(v) if not(IS_PLAYER(v)) // Samual: shouldn't this be IS_SPEC(v)? and rather create a separate macro to include observers too
 100 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(IS_PLAYER(v))
 101
 102 #define FOR_EACH_MONSTER(v) for(v = world; (v = findflags(v, flags, FL_MONSTER)) != world; )
 103
 104 #define CENTER_OR_VIEWOFS(ent) (ent.origin + (IS_PLAYER(ent) ? ent.view_ofs : ((ent.mins + ent.maxs) * 0.5)))
 105
 106 // copies a string to a tempstring (so one can strunzone it)
 107 string strcat1(string s) = #115; // FRIK_FILE
 108
 109 float logfile_open;
 110 float logfile;
 111
 112 void GameLogEcho(string s)
 113 {
 114     string fn;
 115     float matches;
 116
 117     if (autocvar_sv_eventlog_files)
 118     {
 119         if (!logfile_open)
 120         {
 121             logfile_open = TRUE;
 122             matches = autocvar_sv_eventlog_files_counter + 1;
 123             cvar_set("sv_eventlog_files_counter", ftos(matches));
 124             fn = ftos(matches);
 125             if (strlen(fn) < 8)
 126                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 127             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 128             logfile = fopen(fn, FILE_APPEND);
 129             fputs(logfile, ":logversion:3\n");
 130         }
 131         if (logfile >= 0)
 132         {
 133             if (autocvar_sv_eventlog_files_timestamps)
 134                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 135             else
 136                 fputs(logfile, strcat(s, "\n"));
 137         }
 138     }
 139     if (autocvar_sv_eventlog_console)
 140     {
 141         print(s, "\n");
 142     }
 143 }
 144
 145 void GameLogInit()
 146 {
 147     logfile_open = 0;
 148     // will be opened later
 149 }
 150
 151 void GameLogClose()
 152 {
 153     if (logfile_open && logfile >= 0)
 154     {
 155         fclose(logfile);
 156         logfile = -1;
 157     }
 158 }
 159
 160 float spawnpoint_nag;
 161 void relocate_spawnpoint()
 162 {
 163     // nudge off the floor
 164     setorigin(self, self.origin + '0 0 1');
 165
 166     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 167     if (trace_startsolid)
 168     {
 169         vector o;
 170         o = self.origin;
 171         self.mins = PL_MIN;
 172         self.maxs = PL_MAX;
 173         if (!move_out_of_solid(self))
 174             objerror("could not get out of solid at all!");
 175         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 176         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 177         print(" ", ftos(self.origin_y - o_y));
 178         print(" ", ftos(self.origin_z - o_z), "'\n");
 179         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
 180         {
 181             if (!spawnpoint_nag)
 182                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 183             spawnpoint_nag = 1;
 184         }
 185         else
 186         {
 187             setorigin(self, o);
 188             self.mins = self.maxs = '0 0 0';
 189             objerror("player spawn point in solid, mapper sucks!\n");
 190             return;
 191         }
 192     }
 193
 194     self.use = spawnpoint_use;
 195     self.team_saved = self.team;
 196     if (!self.cnt)
 197         self.cnt = 1;
 198
 199     if (have_team_spawns != 0)
 200         if (self.team)
 201             have_team_spawns = 1;
 202     have_team_spawns_forteam[self.team] = 1;
 203
 204     if (autocvar_r_showbboxes)
 205     {
 206         // show where spawnpoints point at too
 207         makevectors(self.angles);
 208         entity e;
 209         e = spawn();
 210         e.classname = "info_player_foo";
 211         setorigin(e, self.origin + v_forward * 24);
 212         setsize(e, '-8 -8 -8', '8 8 8');
 213         e.solid = SOLID_TRIGGER;
 214     }
 215 }
 216
 217 #define strstr strstrofs
 218 /*
 219 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 220 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 221 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 222 // BE CONSTANT OR strzoneD!
 223 float strstr(string haystack, string needle, float offset)
 224 {
 225         float len, endpos;
 226         string found;
 227         len = strlen(needle);
 228         endpos = strlen(haystack) - len;
 229         while(offset <= endpos)
 230         {
 231                 found = substring(haystack, offset, len);
 232                 if(found == needle)
 233                         return offset;
 234                 offset = offset + 1;
 235         }
 236         return -1;
 237 }
 238 */
 239
 240 float NUM_NEAREST_ENTITIES = 4;
 241 entity nearest_entity[NUM_NEAREST_ENTITIES];
 242 float nearest_length[NUM_NEAREST_ENTITIES];
 243 entity findnearest(vector point, .string field, string value, vector axismod)
 244 {
 245     entity localhead;
 246     float i;
 247     float j;
 248     float len;
 249     vector dist;
 250
 251     float num_nearest;
 252     num_nearest = 0;
 253
 254     localhead = find(world, field, value);
 255     while (localhead)
 256     {
 257         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 258             dist = localhead.oldorigin;
 259         else
 260             dist = localhead.origin;
 261         dist = dist - point;
 262         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 263         len = vlen(dist);
 264
 265         for (i = 0; i < num_nearest; ++i)
 266         {
 267             if (len < nearest_length[i])
 268                 break;
 269         }
 270
 271         // now i tells us where to insert at
 272         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 273         if (i < NUM_NEAREST_ENTITIES)
 274         {
 275             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 276             {
 277                 nearest_length[j + 1] = nearest_length[j];
 278                 nearest_entity[j + 1] = nearest_entity[j];
 279             }
 280             nearest_length[i] = len;
 281             nearest_entity[i] = localhead;
 282             if (num_nearest < NUM_NEAREST_ENTITIES)
 283                 num_nearest = num_nearest + 1;
 284         }
 285
 286         localhead = find(localhead, field, value);
 287     }
 288
 289     // now use the first one from our list that we can see
 290     for (i = 0; i < num_nearest; ++i)
 291     {
 292         traceline(point, nearest_entity[i].origin, TRUE, world);
 293         if (trace_fraction == 1)
 294         {
 295             if (i != 0)
 296             {
 297                 dprint("Nearest point (");
 298                 dprint(nearest_entity[0].netname);
 299                 dprint(") is not visible, using a visible one.\n");
 300             }
 301             return nearest_entity[i];
 302         }
 303     }
 304
 305     if (num_nearest == 0)
 306         return world;
 307
 308     dprint("Not seeing any location point, using nearest as fallback.\n");
 309     /* DEBUGGING CODE:
 310     dprint("Candidates were: ");
 311     for(j = 0; j < num_nearest; ++j)
 312     {
 313         if(j != 0)
 314                 dprint(", ");
 315         dprint(nearest_entity[j].netname);
 316     }
 317     dprint("\n");
 318     */
 319
 320     return nearest_entity[0];
 321 }
 322
 323 void spawnfunc_target_location()
 324 {
 325     self.classname = "target_location";
 326     // location name in netname
 327     // eventually support: count, teamgame selectors, line of sight?
 328 }
 329
 330 void spawnfunc_info_location()
 331 {
 332     self.classname = "target_location";
 333     self.message = self.netname;
 334 }
 335
 336 string NearestLocation(vector p)
 337 {
 338     entity loc;
 339     string ret;
 340     ret = "somewhere";
 341     loc = findnearest(p, classname, "target_location", '1 1 1');
 342     if (loc)
 343     {
 344         ret = loc.message;
 345     }
 346     else
 347     {
 348         loc = findnearest(p, target, "###item###", '1 1 4');
 349         if (loc)
 350             ret = loc.netname;
 351     }
 352     return ret;
 353 }
 354
 355 string formatmessage(string msg)
 356 {
 357         float p, p1, p2;
 358         float n;
 359         vector cursor;
 360         entity cursor_ent;
 361         string escape;
 362         string replacement;
 363         p = 0;
 364         n = 7;
 365
 366         WarpZone_crosshair_trace(self);
 367         cursor = trace_endpos;
 368         cursor_ent = trace_ent;
 369
 370         while (1) {
 371                 if (n < 1)
 372                         break; // too many replacements
 373
 374                 n = n - 1;
 375                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 376                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 377
 378                 if (p1 < 0)
 379                         p1 = p2;
 380
 381                 if (p2 < 0)
 382                         p2 = p1;
 383
 384                 p = min(p1, p2);
 385
 386                 if (p < 0)
 387                         break;
 388
 389                 replacement = substring(msg, p, 2);
 390                 escape = substring(msg, p + 1, 1);
 391
 392                 if (escape == "%")
 393                         replacement = "%";
 394                 else if (escape == "\\")
 395                         replacement = "\\";
 396                 else if (escape == "n")
 397                         replacement = "\n";
 398                 else if (escape == "a")
 399                         replacement = ftos(floor(self.armorvalue));
 400                 else if (escape == "h")
 401                         replacement = ftos(floor(self.health));
 402                 else if (escape == "l")
 403                         replacement = NearestLocation(self.origin);
 404                 else if (escape == "y")
 405                         replacement = NearestLocation(cursor);
 406                 else if (escape == "d")
 407                         replacement = NearestLocation(self.death_origin);
 408                 else if (escape == "w") {
 409                         float wep;
 410                         wep = self.weapon;
 411                         if (!wep)
 412                                 wep = self.switchweapon;
 413                         if (!wep)
 414                                 wep = self.cnt;
 415                         replacement = W_Name(wep);
 416                 } else if (escape == "W") {
 417                         if (self.items & IT_SHELLS) replacement = "shells";
 418                         else if (self.items & IT_NAILS) replacement = "bullets";
 419                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 420                         else if (self.items & IT_CELLS) replacement = "cells";
 421                         else replacement = "batteries"; // ;)
 422                 } else if (escape == "x") {
 423                         replacement = cursor_ent.netname;
 424                         if (replacement == "" || !cursor_ent)
 425                                 replacement = "nothing";
 426                 } else if (escape == "s")
 427                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 428                 else if (escape == "S")
 429                         replacement = ftos(vlen(self.velocity));
 430
 431                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 432                 p = p + strlen(replacement);
 433         }
 434         return msg;
 435 }
 436
 437 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 438         return (value == 0) ? FALSE : TRUE;
 439 }
 440
 441 /*
 442 =============
 443 GetCvars
 444 =============
 445 Called with:
 446   0:  sends the request
 447   >0: receives a cvar from name=argv(f) value=argv(f+1)
 448 */
 449 void GetCvars_handleString(string thisname, float f, .string field, string name)
 450 {
 451         if (f < 0)
 452         {
 453                 if (self.field)
 454                         strunzone(self.field);
 455                 self.field = string_null;
 456         }
 457         else if (f > 0)
 458         {
 459                 if (thisname == name)
 460                 {
 461                         if (self.field)
 462                                 strunzone(self.field);
 463                         self.field = strzone(argv(f + 1));
 464                 }
 465         }
 466         else
 467                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 468 }
 469 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 470 {
 471         GetCvars_handleString(thisname, f, field, name);
 472         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 473                 if (thisname == name)
 474                 {
 475                         string s;
 476                         s = func(strcat1(self.field));
 477                         if (s != self.field)
 478                         {
 479                                 strunzone(self.field);
 480                                 self.field = strzone(s);
 481                         }
 482                 }
 483 }
 484 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 485 {
 486         if (f < 0)
 487         {
 488         }
 489         else if (f > 0)
 490         {
 491                 if (thisname == name)
 492                         self.field = stof(argv(f + 1));
 493         }
 494         else
 495                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 496 }
 497 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 498 {
 499         if (f < 0)
 500         {
 501         }
 502         else if (f > 0)
 503         {
 504                 if (thisname == name)
 505                 {
 506                         if(!self.field)
 507                         {
 508                                 self.field = stof(argv(f + 1));
 509                                 if(!self.field)
 510                                         self.field = -1;
 511                         }
 512                 }
 513         }
 514         else
 515         {
 516                 if(!self.field)
 517                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 518         }
 519 }
 520 float w_getbestweapon(entity e);
 521 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 522 {
 523         string o;
 524         o = W_FixWeaponOrder_ForceComplete(wo);
 525         if(self.weaponorder_byimpulse)
 526         {
 527                 strunzone(self.weaponorder_byimpulse);
 528                 self.weaponorder_byimpulse = string_null;
 529         }
 530         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 531         return o;
 532 }
 533 void GetCvars(float f)
 534 {
 535         string s = string_null;
 536
 537         if (f > 0)
 538                 s = strcat1(argv(f));
 539
 540         get_cvars_f = f;
 541         get_cvars_s = s;
 542
 543         MUTATOR_CALLHOOK(GetCvars);
 544
 545         Notification_GetCvars();
 546
 547         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 548         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 549         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 550         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 551         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 552         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 553         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 554         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 555         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 556         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 557         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 558         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 559         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 560         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 561         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 562         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 563         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 564         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 565         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 566         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 567         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 568         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 569         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 570
 571         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 572         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 573
 574         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 575         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 576         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 577         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 578         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 579
 580         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 581         if (f > 0)
 582         {
 583                 if (s == "cl_weaponpriority")
 584                         self.switchweapon = w_getbestweapon(self);
 585                 if (s == "cl_allow_uidtracking")
 586                         PlayerStats_AddPlayer(self);
 587         }
 588 }
 589
 590 // decolorizes and team colors the player name when needed
 591 string playername(entity p)
 592 {
 593     string t;
 594     if (teamplay && !intermission_running && p.classname == "player")
 595     {
 596         t = Team_ColorCode(p.team);
 597         return strcat(t, strdecolorize(p.netname));
 598     }
 599     else
 600         return p.netname;
 601 }
 602
 603 vector randompos(vector m1, vector m2)
 604 {
 605     vector v;
 606     m2 = m2 - m1;
 607     v_x = m2_x * random() + m1_x;
 608     v_y = m2_y * random() + m1_y;
 609     v_z = m2_z * random() + m1_z;
 610     return  v;
 611 }
 612
 613 //#NO AUTOCVARS START
 614
 615 float g_pickup_shells;
 616 float g_pickup_shells_max;
 617 float g_pickup_nails;
 618 float g_pickup_nails_max;
 619 float g_pickup_rockets;
 620 float g_pickup_rockets_max;
 621 float g_pickup_cells;
 622 float g_pickup_cells_max;
 623 float g_pickup_fuel;
 624 float g_pickup_fuel_jetpack;
 625 float g_pickup_fuel_max;
 626 float g_pickup_armorsmall;
 627 float g_pickup_armorsmall_max;
 628 float g_pickup_armorsmall_anyway;
 629 float g_pickup_armormedium;
 630 float g_pickup_armormedium_max;
 631 float g_pickup_armormedium_anyway;
 632 float g_pickup_armorbig;
 633 float g_pickup_armorbig_max;
 634 float g_pickup_armorbig_anyway;
 635 float g_pickup_armorlarge;
 636 float g_pickup_armorlarge_max;
 637 float g_pickup_armorlarge_anyway;
 638 float g_pickup_healthsmall;
 639 float g_pickup_healthsmall_max;
 640 float g_pickup_healthsmall_anyway;
 641 float g_pickup_healthmedium;
 642 float g_pickup_healthmedium_max;
 643 float g_pickup_healthmedium_anyway;
 644 float g_pickup_healthlarge;
 645 float g_pickup_healthlarge_max;
 646 float g_pickup_healthlarge_anyway;
 647 float g_pickup_healthmega;
 648 float g_pickup_healthmega_max;
 649 float g_pickup_healthmega_anyway;
 650 float g_pickup_ammo_anyway;
 651 float g_pickup_weapons_anyway;
 652 float g_weaponarena;
 653 WEPSET_DECLARE_A(g_weaponarena_weapons);
 654 float g_weaponarena_random;
 655 float g_weaponarena_random_with_laser;
 656 string g_weaponarena_list;
 657 float g_weaponspeedfactor;
 658 float g_weaponratefactor;
 659 float g_weapondamagefactor;
 660 float g_weaponforcefactor;
 661 float g_weaponspreadfactor;
 662
 663 WEPSET_DECLARE_A(start_weapons);
 664 WEPSET_DECLARE_A(start_weapons_default);
 665 WEPSET_DECLARE_A(start_weapons_defaultmask);
 666 float start_items;
 667 float start_ammo_shells;
 668 float start_ammo_nails;
 669 float start_ammo_rockets;
 670 float start_ammo_cells;
 671 float start_ammo_fuel;
 672 float start_health;
 673 float start_armorvalue;
 674 WEPSET_DECLARE_A(warmup_start_weapons);
 675 WEPSET_DECLARE_A(warmup_start_weapons_default);
 676 WEPSET_DECLARE_A(warmup_start_weapons_defaultmask);
 677 float warmup_start_ammo_shells;
 678 float warmup_start_ammo_nails;
 679 float warmup_start_ammo_rockets;
 680 float warmup_start_ammo_cells;
 681 float warmup_start_ammo_fuel;
 682 float warmup_start_health;
 683 float warmup_start_armorvalue;
 684 float g_weapon_stay;
 685
 686 entity get_weaponinfo(float w);
 687
 688 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 689 {
 690         var float i = weaponinfo.weapon;
 691         var float d = 0;
 692
 693         if (!i)
 694                 return 0;
 695
 696         if (g_lms || g_ca || allguns)
 697         {
 698                 if(weaponinfo.spawnflags & WEP_FLAG_NORMAL)
 699                         d = TRUE;
 700                 else
 701                         d = FALSE;
 702         }
 703         else if (g_cts)
 704                 d = (i == WEP_SHOTGUN);
 705         else if (g_nexball)
 706                 d = 0; // weapon is set a few lines later
 707         else
 708                 d = (i == WEP_LASER || i == WEP_SHOTGUN);
 709
 710         if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 711                 d |= (i == WEP_HOOK);
 712         if(weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED) // never default mutator blocked guns
 713                 d = 0;
 714
 715         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 716
 717         //print(strcat("want_weapon: ", weaponinfo.netname, " - d: ", ftos(d), ", t: ", ftos(t), ". \n"));
 718
 719         // bit order in t:
 720         // 1: want or not
 721         // 2: is default?
 722         // 4: is set by default?
 723         if(t < 0)
 724                 t = 4 | (3 * d);
 725         else
 726                 t |= (2 * d);
 727
 728         return t;
 729 }
 730
 731 void readplayerstartcvars()
 732 {
 733         entity e;
 734         float i, j, t;
 735         string s;
 736
 737         // initialize starting values for players
 738         WEPSET_CLEAR_A(start_weapons);
 739         WEPSET_CLEAR_A(start_weapons_default);
 740         WEPSET_CLEAR_A(start_weapons_defaultmask);
 741         start_items = 0;
 742         start_ammo_shells = 0;
 743         start_ammo_nails = 0;
 744         start_ammo_rockets = 0;
 745         start_ammo_cells = 0;
 746         start_health = cvar("g_balance_health_start");
 747         start_armorvalue = cvar("g_balance_armor_start");
 748
 749         g_weaponarena = 0;
 750         WEPSET_CLEAR_A(g_weaponarena_weapons);
 751
 752         s = cvar_string("g_weaponarena");
 753         if (s == "0" || s == "")
 754         {
 755                 if(g_lms || g_ca)
 756                         s = "most";
 757         }
 758
 759         if (s == "0" || s == "")
 760         {
 761                 // no arena
 762         }
 763         else if (s == "off")
 764         {
 765                 // forcibly turn off weaponarena
 766         }
 767         else if (s == "all")
 768         {
 769                 g_weaponarena = 1;
 770                 g_weaponarena_list = "All Weapons";
 771                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 772                 {
 773                         e = get_weaponinfo(j);
 774                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
 775                                 WEPSET_OR_AW(g_weaponarena_weapons, j);
 776                 }
 777         }
 778         else if (s == "most")
 779         {
 780                 g_weaponarena = 1;
 781                 g_weaponarena_list = "Most Weapons";
 782                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 783                 {
 784                         e = get_weaponinfo(j);
 785                         if not(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
 786                                 if (e.spawnflags & WEP_FLAG_NORMAL)
 787                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
 788                 }
 789         }
 790         else if (s == "none")
 791         {
 792                 g_weaponarena = 1;
 793                 g_weaponarena_list = "No Weapons";
 794         }
 795         else
 796         {
 797                 g_weaponarena = 1;
 798                 t = tokenize_console(s);
 799                 g_weaponarena_list = "";
 800                 for (i = 0; i < t; ++i)
 801                 {
 802                         s = argv(i);
 803                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 804                         {
 805                                 e = get_weaponinfo(j);
 806                                 if (e.netname == s)
 807                                 {
 808                                         WEPSET_OR_AW(g_weaponarena_weapons, j);
 809                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 810                                         break;
 811                                 }
 812                         }
 813                         if (j > WEP_LAST)
 814                         {
 815                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 816                         }
 817                 }
 818                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 819         }
 820
 821         if(g_weaponarena)
 822                 g_weaponarena_random = cvar("g_weaponarena_random");
 823         else
 824                 g_weaponarena_random = 0;
 825         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 826
 827         if (g_weaponarena)
 828         {
 829                 g_minstagib = 0; // incompatible
 830                 g_pinata = 0; // incompatible
 831                 g_weapon_stay = 0; // incompatible
 832                 WEPSET_COPY_AA(start_weapons, g_weaponarena_weapons);
 833                 if(!(g_lms || g_ca))
 834                         start_items |= IT_UNLIMITED_AMMO;
 835         }
 836         else if (g_minstagib)
 837         {
 838                 g_pinata = 0; // incompatible
 839                 g_weapon_stay = 0; // incompatible
 840                 g_bloodloss = 0; // incompatible
 841                 start_health = 100;
 842                 start_armorvalue = 0;
 843                 WEPSET_COPY_AW(start_weapons, WEP_MINSTANEX);
 844                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 845                 start_items |= IT_UNLIMITED_SUPERWEAPONS;
 846
 847                 if (g_minstagib_invis_alpha <= 0)
 848                         g_minstagib_invis_alpha = -1;
 849         }
 850         else
 851         {
 852                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 853                 {
 854                         e = get_weaponinfo(i);
 855                         float w = want_weapon("g_start_weapon_", e, FALSE);
 856                         if(w & 1)
 857                                 WEPSET_OR_AW(start_weapons, i);
 858                         if(w & 2)
 859                                 WEPSET_OR_AW(start_weapons_default, i);
 860                         if(w & 4)
 861                                 WEPSET_OR_AW(start_weapons_defaultmask, i);
 862                 }
 863         }
 864
 865         if(!cvar("g_use_ammunition"))
 866                 start_items |= IT_UNLIMITED_AMMO;
 867
 868         if(cvar("g_nexball"))
 869                 start_items |= IT_UNLIMITED_SUPERWEAPONS; // FIXME BAD BAD BAD BAD HACK, NEXBALL SHOULDN'T ABUSE PORTO'S WEAPON SLOT
 870
 871         if(g_minstagib)
 872         {
 873                 start_ammo_cells = cvar("g_minstagib_ammo_start");
 874                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 875         }
 876         else if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 877         {
 878                 start_ammo_rockets = 999;
 879                 start_ammo_shells = 999;
 880                 start_ammo_cells = 999;
 881                 start_ammo_nails = 999;
 882                 start_ammo_fuel = 999;
 883         }
 884         else
 885         {
 886                 if(g_lms || g_ca)
 887                 {
 888                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
 889                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
 890                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 891                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
 892                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
 893                 }
 894                 else
 895                 {
 896                         start_ammo_shells = cvar("g_start_ammo_shells");
 897                         start_ammo_nails = cvar("g_start_ammo_nails");
 898                         start_ammo_rockets = cvar("g_start_ammo_rockets");
 899                         start_ammo_cells = cvar("g_start_ammo_cells");
 900                         start_ammo_fuel = cvar("g_start_ammo_fuel");
 901                 }
 902         }
 903
 904         if (g_lms || g_ca)
 905         {
 906                 start_health = cvar("g_lms_start_health");
 907                 start_armorvalue = cvar("g_lms_start_armor");
 908         }
 909
 910         if (inWarmupStage)
 911         {
 912                 warmup_start_ammo_shells = start_ammo_shells;
 913                 warmup_start_ammo_nails = start_ammo_nails;
 914                 warmup_start_ammo_rockets = start_ammo_rockets;
 915                 warmup_start_ammo_cells = start_ammo_cells;
 916                 warmup_start_ammo_fuel = start_ammo_fuel;
 917                 warmup_start_health = start_health;
 918                 warmup_start_armorvalue = start_armorvalue;
 919                 WEPSET_COPY_AA(warmup_start_weapons, start_weapons);
 920                 WEPSET_COPY_AA(warmup_start_weapons_default, start_weapons_default);
 921                 WEPSET_COPY_AA(warmup_start_weapons_defaultmask, start_weapons_defaultmask);
 922
 923                 if (!g_weaponarena && !g_minstagib && !g_ca)
 924                 {
 925                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 926                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 927                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 928                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 929                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 930                         warmup_start_health = cvar("g_warmup_start_health");
 931                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 932                         WEPSET_CLEAR_A(warmup_start_weapons);
 933                         WEPSET_CLEAR_A(warmup_start_weapons_default);
 934                         WEPSET_CLEAR_A(warmup_start_weapons_defaultmask);
 935                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 936                         {
 937                                 e = get_weaponinfo(i);
 938                                 float w = want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns"));
 939                                 if(w & 1)
 940                                         WEPSET_OR_AW(warmup_start_weapons, i);
 941                                 if(w & 2)
 942                                         WEPSET_OR_AW(warmup_start_weapons_default, i);
 943                                 if(w & 4)
 944                                         WEPSET_OR_AW(warmup_start_weapons_defaultmask, i);
 945                         }
 946                 }
 947         }
 948
 949         if (g_jetpack)
 950                 start_items |= IT_JETPACK;
 951
 952         MUTATOR_CALLHOOK(SetStartItems);
 953
 954         if ((start_items & IT_JETPACK) || (g_grappling_hook && WEPSET_CONTAINS_AW(start_weapons, WEP_HOOK)))
 955         {
 956                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
 957                 start_items |= IT_FUEL_REGEN;
 958                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 959                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 960         }
 961
 962         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 963         {
 964                 e = get_weaponinfo(i);
 965                 if(WEPSET_CONTAINS_AW(start_weapons, i) || WEPSET_CONTAINS_AW(warmup_start_weapons, i))
 966                         weapon_action(i, WR_PRECACHE);
 967         }
 968
 969         start_ammo_shells = max(0, start_ammo_shells);
 970         start_ammo_nails = max(0, start_ammo_nails);
 971         start_ammo_cells = max(0, start_ammo_cells);
 972         start_ammo_rockets = max(0, start_ammo_rockets);
 973         start_ammo_fuel = max(0, start_ammo_fuel);
 974
 975         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 976         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 977         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 978         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 979         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
 980 }
 981
 982 float g_bugrigs;
 983 float g_bugrigs_planar_movement;
 984 float g_bugrigs_planar_movement_car_jumping;
 985 float g_bugrigs_reverse_spinning;
 986 float g_bugrigs_reverse_speeding;
 987 float g_bugrigs_reverse_stopping;
 988 float g_bugrigs_air_steering;
 989 float g_bugrigs_angle_smoothing;
 990 float g_bugrigs_friction_floor;
 991 float g_bugrigs_friction_brake;
 992 float g_bugrigs_friction_air;
 993 float g_bugrigs_accel;
 994 float g_bugrigs_speed_ref;
 995 float g_bugrigs_speed_pow;
 996 float g_bugrigs_steer;
 997
 998 float g_touchexplode;
 999 float g_touchexplode_radius;
1000 float g_touchexplode_damage;
1001 float g_touchexplode_edgedamage;
1002 float g_touchexplode_force;
1003
1004 float sv_autotaunt;
1005 float sv_taunt;
1006
1007 string GetGametype(); // g_world.qc
1008 void readlevelcvars(void)
1009 {
1010         g_minstagib = cvar("g_minstagib");
1011
1012         monster_skill = cvar("g_monsters_skill");
1013
1014         // load ALL the mutators
1015         if(cvar("g_dodging"))
1016                 MUTATOR_ADD(mutator_dodging);
1017         if(cvar("g_spawn_near_teammate"))
1018                 MUTATOR_ADD(mutator_spawn_near_teammate);
1019         if(cvar("g_physical_items"))
1020                 MUTATOR_ADD(mutator_physical_items);
1021         if(!g_minstagib)
1022         {
1023                 if(cvar("g_invincible_projectiles"))
1024                         MUTATOR_ADD(mutator_invincibleprojectiles);
1025                 if(cvar("g_new_toys"))
1026                         MUTATOR_ADD(mutator_new_toys);
1027                 if(cvar("g_nix"))
1028                         MUTATOR_ADD(mutator_nix);
1029                 if(cvar("g_rocket_flying"))
1030                         MUTATOR_ADD(mutator_rocketflying);
1031                 if(cvar("g_vampire"))
1032                         MUTATOR_ADD(mutator_vampire);
1033                 if(cvar("g_superspectate"))
1034                         MUTATOR_ADD(mutator_superspec);
1035         }
1036
1037         // is this a mutator? is this a mode?
1038         if(cvar("g_sandbox"))
1039                 MUTATOR_ADD(sandbox);
1040
1041         if(cvar("sv_allow_fullbright"))
1042                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
1043
1044     g_bugrigs = cvar("g_bugrigs");
1045     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1046     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1047     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1048     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1049     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1050     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1051     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1052     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1053     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1054     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1055     g_bugrigs_accel = cvar("g_bugrigs_accel");
1056     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1057     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1058     g_bugrigs_steer = cvar("g_bugrigs_steer");
1059
1060     g_touchexplode = cvar("g_touchexplode");
1061     g_touchexplode_radius = cvar("g_touchexplode_radius");
1062     g_touchexplode_damage = cvar("g_touchexplode_damage");
1063     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1064     g_touchexplode_force = cvar("g_touchexplode_force");
1065
1066         sv_clones = cvar("sv_clones");
1067         sv_foginterval = cvar("sv_foginterval");
1068         g_cloaked = cvar("g_cloaked");
1069     if(g_cts)
1070         g_cloaked = 1; // always enable cloak in CTS
1071         g_jump_grunt = cvar("g_jump_grunt");
1072         g_footsteps = cvar("g_footsteps");
1073         g_grappling_hook = cvar("g_grappling_hook");
1074         g_jetpack = cvar("g_jetpack");
1075         g_midair = cvar("g_midair");
1076         g_norecoil = cvar("g_norecoil");
1077         g_bloodloss = cvar("g_bloodloss");
1078         sv_maxidle = cvar("sv_maxidle");
1079         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1080         sv_autotaunt = cvar("sv_autotaunt");
1081         sv_taunt = cvar("sv_taunt");
1082
1083         inWarmupStage = cvar("g_warmup");
1084         g_warmup_limit = cvar("g_warmup_limit");
1085         g_warmup_allguns = cvar("g_warmup_allguns");
1086         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1087
1088         if ((g_race && g_race_qualifying == 2) || g_arena || g_assault || cvar("g_campaign"))
1089                 inWarmupStage = 0; // these modes cannot work together, sorry
1090
1091         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1092         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
1093         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1094         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1095         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1096         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1097         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1098         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1099         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
1100         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1101         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1102         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1103         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1104         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1105
1106         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1107         g_weaponratefactor = cvar("g_weaponratefactor");
1108         g_weapondamagefactor = cvar("g_weapondamagefactor");
1109         g_weaponforcefactor = cvar("g_weaponforcefactor");
1110         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1111
1112         g_pickup_shells = cvar("g_pickup_shells");
1113         g_pickup_shells_max = cvar("g_pickup_shells_max");
1114         g_pickup_nails = cvar("g_pickup_nails");
1115         g_pickup_nails_max = cvar("g_pickup_nails_max");
1116         g_pickup_rockets = cvar("g_pickup_rockets");
1117         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1118         g_pickup_cells = cvar("g_pickup_cells");
1119         g_pickup_cells_max = cvar("g_pickup_cells_max");
1120         g_pickup_fuel = cvar("g_pickup_fuel");
1121         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1122         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1123         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1124         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1125         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1126         g_pickup_armormedium = cvar("g_pickup_armormedium");
1127         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1128         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1129         g_pickup_armorbig = cvar("g_pickup_armorbig");
1130         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1131         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1132         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1133         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1134         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1135         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1136         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1137         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1138         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1139         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1140         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1141         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1142         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1143         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1144         g_pickup_healthmega = cvar("g_pickup_healthmega");
1145         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1146         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1147
1148         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1149         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1150
1151         g_pinata = cvar("g_pinata");
1152
1153     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1154     if(!g_weapon_stay)
1155         g_weapon_stay = cvar("g_weapon_stay");
1156
1157         if not(inWarmupStage && !g_ca)
1158                 game_starttime = cvar("g_start_delay");
1159
1160         readplayerstartcvars();
1161 }
1162
1163 //#NO AUTOCVARS END
1164
1165 // Sound functions
1166 string precache_sound (string s) = #19;
1167 float precache_sound_index (string s) = #19;
1168
1169 #define SND_VOLUME      1
1170 #define SND_ATTENUATION 2
1171 #define SND_LARGEENTITY 8
1172 #define SND_LARGESOUND  16
1173
1174 float sound_allowed(float dest, entity e)
1175 {
1176     // sounds from world may always pass
1177     for (;;)
1178     {
1179         if (e.classname == "body")
1180             e = e.enemy;
1181         else if (e.realowner && e.realowner != e)
1182             e = e.realowner;
1183         else if (e.owner && e.owner != e)
1184             e = e.owner;
1185         else
1186             break;
1187     }
1188     // sounds to self may always pass
1189     if (dest == MSG_ONE)
1190         if (e == msg_entity)
1191             return TRUE;
1192     // sounds by players can be removed
1193     if (autocvar_bot_sound_monopoly)
1194         if (clienttype(e) == CLIENTTYPE_REAL)
1195             return FALSE;
1196     // anything else may pass
1197     return TRUE;
1198 }
1199
1200 #ifdef COMPAT_XON010_CHANNELS
1201 void(entity e, float chan, string samp, float vol, float atten) builtin_sound = #8;
1202 void sound(entity e, float chan, string samp, float vol, float atten)
1203 {
1204     if (!sound_allowed(MSG_BROADCAST, e))
1205         return;
1206     builtin_sound(e, chan, samp, vol, atten);
1207 }
1208 #else
1209 #undef sound
1210 void sound(entity e, float chan, string samp, float vol, float atten)
1211 {
1212     if (!sound_allowed(MSG_BROADCAST, e))
1213         return;
1214     sound7(e, chan, samp, vol, atten, 0, 0);
1215 }
1216 #endif
1217
1218 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1219 {
1220     float entno, idx;
1221
1222     if (!sound_allowed(dest, e))
1223         return;
1224
1225     entno = num_for_edict(e);
1226     idx = precache_sound_index(samp);
1227
1228     float sflags;
1229     sflags = 0;
1230
1231     atten = floor(atten * 64);
1232     vol = floor(vol * 255);
1233
1234     if (vol != 255)
1235         sflags |= SND_VOLUME;
1236     if (atten != 64)
1237         sflags |= SND_ATTENUATION;
1238     if (entno >= 8192 || chan < 0 || chan > 7)
1239         sflags |= SND_LARGEENTITY;
1240     if (idx >= 256)
1241         sflags |= SND_LARGESOUND;
1242
1243     WriteByte(dest, SVC_SOUND);
1244     WriteByte(dest, sflags);
1245     if (sflags & SND_VOLUME)
1246         WriteByte(dest, vol);
1247     if (sflags & SND_ATTENUATION)
1248         WriteByte(dest, atten);
1249     if (sflags & SND_LARGEENTITY)
1250     {
1251         WriteShort(dest, entno);
1252         WriteByte(dest, chan);
1253     }
1254     else
1255     {
1256         WriteShort(dest, entno * 8 + chan);
1257     }
1258     if (sflags & SND_LARGESOUND)
1259         WriteShort(dest, idx);
1260     else
1261         WriteByte(dest, idx);
1262
1263     WriteCoord(dest, o_x);
1264     WriteCoord(dest, o_y);
1265     WriteCoord(dest, o_z);
1266 }
1267 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1268 {
1269     vector o;
1270
1271     if (!sound_allowed(dest, e))
1272         return;
1273
1274     o = e.origin + 0.5 * (e.mins + e.maxs);
1275     soundtoat(dest, e, o, chan, samp, vol, atten);
1276 }
1277 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1278 {
1279     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1280 }
1281 void stopsoundto(float dest, entity e, float chan)
1282 {
1283     float entno;
1284
1285     if (!sound_allowed(dest, e))
1286         return;
1287
1288     entno = num_for_edict(e);
1289
1290     if (entno >= 8192 || chan < 0 || chan > 7)
1291     {
1292         float idx, sflags;
1293         idx = precache_sound_index("misc/null.wav");
1294         sflags = SND_LARGEENTITY;
1295         if (idx >= 256)
1296             sflags |= SND_LARGESOUND;
1297         WriteByte(dest, SVC_SOUND);
1298         WriteByte(dest, sflags);
1299         WriteShort(dest, entno);
1300         WriteByte(dest, chan);
1301         if (sflags & SND_LARGESOUND)
1302             WriteShort(dest, idx);
1303         else
1304             WriteByte(dest, idx);
1305         WriteCoord(dest, e.origin_x);
1306         WriteCoord(dest, e.origin_y);
1307         WriteCoord(dest, e.origin_z);
1308     }
1309     else
1310     {
1311         WriteByte(dest, SVC_STOPSOUND);
1312         WriteShort(dest, entno * 8 + chan);
1313     }
1314 }
1315 void stopsound(entity e, float chan)
1316 {
1317     if (!sound_allowed(MSG_BROADCAST, e))
1318         return;
1319
1320     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1321     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1322 }
1323
1324 void play2(entity e, string filename)
1325 {
1326     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1327     msg_entity = e;
1328     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTN_NONE);
1329 }
1330
1331 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1332 .float spamtime;
1333 float spamsound(entity e, float chan, string samp, float vol, float atten)
1334 {
1335     if (!sound_allowed(MSG_BROADCAST, e))
1336         return FALSE;
1337
1338     if (time > e.spamtime)
1339     {
1340         e.spamtime = time;
1341         sound(e, chan, samp, vol, atten);
1342         return TRUE;
1343     }
1344     return FALSE;
1345 }
1346
1347 void play2team(float t, string filename)
1348 {
1349     entity head;
1350
1351     if (autocvar_bot_sound_monopoly)
1352         return;
1353
1354     FOR_EACH_REALPLAYER(head)
1355     {
1356         if (head.team == t)
1357             play2(head, filename);
1358     }
1359 }
1360
1361 void play2all(string samp)
1362 {
1363     if (autocvar_bot_sound_monopoly)
1364         return;
1365
1366     sound(world, CH_INFO, samp, VOL_BASE, ATTN_NONE);
1367 }
1368
1369 void PrecachePlayerSounds(string f);
1370 void precache_playermodel(string m)
1371 {
1372         float globhandle, i, n;
1373         string f;
1374
1375         if(substring(m, -9,5) == "_lod1")
1376                 return;
1377         if(substring(m, -9,5) == "_lod2")
1378                 return;
1379         precache_model(m);
1380         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1381         if(fexists(f))
1382                 precache_model(f);
1383         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1384         if(fexists(f))
1385                 precache_model(f);
1386
1387         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1388         if (globhandle < 0)
1389                 return;
1390         n = search_getsize(globhandle);
1391         for (i = 0; i < n; ++i)
1392         {
1393                 //print(search_getfilename(globhandle, i), "\n");
1394                 f = search_getfilename(globhandle, i);
1395                 PrecachePlayerSounds(f);
1396         }
1397         search_end(globhandle);
1398 }
1399 void precache_all_playermodels(string pattern)
1400 {
1401         float globhandle, i, n;
1402         string f;
1403
1404         globhandle = search_begin(pattern, TRUE, FALSE);
1405         if (globhandle < 0)
1406                 return;
1407         n = search_getsize(globhandle);
1408         for (i = 0; i < n; ++i)
1409         {
1410                 //print(search_getfilename(globhandle, i), "\n");
1411                 f = search_getfilename(globhandle, i);
1412                 precache_playermodel(f);
1413         }
1414         search_end(globhandle);
1415 }
1416
1417 void precache()
1418 {
1419     // gamemode related things
1420     precache_model ("models/misc/chatbubble.spr");
1421
1422 #ifdef TTURRETS_ENABLED
1423     if (autocvar_g_turrets)
1424         turrets_precash();
1425 #endif
1426
1427     // Precache all player models if desired
1428     if (autocvar_sv_precacheplayermodels)
1429     {
1430         PrecachePlayerSounds("sound/player/default.sounds");
1431         precache_all_playermodels("models/player/*.zym");
1432         precache_all_playermodels("models/player/*.dpm");
1433         precache_all_playermodels("models/player/*.md3");
1434         precache_all_playermodels("models/player/*.psk");
1435         precache_all_playermodels("models/player/*.iqm");
1436     }
1437
1438     if (autocvar_sv_defaultcharacter)
1439     {
1440         string s;
1441         s = autocvar_sv_defaultplayermodel_red;
1442         if (s != "")
1443             precache_playermodel(s);
1444         s = autocvar_sv_defaultplayermodel_blue;
1445         if (s != "")
1446             precache_playermodel(s);
1447         s = autocvar_sv_defaultplayermodel_yellow;
1448         if (s != "")
1449             precache_playermodel(s);
1450         s = autocvar_sv_defaultplayermodel_pink;
1451         if (s != "")
1452             precache_playermodel(s);
1453         s = autocvar_sv_defaultplayermodel;
1454         if (s != "")
1455             precache_playermodel(s);
1456     }
1457
1458     if (g_footsteps)
1459     {
1460         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1461         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1462     }
1463
1464     // gore and miscellaneous sounds
1465     //precache_sound ("misc/h2ohit.wav");
1466     precache_model ("models/hook.md3");
1467     precache_sound ("misc/armorimpact.wav");
1468     precache_sound ("misc/bodyimpact1.wav");
1469     precache_sound ("misc/bodyimpact2.wav");
1470     precache_sound ("misc/gib.wav");
1471     precache_sound ("misc/gib_splat01.wav");
1472     precache_sound ("misc/gib_splat02.wav");
1473     precache_sound ("misc/gib_splat03.wav");
1474     precache_sound ("misc/gib_splat04.wav");
1475     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1476     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1477     precache_sound ("misc/null.wav");
1478     precache_sound ("misc/spawn.wav");
1479     precache_sound ("misc/talk.wav");
1480     precache_sound ("misc/teleport.wav");
1481     precache_sound ("misc/poweroff.wav");
1482     precache_sound ("player/lava.wav");
1483     precache_sound ("player/slime.wav");
1484
1485     precache_model ("models/sprites/0.spr32");
1486     precache_model ("models/sprites/1.spr32");
1487     precache_model ("models/sprites/2.spr32");
1488     precache_model ("models/sprites/3.spr32");
1489     precache_model ("models/sprites/4.spr32");
1490     precache_model ("models/sprites/5.spr32");
1491     precache_model ("models/sprites/6.spr32");
1492     precache_model ("models/sprites/7.spr32");
1493     precache_model ("models/sprites/8.spr32");
1494     precache_model ("models/sprites/9.spr32");
1495     precache_model ("models/sprites/10.spr32");
1496
1497     // common weapon precaches
1498         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1499     precache_sound ("weapons/weapon_switch.wav");
1500     precache_sound ("weapons/weaponpickup.wav");
1501     precache_sound ("weapons/unavailable.wav");
1502     precache_sound ("weapons/dryfire.wav");
1503     if (g_grappling_hook)
1504     {
1505         precache_sound ("weapons/hook_fire.wav"); // hook
1506         precache_sound ("weapons/hook_impact.wav"); // hook
1507     }
1508
1509     if(autocvar_sv_precacheweapons)
1510     {
1511         //precache weapon models/sounds
1512         float wep;
1513         wep = WEP_FIRST;
1514         while (wep <= WEP_LAST)
1515         {
1516             weapon_action(wep, WR_PRECACHE);
1517             wep = wep + 1;
1518         }
1519     }
1520
1521     precache_model("models/elaser.mdl");
1522     precache_model("models/laser.mdl");
1523     precache_model("models/ebomb.mdl");
1524
1525 #if 0
1526     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1527
1528     if (!self.noise && self.music) // quake 3 uses the music field
1529         self.noise = self.music;
1530
1531     // plays music for the level if there is any
1532     if (self.noise)
1533     {
1534         precache_sound (self.noise);
1535         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1536     }
1537 #endif
1538 }
1539
1540 // WARNING: this kills the trace globals
1541 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1542 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1543
1544 #define INITPRIO_FIRST              0
1545 #define INITPRIO_GAMETYPE           0
1546 #define INITPRIO_GAMETYPE_FALLBACK  1
1547 #define INITPRIO_FINDTARGET        10
1548 #define INITPRIO_DROPTOFLOOR       20
1549 #define INITPRIO_SETLOCATION       90
1550 #define INITPRIO_LINKDOORS         91
1551 #define INITPRIO_LAST              99
1552
1553 .void(void) initialize_entity;
1554 .float initialize_entity_order;
1555 .entity initialize_entity_next;
1556 entity initialize_entity_first;
1557
1558 void make_safe_for_remove(entity e)
1559 {
1560     if (e.initialize_entity)
1561     {
1562         entity ent, prev = world;
1563         for (ent = initialize_entity_first; ent; )
1564         {
1565             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1566             {
1567                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1568                 // skip it in linked list
1569                 if (prev)
1570                 {
1571                     prev.initialize_entity_next = ent.initialize_entity_next;
1572                     ent = prev.initialize_entity_next;
1573                 }
1574                 else
1575                 {
1576                     initialize_entity_first = ent.initialize_entity_next;
1577                     ent = initialize_entity_first;
1578                 }
1579             }
1580             else
1581             {
1582                 prev = ent;
1583                 ent = ent.initialize_entity_next;
1584             }
1585         }
1586     }
1587 }
1588
1589 void objerror(string s)
1590 {
1591     make_safe_for_remove(self);
1592     builtin_objerror(s);
1593 }
1594
1595 .float remove_except_protected_forbidden;
1596 void remove_except_protected(entity e)
1597 {
1598         if(e.remove_except_protected_forbidden)
1599                 error("not allowed to remove this at this point");
1600         builtin_remove(e);
1601 }
1602
1603 void remove_unsafely(entity e)
1604 {
1605     if(e.classname == "spike")
1606         error("Removing spikes is forbidden (crylink bug), please report");
1607     builtin_remove(e);
1608 }
1609
1610 void remove_safely(entity e)
1611 {
1612     make_safe_for_remove(e);
1613     builtin_remove(e);
1614 }
1615
1616 void InitializeEntity(entity e, void(void) func, float order)
1617 {
1618     entity prev, cur;
1619
1620     if (!e || e.initialize_entity)
1621     {
1622         // make a proxy initializer entity
1623         entity e_old;
1624         e_old = e;
1625         e = spawn();
1626         e.classname = "initialize_entity";
1627         e.enemy = e_old;
1628     }
1629
1630     e.initialize_entity = func;
1631     e.initialize_entity_order = order;
1632
1633     cur = initialize_entity_first;
1634     prev = world;
1635     for (;;)
1636     {
1637         if (!cur || cur.initialize_entity_order > order)
1638         {
1639             // insert between prev and cur
1640             if (prev)
1641                 prev.initialize_entity_next = e;
1642             else
1643                 initialize_entity_first = e;
1644             e.initialize_entity_next = cur;
1645             return;
1646         }
1647         prev = cur;
1648         cur = cur.initialize_entity_next;
1649     }
1650 }
1651 void InitializeEntitiesRun()
1652 {
1653     entity startoflist;
1654     startoflist = initialize_entity_first;
1655     initialize_entity_first = world;
1656     remove = remove_except_protected;
1657     for (self = startoflist; self; self = self.initialize_entity_next)
1658     {
1659         self.remove_except_protected_forbidden = 1;
1660     }
1661     for (self = startoflist; self; )
1662     {
1663         entity e;
1664         var void(void) func;
1665         e = self.initialize_entity_next;
1666         func = self.initialize_entity;
1667         self.initialize_entity_order = 0;
1668         self.initialize_entity = func_null;
1669         self.initialize_entity_next = world;
1670         self.remove_except_protected_forbidden = 0;
1671         if (self.classname == "initialize_entity")
1672         {
1673             entity e_old;
1674             e_old = self.enemy;
1675             builtin_remove(self);
1676             self = e_old;
1677         }
1678         //dprint("Delayed initialization: ", self.classname, "\n");
1679         if(func)
1680             func();
1681         else
1682         {
1683             eprint(self);
1684             backtrace(strcat("Null function in: ", self.classname, "\n"));
1685         }
1686         self = e;
1687     }
1688     remove = remove_unsafely;
1689 }
1690
1691 .float uncustomizeentityforclient_set;
1692 .void(void) uncustomizeentityforclient;
1693 void UncustomizeEntitiesRun()
1694 {
1695     entity oldself;
1696     oldself = self;
1697     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1698         self.uncustomizeentityforclient();
1699     self = oldself;
1700 }
1701 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1702 {
1703     e.customizeentityforclient = customizer;
1704     e.uncustomizeentityforclient = uncustomizer;
1705     e.uncustomizeentityforclient_set = !!uncustomizer;
1706 }
1707
1708 .float nottargeted;
1709 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1710
1711 void() SUB_Remove;
1712 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1713 {
1714     vector mi, ma;
1715
1716     if (e.classname == "")
1717         e.classname = "net_linked";
1718
1719     if (e.model == "" || self.modelindex == 0)
1720     {
1721         mi = e.mins;
1722         ma = e.maxs;
1723         setmodel(e, "null");
1724         setsize(e, mi, ma);
1725     }
1726
1727     e.SendEntity = sendfunc;
1728     e.SendFlags = 0xFFFFFF;
1729
1730     if (!docull)
1731         e.effects |= EF_NODEPTHTEST;
1732
1733     if (dt)
1734     {
1735         e.nextthink = time + dt;
1736         e.think = SUB_Remove;
1737     }
1738 }
1739
1740 void adaptor_think2touch()
1741 {
1742     entity o;
1743     o = other;
1744     other = world;
1745     self.touch();
1746     other = o;
1747 }
1748
1749 void adaptor_think2use()
1750 {
1751     entity o, a;
1752     o = other;
1753     a = activator;
1754     activator = world;
1755     other = world;
1756     self.use();
1757     other = o;
1758     activator = a;
1759 }
1760
1761 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1762 {
1763         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1764                 self.projectiledeathtype |= HITTYPE_SPLASH;
1765         adaptor_think2use();
1766 }
1767
1768 // deferred dropping
1769 void DropToFloor_Handler()
1770 {
1771     builtin_droptofloor();
1772     self.dropped_origin = self.origin;
1773 }
1774
1775 void droptofloor()
1776 {
1777     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1778 }
1779
1780
1781
1782 float trace_hits_box_a0, trace_hits_box_a1;
1783
1784 float trace_hits_box_1d(float end, float thmi, float thma)
1785 {
1786     if (end == 0)
1787     {
1788         // just check if x is in range
1789         if (0 < thmi)
1790             return FALSE;
1791         if (0 > thma)
1792             return FALSE;
1793     }
1794     else
1795     {
1796         // do the trace with respect to x
1797         // 0 -> end has to stay in thmi -> thma
1798         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1799         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1800         if (trace_hits_box_a0 > trace_hits_box_a1)
1801             return FALSE;
1802     }
1803     return TRUE;
1804 }
1805
1806 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1807 {
1808     end -= start;
1809     thmi -= start;
1810     thma -= start;
1811     // now it is a trace from 0 to end
1812
1813     trace_hits_box_a0 = 0;
1814     trace_hits_box_a1 = 1;
1815
1816     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1817         return FALSE;
1818     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1819         return FALSE;
1820     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1821         return FALSE;
1822
1823     return TRUE;
1824 }
1825
1826 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1827 {
1828     return trace_hits_box(start, end, thmi - ma, thma - mi);
1829 }
1830
1831 float SUB_NoImpactCheck()
1832 {
1833         // zero hitcontents = this is not the real impact, but either the
1834         // mirror-impact of something hitting the projectile instead of the
1835         // projectile hitting the something, or a touchareagrid one. Neither of
1836         // these stop the projectile from moving, so...
1837         if(trace_dphitcontents == 0)
1838         {
1839                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1840                 dprint(sprintf(_("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n"), num_for_edict(self), self.classname, vtos(self.origin)));
1841                 checkclient();
1842         }
1843     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1844         return 1;
1845     if (other == world && self.size != '0 0 0')
1846     {
1847         vector tic;
1848         tic = self.velocity * sys_frametime;
1849         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1850         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1851         if (trace_fraction >= 1)
1852         {
1853             dprint("Odd... did not hit...?\n");
1854         }
1855         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1856         {
1857             dprint("Detected and prevented the sky-grapple bug.\n");
1858             return 1;
1859         }
1860     }
1861
1862     return 0;
1863 }
1864
1865 #define SUB_OwnerCheck() (other && (other == self.owner))
1866
1867 void RemoveGrapplingHook(entity pl);
1868 void W_Crylink_Dequeue(entity e);
1869 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1870 {
1871         if(SUB_OwnerCheck())
1872                 return TRUE;
1873         if(SUB_NoImpactCheck())
1874         {
1875                 if(self.classname == "grapplinghook")
1876                         RemoveGrapplingHook(self.realowner);
1877                 else if(self.classname == "spike")
1878                 {
1879                         W_Crylink_Dequeue(self);
1880                         remove(self);
1881                 }
1882                 else
1883                         remove(self);
1884                 return TRUE;
1885         }
1886         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1887                 UpdateCSQCProjectile(self);
1888         return FALSE;
1889 }
1890 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1891
1892 #define ITEM_TOUCH_NEEDKILL() (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
1893 #define ITEM_DAMAGE_NEEDKILL(dt) (((dt) == DEATH_HURTTRIGGER) || ((dt) == DEATH_SLIME) || ((dt) == DEATH_LAVA) || ((dt) == DEATH_SWAMP))
1894
1895 void URI_Get_Callback(float id, float status, string data)
1896 {
1897         if(url_URI_Get_Callback(id, status, data))
1898         {
1899                 // handled
1900         }
1901         else if (id == URI_GET_DISCARD)
1902         {
1903                 // discard
1904         }
1905         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1906         {
1907                 // sv_cmd curl
1908                 Curl_URI_Get_Callback(id, status, data);
1909         }
1910         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1911         {
1912                 // online ban list
1913                 OnlineBanList_URI_Get_Callback(id, status, data);
1914         }
1915         else
1916         {
1917                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1918         }
1919 }
1920
1921 string uid2name(string myuid) {
1922         string s;
1923         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
1924
1925         // FIXME remove this later after 0.6 release
1926         // convert old style broken records to correct style
1927         if(s == "")
1928         {
1929                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
1930                 if(s != "")
1931                 {
1932                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
1933                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
1934                 }
1935         }
1936
1937         if(s == "")
1938                 s = "^1Unregistered Player";
1939         return s;
1940 }
1941
1942 float race_readTime(string map, float pos)
1943 {
1944         string rr;
1945         if(g_cts)
1946                 rr = CTS_RECORD;
1947         else
1948                 rr = RACE_RECORD;
1949
1950         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
1951 }
1952
1953 string race_readUID(string map, float pos)
1954 {
1955         string rr;
1956         if(g_cts)
1957                 rr = CTS_RECORD;
1958         else
1959                 rr = RACE_RECORD;
1960
1961         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
1962 }
1963
1964 float race_readPos(string map, float t) {
1965         float i;
1966         for (i = 1; i <= RANKINGS_CNT; ++i)
1967                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
1968                         return i;
1969
1970         return 0; // pos is zero if unranked
1971 }
1972
1973 void race_writeTime(string map, float t, string myuid)
1974 {
1975         string rr;
1976         if(g_cts)
1977                 rr = CTS_RECORD;
1978         else
1979                 rr = RACE_RECORD;
1980
1981         float newpos;
1982         newpos = race_readPos(map, t);
1983
1984         float i, prevpos = 0;
1985         for(i = 1; i <= RANKINGS_CNT; ++i)
1986         {
1987                 if(race_readUID(map, i) == myuid)
1988                         prevpos = i;
1989         }
1990         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
1991                 for (i = prevpos; i > newpos; --i) {
1992                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1993                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1994                 }
1995         } else { // player has no ranked record yet
1996                 for (i = RANKINGS_CNT; i > newpos; --i) {
1997                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
1998                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
1999                 }
2000         }
2001
2002         // store new time itself
2003         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
2004         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
2005 }
2006
2007 string race_readName(string map, float pos)
2008 {
2009         string rr;
2010         if(g_cts)
2011                 rr = CTS_RECORD;
2012         else
2013                 rr = RACE_RECORD;
2014
2015         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
2016 }
2017
2018 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2019 {
2020     float m, i;
2021     vector start, org, delta, end, enddown, mstart;
2022     entity sp;
2023
2024     m = e.dphitcontentsmask;
2025     e.dphitcontentsmask = goodcontents | badcontents;
2026
2027     org = world.mins;
2028     delta = world.maxs - world.mins;
2029
2030     start = end = org;
2031
2032     for (i = 0; i < attempts; ++i)
2033     {
2034         start_x = org_x + random() * delta_x;
2035         start_y = org_y + random() * delta_y;
2036         start_z = org_z + random() * delta_z;
2037
2038         // rule 1: start inside world bounds, and outside
2039         // solid, and don't start from somewhere where you can
2040         // fall down to evil
2041         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2042         if (trace_fraction >= 1)
2043             continue;
2044         if (trace_startsolid)
2045             continue;
2046         if (trace_dphitcontents & badcontents)
2047             continue;
2048         if (trace_dphitq3surfaceflags & badsurfaceflags)
2049             continue;
2050
2051         // rule 2: if we are too high, lower the point
2052         if (trace_fraction * delta_z > maxaboveground)
2053             start = trace_endpos + '0 0 1' * maxaboveground;
2054         enddown = trace_endpos;
2055
2056         // rule 3: make sure we aren't outside the map. This only works
2057         // for somewhat well formed maps. A good rule of thumb is that
2058         // the map should have a convex outside hull.
2059         // these can be traceLINES as we already verified the starting box
2060         mstart = start + 0.5 * (e.mins + e.maxs);
2061         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2062         if (trace_fraction >= 1)
2063             continue;
2064         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2065         if (trace_fraction >= 1)
2066             continue;
2067         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2068         if (trace_fraction >= 1)
2069             continue;
2070         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2071         if (trace_fraction >= 1)
2072             continue;
2073         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2074         if (trace_fraction >= 1)
2075             continue;
2076
2077         // rule 4: we must "see" some spawnpoint
2078         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
2079                 if(checkpvs(mstart, sp))
2080                         break;
2081         if(!sp)
2082         {
2083                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
2084                         if(checkpvs(mstart, sp))
2085                                 break;
2086                 if(!sp)
2087                         continue;
2088         }
2089
2090         // find a random vector to "look at"
2091         end_x = org_x + random() * delta_x;
2092         end_y = org_y + random() * delta_y;
2093         end_z = org_z + random() * delta_z;
2094         end = start + normalize(end - start) * vlen(delta);
2095
2096         // rule 4: start TO end must not be too short
2097         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2098         if (trace_startsolid)
2099             continue;
2100         if (trace_fraction < minviewdistance / vlen(delta))
2101             continue;
2102
2103         // rule 5: don't want to look at sky
2104         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2105             continue;
2106
2107         // rule 6: we must not end up in trigger_hurt
2108         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2109             continue;
2110
2111         break;
2112     }
2113
2114     e.dphitcontentsmask = m;
2115
2116     if (i < attempts)
2117     {
2118         setorigin(e, start);
2119         e.angles = vectoangles(end - start);
2120         dprint("Needed ", ftos(i + 1), " attempts\n");
2121         return TRUE;
2122     }
2123     else
2124         return FALSE;
2125 }
2126
2127 float zcurveparticles_effectno;
2128 vector zcurveparticles_start;
2129 float zcurveparticles_spd;
2130
2131 void endzcurveparticles()
2132 {
2133         if(zcurveparticles_effectno)
2134         {
2135                 // terminator
2136                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2137         }
2138         zcurveparticles_effectno = 0;
2139 }
2140
2141 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2142 {
2143         spd = bound(0, floor(spd / 16), 32767);
2144         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2145         {
2146                 endzcurveparticles();
2147                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2148                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2149                 WriteShort(MSG_BROADCAST, effectno);
2150                 WriteCoord(MSG_BROADCAST, start_x);
2151                 WriteCoord(MSG_BROADCAST, start_y);
2152                 WriteCoord(MSG_BROADCAST, start_z);
2153                 zcurveparticles_effectno = effectno;
2154                 zcurveparticles_start = start;
2155         }
2156         else
2157                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2158         WriteCoord(MSG_BROADCAST, end_x);
2159         WriteCoord(MSG_BROADCAST, end_y);
2160         WriteCoord(MSG_BROADCAST, end_z);
2161         WriteCoord(MSG_BROADCAST, end_dz);
2162         zcurveparticles_spd = spd;
2163 }
2164
2165 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2166 {
2167         float end_dz;
2168         vector vecxy, velxy;
2169
2170         vecxy = end - start;
2171         vecxy_z = 0;
2172         velxy = vel;
2173         velxy_z = 0;
2174
2175         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2176         {
2177                 endzcurveparticles();
2178                 trailparticles(world, effectno, start, end);
2179                 return;
2180         }
2181
2182         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2183         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2184 }
2185
2186 void write_recordmarker(entity pl, float tstart, float dt)
2187 {
2188     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2189
2190     // also write a marker into demo files for demotc-race-record-extractor to find
2191     stuffcmd(pl,
2192              strcat(
2193                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2194                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2195 }
2196
2197 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2198 {
2199         switch(algn)
2200         {
2201                 default:
2202                 case 3: // right
2203                         break;
2204
2205                 case 4: // left
2206                         vecs_y = -vecs_y;
2207                         break;
2208
2209                 case 1:
2210                         if(allowcenter) // 2: allow center handedness
2211                         {
2212                                 // center
2213                                 vecs_y = 0;
2214                                 vecs_z -= 2;
2215                         }
2216                         else
2217                         {
2218                                 // right
2219                         }
2220                         break;
2221
2222                 case 2:
2223                         if(allowcenter) // 2: allow center handedness
2224                         {
2225                                 // center
2226                                 vecs_y = 0;
2227                                 vecs_z -= 2;
2228                         }
2229                         else
2230                         {
2231                                 // left
2232                                 vecs_y = -vecs_y;
2233                         }
2234                         break;
2235         }
2236         return vecs;
2237 }
2238
2239 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2240 {
2241         string s;
2242         vector v;
2243
2244         if (autocvar_g_shootfromeye)
2245         {
2246                 if (visual)
2247                 {
2248                         if (autocvar_g_shootfromclient) { vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn); }
2249                         else { vecs_y = 0; vecs_z -= 2; }
2250                 }
2251                 else
2252                 {
2253                         vecs_y = 0;
2254                         vecs_z = 0;
2255                 }
2256         }
2257         else if (autocvar_g_shootfromcenter)
2258         {
2259                 vecs_y = 0;
2260                 vecs_z -= 2;
2261         }
2262         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2263         {
2264                 v = stov(s);
2265                 if (y_is_right)
2266                         v_y = -v_y;
2267                 if (v_x != 0)
2268                         vecs_x = v_x;
2269                 vecs_y = v_y;
2270                 vecs_z = v_z;
2271         }
2272         else if (autocvar_g_shootfromclient)
2273         {
2274                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2275         }
2276         return vecs;
2277 }
2278
2279 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2280 {
2281         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2282 }
2283
2284
2285 void attach_sameorigin(entity e, entity to, string tag)
2286 {
2287     vector org, t_forward, t_left, t_up, e_forward, e_up;
2288     float tagscale;
2289
2290     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2291     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2292     t_forward = v_forward * tagscale;
2293     t_left = v_right * -tagscale;
2294     t_up = v_up * tagscale;
2295
2296     e.origin_x = org * t_forward;
2297     e.origin_y = org * t_left;
2298     e.origin_z = org * t_up;
2299
2300     // current forward and up directions
2301     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2302                 e.angles = AnglesTransform_FromVAngles(e.angles);
2303         else
2304                 e.angles = AnglesTransform_FromAngles(e.angles);
2305     fixedmakevectors(e.angles);
2306
2307     // untransform forward, up!
2308     e_forward_x = v_forward * t_forward;
2309     e_forward_y = v_forward * t_left;
2310     e_forward_z = v_forward * t_up;
2311     e_up_x = v_up * t_forward;
2312     e_up_y = v_up * t_left;
2313     e_up_z = v_up * t_up;
2314
2315     e.angles = fixedvectoangles2(e_forward, e_up);
2316     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2317                 e.angles = AnglesTransform_ToVAngles(e.angles);
2318         else
2319                 e.angles = AnglesTransform_ToAngles(e.angles);
2320
2321     setattachment(e, to, tag);
2322     setorigin(e, e.origin);
2323 }
2324
2325 void detach_sameorigin(entity e)
2326 {
2327     vector org;
2328     org = gettaginfo(e, 0);
2329     e.angles = fixedvectoangles2(v_forward, v_up);
2330     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2331                 e.angles = AnglesTransform_ToVAngles(e.angles);
2332         else
2333                 e.angles = AnglesTransform_ToAngles(e.angles);
2334     setorigin(e, org);
2335     setattachment(e, world, "");
2336     setorigin(e, e.origin);
2337 }
2338
2339 void follow_sameorigin(entity e, entity to)
2340 {
2341     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2342     e.aiment = to; // make the hole follow bmodel
2343     e.punchangle = to.angles; // the original angles of bmodel
2344     e.view_ofs = e.origin - to.origin; // relative origin
2345     e.v_angle = e.angles - to.angles; // relative angles
2346 }
2347
2348 void unfollow_sameorigin(entity e)
2349 {
2350     e.movetype = MOVETYPE_NONE;
2351 }
2352
2353 entity gettaginfo_relative_ent;
2354 vector gettaginfo_relative(entity e, float tag)
2355 {
2356     if (!gettaginfo_relative_ent)
2357     {
2358         gettaginfo_relative_ent = spawn();
2359         gettaginfo_relative_ent.effects = EF_NODRAW;
2360     }
2361     gettaginfo_relative_ent.model = e.model;
2362     gettaginfo_relative_ent.modelindex = e.modelindex;
2363     gettaginfo_relative_ent.frame = e.frame;
2364     return gettaginfo(gettaginfo_relative_ent, tag);
2365 }
2366
2367 .float scale2;
2368
2369 float modeleffect_SendEntity(entity to, float sf)
2370 {
2371         float f;
2372         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2373
2374         f = 0;
2375         if(self.velocity != '0 0 0')
2376                 f |= 1;
2377         if(self.angles != '0 0 0')
2378                 f |= 2;
2379         if(self.avelocity != '0 0 0')
2380                 f |= 4;
2381
2382         WriteByte(MSG_ENTITY, f);
2383         WriteShort(MSG_ENTITY, self.modelindex);
2384         WriteByte(MSG_ENTITY, self.skin);
2385         WriteByte(MSG_ENTITY, self.frame);
2386         WriteCoord(MSG_ENTITY, self.origin_x);
2387         WriteCoord(MSG_ENTITY, self.origin_y);
2388         WriteCoord(MSG_ENTITY, self.origin_z);
2389         if(f & 1)
2390         {
2391                 WriteCoord(MSG_ENTITY, self.velocity_x);
2392                 WriteCoord(MSG_ENTITY, self.velocity_y);
2393                 WriteCoord(MSG_ENTITY, self.velocity_z);
2394         }
2395         if(f & 2)
2396         {
2397                 WriteCoord(MSG_ENTITY, self.angles_x);
2398                 WriteCoord(MSG_ENTITY, self.angles_y);
2399                 WriteCoord(MSG_ENTITY, self.angles_z);
2400         }
2401         if(f & 4)
2402         {
2403                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2404                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2405                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2406         }
2407         WriteShort(MSG_ENTITY, self.scale * 256.0);
2408         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2409         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2410         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2411         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2412
2413         return TRUE;
2414 }
2415
2416 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2417 {
2418         entity e;
2419         float sz;
2420         e = spawn();
2421         e.classname = "modeleffect";
2422         setmodel(e, m);
2423         e.frame = f;
2424         setorigin(e, o);
2425         e.velocity = v;
2426         e.angles = ang;
2427         e.avelocity = angv;
2428         e.alpha = a;
2429         e.teleport_time = t1;
2430         e.fade_time = t2;
2431         e.skin = s;
2432         if(s0 >= 0)
2433                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2434         else
2435                 e.scale = -s0;
2436         if(s2 >= 0)
2437                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2438         else
2439                 e.scale2 = -s2;
2440         sz = max(e.scale, e.scale2);
2441         setsize(e, e.mins * sz, e.maxs * sz);
2442         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2443 }
2444
2445 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2446 {
2447         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2448 }
2449
2450 float randombit(float bits)
2451 {
2452         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2453                 return bits;
2454
2455         float n, f, b, r;
2456
2457         r = random();
2458         b = 0;
2459         n = 0;
2460
2461         for(f = 1; f <= bits; f *= 2)
2462         {
2463                 if(bits & f)
2464                 {
2465                         ++n;
2466                         r *= n;
2467                         if(r <= 1)
2468                                 b = f;
2469                         else
2470                                 r = (r - 1) / (n - 1);
2471                 }
2472         }
2473
2474         return b;
2475 }
2476
2477 float randombits(float bits, float k, float error_return)
2478 {
2479         float r;
2480         r = 0;
2481         while(k > 0 && bits != r)
2482         {
2483                 r += randombit(bits - r);
2484                 --k;
2485         }
2486         if(error_return)
2487                 if(k > 0)
2488                         return -1; // all
2489         return r;
2490 }
2491
2492 void randombit_test(float bits, float iter)
2493 {
2494         while(iter > 0)
2495         {
2496                 print(ftos(randombit(bits)), "\n");
2497                 --iter;
2498         }
2499 }
2500
2501 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2502 {
2503         if(halflifedist > 0)
2504                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2505         else if(halflifedist < 0)
2506                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2507         else
2508                 return 1;
2509 }
2510
2511
2512
2513
2514 #ifdef RELEASE
2515 #define cvar_string_normal builtin_cvar_string
2516 #define cvar_normal builtin_cvar
2517 #else
2518 string cvar_string_normal(string n)
2519 {
2520         if not(cvar_type(n) & 1)
2521                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2522         return builtin_cvar_string(n);
2523 }
2524
2525 float cvar_normal(string n)
2526 {
2527         return stof(cvar_string_normal(n));
2528 }
2529 #endif
2530 #define cvar_set_normal builtin_cvar_set
2531
2532 void defer_think()
2533 {
2534     entity oself;
2535
2536     oself           = self;
2537     self            = self.owner;
2538     oself.think     = SUB_Remove;
2539     oself.nextthink = time;
2540
2541     oself.use();
2542 }
2543
2544 /*
2545     Execute func() after time + fdelay.
2546     self when func is executed = self when defer is called
2547 */
2548 void defer(float fdelay, void() func)
2549 {
2550     entity e;
2551
2552     e           = spawn();
2553     e.owner     = self;
2554     e.use       = func;
2555     e.think     = defer_think;
2556     e.nextthink = time + fdelay;
2557 }
2558
2559 .string aiment_classname;
2560 .float aiment_deadflag;
2561 void SetMovetypeFollow(entity ent, entity e)
2562 {
2563         // FIXME this may not be warpzone aware
2564         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2565         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2566         ent.aiment = e; // make the hole follow bmodel
2567         ent.punchangle = e.angles; // the original angles of bmodel
2568         ent.view_ofs = ent.origin - e.origin; // relative origin
2569         ent.v_angle = ent.angles - e.angles; // relative angles
2570         ent.aiment_classname = strzone(e.classname);
2571         ent.aiment_deadflag = e.deadflag;
2572 }
2573 void UnsetMovetypeFollow(entity ent)
2574 {
2575         ent.movetype = MOVETYPE_FLY;
2576         PROJECTILE_MAKETRIGGER(ent);
2577         ent.aiment = world;
2578 }
2579 float LostMovetypeFollow(entity ent)
2580 {
2581 /*
2582         if(ent.movetype != MOVETYPE_FOLLOW)
2583                 if(ent.aiment)
2584                         error("???");
2585 */
2586         if(ent.aiment)
2587         {
2588                 if(ent.aiment.classname != ent.aiment_classname)
2589                         return 1;
2590                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2591                         return 1;
2592         }
2593         return 0;
2594 }
2595
2596 float isPushable(entity e)
2597 {
2598         if(e.iscreature)
2599                 return TRUE;
2600         if(e.pushable)
2601                 return TRUE;
2602         switch(e.classname)
2603         {
2604                 case "body":
2605                 case "droppedweapon":
2606                 case "keepawayball":
2607                 case "nexball_basketball":
2608                 case "nexball_football":
2609                         return TRUE;
2610                 case "bullet": // antilagged bullets can't hit this either
2611                         return FALSE;
2612         }
2613         if (e.projectiledeathtype)
2614                 return TRUE;
2615         return FALSE;
2616 }