qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/bot.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "cl_client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include "ipban.qh"
  15 #include "mapvoting.qh"
  16 #include "mutators/all.qh"
  17 #include "race.qh"
  18 #include "scores.qh"
  19 #include "teamplay.qh"
  20 #include "weapons/weaponstats.qh"
  21 #include "../common/buffs/all.qh"
  22 #include "../common/constants.qh"
  23 #include "../common/deathtypes/all.qh"
  24 #include "../common/mapinfo.qh"
  25 #include "../common/monsters/all.qh"
  26 #include "../common/monsters/sv_monsters.qh"
  27 #include "../common/vehicles/all.qh"
  28 #include "../common/notifications.qh"
  29 #include "../common/physics.qh"
  30 #include "../common/playerstats.qh"
  31 #include "../common/stats.qh"
  32 #include "../common/teams.qh"
  33 #include "../common/triggers/trigger/secret.qh"
  34 #include "../common/triggers/target/music.qh"
  35 #include "../common/util.qh"
  36 #include "../common/items/all.qh"
  37 #include "../common/weapons/all.qh"
  38
  39 const float LATENCY_THINKRATE = 10;
  40 .float latency_sum;
  41 .float latency_cnt;
  42 .float latency_time;
  43 entity pingplreport;
  44 void PingPLReport_Think()
  45 {SELFPARAM();
  46         float delta;
  47         entity e;
  48
  49         delta = 3 / maxclients;
  50         if(delta < sys_frametime)
  51                 delta = 0;
  52         self.nextthink = time + delta;
  53
  54         e = edict_num(self.cnt + 1);
  55         if(IS_REAL_CLIENT(e))
  56         {
  57                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  58                 WriteByte(MSG_BROADCAST, self.cnt);
  59                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  60                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  61                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  62
  63                 // record latency times for clients throughout the match so we can report it to playerstats
  64                 if(time > (e.latency_time + LATENCY_THINKRATE))
  65                 {
  66                         e.latency_sum += e.ping;
  67                         e.latency_cnt += 1;
  68                         e.latency_time = time;
  69                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  70                 }
  71         }
  72         else
  73         {
  74                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  75                 WriteByte(MSG_BROADCAST, self.cnt);
  76                 WriteShort(MSG_BROADCAST, 0);
  77                 WriteByte(MSG_BROADCAST, 0);
  78                 WriteByte(MSG_BROADCAST, 0);
  79         }
  80         self.cnt = (self.cnt + 1) % maxclients;
  81 }
  82 void PingPLReport_Spawn()
  83 {
  84         pingplreport = new(pingplreport);
  85         make_pure(pingplreport);
  86         pingplreport.think = PingPLReport_Think;
  87         pingplreport.nextthink = time;
  88 }
  89
  90 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  91 string redirection_target;
  92 float world_initialized;
  93
  94 string GetGametype();
  95 void ShuffleMaplist();
  96
  97 void SetDefaultAlpha()
  98 {
  99         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
 100         {
 101                 default_player_alpha = autocvar_g_player_alpha;
 102                 if(default_player_alpha == 0)
 103                         default_player_alpha = 1;
 104                 default_weapon_alpha = default_player_alpha;
 105         }
 106 }
 107
 108 void GotoFirstMap()
 109 {SELFPARAM();
 110         float n;
 111         if(autocvar__sv_init)
 112         {
 113                 // cvar_set("_sv_init", "0");
 114                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 115                 // to this "init" map on a dedicated server will cause no permanent
 116                 // harm
 117                 if(autocvar_g_maplist_shuffle)
 118                         ShuffleMaplist();
 119                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 120                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 121
 122                 MapInfo_Enumerate();
 123                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 124
 125                 if(!DoNextMapOverride(1))
 126                         GotoNextMap(1);
 127
 128                 return;
 129         }
 130
 131         if(time < 5)
 132         {
 133                 self.nextthink = time;
 134         }
 135         else
 136         {
 137                 self.nextthink = time + 1;
 138                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 139         }
 140 }
 141
 142 void cvar_changes_init()
 143 {
 144         float h;
 145         string k, v, d;
 146         float n, i, adding, pureadding;
 147
 148         if(cvar_changes)
 149                 strunzone(cvar_changes);
 150         cvar_changes = string_null;
 151         if(cvar_purechanges)
 152                 strunzone(cvar_purechanges);
 153         cvar_purechanges = string_null;
 154         cvar_purechanges_count = 0;
 155
 156         h = buf_create();
 157         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 158         n = buf_getsize(h);
 159
 160         adding = true;
 161         pureadding = true;
 162
 163         for(i = 0; i < n; ++i)
 164         {
 165                 k = bufstr_get(h, i);
 166
 167 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 168 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 169 #define BADCVAR(p) if(k == p) continue
 170
 171                 // general excludes and namespaces for server admin used cvars
 172                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 173
 174                 // internal
 175                 BADPREFIX("csqc_");
 176                 BADPREFIX("cvar_check_");
 177                 BADCVAR("gamecfg");
 178                 BADCVAR("g_configversion");
 179                 BADCVAR("g_maplist_index");
 180                 BADCVAR("halflifebsp");
 181                 BADCVAR("sv_mapformat_is_quake2");
 182                 BADCVAR("sv_mapformat_is_quake3");
 183                 BADPREFIX("sv_world");
 184
 185                 // client
 186                 BADPREFIX("chase_");
 187                 BADPREFIX("cl_");
 188                 BADPREFIX("con_");
 189                 BADPREFIX("scoreboard_");
 190                 BADPREFIX("g_campaign");
 191                 BADPREFIX("g_waypointsprite_");
 192                 BADPREFIX("gl_");
 193                 BADPREFIX("joy");
 194                 BADPREFIX("hud_");
 195                 BADPREFIX("m_");
 196                 BADPREFIX("menu_");
 197                 BADPREFIX("net_slist_");
 198                 BADPREFIX("r_");
 199                 BADPREFIX("sbar_");
 200                 BADPREFIX("scr_");
 201                 BADPREFIX("snd_");
 202                 BADPREFIX("show");
 203                 BADPREFIX("sensitivity");
 204                 BADPREFIX("userbind");
 205                 BADPREFIX("v_");
 206                 BADPREFIX("vid_");
 207                 BADPREFIX("crosshair");
 208                 BADCVAR("mod_q3bsp_lightmapmergepower");
 209                 BADCVAR("mod_q3bsp_nolightmaps");
 210                 BADCVAR("fov");
 211                 BADCVAR("mastervolume");
 212                 BADCVAR("volume");
 213                 BADCVAR("bgmvolume");
 214
 215                 // private
 216                 BADCVAR("developer");
 217                 BADCVAR("log_dest_udp");
 218                 BADCVAR("net_address");
 219                 BADCVAR("net_address_ipv6");
 220                 BADCVAR("port");
 221                 BADCVAR("savedgamecfg");
 222                 BADCVAR("serverconfig");
 223                 BADCVAR("sv_autoscreenshot");
 224                 BADCVAR("sv_heartbeatperiod");
 225                 BADCVAR("sv_vote_master_password");
 226                 BADCVAR("sys_colortranslation");
 227                 BADCVAR("sys_specialcharactertranslation");
 228                 BADCVAR("timeformat");
 229                 BADCVAR("timestamps");
 230                 BADPREFIX("developer_");
 231                 BADPREFIX("g_ban_");
 232                 BADPREFIX("g_banned_list");
 233                 BADPREFIX("g_chat_flood_");
 234                 BADPREFIX("g_ghost_items");
 235                 BADPREFIX("g_playerstats_");
 236                 BADPREFIX("g_respawn_ghosts");
 237                 BADPREFIX("g_voice_flood_");
 238                 BADPREFIX("log_file");
 239                 BADPREFIX("rcon_");
 240                 BADPREFIX("sv_allowdownloads");
 241                 BADPREFIX("sv_autodemo");
 242                 BADPREFIX("sv_curl_");
 243                 BADPREFIX("sv_eventlog");
 244                 BADPREFIX("sv_logscores_");
 245                 BADPREFIX("sv_master");
 246                 BADPREFIX("sv_weaponstats_");
 247                 BADPREFIX("sv_waypointsprite_");
 248                 BADCVAR("rescan_pending");
 249
 250                 // these can contain player IDs, so better hide
 251                 BADPREFIX("g_forced_team_");
 252
 253                 // mapinfo
 254                 BADCVAR("fraglimit");
 255                 BADCVAR("g_assault");
 256                 BADCVAR("g_ca");
 257                 BADCVAR("g_ca_teams");
 258                 BADCVAR("g_ctf");
 259                 BADCVAR("g_cts");
 260                 BADCVAR("g_dm");
 261                 BADCVAR("g_domination");
 262                 BADCVAR("g_domination_default_teams");
 263                 BADCVAR("g_freezetag");
 264                 BADCVAR("g_freezetag_teams");
 265                 BADCVAR("g_invasion_teams");
 266                 BADCVAR("g_keepaway");
 267                 BADCVAR("g_keyhunt");
 268                 BADCVAR("g_keyhunt_teams");
 269                 BADCVAR("g_lms");
 270                 BADCVAR("g_nexball");
 271                 BADCVAR("g_onslaught");
 272                 BADCVAR("g_race");
 273                 BADCVAR("g_race_qualifying_timelimit");
 274                 BADCVAR("g_tdm");
 275                 BADCVAR("g_tdm_teams");
 276                 BADCVAR("leadlimit");
 277                 BADCVAR("nextmap");
 278                 BADCVAR("teamplay");
 279                 BADCVAR("timelimit");
 280
 281                 // long
 282                 BADCVAR("hostname");
 283                 BADCVAR("g_maplist");
 284                 BADCVAR("g_maplist_mostrecent");
 285                 BADCVAR("sv_motd");
 286
 287                 v = cvar_string(k);
 288                 d = cvar_defstring(k);
 289                 if(v == d)
 290                         continue;
 291
 292                 if(adding)
 293                 {
 294                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 295                         if(strlen(cvar_changes) > 16384)
 296                         {
 297                                 cvar_changes = "// too many settings have been changed to show them here\n";
 298                                 adding = 0;
 299                         }
 300                 }
 301
 302                 // now check if the changes are actually gameplay relevant
 303
 304                 // does nothing visible
 305                 BADCVAR("captureleadlimit_override");
 306                 BADCVAR("g_balance_kill_delay");
 307                 BADCVAR("g_ca_point_limit");
 308                 BADCVAR("g_ca_point_leadlimit");
 309                 BADCVAR("g_ctf_captimerecord_always");
 310                 BADCVAR("g_ctf_flag_glowtrails");
 311                 BADCVAR("g_ctf_flag_pickup_verbosename");
 312                 BADCVAR("g_domination_point_leadlimit");
 313                 BADCVAR("g_forced_respawn");
 314                 BADCVAR("g_freezetag_point_limit");
 315                 BADCVAR("g_freezetag_point_leadlimit");
 316                 BADCVAR("g_keyhunt_point_leadlimit");
 317                 BADPREFIX("g_mod_");
 318                 BADCVAR("g_invasion_point_limit");
 319                 BADCVAR("g_nexball_goalleadlimit");
 320                 BADCVAR("g_tdm_point_limit");
 321                 BADCVAR("g_tdm_point_leadlimit");
 322                 BADCVAR("leadlimit_and_fraglimit");
 323                 BADCVAR("leadlimit_override");
 324                 BADCVAR("pausable");
 325                 BADCVAR("sv_allow_fullbright");
 326                 BADCVAR("sv_checkforpacketsduringsleep");
 327                 BADCVAR("sv_timeout");
 328                 BADPREFIX("sv_timeout_");
 329                 BADPREFIX("crypto_");
 330                 BADPREFIX("g_chat_");
 331                 BADPREFIX("g_ctf_captimerecord_");
 332                 BADPREFIX("g_maplist_votable_");
 333                 BADPREFIX("net_");
 334                 BADPREFIX("prvm_");
 335                 BADPREFIX("skill_");
 336                 BADPREFIX("sv_cullentities_");
 337                 BADPREFIX("sv_maxidle_");
 338                 BADPREFIX("sv_vote_");
 339                 BADPREFIX("timelimit_");
 340                 BADCVAR("gameversion");
 341                 BADPREFIX("gameversion_");
 342                 BADCVAR("sv_minigames");
 343                 BADPREFIX("sv_minigames_");
 344                 BADCVAR("sv_namechangetimer");
 345
 346                 // allowed changes to server admins (please sync this to server.cfg)
 347                 // vi commands:
 348                 //   :/"impure"/,$d
 349                 //   :g!,^\/\/[^ /],d
 350                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 351                 //   :%!sort
 352                 // yes, this does contain some redundant stuff, don't really care
 353                 BADCVAR("bot_config_file");
 354                 BADCVAR("bot_number");
 355                 BADCVAR("bot_prefix");
 356                 BADCVAR("bot_suffix");
 357                 BADCVAR("capturelimit_override");
 358                 BADCVAR("fraglimit_override");
 359                 BADCVAR("gametype");
 360                 BADCVAR("g_antilag");
 361                 BADCVAR("g_balance_teams");
 362                 BADCVAR("g_balance_teams_prevent_imbalance");
 363                 BADCVAR("g_balance_teams_scorefactor");
 364                 BADCVAR("g_ban_sync_trusted_servers");
 365                 BADCVAR("g_ban_sync_uri");
 366                 BADCVAR("g_ca_teams_override");
 367                 BADCVAR("g_ctf_ignore_frags");
 368                 BADCVAR("g_domination_point_limit");
 369                 BADCVAR("g_domination_teams_override");
 370                 BADCVAR("g_freezetag_teams_override");
 371                 BADCVAR("g_friendlyfire");
 372                 BADCVAR("g_fullbrightitems");
 373                 BADCVAR("g_fullbrightplayers");
 374                 BADCVAR("g_keyhunt_point_limit");
 375                 BADCVAR("g_keyhunt_teams_override");
 376                 BADCVAR("g_lms_lives_override");
 377                 BADCVAR("g_maplist");
 378                 BADCVAR("g_maplist_check_waypoints");
 379                 BADCVAR("g_maplist_mostrecent_count");
 380                 BADCVAR("g_maplist_shuffle");
 381                 BADCVAR("g_maplist_votable");
 382                 BADCVAR("g_maplist_votable_abstain");
 383                 BADCVAR("g_maplist_votable_nodetail");
 384                 BADCVAR("g_maplist_votable_suggestions");
 385                 BADCVAR("g_maxplayers");
 386                 BADCVAR("g_mirrordamage");
 387                 BADCVAR("g_nexball_goallimit");
 388                 BADCVAR("g_powerups");
 389                 BADCVAR("g_start_delay");
 390                 BADCVAR("g_tdm_teams_override");
 391                 BADCVAR("g_warmup");
 392                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 393                 BADCVAR("hostname");
 394                 BADCVAR("log_file");
 395                 BADCVAR("maxplayers");
 396                 BADCVAR("minplayers");
 397                 BADCVAR("net_address");
 398                 BADCVAR("port");
 399                 BADCVAR("rcon_password");
 400                 BADCVAR("rcon_restricted_commands");
 401                 BADCVAR("rcon_restricted_password");
 402                 BADCVAR("skill");
 403                 BADCVAR("sv_adminnick");
 404                 BADCVAR("sv_autoscreenshot");
 405                 BADCVAR("sv_autotaunt");
 406                 BADCVAR("sv_curl_defaulturl");
 407                 BADCVAR("sv_defaultcharacter");
 408                 BADCVAR("sv_defaultplayercolors");
 409                 BADCVAR("sv_defaultplayermodel");
 410                 BADCVAR("sv_defaultplayerskin");
 411                 BADCVAR("sv_maxidle");
 412                 BADCVAR("sv_maxrate");
 413                 BADCVAR("sv_motd");
 414                 BADCVAR("sv_public");
 415                 BADCVAR("sv_ready_restart");
 416                 BADCVAR("sv_status_privacy");
 417                 BADCVAR("sv_taunt");
 418                 BADCVAR("sv_vote_call");
 419                 BADCVAR("sv_vote_commands");
 420                 BADCVAR("sv_vote_majority_factor");
 421                 BADCVAR("sv_vote_master");
 422                 BADCVAR("sv_vote_master_commands");
 423                 BADCVAR("sv_vote_master_password");
 424                 BADCVAR("sv_vote_simple_majority_factor");
 425                 BADCVAR("teamplay_mode");
 426                 BADCVAR("timelimit_override");
 427                 BADCVAR("g_spawnshieldtime");
 428                 BADPREFIX("g_warmup_");
 429                 BADPREFIX("sv_ready_restart_");
 430
 431                 // mutators that announce themselves properly to the server browser
 432                 BADCVAR("g_instagib");
 433                 BADCVAR("g_new_toys");
 434                 BADCVAR("g_nix");
 435                 BADCVAR("g_grappling_hook");
 436                 BADCVAR("g_jetpack");
 437
 438 #undef BADPREFIX
 439 #undef BADCVAR
 440
 441                 if(pureadding)
 442                 {
 443                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 444                         if(strlen(cvar_purechanges) > 16384)
 445                         {
 446                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 447                                 pureadding = 0;
 448                         }
 449                 }
 450                 ++cvar_purechanges_count;
 451                 // WARNING: this variable is used for the server list
 452                 // NEVER dare to skip this code!
 453                 // Hacks to intentionally appearing as "pure server" even though you DO have
 454                 // modified settings may be punished by removal from the server list.
 455                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 456                 // though.
 457         }
 458         buf_del(h);
 459         if(cvar_changes == "")
 460                 cvar_changes = "// this server runs at default server settings\n";
 461         else
 462                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 463         cvar_changes = strzone(cvar_changes);
 464         if(cvar_purechanges == "")
 465                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 466         else
 467                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 468         cvar_purechanges = strzone(cvar_purechanges);
 469 }
 470
 471 void detect_maptype()
 472 {
 473 #if 0
 474         vector o, v;
 475         float i;
 476
 477         for (;;)
 478         {
 479                 o = world.mins;
 480                 o.x += random() * (world.maxs.x - world.mins.x);
 481                 o.y += random() * (world.maxs.y - world.mins.y);
 482                 o.z += random() * (world.maxs.z - world.mins.z);
 483
 484                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 485                 if(trace_fraction == 1)
 486                         continue;
 487
 488                 v = trace_endpos;
 489
 490                 for(i = 0; i < 64; i += 4)
 491                 {
 492                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 493         if(trace_fraction == 1)
 494                 continue;
 495                         LOG_INFO(ftos(i), " -> ", vtos(trace_endpos), "\n");
 496                 }
 497
 498                 break;
 499         }
 500 #endif
 501 }
 502
 503 entity randomseed;
 504 bool RandomSeed_Send(entity this, entity to, int sf)
 505 {
 506         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 507         WriteShort(MSG_ENTITY, self.cnt);
 508         return true;
 509 }
 510 void RandomSeed_Think()
 511 {SELFPARAM();
 512         self.cnt = bound(0, floor(random() * 65536), 65535);
 513         self.nextthink = time + 5;
 514
 515         self.SendFlags |= 1;
 516 }
 517 void RandomSeed_Spawn()
 518 {SELFPARAM();
 519         randomseed = new(randomseed);
 520         make_pure(randomseed);
 521         randomseed.think = RandomSeed_Think;
 522         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 523
 524         WITH(entity, self, randomseed, randomseed.think()); // sets random seed and nextthink
 525 }
 526
 527 spawnfunc(__init_dedicated_server)
 528 {
 529         // handler for _init/_init map (only for dedicated server initialization)
 530
 531         world_initialized = -1; // don't complain
 532         cvar = cvar_normal;
 533         cvar_string = cvar_string_normal;
 534         cvar_set = cvar_set_normal;
 535
 536         remove = remove_unsafely;
 537
 538         entity e = spawn();
 539         e.think = GotoFirstMap;
 540         e.nextthink = time; // this is usually 1 at this point
 541
 542         e = new(info_player_deathmatch);  // safeguard against player joining
 543
 544         self.classname = "worldspawn"; // safeguard against various stuff ;)
 545
 546         // needs to be done so early because of the constants they create
 547         static_init();
 548         static_init_late();
 549         static_init_precache();
 550
 551         MapInfo_Enumerate();
 552         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 553 }
 554
 555 void Map_MarkAsRecent(string m);
 556 float world_already_spawned;
 557 void Nagger_Init();
 558 void ClientInit_Spawn();
 559 void WeaponStats_Init();
 560 void WeaponStats_Shutdown();
 561 void Physics_AddStats();
 562 spawnfunc(worldspawn)
 563 {
 564         float fd, l, j, n;
 565         string s;
 566
 567         cvar = cvar_normal;
 568         cvar_string = cvar_string_normal;
 569         cvar_set = cvar_set_normal;
 570
 571         if(world_already_spawned)
 572                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 573         world_already_spawned = true;
 574
 575         remove = remove_safely; // during spawning, watch what you remove!
 576
 577         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 578
 579         compressShortVector_init();
 580
 581         entity head;
 582         head = nextent(world);
 583         maxclients = 0;
 584         while(head)
 585         {
 586                 ++maxclients;
 587                 head = nextent(head);
 588         }
 589
 590         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? true : false);
 591
 592         // needs to be done so early because of the constants they create
 593         static_init();
 594
 595         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 596
 597         TemporaryDB = db_create();
 598
 599         // 0 normal
 600         lightstyle(0, "m");
 601
 602         // 1 FLICKER (first variety)
 603         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 604
 605         // 2 SLOW STRONG PULSE
 606         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 607
 608         // 3 CANDLE (first variety)
 609         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 610
 611         // 4 FAST STROBE
 612         lightstyle(4, "mamamamamama");
 613
 614         // 5 GENTLE PULSE 1
 615         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 616
 617         // 6 FLICKER (second variety)
 618         lightstyle(6, "nmonqnmomnmomomno");
 619
 620         // 7 CANDLE (second variety)
 621         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 622
 623         // 8 CANDLE (third variety)
 624         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 625
 626         // 9 SLOW STROBE (fourth variety)
 627         lightstyle(9, "aaaaaaaazzzzzzzz");
 628
 629         // 10 FLUORESCENT FLICKER
 630         lightstyle(10, "mmamammmmammamamaaamammma");
 631
 632         // 11 SLOW PULSE NOT FADE TO BLACK
 633         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 634
 635         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 636
 637         // 63 testing
 638         lightstyle(63, "a");
 639
 640         if(autocvar_g_campaign)
 641                 CampaignPreInit();
 642
 643         Map_MarkAsRecent(mapname);
 644
 645         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 646
 647         InitGameplayMode();
 648         static_init_late();
 649         static_init_precache();
 650         readlevelcvars();
 651         GrappleHookInit();
 652
 653         player_count = 0;
 654         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 655         if(bot_waypoints_for_items == 1)
 656                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 657                         bot_waypoints_for_items = 0;
 658
 659         precache();
 660
 661         WaypointSprite_Init();
 662
 663         GameLogInit(); // prepare everything
 664         // NOTE for matchid:
 665         // changing the logic generating it is okay. But:
 666         // it HAS to stay <= 64 chars
 667         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 668         if(autocvar_sv_eventlog)
 669         {
 670                 s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 671                 matchid = strzone(s);
 672
 673                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 674                 s = ":gameinfo:mutators:LIST";
 675
 676                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 677                 s = ret_string;
 678
 679                 // initialiation stuff, not good in the mutator system
 680                 if(!autocvar_g_use_ammunition)
 681                         s = strcat(s, ":no_use_ammunition");
 682
 683                 // initialiation stuff, not good in the mutator system
 684                 if(autocvar_g_pickup_items == 0)
 685                         s = strcat(s, ":no_pickup_items");
 686                 if(autocvar_g_pickup_items > 0)
 687                         s = strcat(s, ":pickup_items");
 688
 689                 // initialiation stuff, not good in the mutator system
 690                 if(autocvar_g_weaponarena != "0")
 691                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 692
 693                 // TODO to mutator system
 694                 if(autocvar_g_norecoil)
 695                         s = strcat(s, ":norecoil");
 696
 697                 // TODO to mutator system
 698                 if(autocvar_g_powerups == 0)
 699                         s = strcat(s, ":no_powerups");
 700                 if(autocvar_g_powerups > 0)
 701                         s = strcat(s, ":powerups");
 702
 703                 GameLogEcho(s);
 704                 GameLogEcho(":gameinfo:end");
 705         }
 706         else
 707                 matchid = strzone(ftos(random()));
 708
 709         cvar_set("nextmap", "");
 710
 711         SetDefaultAlpha();
 712
 713         if(autocvar_g_campaign)
 714                 CampaignPostInit();
 715
 716         Ban_LoadBans();
 717
 718         MapInfo_Enumerate();
 719         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 720
 721         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 722         {
 723                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 724                 if(fd != -1)
 725                 {
 726                         while((s = fgets(fd)))
 727                         {
 728                                 l = tokenize_console(s);
 729                                 if(l < 2)
 730                                         continue;
 731                                 if(argv(0) == "cd")
 732                                 {
 733                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 734                                         LOG_INFO("  cdtrack ", argv(2), "\n");
 735                                 }
 736                                 else if(argv(0) == "fog")
 737                                 {
 738                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 739                                         LOG_INFO("  \"fog\" \"", s, "\"\n");
 740                                 }
 741                                 else if(argv(0) == "set")
 742                                 {
 743                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 744                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 745                                 }
 746                                 else if(argv(0) != "//")
 747                                 {
 748                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 749                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 750                                 }
 751                         }
 752                         fclose(fd);
 753                 }
 754         }
 755
 756         WeaponStats_Init();
 757
 758         WepSet_AddStat();
 759         WepSet_AddStat_InMap();
 760         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 761         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 762         Nagger_Init();
 763
 764         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 765         addstat(STAT_PLASMA, AS_INT, ammo_plasma);
 766         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 767         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 768         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 769         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 770         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 771         addstat(STAT_DAMAGE_DEALT_TOTAL, AS_INT, damage_dealt_total);
 772         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 773         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 774
 775         addstat(STAT_VORTEX_CHARGE, AS_FLOAT, vortex_charge);
 776         addstat(STAT_VORTEX_CHARGEPOOL, AS_FLOAT, vortex_chargepool_ammo);
 777
 778         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 779
 780         // freeze attacks
 781         addstat(STAT_FROZEN, AS_INT, frozen);
 782         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 783
 784         // physics
 785         Physics_AddStats();
 786
 787         // new properties
 788         addstat(STAT_MOVEVARS_JUMPVELOCITY, AS_FLOAT, stat_sv_jumpvelocity);
 789         addstat(STAT_MOVEVARS_AIRACCEL_QW_STRETCHFACTOR, AS_FLOAT, stat_sv_airaccel_qw_stretchfactor);
 790         addstat(STAT_MOVEVARS_MAXAIRSTRAFESPEED, AS_FLOAT, stat_sv_maxairstrafespeed);
 791         addstat(STAT_MOVEVARS_MAXAIRSPEED, AS_FLOAT, stat_sv_maxairspeed);
 792         addstat(STAT_MOVEVARS_AIRSTRAFEACCELERATE, AS_FLOAT, stat_sv_airstrafeaccelerate);
 793         addstat(STAT_MOVEVARS_WARSOWBUNNY_TURNACCEL, AS_FLOAT, stat_sv_warsowbunny_turnaccel);
 794         addstat(STAT_MOVEVARS_AIRACCEL_SIDEWAYS_FRICTION, AS_FLOAT, stat_sv_airaccel_sideways_friction);
 795         addstat(STAT_MOVEVARS_AIRCONTROL, AS_FLOAT, stat_sv_aircontrol);
 796         addstat(STAT_MOVEVARS_AIRCONTROL_POWER, AS_FLOAT, stat_sv_aircontrol_power);
 797         addstat(STAT_MOVEVARS_AIRCONTROL_PENALTY, AS_FLOAT, stat_sv_aircontrol_penalty);
 798         addstat(STAT_MOVEVARS_WARSOWBUNNY_AIRFORWARDACCEL, AS_FLOAT, stat_sv_warsowbunny_airforwardaccel);
 799         addstat(STAT_MOVEVARS_WARSOWBUNNY_TOPSPEED, AS_FLOAT, stat_sv_warsowbunny_topspeed);
 800         addstat(STAT_MOVEVARS_WARSOWBUNNY_ACCEL, AS_FLOAT, stat_sv_warsowbunny_accel);
 801         addstat(STAT_MOVEVARS_WARSOWBUNNY_BACKTOSIDERATIO, AS_FLOAT, stat_sv_warsowbunny_backtosideratio);
 802         addstat(STAT_MOVEVARS_FRICTION, AS_FLOAT, stat_sv_friction);
 803         addstat(STAT_MOVEVARS_ACCELERATE, AS_FLOAT, stat_sv_accelerate);
 804         addstat(STAT_MOVEVARS_STOPSPEED, AS_FLOAT, stat_sv_stopspeed);
 805         addstat(STAT_MOVEVARS_AIRACCELERATE, AS_FLOAT, stat_sv_airaccelerate);
 806         addstat(STAT_MOVEVARS_AIRSTOPACCELERATE, AS_FLOAT, stat_sv_airstopaccelerate);
 807
 808         // secrets
 809         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 810         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 811
 812         // monsters
 813         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 814         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 815
 816         // misc
 817         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 818
 819         next_pingtime = time + 5;
 820
 821         detect_maptype();
 822
 823         // set up information replies for clients and server to use
 824         maplist_reply = strzone(getmaplist());
 825         lsmaps_reply = strzone(getlsmaps());
 826         monsterlist_reply = strzone(getmonsterlist());
 827         for(int i = 0; i < 10; ++i)
 828         {
 829                 s = getrecords(i);
 830                 if (s)
 831                         records_reply[i] = strzone(s);
 832         }
 833         ladder_reply = strzone(getladder());
 834         rankings_reply = strzone(getrankings());
 835
 836         // begin other init
 837         ClientInit_Spawn();
 838         RandomSeed_Spawn();
 839         PingPLReport_Spawn();
 840
 841         CheatInit();
 842
 843         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 844
 845         // fill sv_curl_serverpackages from .serverpackage files
 846         if(autocvar_sv_curl_serverpackages_auto)
 847         {
 848                 s = "";
 849                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 850                 for(int i = 0; i < n; ++i)
 851                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 852                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 853                                 s = strcat(s, " ", argv(i));
 854                 fd = search_begin("*-serverpackage.txt", true, false);
 855                 if(fd >= 0)
 856                 {
 857                         j = search_getsize(fd);
 858                         for(int i = 0; i < j; ++i)
 859                                 s = strcat(s, " ", search_getfilename(fd, i));
 860                         search_end(fd);
 861                 }
 862                 fd = search_begin("*.serverpackage", true, false);
 863                 if(fd >= 0)
 864                 {
 865                         j = search_getsize(fd);
 866                         for(int i = 0; i < j; ++i)
 867                                 s = strcat(s, " ", search_getfilename(fd, i));
 868                         search_end(fd);
 869                 }
 870                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 871         }
 872
 873         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 874         modname = "Xonotic";
 875         // physics/balance/config changes that count as mod
 876         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 877                 modname = cvar_string("g_mod_physics");
 878         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 879                 modname = cvar_string("g_mod_balance");
 880         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 881                 modname = cvar_string("g_mod_config");
 882         // extra mutators that deserve to count as mod
 883         MUTATOR_CALLHOOK(SetModname);
 884
 885         // save it for later
 886         modname = strzone(modname);
 887
 888         WinningConditionHelper(); // set worldstatus
 889
 890         world_initialized = 1;
 891 }
 892
 893 spawnfunc(light)
 894 {
 895         //makestatic (self); // Who the f___ did that?
 896         remove(self);
 897 }
 898
 899 string GetGametype()
 900 {
 901         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 902 }
 903
 904 string GetMapname()
 905 {
 906         return mapname;
 907 }
 908
 909 float Map_Count, Map_Current;
 910 string Map_Current_Name;
 911
 912 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 913 float GetMaplistPosition()
 914 {
 915         float pos, idx;
 916         string map;
 917
 918         map = GetMapname();
 919         idx = autocvar_g_maplist_index;
 920
 921         if(idx >= 0)
 922                 if(idx < Map_Count)
 923                         if(map == argv(idx))
 924                                 return idx;
 925
 926         for(pos = 0; pos < Map_Count; ++pos)
 927                 if(map == argv(pos))
 928                         return pos;
 929
 930         // resume normal maplist rotation if current map is not in g_maplist
 931         return idx;
 932 }
 933
 934 float MapHasRightSize(string map)
 935 {
 936         float fh;
 937         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 938         if(autocvar_g_maplist_check_waypoints)
 939         {
 940                 LOG_TRACE("checkwp "); LOG_TRACE(map);
 941                 if(!fexists(strcat("maps/", map, ".waypoints")))
 942                 {
 943                         LOG_TRACE(": no waypoints\n");
 944                         return false;
 945                 }
 946                 LOG_TRACE(": has waypoints\n");
 947         }
 948
 949         // open map size restriction file
 950         LOG_TRACE("opensize "); LOG_TRACE(map);
 951         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 952         if(fh >= 0)
 953         {
 954                 float mapmin, mapmax;
 955                 LOG_TRACE(": ok, ");
 956                 mapmin = stof(fgets(fh));
 957                 mapmax = stof(fgets(fh));
 958                 fclose(fh);
 959                 if(player_count < mapmin)
 960                 {
 961                         LOG_TRACE("not enough\n");
 962                         return false;
 963                 }
 964                 if(player_count > mapmax)
 965                 {
 966                         LOG_TRACE("too many\n");
 967                         return false;
 968                 }
 969                 LOG_TRACE("right size\n");
 970                 return true;
 971         }
 972         LOG_TRACE(": not found\n");
 973         return true;
 974 }
 975
 976 string Map_Filename(float position)
 977 {
 978         return strcat("maps/", argv(position), ".bsp");
 979 }
 980
 981 void Map_MarkAsRecent(string m)
 982 {
 983         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
 984 }
 985
 986 float Map_IsRecent(string m)
 987 {
 988         return strhasword(autocvar_g_maplist_mostrecent, m);
 989 }
 990
 991 float Map_Check(float position, float pass)
 992 {
 993         string filename;
 994         string map_next;
 995         map_next = argv(position);
 996         if(pass <= 1)
 997         {
 998                 if(Map_IsRecent(map_next))
 999                         return 0;
1000         }
1001         filename = Map_Filename(position);
1002         if(MapInfo_CheckMap(map_next))
1003         {
1004                 if(pass == 2)
1005                         return 1;
1006                 if(MapHasRightSize(map_next))
1007                         return 1;
1008                 return 0;
1009         }
1010         else
1011                 LOG_TRACE( "Couldn't select '", filename, "'..\n" );
1012
1013         return 0;
1014 }
1015
1016 void Map_Goto_SetStr(string nextmapname)
1017 {
1018         if(getmapname_stored != "")
1019                 strunzone(getmapname_stored);
1020         if(nextmapname == "")
1021                 getmapname_stored = "";
1022         else
1023                 getmapname_stored = strzone(nextmapname);
1024 }
1025
1026 void Map_Goto_SetFloat(float position)
1027 {
1028         cvar_set("g_maplist_index", ftos(position));
1029         Map_Goto_SetStr(argv(position));
1030 }
1031
1032 void Map_Goto(float reinit)
1033 {
1034         MapInfo_LoadMap(getmapname_stored, reinit);
1035 }
1036
1037 // return codes of map selectors:
1038 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1039 //   -2 = permanent failure
1040 float() MaplistMethod_Iterate = // usual method
1041 {
1042         float pass, i;
1043
1044         LOG_TRACE("Trying MaplistMethod_Iterate\n");
1045
1046         for(pass = 1; pass <= 2; ++pass)
1047         {
1048                 for(i = 1; i < Map_Count; ++i)
1049                 {
1050                         float mapindex;
1051                         mapindex = (i + Map_Current) % Map_Count;
1052                         if(Map_Check(mapindex, pass))
1053                                 return mapindex;
1054                 }
1055         }
1056         return -1;
1057 }
1058
1059 float() MaplistMethod_Repeat = // fallback method
1060 {
1061         LOG_TRACE("Trying MaplistMethod_Repeat\n");
1062
1063         if(Map_Check(Map_Current, 2))
1064                 return Map_Current;
1065         return -2;
1066 }
1067
1068 float() MaplistMethod_Random = // random map selection
1069 {
1070         float i, imax;
1071
1072         LOG_TRACE("Trying MaplistMethod_Random\n");
1073
1074         imax = 42;
1075
1076         for(i = 0; i <= imax; ++i)
1077         {
1078                 float mapindex;
1079                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1080                 if(Map_Check(mapindex, 1))
1081                         return mapindex;
1082         }
1083         return -1;
1084 }
1085
1086 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1087 // the exponent sets a bias on the map selection:
1088 // the higher the exponent, the less likely "shortly repeated" same maps are
1089 {
1090         float i, j, imax, insertpos;
1091
1092         LOG_TRACE("Trying MaplistMethod_Shuffle\n");
1093
1094         imax = 42;
1095
1096         for(i = 0; i <= imax; ++i)
1097         {
1098                 string newlist;
1099
1100                 // now reinsert this at another position
1101                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1102                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1103                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1104                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1105
1106                 // insert the current map there
1107                 newlist = "";
1108                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1109                         newlist = strcat(newlist, " ", argv(j));
1110                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1111                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1112                         newlist = strcat(newlist, " ", argv(j));
1113                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1114                 cvar_set("g_maplist", newlist);
1115                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1116
1117                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1118                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1119                 if(Map_Check(Map_Current, 1))
1120                         return Map_Current;
1121         }
1122         return -1;
1123 }
1124
1125 void Maplist_Init()
1126 {
1127         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1128         float i;
1129         for (i = 0; i < Map_Count; ++i)
1130                 if (Map_Check(i, 2))
1131                         break;
1132         if (i == Map_Count)
1133         {
1134                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1135                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1136                 if(autocvar_g_maplist_shuffle)
1137                         ShuffleMaplist();
1138                 localcmd("\nmenu_cmd sync\n");
1139                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1140         }
1141         if(Map_Count == 0)
1142                 error("empty maplist, cannot select a new map");
1143         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1144
1145         if(Map_Current_Name)
1146                 strunzone(Map_Current_Name);
1147         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1148         // this may or may not be correct, but who cares, in the worst case a map
1149         // isn't chosen in the first pass that should have been
1150 }
1151
1152 string GetNextMap()
1153 {
1154         float nextMap;
1155
1156         Maplist_Init();
1157         nextMap = -1;
1158
1159         if(nextMap == -1)
1160                 if(autocvar_g_maplist_shuffle > 0)
1161                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1162
1163         if(nextMap == -1)
1164                 if(autocvar_g_maplist_selectrandom)
1165                         nextMap = MaplistMethod_Random();
1166
1167         if(nextMap == -1)
1168                 nextMap = MaplistMethod_Iterate();
1169
1170         if(nextMap == -1)
1171                 nextMap = MaplistMethod_Repeat();
1172
1173         if(nextMap >= 0)
1174         {
1175                 Map_Goto_SetFloat(nextMap);
1176                 return getmapname_stored;
1177         }
1178
1179         return "";
1180 }
1181
1182 float DoNextMapOverride(float reinit)
1183 {
1184         if(autocvar_g_campaign)
1185         {
1186                 CampaignPostIntermission();
1187                 alreadychangedlevel = true;
1188                 return true;
1189         }
1190         if(autocvar_quit_when_empty)
1191         {
1192                 if(player_count <= currentbots)
1193                 {
1194                         localcmd("quit\n");
1195                         alreadychangedlevel = true;
1196                         return true;
1197                 }
1198         }
1199         if(autocvar_quit_and_redirect != "")
1200         {
1201                 redirection_target = strzone(autocvar_quit_and_redirect);
1202                 alreadychangedlevel = true;
1203                 return true;
1204         }
1205         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1206         {
1207                 localcmd("restart\n");
1208                 alreadychangedlevel = true;
1209                 return true;
1210         }
1211         if(autocvar_nextmap != "")
1212         {
1213                 string m;
1214                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1215                 cvar_set("nextmap",m);
1216
1217                 if(!m || gametypevote)
1218                         return false;
1219                 if(autocvar_sv_vote_gametype)
1220                 {
1221                         Map_Goto_SetStr(m);
1222                         return false;
1223                 }
1224
1225                 if(MapInfo_CheckMap(m))
1226                 {
1227                         Map_Goto_SetStr(m);
1228                         Map_Goto(reinit);
1229                         alreadychangedlevel = true;
1230                         return true;
1231                 }
1232         }
1233         if(!reinit && autocvar_lastlevel)
1234         {
1235                 cvar_settemp_restore();
1236                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1237                 alreadychangedlevel = true;
1238                 return true;
1239         }
1240         return false;
1241 }
1242
1243 void GotoNextMap(float reinit)
1244 {
1245         //string nextmap;
1246         //float n, nummaps;
1247         //string s;
1248         if (alreadychangedlevel)
1249                 return;
1250         alreadychangedlevel = true;
1251
1252         string nextMap;
1253
1254         nextMap = GetNextMap();
1255         if(nextMap == "")
1256                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1257         Map_Goto(reinit);
1258 }
1259
1260
1261 /*
1262 ============
1263 IntermissionThink
1264
1265 When the player presses attack or jump, change to the next level
1266 ============
1267 */
1268 .float autoscreenshot;
1269 void IntermissionThink()
1270 {SELFPARAM();
1271         FixIntermissionClient(self);
1272
1273         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1274         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1275
1276         if( (server_screenshot || client_screenshot)
1277                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1278         {
1279                 self.autoscreenshot = -1;
1280                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1281                 return;
1282         }
1283
1284         if (time < intermission_exittime)
1285                 return;
1286
1287         if(!mapvote_initialized)
1288                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1289                         return;
1290
1291         MapVote_Start();
1292 }
1293
1294 /*
1295 ============
1296 FindIntermission
1297
1298 Returns the entity to view from
1299 ============
1300 */
1301 /*
1302 entity FindIntermission()
1303 {
1304         local   entity spot;
1305         local   float cyc;
1306
1307 // look for info_intermission first
1308         spot = find (world, classname, "info_intermission");
1309         if (spot)
1310         {       // pick a random one
1311                 cyc = random() * 4;
1312                 while (cyc > 1)
1313                 {
1314                         spot = find (spot, classname, "info_intermission");
1315                         if (!spot)
1316                                 spot = find (spot, classname, "info_intermission");
1317                         cyc = cyc - 1;
1318                 }
1319                 return spot;
1320         }
1321
1322 // then look for the start position
1323         spot = find (world, classname, "info_player_start");
1324         if (spot)
1325                 return spot;
1326
1327 // testinfo_player_start is only found in regioned levels
1328         spot = find (world, classname, "testplayerstart");
1329         if (spot)
1330                 return spot;
1331
1332 // then look for the start position
1333         spot = find (world, classname, "info_player_deathmatch");
1334         if (spot)
1335                 return spot;
1336
1337         //objerror ("FindIntermission: no spot");
1338         return world;
1339 }
1340 */
1341
1342 /*
1343 ===============================================================================
1344
1345 RULES
1346
1347 ===============================================================================
1348 */
1349
1350 void DumpStats(float final)
1351 {
1352         float file;
1353         string s;
1354         float to_console;
1355         float to_eventlog;
1356         float to_file;
1357         float i;
1358
1359         to_console = autocvar_sv_logscores_console;
1360         to_eventlog = autocvar_sv_eventlog;
1361         to_file = autocvar_sv_logscores_file;
1362
1363         if(!final)
1364         {
1365                 to_console = true; // always print printstats replies
1366                 to_eventlog = false; // but never print them to the event log
1367         }
1368
1369         if(to_eventlog)
1370                 if(autocvar_sv_eventlog_console)
1371                         to_console = false; // otherwise we get the output twice
1372
1373         if(final)
1374                 s = ":scores:";
1375         else
1376                 s = ":status:";
1377         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1378
1379         if(to_console)
1380                 LOG_INFO(s, "\n");
1381         if(to_eventlog)
1382                 GameLogEcho(s);
1383
1384         file = -1;
1385         if(to_file)
1386         {
1387                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1388                 if(file == -1)
1389                         to_file = false;
1390                 else
1391                         fputs(file, strcat(s, "\n"));
1392         }
1393
1394         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1395         if(to_console)
1396                 LOG_INFO(s, "\n");
1397         if(to_eventlog)
1398                 GameLogEcho(s);
1399         if(to_file)
1400                 fputs(file, strcat(s, "\n"));
1401
1402         FOR_EACH_CLIENT(other)
1403         {
1404                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1405                 {
1406                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1407                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1408                         if(IS_PLAYER(other) || MUTATOR_CALLHOOK(GetPlayerStatus, other, s))
1409                                 s = strcat(s, ftos(other.team), ":");
1410                         else
1411                                 s = strcat(s, "spectator:");
1412
1413                         if(to_console)
1414                                 LOG_INFO(s, other.netname, "\n");
1415                         if(to_eventlog)
1416                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1417                         if(to_file)
1418                                 fputs(file, strcat(s, other.netname, "\n"));
1419                 }
1420         }
1421
1422         if(teamplay)
1423         {
1424                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1425                 if(to_console)
1426                         LOG_INFO(s, "\n");
1427                 if(to_eventlog)
1428                         GameLogEcho(s);
1429                 if(to_file)
1430                         fputs(file, strcat(s, "\n"));
1431
1432                 for(i = 1; i < 16; ++i)
1433                 {
1434                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1435                         s = strcat(s, ":", ftos(i));
1436                         if(to_console)
1437                                 LOG_INFO(s, "\n");
1438                         if(to_eventlog)
1439                                 GameLogEcho(s);
1440                         if(to_file)
1441                                 fputs(file, strcat(s, "\n"));
1442                 }
1443         }
1444
1445         if(to_console)
1446                 LOG_INFO(":end\n");
1447         if(to_eventlog)
1448                 GameLogEcho(":end");
1449         if(to_file)
1450         {
1451                 fputs(file, ":end\n");
1452                 fclose(file);
1453         }
1454 }
1455
1456 void FixIntermissionClient(entity e)
1457 {
1458         string s;
1459         if(!e.autoscreenshot) // initial call
1460         {
1461                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1462                 e.health = -2342;
1463                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1464                 e.solid = SOLID_NOT;
1465                 e.movetype = MOVETYPE_NONE;
1466                 e.takedamage = DAMAGE_NO;
1467                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1468                 {
1469                     .entity weaponentity = weaponentities[slot];
1470                         if(e.(weaponentity))
1471                         {
1472                                 e.(weaponentity).effects = EF_NODRAW;
1473                                 if (e.(weaponentity).(weaponentity))
1474                                         e.(weaponentity).(weaponentity).effects = EF_NODRAW;
1475                         }
1476                 }
1477                 if(IS_REAL_CLIENT(e))
1478                 {
1479                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1480                         s = autocvar_sv_intermission_cdtrack;
1481                         if(s != "")
1482                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1483                         msg_entity = e;
1484                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1485                 }
1486         }
1487 }
1488
1489 /*
1490 go to the next level for deathmatch
1491 only called if a time or frag limit has expired
1492 */
1493 void NextLevel()
1494 {
1495         gameover = true;
1496
1497         intermission_running = 1;
1498
1499 // enforce a wait time before allowing changelevel
1500         if(player_count > 0)
1501                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1502         else
1503                 intermission_exittime = -1;
1504
1505         /*
1506         WriteByte (MSG_ALL, SVC_CDTRACK);
1507         WriteByte (MSG_ALL, 3);
1508         WriteByte (MSG_ALL, 3);
1509         // done in FixIntermission
1510         */
1511
1512         //pos = FindIntermission ();
1513
1514         VoteReset();
1515
1516         DumpStats(true);
1517
1518         // send statistics
1519         PlayerStats_GameReport(true);
1520         WeaponStats_Shutdown();
1521
1522         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1523
1524         if(autocvar_sv_eventlog)
1525                 GameLogEcho(":gameover");
1526
1527         GameLogClose();
1528
1529         FOR_EACH_PLAYER(other) {
1530                 FixIntermissionClient(other);
1531                 if(other.winning)
1532                         bprint(other.netname, " ^7wins.\n");
1533         }
1534
1535         entity oldself = self;
1536         target_music_kill();
1537         self = oldself;
1538
1539         if(autocvar_g_campaign)
1540                 CampaignPreIntermission();
1541
1542         MUTATOR_CALLHOOK(MatchEnd);
1543
1544         localcmd("\nsv_hook_gameend\n");
1545 }
1546
1547 /*
1548 ============
1549 CheckRules_Player
1550
1551 Exit deathmatch games upon conditions
1552 ============
1553 */
1554 void CheckRules_Player()
1555 {SELFPARAM();
1556         if (gameover)   // someone else quit the game already
1557                 return;
1558
1559         if(self.deadflag == DEAD_NO)
1560                 self.play_time += frametime;
1561
1562         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1563         //   (div0: and that in CheckRules_World please)
1564 }
1565
1566
1567 float InitiateSuddenDeath()
1568 {
1569         // Check first whether normal overtimes could be added before initiating suddendeath mode
1570         // - for this timelimit_overtime needs to be >0 of course
1571         // - also check the winning condition calculated in the previous frame and only add normal overtime
1572         //   again, if at the point at which timelimit would be extended again, still no winner was found
1573         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1574         {
1575                 return 1; // need to call InitiateOvertime later
1576         }
1577         else
1578         {
1579                 if(!checkrules_suddendeathend)
1580                 {
1581                         if(autocvar_g_campaign)
1582                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1583                         else
1584                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1585                         if(g_race && !g_race_qualifying)
1586                                 race_StartCompleting();
1587                 }
1588                 return 0;
1589         }
1590 }
1591
1592 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1593 {
1594         ++checkrules_overtimesadded;
1595         //add one more overtime by simply extending the timelimit
1596         float tl;
1597         tl = autocvar_timelimit;
1598         tl += autocvar_timelimit_overtime;
1599         cvar_set("timelimit", ftos(tl));
1600
1601         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1602 }
1603
1604 float GetWinningCode(float fraglimitreached, float equality)
1605 {
1606         if(autocvar_g_campaign == 1)
1607                 if(fraglimitreached)
1608                         return WINNING_YES;
1609                 else
1610                         return WINNING_NO;
1611
1612         else
1613                 if(equality)
1614                         if(fraglimitreached)
1615                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1616                         else
1617                                 return WINNING_NEVER;
1618                 else
1619                         if(fraglimitreached)
1620                                 return WINNING_YES;
1621                         else
1622                                 return WINNING_NO;
1623 }
1624
1625 // set the .winning flag for exactly those players with a given field value
1626 void SetWinners(.float field, float value)
1627 {
1628         entity head;
1629         FOR_EACH_PLAYER(head)
1630                 head.winning = (head.(field) == value);
1631 }
1632
1633 // set the .winning flag for those players with a given field value
1634 void AddWinners(.float field, float value)
1635 {
1636         entity head;
1637         FOR_EACH_PLAYER(head)
1638                 if (head.(field) == value)
1639                         head.winning = 1;
1640 }
1641
1642 // clear the .winning flags
1643 void ClearWinners()
1644 {
1645         entity head;
1646         FOR_EACH_PLAYER(head)
1647                 head.winning = 0;
1648 }
1649
1650 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1651 // they win. Otherwise the defending team wins once the timelimit passes.
1652 void assault_new_round();
1653 float WinningCondition_Assault()
1654 {SELFPARAM();
1655         float status;
1656
1657         WinningConditionHelper(); // set worldstatus
1658
1659         status = WINNING_NO;
1660         // as the timelimit has not yet passed just assume the defending team will win
1661         if(assault_attacker_team == NUM_TEAM_1)
1662         {
1663                 SetWinners(team, NUM_TEAM_2);
1664         }
1665         else
1666         {
1667                 SetWinners(team, NUM_TEAM_1);
1668         }
1669
1670         entity ent;
1671         ent = find(world, classname, "target_assault_roundend");
1672         if(ent)
1673         {
1674                 if(ent.winning) // round end has been triggered by attacking team
1675                 {
1676                         bprint("ASSAULT: round completed...\n");
1677                         SetWinners(team, assault_attacker_team);
1678
1679                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1680
1681                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1682                         {
1683                                 status = WINNING_YES;
1684                         }
1685                         else
1686                         {
1687                                 WITH(entity, self, ent, assault_new_round());
1688                         }
1689                 }
1690         }
1691
1692         return status;
1693 }
1694
1695 void ShuffleMaplist()
1696 {
1697         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1698 }
1699
1700 float leaderfrags;
1701 float WinningCondition_Scores(float limit, float leadlimit)
1702 {
1703         float limitreached;
1704
1705         // TODO make everything use THIS winning condition (except LMS)
1706         WinningConditionHelper();
1707
1708         if(teamplay)
1709         {
1710                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1711                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1712                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1713                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1714         }
1715
1716         ClearWinners();
1717         if(WinningConditionHelper_winner)
1718                 WinningConditionHelper_winner.winning = 1;
1719         if(WinningConditionHelper_winnerteam >= 0)
1720                 SetWinners(team, WinningConditionHelper_winnerteam);
1721
1722         if(WinningConditionHelper_lowerisbetter)
1723         {
1724                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1725                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1726                 limit = -limit;
1727         }
1728
1729         if(WinningConditionHelper_zeroisworst)
1730                 leadlimit = 0; // not supported in this mode
1731
1732         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1733         // these modes always score in increments of 1, thus this makes sense
1734         {
1735                 if(leaderfrags != WinningConditionHelper_topscore)
1736                 {
1737                         leaderfrags = WinningConditionHelper_topscore;
1738
1739                         if (limit)
1740                         if (leaderfrags == limit - 1)
1741                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1742                         else if (leaderfrags == limit - 2)
1743                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1744                         else if (leaderfrags == limit - 3)
1745                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1746                 }
1747         }
1748
1749         limitreached = false;
1750         if(limit)
1751                 if(WinningConditionHelper_topscore >= limit)
1752                         limitreached = true;
1753         if(leadlimit)
1754         {
1755                 float leadlimitreached;
1756                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1757                 if(autocvar_leadlimit_and_fraglimit)
1758                         limitreached = (limitreached && leadlimitreached);
1759                 else
1760                         limitreached = (limitreached || leadlimitreached);
1761         }
1762
1763         if(limit)
1764                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1765
1766         return GetWinningCode(
1767                 WinningConditionHelper_topscore && limitreached,
1768                 WinningConditionHelper_equality
1769         );
1770 }
1771
1772 float WinningCondition_Race(float fraglimit)
1773 {
1774         float wc;
1775         entity p;
1776         float n, c;
1777
1778         n = 0;
1779         c = 0;
1780         FOR_EACH_PLAYER(p)
1781         {
1782                 ++n;
1783                 if(p.race_completed)
1784                         ++c;
1785         }
1786         if(n && (n == c))
1787                 return WINNING_YES;
1788         wc = WinningCondition_Scores(fraglimit, 0);
1789
1790         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1791         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1792         // do NOT support equality when the laps are all raced!
1793                 return WINNING_STARTSUDDENDEATHOVERTIME;
1794         else
1795                 return WINNING_NEVER;
1796 }
1797
1798 float WinningCondition_QualifyingThenRace(float limit)
1799 {
1800         float wc;
1801         wc = WinningCondition_Scores(limit, 0);
1802
1803         // NEVER initiate overtime
1804         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1805         {
1806                 return WINNING_YES;
1807         }
1808
1809         return wc;
1810 }
1811
1812 float WinningCondition_RanOutOfSpawns()
1813 {
1814         entity head;
1815
1816         if(have_team_spawns <= 0)
1817                 return WINNING_NO;
1818
1819         if(!autocvar_g_spawn_useallspawns)
1820                 return WINNING_NO;
1821
1822         if(!some_spawn_has_been_used)
1823                 return WINNING_NO;
1824
1825         team1_score = team2_score = team3_score = team4_score = 0;
1826
1827         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1828         {
1829                 if(head.team == NUM_TEAM_1)
1830                         team1_score = 1;
1831                 else if(head.team == NUM_TEAM_2)
1832                         team2_score = 1;
1833                 else if(head.team == NUM_TEAM_3)
1834                         team3_score = 1;
1835                 else if(head.team == NUM_TEAM_4)
1836                         team4_score = 1;
1837         }
1838
1839         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1840         {
1841                 if(head.team == NUM_TEAM_1)
1842                         team1_score = 1;
1843                 else if(head.team == NUM_TEAM_2)
1844                         team2_score = 1;
1845                 else if(head.team == NUM_TEAM_3)
1846                         team3_score = 1;
1847                 else if(head.team == NUM_TEAM_4)
1848                         team4_score = 1;
1849         }
1850
1851         ClearWinners();
1852         if(team1_score + team2_score + team3_score + team4_score == 0)
1853         {
1854                 checkrules_equality = true;
1855                 return WINNING_YES;
1856         }
1857         else if(team1_score + team2_score + team3_score + team4_score == 1)
1858         {
1859                 float t, i;
1860                 if(team1_score)
1861                         t = NUM_TEAM_1;
1862                 else if(team2_score)
1863                         t = NUM_TEAM_2;
1864                 else if(team3_score)
1865                         t = NUM_TEAM_3;
1866                 else // if(team4_score)
1867                         t = NUM_TEAM_4;
1868                 CheckAllowedTeams(world);
1869                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1870                 {
1871                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1872                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
1873                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
1874                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
1875                 }
1876
1877                 AddWinners(team, t);
1878                 return WINNING_YES;
1879         }
1880         else
1881                 return WINNING_NO;
1882 }
1883
1884 /*
1885 ============
1886 CheckRules_World
1887
1888 Exit deathmatch games upon conditions
1889 ============
1890 */
1891 void CheckRules_World()
1892 {
1893         float timelimit;
1894         float fraglimit;
1895         float leadlimit;
1896
1897         VoteThink();
1898         MapVote_Think();
1899
1900         SetDefaultAlpha();
1901
1902         if (gameover)   // someone else quit the game already
1903         {
1904                 if(player_count == 0) // Nobody there? Then let's go to the next map
1905                         MapVote_Start();
1906                         // this will actually check the player count in the next frame
1907                         // again, but this shouldn't hurt
1908                 return;
1909         }
1910
1911         timelimit = autocvar_timelimit * 60;
1912         fraglimit = autocvar_fraglimit;
1913         leadlimit = autocvar_leadlimit;
1914
1915         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1916         {
1917                 if(timelimit > 0)
1918                         timelimit = 0; // timelimit is not made for warmup
1919                 if(fraglimit > 0)
1920                         fraglimit = 0; // no fraglimit for now
1921                 leadlimit = 0; // no leadlimit for now
1922         }
1923
1924         if(timelimit > 0)
1925         {
1926                 timelimit += game_starttime;
1927         }
1928         else if (timelimit < 0)
1929         {
1930                 // endmatch
1931                 NextLevel();
1932                 return;
1933         }
1934
1935         float wantovertime;
1936         wantovertime = 0;
1937
1938         if(timelimit > game_starttime)
1939                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
1940         else
1941                 game_completion_ratio = 0;
1942
1943         if(checkrules_suddendeathend)
1944         {
1945                 if(!checkrules_suddendeathwarning)
1946                 {
1947                         checkrules_suddendeathwarning = true;
1948                         if(g_race && !g_race_qualifying)
1949                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
1950                         else
1951                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
1952                 }
1953         }
1954         else
1955         {
1956                 if (timelimit && time >= timelimit)
1957                 {
1958                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1959                         {
1960                                 float totalplayers;
1961                                 float playerswithlaps;
1962                                 float readyplayers;
1963                                 entity head;
1964                                 totalplayers = playerswithlaps = readyplayers = 0;
1965                                 FOR_EACH_PLAYER(head)
1966                                 {
1967                                         ++totalplayers;
1968                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
1969                                                 ++playerswithlaps;
1970                                         if(head.ready)
1971                                                 ++readyplayers;
1972                                 }
1973
1974                                 // at least 2 of the players have completed a lap: start the RACE
1975                                 // otherwise, the players should end the qualifying on their own
1976                                 if(readyplayers || playerswithlaps >= 2)
1977                                 {
1978                                         checkrules_suddendeathend = 0;
1979                                         ReadyRestart(); // go to race
1980                                         return;
1981                                 }
1982                                 else
1983                                         wantovertime |= InitiateSuddenDeath();
1984                         }
1985                         else
1986                                 wantovertime |= InitiateSuddenDeath();
1987                 }
1988         }
1989
1990         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1991         {
1992                 NextLevel();
1993                 return;
1994         }
1995
1996         int checkrules_status = WinningCondition_RanOutOfSpawns();
1997         if(checkrules_status == WINNING_YES)
1998                 bprint("Hey! Someone ran out of spawns!\n");
1999         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
2000                 checkrules_status = ret_float;
2001         else
2002                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2003
2004         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2005         {
2006                 checkrules_status = WINNING_NEVER;
2007                 checkrules_overtimesadded = -1;
2008                 wantovertime |= InitiateSuddenDeath();
2009         }
2010
2011         if(checkrules_status == WINNING_NEVER)
2012                 // equality cases! Nobody wins if the overtime ends in a draw.
2013                 ClearWinners();
2014
2015         if(wantovertime)
2016         {
2017                 if(checkrules_status == WINNING_NEVER)
2018                         InitiateOvertime();
2019                 else
2020                         checkrules_status = WINNING_YES;
2021         }
2022
2023         if(checkrules_suddendeathend)
2024                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2025                         checkrules_status = WINNING_YES;
2026
2027         if(checkrules_status == WINNING_YES)
2028         {
2029                 //print("WINNING\n");
2030                 NextLevel();
2031         }
2032 }
2033
2034 string GotoMap(string m)
2035 {
2036         m = GameTypeVote_MapInfo_FixName(m);
2037         if (!m)
2038                 return "The map you suggested is not available on this server.";
2039         if (!autocvar_sv_vote_gametype)
2040         if(!MapInfo_CheckMap(m))
2041                 return "The map you suggested does not support the current game mode.";
2042         cvar_set("nextmap", m);
2043         cvar_set("timelimit", "-1");
2044         if(mapvote_initialized || alreadychangedlevel)
2045         {
2046                 if(DoNextMapOverride(0))
2047                         return "Map switch initiated.";
2048                 else
2049                         return "Hm... no. For some reason I like THIS map more.";
2050         }
2051         else
2052                 return "Map switch will happen after scoreboard.";
2053 }
2054
2055
2056 void EndFrame()
2057 {SELFPARAM();
2058         anticheat_endframe();
2059
2060         float altime;
2061         entity e_;
2062         FOR_EACH_REALCLIENT(e_)
2063         {
2064                 entity e = IS_SPEC(e_) ? e_.enemy : e_;
2065                 if(e.typehitsound)
2066                         e_.typehit_time = time;
2067                 else if(e.damage_dealt)
2068                 {
2069                         e_.hit_time = time;
2070                         e_.damage_dealt_total += ceil(e.damage_dealt);
2071                 }
2072         }
2073         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2074         // add 1 frametime because after this, engine SV_Physics
2075         // increases time by a frametime and then networks the frame
2076         // add another frametime because client shows everything with
2077         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2078         // needed!
2079         FOR_EACH_CLIENT(e_)
2080         {
2081                 e_.typehitsound = false;
2082                 e_.damage_dealt = 0;
2083                 setself(e_);
2084                 antilag_record(e_, altime);
2085         }
2086         FOR_EACH_MONSTER(e_)
2087         {
2088                 setself(e_);
2089                 antilag_record(e_, altime);
2090         }
2091 }
2092
2093
2094 /*
2095  * RedirectionThink:
2096  * returns true if redirecting
2097  */
2098 float redirection_timeout;
2099 float redirection_nextthink;
2100 float RedirectionThink()
2101 {SELFPARAM();
2102         float clients_found;
2103
2104         if(redirection_target == "")
2105                 return false;
2106
2107         if(!redirection_timeout)
2108         {
2109                 cvar_set("sv_public", "-2");
2110                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2111                 if(redirection_target == "self")
2112                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2113                 else
2114                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2115         }
2116
2117         if(time < redirection_nextthink)
2118                 return true;
2119
2120         redirection_nextthink = time + 1;
2121
2122         clients_found = 0;
2123         entity e;
2124         FOR_EACH_REALCLIENT(e)
2125         {
2126                 setself(e);
2127                 // TODO add timer
2128                 LOG_INFO("Redirecting: sending connect command to ", self.netname, "\n");
2129                 if(redirection_target == "self")
2130                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2131                 else
2132                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2133                 ++clients_found;
2134         }
2135
2136         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.\n");
2137
2138         if(time > redirection_timeout || clients_found == 0)
2139                 localcmd("\nwait; wait; wait; quit\n");
2140
2141         return true;
2142 }
2143
2144 void TargetMusic_RestoreGame();
2145 void RestoreGame()
2146 {
2147         // Loaded from a save game
2148         // some things then break, so let's work around them...
2149
2150         // Progs DB (capture records)
2151         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2152
2153         // Mapinfo
2154         MapInfo_Shutdown();
2155         MapInfo_Enumerate();
2156         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2157         WeaponStats_Init();
2158
2159         TargetMusic_RestoreGame();
2160 }
2161
2162 void Shutdown()
2163 {
2164         gameover = 2;
2165
2166         if(world_initialized > 0)
2167         {
2168                 world_initialized = 0;
2169                 LOG_INFO("Saving persistent data...\n");
2170                 Ban_SaveBans();
2171
2172                 // playerstats with unfinished match
2173                 PlayerStats_GameReport(false);
2174
2175                 if(!cheatcount_total)
2176                 {
2177                         if(autocvar_sv_db_saveasdump)
2178                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2179                         else
2180                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2181                 }
2182                 if(autocvar_developer)
2183                 {
2184                         if(autocvar_sv_db_saveasdump)
2185                                 db_dump(TemporaryDB, "server-temp.db");
2186                         else
2187                                 db_save(TemporaryDB, "server-temp.db");
2188                 }
2189                 CheatShutdown(); // must be after cheatcount check
2190                 db_close(ServerProgsDB);
2191                 db_close(TemporaryDB);
2192                 LOG_INFO("done!\n");
2193                 // tell the bot system the game is ending now
2194                 bot_endgame();
2195
2196                 WeaponStats_Shutdown();
2197                 MapInfo_Shutdown();
2198         }
2199         else if(world_initialized == 0)
2200         {
2201                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data\n");
2202         }
2203 }