qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2 #include "_all.qh"
   3
   4 #include "anticheat.qh"
   5 #include "antilag.qh"
   6 #include "bot/bot.qh"
   7 #include "campaign.qh"
   8 #include "cheats.qh"
   9 #include "cl_client.qh"
  10 #include "command/common.qh"
  11 #include "command/getreplies.qh"
  12 #include "command/sv_cmd.qh"
  13 #include "command/vote.qh"
  14 #include "g_hook.qh"
  15 #include "ipban.qh"
  16 #include "mapvoting.qh"
  17 #include "mutators/mutators_include.qh"
  18 #include "race.qh"
  19 #include "scores.qh"
  20 #include "teamplay.qh"
  21 #include "waypointsprites.qh"
  22 #include "weapons/weaponstats.qh"
  23 #include "../common/buffs.qh"
  24 #include "../common/constants.qh"
  25 #include "../common/deathtypes.qh"
  26 #include "../common/mapinfo.qh"
  27 #include "../common/monsters/all.qh"
  28 #include "../common/monsters/sv_monsters.qh"
  29 #include "../common/notifications.qh"
  30 #include "../common/playerstats.qh"
  31 #include "../common/stats.qh"
  32 #include "../common/teams.qh"
  33 #include "../common/util.qh"
  34 #include "../common/items/all.qh"
  35 #include "../common/weapons/all.qh"
  36
  37 const float LATENCY_THINKRATE = 10;
  38 .float latency_sum;
  39 .float latency_cnt;
  40 .float latency_time;
  41 entity pingplreport;
  42 void PingPLReport_Think()
  43 {
  44         float delta;
  45         entity e;
  46
  47         delta = 3 / maxclients;
  48         if(delta < sys_frametime)
  49                 delta = 0;
  50         self.nextthink = time + delta;
  51
  52         e = edict_num(self.cnt + 1);
  53         if(IS_REAL_CLIENT(e))
  54         {
  55                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  56                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  57                 WriteByte(MSG_BROADCAST, self.cnt);
  58                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  59                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  60                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  61
  62                 // record latency times for clients throughout the match so we can report it to playerstats
  63                 if(time > (e.latency_time + LATENCY_THINKRATE))
  64                 {
  65                         e.latency_sum += e.ping;
  66                         e.latency_cnt += 1;
  67                         e.latency_time = time;
  68                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  69                 }
  70         }
  71         else
  72         {
  73                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  74                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  75                 WriteByte(MSG_BROADCAST, self.cnt);
  76                 WriteShort(MSG_BROADCAST, 0);
  77                 WriteByte(MSG_BROADCAST, 0);
  78                 WriteByte(MSG_BROADCAST, 0);
  79         }
  80         self.cnt = (self.cnt + 1) % maxclients;
  81 }
  82 void PingPLReport_Spawn()
  83 {
  84         pingplreport = spawn();
  85         pingplreport.classname = "pingplreport";
  86         pingplreport.think = PingPLReport_Think;
  87         pingplreport.nextthink = time;
  88 }
  89
  90 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  91 string redirection_target;
  92 float world_initialized;
  93
  94 string GetGametype();
  95 void ShuffleMaplist();
  96
  97 void SetDefaultAlpha()
  98 {
  99         if(autocvar_g_running_guns)
 100         {
 101                 default_player_alpha = -1;
 102                 default_weapon_alpha = +1;
 103         }
 104         else if(g_cloaked)
 105         {
 106                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
 107                 default_weapon_alpha = default_player_alpha;
 108         }
 109         else
 110         {
 111                 default_player_alpha = autocvar_g_player_alpha;
 112                 if(default_player_alpha == 0)
 113                         default_player_alpha = 1;
 114                 default_weapon_alpha = default_player_alpha;
 115         }
 116 }
 117
 118 void GotoFirstMap()
 119 {
 120         float n;
 121         if(autocvar__sv_init)
 122         {
 123                 // cvar_set("_sv_init", "0");
 124                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 125                 // to this "init" map on a dedicated server will cause no permanent
 126                 // harm
 127                 if(autocvar_g_maplist_shuffle)
 128                         ShuffleMaplist();
 129                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 130                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 131
 132                 MapInfo_Enumerate();
 133                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 134
 135                 if(!DoNextMapOverride(1))
 136                         GotoNextMap(1);
 137
 138                 return;
 139         }
 140
 141         if(time < 5)
 142         {
 143                 self.nextthink = time;
 144         }
 145         else
 146         {
 147                 self.nextthink = time + 1;
 148                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 149         }
 150 }
 151
 152 void cvar_changes_init()
 153 {
 154         float h;
 155         string k, v, d;
 156         float n, i, adding, pureadding;
 157
 158         if(cvar_changes)
 159                 strunzone(cvar_changes);
 160         cvar_changes = string_null;
 161         if(cvar_purechanges)
 162                 strunzone(cvar_purechanges);
 163         cvar_purechanges = string_null;
 164         cvar_purechanges_count = 0;
 165
 166         h = buf_create();
 167         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 168         n = buf_getsize(h);
 169
 170         adding = true;
 171         pureadding = true;
 172
 173         for(i = 0; i < n; ++i)
 174         {
 175                 k = bufstr_get(h, i);
 176
 177 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 178 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 179 #define BADCVAR(p) if(k == p) continue
 180
 181                 // general excludes and namespaces for server admin used cvars
 182                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 183
 184                 // internal
 185                 BADPREFIX("csqc_");
 186                 BADPREFIX("cvar_check_");
 187                 BADCVAR("gamecfg");
 188                 BADCVAR("g_configversion");
 189                 BADCVAR("g_maplist_index");
 190                 BADCVAR("halflifebsp");
 191                 BADCVAR("sv_mapformat_is_quake2");
 192                 BADCVAR("sv_mapformat_is_quake3");
 193                 BADPREFIX("sv_world");
 194
 195                 // client
 196                 BADPREFIX("chase_");
 197                 BADPREFIX("cl_");
 198                 BADPREFIX("con_");
 199                 BADPREFIX("scoreboard_");
 200                 BADPREFIX("g_campaign");
 201                 BADPREFIX("g_waypointsprite_");
 202                 BADPREFIX("gl_");
 203                 BADPREFIX("joy");
 204                 BADPREFIX("hud_");
 205                 BADPREFIX("m_");
 206                 BADPREFIX("menu_");
 207                 BADPREFIX("net_slist_");
 208                 BADPREFIX("r_");
 209                 BADPREFIX("sbar_");
 210                 BADPREFIX("scr_");
 211                 BADPREFIX("snd_");
 212                 BADPREFIX("show");
 213                 BADPREFIX("sensitivity");
 214                 BADPREFIX("userbind");
 215                 BADPREFIX("v_");
 216                 BADPREFIX("vid_");
 217                 BADPREFIX("crosshair");
 218                 BADCVAR("mod_q3bsp_lightmapmergepower");
 219                 BADCVAR("mod_q3bsp_nolightmaps");
 220                 BADCVAR("fov");
 221                 BADCVAR("mastervolume");
 222                 BADCVAR("volume");
 223                 BADCVAR("bgmvolume");
 224
 225                 // private
 226                 BADCVAR("developer");
 227                 BADCVAR("log_dest_udp");
 228                 BADCVAR("net_address");
 229                 BADCVAR("net_address_ipv6");
 230                 BADCVAR("port");
 231                 BADCVAR("savedgamecfg");
 232                 BADCVAR("serverconfig");
 233                 BADCVAR("sv_autoscreenshot");
 234                 BADCVAR("sv_heartbeatperiod");
 235                 BADCVAR("sv_vote_master_password");
 236                 BADCVAR("sys_colortranslation");
 237                 BADCVAR("sys_specialcharactertranslation");
 238                 BADCVAR("timeformat");
 239                 BADCVAR("timestamps");
 240                 BADPREFIX("developer_");
 241                 BADPREFIX("g_ban_");
 242                 BADPREFIX("g_banned_list");
 243                 BADPREFIX("g_chat_flood_");
 244                 BADPREFIX("g_ghost_items");
 245                 BADPREFIX("g_playerstats_");
 246                 BADPREFIX("g_respawn_ghosts");
 247                 BADPREFIX("g_voice_flood_");
 248                 BADPREFIX("log_file");
 249                 BADPREFIX("rcon_");
 250                 BADPREFIX("sv_allowdownloads");
 251                 BADPREFIX("sv_autodemo");
 252                 BADPREFIX("sv_curl_");
 253                 BADPREFIX("sv_eventlog");
 254                 BADPREFIX("sv_logscores_");
 255                 BADPREFIX("sv_master");
 256                 BADPREFIX("sv_weaponstats_");
 257                 BADPREFIX("sv_waypointsprite_");
 258                 BADCVAR("rescan_pending");
 259
 260                 // these can contain player IDs, so better hide
 261                 BADPREFIX("g_forced_team_");
 262
 263                 // mapinfo
 264                 BADCVAR("fraglimit");
 265                 BADCVAR("g_assault");
 266                 BADCVAR("g_ca");
 267                 BADCVAR("g_ca_teams");
 268                 BADCVAR("g_ctf");
 269                 BADCVAR("g_cts");
 270                 BADCVAR("g_dm");
 271                 BADCVAR("g_domination");
 272                 BADCVAR("g_domination_default_teams");
 273                 BADCVAR("g_freezetag");
 274                 BADCVAR("g_freezetag_teams");
 275                 BADCVAR("g_invasion_teams");
 276                 BADCVAR("g_keepaway");
 277                 BADCVAR("g_keyhunt");
 278                 BADCVAR("g_keyhunt_teams");
 279                 BADCVAR("g_lms");
 280                 BADCVAR("g_nexball");
 281                 BADCVAR("g_onslaught");
 282                 BADCVAR("g_race");
 283                 BADCVAR("g_race_qualifying_timelimit");
 284                 BADCVAR("g_tdm");
 285                 BADCVAR("g_tdm_teams");
 286                 BADCVAR("leadlimit");
 287                 BADCVAR("nextmap");
 288                 BADCVAR("teamplay");
 289                 BADCVAR("timelimit");
 290
 291                 // long
 292                 BADCVAR("hostname");
 293                 BADCVAR("g_maplist");
 294                 BADCVAR("g_maplist_mostrecent");
 295                 BADCVAR("sv_motd");
 296
 297                 v = cvar_string(k);
 298                 d = cvar_defstring(k);
 299                 if(v == d)
 300                         continue;
 301
 302                 if(adding)
 303                 {
 304                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 305                         if(strlen(cvar_changes) > 16384)
 306                         {
 307                                 cvar_changes = "// too many settings have been changed to show them here\n";
 308                                 adding = 0;
 309                         }
 310                 }
 311
 312                 // now check if the changes are actually gameplay relevant
 313
 314                 // does nothing visible
 315                 BADCVAR("captureleadlimit_override");
 316                 BADCVAR("g_balance_kill_delay");
 317                 BADCVAR("g_ca_point_limit");
 318                 BADCVAR("g_ca_point_leadlimit");
 319                 BADCVAR("g_ctf_captimerecord_always");
 320                 BADCVAR("g_ctf_flag_glowtrails");
 321                 BADCVAR("g_ctf_flag_pickup_verbosename");
 322                 BADCVAR("g_domination_point_leadlimit");
 323                 BADCVAR("g_forced_respawn");
 324                 BADCVAR("g_freezetag_point_limit");
 325                 BADCVAR("g_freezetag_point_leadlimit");
 326                 BADCVAR("g_keyhunt_point_leadlimit");
 327                 BADPREFIX("g_mod_");
 328                 BADCVAR("g_invasion_point_limit");
 329                 BADCVAR("g_nexball_goalleadlimit");
 330                 BADCVAR("g_tdm_point_limit");
 331                 BADCVAR("g_tdm_point_leadlimit");
 332                 BADCVAR("leadlimit_and_fraglimit");
 333                 BADCVAR("leadlimit_override");
 334                 BADCVAR("pausable");
 335                 BADCVAR("sv_allow_fullbright");
 336                 BADCVAR("sv_checkforpacketsduringsleep");
 337                 BADCVAR("sv_fraginfo");
 338                 BADCVAR("sv_timeout");
 339                 BADPREFIX("sv_timeout_");
 340                 BADPREFIX("crypto_");
 341                 BADPREFIX("g_chat_");
 342                 BADPREFIX("g_ctf_captimerecord_");
 343                 BADPREFIX("g_maplist_votable_");
 344                 BADPREFIX("net_");
 345                 BADPREFIX("prvm_");
 346                 BADPREFIX("skill_");
 347                 BADPREFIX("sv_cullentities_");
 348                 BADPREFIX("sv_fraginfo_");
 349                 BADPREFIX("sv_maxidle_");
 350                 BADPREFIX("sv_vote_");
 351                 BADPREFIX("timelimit_");
 352                 BADCVAR("gameversion");
 353                 BADPREFIX("gameversion_");
 354                 BADCVAR("sv_namechangetimer");
 355
 356                 // allowed changes to server admins (please sync this to server.cfg)
 357                 // vi commands:
 358                 //   :/"impure"/,$d
 359                 //   :g!,^\/\/[^ /],d
 360                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 361                 //   :%!sort
 362                 // yes, this does contain some redundant stuff, don't really care
 363                 BADCVAR("bot_config_file");
 364                 BADCVAR("bot_number");
 365                 BADCVAR("bot_prefix");
 366                 BADCVAR("bot_suffix");
 367                 BADCVAR("capturelimit_override");
 368                 BADCVAR("fraglimit_override");
 369                 BADCVAR("gametype");
 370                 BADCVAR("g_antilag");
 371                 BADCVAR("g_balance_teams");
 372                 BADCVAR("g_balance_teams_prevent_imbalance");
 373                 BADCVAR("g_balance_teams_scorefactor");
 374                 BADCVAR("g_ban_sync_trusted_servers");
 375                 BADCVAR("g_ban_sync_uri");
 376                 BADCVAR("g_ca_teams_override");
 377                 BADCVAR("g_ctf_ignore_frags");
 378                 BADCVAR("g_domination_point_limit");
 379                 BADCVAR("g_domination_teams_override");
 380                 BADCVAR("g_freezetag_teams_override");
 381                 BADCVAR("g_friendlyfire");
 382                 BADCVAR("g_fullbrightitems");
 383                 BADCVAR("g_fullbrightplayers");
 384                 BADCVAR("g_keyhunt_point_limit");
 385                 BADCVAR("g_keyhunt_teams_override");
 386                 BADCVAR("g_lms_lives_override");
 387                 BADCVAR("g_maplist");
 388                 BADCVAR("g_maplist_check_waypoints");
 389                 BADCVAR("g_maplist_mostrecent_count");
 390                 BADCVAR("g_maplist_shuffle");
 391                 BADCVAR("g_maplist_votable");
 392                 BADCVAR("g_maplist_votable_abstain");
 393                 BADCVAR("g_maplist_votable_nodetail");
 394                 BADCVAR("g_maplist_votable_suggestions");
 395                 BADCVAR("g_maxplayers");
 396                 BADCVAR("g_mirrordamage");
 397                 BADCVAR("g_nexball_goallimit");
 398                 BADCVAR("g_powerups");
 399                 BADCVAR("g_start_delay");
 400                 BADCVAR("g_tdm_teams_override");
 401                 BADCVAR("g_warmup");
 402                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 403                 BADCVAR("hostname");
 404                 BADCVAR("log_file");
 405                 BADCVAR("maxplayers");
 406                 BADCVAR("minplayers");
 407                 BADCVAR("net_address");
 408                 BADCVAR("port");
 409                 BADCVAR("rcon_password");
 410                 BADCVAR("rcon_restricted_commands");
 411                 BADCVAR("rcon_restricted_password");
 412                 BADCVAR("skill");
 413                 BADCVAR("sv_adminnick");
 414                 BADCVAR("sv_autoscreenshot");
 415                 BADCVAR("sv_autotaunt");
 416                 BADCVAR("sv_curl_defaulturl");
 417                 BADCVAR("sv_defaultcharacter");
 418                 BADCVAR("sv_defaultplayercolors");
 419                 BADCVAR("sv_defaultplayermodel");
 420                 BADCVAR("sv_defaultplayerskin");
 421                 BADCVAR("sv_maxidle");
 422                 BADCVAR("sv_maxrate");
 423                 BADCVAR("sv_motd");
 424                 BADCVAR("sv_public");
 425                 BADCVAR("sv_ready_restart");
 426                 BADCVAR("sv_status_privacy");
 427                 BADCVAR("sv_taunt");
 428                 BADCVAR("sv_vote_call");
 429                 BADCVAR("sv_vote_commands");
 430                 BADCVAR("sv_vote_majority_factor");
 431                 BADCVAR("sv_vote_master");
 432                 BADCVAR("sv_vote_master_commands");
 433                 BADCVAR("sv_vote_master_password");
 434                 BADCVAR("sv_vote_simple_majority_factor");
 435                 BADCVAR("teamplay_mode");
 436                 BADCVAR("timelimit_override");
 437                 BADCVAR("g_spawnshieldtime");
 438                 BADPREFIX("g_warmup_");
 439                 BADPREFIX("sv_ready_restart_");
 440
 441                 // mutators that announce themselves properly to the server browser
 442                 BADCVAR("g_instagib");
 443                 BADCVAR("g_new_toys");
 444                 BADCVAR("g_nix");
 445                 BADCVAR("g_grappling_hook");
 446                 BADCVAR("g_jetpack");
 447
 448 #undef BADPREFIX
 449 #undef BADCVAR
 450
 451                 if(pureadding)
 452                 {
 453                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 454                         if(strlen(cvar_purechanges) > 16384)
 455                         {
 456                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 457                                 pureadding = 0;
 458                         }
 459                 }
 460                 ++cvar_purechanges_count;
 461                 // WARNING: this variable is used for the server list
 462                 // NEVER dare to skip this code!
 463                 // Hacks to intentionally appearing as "pure server" even though you DO have
 464                 // modified settings may be punished by removal from the server list.
 465                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 466                 // though.
 467         }
 468         buf_del(h);
 469         if(cvar_changes == "")
 470                 cvar_changes = "// this server runs at default server settings\n";
 471         else
 472                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 473         cvar_changes = strzone(cvar_changes);
 474         if(cvar_purechanges == "")
 475                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 476         else
 477                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 478         cvar_purechanges = strzone(cvar_purechanges);
 479 }
 480
 481 void detect_maptype()
 482 {
 483 #if 0
 484         vector o, v;
 485         float i;
 486
 487         for (;;)
 488         {
 489                 o = world.mins;
 490                 o.x += random() * (world.maxs.x - world.mins.x);
 491                 o.y += random() * (world.maxs.y - world.mins.y);
 492                 o.z += random() * (world.maxs.z - world.mins.z);
 493
 494                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 495                 if(trace_fraction == 1)
 496                         continue;
 497
 498                 v = trace_endpos;
 499
 500                 for(i = 0; i < 64; i += 4)
 501                 {
 502                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 503         if(trace_fraction == 1)
 504                 continue;
 505                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 506                 }
 507
 508                 break;
 509         }
 510 #endif
 511 }
 512
 513 entity randomseed;
 514 float RandomSeed_Send(entity to, int sf)
 515 {
 516         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 517         WriteShort(MSG_ENTITY, self.cnt);
 518         return true;
 519 }
 520 void RandomSeed_Think()
 521 {
 522         self.cnt = bound(0, floor(random() * 65536), 65535);
 523         self.nextthink = time + 5;
 524
 525         self.SendFlags |= 1;
 526 }
 527 void RandomSeed_Spawn()
 528 {
 529         randomseed = spawn();
 530         randomseed.think = RandomSeed_Think;
 531         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 532
 533         entity oldself;
 534         oldself = self;
 535         self = randomseed;
 536         self.think(); // sets random seed and nextthink
 537         self = oldself;
 538 }
 539
 540 void spawnfunc___init_dedicated_server(void)
 541 {
 542         // handler for _init/_init map (only for dedicated server initialization)
 543
 544         world_initialized = -1; // don't complain
 545         cvar = cvar_normal;
 546         cvar_string = cvar_string_normal;
 547         cvar_set = cvar_set_normal;
 548
 549         remove = remove_unsafely;
 550
 551         entity e;
 552         e = spawn();
 553         e.think = GotoFirstMap;
 554         e.nextthink = time; // this is usually 1 at this point
 555
 556         e = spawn();
 557         e.classname = "info_player_deathmatch"; // safeguard against player joining
 558
 559         self.classname = "worldspawn"; // safeguard against various stuff ;)
 560
 561         // needs to be done so early because of the constants they create
 562         static_init();
 563         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 564         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 565         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 566         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 567         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 568
 569         MapInfo_Enumerate();
 570         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 571 }
 572
 573 void Map_MarkAsRecent(string m);
 574 float world_already_spawned;
 575 void Nagger_Init();
 576 void Item_ItemsTime_Init();
 577 void ClientInit_Spawn();
 578 void WeaponStats_Init();
 579 void WeaponStats_Shutdown();
 580 void Physics_AddStats();
 581 void spawnfunc_worldspawn (void)
 582 {
 583         float fd, l, j, n;
 584         string s;
 585
 586         cvar = cvar_normal;
 587         cvar_string = cvar_string_normal;
 588         cvar_set = cvar_set_normal;
 589
 590         if(world_already_spawned)
 591                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 592         world_already_spawned = true;
 593
 594         remove = remove_safely; // during spawning, watch what you remove!
 595
 596         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 597
 598         compressShortVector_init();
 599
 600         entity head;
 601         head = nextent(world);
 602         maxclients = 0;
 603         while(head)
 604         {
 605                 ++maxclients;
 606                 head = nextent(head);
 607         }
 608
 609         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? true : false);
 610
 611         // needs to be done so early because of the constants they create
 612         static_init();
 613         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 614         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 615         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 616         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 617         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 618
 619         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 620
 621         TemporaryDB = db_create();
 622
 623         // 0 normal
 624         lightstyle(0, "m");
 625
 626         // 1 FLICKER (first variety)
 627         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 628
 629         // 2 SLOW STRONG PULSE
 630         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 631
 632         // 3 CANDLE (first variety)
 633         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 634
 635         // 4 FAST STROBE
 636         lightstyle(4, "mamamamamama");
 637
 638         // 5 GENTLE PULSE 1
 639         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 640
 641         // 6 FLICKER (second variety)
 642         lightstyle(6, "nmonqnmomnmomomno");
 643
 644         // 7 CANDLE (second variety)
 645         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 646
 647         // 8 CANDLE (third variety)
 648         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 649
 650         // 9 SLOW STROBE (fourth variety)
 651         lightstyle(9, "aaaaaaaazzzzzzzz");
 652
 653         // 10 FLUORESCENT FLICKER
 654         lightstyle(10, "mmamammmmammamamaaamammma");
 655
 656         // 11 SLOW PULSE NOT FADE TO BLACK
 657         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 658
 659         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 660
 661         // 63 testing
 662         lightstyle(63, "a");
 663
 664         if(autocvar_g_campaign)
 665                 CampaignPreInit();
 666
 667         Map_MarkAsRecent(mapname);
 668
 669         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 670
 671         precache_model ("null"); // we need this one before InitGameplayMode
 672         InitGameplayMode();
 673         readlevelcvars();
 674         GrappleHookInit();
 675
 676         player_count = 0;
 677         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 678         if(bot_waypoints_for_items == 1)
 679                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 680                         bot_waypoints_for_items = 0;
 681
 682         precache();
 683
 684         WaypointSprite_Init();
 685
 686         GameLogInit(); // prepare everything
 687         // NOTE for matchid:
 688         // changing the logic generating it is okay. But:
 689         // it HAS to stay <= 64 chars
 690         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 691         if(autocvar_sv_eventlog)
 692         {
 693                 s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 694                 matchid = strzone(s);
 695
 696                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 697                 s = ":gameinfo:mutators:LIST";
 698
 699                 ret_string = s;
 700                 MUTATOR_CALLHOOK(BuildMutatorsString);
 701                 s = ret_string;
 702
 703                 // simple, probably not good in the mutator system
 704                 if(autocvar_g_grappling_hook)
 705                         s = strcat(s, ":grappling_hook");
 706
 707                 // initialiation stuff, not good in the mutator system
 708                 if(!autocvar_g_use_ammunition)
 709                         s = strcat(s, ":no_use_ammunition");
 710
 711                 // initialiation stuff, not good in the mutator system
 712                 if(autocvar_g_pickup_items == 0)
 713                         s = strcat(s, ":no_pickup_items");
 714                 if(autocvar_g_pickup_items > 0)
 715                         s = strcat(s, ":pickup_items");
 716
 717                 // initialiation stuff, not good in the mutator system
 718                 if(autocvar_g_weaponarena != "0")
 719                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 720
 721                 // TODO to mutator system
 722                 if(autocvar_g_norecoil)
 723                         s = strcat(s, ":norecoil");
 724
 725                 // TODO to mutator system
 726                 if(autocvar_g_powerups == 0)
 727                         s = strcat(s, ":no_powerups");
 728                 if(autocvar_g_powerups > 0)
 729                         s = strcat(s, ":powerups");
 730
 731                 GameLogEcho(s);
 732                 GameLogEcho(":gameinfo:end");
 733         }
 734         else
 735                 matchid = strzone(ftos(random()));
 736
 737         cvar_set("nextmap", "");
 738
 739         SetDefaultAlpha();
 740
 741         if(autocvar_g_campaign)
 742                 CampaignPostInit();
 743
 744         Ban_LoadBans();
 745
 746         MapInfo_Enumerate();
 747         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 748
 749         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 750         {
 751                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 752                 if(fd != -1)
 753                 {
 754                         while((s = fgets(fd)))
 755                         {
 756                                 l = tokenize_console(s);
 757                                 if(l < 2)
 758                                         continue;
 759                                 if(argv(0) == "cd")
 760                                 {
 761                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 762                                         print("  cdtrack ", argv(2), "\n");
 763                                 }
 764                                 else if(argv(0) == "fog")
 765                                 {
 766                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 767                                         print("  \"fog\" \"", s, "\"\n");
 768                                 }
 769                                 else if(argv(0) == "set")
 770                                 {
 771                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 772                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 773                                 }
 774                                 else if(argv(0) != "//")
 775                                 {
 776                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 777                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 778                                 }
 779                         }
 780                         fclose(fd);
 781                 }
 782         }
 783
 784         WeaponStats_Init();
 785
 786         WepSet_AddStat();
 787         WepSet_AddStat_InMap();
 788         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 789         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 790         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 791         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 792         addstat(STAT_ALLOW_OLDVORTEXBEAM, AS_INT, stat_allow_oldvortexbeam);
 793         Nagger_Init();
 794
 795         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 796         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 797         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 798         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 799         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 800         addstat(STAT_PLASMA, AS_INT, ammo_plasma);
 801         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 802         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 803         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 804         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 805         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 806         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 807         addstat(STAT_DAMAGE_DEALT_TOTAL, AS_INT, damage_dealt_total);
 808         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 809         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 810
 811         addstat(STAT_VORTEX_CHARGE, AS_FLOAT, vortex_charge);
 812         addstat(STAT_VORTEX_CHARGEPOOL, AS_FLOAT, vortex_chargepool_ammo);
 813
 814         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 815
 816         addstat(STAT_ARC_HEAT, AS_FLOAT, arc_heat_percent);
 817
 818         // items time
 819         addstat(STAT_ARMOR_LARGE_TIME, AS_FLOAT, item_armor_large_time);
 820         addstat(STAT_HEALTH_MEGA_TIME, AS_FLOAT, item_health_mega_time);
 821         addstat(STAT_INVISIBLE_TIME, AS_FLOAT, item_invisible_time);
 822         addstat(STAT_SPEED_TIME, AS_FLOAT, item_speed_time);
 823         addstat(STAT_EXTRALIFE_TIME, AS_FLOAT, item_extralife_time);
 824         addstat(STAT_STRENGTH_TIME, AS_FLOAT, item_strength_time);
 825         addstat(STAT_SHIELD_TIME, AS_FLOAT, item_shield_time);
 826         addstat(STAT_FUELREGEN_TIME, AS_FLOAT, item_fuelregen_time);
 827         addstat(STAT_JETPACK_TIME, AS_FLOAT, item_jetpack_time);
 828         addstat(STAT_SUPERWEAPONS_TIME, AS_FLOAT, item_superweapons_time);
 829         Item_ItemsTime_Init();
 830
 831         // freeze attacks
 832         addstat(STAT_FROZEN, AS_INT, frozen);
 833         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 834
 835         // physics
 836         Physics_AddStats();
 837
 838         // new properties
 839         addstat(STAT_MOVEVARS_JUMPVELOCITY, AS_FLOAT, stat_sv_jumpvelocity);
 840         addstat(STAT_MOVEVARS_AIRACCEL_QW_STRETCHFACTOR, AS_FLOAT, stat_sv_airaccel_qw_stretchfactor);
 841         addstat(STAT_MOVEVARS_MAXAIRSTRAFESPEED, AS_FLOAT, stat_sv_maxairstrafespeed);
 842         addstat(STAT_MOVEVARS_MAXAIRSPEED, AS_FLOAT, stat_sv_maxairspeed);
 843         addstat(STAT_MOVEVARS_AIRSTRAFEACCELERATE, AS_FLOAT, stat_sv_airstrafeaccelerate);
 844         addstat(STAT_MOVEVARS_WARSOWBUNNY_TURNACCEL, AS_FLOAT, stat_sv_warsowbunny_turnaccel);
 845         addstat(STAT_MOVEVARS_AIRACCEL_SIDEWAYS_FRICTION, AS_FLOAT, stat_sv_airaccel_sideways_friction);
 846         addstat(STAT_MOVEVARS_AIRCONTROL, AS_FLOAT, stat_sv_aircontrol);
 847         addstat(STAT_MOVEVARS_AIRCONTROL_POWER, AS_FLOAT, stat_sv_aircontrol_power);
 848         addstat(STAT_MOVEVARS_AIRCONTROL_PENALTY, AS_FLOAT, stat_sv_aircontrol_penalty);
 849         addstat(STAT_MOVEVARS_WARSOWBUNNY_AIRFORWARDACCEL, AS_FLOAT, stat_sv_warsowbunny_airforwardaccel);
 850         addstat(STAT_MOVEVARS_WARSOWBUNNY_TOPSPEED, AS_FLOAT, stat_sv_warsowbunny_topspeed);
 851         addstat(STAT_MOVEVARS_WARSOWBUNNY_ACCEL, AS_FLOAT, stat_sv_warsowbunny_accel);
 852         addstat(STAT_MOVEVARS_WARSOWBUNNY_BACKTOSIDERATIO, AS_FLOAT, stat_sv_warsowbunny_backtosideratio);
 853         addstat(STAT_MOVEVARS_FRICTION, AS_FLOAT, stat_sv_friction);
 854         addstat(STAT_MOVEVARS_ACCELERATE, AS_FLOAT, stat_sv_accelerate);
 855         addstat(STAT_MOVEVARS_STOPSPEED, AS_FLOAT, stat_sv_stopspeed);
 856         addstat(STAT_MOVEVARS_AIRACCELERATE, AS_FLOAT, stat_sv_airaccelerate);
 857         addstat(STAT_MOVEVARS_AIRSTOPACCELERATE, AS_FLOAT, stat_sv_airstopaccelerate);
 858
 859         // secrets
 860         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 861         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 862
 863         // monsters
 864         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 865         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 866
 867         // misc
 868         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 869
 870         next_pingtime = time + 5;
 871
 872         detect_maptype();
 873
 874         // set up information replies for clients and server to use
 875         maplist_reply = strzone(getmaplist());
 876         lsmaps_reply = strzone(getlsmaps());
 877         monsterlist_reply = strzone(getmonsterlist());
 878         for(int i = 0; i < 10; ++i)
 879         {
 880                 s = getrecords(i);
 881                 if (s)
 882                         records_reply[i] = strzone(s);
 883         }
 884         ladder_reply = strzone(getladder());
 885         rankings_reply = strzone(getrankings());
 886
 887         // begin other init
 888         ClientInit_Spawn();
 889         RandomSeed_Spawn();
 890         PingPLReport_Spawn();
 891
 892         CheatInit();
 893
 894         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 895
 896         // fill sv_curl_serverpackages from .serverpackage files
 897         if(autocvar_sv_curl_serverpackages_auto)
 898         {
 899                 s = "";
 900                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 901                 for(int i = 0; i < n; ++i)
 902                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 903                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 904                                 s = strcat(s, " ", argv(i));
 905                 fd = search_begin("*-serverpackage.txt", true, false);
 906                 if(fd >= 0)
 907                 {
 908                         j = search_getsize(fd);
 909                         for(int i = 0; i < j; ++i)
 910                                 s = strcat(s, " ", search_getfilename(fd, i));
 911                         search_end(fd);
 912                 }
 913                 fd = search_begin("*.serverpackage", true, false);
 914                 if(fd >= 0)
 915                 {
 916                         j = search_getsize(fd);
 917                         for(int i = 0; i < j; ++i)
 918                                 s = strcat(s, " ", search_getfilename(fd, i));
 919                         search_end(fd);
 920                 }
 921                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 922         }
 923
 924         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 925         modname = "Xonotic";
 926         // physics/balance/config changes that count as mod
 927         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 928                 modname = cvar_string("g_mod_physics");
 929         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 930                 modname = cvar_string("g_mod_balance");
 931         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 932                 modname = cvar_string("g_mod_config");
 933         // extra mutators that deserve to count as mod
 934         MUTATOR_CALLHOOK(SetModname);
 935
 936         // save it for later
 937         modname = strzone(modname);
 938
 939         WinningConditionHelper(); // set worldstatus
 940
 941         world_initialized = 1;
 942 }
 943
 944 void spawnfunc_light (void)
 945 {
 946         //makestatic (self); // Who the f___ did that?
 947         remove(self);
 948 }
 949
 950 string GetGametype()
 951 {
 952         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 953 }
 954
 955 string GetMapname()
 956 {
 957         return mapname;
 958 }
 959
 960 float Map_Count, Map_Current;
 961 string Map_Current_Name;
 962
 963 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 964 float GetMaplistPosition()
 965 {
 966         float pos, idx;
 967         string map;
 968
 969         map = GetMapname();
 970         idx = autocvar_g_maplist_index;
 971
 972         if(idx >= 0)
 973                 if(idx < Map_Count)
 974                         if(map == argv(idx))
 975                                 return idx;
 976
 977         for(pos = 0; pos < Map_Count; ++pos)
 978                 if(map == argv(pos))
 979                         return pos;
 980
 981         // resume normal maplist rotation if current map is not in g_maplist
 982         return idx;
 983 }
 984
 985 float MapHasRightSize(string map)
 986 {
 987         float fh;
 988         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 989         if(autocvar_g_maplist_check_waypoints)
 990         {
 991                 dprint("checkwp "); dprint(map);
 992                 if(!fexists(strcat("maps/", map, ".waypoints")))
 993                 {
 994                         dprint(": no waypoints\n");
 995                         return false;
 996                 }
 997                 dprint(": has waypoints\n");
 998         }
 999
1000         // open map size restriction file
1001         dprint("opensize "); dprint(map);
1002         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1003         if(fh >= 0)
1004         {
1005                 float mapmin, mapmax;
1006                 dprint(": ok, ");
1007                 mapmin = stof(fgets(fh));
1008                 mapmax = stof(fgets(fh));
1009                 fclose(fh);
1010                 if(player_count < mapmin)
1011                 {
1012                         dprint("not enough\n");
1013                         return false;
1014                 }
1015                 if(player_count > mapmax)
1016                 {
1017                         dprint("too many\n");
1018                         return false;
1019                 }
1020                 dprint("right size\n");
1021                 return true;
1022         }
1023         dprint(": not found\n");
1024         return true;
1025 }
1026
1027 string Map_Filename(float position)
1028 {
1029         return strcat("maps/", argv(position), ".bsp");
1030 }
1031
1032 string strwords(string s, float w)
1033 {
1034         float endpos;
1035         for(endpos = 0; w && endpos >= 0; --w)
1036                 endpos = strstrofs(s, " ", endpos + 1);
1037         if(endpos < 0)
1038                 return s;
1039         else
1040                 return substring(s, 0, endpos);
1041 }
1042
1043 float strhasword(string s, string w)
1044 {
1045         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1046 }
1047
1048 void Map_MarkAsRecent(string m)
1049 {
1050         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1051 }
1052
1053 float Map_IsRecent(string m)
1054 {
1055         return strhasword(autocvar_g_maplist_mostrecent, m);
1056 }
1057
1058 float Map_Check(float position, float pass)
1059 {
1060         string filename;
1061         string map_next;
1062         map_next = argv(position);
1063         if(pass <= 1)
1064         {
1065                 if(Map_IsRecent(map_next))
1066                         return 0;
1067         }
1068         filename = Map_Filename(position);
1069         if(MapInfo_CheckMap(map_next))
1070         {
1071                 if(pass == 2)
1072                         return 1;
1073                 if(MapHasRightSize(map_next))
1074                         return 1;
1075                 return 0;
1076         }
1077         else
1078                 dprint( "Couldn't select '", filename, "'..\n" );
1079
1080         return 0;
1081 }
1082
1083 void Map_Goto_SetStr(string nextmapname)
1084 {
1085         if(getmapname_stored != "")
1086                 strunzone(getmapname_stored);
1087         if(nextmapname == "")
1088                 getmapname_stored = "";
1089         else
1090                 getmapname_stored = strzone(nextmapname);
1091 }
1092
1093 void Map_Goto_SetFloat(float position)
1094 {
1095         cvar_set("g_maplist_index", ftos(position));
1096         Map_Goto_SetStr(argv(position));
1097 }
1098
1099 void Map_Goto(float reinit)
1100 {
1101         MapInfo_LoadMap(getmapname_stored, reinit);
1102 }
1103
1104 // return codes of map selectors:
1105 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1106 //   -2 = permanent failure
1107 float() MaplistMethod_Iterate = // usual method
1108 {
1109         float pass, i;
1110
1111         dprint("Trying MaplistMethod_Iterate\n");
1112
1113         for(pass = 1; pass <= 2; ++pass)
1114         {
1115                 for(i = 1; i < Map_Count; ++i)
1116                 {
1117                         float mapindex;
1118                         mapindex = (i + Map_Current) % Map_Count;
1119                         if(Map_Check(mapindex, pass))
1120                                 return mapindex;
1121                 }
1122         }
1123         return -1;
1124 }
1125
1126 float() MaplistMethod_Repeat = // fallback method
1127 {
1128         dprint("Trying MaplistMethod_Repeat\n");
1129
1130         if(Map_Check(Map_Current, 2))
1131                 return Map_Current;
1132         return -2;
1133 }
1134
1135 float() MaplistMethod_Random = // random map selection
1136 {
1137         float i, imax;
1138
1139         dprint("Trying MaplistMethod_Random\n");
1140
1141         imax = 42;
1142
1143         for(i = 0; i <= imax; ++i)
1144         {
1145                 float mapindex;
1146                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1147                 if(Map_Check(mapindex, 1))
1148                         return mapindex;
1149         }
1150         return -1;
1151 }
1152
1153 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1154 // the exponent sets a bias on the map selection:
1155 // the higher the exponent, the less likely "shortly repeated" same maps are
1156 {
1157         float i, j, imax, insertpos;
1158
1159         dprint("Trying MaplistMethod_Shuffle\n");
1160
1161         imax = 42;
1162
1163         for(i = 0; i <= imax; ++i)
1164         {
1165                 string newlist;
1166
1167                 // now reinsert this at another position
1168                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1169                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1170                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1171                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1172
1173                 // insert the current map there
1174                 newlist = "";
1175                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1176                         newlist = strcat(newlist, " ", argv(j));
1177                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1178                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1179                         newlist = strcat(newlist, " ", argv(j));
1180                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1181                 cvar_set("g_maplist", newlist);
1182                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1183
1184                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1185                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1186                 if(Map_Check(Map_Current, 1))
1187                         return Map_Current;
1188         }
1189         return -1;
1190 }
1191
1192 void Maplist_Init()
1193 {
1194         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1195         float i;
1196         for (i = 0; i < Map_Count; ++i)
1197                 if (Map_Check(i, 2))
1198                         break;
1199         if (i == Map_Count)
1200         {
1201                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1202                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1203                 if(autocvar_g_maplist_shuffle)
1204                         ShuffleMaplist();
1205                 localcmd("\nmenu_cmd sync\n");
1206                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1207         }
1208         if(Map_Count == 0)
1209                 error("empty maplist, cannot select a new map");
1210         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1211
1212         if(Map_Current_Name)
1213                 strunzone(Map_Current_Name);
1214         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1215         // this may or may not be correct, but who cares, in the worst case a map
1216         // isn't chosen in the first pass that should have been
1217 }
1218
1219 string GetNextMap()
1220 {
1221         float nextMap;
1222
1223         Maplist_Init();
1224         nextMap = -1;
1225
1226         if(nextMap == -1)
1227                 if(autocvar_g_maplist_shuffle > 0)
1228                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1229
1230         if(nextMap == -1)
1231                 if(autocvar_g_maplist_selectrandom)
1232                         nextMap = MaplistMethod_Random();
1233
1234         if(nextMap == -1)
1235                 nextMap = MaplistMethod_Iterate();
1236
1237         if(nextMap == -1)
1238                 nextMap = MaplistMethod_Repeat();
1239
1240         if(nextMap >= 0)
1241         {
1242                 Map_Goto_SetFloat(nextMap);
1243                 return getmapname_stored;
1244         }
1245
1246         return "";
1247 }
1248
1249 float DoNextMapOverride(float reinit)
1250 {
1251         if(autocvar_g_campaign)
1252         {
1253                 CampaignPostIntermission();
1254                 alreadychangedlevel = true;
1255                 return true;
1256         }
1257         if(autocvar_quit_when_empty)
1258         {
1259                 if(player_count <= currentbots)
1260                 {
1261                         localcmd("quit\n");
1262                         alreadychangedlevel = true;
1263                         return true;
1264                 }
1265         }
1266         if(autocvar_quit_and_redirect != "")
1267         {
1268                 redirection_target = strzone(autocvar_quit_and_redirect);
1269                 alreadychangedlevel = true;
1270                 return true;
1271         }
1272         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1273         {
1274                 localcmd("restart\n");
1275                 alreadychangedlevel = true;
1276                 return true;
1277         }
1278         if(autocvar_nextmap != "")
1279         {
1280                 string m;
1281                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1282                 cvar_set("nextmap",m);
1283
1284                 if(!m || gametypevote)
1285                         return false;
1286                 if(autocvar_sv_vote_gametype)
1287                 {
1288                         Map_Goto_SetStr(m);
1289                         return false;
1290                 }
1291
1292                 if(MapInfo_CheckMap(m))
1293                 {
1294                         Map_Goto_SetStr(m);
1295                         Map_Goto(reinit);
1296                         alreadychangedlevel = true;
1297                         return true;
1298                 }
1299         }
1300         if(!reinit && autocvar_lastlevel)
1301         {
1302                 cvar_settemp_restore();
1303                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1304                 alreadychangedlevel = true;
1305                 return true;
1306         }
1307         return false;
1308 }
1309
1310 void GotoNextMap(float reinit)
1311 {
1312         //string nextmap;
1313         //float n, nummaps;
1314         //string s;
1315         if (alreadychangedlevel)
1316                 return;
1317         alreadychangedlevel = true;
1318
1319         string nextMap;
1320
1321         nextMap = GetNextMap();
1322         if(nextMap == "")
1323                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1324         Map_Goto(reinit);
1325 }
1326
1327
1328 /*
1329 ============
1330 IntermissionThink
1331
1332 When the player presses attack or jump, change to the next level
1333 ============
1334 */
1335 .float autoscreenshot;
1336 void IntermissionThink()
1337 {
1338         FixIntermissionClient(self);
1339
1340         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1341         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1342
1343         if( (server_screenshot || client_screenshot)
1344                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1345         {
1346                 self.autoscreenshot = -1;
1347                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1348                 return;
1349         }
1350
1351         if (time < intermission_exittime)
1352                 return;
1353
1354         if(!mapvote_initialized)
1355                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1356                         return;
1357
1358         MapVote_Start();
1359 }
1360
1361 /*
1362 ============
1363 FindIntermission
1364
1365 Returns the entity to view from
1366 ============
1367 */
1368 /*
1369 entity FindIntermission()
1370 {
1371         local   entity spot;
1372         local   float cyc;
1373
1374 // look for info_intermission first
1375         spot = find (world, classname, "info_intermission");
1376         if (spot)
1377         {       // pick a random one
1378                 cyc = random() * 4;
1379                 while (cyc > 1)
1380                 {
1381                         spot = find (spot, classname, "info_intermission");
1382                         if (!spot)
1383                                 spot = find (spot, classname, "info_intermission");
1384                         cyc = cyc - 1;
1385                 }
1386                 return spot;
1387         }
1388
1389 // then look for the start position
1390         spot = find (world, classname, "info_player_start");
1391         if (spot)
1392                 return spot;
1393
1394 // testinfo_player_start is only found in regioned levels
1395         spot = find (world, classname, "testplayerstart");
1396         if (spot)
1397                 return spot;
1398
1399 // then look for the start position
1400         spot = find (world, classname, "info_player_deathmatch");
1401         if (spot)
1402                 return spot;
1403
1404         //objerror ("FindIntermission: no spot");
1405         return world;
1406 }
1407 */
1408
1409 /*
1410 ===============================================================================
1411
1412 RULES
1413
1414 ===============================================================================
1415 */
1416
1417 void DumpStats(float final)
1418 {
1419         float file;
1420         string s;
1421         float to_console;
1422         float to_eventlog;
1423         float to_file;
1424         float i;
1425
1426         to_console = autocvar_sv_logscores_console;
1427         to_eventlog = autocvar_sv_eventlog;
1428         to_file = autocvar_sv_logscores_file;
1429
1430         if(!final)
1431         {
1432                 to_console = true; // always print printstats replies
1433                 to_eventlog = false; // but never print them to the event log
1434         }
1435
1436         if(to_eventlog)
1437                 if(autocvar_sv_eventlog_console)
1438                         to_console = false; // otherwise we get the output twice
1439
1440         if(final)
1441                 s = ":scores:";
1442         else
1443                 s = ":status:";
1444         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1445
1446         if(to_console)
1447                 print(s, "\n");
1448         if(to_eventlog)
1449                 GameLogEcho(s);
1450
1451         file = -1;
1452         if(to_file)
1453         {
1454                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1455                 if(file == -1)
1456                         to_file = false;
1457                 else
1458                         fputs(file, strcat(s, "\n"));
1459         }
1460
1461         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1462         if(to_console)
1463                 print(s, "\n");
1464         if(to_eventlog)
1465                 GameLogEcho(s);
1466         if(to_file)
1467                 fputs(file, strcat(s, "\n"));
1468
1469         FOR_EACH_CLIENT(other)
1470         {
1471                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1472                 {
1473                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1474                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1475                         if(IS_PLAYER(other) || other.caplayer == 1 || g_lms)
1476                                 s = strcat(s, ftos(other.team), ":");
1477                         else
1478                                 s = strcat(s, "spectator:");
1479
1480                         if(to_console)
1481                                 print(s, other.netname, "\n");
1482                         if(to_eventlog)
1483                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1484                         if(to_file)
1485                                 fputs(file, strcat(s, other.netname, "\n"));
1486                 }
1487         }
1488
1489         if(teamplay)
1490         {
1491                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1492                 if(to_console)
1493                         print(s, "\n");
1494                 if(to_eventlog)
1495                         GameLogEcho(s);
1496                 if(to_file)
1497                         fputs(file, strcat(s, "\n"));
1498
1499                 for(i = 1; i < 16; ++i)
1500                 {
1501                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1502                         s = strcat(s, ":", ftos(i));
1503                         if(to_console)
1504                                 print(s, "\n");
1505                         if(to_eventlog)
1506                                 GameLogEcho(s);
1507                         if(to_file)
1508                                 fputs(file, strcat(s, "\n"));
1509                 }
1510         }
1511
1512         if(to_console)
1513                 print(":end\n");
1514         if(to_eventlog)
1515                 GameLogEcho(":end");
1516         if(to_file)
1517         {
1518                 fputs(file, ":end\n");
1519                 fclose(file);
1520         }
1521 }
1522
1523 void FixIntermissionClient(entity e)
1524 {
1525         string s;
1526         if(!e.autoscreenshot) // initial call
1527         {
1528                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1529                 e.health = -2342;
1530                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1531                 e.solid = SOLID_NOT;
1532                 e.movetype = MOVETYPE_NONE;
1533                 e.takedamage = DAMAGE_NO;
1534                 if(e.weaponentity)
1535                 {
1536                         e.weaponentity.effects = EF_NODRAW;
1537                         if (e.weaponentity.weaponentity)
1538                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1539                 }
1540                 if(IS_REAL_CLIENT(e))
1541                 {
1542                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1543                         s = autocvar_sv_intermission_cdtrack;
1544                         if(s != "")
1545                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1546                         msg_entity = e;
1547                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1548                 }
1549         }
1550 }
1551
1552 /*
1553 go to the next level for deathmatch
1554 only called if a time or frag limit has expired
1555 */
1556 void NextLevel()
1557 {
1558         gameover = true;
1559
1560         intermission_running = 1;
1561
1562 // enforce a wait time before allowing changelevel
1563         if(player_count > 0)
1564                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1565         else
1566                 intermission_exittime = -1;
1567
1568         /*
1569         WriteByte (MSG_ALL, SVC_CDTRACK);
1570         WriteByte (MSG_ALL, 3);
1571         WriteByte (MSG_ALL, 3);
1572         // done in FixIntermission
1573         */
1574
1575         //pos = FindIntermission ();
1576
1577         VoteReset();
1578
1579         DumpStats(true);
1580
1581         // send statistics
1582         PlayerStats_GameReport(true);
1583         WeaponStats_Shutdown();
1584
1585         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1586
1587         if(autocvar_sv_eventlog)
1588                 GameLogEcho(":gameover");
1589
1590         GameLogClose();
1591
1592         FOR_EACH_PLAYER(other) {
1593                 FixIntermissionClient(other);
1594                 if(other.winning)
1595                         bprint(other.netname, " ^7wins.\n");
1596         }
1597
1598         if(autocvar_g_campaign)
1599                 CampaignPreIntermission();
1600
1601         MUTATOR_CALLHOOK(MatchEnd);
1602
1603         localcmd("\nsv_hook_gameend\n");
1604 }
1605
1606 /*
1607 ============
1608 CheckRules_Player
1609
1610 Exit deathmatch games upon conditions
1611 ============
1612 */
1613 void CheckRules_Player()
1614 {
1615         if (gameover)   // someone else quit the game already
1616                 return;
1617
1618         if(self.deadflag == DEAD_NO)
1619                 self.play_time += frametime;
1620
1621         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1622         //   (div0: and that in CheckRules_World please)
1623 }
1624
1625
1626 float InitiateSuddenDeath()
1627 {
1628         // Check first whether normal overtimes could be added before initiating suddendeath mode
1629         // - for this timelimit_overtime needs to be >0 of course
1630         // - also check the winning condition calculated in the previous frame and only add normal overtime
1631         //   again, if at the point at which timelimit would be extended again, still no winner was found
1632         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1633         {
1634                 return 1; // need to call InitiateOvertime later
1635         }
1636         else
1637         {
1638                 if(!checkrules_suddendeathend)
1639                 {
1640                         if(autocvar_g_campaign)
1641                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1642                         else
1643                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1644                         if(g_race && !g_race_qualifying)
1645                                 race_StartCompleting();
1646                 }
1647                 return 0;
1648         }
1649 }
1650
1651 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1652 {
1653         ++checkrules_overtimesadded;
1654         //add one more overtime by simply extending the timelimit
1655         float tl;
1656         tl = autocvar_timelimit;
1657         tl += autocvar_timelimit_overtime;
1658         cvar_set("timelimit", ftos(tl));
1659
1660         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1661 }
1662
1663 float GetWinningCode(float fraglimitreached, float equality)
1664 {
1665         if(autocvar_g_campaign == 1)
1666                 if(fraglimitreached)
1667                         return WINNING_YES;
1668                 else
1669                         return WINNING_NO;
1670
1671         else
1672                 if(equality)
1673                         if(fraglimitreached)
1674                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1675                         else
1676                                 return WINNING_NEVER;
1677                 else
1678                         if(fraglimitreached)
1679                                 return WINNING_YES;
1680                         else
1681                                 return WINNING_NO;
1682 }
1683
1684 // set the .winning flag for exactly those players with a given field value
1685 void SetWinners(.float field, float value)
1686 {
1687         entity head;
1688         FOR_EACH_PLAYER(head)
1689                 head.winning = (head.(field) == value);
1690 }
1691
1692 // set the .winning flag for those players with a given field value
1693 void AddWinners(.float field, float value)
1694 {
1695         entity head;
1696         FOR_EACH_PLAYER(head)
1697                 if (head.(field) == value)
1698                         head.winning = 1;
1699 }
1700
1701 // clear the .winning flags
1702 void ClearWinners(void)
1703 {
1704         entity head;
1705         FOR_EACH_PLAYER(head)
1706                 head.winning = 0;
1707 }
1708
1709 // Onslaught winning condition:
1710 // game terminates if only one team has a working generator (or none)
1711 float WinningCondition_Onslaught()
1712 {
1713         entity head;
1714         float t1, t2, t3, t4;
1715
1716         WinningConditionHelper(); // set worldstatus
1717
1718         if(warmup_stage)
1719                 return WINNING_NO;
1720
1721         // first check if the game has ended
1722         t1 = t2 = t3 = t4 = 0;
1723         head = find(world, classname, "onslaught_generator");
1724         while (head)
1725         {
1726                 if (head.health > 0)
1727                 {
1728                         if (head.team == NUM_TEAM_1) t1 = 1;
1729                         if (head.team == NUM_TEAM_2) t2 = 1;
1730                         if (head.team == NUM_TEAM_3) t3 = 1;
1731                         if (head.team == NUM_TEAM_4) t4 = 1;
1732                 }
1733                 head = find(head, classname, "onslaught_generator");
1734         }
1735         if (t1 + t2 + t3 + t4 < 2)
1736         {
1737                 // game over, only one team remains (or none)
1738                 ClearWinners();
1739                 if (t1) SetWinners(team, NUM_TEAM_1);
1740                 if (t2) SetWinners(team, NUM_TEAM_2);
1741                 if (t3) SetWinners(team, NUM_TEAM_3);
1742                 if (t4) SetWinners(team, NUM_TEAM_4);
1743                 dprint("Have a winner, ending game.\n");
1744                 return WINNING_YES;
1745         }
1746
1747         // Two or more teams remain
1748         return WINNING_NO;
1749 }
1750
1751 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1752 // they win. Otherwise the defending team wins once the timelimit passes.
1753 void assault_new_round();
1754 float WinningCondition_Assault()
1755 {
1756         float status;
1757
1758         WinningConditionHelper(); // set worldstatus
1759
1760         status = WINNING_NO;
1761         // as the timelimit has not yet passed just assume the defending team will win
1762         if(assault_attacker_team == NUM_TEAM_1)
1763         {
1764                 SetWinners(team, NUM_TEAM_2);
1765         }
1766         else
1767         {
1768                 SetWinners(team, NUM_TEAM_1);
1769         }
1770
1771         entity ent;
1772         ent = find(world, classname, "target_assault_roundend");
1773         if(ent)
1774         {
1775                 if(ent.winning) // round end has been triggered by attacking team
1776                 {
1777                         bprint("ASSAULT: round completed...\n");
1778                         SetWinners(team, assault_attacker_team);
1779
1780                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1781
1782                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1783                         {
1784                                 status = WINNING_YES;
1785                         }
1786                         else
1787                         {
1788                                 entity oldself;
1789                                 oldself = self;
1790                                 self = ent;
1791                                 assault_new_round();
1792                                 self = oldself;
1793                         }
1794                 }
1795         }
1796
1797         return status;
1798 }
1799
1800 // LMS winning condition: game terminates if and only if there's at most one
1801 // one player who's living lives. Top two scores being equal cancels the time
1802 // limit.
1803 float WinningCondition_LMS()
1804 {
1805         entity head, head2;
1806         float have_player;
1807         float have_players;
1808         float l;
1809
1810         have_player = false;
1811         have_players = false;
1812         l = LMS_NewPlayerLives();
1813
1814         head = find(world, classname, "player");
1815         if(head)
1816                 have_player = true;
1817         head2 = find(head, classname, "player");
1818         if(head2)
1819                 have_players = true;
1820
1821         if(have_player)
1822         {
1823                 // we have at least one player
1824                 if(have_players)
1825                 {
1826                         // two or more active players - continue with the game
1827                 }
1828                 else
1829                 {
1830                         // exactly one player?
1831
1832                         ClearWinners();
1833                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1834
1835                         if(l)
1836                         {
1837                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1838                                 return WINNING_NO;
1839                         }
1840                         else
1841                         {
1842                                 // a winner!
1843                                 // and assign him his first place
1844                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1845                                 return WINNING_YES;
1846                         }
1847                 }
1848         }
1849         else
1850         {
1851                 // nobody is playing at all...
1852                 if(l)
1853                 {
1854                         // wait for players...
1855                 }
1856                 else
1857                 {
1858                         // SNAFU (maybe a draw game?)
1859                         ClearWinners();
1860                         dprint("No players, ending game.\n");
1861                         return WINNING_YES;
1862                 }
1863         }
1864
1865         // When we get here, we have at least two players who are actually LIVING,
1866         // now check if the top two players have equal score.
1867         WinningConditionHelper();
1868
1869         ClearWinners();
1870         if(WinningConditionHelper_winner)
1871                 WinningConditionHelper_winner.winning = true;
1872         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1873                 return WINNING_NEVER;
1874
1875         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1876         return WINNING_NO;
1877 }
1878
1879 void ShuffleMaplist()
1880 {
1881         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1882 }
1883
1884 float leaderfrags;
1885 float WinningCondition_Scores(float limit, float leadlimit)
1886 {
1887         float limitreached;
1888
1889         // TODO make everything use THIS winning condition (except LMS)
1890         WinningConditionHelper();
1891
1892         if(teamplay)
1893         {
1894                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1895                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1896                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1897                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1898         }
1899
1900         ClearWinners();
1901         if(WinningConditionHelper_winner)
1902                 WinningConditionHelper_winner.winning = 1;
1903         if(WinningConditionHelper_winnerteam >= 0)
1904                 SetWinners(team, WinningConditionHelper_winnerteam);
1905
1906         if(WinningConditionHelper_lowerisbetter)
1907         {
1908                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1909                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1910                 limit = -limit;
1911         }
1912
1913         if(WinningConditionHelper_zeroisworst)
1914                 leadlimit = 0; // not supported in this mode
1915
1916         if(g_dm || g_tdm || g_ca || g_freezetag || (g_race && !g_race_qualifying) || g_nexball)
1917         // these modes always score in increments of 1, thus this makes sense
1918         {
1919                 if(leaderfrags != WinningConditionHelper_topscore)
1920                 {
1921                         leaderfrags = WinningConditionHelper_topscore;
1922
1923                         if (limit)
1924                         if (leaderfrags == limit - 1)
1925                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1926                         else if (leaderfrags == limit - 2)
1927                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1928                         else if (leaderfrags == limit - 3)
1929                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1930                 }
1931         }
1932
1933         limitreached = false;
1934         if(limit)
1935                 if(WinningConditionHelper_topscore >= limit)
1936                         limitreached = true;
1937         if(leadlimit)
1938         {
1939                 float leadlimitreached;
1940                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1941                 if(autocvar_leadlimit_and_fraglimit)
1942                         limitreached = (limitreached && leadlimitreached);
1943                 else
1944                         limitreached = (limitreached || leadlimitreached);
1945         }
1946
1947         if(limit)
1948                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1949
1950         return GetWinningCode(
1951                 WinningConditionHelper_topscore && limitreached,
1952                 WinningConditionHelper_equality
1953         );
1954 }
1955
1956 float WinningCondition_Race(float fraglimit)
1957 {
1958         float wc;
1959         entity p;
1960         float n, c;
1961
1962         n = 0;
1963         c = 0;
1964         FOR_EACH_PLAYER(p)
1965         {
1966                 ++n;
1967                 if(p.race_completed)
1968                         ++c;
1969         }
1970         if(n && (n == c))
1971                 return WINNING_YES;
1972         wc = WinningCondition_Scores(fraglimit, 0);
1973
1974         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1975         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1976         // do NOT support equality when the laps are all raced!
1977                 return WINNING_STARTSUDDENDEATHOVERTIME;
1978         else
1979                 return WINNING_NEVER;
1980 }
1981
1982 float WinningCondition_QualifyingThenRace(float limit)
1983 {
1984         float wc;
1985         wc = WinningCondition_Scores(limit, 0);
1986
1987         // NEVER initiate overtime
1988         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1989         {
1990                 return WINNING_YES;
1991         }
1992
1993         return wc;
1994 }
1995
1996 float WinningCondition_RanOutOfSpawns()
1997 {
1998         entity head;
1999
2000         if(have_team_spawns <= 0)
2001                 return WINNING_NO;
2002
2003         if(!autocvar_g_spawn_useallspawns)
2004                 return WINNING_NO;
2005
2006         if(!some_spawn_has_been_used)
2007                 return WINNING_NO;
2008
2009         team1_score = team2_score = team3_score = team4_score = 0;
2010
2011         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2012         {
2013                 if(head.team == NUM_TEAM_1)
2014                         team1_score = 1;
2015                 else if(head.team == NUM_TEAM_2)
2016                         team2_score = 1;
2017                 else if(head.team == NUM_TEAM_3)
2018                         team3_score = 1;
2019                 else if(head.team == NUM_TEAM_4)
2020                         team4_score = 1;
2021         }
2022
2023         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2024         {
2025                 if(head.team == NUM_TEAM_1)
2026                         team1_score = 1;
2027                 else if(head.team == NUM_TEAM_2)
2028                         team2_score = 1;
2029                 else if(head.team == NUM_TEAM_3)
2030                         team3_score = 1;
2031                 else if(head.team == NUM_TEAM_4)
2032                         team4_score = 1;
2033         }
2034
2035         ClearWinners();
2036         if(team1_score + team2_score + team3_score + team4_score == 0)
2037         {
2038                 checkrules_equality = true;
2039                 return WINNING_YES;
2040         }
2041         else if(team1_score + team2_score + team3_score + team4_score == 1)
2042         {
2043                 float t, i;
2044                 if(team1_score)
2045                         t = NUM_TEAM_1;
2046                 else if(team2_score)
2047                         t = NUM_TEAM_2;
2048                 else if(team3_score)
2049                         t = NUM_TEAM_3;
2050                 else // if(team4_score)
2051                         t = NUM_TEAM_4;
2052                 CheckAllowedTeams(world);
2053                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2054                 {
2055                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
2056                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2057                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2058                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2059                 }
2060
2061                 AddWinners(team, t);
2062                 return WINNING_YES;
2063         }
2064         else
2065                 return WINNING_NO;
2066 }
2067
2068 /*
2069 ============
2070 CheckRules_World
2071
2072 Exit deathmatch games upon conditions
2073 ============
2074 */
2075 void CheckRules_World()
2076 {
2077         float timelimit;
2078         float fraglimit;
2079         float leadlimit;
2080
2081         VoteThink();
2082         MapVote_Think();
2083
2084         SetDefaultAlpha();
2085
2086         if (gameover)   // someone else quit the game already
2087         {
2088                 if(player_count == 0) // Nobody there? Then let's go to the next map
2089                         MapVote_Start();
2090                         // this will actually check the player count in the next frame
2091                         // again, but this shouldn't hurt
2092                 return;
2093         }
2094
2095         timelimit = autocvar_timelimit * 60;
2096         fraglimit = autocvar_fraglimit;
2097         leadlimit = autocvar_leadlimit;
2098
2099         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2100         {
2101                 if(timelimit > 0)
2102                         timelimit = 0; // timelimit is not made for warmup
2103                 if(fraglimit > 0)
2104                         fraglimit = 0; // no fraglimit for now
2105                 leadlimit = 0; // no leadlimit for now
2106         }
2107
2108         if(timelimit > 0)
2109         {
2110                 timelimit += game_starttime;
2111         }
2112         else if (timelimit < 0)
2113         {
2114                 // endmatch
2115                 NextLevel();
2116                 return;
2117         }
2118
2119         if(g_onslaught)
2120                 timelimit = 0; // ONS has its own overtime rule
2121
2122         float wantovertime;
2123         wantovertime = 0;
2124
2125         if(timelimit > game_starttime)
2126                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2127         else
2128                 game_completion_ratio = 0;
2129
2130         if(checkrules_suddendeathend)
2131         {
2132                 if(!checkrules_suddendeathwarning)
2133                 {
2134                         checkrules_suddendeathwarning = true;
2135                         if(g_race && !g_race_qualifying)
2136                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2137                         else
2138                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2139                 }
2140         }
2141         else
2142         {
2143                 if (timelimit && time >= timelimit)
2144                 {
2145                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2146                         {
2147                                 float totalplayers;
2148                                 float playerswithlaps;
2149                                 float readyplayers;
2150                                 entity head;
2151                                 totalplayers = playerswithlaps = readyplayers = 0;
2152                                 FOR_EACH_PLAYER(head)
2153                                 {
2154                                         ++totalplayers;
2155                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2156                                                 ++playerswithlaps;
2157                                         if(head.ready)
2158                                                 ++readyplayers;
2159                                 }
2160
2161                                 // at least 2 of the players have completed a lap: start the RACE
2162                                 // otherwise, the players should end the qualifying on their own
2163                                 if(readyplayers || playerswithlaps >= 2)
2164                                 {
2165                                         checkrules_suddendeathend = 0;
2166                                         ReadyRestart(); // go to race
2167                                         return;
2168                                 }
2169                                 else
2170                                         wantovertime |= InitiateSuddenDeath();
2171                         }
2172                         else
2173                                 wantovertime |= InitiateSuddenDeath();
2174                 }
2175         }
2176
2177         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2178         {
2179                 NextLevel();
2180                 return;
2181         }
2182
2183         float checkrules_status;
2184         checkrules_status = WinningCondition_RanOutOfSpawns();
2185         if(checkrules_status == WINNING_YES)
2186         {
2187                 bprint("Hey! Someone ran out of spawns!\n");
2188         }
2189         else if(g_race && !g_race_qualifying && timelimit >= 0)
2190         {
2191                 checkrules_status = WinningCondition_Race(fraglimit);
2192                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2193         }
2194         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2195         {
2196                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2197                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2198         }
2199         else if(g_assault)
2200         {
2201                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2202         }
2203         else if(g_lms)
2204         {
2205                 checkrules_status = WinningCondition_LMS();
2206         }
2207         else if (g_onslaught)
2208         {
2209                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2210         }
2211         else
2212         {
2213                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2214                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2215         }
2216
2217         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2218         {
2219                 checkrules_status = WINNING_NEVER;
2220                 checkrules_overtimesadded = -1;
2221                 wantovertime |= InitiateSuddenDeath();
2222         }
2223
2224         if(checkrules_status == WINNING_NEVER)
2225                 // equality cases! Nobody wins if the overtime ends in a draw.
2226                 ClearWinners();
2227
2228         if(wantovertime)
2229         {
2230                 if(checkrules_status == WINNING_NEVER)
2231                         InitiateOvertime();
2232                 else
2233                         checkrules_status = WINNING_YES;
2234         }
2235
2236         if(checkrules_suddendeathend)
2237                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2238                         checkrules_status = WINNING_YES;
2239
2240         if(checkrules_status == WINNING_YES)
2241         {
2242                 //print("WINNING\n");
2243                 NextLevel();
2244         }
2245 }
2246
2247 string GotoMap(string m)
2248 {
2249         m = GameTypeVote_MapInfo_FixName(m);
2250         if (!m)
2251                 return "The map you suggested is not available on this server.";
2252         if (!autocvar_sv_vote_gametype)
2253         if(!MapInfo_CheckMap(m))
2254                 return "The map you suggested does not support the current game mode.";
2255         cvar_set("nextmap", m);
2256         cvar_set("timelimit", "-1");
2257         if(mapvote_initialized || alreadychangedlevel)
2258         {
2259                 if(DoNextMapOverride(0))
2260                         return "Map switch initiated.";
2261                 else
2262                         return "Hm... no. For some reason I like THIS map more.";
2263         }
2264         else
2265                 return "Map switch will happen after scoreboard.";
2266 }
2267
2268
2269 void EndFrame()
2270 {
2271         anticheat_endframe();
2272
2273         float altime;
2274         FOR_EACH_REALCLIENT(self)
2275         {
2276                 entity e = IS_SPEC(self) ? self.enemy : self;
2277                 if(e.typehitsound)
2278                         self.typehit_time = time;
2279                 else if(e.damage_dealt)
2280                 {
2281                         self.hit_time = time;
2282                         self.damage_dealt_total += ceil(e.damage_dealt);
2283                 }
2284         }
2285         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2286         // add 1 frametime because after this, engine SV_Physics
2287         // increases time by a frametime and then networks the frame
2288         // add another frametime because client shows everything with
2289         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2290         // needed!
2291         FOR_EACH_CLIENT(self)
2292         {
2293                 self.typehitsound = false;
2294                 self.damage_dealt = 0;
2295                 antilag_record(self, altime);
2296         }
2297         FOR_EACH_MONSTER(self)
2298                 antilag_record(self, altime);
2299 }
2300
2301
2302 /*
2303  * RedirectionThink:
2304  * returns true if redirecting
2305  */
2306 float redirection_timeout;
2307 float redirection_nextthink;
2308 float RedirectionThink()
2309 {
2310         float clients_found;
2311
2312         if(redirection_target == "")
2313                 return false;
2314
2315         if(!redirection_timeout)
2316         {
2317                 cvar_set("sv_public", "-2");
2318                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2319                 if(redirection_target == "self")
2320                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2321                 else
2322                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2323         }
2324
2325         if(time < redirection_nextthink)
2326                 return true;
2327
2328         redirection_nextthink = time + 1;
2329
2330         clients_found = 0;
2331         FOR_EACH_REALCLIENT(self)
2332         {
2333                 // TODO add timer
2334                 print("Redirecting: sending connect command to ", self.netname, "\n");
2335                 if(redirection_target == "self")
2336                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2337                 else
2338                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2339                 ++clients_found;
2340         }
2341
2342         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2343
2344         if(time > redirection_timeout || clients_found == 0)
2345                 localcmd("\nwait; wait; wait; quit\n");
2346
2347         return true;
2348 }
2349
2350 void TargetMusic_RestoreGame();
2351 void RestoreGame()
2352 {
2353         // Loaded from a save game
2354         // some things then break, so let's work around them...
2355
2356         // Progs DB (capture records)
2357         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2358
2359         // Mapinfo
2360         MapInfo_Shutdown();
2361         MapInfo_Enumerate();
2362         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2363         WeaponStats_Init();
2364
2365         TargetMusic_RestoreGame();
2366 }
2367
2368 void Shutdown()
2369 {
2370         gameover = 2;
2371
2372         if(world_initialized > 0)
2373         {
2374                 world_initialized = 0;
2375                 print("Saving persistent data...\n");
2376                 Ban_SaveBans();
2377
2378                 // playerstats with unfinished match
2379                 PlayerStats_GameReport(false);
2380
2381                 if(!cheatcount_total)
2382                 {
2383                         if(autocvar_sv_db_saveasdump)
2384                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2385                         else
2386                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2387                 }
2388                 if(autocvar_developer)
2389                 {
2390                         if(autocvar_sv_db_saveasdump)
2391                                 db_dump(TemporaryDB, "server-temp.db");
2392                         else
2393                                 db_save(TemporaryDB, "server-temp.db");
2394                 }
2395                 CheatShutdown(); // must be after cheatcount check
2396                 db_close(ServerProgsDB);
2397                 db_close(TemporaryDB);
2398                 print("done!\n");
2399                 // tell the bot system the game is ending now
2400                 bot_endgame();
2401
2402                 WeaponStats_Shutdown();
2403                 MapInfo_Shutdown();
2404         }
2405         else if(world_initialized == 0)
2406         {
2407                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2408         }
2409 }