]> git.xonotic.org Git - xonotic/xonotic-data.pk3dir.git/blob - qcsrc/server/main.qc
Implement autopause for empty dedicated servers
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / main.qc
1 #include "main.qh"
2
3 #include <common/command/generic.qh>
4 #include <common/constants.qh>
5 #include <common/deathtypes/all.qh>
6 #include <common/debug.qh>
7 #include <common/mapinfo.qh>
8 #include <common/monsters/sv_monsters.qh>
9 #include <common/util.qh>
10 #include <common/vehicles/all.qh>
11 #include <common/weapons/_all.qh>
12 #include <lib/csqcmodel/sv_model.qh>
13 #include <lib/warpzone/common.qh>
14 #include <lib/warpzone/server.qh>
15 #include <server/anticheat.qh>
16 #include <server/bot/api.qh>
17 #include <server/command/common.qh>
18 #include <server/compat/quake3.qh>
19 #include <server/damage.qh>
20 #include <server/gamelog.qh>
21 #include <server/hook.qh>
22 #include <server/ipban.qh>
23 #include <server/mutators/_mod.qh>
24 #include <server/spawnpoints.qh>
25 #include <server/weapons/common.qh>
26 #include <server/weapons/csqcprojectile.qh>
27 #include <server/world.qh>
28
29 void dropclient_do(entity this)
30 {
31         if (this.owner)
32                 dropclient(this.owner);
33         delete(this);
34 }
35 /**
36  * Schedules dropclient for a player and returns true;
37  * if dropclient is already scheduled (for that player) it does nothing and returns false.
38  *
39  * NOTE: this function exists only to allow sending a message to the kicked player with
40  * Send_Notification, which doesn't work if called together with dropclient
41  */
42 bool dropclient_schedule(entity this)
43 {
44         bool scheduled = false;
45         FOREACH_ENTITY_CLASS("dropclient_handler", true,
46         {
47                 if(it.owner == this)
48                 {
49                         scheduled = true;
50                         break; // can't use return here, compiler shows a warning
51                 }
52         });
53         if (scheduled)
54                 return false;
55
56         entity e = new_pure(dropclient_handler);
57         setthink(e, dropclient_do);
58         e.owner = this;
59         e.nextthink = time + 0.1;
60         return true;
61 }
62
63 void CreatureFrame_hotliquids(entity this)
64 {
65         if (this.contents_damagetime >= time)
66         {
67                 return;
68         }
69
70         this.contents_damagetime = time + autocvar_g_balance_contents_damagerate;
71
72         if (this.flags & FL_PROJECTILE)
73         {
74                 if (this.watertype == CONTENT_LAVA)
75                         Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
76                 else if (this.watertype == CONTENT_SLIME)
77                         Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
78         }
79         else
80         {
81                 if (STAT(FROZEN, this))
82                 {
83                         if (this.watertype == CONTENT_LAVA)
84                                 Damage(this, NULL, NULL, 10000, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
85                         else if (this.watertype == CONTENT_SLIME)
86                                 Damage(this, NULL, NULL, 10000, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
87                 }
88                 else if (this.watertype == CONTENT_LAVA)
89                 {
90                         if (this.watersound_finished < time)
91                         {
92                                 this.watersound_finished = time + 0.5;
93                                 sound (this, CH_PLAYER_SINGLE, SND_LAVA, VOL_BASE, ATTEN_NORM);
94                         }
95                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_lava * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
96                         if(autocvar_g_balance_contents_playerdamage_lava_burn)
97                                 Fire_AddDamage(this, NULL, autocvar_g_balance_contents_playerdamage_lava_burn * this.waterlevel, autocvar_g_balance_contents_playerdamage_lava_burn_time * this.waterlevel, DEATH_LAVA.m_id);
98                 }
99                 else if (this.watertype == CONTENT_SLIME)
100                 {
101                         if (this.watersound_finished < time)
102                         {
103                                 this.watersound_finished = time + 0.5;
104                                 sound (this, CH_PLAYER_SINGLE, SND_SLIME, VOL_BASE, ATTEN_NORM);
105                         }
106                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_slime * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
107                 }
108         }
109 }
110
111 void CreatureFrame_Liquids(entity this)
112 {
113         if (this.watertype <= CONTENT_WATER && this.waterlevel > 0) // workaround a retarded bug made by id software :P (yes, it's that old of a bug)
114         {
115                 if (!(this.flags & FL_INWATER))
116                 {
117                         this.flags |= FL_INWATER;
118                         this.contents_damagetime = 0;
119                 }
120
121                 CreatureFrame_hotliquids(this);
122         }
123         else
124         {
125                 if (this.flags & FL_INWATER)
126                 {
127                         // play leave water sound
128                         this.flags &= ~FL_INWATER;
129                         this.contents_damagetime = 0;
130                 }
131         }
132 }
133
134 void CreatureFrame_FallDamage(entity this)
135 {
136         if(IS_VEHICLE(this) || (this.flags & FL_PROJECTILE))
137                 return; // vehicles and projectiles don't receive fall damage
138         if(!(this.velocity || this.oldvelocity))
139                 return; // if the entity hasn't moved and isn't moving, then don't do anything
140
141         // check for falling damage
142         bool have_hook = false;
143         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
144         {
145             .entity weaponentity = weaponentities[slot];
146             if(this.(weaponentity).hook && this.(weaponentity).hook.state)
147             {
148                 have_hook = true;
149                 break;
150             }
151         }
152         if(!have_hook)
153         {
154                 float dm; // dm is the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
155                 if(autocvar_g_balance_falldamage_onlyvertical)
156                         dm = fabs(this.oldvelocity.z) - vlen(this.velocity);
157                 else
158                         dm = vlen(this.oldvelocity) - vlen(this.velocity);
159                 if (IS_DEAD(this))
160                         dm = (dm - autocvar_g_balance_falldamage_deadminspeed) * autocvar_g_balance_falldamage_factor;
161                 else
162                         dm = min((dm - autocvar_g_balance_falldamage_minspeed) * autocvar_g_balance_falldamage_factor, autocvar_g_balance_falldamage_maxdamage);
163                 if (dm > 0)
164                 {
165                         tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 1', MOVE_NOMONSTERS, this);
166                         if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODAMAGE))
167                                 Damage (this, NULL, NULL, dm, DEATH_FALL.m_id, DMG_NOWEP, this.origin, '0 0 0');
168                 }
169         }
170
171         if(autocvar_g_maxspeed > 0 && vdist(this.velocity, >, autocvar_g_maxspeed))
172                 Damage (this, NULL, NULL, 100000, DEATH_SHOOTING_STAR.m_id, DMG_NOWEP, this.origin, '0 0 0');
173 }
174
175 void CreatureFrame_All()
176 {
177         if(game_stopped || time < game_starttime)
178                 return;
179
180         IL_EACH(g_damagedbycontents, it.damagedbycontents,
181         {
182                 if (it.move_movetype == MOVETYPE_NOCLIP) continue;
183                 CreatureFrame_Liquids(it);
184                 CreatureFrame_FallDamage(it);
185                 it.oldvelocity = it.velocity;
186         });
187 }
188
189 void Pause_TryPause_Dedicated(entity this)
190 {
191         if (player_count == 0)
192                 setpause(1);
193 }
194
195 void Pause_TryPause(bool ispaused)
196 {
197         int n = 0;
198         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
199                 if (PHYS_INPUT_BUTTON_CHAT(it) != ispaused) return;
200                 ++n;
201         });
202         if (!n) return;
203         setpause(ispaused);
204 }
205
206 void SV_PausedTic(float elapsedtime)
207 {
208         if (!server_is_dedicated) Pause_TryPause(false);
209 }
210
211 void dedicated_print(string input)
212 {
213         if (server_is_dedicated) print(input);
214 }
215
216 void make_safe_for_remove(entity e)
217 {
218     if (e.initialize_entity)
219     {
220         entity ent, prev = NULL;
221         for (ent = initialize_entity_first; ent; )
222         {
223             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
224             {
225                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
226                 // skip it in linked list
227                 if (prev)
228                 {
229                     prev.initialize_entity_next = ent.initialize_entity_next;
230                     ent = prev.initialize_entity_next;
231                 }
232                 else
233                 {
234                     initialize_entity_first = ent.initialize_entity_next;
235                     ent = initialize_entity_first;
236                 }
237             }
238             else
239             {
240                 prev = ent;
241                 ent = ent.initialize_entity_next;
242             }
243         }
244     }
245 }
246
247 void remove_except_protected(entity e)
248 {
249         if(e.remove_except_protected_forbidden)
250                 error("not allowed to remove this at this point");
251         builtin_remove(e);
252 }
253
254 void remove_unsafely(entity e)
255 {
256     if(e.classname == "spike")
257         error("Removing spikes is forbidden (crylink bug), please report");
258     builtin_remove(e);
259 }
260
261 void remove_safely(entity e)
262 {
263     make_safe_for_remove(e);
264     builtin_remove(e);
265 }
266
267 /*
268 =============
269 StartFrame
270
271 Called before each frame by the server
272 =============
273 */
274
275 bool game_delay_last;
276
277 void systems_update();
278 void sys_phys_update(entity this, float dt);
279 void StartFrame()
280 {
281     // TODO: if move is more than 50ms, split it into two moves (this matches QWSV behavior and the client prediction)
282     IL_EACH(g_players, IS_FAKE_CLIENT(it), sys_phys_update(it, frametime));
283     IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPreThink(it));
284
285         execute_next_frame();
286         if (autocvar_sv_autopause && !server_is_dedicated) Pause_TryPause(true);
287
288         delete_fn = remove_unsafely; // not during spawning!
289         serverprevtime = servertime;
290         servertime = time;
291         serverframetime = frametime;
292
293 #ifdef PROFILING
294         if(time > client_cefc_accumulatortime + 1)
295         {
296                 float t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
297                 int c_seeing = 0;
298                 int c_seen = 0;
299                 FOREACH_CLIENT(true, {
300                         if(IS_REAL_CLIENT(it))
301                                 ++c_seeing;
302                         if(IS_PLAYER(it))
303                                 ++c_seen;
304                 });
305                 LOG_INFO(
306                     "CEFC time: ", ftos(t * 1000), "ms; ",
307             "CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ",
308             "CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0')
309         );
310                 client_cefc_accumulatortime = time;
311                 client_cefc_accumulator = 0;
312         }
313 #endif
314
315         IL_EACH(g_projectiles, it.csqcprojectile_clientanimate, CSQCProjectile_Check(it));
316
317         if (RedirectionThink()) return;
318
319         UncustomizeEntitiesRun();
320         InitializeEntitiesRun();
321
322         WarpZone_StartFrame();
323
324         sys_frametime = autocvar_sys_ticrate * autocvar_slowmo;
325         if (sys_frametime <= 0) sys_frametime = 1.0 / 60.0; // somewhat safe fallback
326
327         if (timeout_status == TIMEOUT_LEADTIME) // just before the timeout (when timeout_status will be TIMEOUT_ACTIVE)
328                 orig_slowmo = autocvar_slowmo; // slowmo will be restored after the timeout
329
330         // detect when the pre-game countdown (if any) has ended and the game has started
331         bool game_delay = (time < game_starttime);
332         if (autocvar_sv_eventlog && game_delay_last && !game_delay)
333                 GameLogEcho(":startdelay_ended");
334         game_delay_last = game_delay;
335
336         CreatureFrame_All();
337         CheckRules_World();
338
339         if (warmup_stage && !game_stopped && warmup_limit > 0 && time - game_starttime >= warmup_limit) {
340                 ReadyRestart(true);
341                 return;
342         }
343
344         bot_serverframe();
345         anticheat_startframe();
346         MUTATOR_CALLHOOK(SV_StartFrame);
347
348         GlobalStats_updateglobal();
349     FOREACH_CLIENT(true, GlobalStats_update(it));
350     IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPostThink(it));
351 }
352
353 .vector originjitter;
354 .vector anglesjitter;
355 .float anglejitter;
356 .string gametypefilter;
357 .string cvarfilter;
358
359 void SV_OnEntityPreSpawnFunction(entity this)
360 {
361         if (this)
362         if (this.gametypefilter != "")
363         if (!isGametypeInFilter(MapInfo_LoadedGametype, teamplay, have_team_spawns, this.gametypefilter))
364         {
365                 delete(this);
366                 return;
367         }
368         if (this.cvarfilter != "" && !expr_evaluate(this.cvarfilter)) {
369                 delete(this);
370                 return;
371         }
372
373         if (q3compat && DoesQ3ARemoveThisEntity(this)) {
374                 delete(this);
375                 return;
376         }
377
378         set_movetype(this, this.movetype);
379
380         if (this.monster_attack) {
381                 IL_PUSH(g_monster_targets, this);
382     }
383
384         // support special -1 and -2 angle from radiant
385         if (this.angles == '0 -1 0') {
386                 this.angles = '-90 0 0';
387         } else if (this.angles == '0 -2 0') {
388                 this.angles = '+90 0 0';
389     }
390
391     #define X(out, in) MACRO_BEGIN \
392         if (in != 0) { out = out + (random() * 2 - 1) * in; } \
393     MACRO_END
394     X(this.origin.x, this.originjitter.x); X(this.origin.y, this.originjitter.y); X(this.origin.z, this.originjitter.z);
395     X(this.angles.x, this.anglesjitter.x); X(this.angles.y, this.anglesjitter.y); X(this.angles.z, this.anglesjitter.z);
396     X(this.angles.y, this.anglejitter);
397     #undef X
398
399         if (MUTATOR_CALLHOOK(OnEntityPreSpawn, this)) {
400                 delete(this);
401                 return;
402         }
403 }
404
405 string GetField_fullspawndata(entity e, string f, ...)
406 /* Retrieves the value of a map entity field from fullspawndata
407  * This bypasses field value changes made by the engine,
408  * eg string-to-float and escape sequence substitution.
409  *
410  * Avoids the need to declare fields just to read them once :)
411  *
412  * Returns the last instance of the field to match DarkPlaces behaviour.
413  * Path support: converts \ to / and tests the file if a third (bool, true) arg is passed.
414  * Returns string_null if the entity does not have the field, or the file is not in the VFS.
415  *
416  * FIXME: entities with //comments are not supported.
417  */
418 {
419         string v = string_null;
420
421         if (!e.fullspawndata)
422         {
423                 //LOG_WARNF("^1EDICT %s (classname %s) has no fullspawndata, engine lacks support?", ftos(num_for_edict(e)), e.classname);
424                 return v;
425         }
426
427         if (strstrofs(e.fullspawndata, "//", 0) >= 0)
428         {
429                 // tokenize and tokenize_console return early if "//" is reached,
430                 // which can leave an odd number of tokens and break key:value pairing.
431                 LOG_WARNF("^1EDICT %s fullspawndata contains unsupported //comment^7%s", ftos(num_for_edict(e)), e.fullspawndata);
432                 return v;
433         }
434
435         //print(sprintf("%s(EDICT %s, FIELD %s)\n", __FUNC__, ftos(num_for_edict(e)), f));
436         //print(strcat("FULLSPAWNDATA:", e.fullspawndata, "\n"));
437
438         // tokenize treats \ as an escape, but tokenize_console returns the required literal
439         for (int t = tokenize_console(e.fullspawndata) - 3; t > 0; t -= 2)
440         {
441                 //print(sprintf("\tTOKEN %s:%s\t%s:%s\n", ftos(t), ftos(t + 1), argv(t), argv(t + 1)));
442                 if (argv(t) == f)
443                 {
444                         v = argv(t + 1);
445                         break;
446                 }
447         }
448
449         //print(strcat("RESULT: ", v, "\n\n"));
450
451         if (v && ...(0, bool) == true)
452         {
453                 v = strreplace("\\", "/", v);
454                 if (whichpack(v) == "")
455                         return string_null;
456         }
457
458         return v;
459 }
460
461 void WarpZone_PostInitialize_Callback()
462 {
463         // create waypoint links for warpzones
464         entity tracetest_ent = spawn();
465         setsize(tracetest_ent, PL_MIN_CONST, PL_MAX_CONST);
466         tracetest_ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
467         //for(entity e = warpzone_first; e; e = e.warpzone_next)
468         for(entity e = NULL; (e = find(e, classname, "trigger_warpzone")); )
469                 waypoint_spawnforteleporter_wz(e, tracetest_ent);
470         delete(tracetest_ent);
471 }
472
473 /** engine callback */
474 void URI_Get_Callback(float id, float status, string data)
475 {
476         if(url_URI_Get_Callback(id, status, data))
477         {
478                 // handled
479         }
480         else if (id == URI_GET_DISCARD)
481         {
482                 // discard
483         }
484         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
485         {
486                 // sv_cmd curl
487                 Curl_URI_Get_Callback(id, status, data);
488         }
489         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
490         {
491                 // online ban list
492                 OnlineBanList_URI_Get_Callback(id, status, data);
493         }
494         else if (MUTATOR_CALLHOOK(URI_GetCallback, id, status, data))
495         {
496                 // handled by a mutator
497         }
498         else
499         {
500                 LOG_INFO("Received HTTP request data for an invalid id ", ftos(id), ".");
501         }
502 }
503
504 /*
505 ==================
506 main
507
508 unused but required by the engine
509 ==================
510 */
511 void main ()
512 {
513
514 }